compiler/basicTypes/OccName.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 -- |
   8 -- #name_types#
   9 -- GHC uses several kinds of name internally:
  10 --
  11 -- * 'OccName.OccName' represents names as strings with just a little more information:
  12 --   the \"namespace\" that the name came from, e.g. the namespace of value, type constructors or
  13 --   data constructors
  14 --
  15 -- * 'RdrName.RdrName': see "RdrName#name_types"
  16 --
  17 -- * 'Name.Name': see "Name#name_types"
  18 --
  19 -- * 'Id.Id': see "Id#name_types"
  20 --
  21 -- * 'Var.Var': see "Var#name_types"
  22 module OccName (
  23         -- * The 'NameSpace' type
  24         NameSpace, -- Abstract
  25
  26         -- ** Construction
  27         -- $real_vs_source_data_constructors
  28         tcName, clsName, tcClsName, dataName, varName, varNameDepth,
  29         tvName, srcDataName, setOccNameDepth, getOccNameDepth,
  30
  31         -- ** Pretty Printing
  32         pprNameSpace, pprNonVarNameSpace, pprNameSpaceBrief,
  33
  34         -- * The 'OccName' type
  35         OccName,        -- Abstract, instance of Outputable
  36         pprOccName,
  37
  38         -- ** Construction
  39         mkOccName, mkOccNameFS,
  40         mkVarOcc, mkVarOccFS,
  41         mkDataOcc, mkDataOccFS,
  42         mkTyVarOcc, mkTyVarOccFS,
  43         mkTcOcc, mkTcOccFS,
  44         mkClsOcc, mkClsOccFS,
  45         mkDFunOcc,
  46         mkTupleOcc,
  47         setOccNameSpace,
  48
  49         -- ** Derived 'OccName's
  50         isDerivedOccName,
  51         mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc,
  52         mkDerivedTyConOcc, mkNewTyCoOcc, mkClassOpAuxOcc,
  53         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
  54         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
  55         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
  56         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc,
  57         mkSuperDictSelOcc, mkLocalOcc, mkMethodOcc, mkInstTyTcOcc,
  58         mkInstTyCoOcc, mkEqPredCoOcc,
  59         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
  60         mkPDataTyConOcc, mkPDataDataConOcc,
  61         mkPReprTyConOcc,
  62         mkPADFunOcc,
  63
  64         -- ** Deconstruction
  65         occNameFS, occNameString, occNameSpace,
  66
  67         isVarOcc, isTvOcc, isTcOcc, isDataOcc, isDataSymOcc, isSymOcc, isValOcc,
  68         parenSymOcc, startsWithUnderscore,
  69
  70         isTcClsNameSpace, isTvNameSpace, isDataConNameSpace, isVarNameSpace, isValNameSpace,
  71
  72         isTupleOcc_maybe,
  73
  74         -- * The 'OccEnv' type
  75         OccEnv, emptyOccEnv, unitOccEnv, extendOccEnv, mapOccEnv,
  76         lookupOccEnv, mkOccEnv, mkOccEnv_C, extendOccEnvList, elemOccEnv,
  77         occEnvElts, foldOccEnv, plusOccEnv, plusOccEnv_C, extendOccEnv_C,
  78         extendOccEnv_Acc, filterOccEnv, delListFromOccEnv, delFromOccEnv,
  79
  80         -- * The 'OccSet' type
  81         OccSet, emptyOccSet, unitOccSet, mkOccSet, extendOccSet,
  82         extendOccSetList,
  83         unionOccSets, unionManyOccSets, minusOccSet, elemOccSet, occSetElts,
  84         foldOccSet, isEmptyOccSet, intersectOccSet, intersectsOccSet,
  85
  86         -- * Tidying up
  87         TidyOccEnv, emptyTidyOccEnv, tidyOccName, initTidyOccEnv,
  88
  89         -- * Lexical characteristics of Haskell names
  90         isLexCon, isLexVar, isLexId, isLexSym,
  91         isLexConId, isLexConSym, isLexVarId, isLexVarSym,
  92         startsVarSym, startsVarId, startsConSym, startsConId
  93     ) where
  94
  95 #include "Typeable.h"
  96
  97 import Util
  98 import Unique
  99 import BasicTypes
 100 import UniqFM
 101 import UniqSet
 102 import FastString
 103 import Outputable
 104 import Binary
 105 import StaticFlags( opt_SuppressUniques )
 106 import Data.Char
 107 import Data.Data
 108 \end{code}
 109
 110 %************************************************************************
 111 %*                                                                      *
 112 \subsection{Name space}
 113 %*                                                                      *
 114 %************************************************************************
 115
 116 \begin{code}
 117 data NameSpace = VarName   Int  -- Variables, including "real" data constructors; Int is the syntactic HetMet bracket depth
 118                | DataName       -- "Source" data constructors
 119                | TvName         -- Type variables
 120                | TcClsName      -- Type constructors and classes; Haskell has them
 121                                 -- in the same name space for now.
 122                deriving( Eq, Ord )
 123    {-! derive: Binary !-}
 124
 125 -- Note [Data Constructors]
 126 -- see also: Note [Data Constructor Naming] in DataCon.lhs
 127 --
 128 -- $real_vs_source_data_constructors
 129 -- There are two forms of data constructor:
 130 --
 131 --      [Source data constructors] The data constructors mentioned in Haskell source code
 132 --
 133 --      [Real data constructors] The data constructors of the representation type, which may not be the same as the source type
 134 --
 135 -- For example:
 136 --
 137 -- > data T = T !(Int, Int)
 138 --
 139 -- The source datacon has type @(Int, Int) -> T@
 140 -- The real   datacon has type @Int -> Int -> T@
 141 --
 142 -- GHC chooses a representation based on the strictness etc.
 143
 144 tcName, clsName, tcClsName :: NameSpace
 145 dataName, srcDataName      :: NameSpace
 146 tvName, varName            :: NameSpace
 147 varNameDepth               :: Int -> NameSpace
 148
 149 -- Though type constructors and classes are in the same name space now,
 150 -- the NameSpace type is abstract, so we can easily separate them later
 151 tcName    = TcClsName           -- Type constructors
 152 clsName   = TcClsName           -- Classes
 153 tcClsName = TcClsName           -- Not sure which!
 154
 155 dataName    = DataName
 156 srcDataName = DataName  -- Haskell-source data constructors should be
 157                         -- in the Data name space
 158
 159 tvName       = TvName
 160
 161 varName      = VarName 0
 162 varNameDepth = VarName
 163
 164 getOccNameDepth :: OccName -> Int
 165 getOccNameDepth name =
 166     case occNameSpace name of
 167       (VarName d) -> d
 168       _           -> 0
 169 setOccNameDepth :: Int -> OccName -> OccName
 170 setOccNameDepth depth name =
 171     case occNameSpace name of
 172       (VarName _) -> name{ occNameSpace = VarName depth }
 173       ns           -> if depth==0
 174                      then name
 175                      else error ("tried to change the depth of a name in namespace " ++ (showSDoc $ ppr name))
 176
 177 isDataConNameSpace :: NameSpace -> Bool
 178 isDataConNameSpace DataName = True
 179 isDataConNameSpace _        = False
 180
 181 isTcClsNameSpace :: NameSpace -> Bool
 182 isTcClsNameSpace TcClsName = True
 183 isTcClsNameSpace _         = False
 184
 185 isTvNameSpace :: NameSpace -> Bool
 186 isTvNameSpace TvName = True
 187 isTvNameSpace _      = False
 188
 189 isVarNameSpace :: NameSpace -> Bool     -- Variables or type variables, but not constructors
 190 isVarNameSpace TvName  = True
 191 isVarNameSpace (VarName _) = True
 192 isVarNameSpace _       = False
 193
 194 isValNameSpace :: NameSpace -> Bool
 195 isValNameSpace DataName = True
 196 isValNameSpace (VarName _)  = True
 197 isValNameSpace _        = False
 198
 199 pprNameSpace :: NameSpace -> SDoc
 200 pprNameSpace DataName  = ptext (sLit "data constructor")
 201 pprNameSpace (VarName _)  = ptext (sLit "variable")
 202 pprNameSpace TvName    = ptext (sLit "type variable")
 203 pprNameSpace TcClsName = ptext (sLit "type constructor or class")
 204
 205 pprNonVarNameSpace :: NameSpace -> SDoc
 206 pprNonVarNameSpace (VarName _) = empty
 207 pprNonVarNameSpace ns = pprNameSpace ns
 208
 209 pprNameSpaceBrief :: NameSpace -> SDoc
 210 pprNameSpaceBrief DataName  = char 'd'
 211 pprNameSpaceBrief (VarName _)  = char 'v'
 212 pprNameSpaceBrief TvName    = ptext (sLit "tv")
 213 pprNameSpaceBrief TcClsName = ptext (sLit "tc")
 214 \end{code}
 215
 216
 217 %************************************************************************
 218 %*                                                                      *
 219 \subsection[Name-pieces-datatypes]{The @OccName@ datatypes}
 220 %*                                                                      *
 221 %************************************************************************
 222
 223 \begin{code}
 224 data OccName = OccName
 225     { occNameSpace  :: !NameSpace
 226     , occNameFS     :: !FastString
 227     }
 228 \end{code}
 229
 230
 231 \begin{code}
 232 instance Eq OccName where
 233     (OccName sp1 s1) == (OccName sp2 s2) = s1 == s2 && sp1 == sp2
 234
 235 instance Ord OccName where
 236         -- Compares lexicographically, *not* by Unique of the string
 237     compare (OccName sp1 s1) (OccName sp2 s2)
 238         = (s1  `compare` s2) `thenCmp` (sp1 `compare` sp2)
 239
 240 INSTANCE_TYPEABLE0(OccName,occNameTc,"OccName")
 241
 242 instance Data OccName where
 243   -- don't traverse?
 244   toConstr _   = abstractConstr "OccName"
 245   gunfold _ _  = error "gunfold"
 246   dataTypeOf _ = mkNoRepType "OccName"
 247 \end{code}
 248
 249
 250 %************************************************************************
 251 %*                                                                      *
 252 \subsection{Printing}
 253 %*                                                                      *
 254 %************************************************************************
 255
 256 \begin{code}
 257 instance Outputable OccName where
 258     ppr = pprOccName
 259
 260 pprOccName :: OccName -> SDoc
 261 pprOccName (OccName sp occ)
 262   = getPprStyle $ \ sty ->
 263     if codeStyle sty
 264     then ftext (zEncodeFS occ)
 265     else pp_occ <> pp_debug sty
 266   where
 267     pp_debug sty | debugStyle sty = braces (pprNameSpaceBrief sp)
 268                  | otherwise      = empty
 269
 270     pp_occ | opt_SuppressUniques = text (strip_th_unique (unpackFS occ))
 271            | otherwise           = ftext occ
 272
 273         -- See Note [Suppressing uniques in OccNames]
 274     strip_th_unique ('[' : c : _) | isAlphaNum c = []
 275     strip_th_unique (c : cs) = c : strip_th_unique cs
 276     strip_th_unique []       = []
 277 \end{code}
 278
 279 Note [Suppressing uniques in OccNames]
 280 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 281 This is a hack to de-wobblify the OccNames that contain uniques from
 282 Template Haskell that have been turned into a string in the OccName.
 283 See Note [Unique OccNames from Template Haskell] in Convert.hs
 284
 285 %************************************************************************
 286 %*                                                                      *
 287 \subsection{Construction}
 288 %*                                                                      *
 289 %************************************************************************
 290
 291 \begin{code}
 292 mkOccName :: NameSpace -> String -> OccName
 293 mkOccName occ_sp str = OccName occ_sp (mkFastString str)
 294
 295 mkOccNameFS :: NameSpace -> FastString -> OccName
 296 mkOccNameFS occ_sp fs = OccName occ_sp fs
 297
 298 mkVarOcc :: String -> OccName
 299 mkVarOcc s = mkOccName varName s
 300
 301 mkVarOccFS :: FastString -> OccName
 302 mkVarOccFS fs = mkOccNameFS varName fs
 303
 304 mkDataOcc :: String -> OccName
 305 mkDataOcc = mkOccName dataName
 306
 307 mkDataOccFS :: FastString -> OccName
 308 mkDataOccFS = mkOccNameFS dataName
 309
 310 mkTyVarOcc :: String -> OccName
 311 mkTyVarOcc = mkOccName tvName
 312
 313 mkTyVarOccFS :: FastString -> OccName
 314 mkTyVarOccFS fs = mkOccNameFS tvName fs
 315
 316 mkTcOcc :: String -> OccName
 317 mkTcOcc = mkOccName tcName
 318
 319 mkTcOccFS :: FastString -> OccName
 320 mkTcOccFS = mkOccNameFS tcName
 321
 322 mkClsOcc :: String -> OccName
 323 mkClsOcc = mkOccName clsName
 324
 325 mkClsOccFS :: FastString -> OccName
 326 mkClsOccFS = mkOccNameFS clsName
 327 \end{code}
 328
 329
 330 %************************************************************************
 331 %*                                                                      *
 332                 Environments
 333 %*                                                                      *
 334 %************************************************************************
 335
 336 OccEnvs are used mainly for the envts in ModIfaces.
 337
 338 Note [The Unique of an OccName]
 339 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 340 They are efficient, because FastStrings have unique Int# keys.  We assume
 341 this key is less than 2^24, and indeed FastStrings are allocated keys
 342 sequentially starting at 0.
 343
 344 So we can make a Unique using
 345         mkUnique ns key  :: Unique
 346 where 'ns' is a Char reprsenting the name space.  This in turn makes it
 347 easy to build an OccEnv.
 348
 349 \begin{code}
 350 instance Uniquable OccName where
 351       -- See Note [The Unique of an OccName]
 352   getUnique (OccName (VarName depth) fs) = mkVarOccUnique fs depth
 353   getUnique (OccName DataName  fs) = mkDataOccUnique fs
 354   getUnique (OccName TvName    fs) = mkTvOccUnique   fs
 355   getUnique (OccName TcClsName fs) = mkTcOccUnique   fs
 356
 357 newtype OccEnv a = A (UniqFM a)
 358
 359 emptyOccEnv :: OccEnv a
 360 unitOccEnv  :: OccName -> a -> OccEnv a
 361 extendOccEnv :: OccEnv a -> OccName -> a -> OccEnv a
 362 extendOccEnvList :: OccEnv a -> [(OccName, a)] -> OccEnv a
 363 lookupOccEnv :: OccEnv a -> OccName -> Maybe a
 364 mkOccEnv     :: [(OccName,a)] -> OccEnv a
 365 mkOccEnv_C   :: (a -> a -> a) -> [(OccName,a)] -> OccEnv a
 366 elemOccEnv   :: OccName -> OccEnv a -> Bool
 367 foldOccEnv   :: (a -> b -> b) -> b -> OccEnv a -> b
 368 occEnvElts   :: OccEnv a -> [a]
 369 extendOccEnv_C :: (a->a->a) -> OccEnv a -> OccName -> a -> OccEnv a
 370 extendOccEnv_Acc :: (a->b->b) -> (a->b) -> OccEnv b -> OccName -> a -> OccEnv b
 371 plusOccEnv     :: OccEnv a -> OccEnv a -> OccEnv a
 372 plusOccEnv_C   :: (a->a->a) -> OccEnv a -> OccEnv a -> OccEnv a
 373 mapOccEnv      :: (a->b) -> OccEnv a -> OccEnv b
 374 delFromOccEnv      :: OccEnv a -> OccName -> OccEnv a
 375 delListFromOccEnv :: OccEnv a -> [OccName] -> OccEnv a
 376 filterOccEnv       :: (elt -> Bool) -> OccEnv elt -> OccEnv elt
 377
 378 emptyOccEnv      = A emptyUFM
 379 unitOccEnv x y = A $ unitUFM x y
 380 extendOccEnv (A x) y z = A $ addToUFM x y z
 381 extendOccEnvList (A x) l = A $ addListToUFM x l
 382 lookupOccEnv (A x) y = lookupUFM x y
 383 mkOccEnv     l    = A $ listToUFM l
 384 elemOccEnv x (A y)       = elemUFM x y
 385 foldOccEnv a b (A c)     = foldUFM a b c
 386 occEnvElts (A x)         = eltsUFM x
 387 plusOccEnv (A x) (A y)   = A $ plusUFM x y
 388 plusOccEnv_C f (A x) (A y)       = A $ plusUFM_C f x y
 389 extendOccEnv_C f (A x) y z   = A $ addToUFM_C f x y z
 390 extendOccEnv_Acc f g (A x) y z   = A $ addToUFM_Acc f g x y z
 391 mapOccEnv f (A x)        = A $ mapUFM f x
 392 mkOccEnv_C comb l = A $ addListToUFM_C comb emptyUFM l
 393 delFromOccEnv (A x) y    = A $ delFromUFM x y
 394 delListFromOccEnv (A x) y  = A $ delListFromUFM x y
 395 filterOccEnv x (A y)       = A $ filterUFM x y
 396
 397 instance Outputable a => Outputable (OccEnv a) where
 398     ppr (A x) = ppr x
 399
 400 type OccSet = UniqSet OccName
 401
 402 emptyOccSet       :: OccSet
 403 unitOccSet        :: OccName -> OccSet
 404 mkOccSet          :: [OccName] -> OccSet
 405 extendOccSet      :: OccSet -> OccName -> OccSet
 406 extendOccSetList  :: OccSet -> [OccName] -> OccSet
 407 unionOccSets      :: OccSet -> OccSet -> OccSet
 408 unionManyOccSets  :: [OccSet] -> OccSet
 409 minusOccSet       :: OccSet -> OccSet -> OccSet
 410 elemOccSet        :: OccName -> OccSet -> Bool
 411 occSetElts        :: OccSet -> [OccName]
 412 foldOccSet        :: (OccName -> b -> b) -> b -> OccSet -> b
 413 isEmptyOccSet     :: OccSet -> Bool
 414 intersectOccSet   :: OccSet -> OccSet -> OccSet
 415 intersectsOccSet  :: OccSet -> OccSet -> Bool
 416
 417 emptyOccSet       = emptyUniqSet
 418 unitOccSet        = unitUniqSet
 419 mkOccSet          = mkUniqSet
 420 extendOccSet      = addOneToUniqSet
 421 extendOccSetList  = addListToUniqSet
 422 unionOccSets      = unionUniqSets
 423 unionManyOccSets  = unionManyUniqSets
 424 minusOccSet       = minusUniqSet
 425 elemOccSet        = elementOfUniqSet
 426 occSetElts        = uniqSetToList
 427 foldOccSet        = foldUniqSet
 428 isEmptyOccSet     = isEmptyUniqSet
 429 intersectOccSet   = intersectUniqSets
 430 intersectsOccSet s1 s2 = not (isEmptyOccSet (s1 `intersectOccSet` s2))
 431 \end{code}
 432
 433
 434 %************************************************************************
 435 %*                                                                      *
 436 \subsection{Predicates and taking them apart}
 437 %*                                                                      *
 438 %************************************************************************
 439
 440 \begin{code}
 441 occNameString :: OccName -> String
 442 occNameString (OccName _ s) = unpackFS s
 443
 444 setOccNameSpace :: NameSpace -> OccName -> OccName
 445 setOccNameSpace sp (OccName _ occ) = OccName sp occ
 446
 447 isVarOcc, isTvOcc, isTcOcc, isDataOcc :: OccName -> Bool
 448
 449 isVarOcc (OccName (VarName _) _) = True
 450 isVarOcc _                   = False
 451
 452 isTvOcc (OccName TvName _) = True
 453 isTvOcc _                  = False
 454
 455 isTcOcc (OccName TcClsName _) = True
 456 isTcOcc _                     = False
 457
 458 -- | /Value/ 'OccNames's are those that are either in
 459 -- the variable or data constructor namespaces
 460 isValOcc :: OccName -> Bool
 461 isValOcc (OccName (VarName _) _) = True
 462 isValOcc (OccName DataName _) = True
 463 isValOcc _                    = False
 464
 465 isDataOcc (OccName DataName _) = True
 466 isDataOcc (OccName (VarName _) s)
 467   | isLexCon s = pprPanic "isDataOcc: check me" (ppr s)
 468                 -- Jan06: I don't think this should happen
 469 isDataOcc _                    = False
 470
 471 -- | Test if the 'OccName' is a data constructor that starts with
 472 -- a symbol (e.g. @:@, or @[]@)
 473 isDataSymOcc :: OccName -> Bool
 474 isDataSymOcc (OccName DataName s) = isLexConSym s
 475 isDataSymOcc (OccName (VarName _) s)
 476   | isLexConSym s = pprPanic "isDataSymOcc: check me" (ppr s)
 477                 -- Jan06: I don't think this should happen
 478 isDataSymOcc _                    = False
 479 -- Pretty inefficient!
 480
 481 -- | Test if the 'OccName' is that for any operator (whether
 482 -- it is a data constructor or variable or whatever)
 483 isSymOcc :: OccName -> Bool
 484 isSymOcc (OccName DataName s)  = isLexConSym s
 485 isSymOcc (OccName TcClsName s) = isLexConSym s
 486 isSymOcc (OccName (VarName _) s)   = isLexSym s
 487 isSymOcc (OccName TvName s)    = isLexSym s
 488 -- Pretty inefficient!
 489
 490 parenSymOcc :: OccName -> SDoc -> SDoc
 491 -- ^ Wrap parens around an operator
 492 parenSymOcc occ doc | isSymOcc occ = parens doc
 493                     | otherwise    = doc
 494 \end{code}
 495
 496
 497 \begin{code}
 498 startsWithUnderscore :: OccName -> Bool
 499 -- ^ Haskell 98 encourages compilers to suppress warnings about unsed
 500 -- names in a pattern if they start with @_@: this implements that test
 501 startsWithUnderscore occ = case occNameString occ of
 502                              ('_' : _) -> True
 503                              _other    -> False
 504 \end{code}
 505
 506
 507 %************************************************************************
 508 %*                                                                      *
 509 \subsection{Making system names}
 510 %*                                                                      *
 511 %************************************************************************
 512
 513 Here's our convention for splitting up the interface file name space:
 514
 515    d...         dictionary identifiers
 516                 (local variables, so no name-clash worries)
 517
 518 All of these other OccNames contain a mixture of alphabetic
 519 and symbolic characters, and hence cannot possibly clash with
 520 a user-written type or function name
 521
 522    $f...        Dict-fun identifiers (from inst decls)
 523    $dmop        Default method for 'op'
 524    $pnC         n'th superclass selector for class C
 525    $wf          Worker for functtoin 'f'
 526    $sf..        Specialised version of f
 527    T:C          Tycon for dictionary for class C
 528    D:C          Data constructor for dictionary for class C
 529    NTCo:T       Coercion connecting newtype T with its representation type
 530    TFCo:R       Coercion connecting a data family to its respresentation type R
 531
 532 In encoded form these appear as Zdfxxx etc
 533
 534         :...            keywords (export:, letrec: etc.)
 535 --- I THINK THIS IS WRONG!
 536
 537 This knowledge is encoded in the following functions.
 538
 539 @mk_deriv@ generates an @OccName@ from the prefix and a string.
 540 NB: The string must already be encoded!
 541
 542 \begin{code}
 543 mk_deriv :: NameSpace
 544          -> String              -- Distinguishes one sort of derived name from another
 545          -> String
 546          -> OccName
 547
 548 mk_deriv occ_sp sys_prefix str = mkOccName occ_sp (sys_prefix ++ str)
 549
 550 isDerivedOccName :: OccName -> Bool
 551 isDerivedOccName occ =
 552    case occNameString occ of
 553      '$':c:_ | isAlphaNum c -> True
 554      ':':c:_ | isAlphaNum c -> True
 555      _other                 -> False
 556 \end{code}
 557
 558 \begin{code}
 559 mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc, mkDerivedTyConOcc,
 560         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
 561         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
 562         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc, mkNewTyCoOcc,
 563         mkInstTyCoOcc, mkEqPredCoOcc, mkClassOpAuxOcc,
 564         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
 565         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
 566         mkPDataTyConOcc, mkPDataDataConOcc, mkPReprTyConOcc, mkPADFunOcc
 567    :: OccName -> OccName
 568
 569 -- These derived variables have a prefix that no Haskell value could have
 570 mkDataConWrapperOcc = mk_simple_deriv varName  "$W"
 571 mkWorkerOcc         = mk_simple_deriv varName  "$w"
 572 mkDefaultMethodOcc  = mk_simple_deriv varName  "$dm"
 573 mkClassOpAuxOcc     = mk_simple_deriv varName  "$c"
 574 mkDerivedTyConOcc   = mk_simple_deriv tcName   ":"      -- The : prefix makes sure it classifies
 575 mkClassTyConOcc     = mk_simple_deriv tcName   "T:"     -- as a tycon/datacon
 576 mkClassDataConOcc   = mk_simple_deriv dataName "D:"     -- We go straight to the "real" data con
 577                                                         -- for datacons from classes
 578 mkDictOcc           = mk_simple_deriv varName  "$d"
 579 mkIPOcc             = mk_simple_deriv varName  "$i"
 580 mkSpecOcc           = mk_simple_deriv varName  "$s"
 581 mkForeignExportOcc  = mk_simple_deriv varName  "$f"
 582 mkNewTyCoOcc        = mk_simple_deriv tcName   "NTCo:"  -- Coercion for newtypes
 583 mkInstTyCoOcc       = mk_simple_deriv tcName   "TFCo:"   -- Coercion for type functions
 584 mkEqPredCoOcc       = mk_simple_deriv tcName   "$co"
 585
 586 -- used in derived instances
 587 mkCon2TagOcc        = mk_simple_deriv varName  "$con2tag_"
 588 mkTag2ConOcc        = mk_simple_deriv varName  "$tag2con_"
 589 mkMaxTagOcc         = mk_simple_deriv varName  "$maxtag_"
 590
 591 -- Generic derivable classes
 592 mkGenOcc1           = mk_simple_deriv varName  "$gfrom"
 593 mkGenOcc2           = mk_simple_deriv varName  "$gto"
 594
 595 -- data T = MkT ... deriving( Data ) needs defintions for
 596 --      $tT   :: Data.Generics.Basics.DataType
 597 --      $cMkT :: Data.Generics.Basics.Constr
 598 mkDataTOcc = mk_simple_deriv varName  "$t"
 599 mkDataCOcc = mk_simple_deriv varName  "$c"
 600
 601 -- Vectorisation
 602 mkVectOcc          = mk_simple_deriv varName  "$v_"
 603 mkVectTyConOcc     = mk_simple_deriv tcName   ":V_"
 604 mkVectDataConOcc   = mk_simple_deriv dataName ":VD_"
 605 mkVectIsoOcc       = mk_simple_deriv varName  "$VI_"
 606 mkPDataTyConOcc    = mk_simple_deriv tcName   ":VP_"
 607 mkPDataDataConOcc  = mk_simple_deriv dataName ":VPD_"
 608 mkPReprTyConOcc    = mk_simple_deriv tcName   ":VR_"
 609 mkPADFunOcc        = mk_simple_deriv varName  "$PA_"
 610
 611 mk_simple_deriv :: NameSpace -> String -> OccName -> OccName
 612 mk_simple_deriv sp px occ = mk_deriv sp px (occNameString occ)
 613
 614 -- Data constructor workers are made by setting the name space
 615 -- of the data constructor OccName (which should be a DataName)
 616 -- to VarName
 617 mkDataConWorkerOcc datacon_occ = setOccNameSpace varName datacon_occ
 618 \end{code}
 619
 620 \begin{code}
 621 mkSuperDictSelOcc :: Int        -- ^ Index of superclass, e.g. 3
 622                   -> OccName    -- ^ Class, e.g. @Ord@
 623                   -> OccName    -- ^ Derived 'Occname', e.g. @$p3Ord@
 624 mkSuperDictSelOcc index cls_occ
 625   = mk_deriv varName "$p" (show index ++ occNameString cls_occ)
 626
 627 mkLocalOcc :: Unique            -- ^ Unique to combine with the 'OccName'
 628            -> OccName           -- ^ Local name, e.g. @sat@
 629            -> OccName           -- ^ Nice unique version, e.g. @$L23sat@
 630 mkLocalOcc uniq occ
 631    = mk_deriv varName ("$L" ++ show uniq) (occNameString occ)
 632         -- The Unique might print with characters
 633         -- that need encoding (e.g. 'z'!)
 634 \end{code}
 635
 636 \begin{code}
 637 -- | Derive a name for the representation type constructor of a
 638 -- @data@\/@newtype@ instance.
 639 mkInstTyTcOcc :: String                 -- ^ Family name, e.g. @Map@
 640               -> OccSet                 -- ^ avoid these Occs
 641               -> OccName                -- ^ @R:Map@
 642 mkInstTyTcOcc str set =
 643   chooseUniqueOcc tcName ('R' : ':' : str) set
 644 \end{code}
 645
 646 \begin{code}
 647 mkDFunOcc :: String             -- ^ Typically the class and type glommed together e.g. @OrdMaybe@.
 648                                 -- Only used in debug mode, for extra clarity
 649           -> Bool               -- ^ Is this a hs-boot instance DFun?
 650           -> OccSet             -- ^ avoid these Occs
 651           -> OccName            -- ^ E.g. @$f3OrdMaybe@
 652
 653 -- In hs-boot files we make dict funs like $fx7ClsTy, which get bound to the real
 654 -- thing when we compile the mother module. Reason: we don't know exactly
 655 -- what the  mother module will call it.
 656
 657 mkDFunOcc info_str is_boot set
 658   = chooseUniqueOcc (VarName 0) (prefix ++ info_str) set
 659   where
 660     prefix | is_boot   = "$fx"
 661            | otherwise = "$f"
 662 \end{code}
 663
 664 Sometimes we need to pick an OccName that has not already been used,
 665 given a set of in-use OccNames.
 666
 667 \begin{code}
 668 chooseUniqueOcc :: NameSpace -> String -> OccSet -> OccName
 669 chooseUniqueOcc ns str set = loop (mkOccName ns str) (0::Int)
 670   where
 671   loop occ n
 672    | occ `elemOccSet` set = loop (mkOccName ns (str ++ show n)) (n+1)
 673    | otherwise            = occ
 674 \end{code}
 675
 676 We used to add a '$m' to indicate a method, but that gives rise to bad
 677 error messages from the type checker when we print the function name or pattern
 678 of an instance-decl binding.  Why? Because the binding is zapped
 679 to use the method name in place of the selector name.
 680 (See TcClassDcl.tcMethodBind)
 681
 682 The way it is now, -ddump-xx output may look confusing, but
 683 you can always say -dppr-debug to get the uniques.
 684
 685 However, we *do* have to zap the first character to be lower case,
 686 because overloaded constructors (blarg) generate methods too.
 687 And convert to VarName space
 688
 689 e.g. a call to constructor MkFoo where
 690         data (Ord a) => Foo a = MkFoo a
 691
 692 If this is necessary, we do it by prefixing '$m'.  These
 693 guys never show up in error messages.  What a hack.
 694
 695 \begin{code}
 696 mkMethodOcc :: OccName -> OccName
 697 mkMethodOcc occ@(OccName (VarName _) _) = occ
 698 mkMethodOcc occ                     = mk_simple_deriv varName "$m" occ
 699 \end{code}
 700
 701
 702 %************************************************************************
 703 %*                                                                      *
 704 \subsection{Tidying them up}
 705 %*                                                                      *
 706 %************************************************************************
 707
 708 Before we print chunks of code we like to rename it so that
 709 we don't have to print lots of silly uniques in it.  But we mustn't
 710 accidentally introduce name clashes!  So the idea is that we leave the
 711 OccName alone unless it accidentally clashes with one that is already
 712 in scope; if so, we tack on '1' at the end and try again, then '2', and
 713 so on till we find a unique one.
 714
 715 There's a wrinkle for operators.  Consider '>>='.  We can't use '>>=1'
 716 because that isn't a single lexeme.  So we encode it to 'lle' and *then*
 717 tack on the '1', if necessary.
 718
 719 \begin{code}
 720 type TidyOccEnv = OccEnv Int    -- The in-scope OccNames
 721         -- Range gives a plausible starting point for new guesses
 722
 723 emptyTidyOccEnv :: TidyOccEnv
 724 emptyTidyOccEnv = emptyOccEnv
 725
 726 initTidyOccEnv :: [OccName] -> TidyOccEnv       -- Initialise with names to avoid!
 727 initTidyOccEnv = foldl (\env occ -> extendOccEnv env occ 1) emptyTidyOccEnv
 728
 729 tidyOccName :: TidyOccEnv -> OccName -> (TidyOccEnv, OccName)
 730
 731 tidyOccName in_scope occ@(OccName occ_sp fs)
 732   = case lookupOccEnv in_scope occ of
 733         Nothing ->      -- Not already used: make it used
 734                    (extendOccEnv in_scope occ 1, occ)
 735
 736         Just n  ->      -- Already used: make a new guess,
 737                         -- change the guess base, and try again
 738                    tidyOccName  (extendOccEnv in_scope occ (n+1))
 739                                 (mkOccName occ_sp (base_occ ++ show n))
 740   where
 741     base_occ = reverse (dropWhile isDigit (reverse (unpackFS fs)))
 742 \end{code}
 743
 744 %************************************************************************
 745 %*                                                                      *
 746                 Stuff for dealing with tuples
 747 %*                                                                      *
 748 %************************************************************************
 749
 750 \begin{code}
 751 mkTupleOcc :: NameSpace -> Boxity -> Arity -> OccName
 752 mkTupleOcc ns bx ar = OccName ns (mkFastString str)
 753   where
 754         -- no need to cache these, the caching is done in the caller
 755         -- (TysWiredIn.mk_tuple)
 756     str = case bx of
 757                 Boxed   -> '(' : commas ++ ")"
 758                 Unboxed -> '(' : '#' : commas ++ "#)"
 759
 760     commas = take (ar-1) (repeat ',')
 761
 762 isTupleOcc_maybe :: OccName -> Maybe (NameSpace, Boxity, Arity)
 763 -- Tuples are special, because there are so many of them!
 764 isTupleOcc_maybe (OccName ns fs)
 765   = case unpackFS fs of
 766         '(':'#':',':rest -> Just (ns, Unboxed, 2 + count_commas rest)
 767         '(':',':rest     -> Just (ns, Boxed,   2 + count_commas rest)
 768         _other           -> Nothing
 769   where
 770     count_commas (',':rest) = 1 + count_commas rest
 771     count_commas _          = 0
 772 \end{code}
 773
 774 %************************************************************************
 775 %*                                                                      *
 776 \subsection{Lexical categories}
 777 %*                                                                      *
 778 %************************************************************************
 779
 780 These functions test strings to see if they fit the lexical categories
 781 defined in the Haskell report.
 782
 783 \begin{code}
 784 isLexCon,   isLexVar,    isLexId,    isLexSym    :: FastString -> Bool
 785 isLexConId, isLexConSym, isLexVarId, isLexVarSym :: FastString -> Bool
 786
 787 isLexCon cs = isLexConId  cs || isLexConSym cs
 788 isLexVar cs = isLexVarId  cs || isLexVarSym cs
 789
 790 isLexId  cs = isLexConId  cs || isLexVarId  cs
 791 isLexSym cs = isLexConSym cs || isLexVarSym cs
 792
 793 -------------
 794
 795 isLexConId cs                           -- Prefix type or data constructors
 796   | nullFS cs          = False          --      e.g. "Foo", "[]", "(,)"
 797   | cs == (fsLit "[]") = True
 798   | otherwise          = startsConId (headFS cs)
 799
 800 isLexVarId cs                           -- Ordinary prefix identifiers
 801   | nullFS cs         = False           --      e.g. "x", "_x"
 802   | otherwise         = startsVarId (headFS cs)
 803
 804 isLexConSym cs                          -- Infix type or data constructors
 805   | nullFS cs          = False          --      e.g. ":-:", ":", "->"
 806   | cs == (fsLit "->") = True
 807   | otherwise          = startsConSym (headFS cs)
 808
 809 isLexVarSym cs                          -- Infix identifiers
 810   | nullFS cs         = False           --      e.g. "+"
 811   | otherwise         = startsVarSym (headFS cs)
 812
 813 -------------
 814 startsVarSym, startsVarId, startsConSym, startsConId :: Char -> Bool
 815 startsVarSym c = isSymbolASCII c || (ord c > 0x7f && isSymbol c) -- Infix Ids
 816 startsConSym c = c == ':'                               -- Infix data constructors
 817 startsVarId c  = isLower c || c == '_'  -- Ordinary Ids
 818 startsConId c  = isUpper c || c == '('  -- Ordinary type constructors and data constructors
 819
 820 isSymbolASCII :: Char -> Bool
 821 isSymbolASCII c = c `elem` "!#$%&*+./<=>?@\\^|~-"
 822 \end{code}
 823
 824 %************************************************************************
 825 %*                                                                      *
 826                 Binary instance
 827     Here rather than BinIface because OccName is abstract
 828 %*                                                                      *
 829 %************************************************************************
 830
 831 \begin{code}
 832 instance Binary NameSpace where
 833     put_ bh (VarName depth) = do if depth > 255-4
 834                                    then error "FIXME: no support for serializing VarNames at this syntactic depth"
 835                                    else putByte bh ((fromIntegral ((depth+3) :: Int)))
 836     put_ bh DataName = do
 837             putByte bh 0
 838     put_ bh TvName = do
 839             putByte bh 1
 840     put_ bh TcClsName = do
 841             putByte bh 2
 842     get bh = do
 843             h <- getByte bh
 844             case h of
 845               0 -> do return DataName
 846               1 -> do return TvName
 847               2 -> do return TcClsName
 848               n -> do return (VarName (fromIntegral (n-3)))
 849
 850 instance Binary OccName where
 851     put_ bh (OccName aa ab) = do
 852             put_ bh aa
 853             put_ bh ab
 854     get bh = do
 855           aa <- get bh
 856           ab <- get bh
 857           return (OccName aa ab)
 858 \end{code}