compiler/basicTypes/OccName.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 -- |
   8 -- #name_types#
   9 -- GHC uses several kinds of name internally:
  10 --
  11 -- * 'OccName.OccName' represents names as strings with just a little more information:
  12 --   the \"namespace\" that the name came from, e.g. the namespace of value, type constructors or
  13 --   data constructors
  14 --
  15 -- * 'RdrName.RdrName': see "RdrName#name_types"
  16 --
  17 -- * 'Name.Name': see "Name#name_types"
  18 --
  19 -- * 'Id.Id': see "Id#name_types"
  20 --
  21 -- * 'Var.Var': see "Var#name_types"
  22 module OccName (
  23         -- * The 'NameSpace' type
  24         NameSpace, -- Abstract
  25
  26         -- ** Construction
  27         -- $real_vs_source_data_constructors
  28         tcName, clsName, tcClsName, dataName, varName,
  29         tvName, srcDataName,
  30
  31         -- ** Pretty Printing
  32         pprNameSpace, pprNonVarNameSpace, pprNameSpaceBrief,
  33
  34         -- * The 'OccName' type
  35         OccName,        -- Abstract, instance of Outputable
  36         pprOccName,
  37
  38         -- ** Construction
  39         mkOccName, mkOccNameFS,
  40         mkVarOcc, mkVarOccFS,
  41         mkDataOcc, mkDataOccFS,
  42         mkTyVarOcc, mkTyVarOccFS,
  43         mkTcOcc, mkTcOccFS,
  44         mkClsOcc, mkClsOccFS,
  45         mkDFunOcc,
  46         mkTupleOcc,
  47         setOccNameSpace,
  48
  49         -- ** Derived 'OccName's
  50         isDerivedOccName,
  51         mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc,
  52         mkDerivedTyConOcc, mkNewTyCoOcc, mkClassOpAuxOcc,
  53         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
  54         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
  55         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
  56         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc,
  57         mkSuperDictSelOcc, mkLocalOcc, mkMethodOcc, mkInstTyTcOcc,
  58         mkInstTyCoOcc, mkEqPredCoOcc,
  59         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
  60         mkPDataTyConOcc, mkPDataDataConOcc,
  61         mkPReprTyConOcc,
  62         mkPADFunOcc,
  63
  64         -- ** Deconstruction
  65         occNameFS, occNameString, occNameSpace,
  66
  67         isVarOcc, isTvOcc, isTcOcc, isDataOcc, isDataSymOcc, isSymOcc, isValOcc,
  68         parenSymOcc, startsWithUnderscore,
  69
  70         isTcClsNameSpace, isTvNameSpace, isDataConNameSpace, isVarNameSpace, isValNameSpace,
  71
  72         isTupleOcc_maybe,
  73
  74         -- * The 'OccEnv' type
  75         OccEnv, emptyOccEnv, unitOccEnv, extendOccEnv, mapOccEnv,
  76         lookupOccEnv, mkOccEnv, mkOccEnv_C, extendOccEnvList, elemOccEnv,
  77         occEnvElts, foldOccEnv, plusOccEnv, plusOccEnv_C, extendOccEnv_C,
  78         extendOccEnv_Acc, filterOccEnv, delListFromOccEnv, delFromOccEnv,
  79
  80         -- * The 'OccSet' type
  81         OccSet, emptyOccSet, unitOccSet, mkOccSet, extendOccSet,
  82         extendOccSetList,
  83         unionOccSets, unionManyOccSets, minusOccSet, elemOccSet, occSetElts,
  84         foldOccSet, isEmptyOccSet, intersectOccSet, intersectsOccSet,
  85
  86         -- * Tidying up
  87         TidyOccEnv, emptyTidyOccEnv, tidyOccName, initTidyOccEnv,
  88
  89         -- * Lexical characteristics of Haskell names
  90         isLexCon, isLexVar, isLexId, isLexSym,
  91         isLexConId, isLexConSym, isLexVarId, isLexVarSym,
  92         startsVarSym, startsVarId, startsConSym, startsConId
  93     ) where
  94
  95 #include "Typeable.h"
  96
  97 import Util
  98 import Unique
  99 import BasicTypes
 100 import UniqFM
 101 import UniqSet
 102 import FastString
 103 import Outputable
 104 import Binary
 105 import StaticFlags( opt_SuppressUniques )
 106 import Data.Char
 107 import Data.Data
 108 \end{code}
 109
 110 %************************************************************************
 111 %*                                                                      *
 112 \subsection{Name space}
 113 %*                                                                      *
 114 %************************************************************************
 115
 116 \begin{code}
 117 data NameSpace = VarName        -- Variables, including "real" data constructors
 118                | DataName       -- "Source" data constructors
 119                | TvName         -- Type variables
 120                | TcClsName      -- Type constructors and classes; Haskell has them
 121                                 -- in the same name space for now.
 122                deriving( Eq, Ord )
 123    {-! derive: Binary !-}
 124
 125 -- Note [Data Constructors]
 126 -- see also: Note [Data Constructor Naming] in DataCon.lhs
 127 --
 128 -- $real_vs_source_data_constructors
 129 -- There are two forms of data constructor:
 130 --
 131 --      [Source data constructors] The data constructors mentioned in Haskell source code
 132 --
 133 --      [Real data constructors] The data constructors of the representation type, which may not be the same as the source type
 134 --
 135 -- For example:
 136 --
 137 -- > data T = T !(Int, Int)
 138 --
 139 -- The source datacon has type @(Int, Int) -> T@
 140 -- The real   datacon has type @Int -> Int -> T@
 141 --
 142 -- GHC chooses a representation based on the strictness etc.
 143
 144 tcName, clsName, tcClsName :: NameSpace
 145 dataName, srcDataName      :: NameSpace
 146 tvName, varName            :: NameSpace
 147
 148 -- Though type constructors and classes are in the same name space now,
 149 -- the NameSpace type is abstract, so we can easily separate them later
 150 tcName    = TcClsName           -- Type constructors
 151 clsName   = TcClsName           -- Classes
 152 tcClsName = TcClsName           -- Not sure which!
 153
 154 dataName    = DataName
 155 srcDataName = DataName  -- Haskell-source data constructors should be
 156                         -- in the Data name space
 157
 158 tvName      = TvName
 159 varName     = VarName
 160
 161 isDataConNameSpace :: NameSpace -> Bool
 162 isDataConNameSpace DataName = True
 163 isDataConNameSpace _        = False
 164
 165 isTcClsNameSpace :: NameSpace -> Bool
 166 isTcClsNameSpace TcClsName = True
 167 isTcClsNameSpace _         = False
 168
 169 isTvNameSpace :: NameSpace -> Bool
 170 isTvNameSpace TvName = True
 171 isTvNameSpace _      = False
 172
 173 isVarNameSpace :: NameSpace -> Bool     -- Variables or type variables, but not constructors
 174 isVarNameSpace TvName  = True
 175 isVarNameSpace VarName = True
 176 isVarNameSpace _       = False
 177
 178 isValNameSpace :: NameSpace -> Bool
 179 isValNameSpace DataName = True
 180 isValNameSpace VarName  = True
 181 isValNameSpace _        = False
 182
 183 pprNameSpace :: NameSpace -> SDoc
 184 pprNameSpace DataName  = ptext (sLit "data constructor")
 185 pprNameSpace VarName   = ptext (sLit "variable")
 186 pprNameSpace TvName    = ptext (sLit "type variable")
 187 pprNameSpace TcClsName = ptext (sLit "type constructor or class")
 188
 189 pprNonVarNameSpace :: NameSpace -> SDoc
 190 pprNonVarNameSpace VarName = empty
 191 pprNonVarNameSpace ns = pprNameSpace ns
 192
 193 pprNameSpaceBrief :: NameSpace -> SDoc
 194 pprNameSpaceBrief DataName  = char 'd'
 195 pprNameSpaceBrief VarName   = char 'v'
 196 pprNameSpaceBrief TvName    = ptext (sLit "tv")
 197 pprNameSpaceBrief TcClsName = ptext (sLit "tc")
 198 \end{code}
 199
 200
 201 %************************************************************************
 202 %*                                                                      *
 203 \subsection[Name-pieces-datatypes]{The @OccName@ datatypes}
 204 %*                                                                      *
 205 %************************************************************************
 206
 207 \begin{code}
 208 data OccName = OccName
 209     { occNameSpace  :: !NameSpace
 210     , occNameFS     :: !FastString
 211     }
 212 \end{code}
 213
 214
 215 \begin{code}
 216 instance Eq OccName where
 217     (OccName sp1 s1) == (OccName sp2 s2) = s1 == s2 && sp1 == sp2
 218
 219 instance Ord OccName where
 220         -- Compares lexicographically, *not* by Unique of the string
 221     compare (OccName sp1 s1) (OccName sp2 s2)
 222         = (s1  `compare` s2) `thenCmp` (sp1 `compare` sp2)
 223
 224 INSTANCE_TYPEABLE0(OccName,occNameTc,"OccName")
 225
 226 instance Data OccName where
 227   -- don't traverse?
 228   toConstr _   = abstractConstr "OccName"
 229   gunfold _ _  = error "gunfold"
 230   dataTypeOf _ = mkNoRepType "OccName"
 231 \end{code}
 232
 233
 234 %************************************************************************
 235 %*                                                                      *
 236 \subsection{Printing}
 237 %*                                                                      *
 238 %************************************************************************
 239
 240 \begin{code}
 241 instance Outputable OccName where
 242     ppr = pprOccName
 243
 244 pprOccName :: OccName -> SDoc
 245 pprOccName (OccName sp occ)
 246   = getPprStyle $ \ sty ->
 247     if codeStyle sty
 248     then ftext (zEncodeFS occ)
 249     else pp_occ <> pp_debug sty
 250   where
 251     pp_debug sty | debugStyle sty = braces (pprNameSpaceBrief sp)
 252                  | otherwise      = empty
 253
 254     pp_occ | opt_SuppressUniques = text (strip_th_unique (unpackFS occ))
 255            | otherwise           = ftext occ
 256
 257         -- See Note [Suppressing uniques in OccNames]
 258     strip_th_unique ('[' : c : _) | isAlphaNum c = []
 259     strip_th_unique (c : cs) = c : strip_th_unique cs
 260     strip_th_unique []       = []
 261 \end{code}
 262
 263 Note [Suppressing uniques in OccNames]
 264 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 265 This is a hack to de-wobblify the OccNames that contain uniques from
 266 Template Haskell that have been turned into a string in the OccName.
 267 See Note [Unique OccNames from Template Haskell] in Convert.hs
 268
 269 %************************************************************************
 270 %*                                                                      *
 271 \subsection{Construction}
 272 %*                                                                      *
 273 %************************************************************************
 274
 275 \begin{code}
 276 mkOccName :: NameSpace -> String -> OccName
 277 mkOccName occ_sp str = OccName occ_sp (mkFastString str)
 278
 279 mkOccNameFS :: NameSpace -> FastString -> OccName
 280 mkOccNameFS occ_sp fs = OccName occ_sp fs
 281
 282 mkVarOcc :: String -> OccName
 283 mkVarOcc s = mkOccName varName s
 284
 285 mkVarOccFS :: FastString -> OccName
 286 mkVarOccFS fs = mkOccNameFS varName fs
 287
 288 mkDataOcc :: String -> OccName
 289 mkDataOcc = mkOccName dataName
 290
 291 mkDataOccFS :: FastString -> OccName
 292 mkDataOccFS = mkOccNameFS dataName
 293
 294 mkTyVarOcc :: String -> OccName
 295 mkTyVarOcc = mkOccName tvName
 296
 297 mkTyVarOccFS :: FastString -> OccName
 298 mkTyVarOccFS fs = mkOccNameFS tvName fs
 299
 300 mkTcOcc :: String -> OccName
 301 mkTcOcc = mkOccName tcName
 302
 303 mkTcOccFS :: FastString -> OccName
 304 mkTcOccFS = mkOccNameFS tcName
 305
 306 mkClsOcc :: String -> OccName
 307 mkClsOcc = mkOccName clsName
 308
 309 mkClsOccFS :: FastString -> OccName
 310 mkClsOccFS = mkOccNameFS clsName
 311 \end{code}
 312
 313
 314 %************************************************************************
 315 %*                                                                      *
 316                 Environments
 317 %*                                                                      *
 318 %************************************************************************
 319
 320 OccEnvs are used mainly for the envts in ModIfaces.
 321
 322 Note [The Unique of an OccName]
 323 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 324 They are efficient, because FastStrings have unique Int# keys.  We assume
 325 this key is less than 2^24, and indeed FastStrings are allocated keys
 326 sequentially starting at 0.
 327
 328 So we can make a Unique using
 329         mkUnique ns key  :: Unique
 330 where 'ns' is a Char reprsenting the name space.  This in turn makes it
 331 easy to build an OccEnv.
 332
 333 \begin{code}
 334 instance Uniquable OccName where
 335       -- See Note [The Unique of an OccName]
 336   getUnique (OccName VarName   fs) = mkVarOccUnique  fs
 337   getUnique (OccName DataName  fs) = mkDataOccUnique fs
 338   getUnique (OccName TvName    fs) = mkTvOccUnique   fs
 339   getUnique (OccName TcClsName fs) = mkTcOccUnique   fs
 340
 341 newtype OccEnv a = A (UniqFM a)
 342
 343 emptyOccEnv :: OccEnv a
 344 unitOccEnv  :: OccName -> a -> OccEnv a
 345 extendOccEnv :: OccEnv a -> OccName -> a -> OccEnv a
 346 extendOccEnvList :: OccEnv a -> [(OccName, a)] -> OccEnv a
 347 lookupOccEnv :: OccEnv a -> OccName -> Maybe a
 348 mkOccEnv     :: [(OccName,a)] -> OccEnv a
 349 mkOccEnv_C   :: (a -> a -> a) -> [(OccName,a)] -> OccEnv a
 350 elemOccEnv   :: OccName -> OccEnv a -> Bool
 351 foldOccEnv   :: (a -> b -> b) -> b -> OccEnv a -> b
 352 occEnvElts   :: OccEnv a -> [a]
 353 extendOccEnv_C :: (a->a->a) -> OccEnv a -> OccName -> a -> OccEnv a
 354 extendOccEnv_Acc :: (a->b->b) -> (a->b) -> OccEnv b -> OccName -> a -> OccEnv b
 355 plusOccEnv     :: OccEnv a -> OccEnv a -> OccEnv a
 356 plusOccEnv_C   :: (a->a->a) -> OccEnv a -> OccEnv a -> OccEnv a
 357 mapOccEnv      :: (a->b) -> OccEnv a -> OccEnv b
 358 delFromOccEnv      :: OccEnv a -> OccName -> OccEnv a
 359 delListFromOccEnv :: OccEnv a -> [OccName] -> OccEnv a
 360 filterOccEnv       :: (elt -> Bool) -> OccEnv elt -> OccEnv elt
 361
 362 emptyOccEnv      = A emptyUFM
 363 unitOccEnv x y = A $ unitUFM x y
 364 extendOccEnv (A x) y z = A $ addToUFM x y z
 365 extendOccEnvList (A x) l = A $ addListToUFM x l
 366 lookupOccEnv (A x) y = lookupUFM x y
 367 mkOccEnv     l    = A $ listToUFM l
 368 elemOccEnv x (A y)       = elemUFM x y
 369 foldOccEnv a b (A c)     = foldUFM a b c
 370 occEnvElts (A x)         = eltsUFM x
 371 plusOccEnv (A x) (A y)   = A $ plusUFM x y
 372 plusOccEnv_C f (A x) (A y)       = A $ plusUFM_C f x y
 373 extendOccEnv_C f (A x) y z   = A $ addToUFM_C f x y z
 374 extendOccEnv_Acc f g (A x) y z   = A $ addToUFM_Acc f g x y z
 375 mapOccEnv f (A x)        = A $ mapUFM f x
 376 mkOccEnv_C comb l = A $ addListToUFM_C comb emptyUFM l
 377 delFromOccEnv (A x) y    = A $ delFromUFM x y
 378 delListFromOccEnv (A x) y  = A $ delListFromUFM x y
 379 filterOccEnv x (A y)       = A $ filterUFM x y
 380
 381 instance Outputable a => Outputable (OccEnv a) where
 382     ppr (A x) = ppr x
 383
 384 type OccSet = UniqSet OccName
 385
 386 emptyOccSet       :: OccSet
 387 unitOccSet        :: OccName -> OccSet
 388 mkOccSet          :: [OccName] -> OccSet
 389 extendOccSet      :: OccSet -> OccName -> OccSet
 390 extendOccSetList  :: OccSet -> [OccName] -> OccSet
 391 unionOccSets      :: OccSet -> OccSet -> OccSet
 392 unionManyOccSets  :: [OccSet] -> OccSet
 393 minusOccSet       :: OccSet -> OccSet -> OccSet
 394 elemOccSet        :: OccName -> OccSet -> Bool
 395 occSetElts        :: OccSet -> [OccName]
 396 foldOccSet        :: (OccName -> b -> b) -> b -> OccSet -> b
 397 isEmptyOccSet     :: OccSet -> Bool
 398 intersectOccSet   :: OccSet -> OccSet -> OccSet
 399 intersectsOccSet  :: OccSet -> OccSet -> Bool
 400
 401 emptyOccSet       = emptyUniqSet
 402 unitOccSet        = unitUniqSet
 403 mkOccSet          = mkUniqSet
 404 extendOccSet      = addOneToUniqSet
 405 extendOccSetList  = addListToUniqSet
 406 unionOccSets      = unionUniqSets
 407 unionManyOccSets  = unionManyUniqSets
 408 minusOccSet       = minusUniqSet
 409 elemOccSet        = elementOfUniqSet
 410 occSetElts        = uniqSetToList
 411 foldOccSet        = foldUniqSet
 412 isEmptyOccSet     = isEmptyUniqSet
 413 intersectOccSet   = intersectUniqSets
 414 intersectsOccSet s1 s2 = not (isEmptyOccSet (s1 `intersectOccSet` s2))
 415 \end{code}
 416
 417
 418 %************************************************************************
 419 %*                                                                      *
 420 \subsection{Predicates and taking them apart}
 421 %*                                                                      *
 422 %************************************************************************
 423
 424 \begin{code}
 425 occNameString :: OccName -> String
 426 occNameString (OccName _ s) = unpackFS s
 427
 428 setOccNameSpace :: NameSpace -> OccName -> OccName
 429 setOccNameSpace sp (OccName _ occ) = OccName sp occ
 430
 431 isVarOcc, isTvOcc, isTcOcc, isDataOcc :: OccName -> Bool
 432
 433 isVarOcc (OccName VarName _) = True
 434 isVarOcc _                   = False
 435
 436 isTvOcc (OccName TvName _) = True
 437 isTvOcc _                  = False
 438
 439 isTcOcc (OccName TcClsName _) = True
 440 isTcOcc _                     = False
 441
 442 -- | /Value/ 'OccNames's are those that are either in
 443 -- the variable or data constructor namespaces
 444 isValOcc :: OccName -> Bool
 445 isValOcc (OccName VarName  _) = True
 446 isValOcc (OccName DataName _) = True
 447 isValOcc _                    = False
 448
 449 isDataOcc (OccName DataName _) = True
 450 isDataOcc (OccName VarName s)
 451   | isLexCon s = pprPanic "isDataOcc: check me" (ppr s)
 452                 -- Jan06: I don't think this should happen
 453 isDataOcc _                    = False
 454
 455 -- | Test if the 'OccName' is a data constructor that starts with
 456 -- a symbol (e.g. @:@, or @[]@)
 457 isDataSymOcc :: OccName -> Bool
 458 isDataSymOcc (OccName DataName s) = isLexConSym s
 459 isDataSymOcc (OccName VarName s)
 460   | isLexConSym s = pprPanic "isDataSymOcc: check me" (ppr s)
 461                 -- Jan06: I don't think this should happen
 462 isDataSymOcc _                    = False
 463 -- Pretty inefficient!
 464
 465 -- | Test if the 'OccName' is that for any operator (whether
 466 -- it is a data constructor or variable or whatever)
 467 isSymOcc :: OccName -> Bool
 468 isSymOcc (OccName DataName s)  = isLexConSym s
 469 isSymOcc (OccName TcClsName s) = isLexConSym s
 470 isSymOcc (OccName VarName s)   = isLexSym s
 471 isSymOcc (OccName TvName s)    = isLexSym s
 472 -- Pretty inefficient!
 473
 474 parenSymOcc :: OccName -> SDoc -> SDoc
 475 -- ^ Wrap parens around an operator
 476 parenSymOcc occ doc | isSymOcc occ = parens doc
 477                     | otherwise    = doc
 478 \end{code}
 479
 480
 481 \begin{code}
 482 startsWithUnderscore :: OccName -> Bool
 483 -- ^ Haskell 98 encourages compilers to suppress warnings about unsed
 484 -- names in a pattern if they start with @_@: this implements that test
 485 startsWithUnderscore occ = case occNameString occ of
 486                              ('_' : _) -> True
 487                              _other    -> False
 488 \end{code}
 489
 490
 491 %************************************************************************
 492 %*                                                                      *
 493 \subsection{Making system names}
 494 %*                                                                      *
 495 %************************************************************************
 496
 497 Here's our convention for splitting up the interface file name space:
 498
 499    d...         dictionary identifiers
 500                 (local variables, so no name-clash worries)
 501
 502 All of these other OccNames contain a mixture of alphabetic
 503 and symbolic characters, and hence cannot possibly clash with
 504 a user-written type or function name
 505
 506    $f...        Dict-fun identifiers (from inst decls)
 507    $dmop        Default method for 'op'
 508    $pnC         n'th superclass selector for class C
 509    $wf          Worker for functtoin 'f'
 510    $sf..        Specialised version of f
 511    T:C          Tycon for dictionary for class C
 512    D:C          Data constructor for dictionary for class C
 513    NTCo:T       Coercion connecting newtype T with its representation type
 514    TFCo:R       Coercion connecting a data family to its respresentation type R
 515
 516 In encoded form these appear as Zdfxxx etc
 517
 518         :...            keywords (export:, letrec: etc.)
 519 --- I THINK THIS IS WRONG!
 520
 521 This knowledge is encoded in the following functions.
 522
 523 @mk_deriv@ generates an @OccName@ from the prefix and a string.
 524 NB: The string must already be encoded!
 525
 526 \begin{code}
 527 mk_deriv :: NameSpace
 528          -> String              -- Distinguishes one sort of derived name from another
 529          -> String
 530          -> OccName
 531
 532 mk_deriv occ_sp sys_prefix str = mkOccName occ_sp (sys_prefix ++ str)
 533
 534 isDerivedOccName :: OccName -> Bool
 535 isDerivedOccName occ =
 536    case occNameString occ of
 537      '$':c:_ | isAlphaNum c -> True
 538      ':':c:_ | isAlphaNum c -> True
 539      _other                 -> False
 540 \end{code}
 541
 542 \begin{code}
 543 mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc, mkDerivedTyConOcc,
 544         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
 545         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
 546         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc, mkNewTyCoOcc,
 547         mkInstTyCoOcc, mkEqPredCoOcc, mkClassOpAuxOcc,
 548         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
 549         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
 550         mkPDataTyConOcc, mkPDataDataConOcc, mkPReprTyConOcc, mkPADFunOcc
 551    :: OccName -> OccName
 552
 553 -- These derived variables have a prefix that no Haskell value could have
 554 mkDataConWrapperOcc = mk_simple_deriv varName  "$W"
 555 mkWorkerOcc         = mk_simple_deriv varName  "$w"
 556 mkDefaultMethodOcc  = mk_simple_deriv varName  "$dm"
 557 mkClassOpAuxOcc     = mk_simple_deriv varName  "$c"
 558 mkDerivedTyConOcc   = mk_simple_deriv tcName   ":"      -- The : prefix makes sure it classifies
 559 mkClassTyConOcc     = mk_simple_deriv tcName   "T:"     -- as a tycon/datacon
 560 mkClassDataConOcc   = mk_simple_deriv dataName "D:"     -- We go straight to the "real" data con
 561                                                         -- for datacons from classes
 562 mkDictOcc           = mk_simple_deriv varName  "$d"
 563 mkIPOcc             = mk_simple_deriv varName  "$i"
 564 mkSpecOcc           = mk_simple_deriv varName  "$s"
 565 mkForeignExportOcc  = mk_simple_deriv varName  "$f"
 566 mkNewTyCoOcc        = mk_simple_deriv tcName   "NTCo:"  -- Coercion for newtypes
 567 mkInstTyCoOcc       = mk_simple_deriv tcName   "TFCo:"   -- Coercion for type functions
 568 mkEqPredCoOcc       = mk_simple_deriv tcName   "$co"
 569
 570 -- used in derived instances
 571 mkCon2TagOcc        = mk_simple_deriv varName  "$con2tag_"
 572 mkTag2ConOcc        = mk_simple_deriv varName  "$tag2con_"
 573 mkMaxTagOcc         = mk_simple_deriv varName  "$maxtag_"
 574
 575 -- Generic derivable classes
 576 mkGenOcc1           = mk_simple_deriv varName  "$gfrom"
 577 mkGenOcc2           = mk_simple_deriv varName  "$gto"
 578
 579 -- data T = MkT ... deriving( Data ) needs defintions for
 580 --      $tT   :: Data.Generics.Basics.DataType
 581 --      $cMkT :: Data.Generics.Basics.Constr
 582 mkDataTOcc = mk_simple_deriv varName  "$t"
 583 mkDataCOcc = mk_simple_deriv varName  "$c"
 584
 585 -- Vectorisation
 586 mkVectOcc          = mk_simple_deriv varName  "$v_"
 587 mkVectTyConOcc     = mk_simple_deriv tcName   ":V_"
 588 mkVectDataConOcc   = mk_simple_deriv dataName ":VD_"
 589 mkVectIsoOcc       = mk_simple_deriv varName  "$VI_"
 590 mkPDataTyConOcc    = mk_simple_deriv tcName   ":VP_"
 591 mkPDataDataConOcc  = mk_simple_deriv dataName ":VPD_"
 592 mkPReprTyConOcc    = mk_simple_deriv tcName   ":VR_"
 593 mkPADFunOcc        = mk_simple_deriv varName  "$PA_"
 594
 595 mk_simple_deriv :: NameSpace -> String -> OccName -> OccName
 596 mk_simple_deriv sp px occ = mk_deriv sp px (occNameString occ)
 597
 598 -- Data constructor workers are made by setting the name space
 599 -- of the data constructor OccName (which should be a DataName)
 600 -- to VarName
 601 mkDataConWorkerOcc datacon_occ = setOccNameSpace varName datacon_occ
 602 \end{code}
 603
 604 \begin{code}
 605 mkSuperDictSelOcc :: Int        -- ^ Index of superclass, e.g. 3
 606                   -> OccName    -- ^ Class, e.g. @Ord@
 607                   -> OccName    -- ^ Derived 'Occname', e.g. @$p3Ord@
 608 mkSuperDictSelOcc index cls_occ
 609   = mk_deriv varName "$p" (show index ++ occNameString cls_occ)
 610
 611 mkLocalOcc :: Unique            -- ^ Unique to combine with the 'OccName'
 612            -> OccName           -- ^ Local name, e.g. @sat@
 613            -> OccName           -- ^ Nice unique version, e.g. @$L23sat@
 614 mkLocalOcc uniq occ
 615    = mk_deriv varName ("$L" ++ show uniq) (occNameString occ)
 616         -- The Unique might print with characters
 617         -- that need encoding (e.g. 'z'!)
 618 \end{code}
 619
 620 \begin{code}
 621 -- | Derive a name for the representation type constructor of a
 622 -- @data@\/@newtype@ instance.
 623 mkInstTyTcOcc :: String                 -- ^ Family name, e.g. @Map@
 624               -> OccSet                 -- ^ avoid these Occs
 625               -> OccName                -- ^ @R:Map@
 626 mkInstTyTcOcc str set =
 627   chooseUniqueOcc tcName ('R' : ':' : str) set
 628 \end{code}
 629
 630 \begin{code}
 631 mkDFunOcc :: String             -- ^ Typically the class and type glommed together e.g. @OrdMaybe@.
 632                                 -- Only used in debug mode, for extra clarity
 633           -> Bool               -- ^ Is this a hs-boot instance DFun?
 634           -> OccSet             -- ^ avoid these Occs
 635           -> OccName            -- ^ E.g. @$f3OrdMaybe@
 636
 637 -- In hs-boot files we make dict funs like $fx7ClsTy, which get bound to the real
 638 -- thing when we compile the mother module. Reason: we don't know exactly
 639 -- what the  mother module will call it.
 640
 641 mkDFunOcc info_str is_boot set
 642   = chooseUniqueOcc VarName (prefix ++ info_str) set
 643   where
 644     prefix | is_boot   = "$fx"
 645            | otherwise = "$f"
 646 \end{code}
 647
 648 Sometimes we need to pick an OccName that has not already been used,
 649 given a set of in-use OccNames.
 650
 651 \begin{code}
 652 chooseUniqueOcc :: NameSpace -> String -> OccSet -> OccName
 653 chooseUniqueOcc ns str set = loop (mkOccName ns str) (0::Int)
 654   where
 655   loop occ n
 656    | occ `elemOccSet` set = loop (mkOccName ns (str ++ show n)) (n+1)
 657    | otherwise            = occ
 658 \end{code}
 659
 660 We used to add a '$m' to indicate a method, but that gives rise to bad
 661 error messages from the type checker when we print the function name or pattern
 662 of an instance-decl binding.  Why? Because the binding is zapped
 663 to use the method name in place of the selector name.
 664 (See TcClassDcl.tcMethodBind)
 665
 666 The way it is now, -ddump-xx output may look confusing, but
 667 you can always say -dppr-debug to get the uniques.
 668
 669 However, we *do* have to zap the first character to be lower case,
 670 because overloaded constructors (blarg) generate methods too.
 671 And convert to VarName space
 672
 673 e.g. a call to constructor MkFoo where
 674         data (Ord a) => Foo a = MkFoo a
 675
 676 If this is necessary, we do it by prefixing '$m'.  These
 677 guys never show up in error messages.  What a hack.
 678
 679 \begin{code}
 680 mkMethodOcc :: OccName -> OccName
 681 mkMethodOcc occ@(OccName VarName _) = occ
 682 mkMethodOcc occ                     = mk_simple_deriv varName "$m" occ
 683 \end{code}
 684
 685
 686 %************************************************************************
 687 %*                                                                      *
 688 \subsection{Tidying them up}
 689 %*                                                                      *
 690 %************************************************************************
 691
 692 Before we print chunks of code we like to rename it so that
 693 we don't have to print lots of silly uniques in it.  But we mustn't
 694 accidentally introduce name clashes!  So the idea is that we leave the
 695 OccName alone unless it accidentally clashes with one that is already
 696 in scope; if so, we tack on '1' at the end and try again, then '2', and
 697 so on till we find a unique one.
 698
 699 There's a wrinkle for operators.  Consider '>>='.  We can't use '>>=1'
 700 because that isn't a single lexeme.  So we encode it to 'lle' and *then*
 701 tack on the '1', if necessary.
 702
 703 \begin{code}
 704 type TidyOccEnv = OccEnv Int    -- The in-scope OccNames
 705         -- Range gives a plausible starting point for new guesses
 706
 707 emptyTidyOccEnv :: TidyOccEnv
 708 emptyTidyOccEnv = emptyOccEnv
 709
 710 initTidyOccEnv :: [OccName] -> TidyOccEnv       -- Initialise with names to avoid!
 711 initTidyOccEnv = foldl (\env occ -> extendOccEnv env occ 1) emptyTidyOccEnv
 712
 713 tidyOccName :: TidyOccEnv -> OccName -> (TidyOccEnv, OccName)
 714
 715 tidyOccName in_scope occ@(OccName occ_sp fs)
 716   = case lookupOccEnv in_scope occ of
 717         Nothing ->      -- Not already used: make it used
 718                    (extendOccEnv in_scope occ 1, occ)
 719
 720         Just n  ->      -- Already used: make a new guess,
 721                         -- change the guess base, and try again
 722                    tidyOccName  (extendOccEnv in_scope occ (n+1))
 723                                 (mkOccName occ_sp (unpackFS fs ++ show n))
 724 \end{code}
 725
 726 %************************************************************************
 727 %*                                                                      *
 728                 Stuff for dealing with tuples
 729 %*                                                                      *
 730 %************************************************************************
 731
 732 \begin{code}
 733 mkTupleOcc :: NameSpace -> Boxity -> Arity -> OccName
 734 mkTupleOcc ns bx ar = OccName ns (mkFastString str)
 735   where
 736         -- no need to cache these, the caching is done in the caller
 737         -- (TysWiredIn.mk_tuple)
 738     str = case bx of
 739                 Boxed   -> '(' : commas ++ ")"
 740                 Unboxed -> '(' : '#' : commas ++ "#)"
 741
 742     commas = take (ar-1) (repeat ',')
 743
 744 isTupleOcc_maybe :: OccName -> Maybe (NameSpace, Boxity, Arity)
 745 -- Tuples are special, because there are so many of them!
 746 isTupleOcc_maybe (OccName ns fs)
 747   = case unpackFS fs of
 748         '(':'#':',':rest -> Just (ns, Unboxed, 2 + count_commas rest)
 749         '(':',':rest     -> Just (ns, Boxed,   2 + count_commas rest)
 750         _other           -> Nothing
 751   where
 752     count_commas (',':rest) = 1 + count_commas rest
 753     count_commas _          = 0
 754 \end{code}
 755
 756 %************************************************************************
 757 %*                                                                      *
 758 \subsection{Lexical categories}
 759 %*                                                                      *
 760 %************************************************************************
 761
 762 These functions test strings to see if they fit the lexical categories
 763 defined in the Haskell report.
 764
 765 \begin{code}
 766 isLexCon,   isLexVar,    isLexId,    isLexSym    :: FastString -> Bool
 767 isLexConId, isLexConSym, isLexVarId, isLexVarSym :: FastString -> Bool
 768
 769 isLexCon cs = isLexConId  cs || isLexConSym cs
 770 isLexVar cs = isLexVarId  cs || isLexVarSym cs
 771
 772 isLexId  cs = isLexConId  cs || isLexVarId  cs
 773 isLexSym cs = isLexConSym cs || isLexVarSym cs
 774
 775 -------------
 776
 777 isLexConId cs                           -- Prefix type or data constructors
 778   | nullFS cs          = False          --      e.g. "Foo", "[]", "(,)"
 779   | cs == (fsLit "[]") = True
 780   | otherwise          = startsConId (headFS cs)
 781
 782 isLexVarId cs                           -- Ordinary prefix identifiers
 783   | nullFS cs         = False           --      e.g. "x", "_x"
 784   | otherwise         = startsVarId (headFS cs)
 785
 786 isLexConSym cs                          -- Infix type or data constructors
 787   | nullFS cs          = False          --      e.g. ":-:", ":", "->"
 788   | cs == (fsLit "->") = True
 789   | otherwise          = startsConSym (headFS cs)
 790
 791 isLexVarSym cs                          -- Infix identifiers
 792   | nullFS cs         = False           --      e.g. "+"
 793   | otherwise         = startsVarSym (headFS cs)
 794
 795 -------------
 796 startsVarSym, startsVarId, startsConSym, startsConId :: Char -> Bool
 797 startsVarSym c = isSymbolASCII c || (ord c > 0x7f && isSymbol c) -- Infix Ids
 798 startsConSym c = c == ':'                               -- Infix data constructors
 799 startsVarId c  = isLower c || c == '_'  -- Ordinary Ids
 800 startsConId c  = isUpper c || c == '('  -- Ordinary type constructors and data constructors
 801
 802 isSymbolASCII :: Char -> Bool
 803 isSymbolASCII c = c `elem` "!#$%&*+./<=>?@\\^|~-"
 804 \end{code}
 805
 806 %************************************************************************
 807 %*                                                                      *
 808                 Binary instance
 809     Here rather than BinIface because OccName is abstract
 810 %*                                                                      *
 811 %************************************************************************
 812
 813 \begin{code}
 814 instance Binary NameSpace where
 815     put_ bh VarName = do
 816             putByte bh 0
 817     put_ bh DataName = do
 818             putByte bh 1
 819     put_ bh TvName = do
 820             putByte bh 2
 821     put_ bh TcClsName = do
 822             putByte bh 3
 823     get bh = do
 824             h <- getByte bh
 825             case h of
 826               0 -> do return VarName
 827               1 -> do return DataName
 828               2 -> do return TvName
 829               _ -> do return TcClsName
 830
 831 instance Binary OccName where
 832     put_ bh (OccName aa ab) = do
 833             put_ bh aa
 834             put_ bh ab
 835     get bh = do
 836           aa <- get bh
 837           ab <- get bh
 838           return (OccName aa ab)
 839 \end{code}