compiler/basicTypes/OccName.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 -- |
   8 -- #name_types#
   9 -- GHC uses several kinds of name internally:
  10 --
  11 -- * 'OccName.OccName' represents names as strings with just a little more information:
  12 --   the \"namespace\" that the name came from, e.g. the namespace of value, type constructors or
  13 --   data constructors
  14 --
  15 -- * 'RdrName.RdrName': see "RdrName#name_types"
  16 --
  17 -- * 'Name.Name': see "Name#name_types"
  18 --
  19 -- * 'Id.Id': see "Id#name_types"
  20 --
  21 -- * 'Var.Var': see "Var#name_types"
  22 module OccName (
  23         -- * The 'NameSpace' type
  24         NameSpace, -- Abstract
  25
  26         -- ** Construction
  27         -- $real_vs_source_data_constructors
  28         tcName, clsName, tcClsName, dataName, varName,
  29         tvName, srcDataName,
  30
  31         -- ** Pretty Printing
  32         pprNameSpace, pprNonVarNameSpace, pprNameSpaceBrief,
  33
  34         -- * The 'OccName' type
  35         OccName,        -- Abstract, instance of Outputable
  36         pprOccName,
  37
  38         -- ** Construction
  39         mkOccName, mkOccNameFS,
  40         mkVarOcc, mkVarOccFS,
  41         mkDataOcc, mkDataOccFS,
  42         mkTyVarOcc, mkTyVarOccFS,
  43         mkTcOcc, mkTcOccFS,
  44         mkClsOcc, mkClsOccFS,
  45         mkDFunOcc,
  46         mkTupleOcc,
  47         setOccNameSpace,
  48
  49         -- ** Derived 'OccName's
  50         isDerivedOccName,
  51         mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc, mkGenDefMethodOcc,
  52         mkDerivedTyConOcc, mkNewTyCoOcc, mkClassOpAuxOcc,
  53         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
  54         mkClassTyConOcc, mkClassDataConOcc, mkDictOcc, mkIPOcc,
  55         mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
  56         mkGenD, mkGenR0, mkGenR0Co, mkGenC, mkGenS,
  57         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc,
  58         mkSuperDictSelOcc, mkLocalOcc, mkMethodOcc, mkInstTyTcOcc,
  59         mkInstTyCoOcc, mkEqPredCoOcc,
  60         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
  61         mkPDataTyConOcc, mkPDataDataConOcc,
  62         mkPReprTyConOcc,
  63         mkPADFunOcc,
  64
  65         -- ** Deconstruction
  66         occNameFS, occNameString, occNameSpace,
  67
  68         isVarOcc, isTvOcc, isTcOcc, isDataOcc, isDataSymOcc, isSymOcc, isValOcc,
  69         parenSymOcc, startsWithUnderscore,
  70
  71         isTcClsNameSpace, isTvNameSpace, isDataConNameSpace, isVarNameSpace, isValNameSpace,
  72
  73         isTupleOcc_maybe,
  74
  75         -- * The 'OccEnv' type
  76         OccEnv, emptyOccEnv, unitOccEnv, extendOccEnv, mapOccEnv,
  77         lookupOccEnv, mkOccEnv, mkOccEnv_C, extendOccEnvList, elemOccEnv,
  78         occEnvElts, foldOccEnv, plusOccEnv, plusOccEnv_C, extendOccEnv_C,
  79         extendOccEnv_Acc, filterOccEnv, delListFromOccEnv, delFromOccEnv,
  80
  81         -- * The 'OccSet' type
  82         OccSet, emptyOccSet, unitOccSet, mkOccSet, extendOccSet,
  83         extendOccSetList,
  84         unionOccSets, unionManyOccSets, minusOccSet, elemOccSet, occSetElts,
  85         foldOccSet, isEmptyOccSet, intersectOccSet, intersectsOccSet,
  86
  87         -- * Tidying up
  88         TidyOccEnv, emptyTidyOccEnv, tidyOccName, initTidyOccEnv,
  89
  90         -- * Lexical characteristics of Haskell names
  91         isLexCon, isLexVar, isLexId, isLexSym,
  92         isLexConId, isLexConSym, isLexVarId, isLexVarSym,
  93         startsVarSym, startsVarId, startsConSym, startsConId
  94     ) where
  95
  96 #include "Typeable.h"
  97
  98 import Util
  99 import Unique
 100 import BasicTypes
 101 import UniqFM
 102 import UniqSet
 103 import FastString
 104 import Outputable
 105 import Binary
 106 import StaticFlags( opt_SuppressUniques )
 107 import Data.Char
 108 import Data.Data
 109 \end{code}
 110
 111 %************************************************************************
 112 %*                                                                      *
 113 \subsection{Name space}
 114 %*                                                                      *
 115 %************************************************************************
 116
 117 \begin{code}
 118 data NameSpace = VarName        -- Variables, including "real" data constructors
 119                | DataName       -- "Source" data constructors
 120                | TvName         -- Type variables
 121                | TcClsName      -- Type constructors and classes; Haskell has them
 122                                 -- in the same name space for now.
 123                deriving( Eq, Ord )
 124    {-! derive: Binary !-}
 125
 126 -- Note [Data Constructors]
 127 -- see also: Note [Data Constructor Naming] in DataCon.lhs
 128 --
 129 -- $real_vs_source_data_constructors
 130 -- There are two forms of data constructor:
 131 --
 132 --      [Source data constructors] The data constructors mentioned in Haskell source code
 133 --
 134 --      [Real data constructors] The data constructors of the representation type, which may not be the same as the source type
 135 --
 136 -- For example:
 137 --
 138 -- > data T = T !(Int, Int)
 139 --
 140 -- The source datacon has type @(Int, Int) -> T@
 141 -- The real   datacon has type @Int -> Int -> T@
 142 --
 143 -- GHC chooses a representation based on the strictness etc.
 144
 145 tcName, clsName, tcClsName :: NameSpace
 146 dataName, srcDataName      :: NameSpace
 147 tvName, varName            :: NameSpace
 148
 149 -- Though type constructors and classes are in the same name space now,
 150 -- the NameSpace type is abstract, so we can easily separate them later
 151 tcName    = TcClsName           -- Type constructors
 152 clsName   = TcClsName           -- Classes
 153 tcClsName = TcClsName           -- Not sure which!
 154
 155 dataName    = DataName
 156 srcDataName = DataName  -- Haskell-source data constructors should be
 157                         -- in the Data name space
 158
 159 tvName      = TvName
 160 varName     = VarName
 161
 162 isDataConNameSpace :: NameSpace -> Bool
 163 isDataConNameSpace DataName = True
 164 isDataConNameSpace _        = False
 165
 166 isTcClsNameSpace :: NameSpace -> Bool
 167 isTcClsNameSpace TcClsName = True
 168 isTcClsNameSpace _         = False
 169
 170 isTvNameSpace :: NameSpace -> Bool
 171 isTvNameSpace TvName = True
 172 isTvNameSpace _      = False
 173
 174 isVarNameSpace :: NameSpace -> Bool     -- Variables or type variables, but not constructors
 175 isVarNameSpace TvName  = True
 176 isVarNameSpace VarName = True
 177 isVarNameSpace _       = False
 178
 179 isValNameSpace :: NameSpace -> Bool
 180 isValNameSpace DataName = True
 181 isValNameSpace VarName  = True
 182 isValNameSpace _        = False
 183
 184 pprNameSpace :: NameSpace -> SDoc
 185 pprNameSpace DataName  = ptext (sLit "data constructor")
 186 pprNameSpace VarName   = ptext (sLit "variable")
 187 pprNameSpace TvName    = ptext (sLit "type variable")
 188 pprNameSpace TcClsName = ptext (sLit "type constructor or class")
 189
 190 pprNonVarNameSpace :: NameSpace -> SDoc
 191 pprNonVarNameSpace VarName = empty
 192 pprNonVarNameSpace ns = pprNameSpace ns
 193
 194 pprNameSpaceBrief :: NameSpace -> SDoc
 195 pprNameSpaceBrief DataName  = char 'd'
 196 pprNameSpaceBrief VarName   = char 'v'
 197 pprNameSpaceBrief TvName    = ptext (sLit "tv")
 198 pprNameSpaceBrief TcClsName = ptext (sLit "tc")
 199 \end{code}
 200
 201
 202 %************************************************************************
 203 %*                                                                      *
 204 \subsection[Name-pieces-datatypes]{The @OccName@ datatypes}
 205 %*                                                                      *
 206 %************************************************************************
 207
 208 \begin{code}
 209 data OccName = OccName
 210     { occNameSpace  :: !NameSpace
 211     , occNameFS     :: !FastString
 212     }
 213 \end{code}
 214
 215
 216 \begin{code}
 217 instance Eq OccName where
 218     (OccName sp1 s1) == (OccName sp2 s2) = s1 == s2 && sp1 == sp2
 219
 220 instance Ord OccName where
 221         -- Compares lexicographically, *not* by Unique of the string
 222     compare (OccName sp1 s1) (OccName sp2 s2)
 223         = (s1  `compare` s2) `thenCmp` (sp1 `compare` sp2)
 224
 225 INSTANCE_TYPEABLE0(OccName,occNameTc,"OccName")
 226
 227 instance Data OccName where
 228   -- don't traverse?
 229   toConstr _   = abstractConstr "OccName"
 230   gunfold _ _  = error "gunfold"
 231   dataTypeOf _ = mkNoRepType "OccName"
 232 \end{code}
 233
 234
 235 %************************************************************************
 236 %*                                                                      *
 237 \subsection{Printing}
 238 %*                                                                      *
 239 %************************************************************************
 240
 241 \begin{code}
 242 instance Outputable OccName where
 243     ppr = pprOccName
 244
 245 pprOccName :: OccName -> SDoc
 246 pprOccName (OccName sp occ)
 247   = getPprStyle $ \ sty ->
 248     if codeStyle sty
 249     then ftext (zEncodeFS occ)
 250     else pp_occ <> pp_debug sty
 251   where
 252     pp_debug sty | debugStyle sty = braces (pprNameSpaceBrief sp)
 253                  | otherwise      = empty
 254
 255     pp_occ | opt_SuppressUniques = text (strip_th_unique (unpackFS occ))
 256            | otherwise           = ftext occ
 257
 258         -- See Note [Suppressing uniques in OccNames]
 259     strip_th_unique ('[' : c : _) | isAlphaNum c = []
 260     strip_th_unique (c : cs) = c : strip_th_unique cs
 261     strip_th_unique []       = []
 262 \end{code}
 263
 264 Note [Suppressing uniques in OccNames]
 265 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 266 This is a hack to de-wobblify the OccNames that contain uniques from
 267 Template Haskell that have been turned into a string in the OccName.
 268 See Note [Unique OccNames from Template Haskell] in Convert.hs
 269
 270 %************************************************************************
 271 %*                                                                      *
 272 \subsection{Construction}
 273 %*                                                                      *
 274 %************************************************************************
 275
 276 \begin{code}
 277 mkOccName :: NameSpace -> String -> OccName
 278 mkOccName occ_sp str = OccName occ_sp (mkFastString str)
 279
 280 mkOccNameFS :: NameSpace -> FastString -> OccName
 281 mkOccNameFS occ_sp fs = OccName occ_sp fs
 282
 283 mkVarOcc :: String -> OccName
 284 mkVarOcc s = mkOccName varName s
 285
 286 mkVarOccFS :: FastString -> OccName
 287 mkVarOccFS fs = mkOccNameFS varName fs
 288
 289 mkDataOcc :: String -> OccName
 290 mkDataOcc = mkOccName dataName
 291
 292 mkDataOccFS :: FastString -> OccName
 293 mkDataOccFS = mkOccNameFS dataName
 294
 295 mkTyVarOcc :: String -> OccName
 296 mkTyVarOcc = mkOccName tvName
 297
 298 mkTyVarOccFS :: FastString -> OccName
 299 mkTyVarOccFS fs = mkOccNameFS tvName fs
 300
 301 mkTcOcc :: String -> OccName
 302 mkTcOcc = mkOccName tcName
 303
 304 mkTcOccFS :: FastString -> OccName
 305 mkTcOccFS = mkOccNameFS tcName
 306
 307 mkClsOcc :: String -> OccName
 308 mkClsOcc = mkOccName clsName
 309
 310 mkClsOccFS :: FastString -> OccName
 311 mkClsOccFS = mkOccNameFS clsName
 312 \end{code}
 313
 314
 315 %************************************************************************
 316 %*                                                                      *
 317                 Environments
 318 %*                                                                      *
 319 %************************************************************************
 320
 321 OccEnvs are used mainly for the envts in ModIfaces.
 322
 323 Note [The Unique of an OccName]
 324 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 325 They are efficient, because FastStrings have unique Int# keys.  We assume
 326 this key is less than 2^24, and indeed FastStrings are allocated keys
 327 sequentially starting at 0.
 328
 329 So we can make a Unique using
 330         mkUnique ns key  :: Unique
 331 where 'ns' is a Char reprsenting the name space.  This in turn makes it
 332 easy to build an OccEnv.
 333
 334 \begin{code}
 335 instance Uniquable OccName where
 336       -- See Note [The Unique of an OccName]
 337   getUnique (OccName VarName   fs) = mkVarOccUnique  fs
 338   getUnique (OccName DataName  fs) = mkDataOccUnique fs
 339   getUnique (OccName TvName    fs) = mkTvOccUnique   fs
 340   getUnique (OccName TcClsName fs) = mkTcOccUnique   fs
 341
 342 newtype OccEnv a = A (UniqFM a)
 343
 344 emptyOccEnv :: OccEnv a
 345 unitOccEnv  :: OccName -> a -> OccEnv a
 346 extendOccEnv :: OccEnv a -> OccName -> a -> OccEnv a
 347 extendOccEnvList :: OccEnv a -> [(OccName, a)] -> OccEnv a
 348 lookupOccEnv :: OccEnv a -> OccName -> Maybe a
 349 mkOccEnv     :: [(OccName,a)] -> OccEnv a
 350 mkOccEnv_C   :: (a -> a -> a) -> [(OccName,a)] -> OccEnv a
 351 elemOccEnv   :: OccName -> OccEnv a -> Bool
 352 foldOccEnv   :: (a -> b -> b) -> b -> OccEnv a -> b
 353 occEnvElts   :: OccEnv a -> [a]
 354 extendOccEnv_C :: (a->a->a) -> OccEnv a -> OccName -> a -> OccEnv a
 355 extendOccEnv_Acc :: (a->b->b) -> (a->b) -> OccEnv b -> OccName -> a -> OccEnv b
 356 plusOccEnv     :: OccEnv a -> OccEnv a -> OccEnv a
 357 plusOccEnv_C   :: (a->a->a) -> OccEnv a -> OccEnv a -> OccEnv a
 358 mapOccEnv      :: (a->b) -> OccEnv a -> OccEnv b
 359 delFromOccEnv      :: OccEnv a -> OccName -> OccEnv a
 360 delListFromOccEnv :: OccEnv a -> [OccName] -> OccEnv a
 361 filterOccEnv       :: (elt -> Bool) -> OccEnv elt -> OccEnv elt
 362
 363 emptyOccEnv      = A emptyUFM
 364 unitOccEnv x y = A $ unitUFM x y
 365 extendOccEnv (A x) y z = A $ addToUFM x y z
 366 extendOccEnvList (A x) l = A $ addListToUFM x l
 367 lookupOccEnv (A x) y = lookupUFM x y
 368 mkOccEnv     l    = A $ listToUFM l
 369 elemOccEnv x (A y)       = elemUFM x y
 370 foldOccEnv a b (A c)     = foldUFM a b c
 371 occEnvElts (A x)         = eltsUFM x
 372 plusOccEnv (A x) (A y)   = A $ plusUFM x y
 373 plusOccEnv_C f (A x) (A y)       = A $ plusUFM_C f x y
 374 extendOccEnv_C f (A x) y z   = A $ addToUFM_C f x y z
 375 extendOccEnv_Acc f g (A x) y z   = A $ addToUFM_Acc f g x y z
 376 mapOccEnv f (A x)        = A $ mapUFM f x
 377 mkOccEnv_C comb l = A $ addListToUFM_C comb emptyUFM l
 378 delFromOccEnv (A x) y    = A $ delFromUFM x y
 379 delListFromOccEnv (A x) y  = A $ delListFromUFM x y
 380 filterOccEnv x (A y)       = A $ filterUFM x y
 381
 382 instance Outputable a => Outputable (OccEnv a) where
 383     ppr (A x) = ppr x
 384
 385 type OccSet = UniqSet OccName
 386
 387 emptyOccSet       :: OccSet
 388 unitOccSet        :: OccName -> OccSet
 389 mkOccSet          :: [OccName] -> OccSet
 390 extendOccSet      :: OccSet -> OccName -> OccSet
 391 extendOccSetList  :: OccSet -> [OccName] -> OccSet
 392 unionOccSets      :: OccSet -> OccSet -> OccSet
 393 unionManyOccSets  :: [OccSet] -> OccSet
 394 minusOccSet       :: OccSet -> OccSet -> OccSet
 395 elemOccSet        :: OccName -> OccSet -> Bool
 396 occSetElts        :: OccSet -> [OccName]
 397 foldOccSet        :: (OccName -> b -> b) -> b -> OccSet -> b
 398 isEmptyOccSet     :: OccSet -> Bool
 399 intersectOccSet   :: OccSet -> OccSet -> OccSet
 400 intersectsOccSet  :: OccSet -> OccSet -> Bool
 401
 402 emptyOccSet       = emptyUniqSet
 403 unitOccSet        = unitUniqSet
 404 mkOccSet          = mkUniqSet
 405 extendOccSet      = addOneToUniqSet
 406 extendOccSetList  = addListToUniqSet
 407 unionOccSets      = unionUniqSets
 408 unionManyOccSets  = unionManyUniqSets
 409 minusOccSet       = minusUniqSet
 410 elemOccSet        = elementOfUniqSet
 411 occSetElts        = uniqSetToList
 412 foldOccSet        = foldUniqSet
 413 isEmptyOccSet     = isEmptyUniqSet
 414 intersectOccSet   = intersectUniqSets
 415 intersectsOccSet s1 s2 = not (isEmptyOccSet (s1 `intersectOccSet` s2))
 416 \end{code}
 417
 418
 419 %************************************************************************
 420 %*                                                                      *
 421 \subsection{Predicates and taking them apart}
 422 %*                                                                      *
 423 %************************************************************************
 424
 425 \begin{code}
 426 occNameString :: OccName -> String
 427 occNameString (OccName _ s) = unpackFS s
 428
 429 setOccNameSpace :: NameSpace -> OccName -> OccName
 430 setOccNameSpace sp (OccName _ occ) = OccName sp occ
 431
 432 isVarOcc, isTvOcc, isTcOcc, isDataOcc :: OccName -> Bool
 433
 434 isVarOcc (OccName VarName _) = True
 435 isVarOcc _                   = False
 436
 437 isTvOcc (OccName TvName _) = True
 438 isTvOcc _                  = False
 439
 440 isTcOcc (OccName TcClsName _) = True
 441 isTcOcc _                     = False
 442
 443 -- | /Value/ 'OccNames's are those that are either in
 444 -- the variable or data constructor namespaces
 445 isValOcc :: OccName -> Bool
 446 isValOcc (OccName VarName  _) = True
 447 isValOcc (OccName DataName _) = True
 448 isValOcc _                    = False
 449
 450 isDataOcc (OccName DataName _) = True
 451 isDataOcc (OccName VarName s)
 452   | isLexCon s = pprPanic "isDataOcc: check me" (ppr s)
 453                 -- Jan06: I don't think this should happen
 454 isDataOcc _                    = False
 455
 456 -- | Test if the 'OccName' is a data constructor that starts with
 457 -- a symbol (e.g. @:@, or @[]@)
 458 isDataSymOcc :: OccName -> Bool
 459 isDataSymOcc (OccName DataName s) = isLexConSym s
 460 isDataSymOcc (OccName VarName s)
 461   | isLexConSym s = pprPanic "isDataSymOcc: check me" (ppr s)
 462                 -- Jan06: I don't think this should happen
 463 isDataSymOcc _                    = False
 464 -- Pretty inefficient!
 465
 466 -- | Test if the 'OccName' is that for any operator (whether
 467 -- it is a data constructor or variable or whatever)
 468 isSymOcc :: OccName -> Bool
 469 isSymOcc (OccName DataName s)  = isLexConSym s
 470 isSymOcc (OccName TcClsName s) = isLexConSym s
 471 isSymOcc (OccName VarName s)   = isLexSym s
 472 isSymOcc (OccName TvName s)    = isLexSym s
 473 -- Pretty inefficient!
 474
 475 parenSymOcc :: OccName -> SDoc -> SDoc
 476 -- ^ Wrap parens around an operator
 477 parenSymOcc occ doc | isSymOcc occ = parens doc
 478                     | otherwise    = doc
 479 \end{code}
 480
 481
 482 \begin{code}
 483 startsWithUnderscore :: OccName -> Bool
 484 -- ^ Haskell 98 encourages compilers to suppress warnings about unsed
 485 -- names in a pattern if they start with @_@: this implements that test
 486 startsWithUnderscore occ = case occNameString occ of
 487                              ('_' : _) -> True
 488                              _other    -> False
 489 \end{code}
 490
 491
 492 %************************************************************************
 493 %*                                                                      *
 494 \subsection{Making system names}
 495 %*                                                                      *
 496 %************************************************************************
 497
 498 Here's our convention for splitting up the interface file name space:
 499
 500    d...         dictionary identifiers
 501                 (local variables, so no name-clash worries)
 502
 503 All of these other OccNames contain a mixture of alphabetic
 504 and symbolic characters, and hence cannot possibly clash with
 505 a user-written type or function name
 506
 507    $f...        Dict-fun identifiers (from inst decls)
 508    $dmop        Default method for 'op'
 509    $pnC         n'th superclass selector for class C
 510    $wf          Worker for functtoin 'f'
 511    $sf..        Specialised version of f
 512    T:C          Tycon for dictionary for class C
 513    D:C          Data constructor for dictionary for class C
 514    NTCo:T       Coercion connecting newtype T with its representation type
 515    TFCo:R       Coercion connecting a data family to its respresentation type R
 516
 517 In encoded form these appear as Zdfxxx etc
 518
 519         :...            keywords (export:, letrec: etc.)
 520 --- I THINK THIS IS WRONG!
 521
 522 This knowledge is encoded in the following functions.
 523
 524 @mk_deriv@ generates an @OccName@ from the prefix and a string.
 525 NB: The string must already be encoded!
 526
 527 \begin{code}
 528 mk_deriv :: NameSpace
 529          -> String              -- Distinguishes one sort of derived name from another
 530          -> String
 531          -> OccName
 532
 533 mk_deriv occ_sp sys_prefix str = mkOccName occ_sp (sys_prefix ++ str)
 534
 535 isDerivedOccName :: OccName -> Bool
 536 isDerivedOccName occ =
 537    case occNameString occ of
 538      '$':c:_ | isAlphaNum c -> True
 539      ':':c:_ | isAlphaNum c -> True
 540      _other                 -> False
 541 \end{code}
 542
 543 \begin{code}
 544 mkDataConWrapperOcc, mkWorkerOcc, mkDefaultMethodOcc, mkGenDefMethodOcc,
 545         mkDerivedTyConOcc, mkClassTyConOcc, mkClassDataConOcc, mkDictOcc,
 546         mkIPOcc, mkSpecOcc, mkForeignExportOcc, mkGenOcc1, mkGenOcc2,
 547         mkGenD, mkGenR0, mkGenR0Co,
 548         mkDataTOcc, mkDataCOcc, mkDataConWorkerOcc, mkNewTyCoOcc,
 549         mkInstTyCoOcc, mkEqPredCoOcc, mkClassOpAuxOcc,
 550         mkCon2TagOcc, mkTag2ConOcc, mkMaxTagOcc,
 551         mkVectOcc, mkVectTyConOcc, mkVectDataConOcc, mkVectIsoOcc,
 552         mkPDataTyConOcc, mkPDataDataConOcc, mkPReprTyConOcc, mkPADFunOcc
 553    :: OccName -> OccName
 554
 555 -- These derived variables have a prefix that no Haskell value could have
 556 mkDataConWrapperOcc = mk_simple_deriv varName  "$W"
 557 mkWorkerOcc         = mk_simple_deriv varName  "$w"
 558 mkDefaultMethodOcc  = mk_simple_deriv varName  "$dm"
 559 mkGenDefMethodOcc   = mk_simple_deriv varName  "$gdm"
 560 mkClassOpAuxOcc     = mk_simple_deriv varName  "$c"
 561 mkDerivedTyConOcc   = mk_simple_deriv tcName   ":"      -- The : prefix makes sure it classifies
 562 mkClassTyConOcc     = mk_simple_deriv tcName   "T:"     -- as a tycon/datacon
 563 mkClassDataConOcc   = mk_simple_deriv dataName "D:"     -- We go straight to the "real" data con
 564                                                         -- for datacons from classes
 565 mkDictOcc           = mk_simple_deriv varName  "$d"
 566 mkIPOcc             = mk_simple_deriv varName  "$i"
 567 mkSpecOcc           = mk_simple_deriv varName  "$s"
 568 mkForeignExportOcc  = mk_simple_deriv varName  "$f"
 569 mkNewTyCoOcc        = mk_simple_deriv tcName   "NTCo:"  -- Coercion for newtypes
 570 mkInstTyCoOcc       = mk_simple_deriv tcName   "TFCo:"   -- Coercion for type functions
 571 mkEqPredCoOcc       = mk_simple_deriv tcName   "$co"
 572
 573 -- used in derived instances
 574 mkCon2TagOcc        = mk_simple_deriv varName  "$con2tag_"
 575 mkTag2ConOcc        = mk_simple_deriv varName  "$tag2con_"
 576 mkMaxTagOcc         = mk_simple_deriv varName  "$maxtag_"
 577
 578 -- Generic derivable classes (old)
 579 mkGenOcc1           = mk_simple_deriv varName  "$gfrom"
 580 mkGenOcc2           = mk_simple_deriv varName  "$gto"
 581
 582 -- Generic deriving mechanism (new)
 583 mkGenD         = mk_simple_deriv tcName "D1"
 584
 585 mkGenC :: OccName -> Int -> OccName
 586 mkGenC occ m   = mk_deriv tcName ("C1_" ++ show m) (occNameString occ)
 587
 588 mkGenS :: OccName -> Int -> Int -> OccName
 589 mkGenS occ m n = mk_deriv tcName ("S1_" ++ show m ++ "_" ++ show n)
 590                    (occNameString occ)
 591
 592 mkGenR0   = mk_simple_deriv tcName "Rep0_"
 593 mkGenR0Co = mk_simple_deriv tcName "CoRep0_"
 594
 595 -- data T = MkT ... deriving( Data ) needs defintions for
 596 --      $tT   :: Data.Generics.Basics.DataType
 597 --      $cMkT :: Data.Generics.Basics.Constr
 598 mkDataTOcc = mk_simple_deriv varName  "$t"
 599 mkDataCOcc = mk_simple_deriv varName  "$c"
 600
 601 -- Vectorisation
 602 mkVectOcc          = mk_simple_deriv varName  "$v_"
 603 mkVectTyConOcc     = mk_simple_deriv tcName   ":V_"
 604 mkVectDataConOcc   = mk_simple_deriv dataName ":VD_"
 605 mkVectIsoOcc       = mk_simple_deriv varName  "$VI_"
 606 mkPDataTyConOcc    = mk_simple_deriv tcName   ":VP_"
 607 mkPDataDataConOcc  = mk_simple_deriv dataName ":VPD_"
 608 mkPReprTyConOcc    = mk_simple_deriv tcName   ":VR_"
 609 mkPADFunOcc        = mk_simple_deriv varName  "$PA_"
 610
 611 mk_simple_deriv :: NameSpace -> String -> OccName -> OccName
 612 mk_simple_deriv sp px occ = mk_deriv sp px (occNameString occ)
 613
 614 -- Data constructor workers are made by setting the name space
 615 -- of the data constructor OccName (which should be a DataName)
 616 -- to VarName
 617 mkDataConWorkerOcc datacon_occ = setOccNameSpace varName datacon_occ
 618 \end{code}
 619
 620 \begin{code}
 621 mkSuperDictSelOcc :: Int        -- ^ Index of superclass, e.g. 3
 622                   -> OccName    -- ^ Class, e.g. @Ord@
 623                   -> OccName    -- ^ Derived 'Occname', e.g. @$p3Ord@
 624 mkSuperDictSelOcc index cls_occ
 625   = mk_deriv varName "$p" (show index ++ occNameString cls_occ)
 626
 627 mkLocalOcc :: Unique            -- ^ Unique to combine with the 'OccName'
 628            -> OccName           -- ^ Local name, e.g. @sat@
 629            -> OccName           -- ^ Nice unique version, e.g. @$L23sat@
 630 mkLocalOcc uniq occ
 631    = mk_deriv varName ("$L" ++ show uniq) (occNameString occ)
 632         -- The Unique might print with characters
 633         -- that need encoding (e.g. 'z'!)
 634 \end{code}
 635
 636 \begin{code}
 637 -- | Derive a name for the representation type constructor of a
 638 -- @data@\/@newtype@ instance.
 639 mkInstTyTcOcc :: String                 -- ^ Family name, e.g. @Map@
 640               -> OccSet                 -- ^ avoid these Occs
 641               -> OccName                -- ^ @R:Map@
 642 mkInstTyTcOcc str set =
 643   chooseUniqueOcc tcName ('R' : ':' : str) set
 644 \end{code}
 645
 646 \begin{code}
 647 mkDFunOcc :: String             -- ^ Typically the class and type glommed together e.g. @OrdMaybe@.
 648                                 -- Only used in debug mode, for extra clarity
 649           -> Bool               -- ^ Is this a hs-boot instance DFun?
 650           -> OccSet             -- ^ avoid these Occs
 651           -> OccName            -- ^ E.g. @$f3OrdMaybe@
 652
 653 -- In hs-boot files we make dict funs like $fx7ClsTy, which get bound to the real
 654 -- thing when we compile the mother module. Reason: we don't know exactly
 655 -- what the  mother module will call it.
 656
 657 mkDFunOcc info_str is_boot set
 658   = chooseUniqueOcc VarName (prefix ++ info_str) set
 659   where
 660     prefix | is_boot   = "$fx"
 661            | otherwise = "$f"
 662 \end{code}
 663
 664 Sometimes we need to pick an OccName that has not already been used,
 665 given a set of in-use OccNames.
 666
 667 \begin{code}
 668 chooseUniqueOcc :: NameSpace -> String -> OccSet -> OccName
 669 chooseUniqueOcc ns str set = loop (mkOccName ns str) (0::Int)
 670   where
 671   loop occ n
 672    | occ `elemOccSet` set = loop (mkOccName ns (str ++ show n)) (n+1)
 673    | otherwise            = occ
 674 \end{code}
 675
 676 We used to add a '$m' to indicate a method, but that gives rise to bad
 677 error messages from the type checker when we print the function name or pattern
 678 of an instance-decl binding.  Why? Because the binding is zapped
 679 to use the method name in place of the selector name.
 680 (See TcClassDcl.tcMethodBind)
 681
 682 The way it is now, -ddump-xx output may look confusing, but
 683 you can always say -dppr-debug to get the uniques.
 684
 685 However, we *do* have to zap the first character to be lower case,
 686 because overloaded constructors (blarg) generate methods too.
 687 And convert to VarName space
 688
 689 e.g. a call to constructor MkFoo where
 690         data (Ord a) => Foo a = MkFoo a
 691
 692 If this is necessary, we do it by prefixing '$m'.  These
 693 guys never show up in error messages.  What a hack.
 694
 695 \begin{code}
 696 mkMethodOcc :: OccName -> OccName
 697 mkMethodOcc occ@(OccName VarName _) = occ
 698 mkMethodOcc occ                     = mk_simple_deriv varName "$m" occ
 699 \end{code}
 700
 701
 702 %************************************************************************
 703 %*                                                                      *
 704 \subsection{Tidying them up}
 705 %*                                                                      *
 706 %************************************************************************
 707
 708 Before we print chunks of code we like to rename it so that
 709 we don't have to print lots of silly uniques in it.  But we mustn't
 710 accidentally introduce name clashes!  So the idea is that we leave the
 711 OccName alone unless it accidentally clashes with one that is already
 712 in scope; if so, we tack on '1' at the end and try again, then '2', and
 713 so on till we find a unique one.
 714
 715 There's a wrinkle for operators.  Consider '>>='.  We can't use '>>=1'
 716 because that isn't a single lexeme.  So we encode it to 'lle' and *then*
 717 tack on the '1', if necessary.
 718
 719 \begin{code}
 720 type TidyOccEnv = OccEnv Int    -- The in-scope OccNames
 721         -- Range gives a plausible starting point for new guesses
 722
 723 emptyTidyOccEnv :: TidyOccEnv
 724 emptyTidyOccEnv = emptyOccEnv
 725
 726 initTidyOccEnv :: [OccName] -> TidyOccEnv       -- Initialise with names to avoid!
 727 initTidyOccEnv = foldl (\env occ -> extendOccEnv env occ 1) emptyTidyOccEnv
 728
 729 tidyOccName :: TidyOccEnv -> OccName -> (TidyOccEnv, OccName)
 730
 731 tidyOccName in_scope occ@(OccName occ_sp fs)
 732   = case lookupOccEnv in_scope occ of
 733         Nothing ->      -- Not already used: make it used
 734                    (extendOccEnv in_scope occ 1, occ)
 735
 736         Just n  ->      -- Already used: make a new guess,
 737                         -- change the guess base, and try again
 738                    tidyOccName  (extendOccEnv in_scope occ (n+1))
 739                                 (mkOccName occ_sp (base_occ ++ show n))
 740   where
 741     base_occ = reverse (dropWhile isDigit (reverse (unpackFS fs)))
 742 \end{code}
 743
 744 %************************************************************************
 745 %*                                                                      *
 746                 Stuff for dealing with tuples
 747 %*                                                                      *
 748 %************************************************************************
 749
 750 \begin{code}
 751 mkTupleOcc :: NameSpace -> Boxity -> Arity -> OccName
 752 mkTupleOcc ns bx ar = OccName ns (mkFastString str)
 753   where
 754         -- no need to cache these, the caching is done in the caller
 755         -- (TysWiredIn.mk_tuple)
 756     str = case bx of
 757                 Boxed   -> '(' : commas ++ ")"
 758                 Unboxed -> '(' : '#' : commas ++ "#)"
 759
 760     commas = take (ar-1) (repeat ',')
 761
 762 isTupleOcc_maybe :: OccName -> Maybe (NameSpace, Boxity, Arity)
 763 -- Tuples are special, because there are so many of them!
 764 isTupleOcc_maybe (OccName ns fs)
 765   = case unpackFS fs of
 766         '(':'#':',':rest -> Just (ns, Unboxed, 2 + count_commas rest)
 767         '(':',':rest     -> Just (ns, Boxed,   2 + count_commas rest)
 768         _other           -> Nothing
 769   where
 770     count_commas (',':rest) = 1 + count_commas rest
 771     count_commas _          = 0
 772 \end{code}
 773
 774 %************************************************************************
 775 %*                                                                      *
 776 \subsection{Lexical categories}
 777 %*                                                                      *
 778 %************************************************************************
 779
 780 These functions test strings to see if they fit the lexical categories
 781 defined in the Haskell report.
 782
 783 \begin{code}
 784 isLexCon,   isLexVar,    isLexId,    isLexSym    :: FastString -> Bool
 785 isLexConId, isLexConSym, isLexVarId, isLexVarSym :: FastString -> Bool
 786
 787 isLexCon cs = isLexConId  cs || isLexConSym cs
 788 isLexVar cs = isLexVarId  cs || isLexVarSym cs
 789
 790 isLexId  cs = isLexConId  cs || isLexVarId  cs
 791 isLexSym cs = isLexConSym cs || isLexVarSym cs
 792
 793 -------------
 794
 795 isLexConId cs                           -- Prefix type or data constructors
 796   | nullFS cs          = False          --      e.g. "Foo", "[]", "(,)"
 797   | cs == (fsLit "[]") = True
 798   | otherwise          = startsConId (headFS cs)
 799
 800 isLexVarId cs                           -- Ordinary prefix identifiers
 801   | nullFS cs         = False           --      e.g. "x", "_x"
 802   | otherwise         = startsVarId (headFS cs)
 803
 804 isLexConSym cs                          -- Infix type or data constructors
 805   | nullFS cs          = False          --      e.g. ":-:", ":", "->"
 806   | cs == (fsLit "->") = True
 807   | otherwise          = startsConSym (headFS cs)
 808
 809 isLexVarSym cs                          -- Infix identifiers
 810   | nullFS cs         = False           --      e.g. "+"
 811   | otherwise         = startsVarSym (headFS cs)
 812
 813 -------------
 814 startsVarSym, startsVarId, startsConSym, startsConId :: Char -> Bool
 815 startsVarSym c = isSymbolASCII c || (ord c > 0x7f && isSymbol c) -- Infix Ids
 816 startsConSym c = c == ':'                               -- Infix data constructors
 817 startsVarId c  = isLower c || c == '_'  -- Ordinary Ids
 818 startsConId c  = isUpper c || c == '('  -- Ordinary type constructors and data constructors
 819
 820 isSymbolASCII :: Char -> Bool
 821 isSymbolASCII c = c `elem` "!#$%&*+./<=>?@\\^|~-"
 822 \end{code}
 823
 824 %************************************************************************
 825 %*                                                                      *
 826                 Binary instance
 827     Here rather than BinIface because OccName is abstract
 828 %*                                                                      *
 829 %************************************************************************
 830
 831 \begin{code}
 832 instance Binary NameSpace where
 833     put_ bh VarName = do
 834             putByte bh 0
 835     put_ bh DataName = do
 836             putByte bh 1
 837     put_ bh TvName = do
 838             putByte bh 2
 839     put_ bh TcClsName = do
 840             putByte bh 3
 841     get bh = do
 842             h <- getByte bh
 843             case h of
 844               0 -> do return VarName
 845               1 -> do return DataName
 846               2 -> do return TvName
 847               _ -> do return TcClsName
 848
 849 instance Binary OccName where
 850     put_ bh (OccName aa ab) = do
 851             put_ bh aa
 852             put_ bh ab
 853     get bh = do
 854           aa <- get bh
 855           ab <- get bh
 856           return (OccName aa ab)
 857 \end{code}