compiler/cmm/CmmProcPointZ.hs

   1 module CmmProcPointZ
   2     ( ProcPointSet, Status(..)
   3     , callProcPoints, minimalProcPointSet
   4     , addProcPointProtocols, splitAtProcPoints, procPointAnalysis
   5     )
   6 where
   7
   8 import Prelude hiding (zip, unzip, last)
   9
  10 import BlockId
  11 import CLabel
  12 import Cmm hiding (blockId)
  13 import CmmContFlowOpt
  14 import CmmInfo
  15 import CmmLiveZ
  16 import CmmTx
  17 import DFMonad
  18 import FiniteMap
  19 import Data.List (sortBy)
  20 import Maybes
  21 import MkZipCfg
  22 import MkZipCfgCmm hiding (CmmBlock, CmmGraph, CmmTopZ)
  23 import Control.Monad
  24 import Outputable
  25 import UniqSet
  26 import UniqSupply
  27 import ZipCfg
  28 import ZipCfgCmmRep
  29 import ZipDataflow
  30
  31 -- Compute a minimal set of proc points for a control-flow graph.
  32
  33 -- Determine a protocol for each proc point (which live variables will
  34 -- be passed as arguments and which will be on the stack).
  35
  36 {-
  37 A proc point is a basic block that, after CPS transformation, will
  38 start a new function.  The entry block of the original function is a
  39 proc point, as is the continuation of each function call.
  40 A third kind of proc point arises if we want to avoid copying code.
  41 Suppose we have code like the following:
  42
  43   f() {
  44     if (...) { ..1..; call foo(); ..2..}
  45     else     { ..3..; call bar(); ..4..}
  46     x = y + z;
  47     return x;
  48   }
  49
  50 The statement 'x = y + z' can be reached from two different proc
  51 points: the continuations of foo() and bar().  We would prefer not to
  52 put a copy in each continuation; instead we would like 'x = y + z' to
  53 be the start of a new procedure to which the continuations can jump:
  54
  55   f_cps () {
  56     if (...) { ..1..; push k_foo; jump foo_cps(); }
  57     else     { ..3..; push k_bar; jump bar_cps(); }
  58   }
  59   k_foo() { ..2..; jump k_join(y, z); }
  60   k_bar() { ..4..; jump k_join(y, z); }
  61   k_join(y, z) { x = y + z; return x; }
  62
  63 You might think then that a criterion to make a node a proc point is
  64 that it is directly reached by two distinct proc points.  (Note
  65 [Direct reachability].)  But this criterion is a bit too simple; for
  66 example, 'return x' is also reached by two proc points, yet there is
  67 no point in pulling it out of k_join.  A good criterion would be to
  68 say that a node should be made a proc point if it is reached by a set
  69 of proc points that is different than its immediate dominator.  NR
  70 believes this criterion can be shown to produce a minimum set of proc
  71 points, and given a dominator tree, the proc points can be chosen in
  72 time linear in the number of blocks.  Lacking a dominator analysis,
  73 however, we turn instead to an iterative solution, starting with no
  74 proc points and adding them according to these rules:
  75
  76   1. The entry block is a proc point.
  77   2. The continuation of a call is a proc point.
  78   3. A node is a proc point if it is directly reached by more proc
  79      points than one of its predecessors.
  80
  81 Because we don't understand the problem very well, we apply rule 3 at
  82 most once per iteration, then recompute the reachability information.
  83 (See Note [No simple dataflow].)  The choice of the new proc point is
  84 arbitrary, and I don't know if the choice affects the final solution,
  85 so I don't know if the number of proc points chosen is the
  86 minimum---but the set will be minimal.
  87 -}
  88
  89 type ProcPointSet = BlockSet
  90
  91 data Status
  92   = ReachedBy ProcPointSet  -- set of proc points that directly reach the block
  93   | ProcPoint               -- this block is itself a proc point
  94
  95 instance Outputable Status where
  96   ppr (ReachedBy ps)
  97       | isEmptyBlockSet ps = text "<not-reached>"
  98       | otherwise = text "reached by" <+>
  99                     (hsep $ punctuate comma $ map ppr $ blockSetToList ps)
 100   ppr ProcPoint = text "<procpt>"
 101
 102
 103 lattice :: DataflowLattice Status
 104 lattice = DataflowLattice "direct proc-point reachability" unreached add_to False
 105     where unreached = ReachedBy emptyBlockSet
 106           add_to _ ProcPoint = noTx ProcPoint
 107           add_to ProcPoint _ = aTx ProcPoint -- aTx because of previous case again
 108           add_to (ReachedBy p) (ReachedBy p') =
 109               let union = unionBlockSets p p'
 110               in  if sizeBlockSet union > sizeBlockSet p' then
 111                       aTx (ReachedBy union)
 112                   else
 113                       noTx (ReachedBy p')
 114 --------------------------------------------------
 115 -- transfer equations
 116
 117 forward :: ForwardTransfers Middle Last Status
 118 forward = ForwardTransfers first middle last exit
 119     where first id ProcPoint = ReachedBy $ unitBlockSet id
 120           first  _ x = x
 121           middle _ x = x
 122           last (LastCall _ (Just id) _ _ _) _ = LastOutFacts [(id, ProcPoint)]
 123           last l x = LastOutFacts $ map (\id -> (id, x)) (succs l)
 124           exit x   = x
 125
 126 -- It is worth distinguishing two sets of proc points:
 127 -- those that are induced by calls in the original graph
 128 -- and those that are introduced because they're reachable from multiple proc points.
 129 callProcPoints      :: CmmGraph -> ProcPointSet
 130 callProcPoints g = fold_blocks add (unitBlockSet (lg_entry g)) g
 131   where add b set = case last $ unzip b of
 132                       LastOther (LastCall _ (Just k) _ _ _) -> extendBlockSet set k
 133                       _ -> set
 134
 135 minimalProcPointSet :: ProcPointSet -> CmmGraph -> FuelMonad ProcPointSet
 136 -- Given the set of successors of calls (which must be proc-points)
 137 -- figure ou the minimal set of necessary proc-points
 138 minimalProcPointSet callProcPoints g = extendPPSet g (postorder_dfs g) callProcPoints
 139
 140 type PPFix = FuelMonad (ForwardFixedPoint Middle Last Status ())
 141
 142 procPointAnalysis :: ProcPointSet -> CmmGraph -> FuelMonad (BlockEnv Status)
 143 -- Once you know what the proc-points are, figure out
 144 -- what proc-points each block is reachable from
 145 procPointAnalysis procPoints g =
 146   let addPP env id = extendBlockEnv env id ProcPoint
 147       initProcPoints = foldl addPP emptyBlockEnv (blockSetToList procPoints)
 148   in liftM zdfFpFacts $
 149         (zdfSolveFrom initProcPoints "proc-point reachability" lattice
 150                               forward (fact_bot lattice) $ graphOfLGraph g :: PPFix)
 151
 152 extendPPSet :: CmmGraph -> [CmmBlock] -> ProcPointSet -> FuelMonad ProcPointSet
 153 extendPPSet g blocks procPoints =
 154     do env <- procPointAnalysis procPoints g
 155        let add block pps = let id = blockId block
 156                            in  case lookupBlockEnv env id of
 157                                  Just ProcPoint -> extendBlockSet pps id
 158                                  _ -> pps
 159            procPoints' = fold_blocks add emptyBlockSet g
 160            newPoints = mapMaybe ppSuccessor blocks
 161            newPoint  = listToMaybe newPoints
 162            ppSuccessor b@(Block bid _) =
 163                let nreached id = case lookupBlockEnv env id `orElse`
 164                                        pprPanic "no ppt" (ppr id <+> ppr b) of
 165                                    ProcPoint -> 1
 166                                    ReachedBy ps -> sizeBlockSet ps
 167                    block_procpoints = nreached bid
 168                    -- | Looking for a successor of b that is reached by
 169                    -- more proc points than b and is not already a proc
 170                    -- point.  If found, it can become a proc point.
 171                    newId succ_id = not (elemBlockSet succ_id procPoints') &&
 172                                    nreached succ_id > block_procpoints
 173                in  listToMaybe $ filter newId $ succs b
 174 {-
 175        case newPoints of
 176            []  -> return procPoints'
 177            pps -> extendPPSet g blocks
 178                     (foldl extendBlockSet procPoints' pps)
 179 -}
 180        case newPoint of Just id ->
 181                           if elemBlockSet id procPoints' then panic "added old proc pt"
 182                           else extendPPSet g blocks (extendBlockSet procPoints' id)
 183                         Nothing -> return procPoints'
 184
 185
 186 ------------------------------------------------------------------------
 187 --                    Computing Proc-Point Protocols                  --
 188 ------------------------------------------------------------------------
 189
 190 {-
 191
 192 There is one major trick, discovered by Michael Adams, which is that
 193 we want to choose protocols in a way that enables us to optimize away
 194 some continuations.  The optimization is very much like branch-chain
 195 elimination, except that it involves passing results as well as
 196 control.  The idea is that if a call's continuation k does nothing but
 197 CopyIn its results and then goto proc point P, the call's continuation
 198 may be changed to P, *provided* P's protocol is identical to the
 199 protocol for the CopyIn.  We choose protocols to make this so.
 200
 201 Here's an explanatory example; we begin with the source code (lines
 202 separate basic blocks):
 203
 204   ..1..;
 205   x, y = g();
 206   goto P;
 207   -------
 208   P: ..2..;
 209
 210 Zipperization converts this code as follows:
 211
 212   ..1..;
 213   call g() returns to k;
 214   -------
 215   k: CopyIn(x, y);
 216      goto P;
 217   -------
 218   P: ..2..;
 219
 220 What we'd like to do is assign P the same CopyIn protocol as k, so we
 221 can eliminate k:
 222
 223   ..1..;
 224   call g() returns to P;
 225   -------
 226   P: CopyIn(x, y); ..2..;
 227
 228 Of course, P may be the target of more than one continuation, and
 229 different continuations may have different protocols.  Michael Adams
 230 implemented a voting mechanism, but he thinks a simple greedy
 231 algorithm would be just as good, so that's what we do.
 232
 233 -}
 234
 235 data Protocol = Protocol Convention CmmFormals Area
 236   deriving Eq
 237 instance Outputable Protocol where
 238   ppr (Protocol c fs a) = text "Protocol" <+> ppr c <+> ppr fs <+> ppr a
 239
 240 -- | Function 'optimize_calls' chooses protocols only for those proc
 241 -- points that are relevant to the optimization explained above.
 242 -- The others are assigned by 'add_unassigned', which is not yet clever.
 243
 244 addProcPointProtocols :: ProcPointSet -> ProcPointSet -> CmmGraph -> FuelMonad CmmGraph
 245 addProcPointProtocols callPPs procPoints g =
 246   do liveness <- cmmLivenessZ g
 247      (protos, g') <- optimize_calls liveness g
 248      blocks'' <- add_CopyOuts protos procPoints g'
 249      return $ LGraph (lg_entry g) blocks''
 250     where optimize_calls liveness g =  -- see Note [Separate Adams optimization]
 251             do let (protos, blocks') =
 252                        fold_blocks maybe_add_call (init_protocols, emptyBlockEnv) g
 253                    protos' = add_unassigned liveness procPoints protos
 254                blocks <- add_CopyIns callPPs protos' blocks'
 255                let g' = LGraph (lg_entry g) (mkBlockEnv (map withKey (concat blocks)))
 256                    withKey b@(Block bid _) = (bid, b)
 257                return (protos', runTx removeUnreachableBlocksZ g')
 258           maybe_add_call :: CmmBlock -> (BlockEnv Protocol, BlockEnv CmmBlock)
 259                          -> (BlockEnv Protocol, BlockEnv CmmBlock)
 260           -- ^ If the block is a call whose continuation goes to a proc point
 261           -- whose protocol either matches the continuation's or is not yet set,
 262           -- redirect the call (cf 'newblock') and set the protocol if necessary
 263           maybe_add_call block (protos, blocks) =
 264               case goto_end $ unzip block of
 265                 (h, LastOther (LastCall tgt (Just k) args res s))
 266                     | Just proto <- lookupBlockEnv protos k,
 267                       Just pee   <- branchesToProcPoint k
 268                     -> let newblock = zipht h (tailOfLast (LastCall tgt (Just pee)
 269                                                                     args res s))
 270                            changed_blocks   = insertBlock newblock blocks
 271                            unchanged_blocks = insertBlock block    blocks
 272                        in case lookupBlockEnv protos pee of
 273                             Nothing -> (extendBlockEnv protos pee proto,changed_blocks)
 274                             Just proto' ->
 275                               if proto == proto' then (protos, changed_blocks)
 276                               else (protos, unchanged_blocks)
 277                 _ -> (protos, insertBlock block blocks)
 278
 279           branchesToProcPoint :: BlockId -> Maybe BlockId
 280           -- ^ Tells whether the named block is just a branch to a proc point
 281           branchesToProcPoint id =
 282               let (Block _ t) = lookupBlockEnv (lg_blocks g) id `orElse`
 283                                     panic "branch out of graph"
 284               in case t of
 285                    ZLast (LastOther (LastBranch pee))
 286                        | elemBlockSet pee procPoints -> Just pee
 287                    _ -> Nothing
 288           init_protocols = fold_blocks maybe_add_proto emptyBlockEnv g
 289           maybe_add_proto :: CmmBlock -> BlockEnv Protocol -> BlockEnv Protocol
 290           --maybe_add_proto (Block id (ZTail (CopyIn c _ fs _srt) _)) env =
 291           --    extendBlockEnv env id (Protocol c fs $ toArea id fs)
 292           maybe_add_proto _ env = env
 293           -- JD: Is this proto stuff even necessary, now that we have
 294           -- common blockification?
 295
 296 -- | For now, following a suggestion by Ben Lippmeier, we pass all
 297 -- live variables as arguments, hoping that a clever register
 298 -- allocator might help.
 299
 300 add_unassigned :: BlockEnv CmmLive -> ProcPointSet -> BlockEnv Protocol ->
 301                   BlockEnv Protocol
 302 add_unassigned = pass_live_vars_as_args
 303
 304 pass_live_vars_as_args :: BlockEnv CmmLive -> ProcPointSet ->
 305                           BlockEnv Protocol -> BlockEnv Protocol
 306 pass_live_vars_as_args _liveness procPoints protos = protos'
 307   where protos' = foldBlockSet addLiveVars protos procPoints
 308         addLiveVars :: BlockId -> BlockEnv Protocol -> BlockEnv Protocol
 309         addLiveVars id protos =
 310             case lookupBlockEnv protos id of
 311               Just _  -> protos
 312               Nothing -> let live = emptyRegSet
 313                                     --lookupBlockEnv _liveness id `orElse`
 314                                     --panic ("no liveness at block " ++ show id)
 315                              formals = uniqSetToList live
 316                              prot = Protocol Private formals $ CallArea $ Young id
 317                          in  extendBlockEnv protos id prot
 318
 319
 320 -- | Add copy-in instructions to each proc point that did not arise from a call
 321 -- instruction. (Proc-points that arise from calls already have their copy-in instructions.)
 322
 323 add_CopyIns :: ProcPointSet -> BlockEnv Protocol -> BlockEnv CmmBlock ->
 324                FuelMonad [[CmmBlock]]
 325 add_CopyIns callPPs protos blocks =
 326   liftUniq $ mapM maybe_insert_CopyIns (blockEnvToList blocks)
 327     where maybe_insert_CopyIns (_, b@(Block id t))
 328            | not $ elemBlockSet id callPPs
 329            = case lookupBlockEnv protos id of
 330                Just (Protocol c fs _area) ->
 331                  do LGraph _ blocks <-
 332                       lgraphOfAGraph (mkLabel id <*> copyInSlot c fs <*> mkZTail t)
 333                     return (map snd $ blockEnvToList blocks)
 334                Nothing -> return [b]
 335            | otherwise = return [b]
 336
 337 -- | Add a CopyOut node before each procpoint.
 338 -- If the predecessor is a call, then the copy outs should already be done by the callee.
 339 -- Note: If we need to add copy-out instructions, they may require stack space,
 340 -- so we accumulate a map from the successors to the necessary stack space,
 341 -- then update the successors after we have finished inserting the copy-outs.
 342
 343 add_CopyOuts :: BlockEnv Protocol -> ProcPointSet -> CmmGraph ->
 344                 FuelMonad (BlockEnv CmmBlock)
 345 add_CopyOuts protos procPoints g = fold_blocks mb_copy_out (return emptyBlockEnv) g
 346     where mb_copy_out :: CmmBlock -> FuelMonad (BlockEnv CmmBlock) ->
 347                                      FuelMonad (BlockEnv CmmBlock)
 348           mb_copy_out b@(Block bid _) z | bid == lg_entry g = skip b z
 349           mb_copy_out b z =
 350             case last $ unzip b of
 351               LastOther (LastCall _ _ _ _ _) -> skip b z -- copy out done by callee
 352               _ -> copy_out b z
 353           copy_out b z = fold_succs trySucc b init >>= finish
 354             where init = z >>= (\bmap -> return (b, bmap))
 355                   trySucc succId z =
 356                     if elemBlockSet succId procPoints then
 357                       case lookupBlockEnv protos succId of
 358                         Nothing -> z
 359                         Just (Protocol c fs _area) -> insert z succId $ copyOutSlot c fs
 360                     else z
 361                   insert z succId m =
 362                     do (b, bmap) <- z
 363                        (b, bs)   <- insertBetween b m succId
 364                        -- pprTrace "insert for succ" (ppr succId <> ppr m) $ do
 365                        return $ (b, foldl (flip insertBlock) bmap bs)
 366                   finish (b@(Block bid _), bmap) =
 367                     return $ (extendBlockEnv bmap bid b)
 368           skip b@(Block bid _) bs =
 369             bs >>= (\bmap -> return (extendBlockEnv bmap bid b))
 370
 371 -- At this point, we have found a set of procpoints, each of which should be
 372 -- the entry point of a procedure.
 373 -- Now, we create the procedure for each proc point,
 374 -- which requires that we:
 375 -- 1. build a map from proc points to the blocks reachable from the proc point
 376 -- 2. turn each branch to a proc point into a jump
 377 -- 3. turn calls and returns into jumps
 378 -- 4. build info tables for the procedures -- and update the info table for
 379 --    the SRTs in the entry procedure as well.
 380 -- Input invariant: A block should only be reachable from a single ProcPoint.
 381 splitAtProcPoints :: CLabel -> ProcPointSet-> ProcPointSet -> BlockEnv Status ->
 382                      CmmTopZ -> FuelMonad [CmmTopZ]
 383 splitAtProcPoints entry_label callPPs procPoints procMap
 384                   (CmmProc (CmmInfo gc upd_fr info_tbl) top_l top_args
 385                            (stackInfo, g@(LGraph entry blocks))) =
 386   do -- Build a map from procpoints to the blocks they reach
 387      let addBlock b@(Block bid _) graphEnv =
 388            case lookupBlockEnv procMap bid of
 389              Just ProcPoint -> add graphEnv bid bid b
 390              Just (ReachedBy set) ->
 391                case blockSetToList set of
 392                  []   -> graphEnv
 393                  [id] -> add graphEnv id bid b
 394                  _    -> panic "Each block should be reachable from only one ProcPoint"
 395              Nothing -> pprPanic "block not reached by a proc point?" (ppr bid)
 396          add graphEnv procId bid b = extendBlockEnv graphEnv procId graph'
 397                where graph  = lookupBlockEnv graphEnv procId `orElse` emptyBlockEnv
 398                      graph' = extendBlockEnv graph bid b
 399      graphEnv <- return $ fold_blocks addBlock emptyBlockEnv g
 400      -- Build a map from proc point BlockId to labels for their new procedures
 401      -- Due to common blockification, we may overestimate the set of procpoints.
 402      let add_label map pp = return $ addToFM map pp lbl
 403            where lbl = if pp == entry then entry_label else blockLbl pp
 404      procLabels <- foldM add_label emptyFM
 405                          (filter (elemBlockEnv blocks) (blockSetToList procPoints))
 406      -- For each procpoint, we need to know the SP offset on entry.
 407      -- If the procpoint is:
 408      --  - continuation of a call, the SP offset is in the call
 409      --  - otherwise, 0 -- no overflow for passing those variables
 410      let add_sp_off b env =
 411            case last (unzip b) of
 412              LastOther (LastCall {cml_cont = Just succ, cml_ret_args = off,
 413                                   cml_ret_off = updfr_off}) ->
 414                extendBlockEnv env succ (off, updfr_off)
 415              _ -> env
 416          spEntryMap = fold_blocks add_sp_off (mkBlockEnv [(entry, stackInfo)]) g
 417          getStackInfo id = lookupBlockEnv spEntryMap id `orElse` (0, Nothing)
 418      -- In each new graph, add blocks jumping off to the new procedures,
 419      -- and replace branches to procpoints with branches to the jump-off blocks
 420      let add_jump_block (env, bs) (pp, l) =
 421            do bid <- liftM mkBlockId getUniqueM
 422               let b = Block bid (ZLast (LastOther jump))
 423                   (argSpace, _) = getStackInfo pp
 424                   jump = LastCall (CmmLit (CmmLabel l')) Nothing argSpace 0 Nothing
 425                   l' = if elemBlockSet pp callPPs then entryLblToInfoLbl l else l
 426               return (extendBlockEnv env pp bid, b : bs)
 427          add_jumps (newGraphEnv) (ppId, blockEnv) =
 428            do let needed_jumps = -- find which procpoints we currently branch to
 429                     foldBlockEnv' add_if_branch_to_pp [] blockEnv
 430                   add_if_branch_to_pp block rst =
 431                     case last (unzip block) of
 432                       LastOther (LastBranch id) -> add_if_pp id rst
 433                       LastOther (LastCondBranch _ ti fi) ->
 434                         add_if_pp ti (add_if_pp fi rst)
 435                       LastOther (LastSwitch _ tbl) -> foldr add_if_pp rst (catMaybes tbl)
 436                       _ -> rst
 437                   add_if_pp id rst = case lookupFM procLabels id of
 438                                        Just x -> (id, x) : rst
 439                                        Nothing -> rst
 440               (jumpEnv, jumpBlocks) <-
 441                  foldM add_jump_block (emptyBlockEnv, []) needed_jumps
 442                   -- update the entry block
 443               let b = expectJust "block in env" $ lookupBlockEnv blockEnv ppId
 444                   off = getStackInfo ppId
 445                   blockEnv' = extendBlockEnv blockEnv ppId b
 446                   -- replace branches to procpoints with branches to jumps
 447                   LGraph _ blockEnv'' = replaceBranches jumpEnv $ LGraph ppId blockEnv'
 448                   -- add the jump blocks to the graph
 449                   blockEnv''' = foldl (flip insertBlock) blockEnv'' jumpBlocks
 450               let g' = (off, LGraph ppId blockEnv''')
 451               -- pprTrace "g' pre jumps" (ppr g') $ do
 452               return (extendBlockEnv newGraphEnv ppId g')
 453      graphEnv <- foldM add_jumps emptyBlockEnv $ blockEnvToList graphEnv
 454      let to_proc (bid, g) | elemBlockSet bid callPPs =
 455            if bid == entry then
 456              CmmProc (CmmInfo gc upd_fr info_tbl) top_l top_args (replacePPIds g)
 457            else
 458              CmmProc emptyContInfoTable lbl [] (replacePPIds g)
 459            where lbl = expectJust "pp label" $ lookupFM procLabels bid
 460          to_proc (bid, g) =
 461            CmmProc (CmmInfo Nothing Nothing CmmNonInfoTable) lbl [] (replacePPIds g)
 462              where lbl = expectJust "pp label" $ lookupFM procLabels bid
 463          -- References to procpoint IDs can now be replaced with the infotable's label
 464          replacePPIds (x, g) = (x, map_nodes id (mapExpMiddle repl) (mapExpLast repl) g)
 465            where repl e@(CmmLit (CmmBlock bid)) =
 466                    case lookupFM procLabels bid of
 467                      Just l  -> CmmLit (CmmLabel (entryLblToInfoLbl l))
 468                      Nothing -> e
 469                  repl e = e
 470      -- The C back end expects to see return continuations before the call sites.
 471      -- Here, we sort them in reverse order -- it gets reversed later.
 472      let (_, block_order) = foldl add_block_num (0::Int, emptyBlockEnv) (postorder_dfs g)
 473          add_block_num (i, map) (Block bid _) = (i+1, extendBlockEnv map bid i)
 474          sort_fn (bid, _) (bid', _) =
 475            compare (expectJust "block_order" $ lookupBlockEnv block_order bid)
 476                    (expectJust "block_order" $ lookupBlockEnv block_order bid')
 477      procs <- return $ map to_proc $ sortBy sort_fn $ blockEnvToList graphEnv
 478      return -- pprTrace "procLabels" (ppr procLabels)
 479             -- pprTrace "splitting graphs" (ppr procs)
 480             procs
 481 splitAtProcPoints _ _ _ _ t@(CmmData _ _) = return [t]
 482
 483 ----------------------------------------------------------------
 484
 485 {-
 486 Note [Direct reachability]
 487
 488 Block B is directly reachable from proc point P iff control can flow
 489 from P to B without passing through an intervening proc point.
 490 -}
 491
 492 ----------------------------------------------------------------
 493
 494 {-
 495 Note [No simple dataflow]
 496
 497 Sadly, it seems impossible to compute the proc points using a single
 498 dataflow pass.  One might attempt to use this simple lattice:
 499
 500   data Location = Unknown
 501                 | InProc BlockId -- node is in procedure headed by the named proc point
 502                 | ProcPoint      -- node is itself a proc point
 503
 504 At a join, a node in two different blocks becomes a proc point.
 505 The difficulty is that the change of information during iterative
 506 computation may promote a node prematurely.  Here's a program that
 507 illustrates the difficulty:
 508
 509   f () {
 510   entry:
 511     ....
 512   L1:
 513     if (...) { ... }
 514     else { ... }
 515
 516   L2: if (...) { g(); goto L1; }
 517       return x + y;
 518   }
 519
 520 The only proc-point needed (besides the entry) is L1.  But in an
 521 iterative analysis, consider what happens to L2.  On the first pass
 522 through, it rises from Unknown to 'InProc entry', but when L1 is
 523 promoted to a proc point (because it's the successor of g()), L1's
 524 successors will be promoted to 'InProc L1'.  The problem hits when the
 525 new fact 'InProc L1' flows into L2 which is already bound to 'InProc entry'.
 526 The join operation makes it a proc point when in fact it needn't be,
 527 because its immediate dominator L1 is already a proc point and there
 528 are no other proc points that directly reach L2.
 529 -}
 530
 531
 532
 533 {- Note [Separate Adams optimization]
 534 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 535 It may be worthwhile to attempt the Adams optimization by rewriting
 536 the graph before the assignment of proc-point protocols.  Here are a
 537 couple of rules:
 538
 539   g() returns to k;                    g() returns to L;
 540   k: CopyIn c ress; goto L:
 541    ...                        ==>        ...
 542   L: // no CopyIn node here            L: CopyIn c ress;
 543
 544
 545 And when c == c' and ress == ress', this also:
 546
 547   g() returns to k;                    g() returns to L;
 548   k: CopyIn c ress; goto L:
 549    ...                        ==>        ...
 550   L: CopyIn c' ress'                   L: CopyIn c' ress' ;
 551
 552 In both cases the goal is to eliminate k.
 553 -}