compiler/cmm/CmmOpt.hs

   1 {-# OPTIONS -w #-}
   2 -- The above warning supression flag is a temporary kludge.
   3 -- While working on this module you are encouraged to remove it and fix
   4 -- any warnings in the module. See
   5 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
   6 -- for details
   7
   8 -----------------------------------------------------------------------------
   9 --
  10 -- Cmm optimisation
  11 --
  12 -- (c) The University of Glasgow 2006
  13 --
  14 -----------------------------------------------------------------------------
  15
  16 module CmmOpt (
  17         cmmMiniInline,
  18         cmmMachOpFold,
  19         cmmLoopifyForC,
  20  ) where
  21
  22 #include "HsVersions.h"
  23
  24 import Cmm
  25 import CmmExpr
  26 import CmmUtils
  27 import CLabel
  28 import MachOp
  29 import StaticFlags
  30
  31 import UniqFM
  32 import Unique
  33 import FastTypes
  34 import Outputable
  35
  36 import Data.Bits
  37 import Data.Word
  38 import Data.Int
  39
  40 -- -----------------------------------------------------------------------------
  41 -- The mini-inliner
  42
  43 {-
  44 This pass inlines assignments to temporaries that are used just
  45 once.  It works as follows:
  46
  47   - count uses of each temporary
  48   - for each temporary that occurs just once:
  49         - attempt to push it forward to the statement that uses it
  50         - only push forward past assignments to other temporaries
  51           (assumes that temporaries are single-assignment)
  52         - if we reach the statement that uses it, inline the rhs
  53           and delete the original assignment.
  54
  55 [N.B. In the Quick C-- compiler, this optimization is achieved by a
  56  combination of two dataflow passes: forward substitution (peephole
  57  optimization) and dead-assignment elimination.  ---NR]
  58
  59 Possible generalisations: here is an example from factorial
  60
  61 Fac_zdwfac_entry:
  62     cmG:
  63         _smi = R2;
  64         if (_smi != 0) goto cmK;
  65         R1 = R3;
  66         jump I64[Sp];
  67     cmK:
  68         _smn = _smi * R3;
  69         R2 = _smi + (-1);
  70         R3 = _smn;
  71         jump Fac_zdwfac_info;
  72
  73 We want to inline _smi and _smn.  To inline _smn:
  74
  75    - we must be able to push forward past assignments to global regs.
  76      We can do this if the rhs of the assignment we are pushing
  77      forward doesn't refer to the global reg being assigned to; easy
  78      to test.
  79
  80 To inline _smi:
  81
  82    - It is a trivial replacement, reg for reg, but it occurs more than
  83      once.
  84    - We can inline trivial assignments even if the temporary occurs
  85      more than once, as long as we don't eliminate the original assignment
  86      (this doesn't help much on its own).
  87    - We need to be able to propagate the assignment forward through jumps;
  88      if we did this, we would find that it can be inlined safely in all
  89      its occurrences.
  90 -}
  91
  92 countUses :: UserOfLocalRegs a => a -> UniqFM Int
  93 countUses a = foldRegsUsed (\m r -> addToUFM m r (count m r + 1)) emptyUFM a
  94   where count m r = lookupWithDefaultUFM m (0::Int) r
  95
  96 cmmMiniInline :: [CmmBasicBlock] -> [CmmBasicBlock]
  97 cmmMiniInline blocks = map do_inline blocks
  98   where do_inline (BasicBlock id stmts)
  99           = BasicBlock id (cmmMiniInlineStmts (countUses blocks) stmts)
 100
 101 cmmMiniInlineStmts :: UniqFM Int -> [CmmStmt] -> [CmmStmt]
 102 cmmMiniInlineStmts uses [] = []
 103 cmmMiniInlineStmts uses (stmt@(CmmAssign (CmmLocal (LocalReg u _ _)) expr) : stmts)
 104         -- not used at all: just discard this assignment
 105   | Nothing <- lookupUFM uses u
 106   = cmmMiniInlineStmts uses stmts
 107
 108         -- used once: try to inline at the use site
 109   | Just 1 <- lookupUFM uses u,
 110     Just stmts' <- lookForInline u expr stmts
 111   =
 112 #ifdef NCG_DEBUG
 113      trace ("nativeGen: inlining " ++ showSDoc (pprStmt stmt)) $
 114 #endif
 115      cmmMiniInlineStmts uses stmts'
 116
 117 cmmMiniInlineStmts uses (stmt:stmts)
 118   = stmt : cmmMiniInlineStmts uses stmts
 119
 120
 121 -- Try to inline a temporary assignment.  We can skip over assignments to
 122 -- other tempoararies, because we know that expressions aren't side-effecting
 123 -- and temporaries are single-assignment.
 124 lookForInline u expr (stmt@(CmmAssign (CmmLocal (LocalReg u' _ _)) rhs) : rest)
 125   | u /= u'
 126   = case lookupUFM (countUses rhs) u of
 127         Just 1 -> Just (inlineStmt u expr stmt : rest)
 128         _other -> case lookForInline u expr rest of
 129                      Nothing    -> Nothing
 130                      Just stmts -> Just (stmt:stmts)
 131
 132 lookForInline u expr (CmmNop : rest)
 133   = lookForInline u expr rest
 134
 135 lookForInline _ _ [] = Nothing
 136
 137 lookForInline u expr (stmt:stmts)
 138   = case lookupUFM (countUses stmt) u of
 139         Just 1 | ok_to_inline -> Just (inlineStmt u expr stmt : stmts)
 140         _other -> Nothing
 141   where
 142         -- we don't inline into CmmCall if the expression refers to global
 143         -- registers.  This is a HACK to avoid global registers clashing with
 144         -- C argument-passing registers, really the back-end ought to be able
 145         -- to handle it properly, but currently neither PprC nor the NCG can
 146         -- do it.  See also CgForeignCall:load_args_into_temps.
 147     ok_to_inline = case stmt of
 148                      CmmCall{} -> hasNoGlobalRegs expr
 149                      _ -> True
 150
 151 inlineStmt :: Unique -> CmmExpr -> CmmStmt -> CmmStmt
 152 inlineStmt u a (CmmAssign r e) = CmmAssign r (inlineExpr u a e)
 153 inlineStmt u a (CmmStore e1 e2) = CmmStore (inlineExpr u a e1) (inlineExpr u a e2)
 154 inlineStmt u a (CmmCall target regs es srt ret)
 155    = CmmCall (infn target) regs es' srt ret
 156    where infn (CmmCallee fn cconv) = CmmCallee fn cconv
 157          infn (CmmPrim p) = CmmPrim p
 158          es' = [ (CmmHinted (inlineExpr u a e) hint) | (CmmHinted e hint) <- es ]
 159 inlineStmt u a (CmmCondBranch e d) = CmmCondBranch (inlineExpr u a e) d
 160 inlineStmt u a (CmmSwitch e d) = CmmSwitch (inlineExpr u a e) d
 161 inlineStmt u a (CmmJump e d) = CmmJump (inlineExpr u a e) d
 162 inlineStmt u a other_stmt = other_stmt
 163
 164 inlineExpr :: Unique -> CmmExpr -> CmmExpr -> CmmExpr
 165 inlineExpr u a e@(CmmReg (CmmLocal (LocalReg u' _ _)))
 166   | u == u' = a
 167   | otherwise = e
 168 inlineExpr u a e@(CmmRegOff (CmmLocal (LocalReg u' rep _)) off)
 169   | u == u' = CmmMachOp (MO_Add rep) [a, CmmLit (CmmInt (fromIntegral off) rep)]
 170   | otherwise = e
 171 inlineExpr u a (CmmLoad e rep) = CmmLoad (inlineExpr u a e) rep
 172 inlineExpr u a (CmmMachOp op es) = CmmMachOp op (map (inlineExpr u a) es)
 173 inlineExpr u a other_expr = other_expr
 174
 175 -- -----------------------------------------------------------------------------
 176 -- MachOp constant folder
 177
 178 -- Now, try to constant-fold the MachOps.  The arguments have already
 179 -- been optimized and folded.
 180
 181 cmmMachOpFold
 182     :: MachOp           -- The operation from an CmmMachOp
 183     -> [CmmExpr]        -- The optimized arguments
 184     -> CmmExpr
 185
 186 cmmMachOpFold op arg@[CmmLit (CmmInt x rep)]
 187   = case op of
 188       MO_S_Neg r -> CmmLit (CmmInt (-x) rep)
 189       MO_Not r   -> CmmLit (CmmInt (complement x) rep)
 190
 191         -- these are interesting: we must first narrow to the
 192         -- "from" type, in order to truncate to the correct size.
 193         -- The final narrow/widen to the destination type
 194         -- is implicit in the CmmLit.
 195       MO_S_Conv from to
 196            | isFloatingRep to -> CmmLit (CmmFloat (fromInteger x) to)
 197            | otherwise        -> CmmLit (CmmInt (narrowS from x) to)
 198       MO_U_Conv from to -> CmmLit (CmmInt (narrowU from x) to)
 199
 200       _ -> panic "cmmMachOpFold: unknown unary op"
 201
 202
 203 -- Eliminate conversion NOPs
 204 cmmMachOpFold (MO_S_Conv rep1 rep2) [x] | rep1 == rep2 = x
 205 cmmMachOpFold (MO_U_Conv rep1 rep2) [x] | rep1 == rep2 = x
 206
 207 -- Eliminate nested conversions where possible
 208 cmmMachOpFold conv_outer args@[CmmMachOp conv_inner [x]]
 209   | Just (rep1,rep2,signed1) <- isIntConversion conv_inner,
 210     Just (_,   rep3,signed2) <- isIntConversion conv_outer
 211   = case () of
 212         -- widen then narrow to the same size is a nop
 213       _ | rep1 < rep2 && rep1 == rep3 -> x
 214         -- Widen then narrow to different size: collapse to single conversion
 215         -- but remember to use the signedness from the widening, just in case
 216         -- the final conversion is a widen.
 217         | rep1 < rep2 && rep2 > rep3 ->
 218             cmmMachOpFold (intconv signed1 rep1 rep3) [x]
 219         -- Nested widenings: collapse if the signedness is the same
 220         | rep1 < rep2 && rep2 < rep3 && signed1 == signed2 ->
 221             cmmMachOpFold (intconv signed1 rep1 rep3) [x]
 222         -- Nested narrowings: collapse
 223         | rep1 > rep2 && rep2 > rep3 ->
 224             cmmMachOpFold (MO_U_Conv rep1 rep3) [x]
 225         | otherwise ->
 226             CmmMachOp conv_outer args
 227   where
 228         isIntConversion (MO_U_Conv rep1 rep2)
 229           | not (isFloatingRep rep1) && not (isFloatingRep rep2)
 230           = Just (rep1,rep2,False)
 231         isIntConversion (MO_S_Conv rep1 rep2)
 232           | not (isFloatingRep rep1) && not (isFloatingRep rep2)
 233           = Just (rep1,rep2,True)
 234         isIntConversion _ = Nothing
 235
 236         intconv True  = MO_S_Conv
 237         intconv False = MO_U_Conv
 238
 239 -- ToDo: a narrow of a load can be collapsed into a narrow load, right?
 240 -- but what if the architecture only supports word-sized loads, should
 241 -- we do the transformation anyway?
 242
 243 cmmMachOpFold mop args@[CmmLit (CmmInt x xrep), CmmLit (CmmInt y _)]
 244   = case mop of
 245         -- for comparisons: don't forget to narrow the arguments before
 246         -- comparing, since they might be out of range.
 247         MO_Eq r   -> CmmLit (CmmInt (if x_u == y_u then 1 else 0) wordRep)
 248         MO_Ne r   -> CmmLit (CmmInt (if x_u /= y_u then 1 else 0) wordRep)
 249
 250         MO_U_Gt r -> CmmLit (CmmInt (if x_u >  y_u then 1 else 0) wordRep)
 251         MO_U_Ge r -> CmmLit (CmmInt (if x_u >= y_u then 1 else 0) wordRep)
 252         MO_U_Lt r -> CmmLit (CmmInt (if x_u <  y_u then 1 else 0) wordRep)
 253         MO_U_Le r -> CmmLit (CmmInt (if x_u <= y_u then 1 else 0) wordRep)
 254
 255         MO_S_Gt r -> CmmLit (CmmInt (if x_s >  y_s then 1 else 0) wordRep)
 256         MO_S_Ge r -> CmmLit (CmmInt (if x_s >= y_s then 1 else 0) wordRep)
 257         MO_S_Lt r -> CmmLit (CmmInt (if x_s <  y_s then 1 else 0) wordRep)
 258         MO_S_Le r -> CmmLit (CmmInt (if x_s <= y_s then 1 else 0) wordRep)
 259
 260         MO_Add r -> CmmLit (CmmInt (x + y) r)
 261         MO_Sub r -> CmmLit (CmmInt (x - y) r)
 262         MO_Mul r -> CmmLit (CmmInt (x * y) r)
 263         MO_S_Quot r | y /= 0 -> CmmLit (CmmInt (x `quot` y) r)
 264         MO_S_Rem  r | y /= 0 -> CmmLit (CmmInt (x `rem` y) r)
 265
 266         MO_And   r -> CmmLit (CmmInt (x .&. y) r)
 267         MO_Or    r -> CmmLit (CmmInt (x .|. y) r)
 268         MO_Xor   r -> CmmLit (CmmInt (x `xor` y) r)
 269
 270         MO_Shl   r -> CmmLit (CmmInt (x `shiftL` fromIntegral y) r)
 271         MO_U_Shr r -> CmmLit (CmmInt (x_u `shiftR` fromIntegral y) r)
 272         MO_S_Shr r -> CmmLit (CmmInt (x `shiftR` fromIntegral y) r)
 273
 274         other      -> CmmMachOp mop args
 275
 276    where
 277         x_u = narrowU xrep x
 278         y_u = narrowU xrep y
 279         x_s = narrowS xrep x
 280         y_s = narrowS xrep y
 281
 282
 283 -- When possible, shift the constants to the right-hand side, so that we
 284 -- can match for strength reductions.  Note that the code generator will
 285 -- also assume that constants have been shifted to the right when
 286 -- possible.
 287
 288 cmmMachOpFold op [x@(CmmLit _), y]
 289    | not (isLit y) && isCommutableMachOp op
 290    = cmmMachOpFold op [y, x]
 291
 292 -- Turn (a+b)+c into a+(b+c) where possible.  Because literals are
 293 -- moved to the right, it is more likely that we will find
 294 -- opportunities for constant folding when the expression is
 295 -- right-associated.
 296 --
 297 -- ToDo: this appears to introduce a quadratic behaviour due to the
 298 -- nested cmmMachOpFold.  Can we fix this?
 299 --
 300 -- Why do we check isLit arg1?  If arg1 is a lit, it means that arg2
 301 -- is also a lit (otherwise arg1 would be on the right).  If we
 302 -- put arg1 on the left of the rearranged expression, we'll get into a
 303 -- loop:  (x1+x2)+x3 => x1+(x2+x3)  => (x2+x3)+x1 => x2+(x3+x1) ...
 304 --
 305 -- Also don't do it if arg1 is PicBaseReg, so that we don't separate the
 306 -- PicBaseReg from the corresponding label (or label difference).
 307 --
 308 cmmMachOpFold mop1 [CmmMachOp mop2 [arg1,arg2], arg3]
 309    | mop1 == mop2 && isAssociativeMachOp mop1
 310      && not (isLit arg1) && not (isPicReg arg1)
 311    = cmmMachOpFold mop1 [arg1, cmmMachOpFold mop2 [arg2,arg3]]
 312
 313 -- Make a RegOff if we can
 314 cmmMachOpFold (MO_Add _) [CmmReg reg, CmmLit (CmmInt n rep)]
 315   = CmmRegOff reg (fromIntegral (narrowS rep n))
 316 cmmMachOpFold (MO_Add _) [CmmRegOff reg off, CmmLit (CmmInt n rep)]
 317   = CmmRegOff reg (off + fromIntegral (narrowS rep n))
 318 cmmMachOpFold (MO_Sub _) [CmmReg reg, CmmLit (CmmInt n rep)]
 319   = CmmRegOff reg (- fromIntegral (narrowS rep n))
 320 cmmMachOpFold (MO_Sub _) [CmmRegOff reg off, CmmLit (CmmInt n rep)]
 321   = CmmRegOff reg (off - fromIntegral (narrowS rep n))
 322
 323 -- Fold label(+/-)offset into a CmmLit where possible
 324
 325 cmmMachOpFold (MO_Add _) [CmmLit (CmmLabel lbl), CmmLit (CmmInt i rep)]
 326   = CmmLit (CmmLabelOff lbl (fromIntegral (narrowU rep i)))
 327 cmmMachOpFold (MO_Add _) [CmmLit (CmmInt i rep), CmmLit (CmmLabel lbl)]
 328   = CmmLit (CmmLabelOff lbl (fromIntegral (narrowU rep i)))
 329 cmmMachOpFold (MO_Sub _) [CmmLit (CmmLabel lbl), CmmLit (CmmInt i rep)]
 330   = CmmLit (CmmLabelOff lbl (fromIntegral (negate (narrowU rep i))))
 331
 332
 333 -- Comparison of literal with widened operand: perform the comparison
 334 -- at the smaller width, as long as the literal is within range.
 335
 336 -- We can't do the reverse trick, when the operand is narrowed:
 337 -- narrowing throws away bits from the operand, there's no way to do
 338 -- the same comparison at the larger size.
 339
 340 #if i386_TARGET_ARCH || x86_64_TARGET_ARCH
 341 -- powerPC NCG has a TODO for I8/I16 comparisons, so don't try
 342
 343 cmmMachOpFold cmp [CmmMachOp conv [x], CmmLit (CmmInt i _)]
 344   |     -- if the operand is widened:
 345     Just (rep, signed, narrow_fn) <- maybe_conversion conv,
 346         -- and this is a comparison operation:
 347     Just narrow_cmp <- maybe_comparison cmp rep signed,
 348         -- and the literal fits in the smaller size:
 349     i == narrow_fn rep i
 350         -- then we can do the comparison at the smaller size
 351   = cmmMachOpFold narrow_cmp [x, CmmLit (CmmInt i rep)]
 352  where
 353     maybe_conversion (MO_U_Conv from to)
 354         | to > from
 355         = Just (from, False, narrowU)
 356     maybe_conversion (MO_S_Conv from to)
 357         | to > from, not (isFloatingRep from)
 358         = Just (from, True, narrowS)
 359         -- don't attempt to apply this optimisation when the source
 360         -- is a float; see #1916
 361     maybe_conversion _ = Nothing
 362
 363         -- careful (#2080): if the original comparison was signed, but
 364         -- we were doing an unsigned widen, then we must do an
 365         -- unsigned comparison at the smaller size.
 366     maybe_comparison (MO_U_Gt _) rep _     = Just (MO_U_Gt rep)
 367     maybe_comparison (MO_U_Ge _) rep _     = Just (MO_U_Ge rep)
 368     maybe_comparison (MO_U_Lt _) rep _     = Just (MO_U_Lt rep)
 369     maybe_comparison (MO_U_Le _) rep _     = Just (MO_U_Le rep)
 370     maybe_comparison (MO_Eq   _) rep _     = Just (MO_Eq   rep)
 371     maybe_comparison (MO_S_Gt _) rep True  = Just (MO_S_Gt rep)
 372     maybe_comparison (MO_S_Ge _) rep True  = Just (MO_S_Ge rep)
 373     maybe_comparison (MO_S_Lt _) rep True  = Just (MO_S_Lt rep)
 374     maybe_comparison (MO_S_Le _) rep True  = Just (MO_S_Le rep)
 375     maybe_comparison (MO_S_Gt _) rep False = Just (MO_U_Gt rep)
 376     maybe_comparison (MO_S_Ge _) rep False = Just (MO_U_Ge rep)
 377     maybe_comparison (MO_S_Lt _) rep False = Just (MO_U_Lt rep)
 378     maybe_comparison (MO_S_Le _) rep False = Just (MO_U_Le rep)
 379     maybe_comparison _ _ _ = Nothing
 380
 381 #endif
 382
 383 -- We can often do something with constants of 0 and 1 ...
 384
 385 cmmMachOpFold mop args@[x, y@(CmmLit (CmmInt 0 _))]
 386   = case mop of
 387         MO_Add   r -> x
 388         MO_Sub   r -> x
 389         MO_Mul   r -> y
 390         MO_And   r -> y
 391         MO_Or    r -> x
 392         MO_Xor   r -> x
 393         MO_Shl   r -> x
 394         MO_S_Shr r -> x
 395         MO_U_Shr r -> x
 396         MO_Ne    r | isComparisonExpr x -> x
 397         MO_Eq    r | Just x' <- maybeInvertCmmExpr x -> x'
 398         MO_U_Gt  r | isComparisonExpr x -> x
 399         MO_S_Gt  r | isComparisonExpr x -> x
 400         MO_U_Lt  r | isComparisonExpr x -> CmmLit (CmmInt 0 wordRep)
 401         MO_S_Lt  r | isComparisonExpr x -> CmmLit (CmmInt 0 wordRep)
 402         MO_U_Ge  r | isComparisonExpr x -> CmmLit (CmmInt 1 wordRep)
 403         MO_S_Ge  r | isComparisonExpr x -> CmmLit (CmmInt 1 wordRep)
 404         MO_U_Le  r | Just x' <- maybeInvertCmmExpr x -> x'
 405         MO_S_Le  r | Just x' <- maybeInvertCmmExpr x -> x'
 406         other    -> CmmMachOp mop args
 407
 408 cmmMachOpFold mop args@[x, y@(CmmLit (CmmInt 1 rep))]
 409   = case mop of
 410         MO_Mul    r -> x
 411         MO_S_Quot r -> x
 412         MO_U_Quot r -> x
 413         MO_S_Rem  r -> CmmLit (CmmInt 0 rep)
 414         MO_U_Rem  r -> CmmLit (CmmInt 0 rep)
 415         MO_Ne    r | Just x' <- maybeInvertCmmExpr x -> x'
 416         MO_Eq    r | isComparisonExpr x -> x
 417         MO_U_Lt  r | Just x' <- maybeInvertCmmExpr x -> x'
 418         MO_S_Lt  r | Just x' <- maybeInvertCmmExpr x -> x'
 419         MO_U_Gt  r | isComparisonExpr x -> CmmLit (CmmInt 0 wordRep)
 420         MO_S_Gt  r | isComparisonExpr x -> CmmLit (CmmInt 0 wordRep)
 421         MO_U_Le  r | isComparisonExpr x -> CmmLit (CmmInt 1 wordRep)
 422         MO_S_Le  r | isComparisonExpr x -> CmmLit (CmmInt 1 wordRep)
 423         MO_U_Ge  r | isComparisonExpr x -> x
 424         MO_S_Ge  r | isComparisonExpr x -> x
 425         other       -> CmmMachOp mop args
 426
 427 -- Now look for multiplication/division by powers of 2 (integers).
 428
 429 cmmMachOpFold mop args@[x, y@(CmmLit (CmmInt n _))]
 430   = case mop of
 431         MO_Mul rep
 432            | Just p <- exactLog2 n ->
 433                  CmmMachOp (MO_Shl rep) [x, CmmLit (CmmInt p rep)]
 434         MO_S_Quot rep
 435            | Just p <- exactLog2 n,
 436              CmmReg _ <- x ->   -- We duplicate x below, hence require
 437                                 -- it is a reg.  FIXME: remove this restriction.
 438                 -- shift right is not the same as quot, because it rounds
 439                 -- to minus infinity, whereasq uot rounds toward zero.
 440                 -- To fix this up, we add one less than the divisor to the
 441                 -- dividend if it is a negative number.
 442                 --
 443                 -- to avoid a test/jump, we use the following sequence:
 444                 --      x1 = x >> word_size-1  (all 1s if -ve, all 0s if +ve)
 445                 --      x2 = y & (divisor-1)
 446                 --      result = (x+x2) >>= log2(divisor)
 447                 -- this could be done a bit more simply using conditional moves,
 448                 -- but we're processor independent here.
 449                 --
 450                 -- we optimise the divide by 2 case slightly, generating
 451                 --      x1 = x >> word_size-1  (unsigned)
 452                 --      return = (x + x1) >>= log2(divisor)
 453                 let
 454                     bits = fromIntegral (machRepBitWidth rep) - 1
 455                     shr = if p == 1 then MO_U_Shr rep else MO_S_Shr rep
 456                     x1 = CmmMachOp shr [x, CmmLit (CmmInt bits rep)]
 457                     x2 = if p == 1 then x1 else
 458                          CmmMachOp (MO_And rep) [x1, CmmLit (CmmInt (n-1) rep)]
 459                     x3 = CmmMachOp (MO_Add rep) [x, x2]
 460                 in
 461                 CmmMachOp (MO_S_Shr rep) [x3, CmmLit (CmmInt p rep)]
 462         other
 463            -> unchanged
 464     where
 465        unchanged = CmmMachOp mop args
 466
 467 -- Anything else is just too hard.
 468
 469 cmmMachOpFold mop args = CmmMachOp mop args
 470
 471 -- -----------------------------------------------------------------------------
 472 -- exactLog2
 473
 474 -- This algorithm for determining the $\log_2$ of exact powers of 2 comes
 475 -- from GCC.  It requires bit manipulation primitives, and we use GHC
 476 -- extensions.  Tough.
 477 --
 478 -- Used to be in MachInstrs --SDM.
 479 -- ToDo: remove use of unboxery --SDM.
 480
 481 -- Unboxery removed in favor of FastInt; but is the function supposed to fail
 482 -- on inputs >= 2147483648, or was that just an implementation artifact?
 483 -- And is this speed-critical, or can we just use Integer operations
 484 -- (including Data.Bits)?
 485 --  --Isaac Dupree
 486
 487 exactLog2 :: Integer -> Maybe Integer
 488 exactLog2 x_
 489   = if (x_ <= 0 || x_ >= 2147483648) then
 490        Nothing
 491     else
 492        case iUnbox (fromInteger x_) of { x ->
 493        if (x `bitAndFastInt` negateFastInt x) /=# x then
 494           Nothing
 495        else
 496           Just (toInteger (iBox (pow2 x)))
 497        }
 498   where
 499     pow2 x | x ==# _ILIT(1) = _ILIT(0)
 500            | otherwise = _ILIT(1) +# pow2 (x `shiftR_FastInt` _ILIT(1))
 501
 502
 503 -- -----------------------------------------------------------------------------
 504 -- widening / narrowing
 505
 506 narrowU :: MachRep -> Integer -> Integer
 507 narrowU I8  x = fromIntegral (fromIntegral x :: Word8)
 508 narrowU I16 x = fromIntegral (fromIntegral x :: Word16)
 509 narrowU I32 x = fromIntegral (fromIntegral x :: Word32)
 510 narrowU I64 x = fromIntegral (fromIntegral x :: Word64)
 511 narrowU _ _ = panic "narrowTo"
 512
 513 narrowS :: MachRep -> Integer -> Integer
 514 narrowS I8  x = fromIntegral (fromIntegral x :: Int8)
 515 narrowS I16 x = fromIntegral (fromIntegral x :: Int16)
 516 narrowS I32 x = fromIntegral (fromIntegral x :: Int32)
 517 narrowS I64 x = fromIntegral (fromIntegral x :: Int64)
 518 narrowS _ _ = panic "narrowTo"
 519
 520 -- -----------------------------------------------------------------------------
 521 -- Loopify for C
 522
 523 {-
 524  This is a simple pass that replaces tail-recursive functions like this:
 525
 526    fac() {
 527      ...
 528      jump fac();
 529    }
 530
 531  with this:
 532
 533   fac() {
 534    L:
 535      ...
 536      goto L;
 537   }
 538
 539   the latter generates better C code, because the C compiler treats it
 540   like a loop, and brings full loop optimisation to bear.
 541
 542   In my measurements this makes little or no difference to anything
 543   except factorial, but what the hell.
 544 -}
 545
 546 cmmLoopifyForC :: RawCmmTop -> RawCmmTop
 547 cmmLoopifyForC p@(CmmProc info entry_lbl [] (ListGraph blocks@(BasicBlock top_id _ : _)))
 548   | null info = p  -- only if there's an info table, ignore case alts
 549   | otherwise =
 550 --  pprTrace "jump_lbl" (ppr jump_lbl <+> ppr entry_lbl) $
 551   CmmProc info entry_lbl [] (ListGraph blocks')
 552   where blocks' = [ BasicBlock id (map do_stmt stmts)
 553                   | BasicBlock id stmts <- blocks ]
 554
 555         do_stmt (CmmJump (CmmLit (CmmLabel lbl)) _) | lbl == jump_lbl
 556                 = CmmBranch top_id
 557         do_stmt stmt = stmt
 558
 559         jump_lbl | tablesNextToCode = entryLblToInfoLbl entry_lbl
 560                  | otherwise        = entry_lbl
 561
 562 cmmLoopifyForC top = top
 563
 564 -- -----------------------------------------------------------------------------
 565 -- Utils
 566
 567 isLit (CmmLit _) = True
 568 isLit _          = False
 569
 570 isComparisonExpr :: CmmExpr -> Bool
 571 isComparisonExpr (CmmMachOp op _) = isComparisonMachOp op
 572 isComparisonExpr _other             = False
 573
 574 isPicReg (CmmReg (CmmGlobal PicBaseReg)) = True
 575 isPicReg _ = False
 576