compiler/cmm/CmmParse.y

   1 -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 2004-2006
   4 --
   5 -- Parser for concrete Cmm.
   6 -- This doesn't just parse the Cmm file, we also do some code generation
   7 -- along the way for switches and foreign calls etc.
   8 --
   9 -----------------------------------------------------------------------------
  10
  11 -- TODO: Add support for interruptible/uninterruptible foreign call specification
  12
  13 {
  14 {-# LANGUAGE BangPatterns #-} -- required for versions of Happy before 1.18.6
  15 {-# OPTIONS -Wwarn -w #-}
  16 -- The above warning supression flag is a temporary kludge.
  17 -- While working on this module you are encouraged to remove it and fix
  18 -- any warnings in the module. See
  19 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  20 -- for details
  21
  22 module CmmParse ( parseCmmFile ) where
  23
  24 import CgMonad          hiding (getDynFlags)
  25 import CgExtCode
  26 import CgHeapery
  27 import CgUtils
  28 import CgProf
  29 import CgTicky
  30 import CgInfoTbls
  31 import CgForeignCall
  32 import CgTailCall
  33 import CgStackery
  34 import ClosureInfo
  35 import CgCallConv
  36 import CgClosure
  37 import CostCentre
  38
  39 import BlockId
  40 import OldCmm
  41 import OldPprCmm()
  42 import CmmUtils
  43 import CmmLex
  44 import CLabel
  45 import SMRep
  46 import Lexer
  47
  48 import ForeignCall
  49 import Module
  50 import Literal
  51 import Unique
  52 import UniqFM
  53 import SrcLoc
  54 import DynFlags
  55 import StaticFlags
  56 import ErrUtils
  57 import StringBuffer
  58 import FastString
  59 import Panic
  60 import Constants
  61 import Outputable
  62 import BasicTypes
  63 import Bag              ( emptyBag, unitBag )
  64 import Var
  65
  66 import Control.Monad
  67 import Data.Array
  68 import Data.Char        ( ord )
  69 import System.Exit
  70
  71 #include "HsVersions.h"
  72 }
  73
  74 %expect 0
  75
  76 %token
  77         ':'     { L _ (CmmT_SpecChar ':') }
  78         ';'     { L _ (CmmT_SpecChar ';') }
  79         '{'     { L _ (CmmT_SpecChar '{') }
  80         '}'     { L _ (CmmT_SpecChar '}') }
  81         '['     { L _ (CmmT_SpecChar '[') }
  82         ']'     { L _ (CmmT_SpecChar ']') }
  83         '('     { L _ (CmmT_SpecChar '(') }
  84         ')'     { L _ (CmmT_SpecChar ')') }
  85         '='     { L _ (CmmT_SpecChar '=') }
  86         '`'     { L _ (CmmT_SpecChar '`') }
  87         '~'     { L _ (CmmT_SpecChar '~') }
  88         '/'     { L _ (CmmT_SpecChar '/') }
  89         '*'     { L _ (CmmT_SpecChar '*') }
  90         '%'     { L _ (CmmT_SpecChar '%') }
  91         '-'     { L _ (CmmT_SpecChar '-') }
  92         '+'     { L _ (CmmT_SpecChar '+') }
  93         '&'     { L _ (CmmT_SpecChar '&') }
  94         '^'     { L _ (CmmT_SpecChar '^') }
  95         '|'     { L _ (CmmT_SpecChar '|') }
  96         '>'     { L _ (CmmT_SpecChar '>') }
  97         '<'     { L _ (CmmT_SpecChar '<') }
  98         ','     { L _ (CmmT_SpecChar ',') }
  99         '!'     { L _ (CmmT_SpecChar '!') }
 100
 101         '..'    { L _ (CmmT_DotDot) }
 102         '::'    { L _ (CmmT_DoubleColon) }
 103         '>>'    { L _ (CmmT_Shr) }
 104         '<<'    { L _ (CmmT_Shl) }
 105         '>='    { L _ (CmmT_Ge) }
 106         '<='    { L _ (CmmT_Le) }
 107         '=='    { L _ (CmmT_Eq) }
 108         '!='    { L _ (CmmT_Ne) }
 109         '&&'    { L _ (CmmT_BoolAnd) }
 110         '||'    { L _ (CmmT_BoolOr) }
 111
 112         'CLOSURE'       { L _ (CmmT_CLOSURE) }
 113         'INFO_TABLE'    { L _ (CmmT_INFO_TABLE) }
 114         'INFO_TABLE_RET'{ L _ (CmmT_INFO_TABLE_RET) }
 115         'INFO_TABLE_FUN'{ L _ (CmmT_INFO_TABLE_FUN) }
 116         'INFO_TABLE_CONSTR'{ L _ (CmmT_INFO_TABLE_CONSTR) }
 117         'INFO_TABLE_SELECTOR'{ L _ (CmmT_INFO_TABLE_SELECTOR) }
 118         'else'          { L _ (CmmT_else) }
 119         'export'        { L _ (CmmT_export) }
 120         'section'       { L _ (CmmT_section) }
 121         'align'         { L _ (CmmT_align) }
 122         'goto'          { L _ (CmmT_goto) }
 123         'if'            { L _ (CmmT_if) }
 124         'jump'          { L _ (CmmT_jump) }
 125         'foreign'       { L _ (CmmT_foreign) }
 126         'never'         { L _ (CmmT_never) }
 127         'prim'          { L _ (CmmT_prim) }
 128         'return'        { L _ (CmmT_return) }
 129         'returns'       { L _ (CmmT_returns) }
 130         'import'        { L _ (CmmT_import) }
 131         'switch'        { L _ (CmmT_switch) }
 132         'case'          { L _ (CmmT_case) }
 133         'default'       { L _ (CmmT_default) }
 134         'bits8'         { L _ (CmmT_bits8) }
 135         'bits16'        { L _ (CmmT_bits16) }
 136         'bits32'        { L _ (CmmT_bits32) }
 137         'bits64'        { L _ (CmmT_bits64) }
 138         'float32'       { L _ (CmmT_float32) }
 139         'float64'       { L _ (CmmT_float64) }
 140         'gcptr'         { L _ (CmmT_gcptr) }
 141
 142         GLOBALREG       { L _ (CmmT_GlobalReg   $$) }
 143         NAME            { L _ (CmmT_Name        $$) }
 144         STRING          { L _ (CmmT_String      $$) }
 145         INT             { L _ (CmmT_Int         $$) }
 146         FLOAT           { L _ (CmmT_Float       $$) }
 147
 148 %monad { P } { >>= } { return }
 149 %lexer { cmmlex } { L _ CmmT_EOF }
 150 %name cmmParse cmm
 151 %tokentype { Located CmmToken }
 152
 153 -- C-- operator precedences, taken from the C-- spec
 154 %right '||'     -- non-std extension, called %disjoin in C--
 155 %right '&&'     -- non-std extension, called %conjoin in C--
 156 %right '!'
 157 %nonassoc '>=' '>' '<=' '<' '!=' '=='
 158 %left '|'
 159 %left '^'
 160 %left '&'
 161 %left '>>' '<<'
 162 %left '-' '+'
 163 %left '/' '*' '%'
 164 %right '~'
 165
 166 %%
 167
 168 cmm     :: { ExtCode }
 169         : {- empty -}                   { return () }
 170         | cmmtop cmm                    { do $1; $2 }
 171
 172 cmmtop  :: { ExtCode }
 173         : cmmproc                       { $1 }
 174         | cmmdata                       { $1 }
 175         | decl                          { $1 }
 176         | 'CLOSURE' '(' NAME ',' NAME lits ')' ';'
 177                 {% withThisPackage $ \pkg ->
 178                    do lits <- sequence $6;
 179                       staticClosure pkg $3 $5 (map getLit lits) }
 180
 181 -- The only static closures in the RTS are dummy closures like
 182 -- stg_END_TSO_QUEUE_closure and stg_dummy_ret.  We don't need
 183 -- to provide the full generality of static closures here.
 184 -- In particular:
 185 --      * CCS can always be CCS_DONT_CARE
 186 --      * closure is always extern
 187 --      * payload is always empty
 188 --      * we can derive closure and info table labels from a single NAME
 189
 190 cmmdata :: { ExtCode }
 191         : 'section' STRING '{' statics '}'
 192                 { do ss <- sequence $4;
 193                      code (emitData (section $2) (concat ss)) }
 194
 195 statics :: { [ExtFCode [CmmStatic]] }
 196         : {- empty -}                   { [] }
 197         | static statics                { $1 : $2 }
 198
 199 -- Strings aren't used much in the RTS HC code, so it doesn't seem
 200 -- worth allowing inline strings.  C-- doesn't allow them anyway.
 201 static  :: { ExtFCode [CmmStatic] }
 202         : NAME ':'
 203                 {% withThisPackage $ \pkg ->
 204                    return [CmmDataLabel (mkCmmDataLabel pkg $1)] }
 205
 206         | type expr ';' { do e <- $2;
 207                              return [CmmStaticLit (getLit e)] }
 208         | type ';'                      { return [CmmUninitialised
 209                                                         (widthInBytes (typeWidth $1))] }
 210         | 'bits8' '[' ']' STRING ';'    { return [mkString $4] }
 211         | 'bits8' '[' INT ']' ';'       { return [CmmUninitialised
 212                                                         (fromIntegral $3)] }
 213         | typenot8 '[' INT ']' ';'      { return [CmmUninitialised
 214                                                 (widthInBytes (typeWidth $1) *
 215                                                         fromIntegral $3)] }
 216         | 'align' INT ';'               { return [CmmAlign (fromIntegral $2)] }
 217         | 'CLOSURE' '(' NAME lits ')'
 218                 { do lits <- sequence $4;
 219                      return $ map CmmStaticLit $
 220                        mkStaticClosure (mkForeignLabel $3 Nothing ForeignLabelInExternalPackage IsData)
 221                          -- mkForeignLabel because these are only used
 222                          -- for CHARLIKE and INTLIKE closures in the RTS.
 223                          dontCareCCS (map getLit lits) [] [] [] }
 224         -- arrays of closures required for the CHARLIKE & INTLIKE arrays
 225
 226 lits    :: { [ExtFCode CmmExpr] }
 227         : {- empty -}           { [] }
 228         | ',' expr lits         { $2 : $3 }
 229
 230 cmmproc :: { ExtCode }
 231 -- TODO: add real SRT/info tables to parsed Cmm
 232         : info maybe_formals_without_hints maybe_gc_block maybe_frame '{' body '}'
 233                 { do ((entry_ret_label, info, live, formals, gc_block, frame), stmts) <-
 234                        getCgStmtsEC' $ loopDecls $ do {
 235                          (entry_ret_label, info, live) <- $1;
 236                          formals <- sequence $2;
 237                          gc_block <- $3;
 238                          frame <- $4;
 239                          $6;
 240                          return (entry_ret_label, info, live, formals, gc_block, frame) }
 241                      blks <- code (cgStmtsToBlocks stmts)
 242                      code (emitInfoTableAndCode entry_ret_label (CmmInfo gc_block frame info) formals blks) }
 243
 244         | info maybe_formals_without_hints ';'
 245                 { do (entry_ret_label, info, live) <- $1;
 246                      formals <- sequence $2;
 247                      code (emitInfoTableAndCode entry_ret_label (CmmInfo Nothing Nothing info) formals []) }
 248
 249         | NAME maybe_formals_without_hints maybe_gc_block maybe_frame '{' body '}'
 250                 {% withThisPackage $ \pkg ->
 251                    do   newFunctionName $1 pkg
 252                         ((formals, gc_block, frame), stmts) <-
 253                                 getCgStmtsEC' $ loopDecls $ do {
 254                                         formals <- sequence $2;
 255                                         gc_block <- $3;
 256                                         frame <- $4;
 257                                         $6;
 258                                         return (formals, gc_block, frame) }
 259                         blks <- code (cgStmtsToBlocks stmts)
 260                         code (emitProc (CmmInfo gc_block frame CmmNonInfoTable) (mkCmmCodeLabel pkg $1) formals blks) }
 261
 262 info    :: { ExtFCode (CLabel, CmmInfoTable, [Maybe LocalReg]) }
 263         : 'INFO_TABLE' '(' NAME ',' INT ',' INT ',' INT ',' STRING ',' STRING ')'
 264                 -- ptrs, nptrs, closure type, description, type
 265                 {% withThisPackage $ \pkg ->
 266                    do prof <- profilingInfo $11 $13
 267                       return (mkCmmEntryLabel pkg $3,
 268                         CmmInfoTable False prof (fromIntegral $9)
 269                                      (ThunkInfo (fromIntegral $5, fromIntegral $7) NoC_SRT),
 270                         []) }
 271
 272         | 'INFO_TABLE_FUN' '(' NAME ',' INT ',' INT ',' INT ',' STRING ',' STRING ',' INT ')'
 273                 -- ptrs, nptrs, closure type, description, type, fun type
 274                 {% withThisPackage $ \pkg ->
 275                    do prof <- profilingInfo $11 $13
 276                       return (mkCmmEntryLabel pkg $3,
 277                         CmmInfoTable False prof (fromIntegral $9)
 278                                      (FunInfo (fromIntegral $5, fromIntegral $7) NoC_SRT
 279                                       0  -- Arity zero
 280                                       (ArgSpec (fromIntegral $15))
 281                                       zeroCLit),
 282                         []) }
 283                 -- we leave most of the fields zero here.  This is only used
 284                 -- to generate the BCO info table in the RTS at the moment.
 285
 286         -- A variant with a non-zero arity (needed to write Main_main in Cmm)
 287         | 'INFO_TABLE_FUN' '(' NAME ',' INT ',' INT ',' INT ',' STRING ',' STRING ',' INT ',' INT ')'
 288                 -- ptrs, nptrs, closure type, description, type, fun type, arity
 289                 {% withThisPackage $ \pkg ->
 290                    do prof <- profilingInfo $11 $13
 291                       return (mkCmmEntryLabel pkg $3,
 292                         CmmInfoTable False prof (fromIntegral $9)
 293                                      (FunInfo (fromIntegral $5, fromIntegral $7) NoC_SRT (fromIntegral $17)
 294                                       (ArgSpec (fromIntegral $15))
 295                                       zeroCLit),
 296                         []) }
 297                 -- we leave most of the fields zero here.  This is only used
 298                 -- to generate the BCO info table in the RTS at the moment.
 299
 300         | 'INFO_TABLE_CONSTR' '(' NAME ',' INT ',' INT ',' INT ',' INT ',' STRING ',' STRING ')'
 301                 -- ptrs, nptrs, tag, closure type, description, type
 302                 {% withThisPackage $ \pkg ->
 303                    do prof <- profilingInfo $13 $15
 304                      -- If profiling is on, this string gets duplicated,
 305                      -- but that's the way the old code did it we can fix it some other time.
 306                       desc_lit <- code $ mkStringCLit $13
 307                       return (mkCmmEntryLabel pkg $3,
 308                         CmmInfoTable False prof (fromIntegral $11)
 309                                      (ConstrInfo (fromIntegral $5, fromIntegral $7) (fromIntegral $9) desc_lit),
 310                         []) }
 311
 312         | 'INFO_TABLE_SELECTOR' '(' NAME ',' INT ',' INT ',' STRING ',' STRING ')'
 313                 -- selector, closure type, description, type
 314                 {% withThisPackage $ \pkg ->
 315                    do prof <- profilingInfo $9 $11
 316                       return (mkCmmEntryLabel pkg $3,
 317                         CmmInfoTable False prof (fromIntegral $7)
 318                                      (ThunkSelectorInfo (fromIntegral $5) NoC_SRT),
 319                         []) }
 320
 321         | 'INFO_TABLE_RET' '(' NAME ',' INT ')'
 322                 -- closure type (no live regs)
 323                 {% withThisPackage $ \pkg ->
 324                    do let infoLabel = mkCmmInfoLabel pkg $3
 325                       return (mkCmmRetLabel pkg $3,
 326                         CmmInfoTable False (ProfilingInfo zeroCLit zeroCLit) (fromIntegral $5)
 327                                      (ContInfo [] NoC_SRT),
 328                         []) }
 329
 330         | 'INFO_TABLE_RET' '(' NAME ',' INT ',' formals_without_hints0 ')'
 331                 -- closure type, live regs
 332                 {% withThisPackage $ \pkg ->
 333                    do live <- sequence (map (liftM Just) $7)
 334                       return (mkCmmRetLabel pkg $3,
 335                         CmmInfoTable False (ProfilingInfo zeroCLit zeroCLit) (fromIntegral $5)
 336                                      (ContInfo live NoC_SRT),
 337                         live) }
 338
 339 body    :: { ExtCode }
 340         : {- empty -}                   { return () }
 341         | decl body                     { do $1; $2 }
 342         | stmt body                     { do $1; $2 }
 343
 344 decl    :: { ExtCode }
 345         : type names ';'                { mapM_ (newLocal $1) $2 }
 346         | 'import' importNames ';'      { mapM_ newImport $2 }
 347         | 'export' names ';'            { return () }  -- ignore exports
 348
 349
 350 -- an imported function name, with optional packageId
 351 importNames
 352         :: { [(FastString, CLabel)] }
 353         : importName                    { [$1] }
 354         | importName ',' importNames    { $1 : $3 }
 355
 356 importName
 357         :: { (FastString,  CLabel) }
 358
 359         -- A label imported without an explicit packageId.
 360         --      These are taken to come frome some foreign, unnamed package.
 361         : NAME
 362         { ($1, mkForeignLabel $1 Nothing ForeignLabelInExternalPackage IsFunction) }
 363
 364         -- A label imported with an explicit packageId.
 365         | STRING NAME
 366         { ($2, mkCmmCodeLabel (fsToPackageId (mkFastString $1)) $2) }
 367
 368
 369 names   :: { [FastString] }
 370         : NAME                          { [$1] }
 371         | NAME ',' names                { $1 : $3 }
 372
 373 stmt    :: { ExtCode }
 374         : ';'                                   { nopEC }
 375
 376         | NAME ':'
 377                 { do l <- newLabel $1; code (labelC l) }
 378
 379         | lreg '=' expr ';'
 380                 { do reg <- $1; e <- $3; stmtEC (CmmAssign reg e) }
 381         | type '[' expr ']' '=' expr ';'
 382                 { doStore $1 $3 $6 }
 383
 384         -- Gah! We really want to say "maybe_results" but that causes
 385         -- a shift/reduce conflict with assignment.  We either
 386         -- we expand out the no-result and single result cases or
 387         -- we tweak the syntax to avoid the conflict.  The later
 388         -- option is taken here because the other way would require
 389         -- multiple levels of expanding and get unwieldy.
 390         | maybe_results 'foreign' STRING expr '(' cmm_hint_exprs0 ')' safety vols opt_never_returns ';'
 391                 {% foreignCall $3 $1 $4 $6 $9 $8 $10 }
 392         | maybe_results 'prim' '%' NAME '(' cmm_hint_exprs0 ')' safety vols ';'
 393                 {% primCall $1 $4 $6 $9 $8 }
 394         -- stmt-level macros, stealing syntax from ordinary C-- function calls.
 395         -- Perhaps we ought to use the %%-form?
 396         | NAME '(' exprs0 ')' ';'
 397                 {% stmtMacro $1 $3  }
 398         | 'switch' maybe_range expr '{' arms default '}'
 399                 { do as <- sequence $5; doSwitch $2 $3 as $6 }
 400         | 'goto' NAME ';'
 401                 { do l <- lookupLabel $2; stmtEC (CmmBranch l) }
 402         | 'jump' expr maybe_actuals ';'
 403                 { do e1 <- $2; e2 <- sequence $3; stmtEC (CmmJump e1 e2) }
 404         | 'return' maybe_actuals ';'
 405                 { do e <- sequence $2; stmtEC (CmmReturn e) }
 406         | 'if' bool_expr 'goto' NAME
 407                 { do l <- lookupLabel $4; cmmRawIf $2 l }
 408         | 'if' bool_expr '{' body '}' else
 409                 { cmmIfThenElse $2 $4 $6 }
 410
 411 opt_never_returns :: { CmmReturnInfo }
 412         :                               { CmmMayReturn }
 413         | 'never' 'returns'             { CmmNeverReturns }
 414
 415 bool_expr :: { ExtFCode BoolExpr }
 416         : bool_op                       { $1 }
 417         | expr                          { do e <- $1; return (BoolTest e) }
 418
 419 bool_op :: { ExtFCode BoolExpr }
 420         : bool_expr '&&' bool_expr      { do e1 <- $1; e2 <- $3;
 421                                           return (BoolAnd e1 e2) }
 422         | bool_expr '||' bool_expr      { do e1 <- $1; e2 <- $3;
 423                                           return (BoolOr e1 e2)  }
 424         | '!' bool_expr                 { do e <- $2; return (BoolNot e) }
 425         | '(' bool_op ')'               { $2 }
 426
 427 -- This is not C-- syntax.  What to do?
 428 safety  :: { CmmSafety }
 429         : {- empty -}                   { CmmUnsafe } -- Default may change soon
 430         | STRING                        {% parseSafety $1 }
 431
 432 -- This is not C-- syntax.  What to do?
 433 vols    :: { Maybe [GlobalReg] }
 434         : {- empty -}                   { Nothing }
 435         | '[' ']'                       { Just [] }
 436         | '[' globals ']'               { Just $2 }
 437
 438 globals :: { [GlobalReg] }
 439         : GLOBALREG                     { [$1] }
 440         | GLOBALREG ',' globals         { $1 : $3 }
 441
 442 maybe_range :: { Maybe (Int,Int) }
 443         : '[' INT '..' INT ']'  { Just (fromIntegral $2, fromIntegral $4) }
 444         | {- empty -}           { Nothing }
 445
 446 arms    :: { [ExtFCode ([Int],Either BlockId ExtCode)] }
 447         : {- empty -}                   { [] }
 448         | arm arms                      { $1 : $2 }
 449
 450 arm     :: { ExtFCode ([Int],Either BlockId ExtCode) }
 451         : 'case' ints ':' arm_body      { do b <- $4; return ($2, b) }
 452
 453 arm_body :: { ExtFCode (Either BlockId ExtCode) }
 454         : '{' body '}'                  { return (Right $2) }
 455         | 'goto' NAME ';'               { do l <- lookupLabel $2; return (Left l) }
 456
 457 ints    :: { [Int] }
 458         : INT                           { [ fromIntegral $1 ] }
 459         | INT ',' ints                  { fromIntegral $1 : $3 }
 460
 461 default :: { Maybe ExtCode }
 462         : 'default' ':' '{' body '}'    { Just $4 }
 463         -- taking a few liberties with the C-- syntax here; C-- doesn't have
 464         -- 'default' branches
 465         | {- empty -}                   { Nothing }
 466
 467 -- Note: OldCmm doesn't support a first class 'else' statement, though
 468 -- CmmNode does.
 469 else    :: { ExtCode }
 470         : {- empty -}                   { nopEC }
 471         | 'else' '{' body '}'           { $3 }
 472
 473 -- we have to write this out longhand so that Happy's precedence rules
 474 -- can kick in.
 475 expr    :: { ExtFCode CmmExpr }
 476         : expr '/' expr                 { mkMachOp MO_U_Quot [$1,$3] }
 477         | expr '*' expr                 { mkMachOp MO_Mul [$1,$3] }
 478         | expr '%' expr                 { mkMachOp MO_U_Rem [$1,$3] }
 479         | expr '-' expr                 { mkMachOp MO_Sub [$1,$3] }
 480         | expr '+' expr                 { mkMachOp MO_Add [$1,$3] }
 481         | expr '>>' expr                { mkMachOp MO_U_Shr [$1,$3] }
 482         | expr '<<' expr                { mkMachOp MO_Shl [$1,$3] }
 483         | expr '&' expr                 { mkMachOp MO_And [$1,$3] }
 484         | expr '^' expr                 { mkMachOp MO_Xor [$1,$3] }
 485         | expr '|' expr                 { mkMachOp MO_Or [$1,$3] }
 486         | expr '>=' expr                { mkMachOp MO_U_Ge [$1,$3] }
 487         | expr '>' expr                 { mkMachOp MO_U_Gt [$1,$3] }
 488         | expr '<=' expr                { mkMachOp MO_U_Le [$1,$3] }
 489         | expr '<' expr                 { mkMachOp MO_U_Lt [$1,$3] }
 490         | expr '!=' expr                { mkMachOp MO_Ne [$1,$3] }
 491         | expr '==' expr                { mkMachOp MO_Eq [$1,$3] }
 492         | '~' expr                      { mkMachOp MO_Not [$2] }
 493         | '-' expr                      { mkMachOp MO_S_Neg [$2] }
 494         | expr0 '`' NAME '`' expr0      {% do { mo <- nameToMachOp $3 ;
 495                                                 return (mkMachOp mo [$1,$5]) } }
 496         | expr0                         { $1 }
 497
 498 expr0   :: { ExtFCode CmmExpr }
 499         : INT   maybe_ty         { return (CmmLit (CmmInt $1 (typeWidth $2))) }
 500         | FLOAT maybe_ty         { return (CmmLit (CmmFloat $1 (typeWidth $2))) }
 501         | STRING                 { do s <- code (mkStringCLit $1);
 502                                       return (CmmLit s) }
 503         | reg                    { $1 }
 504         | type '[' expr ']'      { do e <- $3; return (CmmLoad e $1) }
 505         | '%' NAME '(' exprs0 ')' {% exprOp $2 $4 }
 506         | '(' expr ')'           { $2 }
 507
 508
 509 -- leaving out the type of a literal gives you the native word size in C--
 510 maybe_ty :: { CmmType }
 511         : {- empty -}                   { bWord }
 512         | '::' type                     { $2 }
 513
 514 maybe_actuals :: { [ExtFCode HintedCmmActual] }
 515         : {- empty -}           { [] }
 516         | '(' cmm_hint_exprs0 ')'       { $2 }
 517
 518 cmm_hint_exprs0 :: { [ExtFCode HintedCmmActual] }
 519         : {- empty -}                   { [] }
 520         | cmm_hint_exprs                        { $1 }
 521
 522 cmm_hint_exprs :: { [ExtFCode HintedCmmActual] }
 523         : cmm_hint_expr                 { [$1] }
 524         | cmm_hint_expr ',' cmm_hint_exprs      { $1 : $3 }
 525
 526 cmm_hint_expr :: { ExtFCode HintedCmmActual }
 527         : expr                          { do e <- $1; return (CmmHinted e (inferCmmHint e)) }
 528         | expr STRING                   {% do h <- parseCmmHint $2;
 529                                               return $ do
 530                                                 e <- $1; return (CmmHinted e h) }
 531
 532 exprs0  :: { [ExtFCode CmmExpr] }
 533         : {- empty -}                   { [] }
 534         | exprs                         { $1 }
 535
 536 exprs   :: { [ExtFCode CmmExpr] }
 537         : expr                          { [ $1 ] }
 538         | expr ',' exprs                { $1 : $3 }
 539
 540 reg     :: { ExtFCode CmmExpr }
 541         : NAME                  { lookupName $1 }
 542         | GLOBALREG             { return (CmmReg (CmmGlobal $1)) }
 543
 544 maybe_results :: { [ExtFCode HintedCmmFormal] }
 545         : {- empty -}           { [] }
 546         | '(' cmm_formals ')' '='       { $2 }
 547
 548 cmm_formals :: { [ExtFCode HintedCmmFormal] }
 549         : cmm_formal                    { [$1] }
 550         | cmm_formal ','                        { [$1] }
 551         | cmm_formal ',' cmm_formals    { $1 : $3 }
 552
 553 cmm_formal :: { ExtFCode HintedCmmFormal }
 554         : local_lreg                    { do e <- $1; return (CmmHinted e (inferCmmHint (CmmReg (CmmLocal e)))) }
 555         | STRING local_lreg             {% do h <- parseCmmHint $1;
 556                                               return $ do
 557                                                 e <- $2; return (CmmHinted e h) }
 558
 559 local_lreg :: { ExtFCode LocalReg }
 560         : NAME                  { do e <- lookupName $1;
 561                                      return $
 562                                        case e of
 563                                         CmmReg (CmmLocal r) -> r
 564                                         other -> pprPanic "CmmParse:" (ftext $1 <> text " not a local register") }
 565
 566 lreg    :: { ExtFCode CmmReg }
 567         : NAME                  { do e <- lookupName $1;
 568                                      return $
 569                                        case e of
 570                                         CmmReg r -> r
 571                                         other -> pprPanic "CmmParse:" (ftext $1 <> text " not a register") }
 572         | GLOBALREG             { return (CmmGlobal $1) }
 573
 574 maybe_formals_without_hints :: { [ExtFCode LocalReg] }
 575         : {- empty -}           { [] }
 576         | '(' formals_without_hints0 ')'        { $2 }
 577
 578 formals_without_hints0 :: { [ExtFCode LocalReg] }
 579         : {- empty -}           { [] }
 580         | formals_without_hints         { $1 }
 581
 582 formals_without_hints :: { [ExtFCode LocalReg] }
 583         : formal_without_hint ','               { [$1] }
 584         | formal_without_hint           { [$1] }
 585         | formal_without_hint ',' formals_without_hints { $1 : $3 }
 586
 587 formal_without_hint :: { ExtFCode LocalReg }
 588         : type NAME             { newLocal $1 $2 }
 589
 590 maybe_frame :: { ExtFCode (Maybe UpdateFrame) }
 591         : {- empty -}                   { return Nothing }
 592         | 'jump' expr '(' exprs0 ')'    { do { target <- $2;
 593                                                args <- sequence $4;
 594                                                return $ Just (UpdateFrame target args) } }
 595
 596 maybe_gc_block :: { ExtFCode (Maybe BlockId) }
 597         : {- empty -}                   { return Nothing }
 598         | 'goto' NAME
 599                 { do l <- lookupLabel $2; return (Just l) }
 600
 601 type    :: { CmmType }
 602         : 'bits8'               { b8 }
 603         | typenot8              { $1 }
 604
 605 typenot8 :: { CmmType }
 606         : 'bits16'              { b16 }
 607         | 'bits32'              { b32 }
 608         | 'bits64'              { b64 }
 609         | 'float32'             { f32 }
 610         | 'float64'             { f64 }
 611         | 'gcptr'               { gcWord }
 612 {
 613 section :: String -> Section
 614 section "text"   = Text
 615 section "data"   = Data
 616 section "rodata" = ReadOnlyData
 617 section "relrodata" = RelocatableReadOnlyData
 618 section "bss"    = UninitialisedData
 619 section s        = OtherSection s
 620
 621 mkString :: String -> CmmStatic
 622 mkString s = CmmString (map (fromIntegral.ord) s)
 623
 624 -- mkMachOp infers the type of the MachOp from the type of its first
 625 -- argument.  We assume that this is correct: for MachOps that don't have
 626 -- symmetrical args (e.g. shift ops), the first arg determines the type of
 627 -- the op.
 628 mkMachOp :: (Width -> MachOp) -> [ExtFCode CmmExpr] -> ExtFCode CmmExpr
 629 mkMachOp fn args = do
 630   arg_exprs <- sequence args
 631   return (CmmMachOp (fn (typeWidth (cmmExprType (head arg_exprs)))) arg_exprs)
 632
 633 getLit :: CmmExpr -> CmmLit
 634 getLit (CmmLit l) = l
 635 getLit (CmmMachOp (MO_S_Neg _) [CmmLit (CmmInt i r)])  = CmmInt (negate i) r
 636 getLit _ = panic "invalid literal" -- TODO messy failure
 637
 638 nameToMachOp :: FastString -> P (Width -> MachOp)
 639 nameToMachOp name =
 640   case lookupUFM machOps name of
 641         Nothing -> fail ("unknown primitive " ++ unpackFS name)
 642         Just m  -> return m
 643
 644 exprOp :: FastString -> [ExtFCode CmmExpr] -> P (ExtFCode CmmExpr)
 645 exprOp name args_code =
 646   case lookupUFM exprMacros name of
 647      Just f  -> return $ do
 648         args <- sequence args_code
 649         return (f args)
 650      Nothing -> do
 651         mo <- nameToMachOp name
 652         return $ mkMachOp mo args_code
 653
 654 exprMacros :: UniqFM ([CmmExpr] -> CmmExpr)
 655 exprMacros = listToUFM [
 656   ( fsLit "ENTRY_CODE",   \ [x] -> entryCode x ),
 657   ( fsLit "INFO_PTR",     \ [x] -> closureInfoPtr x ),
 658   ( fsLit "STD_INFO",     \ [x] -> infoTable x ),
 659   ( fsLit "FUN_INFO",     \ [x] -> funInfoTable x ),
 660   ( fsLit "GET_ENTRY",    \ [x] -> entryCode (closureInfoPtr x) ),
 661   ( fsLit "GET_STD_INFO", \ [x] -> infoTable (closureInfoPtr x) ),
 662   ( fsLit "GET_FUN_INFO", \ [x] -> funInfoTable (closureInfoPtr x) ),
 663   ( fsLit "INFO_TYPE",    \ [x] -> infoTableClosureType x ),
 664   ( fsLit "INFO_PTRS",    \ [x] -> infoTablePtrs x ),
 665   ( fsLit "INFO_NPTRS",   \ [x] -> infoTableNonPtrs x )
 666   ]
 667
 668 -- we understand a subset of C-- primitives:
 669 machOps = listToUFM $
 670         map (\(x, y) -> (mkFastString x, y)) [
 671         ( "add",        MO_Add ),
 672         ( "sub",        MO_Sub ),
 673         ( "eq",         MO_Eq ),
 674         ( "ne",         MO_Ne ),
 675         ( "mul",        MO_Mul ),
 676         ( "neg",        MO_S_Neg ),
 677         ( "quot",       MO_S_Quot ),
 678         ( "rem",        MO_S_Rem ),
 679         ( "divu",       MO_U_Quot ),
 680         ( "modu",       MO_U_Rem ),
 681
 682         ( "ge",         MO_S_Ge ),
 683         ( "le",         MO_S_Le ),
 684         ( "gt",         MO_S_Gt ),
 685         ( "lt",         MO_S_Lt ),
 686
 687         ( "geu",        MO_U_Ge ),
 688         ( "leu",        MO_U_Le ),
 689         ( "gtu",        MO_U_Gt ),
 690         ( "ltu",        MO_U_Lt ),
 691
 692         ( "and",        MO_And ),
 693         ( "or",         MO_Or ),
 694         ( "xor",        MO_Xor ),
 695         ( "com",        MO_Not ),
 696         ( "shl",        MO_Shl ),
 697         ( "shrl",       MO_U_Shr ),
 698         ( "shra",       MO_S_Shr ),
 699
 700         ( "fadd",       MO_F_Add ),
 701         ( "fsub",       MO_F_Sub ),
 702         ( "fneg",       MO_F_Neg ),
 703         ( "fmul",       MO_F_Mul ),
 704         ( "fquot",      MO_F_Quot ),
 705
 706         ( "feq",        MO_F_Eq ),
 707         ( "fne",        MO_F_Ne ),
 708         ( "fge",        MO_F_Ge ),
 709         ( "fle",        MO_F_Le ),
 710         ( "fgt",        MO_F_Gt ),
 711         ( "flt",        MO_F_Lt ),
 712
 713         ( "lobits8",  flip MO_UU_Conv W8  ),
 714         ( "lobits16", flip MO_UU_Conv W16 ),
 715         ( "lobits32", flip MO_UU_Conv W32 ),
 716         ( "lobits64", flip MO_UU_Conv W64 ),
 717
 718         ( "zx16",     flip MO_UU_Conv W16 ),
 719         ( "zx32",     flip MO_UU_Conv W32 ),
 720         ( "zx64",     flip MO_UU_Conv W64 ),
 721
 722         ( "sx16",     flip MO_SS_Conv W16 ),
 723         ( "sx32",     flip MO_SS_Conv W32 ),
 724         ( "sx64",     flip MO_SS_Conv W64 ),
 725
 726         ( "f2f32",    flip MO_FF_Conv W32 ),  -- TODO; rounding mode
 727         ( "f2f64",    flip MO_FF_Conv W64 ),  -- TODO; rounding mode
 728         ( "f2i8",     flip MO_FS_Conv W8 ),
 729         ( "f2i16",    flip MO_FS_Conv W16 ),
 730         ( "f2i32",    flip MO_FS_Conv W32 ),
 731         ( "f2i64",    flip MO_FS_Conv W64 ),
 732         ( "i2f32",    flip MO_SF_Conv W32 ),
 733         ( "i2f64",    flip MO_SF_Conv W64 )
 734         ]
 735
 736 callishMachOps = listToUFM $
 737         map (\(x, y) -> (mkFastString x, y)) [
 738         ( "write_barrier", MO_WriteBarrier )
 739         -- ToDo: the rest, maybe
 740     ]
 741
 742 parseSafety :: String -> P CmmSafety
 743 parseSafety "safe"   = return (CmmSafe NoC_SRT)
 744 parseSafety "unsafe" = return CmmUnsafe
 745 parseSafety "interruptible" = return CmmInterruptible
 746 parseSafety str      = fail ("unrecognised safety: " ++ str)
 747
 748 parseCmmHint :: String -> P ForeignHint
 749 parseCmmHint "ptr"    = return AddrHint
 750 parseCmmHint "signed" = return SignedHint
 751 parseCmmHint str      = fail ("unrecognised hint: " ++ str)
 752
 753 -- labels are always pointers, so we might as well infer the hint
 754 inferCmmHint :: CmmExpr -> ForeignHint
 755 inferCmmHint (CmmLit (CmmLabel _)) = AddrHint
 756 inferCmmHint (CmmReg (CmmGlobal g)) | isPtrGlobalReg g = AddrHint
 757 inferCmmHint _ = NoHint
 758
 759 isPtrGlobalReg Sp                    = True
 760 isPtrGlobalReg SpLim                 = True
 761 isPtrGlobalReg Hp                    = True
 762 isPtrGlobalReg HpLim                 = True
 763 isPtrGlobalReg CurrentTSO            = True
 764 isPtrGlobalReg CurrentNursery        = True
 765 isPtrGlobalReg (VanillaReg _ VGcPtr) = True
 766 isPtrGlobalReg _                     = False
 767
 768 happyError :: P a
 769 happyError = srcParseFail
 770
 771 -- -----------------------------------------------------------------------------
 772 -- Statement-level macros
 773
 774 stmtMacro :: FastString -> [ExtFCode CmmExpr] -> P ExtCode
 775 stmtMacro fun args_code = do
 776   case lookupUFM stmtMacros fun of
 777     Nothing -> fail ("unknown macro: " ++ unpackFS fun)
 778     Just fcode -> return $ do
 779         args <- sequence args_code
 780         code (fcode args)
 781
 782 stmtMacros :: UniqFM ([CmmExpr] -> Code)
 783 stmtMacros = listToUFM [
 784   ( fsLit "CCS_ALLOC",             \[words,ccs]  -> profAlloc words ccs ),
 785   ( fsLit "CLOSE_NURSERY",         \[]  -> emitCloseNursery ),
 786   ( fsLit "ENTER_CCS_PAP_CL",     \[e] -> enterCostCentrePAP e ),
 787   ( fsLit "ENTER_CCS_THUNK",      \[e] -> enterCostCentreThunk e ),
 788   ( fsLit "HP_CHK_GEN",           \[words,liveness,reentry] ->
 789                                       hpChkGen words liveness reentry ),
 790   ( fsLit "HP_CHK_NP_ASSIGN_SP0", \[e,f] -> hpChkNodePointsAssignSp0 e f ),
 791   ( fsLit "LOAD_THREAD_STATE",    \[] -> emitLoadThreadState ),
 792   ( fsLit "LDV_ENTER",            \[e] -> ldvEnter e ),
 793   ( fsLit "LDV_RECORD_CREATE",    \[e] -> ldvRecordCreate e ),
 794   ( fsLit "OPEN_NURSERY",          \[]  -> emitOpenNursery ),
 795   ( fsLit "PUSH_UPD_FRAME",        \[sp,e] -> emitPushUpdateFrame sp e ),
 796   ( fsLit "SAVE_THREAD_STATE",    \[] -> emitSaveThreadState ),
 797   ( fsLit "SET_HDR",               \[ptr,info,ccs] ->
 798                                         emitSetDynHdr ptr info ccs ),
 799   ( fsLit "STK_CHK_GEN",          \[words,liveness,reentry] ->
 800                                       stkChkGen words liveness reentry ),
 801   ( fsLit "STK_CHK_NP",    \[e] -> stkChkNodePoints e ),
 802   ( fsLit "TICK_ALLOC_PRIM",       \[hdr,goods,slop] ->
 803                                         tickyAllocPrim hdr goods slop ),
 804   ( fsLit "TICK_ALLOC_PAP",       \[goods,slop] ->
 805                                         tickyAllocPAP goods slop ),
 806   ( fsLit "TICK_ALLOC_UP_THK",    \[goods,slop] ->
 807                                         tickyAllocThunk goods slop ),
 808   ( fsLit "UPD_BH_UPDATABLE",       \[] -> emitBlackHoleCode False ),
 809   ( fsLit "UPD_BH_SINGLE_ENTRY",    \[] -> emitBlackHoleCode True ),
 810
 811   ( fsLit "RET_P",      \[a] ->       emitRetUT [(PtrArg,a)]),
 812   ( fsLit "RET_N",      \[a] ->       emitRetUT [(NonPtrArg,a)]),
 813   ( fsLit "RET_PP",     \[a,b] ->     emitRetUT [(PtrArg,a),(PtrArg,b)]),
 814   ( fsLit "RET_NN",     \[a,b] ->     emitRetUT [(NonPtrArg,a),(NonPtrArg,b)]),
 815   ( fsLit "RET_NP",     \[a,b] ->     emitRetUT [(NonPtrArg,a),(PtrArg,b)]),
 816   ( fsLit "RET_PPP",    \[a,b,c] ->   emitRetUT [(PtrArg,a),(PtrArg,b),(PtrArg,c)]),
 817   ( fsLit "RET_NPP",    \[a,b,c] ->   emitRetUT [(NonPtrArg,a),(PtrArg,b),(PtrArg,c)]),
 818   ( fsLit "RET_NNP",    \[a,b,c] ->   emitRetUT [(NonPtrArg,a),(NonPtrArg,b),(PtrArg,c)]),
 819   ( fsLit "RET_NNN",  \[a,b,c] -> emitRetUT [(NonPtrArg,a),(NonPtrArg,b),(NonPtrArg,c)]),
 820   ( fsLit "RET_NNNN",  \[a,b,c,d] -> emitRetUT [(NonPtrArg,a),(NonPtrArg,b),(NonPtrArg,c),(NonPtrArg,d)]),
 821   ( fsLit "RET_NNNP",   \[a,b,c,d] -> emitRetUT [(NonPtrArg,a),(NonPtrArg,b),(NonPtrArg,c),(PtrArg,d)]),
 822   ( fsLit "RET_NPNP",   \[a,b,c,d] -> emitRetUT [(NonPtrArg,a),(PtrArg,b),(NonPtrArg,c),(PtrArg,d)])
 823
 824  ]
 825
 826
 827
 828 profilingInfo desc_str ty_str = do
 829   lit1 <- if opt_SccProfilingOn
 830                    then code $ mkStringCLit desc_str
 831                    else return (mkIntCLit 0)
 832   lit2 <- if opt_SccProfilingOn
 833                    then code $ mkStringCLit ty_str
 834                    else return (mkIntCLit 0)
 835   return (ProfilingInfo lit1 lit2)
 836
 837
 838 staticClosure :: PackageId -> FastString -> FastString -> [CmmLit] -> ExtCode
 839 staticClosure pkg cl_label info payload
 840   = code $ emitDataLits (mkCmmDataLabel pkg cl_label) lits
 841   where  lits = mkStaticClosure (mkCmmInfoLabel pkg info) dontCareCCS payload [] [] []
 842
 843 foreignCall
 844         :: String
 845         -> [ExtFCode HintedCmmFormal]
 846         -> ExtFCode CmmExpr
 847         -> [ExtFCode HintedCmmActual]
 848         -> Maybe [GlobalReg]
 849         -> CmmSafety
 850         -> CmmReturnInfo
 851         -> P ExtCode
 852 foreignCall conv_string results_code expr_code args_code vols safety ret
 853   = do  convention <- case conv_string of
 854           "C" -> return CCallConv
 855           "stdcall" -> return StdCallConv
 856           "C--" -> return CmmCallConv
 857           _ -> fail ("unknown calling convention: " ++ conv_string)
 858         return $ do
 859           results <- sequence results_code
 860           expr <- expr_code
 861           args <- sequence args_code
 862           --code (stmtC (CmmCall (CmmCallee expr convention) results args safety))
 863           case convention of
 864             -- Temporary hack so at least some functions are CmmSafe
 865             CmmCallConv -> code (stmtC (CmmCall (CmmCallee expr convention) results args safety ret))
 866             _ ->
 867               let expr' = adjCallTarget convention expr args in
 868               case safety of
 869               CmmUnsafe ->
 870                 code (emitForeignCall' PlayRisky results
 871                    (CmmCallee expr' convention) args vols NoC_SRT ret)
 872               CmmSafe srt ->
 873                 code (emitForeignCall' (PlaySafe unused) results
 874                    (CmmCallee expr' convention) args vols NoC_SRT ret) where
 875                 unused = panic "not used by emitForeignCall'"
 876               CmmInterruptible ->
 877                 code (emitForeignCall' PlayInterruptible results
 878                    (CmmCallee expr' convention) args vols NoC_SRT ret)
 879
 880 adjCallTarget :: CCallConv -> CmmExpr -> [CmmHinted CmmExpr] -> CmmExpr
 881 #ifdef mingw32_TARGET_OS
 882 -- On Windows, we have to add the '@N' suffix to the label when making
 883 -- a call with the stdcall calling convention.
 884 adjCallTarget StdCallConv (CmmLit (CmmLabel lbl)) args
 885   = CmmLit (CmmLabel (addLabelSize lbl (sum (map size args))))
 886   where size (CmmHinted e _) = max wORD_SIZE (widthInBytes (typeWidth (cmmExprType e)))
 887                  -- c.f. CgForeignCall.emitForeignCall
 888 #endif
 889 adjCallTarget _ expr _
 890   = expr
 891
 892 primCall
 893         :: [ExtFCode HintedCmmFormal]
 894         -> FastString
 895         -> [ExtFCode HintedCmmActual]
 896         -> Maybe [GlobalReg]
 897         -> CmmSafety
 898         -> P ExtCode
 899 primCall results_code name args_code vols safety
 900   = case lookupUFM callishMachOps name of
 901         Nothing -> fail ("unknown primitive " ++ unpackFS name)
 902         Just p  -> return $ do
 903                 results <- sequence results_code
 904                 args <- sequence args_code
 905                 case safety of
 906                   CmmUnsafe ->
 907                     code (emitForeignCall' PlayRisky results
 908                       (CmmPrim p) args vols NoC_SRT CmmMayReturn)
 909                   CmmSafe srt ->
 910                     code (emitForeignCall' (PlaySafe unused) results
 911                       (CmmPrim p) args vols NoC_SRT CmmMayReturn) where
 912                     unused = panic "not used by emitForeignCall'"
 913                   CmmInterruptible ->
 914                     code (emitForeignCall' PlayInterruptible results
 915                       (CmmPrim p) args vols NoC_SRT CmmMayReturn)
 916
 917 doStore :: CmmType -> ExtFCode CmmExpr  -> ExtFCode CmmExpr -> ExtCode
 918 doStore rep addr_code val_code
 919   = do addr <- addr_code
 920        val <- val_code
 921         -- if the specified store type does not match the type of the expr
 922         -- on the rhs, then we insert a coercion that will cause the type
 923         -- mismatch to be flagged by cmm-lint.  If we don't do this, then
 924         -- the store will happen at the wrong type, and the error will not
 925         -- be noticed.
 926        let val_width = typeWidth (cmmExprType val)
 927            rep_width = typeWidth rep
 928        let coerce_val
 929                 | val_width /= rep_width = CmmMachOp (MO_UU_Conv val_width rep_width) [val]
 930                 | otherwise              = val
 931        stmtEC (CmmStore addr coerce_val)
 932
 933 -- Return an unboxed tuple.
 934 emitRetUT :: [(CgRep,CmmExpr)] -> Code
 935 emitRetUT args = do
 936   tickyUnboxedTupleReturn (length args)  -- TICK
 937   (sp, stmts) <- pushUnboxedTuple 0 args
 938   emitSimultaneously stmts -- NB. the args might overlap with the stack slots
 939                            -- or regs that we assign to, so better use
 940                            -- simultaneous assignments here (#3546)
 941   when (sp /= 0) $ stmtC (CmmAssign spReg (cmmRegOffW spReg (-sp)))
 942   stmtC (CmmJump (entryCode (CmmLoad (cmmRegOffW spReg sp) bWord)) [])
 943   -- TODO (when using CPS): emitStmt (CmmReturn (map snd args))
 944
 945 -- -----------------------------------------------------------------------------
 946 -- If-then-else and boolean expressions
 947
 948 data BoolExpr
 949   = BoolExpr `BoolAnd` BoolExpr
 950   | BoolExpr `BoolOr`  BoolExpr
 951   | BoolNot BoolExpr
 952   | BoolTest CmmExpr
 953
 954 -- ToDo: smart constructors which simplify the boolean expression.
 955
 956 cmmIfThenElse cond then_part else_part = do
 957      then_id <- code newLabelC
 958      join_id <- code newLabelC
 959      c <- cond
 960      emitCond c then_id
 961      else_part
 962      stmtEC (CmmBranch join_id)
 963      code (labelC then_id)
 964      then_part
 965      -- fall through to join
 966      code (labelC join_id)
 967
 968 cmmRawIf cond then_id = do
 969     c <- cond
 970     emitCond c then_id
 971
 972 -- 'emitCond cond true_id'  emits code to test whether the cond is true,
 973 -- branching to true_id if so, and falling through otherwise.
 974 emitCond (BoolTest e) then_id = do
 975   stmtEC (CmmCondBranch e then_id)
 976 emitCond (BoolNot (BoolTest (CmmMachOp op args))) then_id
 977   | Just op' <- maybeInvertComparison op
 978   = emitCond (BoolTest (CmmMachOp op' args)) then_id
 979 emitCond (BoolNot e) then_id = do
 980   else_id <- code newLabelC
 981   emitCond e else_id
 982   stmtEC (CmmBranch then_id)
 983   code (labelC else_id)
 984 emitCond (e1 `BoolOr` e2) then_id = do
 985   emitCond e1 then_id
 986   emitCond e2 then_id
 987 emitCond (e1 `BoolAnd` e2) then_id = do
 988         -- we'd like to invert one of the conditionals here to avoid an
 989         -- extra branch instruction, but we can't use maybeInvertComparison
 990         -- here because we can't look too closely at the expression since
 991         -- we're in a loop.
 992   and_id <- code newLabelC
 993   else_id <- code newLabelC
 994   emitCond e1 and_id
 995   stmtEC (CmmBranch else_id)
 996   code (labelC and_id)
 997   emitCond e2 then_id
 998   code (labelC else_id)
 999
1000
1001 -- -----------------------------------------------------------------------------
1002 -- Table jumps
1003
1004 -- We use a simplified form of C-- switch statements for now.  A
1005 -- switch statement always compiles to a table jump.  Each arm can
1006 -- specify a list of values (not ranges), and there can be a single
1007 -- default branch.  The range of the table is given either by the
1008 -- optional range on the switch (eg. switch [0..7] {...}), or by
1009 -- the minimum/maximum values from the branches.
1010
1011 doSwitch :: Maybe (Int,Int) -> ExtFCode CmmExpr -> [([Int],Either BlockId ExtCode)]
1012          -> Maybe ExtCode -> ExtCode
1013 doSwitch mb_range scrut arms deflt
1014    = do
1015         -- Compile code for the default branch
1016         dflt_entry <-
1017                 case deflt of
1018                   Nothing -> return Nothing
1019                   Just e  -> do b <- forkLabelledCodeEC e; return (Just b)
1020
1021         -- Compile each case branch
1022         table_entries <- mapM emitArm arms
1023
1024         -- Construct the table
1025         let
1026             all_entries = concat table_entries
1027             ixs = map fst all_entries
1028             (min,max)
1029                 | Just (l,u) <- mb_range = (l,u)
1030                 | otherwise              = (minimum ixs, maximum ixs)
1031
1032             entries = elems (accumArray (\_ a -> Just a) dflt_entry (min,max)
1033                                 all_entries)
1034         expr <- scrut
1035         -- ToDo: check for out of range and jump to default if necessary
1036         stmtEC (CmmSwitch expr entries)
1037    where
1038         emitArm :: ([Int],Either BlockId ExtCode) -> ExtFCode [(Int,BlockId)]
1039         emitArm (ints,Left blockid) = return [ (i,blockid) | i <- ints ]
1040         emitArm (ints,Right code) = do
1041            blockid <- forkLabelledCodeEC code
1042            return [ (i,blockid) | i <- ints ]
1043
1044 -- -----------------------------------------------------------------------------
1045 -- Putting it all together
1046
1047 -- The initial environment: we define some constants that the compiler
1048 -- knows about here.
1049 initEnv :: Env
1050 initEnv = listToUFM [
1051   ( fsLit "SIZEOF_StgHeader",
1052     Var (CmmLit (CmmInt (fromIntegral (fixedHdrSize * wORD_SIZE)) wordWidth) )),
1053   ( fsLit "SIZEOF_StgInfoTable",
1054     Var (CmmLit (CmmInt (fromIntegral stdInfoTableSizeB) wordWidth) ))
1055   ]
1056
1057 parseCmmFile :: DynFlags -> FilePath -> IO (Messages, Maybe Cmm)
1058 parseCmmFile dflags filename = do
1059   showPass dflags "ParseCmm"
1060   buf <- hGetStringBuffer filename
1061   let
1062         init_loc = mkSrcLoc (mkFastString filename) 1 1
1063         init_state = (mkPState dflags buf init_loc) { lex_state = [0] }
1064                 -- reset the lex_state: the Lexer monad leaves some stuff
1065                 -- in there we don't want.
1066   case unP cmmParse init_state of
1067     PFailed span err -> do
1068         let msg = mkPlainErrMsg span err
1069         return ((emptyBag, unitBag msg), Nothing)
1070     POk pst code -> do
1071         cmm <- initC dflags no_module (getCmm (unEC code initEnv [] >> return ()))
1072         let ms = getMessages pst
1073         if (errorsFound dflags ms)
1074          then return (ms, Nothing)
1075          else do
1076            dumpIfSet_dyn dflags Opt_D_dump_cmm "Cmm" (ppr cmm)
1077            return (ms, Just cmm)
1078   where
1079         no_module = panic "parseCmmFile: no module"
1080 }