compiler/basicTypes/OccName.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 -- |
   8 -- #name_types#
   9 -- GHC uses several kinds of name internally:
  10 --
  11 -- * 'OccName.OccName' represents names as strings with just a little more information:
  12 --   the \"namespace\" that the name came from, e.g. the namespace of value, type constructors or
  13 --   data constructors
  14 --
  15 -- * 'RdrName.RdrName': see "RdrName#name_types"
  16 --
  17 -- * 'Name.Name': see "Name#name_types"
  18 --
  19 -- * 'Id.Id': see "Id#name_types"
  20 --
  21 -- * 'Var.Var': see "Var#name_types"
  22 module OccName (
  23         -- * The 'NameSpace' type
  24         NameSpace, -- Abstract
  25
  26         -- ** Construction
  27         -- $real_vs_source_data_constructors
  28         tcName, clsName, tcClsName, dataName, varName, varNameDepth,
  29         tvName, srcDataName, setOccNameDepth, getOccNameDepth,
  30
  31         -- ** Pretty Printing
  32         pprNameSpace, pprNonVarNameSpace, pprNameSpaceBrief,
  33
  34         -- * The 'OccName' type
  35         OccName,        -- Abstract, instance of Outputable
  36         pprOccName,
  37
  38         -- ** Construction
  39         mkOccName, mkOccNameFS,
  40         mkVarOcc, mkVarOccFS,
  41         mkDataOcc, mkDataOccFS,
  42         mkTyVarOcc, mkTyVarOccFS,
  43         mkTcOcc, mkTcOccFS,
  44         mkClsOcc, mkClsOccFS,
  45         mkDFunOcc,
  46         mkTupleOcc,
  47         setOccNameSpace,
  48
  49         -- ** Derived 'OccName's
  50         isDerivedOccName,
  51         mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc,
  52         mkDerivedTyConOcc, mkNewTyCoOcc, mkClassOpAuxOcc,
  53         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
  54         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
  55         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
  56         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc,
  57         mkSuperDictSelOcc, mkLocalOcc, mkMethodOcc, mkInstTyTcOcc,
  58         mkInstTyCoOcc, mkEqPredCoOcc,
  59         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
  60         mkPDataTyConOcc, mkPDataDataConOcc,
  61         mkPReprTyConOcc,
  62         mkPADFunOcc,
  63
  64         -- ** Deconstruction
  65         occNameFS, occNameString, occNameSpace,
  66
  67         isVarOcc, isTvOcc, isTcOcc, isDataOcc, isDataSymOcc, isSymOcc, isValOcc,
  68         parenSymOcc, startsWithUnderscore,
  69
  70         isTcClsNameSpace, isTvNameSpace, isDataConNameSpace, isVarNameSpace, isValNameSpace,
  71
  72         isTupleOcc_maybe,
  73
  74         -- * The 'OccEnv' type
  75         OccEnv, emptyOccEnv, unitOccEnv, extendOccEnv, mapOccEnv,
  76         lookupOccEnv, mkOccEnv, mkOccEnv_C, extendOccEnvList, elemOccEnv,
  77         occEnvElts, foldOccEnv, plusOccEnv, plusOccEnv_C, extendOccEnv_C,
  78         extendOccEnv_Acc, filterOccEnv, delListFromOccEnv, delFromOccEnv,
  79
  80         -- * The 'OccSet' type
  81         OccSet, emptyOccSet, unitOccSet, mkOccSet, extendOccSet,
  82         extendOccSetList,
  83         unionOccSets, unionManyOccSets, minusOccSet, elemOccSet, occSetElts,
  84         foldOccSet, isEmptyOccSet, intersectOccSet, intersectsOccSet,
  85
  86         -- * Tidying up
  87         TidyOccEnv, emptyTidyOccEnv, tidyOccName, initTidyOccEnv,
  88
  89         -- * Lexical characteristics of Haskell names
  90         isLexCon, isLexVar, isLexId, isLexSym,
  91         isLexConId, isLexConSym, isLexVarId, isLexVarSym,
  92         startsVarSym, startsVarId, startsConSym, startsConId
  93     ) where
  94
  95 #include "Typeable.h"
  96
  97 import Util
  98 import Unique
  99 import BasicTypes
 100 import UniqFM
 101 import UniqSet
 102 import FastString
 103 import Outputable
 104 import Binary
 105 import StaticFlags( opt_SuppressUniques )
 106 import Data.Char
 107 import Data.Data
 108 \end{code}
 109
 110 %************************************************************************
 111 %*                                                                      *
 112 \subsection{Name space}
 113 %*                                                                      *
 114 %************************************************************************
 115
 116 \begin{code}
 117 data NameSpace = VarName   Int  -- Variables, including "real" data constructors; Int is the syntactic HetMet bracket depth
 118                | DataName       -- "Source" data constructors
 119                | TvName         -- Type variables
 120                | TcClsName      -- Type constructors and classes; Haskell has them
 121                                 -- in the same name space for now.
 122                deriving( Eq, Ord )
 123    {-! derive: Binary !-}
 124
 125 -- Note [Data Constructors]
 126 -- see also: Note [Data Constructor Naming] in DataCon.lhs
 127 --
 128 -- $real_vs_source_data_constructors
 129 -- There are two forms of data constructor:
 130 --
 131 --      [Source data constructors] The data constructors mentioned in Haskell source code
 132 --
 133 --      [Real data constructors] The data constructors of the representation type, which may not be the same as the source type
 134 --
 135 -- For example:
 136 --
 137 -- > data T = T !(Int, Int)
 138 --
 139 -- The source datacon has type @(Int, Int) -> T@
 140 -- The real   datacon has type @Int -> Int -> T@
 141 --
 142 -- GHC chooses a representation based on the strictness etc.
 143
 144 tcName, clsName, tcClsName :: NameSpace
 145 dataName, srcDataName      :: NameSpace
 146 tvName, varName            :: NameSpace
 147 varNameDepth               :: Int -> NameSpace
 148
 149 -- Though type constructors and classes are in the same name space now,
 150 -- the NameSpace type is abstract, so we can easily separate them later
 151 tcName    = TcClsName           -- Type constructors
 152 clsName   = TcClsName           -- Classes
 153 tcClsName = TcClsName           -- Not sure which!
 154
 155 dataName    = DataName
 156 srcDataName = DataName  -- Haskell-source data constructors should be
 157                         -- in the Data name space
 158
 159 tvName       = TvName
 160
 161 varName      = VarName 0
 162 varNameDepth = VarName
 163
 164 getOccNameDepth :: OccName -> Int
 165 getOccNameDepth name =
 166     case occNameSpace name of
 167       (VarName d) -> d
 168       _           -> 0
 169 setOccNameDepth :: Int -> OccName -> OccName
 170 setOccNameDepth depth name =
 171     case occNameSpace name of
 172       (VarName _) -> name{ occNameSpace = VarName depth }
 173       ns           -> if depth==0
 174                      then name
 175                      else error ("tried to change the depth of a name in namespace " ++ (showSDoc $ ppr name))
 176
 177 isDataConNameSpace :: NameSpace -> Bool
 178 isDataConNameSpace DataName = True
 179 isDataConNameSpace _        = False
 180
 181 isTcClsNameSpace :: NameSpace -> Bool
 182 isTcClsNameSpace TcClsName = True
 183 isTcClsNameSpace _         = False
 184
 185 isTvNameSpace :: NameSpace -> Bool
 186 isTvNameSpace TvName = True
 187 isTvNameSpace _      = False
 188
 189 isVarNameSpace :: NameSpace -> Bool     -- Variables or type variables, but not constructors
 190 isVarNameSpace TvName  = True
 191 isVarNameSpace (VarName _) = True
 192 isVarNameSpace _       = False
 193
 194 isValNameSpace :: NameSpace -> Bool
 195 isValNameSpace DataName = True
 196 isValNameSpace (VarName _)  = True
 197 isValNameSpace _        = False
 198
 199 pprNameSpace :: NameSpace -> SDoc
 200 pprNameSpace DataName  = ptext (sLit "data constructor")
 201 pprNameSpace (VarName _)  = ptext (sLit "variable")
 202 pprNameSpace TvName    = ptext (sLit "type variable")
 203 pprNameSpace TcClsName = ptext (sLit "type constructor or class")
 204
 205 pprNonVarNameSpace :: NameSpace -> SDoc
 206 pprNonVarNameSpace (VarName _) = empty
 207 pprNonVarNameSpace ns = pprNameSpace ns
 208
 209 pprNameSpaceBrief :: NameSpace -> SDoc
 210 pprNameSpaceBrief DataName  = char 'd'
 211 pprNameSpaceBrief (VarName _)  = char 'v'
 212 pprNameSpaceBrief TvName    = ptext (sLit "tv")
 213 pprNameSpaceBrief TcClsName = ptext (sLit "tc")
 214 \end{code}
 215
 216
 217 %************************************************************************
 218 %*                                                                      *
 219 \subsection[Name-pieces-datatypes]{The @OccName@ datatypes}
 220 %*                                                                      *
 221 %************************************************************************
 222
 223 \begin{code}
 224 data OccName = OccName
 225     { occNameSpace  :: !NameSpace
 226     , occNameFS     :: !FastString
 227     }
 228     deriving Typeable
 229 \end{code}
 230
 231
 232 \begin{code}
 233 instance Eq OccName where
 234     (OccName sp1 s1) == (OccName sp2 s2) = s1 == s2 && sp1 == sp2
 235
 236 instance Ord OccName where
 237         -- Compares lexicographically, *not* by Unique of the string
 238     compare (OccName sp1 s1) (OccName sp2 s2)
 239         = (s1  `compare` s2) `thenCmp` (sp1 `compare` sp2)
 240
 241 instance Data OccName where
 242   -- don't traverse?
 243   toConstr _   = abstractConstr "OccName"
 244   gunfold _ _  = error "gunfold"
 245   dataTypeOf _ = mkNoRepType "OccName"
 246 \end{code}
 247
 248
 249 %************************************************************************
 250 %*                                                                      *
 251 \subsection{Printing}
 252 %*                                                                      *
 253 %************************************************************************
 254
 255 \begin{code}
 256 instance Outputable OccName where
 257     ppr = pprOccName
 258
 259 pprOccName :: OccName -> SDoc
 260 pprOccName (OccName sp occ)
 261   = getPprStyle $ \ sty ->
 262     if codeStyle sty
 263     then ftext (zEncodeFS occ)
 264     else pp_occ <> pp_debug sty
 265   where
 266     pp_debug sty | debugStyle sty = braces (pprNameSpaceBrief sp)
 267                  | otherwise      = empty
 268
 269     pp_occ | opt_SuppressUniques = text (strip_th_unique (unpackFS occ))
 270            | otherwise           = ftext occ
 271
 272         -- See Note [Suppressing uniques in OccNames]
 273     strip_th_unique ('[' : c : _) | isAlphaNum c = []
 274     strip_th_unique (c : cs) = c : strip_th_unique cs
 275     strip_th_unique []       = []
 276 \end{code}
 277
 278 Note [Suppressing uniques in OccNames]
 279 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 280 This is a hack to de-wobblify the OccNames that contain uniques from
 281 Template Haskell that have been turned into a string in the OccName.
 282 See Note [Unique OccNames from Template Haskell] in Convert.hs
 283
 284 %************************************************************************
 285 %*                                                                      *
 286 \subsection{Construction}
 287 %*                                                                      *
 288 %************************************************************************
 289
 290 \begin{code}
 291 mkOccName :: NameSpace -> String -> OccName
 292 mkOccName occ_sp str = OccName occ_sp (mkFastString str)
 293
 294 mkOccNameFS :: NameSpace -> FastString -> OccName
 295 mkOccNameFS occ_sp fs = OccName occ_sp fs
 296
 297 mkVarOcc :: String -> OccName
 298 mkVarOcc s = mkOccName varName s
 299
 300 mkVarOccFS :: FastString -> OccName
 301 mkVarOccFS fs = mkOccNameFS varName fs
 302
 303 mkDataOcc :: String -> OccName
 304 mkDataOcc = mkOccName dataName
 305
 306 mkDataOccFS :: FastString -> OccName
 307 mkDataOccFS = mkOccNameFS dataName
 308
 309 mkTyVarOcc :: String -> OccName
 310 mkTyVarOcc = mkOccName tvName
 311
 312 mkTyVarOccFS :: FastString -> OccName
 313 mkTyVarOccFS fs = mkOccNameFS tvName fs
 314
 315 mkTcOcc :: String -> OccName
 316 mkTcOcc = mkOccName tcName
 317
 318 mkTcOccFS :: FastString -> OccName
 319 mkTcOccFS = mkOccNameFS tcName
 320
 321 mkClsOcc :: String -> OccName
 322 mkClsOcc = mkOccName clsName
 323
 324 mkClsOccFS :: FastString -> OccName
 325 mkClsOccFS = mkOccNameFS clsName
 326 \end{code}
 327
 328
 329 %************************************************************************
 330 %*                                                                      *
 331                 Environments
 332 %*                                                                      *
 333 %************************************************************************
 334
 335 OccEnvs are used mainly for the envts in ModIfaces.
 336
 337 Note [The Unique of an OccName]
 338 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 339 They are efficient, because FastStrings have unique Int# keys.  We assume
 340 this key is less than 2^24, and indeed FastStrings are allocated keys
 341 sequentially starting at 0.
 342
 343 So we can make a Unique using
 344         mkUnique ns key  :: Unique
 345 where 'ns' is a Char reprsenting the name space.  This in turn makes it
 346 easy to build an OccEnv.
 347
 348 \begin{code}
 349 instance Uniquable OccName where
 350       -- See Note [The Unique of an OccName]
 351   getUnique (OccName (VarName depth) fs) = mkVarOccUnique fs depth
 352   getUnique (OccName DataName  fs) = mkDataOccUnique fs
 353   getUnique (OccName TvName    fs) = mkTvOccUnique   fs
 354   getUnique (OccName TcClsName fs) = mkTcOccUnique   fs
 355
 356 newtype OccEnv a = A (UniqFM a)
 357
 358 emptyOccEnv :: OccEnv a
 359 unitOccEnv  :: OccName -> a -> OccEnv a
 360 extendOccEnv :: OccEnv a -> OccName -> a -> OccEnv a
 361 extendOccEnvList :: OccEnv a -> [(OccName, a)] -> OccEnv a
 362 lookupOccEnv :: OccEnv a -> OccName -> Maybe a
 363 mkOccEnv     :: [(OccName,a)] -> OccEnv a
 364 mkOccEnv_C   :: (a -> a -> a) -> [(OccName,a)] -> OccEnv a
 365 elemOccEnv   :: OccName -> OccEnv a -> Bool
 366 foldOccEnv   :: (a -> b -> b) -> b -> OccEnv a -> b
 367 occEnvElts   :: OccEnv a -> [a]
 368 extendOccEnv_C :: (a->a->a) -> OccEnv a -> OccName -> a -> OccEnv a
 369 extendOccEnv_Acc :: (a->b->b) -> (a->b) -> OccEnv b -> OccName -> a -> OccEnv b
 370 plusOccEnv     :: OccEnv a -> OccEnv a -> OccEnv a
 371 plusOccEnv_C   :: (a->a->a) -> OccEnv a -> OccEnv a -> OccEnv a
 372 mapOccEnv      :: (a->b) -> OccEnv a -> OccEnv b
 373 delFromOccEnv      :: OccEnv a -> OccName -> OccEnv a
 374 delListFromOccEnv :: OccEnv a -> [OccName] -> OccEnv a
 375 filterOccEnv       :: (elt -> Bool) -> OccEnv elt -> OccEnv elt
 376
 377 emptyOccEnv      = A emptyUFM
 378 unitOccEnv x y = A $ unitUFM x y
 379 extendOccEnv (A x) y z = A $ addToUFM x y z
 380 extendOccEnvList (A x) l = A $ addListToUFM x l
 381 lookupOccEnv (A x) y = lookupUFM x y
 382 mkOccEnv     l    = A $ listToUFM l
 383 elemOccEnv x (A y)       = elemUFM x y
 384 foldOccEnv a b (A c)     = foldUFM a b c
 385 occEnvElts (A x)         = eltsUFM x
 386 plusOccEnv (A x) (A y)   = A $ plusUFM x y
 387 plusOccEnv_C f (A x) (A y)       = A $ plusUFM_C f x y
 388 extendOccEnv_C f (A x) y z   = A $ addToUFM_C f x y z
 389 extendOccEnv_Acc f g (A x) y z   = A $ addToUFM_Acc f g x y z
 390 mapOccEnv f (A x)        = A $ mapUFM f x
 391 mkOccEnv_C comb l = A $ addListToUFM_C comb emptyUFM l
 392 delFromOccEnv (A x) y    = A $ delFromUFM x y
 393 delListFromOccEnv (A x) y  = A $ delListFromUFM x y
 394 filterOccEnv x (A y)       = A $ filterUFM x y
 395
 396 instance Outputable a => Outputable (OccEnv a) where
 397     ppr (A x) = ppr x
 398
 399 type OccSet = UniqSet OccName
 400
 401 emptyOccSet       :: OccSet
 402 unitOccSet        :: OccName -> OccSet
 403 mkOccSet          :: [OccName] -> OccSet
 404 extendOccSet      :: OccSet -> OccName -> OccSet
 405 extendOccSetList  :: OccSet -> [OccName] -> OccSet
 406 unionOccSets      :: OccSet -> OccSet -> OccSet
 407 unionManyOccSets  :: [OccSet] -> OccSet
 408 minusOccSet       :: OccSet -> OccSet -> OccSet
 409 elemOccSet        :: OccName -> OccSet -> Bool
 410 occSetElts        :: OccSet -> [OccName]
 411 foldOccSet        :: (OccName -> b -> b) -> b -> OccSet -> b
 412 isEmptyOccSet     :: OccSet -> Bool
 413 intersectOccSet   :: OccSet -> OccSet -> OccSet
 414 intersectsOccSet  :: OccSet -> OccSet -> Bool
 415
 416 emptyOccSet       = emptyUniqSet
 417 unitOccSet        = unitUniqSet
 418 mkOccSet          = mkUniqSet
 419 extendOccSet      = addOneToUniqSet
 420 extendOccSetList  = addListToUniqSet
 421 unionOccSets      = unionUniqSets
 422 unionManyOccSets  = unionManyUniqSets
 423 minusOccSet       = minusUniqSet
 424 elemOccSet        = elementOfUniqSet
 425 occSetElts        = uniqSetToList
 426 foldOccSet        = foldUniqSet
 427 isEmptyOccSet     = isEmptyUniqSet
 428 intersectOccSet   = intersectUniqSets
 429 intersectsOccSet s1 s2 = not (isEmptyOccSet (s1 `intersectOccSet` s2))
 430 \end{code}
 431
 432
 433 %************************************************************************
 434 %*                                                                      *
 435 \subsection{Predicates and taking them apart}
 436 %*                                                                      *
 437 %************************************************************************
 438
 439 \begin{code}
 440 occNameString :: OccName -> String
 441 occNameString (OccName _ s) = unpackFS s
 442
 443 setOccNameSpace :: NameSpace -> OccName -> OccName
 444 setOccNameSpace sp (OccName _ occ) = OccName sp occ
 445
 446 isVarOcc, isTvOcc, isTcOcc, isDataOcc :: OccName -> Bool
 447
 448 isVarOcc (OccName (VarName _) _) = True
 449 isVarOcc _                   = False
 450
 451 isTvOcc (OccName TvName _) = True
 452 isTvOcc _                  = False
 453
 454 isTcOcc (OccName TcClsName _) = True
 455 isTcOcc _                     = False
 456
 457 -- | /Value/ 'OccNames's are those that are either in
 458 -- the variable or data constructor namespaces
 459 isValOcc :: OccName -> Bool
 460 isValOcc (OccName (VarName _) _) = True
 461 isValOcc (OccName DataName _) = True
 462 isValOcc _                    = False
 463
 464 isDataOcc (OccName DataName _) = True
 465 isDataOcc (OccName (VarName _) s)
 466   | isLexCon s = pprPanic "isDataOcc: check me" (ppr s)
 467                 -- Jan06: I don't think this should happen
 468 isDataOcc _                    = False
 469
 470 -- | Test if the 'OccName' is a data constructor that starts with
 471 -- a symbol (e.g. @:@, or @[]@)
 472 isDataSymOcc :: OccName -> Bool
 473 isDataSymOcc (OccName DataName s) = isLexConSym s
 474 isDataSymOcc (OccName (VarName _) s)
 475   | isLexConSym s = pprPanic "isDataSymOcc: check me" (ppr s)
 476                 -- Jan06: I don't think this should happen
 477 isDataSymOcc _                    = False
 478 -- Pretty inefficient!
 479
 480 -- | Test if the 'OccName' is that for any operator (whether
 481 -- it is a data constructor or variable or whatever)
 482 isSymOcc :: OccName -> Bool
 483 isSymOcc (OccName DataName s)  = isLexConSym s
 484 isSymOcc (OccName TcClsName s) = isLexConSym s
 485 isSymOcc (OccName (VarName _) s)   = isLexSym s
 486 isSymOcc (OccName TvName s)    = isLexSym s
 487 -- Pretty inefficient!
 488
 489 parenSymOcc :: OccName -> SDoc -> SDoc
 490 -- ^ Wrap parens around an operator
 491 parenSymOcc occ doc | isSymOcc occ = parens doc
 492                     | otherwise    = doc
 493 \end{code}
 494
 495
 496 \begin{code}
 497 startsWithUnderscore :: OccName -> Bool
 498 -- ^ Haskell 98 encourages compilers to suppress warnings about unsed
 499 -- names in a pattern if they start with @_@: this implements that test
 500 startsWithUnderscore occ = case occNameString occ of
 501                              ('_' : _) -> True
 502                              _other    -> False
 503 \end{code}
 504
 505
 506 %************************************************************************
 507 %*                                                                      *
 508 \subsection{Making system names}
 509 %*                                                                      *
 510 %************************************************************************
 511
 512 Here's our convention for splitting up the interface file name space:
 513
 514    d...         dictionary identifiers
 515                 (local variables, so no name-clash worries)
 516
 517 All of these other OccNames contain a mixture of alphabetic
 518 and symbolic characters, and hence cannot possibly clash with
 519 a user-written type or function name
 520
 521    $f...        Dict-fun identifiers (from inst decls)
 522    $dmop        Default method for 'op'
 523    $pnC         n'th superclass selector for class C
 524    $wf          Worker for functtoin 'f'
 525    $sf..        Specialised version of f
 526    T:C          Tycon for dictionary for class C
 527    D:C          Data constructor for dictionary for class C
 528    NTCo:T       Coercion connecting newtype T with its representation type
 529    TFCo:R       Coercion connecting a data family to its respresentation type R
 530
 531 In encoded form these appear as Zdfxxx etc
 532
 533         :...            keywords (export:, letrec: etc.)
 534 --- I THINK THIS IS WRONG!
 535
 536 This knowledge is encoded in the following functions.
 537
 538 @mk_deriv@ generates an @OccName@ from the prefix and a string.
 539 NB: The string must already be encoded!
 540
 541 \begin{code}
 542 mk_deriv :: NameSpace
 543          -> String              -- Distinguishes one sort of derived name from another
 544          -> String
 545          -> OccName
 546
 547 mk_deriv occ_sp sys_prefix str = mkOccName occ_sp (sys_prefix ++ str)
 548
 549 isDerivedOccName :: OccName -> Bool
 550 isDerivedOccName occ =
 551    case occNameString occ of
 552      '$':c:_ | isAlphaNum c -> True
 553      ':':c:_ | isAlphaNum c -> True
 554      _other                 -> False
 555 \end{code}
 556
 557 \begin{code}
 558 mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc, mkDerivedTyConOcc,
 559         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
 560         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
 561         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc, mkNewTyCoOcc,
 562         mkInstTyCoOcc, mkEqPredCoOcc, mkClassOpAuxOcc,
 563         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
 564         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
 565         mkPDataTyConOcc, mkPDataDataConOcc, mkPReprTyConOcc, mkPADFunOcc
 566    :: OccName -> OccName
 567
 568 -- These derived variables have a prefix that no Haskell value could have
 569 mkDataConWrapperOcc = mk_simple_deriv varName  "$W"
 570 mkWorkerOcc         = mk_simple_deriv varName  "$w"
 571 mkDefaultMethodOcc  = mk_simple_deriv varName  "$dm"
 572 mkClassOpAuxOcc     = mk_simple_deriv varName  "$c"
 573 mkDerivedTyConOcc   = mk_simple_deriv tcName   ":"      -- The : prefix makes sure it classifies
 574 mkClassTyConOcc     = mk_simple_deriv tcName   "T:"     -- as a tycon/datacon
 575 mkClassDataConOcc   = mk_simple_deriv dataName "D:"     -- We go straight to the "real" data con
 576                                                         -- for datacons from classes
 577 mkDictOcc           = mk_simple_deriv varName  "$d"
 578 mkIPOcc             = mk_simple_deriv varName  "$i"
 579 mkSpecOcc           = mk_simple_deriv varName  "$s"
 580 mkForeignExportOcc  = mk_simple_deriv varName  "$f"
 581 mkNewTyCoOcc        = mk_simple_deriv tcName   "NTCo:"  -- Coercion for newtypes
 582 mkInstTyCoOcc       = mk_simple_deriv tcName   "TFCo:"   -- Coercion for type functions
 583 mkEqPredCoOcc       = mk_simple_deriv tcName   "$co"
 584
 585 -- used in derived instances
 586 mkCon2TagOcc        = mk_simple_deriv varName  "$con2tag_"
 587 mkTag2ConOcc        = mk_simple_deriv varName  "$tag2con_"
 588 mkMaxTagOcc         = mk_simple_deriv varName  "$maxtag_"
 589
 590 -- Generic derivable classes
 591 mkGenOcc1           = mk_simple_deriv varName  "$gfrom"
 592 mkGenOcc2           = mk_simple_deriv varName  "$gto"
 593
 594 -- data T = MkT ... deriving( Data ) needs defintions for
 595 --      $tT   :: Data.Generics.Basics.DataType
 596 --      $cMkT :: Data.Generics.Basics.Constr
 597 mkDataTOcc = mk_simple_deriv varName  "$t"
 598 mkDataCOcc = mk_simple_deriv varName  "$c"
 599
 600 -- Vectorisation
 601 mkVectOcc          = mk_simple_deriv varName  "$v_"
 602 mkVectTyConOcc     = mk_simple_deriv tcName   ":V_"
 603 mkVectDataConOcc   = mk_simple_deriv dataName ":VD_"
 604 mkVectIsoOcc       = mk_simple_deriv varName  "$VI_"
 605 mkPDataTyConOcc    = mk_simple_deriv tcName   ":VP_"
 606 mkPDataDataConOcc  = mk_simple_deriv dataName ":VPD_"
 607 mkPReprTyConOcc    = mk_simple_deriv tcName   ":VR_"
 608 mkPADFunOcc        = mk_simple_deriv varName  "$PA_"
 609
 610 mk_simple_deriv :: NameSpace -> String -> OccName -> OccName
 611 mk_simple_deriv sp px occ = mk_deriv sp px (occNameString occ)
 612
 613 -- Data constructor workers are made by setting the name space
 614 -- of the data constructor OccName (which should be a DataName)
 615 -- to VarName
 616 mkDataConWorkerOcc datacon_occ = setOccNameSpace varName datacon_occ
 617 \end{code}
 618
 619 \begin{code}
 620 mkSuperDictSelOcc :: Int        -- ^ Index of superclass, e.g. 3
 621                   -> OccName    -- ^ Class, e.g. @Ord@
 622                   -> OccName    -- ^ Derived 'Occname', e.g. @$p3Ord@
 623 mkSuperDictSelOcc index cls_occ
 624   = mk_deriv varName "$p" (show index ++ occNameString cls_occ)
 625
 626 mkLocalOcc :: Unique            -- ^ Unique to combine with the 'OccName'
 627            -> OccName           -- ^ Local name, e.g. @sat@
 628            -> OccName           -- ^ Nice unique version, e.g. @$L23sat@
 629 mkLocalOcc uniq occ
 630    = mk_deriv varName ("$L" ++ show uniq) (occNameString occ)
 631         -- The Unique might print with characters
 632         -- that need encoding (e.g. 'z'!)
 633 \end{code}
 634
 635 \begin{code}
 636 -- | Derive a name for the representation type constructor of a
 637 -- @data@\/@newtype@ instance.
 638 mkInstTyTcOcc :: String                 -- ^ Family name, e.g. @Map@
 639               -> OccSet                 -- ^ avoid these Occs
 640               -> OccName                -- ^ @R:Map@
 641 mkInstTyTcOcc str set =
 642   chooseUniqueOcc tcName ('R' : ':' : str) set
 643 \end{code}
 644
 645 \begin{code}
 646 mkDFunOcc :: String             -- ^ Typically the class and type glommed together e.g. @OrdMaybe@.
 647                                 -- Only used in debug mode, for extra clarity
 648           -> Bool               -- ^ Is this a hs-boot instance DFun?
 649           -> OccSet             -- ^ avoid these Occs
 650           -> OccName            -- ^ E.g. @$f3OrdMaybe@
 651
 652 -- In hs-boot files we make dict funs like $fx7ClsTy, which get bound to the real
 653 -- thing when we compile the mother module. Reason: we don't know exactly
 654 -- what the  mother module will call it.
 655
 656 mkDFunOcc info_str is_boot set
 657   = chooseUniqueOcc (VarName 0) (prefix ++ info_str) set
 658   where
 659     prefix | is_boot   = "$fx"
 660            | otherwise = "$f"
 661 \end{code}
 662
 663 Sometimes we need to pick an OccName that has not already been used,
 664 given a set of in-use OccNames.
 665
 666 \begin{code}
 667 chooseUniqueOcc :: NameSpace -> String -> OccSet -> OccName
 668 chooseUniqueOcc ns str set = loop (mkOccName ns str) (0::Int)
 669   where
 670   loop occ n
 671    | occ `elemOccSet` set = loop (mkOccName ns (str ++ show n)) (n+1)
 672    | otherwise            = occ
 673 \end{code}
 674
 675 We used to add a '$m' to indicate a method, but that gives rise to bad
 676 error messages from the type checker when we print the function name or pattern
 677 of an instance-decl binding.  Why? Because the binding is zapped
 678 to use the method name in place of the selector name.
 679 (See TcClassDcl.tcMethodBind)
 680
 681 The way it is now, -ddump-xx output may look confusing, but
 682 you can always say -dppr-debug to get the uniques.
 683
 684 However, we *do* have to zap the first character to be lower case,
 685 because overloaded constructors (blarg) generate methods too.
 686 And convert to VarName space
 687
 688 e.g. a call to constructor MkFoo where
 689         data (Ord a) => Foo a = MkFoo a
 690
 691 If this is necessary, we do it by prefixing '$m'.  These
 692 guys never show up in error messages.  What a hack.
 693
 694 \begin{code}
 695 mkMethodOcc :: OccName -> OccName
 696 mkMethodOcc occ@(OccName (VarName _) _) = occ
 697 mkMethodOcc occ                     = mk_simple_deriv varName "$m" occ
 698 \end{code}
 699
 700
 701 %************************************************************************
 702 %*                                                                      *
 703 \subsection{Tidying them up}
 704 %*                                                                      *
 705 %************************************************************************
 706
 707 Before we print chunks of code we like to rename it so that
 708 we don't have to print lots of silly uniques in it.  But we mustn't
 709 accidentally introduce name clashes!  So the idea is that we leave the
 710 OccName alone unless it accidentally clashes with one that is already
 711 in scope; if so, we tack on '1' at the end and try again, then '2', and
 712 so on till we find a unique one.
 713
 714 There's a wrinkle for operators.  Consider '>>='.  We can't use '>>=1'
 715 because that isn't a single lexeme.  So we encode it to 'lle' and *then*
 716 tack on the '1', if necessary.
 717
 718 \begin{code}
 719 type TidyOccEnv = OccEnv Int    -- The in-scope OccNames
 720         -- Range gives a plausible starting point for new guesses
 721
 722 emptyTidyOccEnv :: TidyOccEnv
 723 emptyTidyOccEnv = emptyOccEnv
 724
 725 initTidyOccEnv :: [OccName] -> TidyOccEnv       -- Initialise with names to avoid!
 726 initTidyOccEnv = foldl (\env occ -> extendOccEnv env occ 1) emptyTidyOccEnv
 727
 728 tidyOccName :: TidyOccEnv -> OccName -> (TidyOccEnv, OccName)
 729
 730 tidyOccName in_scope occ@(OccName occ_sp fs)
 731   = case lookupOccEnv in_scope occ of
 732         Nothing ->      -- Not already used: make it used
 733                    (extendOccEnv in_scope occ 1, occ)
 734
 735         Just n  ->      -- Already used: make a new guess,
 736                         -- change the guess base, and try again
 737                    tidyOccName  (extendOccEnv in_scope occ (n+1))
 738                                 (mkOccName occ_sp (base_occ ++ show n))
 739   where
 740     base_occ = reverse (dropWhile isDigit (reverse (unpackFS fs)))
 741 \end{code}
 742
 743 %************************************************************************
 744 %*                                                                      *
 745                 Stuff for dealing with tuples
 746 %*                                                                      *
 747 %************************************************************************
 748
 749 \begin{code}
 750 mkTupleOcc :: NameSpace -> Boxity -> Arity -> OccName
 751 mkTupleOcc ns bx ar = OccName ns (mkFastString str)
 752   where
 753         -- no need to cache these, the caching is done in the caller
 754         -- (TysWiredIn.mk_tuple)
 755     str = case bx of
 756                 Boxed   -> '(' : commas ++ ")"
 757                 Unboxed -> '(' : '#' : commas ++ "#)"
 758
 759     commas = take (ar-1) (repeat ',')
 760
 761 isTupleOcc_maybe :: OccName -> Maybe (NameSpace, Boxity, Arity)
 762 -- Tuples are special, because there are so many of them!
 763 isTupleOcc_maybe (OccName ns fs)
 764   = case unpackFS fs of
 765         '(':'#':',':rest -> Just (ns, Unboxed, 2 + count_commas rest)
 766         '(':',':rest     -> Just (ns, Boxed,   2 + count_commas rest)
 767         _other           -> Nothing
 768   where
 769     count_commas (',':rest) = 1 + count_commas rest
 770     count_commas _          = 0
 771 \end{code}
 772
 773 %************************************************************************
 774 %*                                                                      *
 775 \subsection{Lexical categories}
 776 %*                                                                      *
 777 %************************************************************************
 778
 779 These functions test strings to see if they fit the lexical categories
 780 defined in the Haskell report.
 781
 782 \begin{code}
 783 isLexCon,   isLexVar,    isLexId,    isLexSym    :: FastString -> Bool
 784 isLexConId, isLexConSym, isLexVarId, isLexVarSym :: FastString -> Bool
 785
 786 isLexCon cs = isLexConId  cs || isLexConSym cs
 787 isLexVar cs = isLexVarId  cs || isLexVarSym cs
 788
 789 isLexId  cs = isLexConId  cs || isLexVarId  cs
 790 isLexSym cs = isLexConSym cs || isLexVarSym cs
 791
 792 -------------
 793
 794 isLexConId cs                           -- Prefix type or data constructors
 795   | nullFS cs          = False          --      e.g. "Foo", "[]", "(,)"
 796   | cs == (fsLit "[]") = True
 797   | otherwise          = startsConId (headFS cs)
 798
 799 isLexVarId cs                           -- Ordinary prefix identifiers
 800   | nullFS cs         = False           --      e.g. "x", "_x"
 801   | otherwise         = startsVarId (headFS cs)
 802
 803 isLexConSym cs                          -- Infix type or data constructors
 804   | nullFS cs          = False          --      e.g. ":-:", ":", "->"
 805   | cs == (fsLit "->") = True
 806   | otherwise          = startsConSym (headFS cs)
 807
 808 isLexVarSym cs                          -- Infix identifiers
 809   | nullFS cs         = False           --      e.g. "+"
 810   | otherwise         = startsVarSym (headFS cs)
 811
 812 -------------
 813 startsVarSym, startsVarId, startsConSym, startsConId :: Char -> Bool
 814 startsVarSym c = isSymbolASCII c || (ord c > 0x7f && isSymbol c) -- Infix Ids
 815 startsConSym c = c == ':'                               -- Infix data constructors
 816 startsVarId c  = isLower c || c == '_'  -- Ordinary Ids
 817 startsConId c  = isUpper c || c == '('  -- Ordinary type constructors and data constructors
 818
 819 isSymbolASCII :: Char -> Bool
 820 isSymbolASCII c = c `elem` "!#$%&*+./<=>?@\\^|~-"
 821 \end{code}
 822
 823 %************************************************************************
 824 %*                                                                      *
 825                 Binary instance
 826     Here rather than BinIface because OccName is abstract
 827 %*                                                                      *
 828 %************************************************************************
 829
 830 \begin{code}
 831 instance Binary NameSpace where
 832     put_ bh (VarName depth) = do if depth > 255-4
 833                                    then error "FIXME: no support for serializing VarNames at this syntactic depth"
 834                                    else putByte bh ((fromIntegral ((depth+3) :: Int)))
 835     put_ bh DataName = do
 836             putByte bh 0
 837     put_ bh TvName = do
 838             putByte bh 1
 839     put_ bh TcClsName = do
 840             putByte bh 2
 841     get bh = do
 842             h <- getByte bh
 843             case h of
 844               0 -> do return DataName
 845               1 -> do return TvName
 846               2 -> do return TcClsName
 847               n -> do return (VarName (fromIntegral (n-3)))
 848
 849 instance Binary OccName where
 850     put_ bh (OccName aa ab) = do
 851             put_ bh aa
 852             put_ bh ab
 853     get bh = do
 854           aa <- get bh
 855           ab <- get bh
 856           return (OccName aa ab)
 857 \end{code}