compiler/basicTypes/OccName.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 -- |
   8 -- #name_types#
   9 -- GHC uses several kinds of name internally:
  10 --
  11 -- * 'OccName.OccName' represents names as strings with just a little more information:
  12 --   the \"namespace\" that the name came from, e.g. the namespace of value, type constructors or
  13 --   data constructors
  14 --
  15 -- * 'RdrName.RdrName': see "RdrName#name_types"
  16 --
  17 -- * 'Name.Name': see "Name#name_types"
  18 --
  19 -- * 'Id.Id': see "Id#name_types"
  20 --
  21 -- * 'Var.Var': see "Var#name_types"
  22 module OccName (
  23         -- * The 'NameSpace' type
  24         NameSpace, -- Abstract
  25
  26         -- ** Construction
  27         -- $real_vs_source_data_constructors
  28         tcName, clsName, tcClsName, dataName, varName,
  29         tvName, srcDataName,
  30
  31         -- ** Pretty Printing
  32         pprNameSpace, pprNonVarNameSpace, pprNameSpaceBrief,
  33
  34         -- * The 'OccName' type
  35         OccName,        -- Abstract, instance of Outputable
  36         pprOccName,
  37
  38         -- ** Construction
  39         mkOccName, mkOccNameFS,
  40         mkVarOcc, mkVarOccFS,
  41         mkDataOcc, mkDataOccFS,
  42         mkTyVarOcc, mkTyVarOccFS,
  43         mkTcOcc, mkTcOccFS,
  44         mkClsOcc, mkClsOccFS,
  45         mkDFunOcc,
  46         mkTupleOcc,
  47         setOccNameSpace,
  48
  49         -- ** Derived 'OccName's
  50         isDerivedOccName,
  51         mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc,
  52         mkDerivedTyConOcc, mkNewTyCoOcc,
  53         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
  54         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
  55         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
  56         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc,
  57         mkSuperDictSelOcc, mkLocalOcc, mkMethodOcc, mkInstTyTcOcc,
  58         mkInstTyCoOcc, mkEqPredCoOcc,
  59         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
  60         mkPDataTyConOcc, mkPDataDataConOcc,
  61         mkPReprTyConOcc,
  62         mkPADFunOcc,
  63
  64         -- ** Deconstruction
  65         occNameFS, occNameString, occNameSpace,
  66
  67         isVarOcc, isTvOcc, isTcOcc, isDataOcc, isDataSymOcc, isSymOcc, isValOcc,
  68         parenSymOcc, startsWithUnderscore,
  69
  70         isTcClsNameSpace, isTvNameSpace, isDataConNameSpace, isVarNameSpace, isValNameSpace,
  71
  72         isTupleOcc_maybe,
  73
  74         -- * The 'OccEnv' type
  75         OccEnv, emptyOccEnv, unitOccEnv, extendOccEnv, mapOccEnv,
  76         lookupOccEnv, mkOccEnv, mkOccEnv_C, extendOccEnvList, elemOccEnv,
  77         occEnvElts, foldOccEnv, plusOccEnv, plusOccEnv_C, extendOccEnv_C,
  78         filterOccEnv, delListFromOccEnv, delFromOccEnv,
  79
  80         -- * The 'OccSet' type
  81         OccSet, emptyOccSet, unitOccSet, mkOccSet, extendOccSet,
  82         extendOccSetList,
  83         unionOccSets, unionManyOccSets, minusOccSet, elemOccSet, occSetElts,
  84         foldOccSet, isEmptyOccSet, intersectOccSet, intersectsOccSet,
  85
  86         -- * Tidying up
  87         TidyOccEnv, emptyTidyOccEnv, tidyOccName, initTidyOccEnv,
  88
  89         -- * Lexical characteristics of Haskell names
  90         isLexCon, isLexVar, isLexId, isLexSym,
  91         isLexConId, isLexConSym, isLexVarId, isLexVarSym,
  92         startsVarSym, startsVarId, startsConSym, startsConId
  93     ) where
  94
  95 import Util
  96 import Unique
  97 import BasicTypes
  98 import UniqFM
  99 import UniqSet
 100 import FastString
 101 import Outputable
 102 import Binary
 103 import Data.Char
 104 \end{code}
 105
 106 \begin{code}
 107 -- Unicode TODO: put isSymbol in libcompat
 108 #if !defined(__GLASGOW_HASKELL__) || __GLASGOW_HASKELL__ > 604
 109 #else
 110 isSymbol :: a -> Bool
 111 isSymbol = const False
 112 #endif
 113
 114 \end{code}
 115
 116 %************************************************************************
 117 %*                                                                      *
 118 \subsection{Name space}
 119 %*                                                                      *
 120 %************************************************************************
 121
 122 \begin{code}
 123 data NameSpace = VarName        -- Variables, including "real" data constructors
 124                | DataName       -- "Source" data constructors
 125                | TvName         -- Type variables
 126                | TcClsName      -- Type constructors and classes; Haskell has them
 127                                 -- in the same name space for now.
 128                deriving( Eq, Ord )
 129    {-! derive: Binary !-}
 130
 131 -- Note [Data Constructors]
 132 -- see also: Note [Data Constructor Naming] in DataCon.lhs
 133 --
 134 -- $real_vs_source_data_constructors
 135 -- There are two forms of data constructor:
 136 --
 137 --      [Source data constructors] The data constructors mentioned in Haskell source code
 138 --
 139 --      [Real data constructors] The data constructors of the representation type, which may not be the same as the source type
 140 --
 141 -- For example:
 142 --
 143 -- > data T = T !(Int, Int)
 144 --
 145 -- The source datacon has type @(Int, Int) -> T@
 146 -- The real   datacon has type @Int -> Int -> T@
 147 --
 148 -- GHC chooses a representation based on the strictness etc.
 149
 150 tcName, clsName, tcClsName :: NameSpace
 151 dataName, srcDataName      :: NameSpace
 152 tvName, varName            :: NameSpace
 153
 154 -- Though type constructors and classes are in the same name space now,
 155 -- the NameSpace type is abstract, so we can easily separate them later
 156 tcName    = TcClsName           -- Type constructors
 157 clsName   = TcClsName           -- Classes
 158 tcClsName = TcClsName           -- Not sure which!
 159
 160 dataName    = DataName
 161 srcDataName = DataName  -- Haskell-source data constructors should be
 162                         -- in the Data name space
 163
 164 tvName      = TvName
 165 varName     = VarName
 166
 167 isDataConNameSpace :: NameSpace -> Bool
 168 isDataConNameSpace DataName = True
 169 isDataConNameSpace _        = False
 170
 171 isTcClsNameSpace :: NameSpace -> Bool
 172 isTcClsNameSpace TcClsName = True
 173 isTcClsNameSpace _         = False
 174
 175 isTvNameSpace :: NameSpace -> Bool
 176 isTvNameSpace TvName = True
 177 isTvNameSpace _      = False
 178
 179 isVarNameSpace :: NameSpace -> Bool     -- Variables or type variables, but not constructors
 180 isVarNameSpace TvName  = True
 181 isVarNameSpace VarName = True
 182 isVarNameSpace _       = False
 183
 184 isValNameSpace :: NameSpace -> Bool
 185 isValNameSpace DataName = True
 186 isValNameSpace VarName  = True
 187 isValNameSpace _        = False
 188
 189 pprNameSpace :: NameSpace -> SDoc
 190 pprNameSpace DataName  = ptext (sLit "data constructor")
 191 pprNameSpace VarName   = ptext (sLit "variable")
 192 pprNameSpace TvName    = ptext (sLit "type variable")
 193 pprNameSpace TcClsName = ptext (sLit "type constructor or class")
 194
 195 pprNonVarNameSpace :: NameSpace -> SDoc
 196 pprNonVarNameSpace VarName = empty
 197 pprNonVarNameSpace ns = pprNameSpace ns
 198
 199 pprNameSpaceBrief :: NameSpace -> SDoc
 200 pprNameSpaceBrief DataName  = char 'd'
 201 pprNameSpaceBrief VarName   = char 'v'
 202 pprNameSpaceBrief TvName    = ptext (sLit "tv")
 203 pprNameSpaceBrief TcClsName = ptext (sLit "tc")
 204 \end{code}
 205
 206
 207 %************************************************************************
 208 %*                                                                      *
 209 \subsection[Name-pieces-datatypes]{The @OccName@ datatypes}
 210 %*                                                                      *
 211 %************************************************************************
 212
 213 \begin{code}
 214 data OccName = OccName
 215     { occNameSpace  :: !NameSpace
 216     , occNameFS     :: !FastString
 217     }
 218 \end{code}
 219
 220
 221 \begin{code}
 222 instance Eq OccName where
 223     (OccName sp1 s1) == (OccName sp2 s2) = s1 == s2 && sp1 == sp2
 224
 225 instance Ord OccName where
 226         -- Compares lexicographically, *not* by Unique of the string
 227     compare (OccName sp1 s1) (OccName sp2 s2)
 228         = (s1  `compare` s2) `thenCmp` (sp1 `compare` sp2)
 229 \end{code}
 230
 231
 232 %************************************************************************
 233 %*                                                                      *
 234 \subsection{Printing}
 235 %*                                                                      *
 236 %************************************************************************
 237
 238 \begin{code}
 239 instance Outputable OccName where
 240     ppr = pprOccName
 241
 242 pprOccName :: OccName -> SDoc
 243 pprOccName (OccName sp occ)
 244   = getPprStyle $ \ sty ->
 245     if codeStyle sty
 246         then ftext (zEncodeFS occ)
 247         else ftext occ <> if debugStyle sty
 248                             then braces (pprNameSpaceBrief sp)
 249                             else empty
 250 \end{code}
 251
 252
 253 %************************************************************************
 254 %*                                                                      *
 255 \subsection{Construction}
 256 %*                                                                      *
 257 %************************************************************************
 258
 259 \begin{code}
 260 mkOccName :: NameSpace -> String -> OccName
 261 mkOccName occ_sp str = OccName occ_sp (mkFastString str)
 262
 263 mkOccNameFS :: NameSpace -> FastString -> OccName
 264 mkOccNameFS occ_sp fs = OccName occ_sp fs
 265
 266 mkVarOcc :: String -> OccName
 267 mkVarOcc s = mkOccName varName s
 268
 269 mkVarOccFS :: FastString -> OccName
 270 mkVarOccFS fs = mkOccNameFS varName fs
 271
 272 mkDataOcc :: String -> OccName
 273 mkDataOcc = mkOccName dataName
 274
 275 mkDataOccFS :: FastString -> OccName
 276 mkDataOccFS = mkOccNameFS dataName
 277
 278 mkTyVarOcc :: String -> OccName
 279 mkTyVarOcc = mkOccName tvName
 280
 281 mkTyVarOccFS :: FastString -> OccName
 282 mkTyVarOccFS fs = mkOccNameFS tvName fs
 283
 284 mkTcOcc :: String -> OccName
 285 mkTcOcc = mkOccName tcName
 286
 287 mkTcOccFS :: FastString -> OccName
 288 mkTcOccFS = mkOccNameFS tcName
 289
 290 mkClsOcc :: String -> OccName
 291 mkClsOcc = mkOccName clsName
 292
 293 mkClsOccFS :: FastString -> OccName
 294 mkClsOccFS = mkOccNameFS clsName
 295 \end{code}
 296
 297
 298 %************************************************************************
 299 %*                                                                      *
 300                 Environments
 301 %*                                                                      *
 302 %************************************************************************
 303
 304 OccEnvs are used mainly for the envts in ModIfaces.
 305
 306 Note [The Unique of an OccName]
 307 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 308 They are efficient, because FastStrings have unique Int# keys.  We assume
 309 this key is less than 2^24, and indeed FastStrings are allocated keys
 310 sequentially starting at 0.
 311
 312 So we can make a Unique using
 313         mkUnique ns key  :: Unique
 314 where 'ns' is a Char reprsenting the name space.  This in turn makes it
 315 easy to build an OccEnv.
 316
 317 \begin{code}
 318 instance Uniquable OccName where
 319       -- See Note [The Unique of an OccName]
 320   getUnique (OccName VarName   fs) = mkVarOccUnique  fs
 321   getUnique (OccName DataName  fs) = mkDataOccUnique fs
 322   getUnique (OccName TvName    fs) = mkTvOccUnique   fs
 323   getUnique (OccName TcClsName fs) = mkTcOccUnique   fs
 324
 325 newtype OccEnv a = A (UniqFM a)
 326
 327 emptyOccEnv :: OccEnv a
 328 unitOccEnv  :: OccName -> a -> OccEnv a
 329 extendOccEnv :: OccEnv a -> OccName -> a -> OccEnv a
 330 extendOccEnvList :: OccEnv a -> [(OccName, a)] -> OccEnv a
 331 lookupOccEnv :: OccEnv a -> OccName -> Maybe a
 332 mkOccEnv     :: [(OccName,a)] -> OccEnv a
 333 mkOccEnv_C   :: (a -> a -> a) -> [(OccName,a)] -> OccEnv a
 334 elemOccEnv   :: OccName -> OccEnv a -> Bool
 335 foldOccEnv   :: (a -> b -> b) -> b -> OccEnv a -> b
 336 occEnvElts   :: OccEnv a -> [a]
 337 extendOccEnv_C :: (a->a->a) -> OccEnv a -> OccName -> a -> OccEnv a
 338 plusOccEnv     :: OccEnv a -> OccEnv a -> OccEnv a
 339 plusOccEnv_C   :: (a->a->a) -> OccEnv a -> OccEnv a -> OccEnv a
 340 mapOccEnv      :: (a->b) -> OccEnv a -> OccEnv b
 341 delFromOccEnv      :: OccEnv a -> OccName -> OccEnv a
 342 delListFromOccEnv :: OccEnv a -> [OccName] -> OccEnv a
 343 filterOccEnv       :: (elt -> Bool) -> OccEnv elt -> OccEnv elt
 344
 345 emptyOccEnv      = A emptyUFM
 346 unitOccEnv x y = A $ unitUFM x y
 347 extendOccEnv (A x) y z = A $ addToUFM x y z
 348 extendOccEnvList (A x) l = A $ addListToUFM x l
 349 lookupOccEnv (A x) y = lookupUFM x y
 350 mkOccEnv     l    = A $ listToUFM l
 351 elemOccEnv x (A y)       = elemUFM x y
 352 foldOccEnv a b (A c)     = foldUFM a b c
 353 occEnvElts (A x)         = eltsUFM x
 354 plusOccEnv (A x) (A y)   = A $ plusUFM x y
 355 plusOccEnv_C f (A x) (A y)       = A $ plusUFM_C f x y
 356 extendOccEnv_C f (A x) y z   = A $ addToUFM_C f x y z
 357 mapOccEnv f (A x)        = A $ mapUFM f x
 358 mkOccEnv_C comb l = A $ addListToUFM_C comb emptyUFM l
 359 delFromOccEnv (A x) y    = A $ delFromUFM x y
 360 delListFromOccEnv (A x) y  = A $ delListFromUFM x y
 361 filterOccEnv x (A y)       = A $ filterUFM x y
 362
 363 instance Outputable a => Outputable (OccEnv a) where
 364     ppr (A x) = ppr x
 365
 366 type OccSet = UniqSet OccName
 367
 368 emptyOccSet       :: OccSet
 369 unitOccSet        :: OccName -> OccSet
 370 mkOccSet          :: [OccName] -> OccSet
 371 extendOccSet      :: OccSet -> OccName -> OccSet
 372 extendOccSetList  :: OccSet -> [OccName] -> OccSet
 373 unionOccSets      :: OccSet -> OccSet -> OccSet
 374 unionManyOccSets  :: [OccSet] -> OccSet
 375 minusOccSet       :: OccSet -> OccSet -> OccSet
 376 elemOccSet        :: OccName -> OccSet -> Bool
 377 occSetElts        :: OccSet -> [OccName]
 378 foldOccSet        :: (OccName -> b -> b) -> b -> OccSet -> b
 379 isEmptyOccSet     :: OccSet -> Bool
 380 intersectOccSet   :: OccSet -> OccSet -> OccSet
 381 intersectsOccSet  :: OccSet -> OccSet -> Bool
 382
 383 emptyOccSet       = emptyUniqSet
 384 unitOccSet        = unitUniqSet
 385 mkOccSet          = mkUniqSet
 386 extendOccSet      = addOneToUniqSet
 387 extendOccSetList  = addListToUniqSet
 388 unionOccSets      = unionUniqSets
 389 unionManyOccSets  = unionManyUniqSets
 390 minusOccSet       = minusUniqSet
 391 elemOccSet        = elementOfUniqSet
 392 occSetElts        = uniqSetToList
 393 foldOccSet        = foldUniqSet
 394 isEmptyOccSet     = isEmptyUniqSet
 395 intersectOccSet   = intersectUniqSets
 396 intersectsOccSet s1 s2 = not (isEmptyOccSet (s1 `intersectOccSet` s2))
 397 \end{code}
 398
 399
 400 %************************************************************************
 401 %*                                                                      *
 402 \subsection{Predicates and taking them apart}
 403 %*                                                                      *
 404 %************************************************************************
 405
 406 \begin{code}
 407 occNameString :: OccName -> String
 408 occNameString (OccName _ s) = unpackFS s
 409
 410 setOccNameSpace :: NameSpace -> OccName -> OccName
 411 setOccNameSpace sp (OccName _ occ) = OccName sp occ
 412
 413 isVarOcc, isTvOcc, isTcOcc, isDataOcc :: OccName -> Bool
 414
 415 isVarOcc (OccName VarName _) = True
 416 isVarOcc _                   = False
 417
 418 isTvOcc (OccName TvName _) = True
 419 isTvOcc _                  = False
 420
 421 isTcOcc (OccName TcClsName _) = True
 422 isTcOcc _                     = False
 423
 424 -- | /Value/ 'OccNames's are those that are either in
 425 -- the variable or data constructor namespaces
 426 isValOcc :: OccName -> Bool
 427 isValOcc (OccName VarName  _) = True
 428 isValOcc (OccName DataName _) = True
 429 isValOcc _                    = False
 430
 431 isDataOcc (OccName DataName _) = True
 432 isDataOcc (OccName VarName s)
 433   | isLexCon s = pprPanic "isDataOcc: check me" (ppr s)
 434                 -- Jan06: I don't think this should happen
 435 isDataOcc _                    = False
 436
 437 -- | Test if the 'OccName' is a data constructor that starts with
 438 -- a symbol (e.g. @:@, or @[]@)
 439 isDataSymOcc :: OccName -> Bool
 440 isDataSymOcc (OccName DataName s) = isLexConSym s
 441 isDataSymOcc (OccName VarName s)
 442   | isLexConSym s = pprPanic "isDataSymOcc: check me" (ppr s)
 443                 -- Jan06: I don't think this should happen
 444 isDataSymOcc _                    = False
 445 -- Pretty inefficient!
 446
 447 -- | Test if the 'OccName' is that for any operator (whether
 448 -- it is a data constructor or variable or whatever)
 449 isSymOcc :: OccName -> Bool
 450 isSymOcc (OccName DataName s)  = isLexConSym s
 451 isSymOcc (OccName TcClsName s) = isLexConSym s
 452 isSymOcc (OccName VarName s)   = isLexSym s
 453 isSymOcc (OccName TvName s)    = isLexSym s
 454 -- Pretty inefficient!
 455
 456 parenSymOcc :: OccName -> SDoc -> SDoc
 457 -- ^ Wrap parens around an operator
 458 parenSymOcc occ doc | isSymOcc occ = parens doc
 459                     | otherwise    = doc
 460 \end{code}
 461
 462
 463 \begin{code}
 464 startsWithUnderscore :: OccName -> Bool
 465 -- ^ Haskell 98 encourages compilers to suppress warnings about unsed
 466 -- names in a pattern if they start with @_@: this implements that test
 467 startsWithUnderscore occ = case occNameString occ of
 468                              ('_' : _) -> True
 469                              _other    -> False
 470 \end{code}
 471
 472
 473 %************************************************************************
 474 %*                                                                      *
 475 \subsection{Making system names}
 476 %*                                                                      *
 477 %************************************************************************
 478
 479 Here's our convention for splitting up the interface file name space:
 480
 481    d...         dictionary identifiers
 482                 (local variables, so no name-clash worries)
 483
 484 All of these other OccNames contain a mixture of alphabetic
 485 and symbolic characters, and hence cannot possibly clash with
 486 a user-written type or function name
 487
 488    $f...        Dict-fun identifiers (from inst decls)
 489    $dmop        Default method for 'op'
 490    $pnC         n'th superclass selector for class C
 491    $wf          Worker for functtoin 'f'
 492    $sf..        Specialised version of f
 493    T:C          Tycon for dictionary for class C
 494    D:C          Data constructor for dictionary for class C
 495    NTCo:T       Coercion connecting newtype T with its representation type
 496    TFCo:R       Coercion connecting a data family to its respresentation type R
 497
 498 In encoded form these appear as Zdfxxx etc
 499
 500         :...            keywords (export:, letrec: etc.)
 501 --- I THINK THIS IS WRONG!
 502
 503 This knowledge is encoded in the following functions.
 504
 505 @mk_deriv@ generates an @OccName@ from the prefix and a string.
 506 NB: The string must already be encoded!
 507
 508 \begin{code}
 509 mk_deriv :: NameSpace
 510          -> String              -- Distinguishes one sort of derived name from another
 511          -> String
 512          -> OccName
 513
 514 mk_deriv occ_sp sys_prefix str = mkOccName occ_sp (sys_prefix ++ str)
 515
 516 isDerivedOccName :: OccName -> Bool
 517 isDerivedOccName occ =
 518    case occNameString occ of
 519      '$':c:_ | isAlphaNum c -> True
 520      ':':c:_ | isAlphaNum c -> True
 521      _other                 -> False
 522 \end{code}
 523
 524 \begin{code}
 525 mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc, mkDerivedTyConOcc,
 526         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
 527         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
 528         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc, mkNewTyCoOcc,
 529         mkInstTyCoOcc, mkEqPredCoOcc,
 530         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
 531         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
 532         mkPDataTyConOcc, mkPDataDataConOcc, mkPReprTyConOcc, mkPADFunOcc
 533    :: OccName -> OccName
 534
 535 -- These derived variables have a prefix that no Haskell value could have
 536 mkDataConWrapperOcc = mk_simple_deriv varName  "$W"
 537 mkWorkerOcc         = mk_simple_deriv varName  "$w"
 538 mkDefaultMethodOcc  = mk_simple_deriv varName  "$dm"
 539 mkDerivedTyConOcc   = mk_simple_deriv tcName   ":"      -- The : prefix makes sure it classifies
 540 mkClassTyConOcc     = mk_simple_deriv tcName   "T:"     -- as a tycon/datacon
 541 mkClassDataConOcc   = mk_simple_deriv dataName "D:"     -- We go straight to the "real" data con
 542                                                         -- for datacons from classes
 543 mkDictOcc           = mk_simple_deriv varName  "$d"
 544 mkIPOcc             = mk_simple_deriv varName  "$i"
 545 mkSpecOcc           = mk_simple_deriv varName  "$s"
 546 mkForeignExportOcc  = mk_simple_deriv varName  "$f"
 547 mkNewTyCoOcc        = mk_simple_deriv tcName  "NTCo:"   -- Coercion for newtypes
 548 mkInstTyCoOcc       = mk_simple_deriv tcName  "TFCo:"   -- Coercion for type functions
 549 mkEqPredCoOcc       = mk_simple_deriv tcName  "$co"
 550
 551 -- used in derived instances
 552 mkCon2TagOcc        = mk_simple_deriv varName  "$con2tag_"
 553 mkTag2ConOcc        = mk_simple_deriv varName  "$tag2con_"
 554 mkMaxTagOcc         = mk_simple_deriv varName  "$maxtag_"
 555
 556 -- Generic derivable classes
 557 mkGenOcc1           = mk_simple_deriv varName  "$gfrom"
 558 mkGenOcc2           = mk_simple_deriv varName  "$gto"
 559
 560 -- data T = MkT ... deriving( Data ) needs defintions for
 561 --      $tT   :: Data.Generics.Basics.DataType
 562 --      $cMkT :: Data.Generics.Basics.Constr
 563 mkDataTOcc = mk_simple_deriv varName  "$t"
 564 mkDataCOcc = mk_simple_deriv varName  "$c"
 565
 566 -- Vectorisation
 567 mkVectOcc          = mk_simple_deriv varName  "$v_"
 568 mkVectTyConOcc     = mk_simple_deriv tcName   ":V_"
 569 mkVectDataConOcc   = mk_simple_deriv dataName ":VD_"
 570 mkVectIsoOcc       = mk_simple_deriv varName  "$VI_"
 571 mkPDataTyConOcc    = mk_simple_deriv tcName   ":VP_"
 572 mkPDataDataConOcc  = mk_simple_deriv dataName ":VPD_"
 573 mkPReprTyConOcc    = mk_simple_deriv tcName   ":VR_"
 574 mkPADFunOcc        = mk_simple_deriv varName  "$PA_"
 575
 576 mk_simple_deriv :: NameSpace -> String -> OccName -> OccName
 577 mk_simple_deriv sp px occ = mk_deriv sp px (occNameString occ)
 578
 579 -- Data constructor workers are made by setting the name space
 580 -- of the data constructor OccName (which should be a DataName)
 581 -- to VarName
 582 mkDataConWorkerOcc datacon_occ = setOccNameSpace varName datacon_occ
 583 \end{code}
 584
 585 \begin{code}
 586 mkSuperDictSelOcc :: Int        -- ^ Index of superclass, e.g. 3
 587                   -> OccName    -- ^ Class, e.g. @Ord@
 588                   -> OccName    -- ^ Derived 'Occname', e.g. @$p3Ord@
 589 mkSuperDictSelOcc index cls_occ
 590   = mk_deriv varName "$p" (show index ++ occNameString cls_occ)
 591
 592 mkLocalOcc :: Unique            -- ^ Unique to combine with the 'OccName'
 593            -> OccName           -- ^ Local name, e.g. @sat@
 594            -> OccName           -- ^ Nice unique version, e.g. @$L23sat@
 595 mkLocalOcc uniq occ
 596    = mk_deriv varName ("$L" ++ show uniq) (occNameString occ)
 597         -- The Unique might print with characters
 598         -- that need encoding (e.g. 'z'!)
 599 \end{code}
 600
 601 \begin{code}
 602 -- | Derive a name for the representation type constructor of a
 603 -- @data@\/@newtype@ instance.
 604 mkInstTyTcOcc :: String                 -- ^ Family name, e.g. @Map@
 605               -> OccSet                 -- ^ avoid these Occs
 606               -> OccName                -- ^ @R:Map@
 607 mkInstTyTcOcc str set =
 608   chooseUniqueOcc tcName ('R' : ':' : str) set
 609 \end{code}
 610
 611 \begin{code}
 612 mkDFunOcc :: String             -- ^ Typically the class and type glommed together e.g. @OrdMaybe@.
 613                                 -- Only used in debug mode, for extra clarity
 614           -> Bool               -- ^ Is this a hs-boot instance DFun?
 615           -> OccSet             -- ^ avoid these Occs
 616           -> OccName            -- ^ E.g. @$f3OrdMaybe@
 617
 618 -- In hs-boot files we make dict funs like $fx7ClsTy, which get bound to the real
 619 -- thing when we compile the mother module. Reason: we don't know exactly
 620 -- what the  mother module will call it.
 621
 622 mkDFunOcc info_str is_boot set
 623   = chooseUniqueOcc VarName (prefix ++ info_str) set
 624   where
 625     prefix | is_boot   = "$fx"
 626            | otherwise = "$f"
 627 \end{code}
 628
 629 Sometimes we need to pick an OccName that has not already been used,
 630 given a set of in-use OccNames.
 631
 632 \begin{code}
 633 chooseUniqueOcc :: NameSpace -> String -> OccSet -> OccName
 634 chooseUniqueOcc ns str set = loop (mkOccName ns str) (0::Int)
 635   where
 636   loop occ n
 637    | occ `elemOccSet` set = loop (mkOccName ns (str ++ show n)) (n+1)
 638    | otherwise            = occ
 639 \end{code}
 640
 641 We used to add a '$m' to indicate a method, but that gives rise to bad
 642 error messages from the type checker when we print the function name or pattern
 643 of an instance-decl binding.  Why? Because the binding is zapped
 644 to use the method name in place of the selector name.
 645 (See TcClassDcl.tcMethodBind)
 646
 647 The way it is now, -ddump-xx output may look confusing, but
 648 you can always say -dppr-debug to get the uniques.
 649
 650 However, we *do* have to zap the first character to be lower case,
 651 because overloaded constructors (blarg) generate methods too.
 652 And convert to VarName space
 653
 654 e.g. a call to constructor MkFoo where
 655         data (Ord a) => Foo a = MkFoo a
 656
 657 If this is necessary, we do it by prefixing '$m'.  These
 658 guys never show up in error messages.  What a hack.
 659
 660 \begin{code}
 661 mkMethodOcc :: OccName -> OccName
 662 mkMethodOcc occ@(OccName VarName _) = occ
 663 mkMethodOcc occ                     = mk_simple_deriv varName "$m" occ
 664 \end{code}
 665
 666
 667 %************************************************************************
 668 %*                                                                      *
 669 \subsection{Tidying them up}
 670 %*                                                                      *
 671 %************************************************************************
 672
 673 Before we print chunks of code we like to rename it so that
 674 we don't have to print lots of silly uniques in it.  But we mustn't
 675 accidentally introduce name clashes!  So the idea is that we leave the
 676 OccName alone unless it accidentally clashes with one that is already
 677 in scope; if so, we tack on '1' at the end and try again, then '2', and
 678 so on till we find a unique one.
 679
 680 There's a wrinkle for operators.  Consider '>>='.  We can't use '>>=1'
 681 because that isn't a single lexeme.  So we encode it to 'lle' and *then*
 682 tack on the '1', if necessary.
 683
 684 \begin{code}
 685 type TidyOccEnv = OccEnv Int    -- The in-scope OccNames
 686         -- Range gives a plausible starting point for new guesses
 687
 688 emptyTidyOccEnv :: TidyOccEnv
 689 emptyTidyOccEnv = emptyOccEnv
 690
 691 initTidyOccEnv :: [OccName] -> TidyOccEnv       -- Initialise with names to avoid!
 692 initTidyOccEnv = foldl (\env occ -> extendOccEnv env occ 1) emptyTidyOccEnv
 693
 694 tidyOccName :: TidyOccEnv -> OccName -> (TidyOccEnv, OccName)
 695
 696 tidyOccName in_scope occ@(OccName occ_sp fs)
 697   = case lookupOccEnv in_scope occ of
 698         Nothing ->      -- Not already used: make it used
 699                    (extendOccEnv in_scope occ 1, occ)
 700
 701         Just n  ->      -- Already used: make a new guess,
 702                         -- change the guess base, and try again
 703                    tidyOccName  (extendOccEnv in_scope occ (n+1))
 704                                 (mkOccName occ_sp (unpackFS fs ++ show n))
 705 \end{code}
 706
 707 %************************************************************************
 708 %*                                                                      *
 709                 Stuff for dealing with tuples
 710 %*                                                                      *
 711 %************************************************************************
 712
 713 \begin{code}
 714 mkTupleOcc :: NameSpace -> Boxity -> Arity -> OccName
 715 mkTupleOcc ns bx ar = OccName ns (mkFastString str)
 716   where
 717         -- no need to cache these, the caching is done in the caller
 718         -- (TysWiredIn.mk_tuple)
 719     str = case bx of
 720                 Boxed   -> '(' : commas ++ ")"
 721                 Unboxed -> '(' : '#' : commas ++ "#)"
 722
 723     commas = take (ar-1) (repeat ',')
 724
 725 isTupleOcc_maybe :: OccName -> Maybe (NameSpace, Boxity, Arity)
 726 -- Tuples are special, because there are so many of them!
 727 isTupleOcc_maybe (OccName ns fs)
 728   = case unpackFS fs of
 729         '(':'#':',':rest -> Just (ns, Unboxed, 2 + count_commas rest)
 730         '(':',':rest     -> Just (ns, Boxed,   2 + count_commas rest)
 731         _other           -> Nothing
 732   where
 733     count_commas (',':rest) = 1 + count_commas rest
 734     count_commas _          = 0
 735 \end{code}
 736
 737 %************************************************************************
 738 %*                                                                      *
 739 \subsection{Lexical categories}
 740 %*                                                                      *
 741 %************************************************************************
 742
 743 These functions test strings to see if they fit the lexical categories
 744 defined in the Haskell report.
 745
 746 \begin{code}
 747 isLexCon,   isLexVar,    isLexId,    isLexSym    :: FastString -> Bool
 748 isLexConId, isLexConSym, isLexVarId, isLexVarSym :: FastString -> Bool
 749
 750 isLexCon cs = isLexConId  cs || isLexConSym cs
 751 isLexVar cs = isLexVarId  cs || isLexVarSym cs
 752
 753 isLexId  cs = isLexConId  cs || isLexVarId  cs
 754 isLexSym cs = isLexConSym cs || isLexVarSym cs
 755
 756 -------------
 757
 758 isLexConId cs                           -- Prefix type or data constructors
 759   | nullFS cs          = False          --      e.g. "Foo", "[]", "(,)"
 760   | cs == (fsLit "[]") = True
 761   | otherwise          = startsConId (headFS cs)
 762
 763 isLexVarId cs                           -- Ordinary prefix identifiers
 764   | nullFS cs         = False           --      e.g. "x", "_x"
 765   | otherwise         = startsVarId (headFS cs)
 766
 767 isLexConSym cs                          -- Infix type or data constructors
 768   | nullFS cs          = False          --      e.g. ":-:", ":", "->"
 769   | cs == (fsLit "->") = True
 770   | otherwise          = startsConSym (headFS cs)
 771
 772 isLexVarSym cs                          -- Infix identifiers
 773   | nullFS cs         = False           --      e.g. "+"
 774   | otherwise         = startsVarSym (headFS cs)
 775
 776 -------------
 777 startsVarSym, startsVarId, startsConSym, startsConId :: Char -> Bool
 778 startsVarSym c = isSymbolASCII c || (ord c > 0x7f && isSymbol c) -- Infix Ids
 779 startsConSym c = c == ':'                               -- Infix data constructors
 780 startsVarId c  = isLower c || c == '_'  -- Ordinary Ids
 781 startsConId c  = isUpper c || c == '('  -- Ordinary type constructors and data constructors
 782
 783 isSymbolASCII :: Char -> Bool
 784 isSymbolASCII c = c `elem` "!#$%&*+./<=>?@\\^|~-"
 785 \end{code}
 786
 787 %************************************************************************
 788 %*                                                                      *
 789                 Binary instance
 790     Here rather than BinIface because OccName is abstract
 791 %*                                                                      *
 792 %************************************************************************
 793
 794 \begin{code}
 795 instance Binary NameSpace where
 796     put_ bh VarName = do
 797             putByte bh 0
 798     put_ bh DataName = do
 799             putByte bh 1
 800     put_ bh TvName = do
 801             putByte bh 2
 802     put_ bh TcClsName = do
 803             putByte bh 3
 804     get bh = do
 805             h <- getByte bh
 806             case h of
 807               0 -> do return VarName
 808               1 -> do return DataName
 809               2 -> do return TvName
 810               _ -> do return TcClsName
 811
 812 instance Binary OccName where
 813     put_ bh (OccName aa ab) = do
 814             put_ bh aa
 815             put_ bh ab
 816     get bh = do
 817           aa <- get bh
 818           ab <- get bh
 819           return (OccName aa ab)
 820 \end{code}