compiler/codeGen/CgExpr.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 module CgExpr ( cgExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import Constants
  12 import StgSyn
  13 import CgMonad
  14
  15 import CostCentre
  16 import SMRep
  17 import CoreSyn
  18 import CgProf
  19 import CgHeapery
  20 import CgBindery
  21 import CgCase
  22 import CgClosure
  23 import CgCon
  24 import CgLetNoEscape
  25 import CgTailCall
  26 import CgInfoTbls
  27 import CgForeignCall
  28 import CgPrimOp
  29 import CgHpc
  30 import CgUtils
  31 import ClosureInfo
  32 import Cmm
  33 import CmmUtils
  34 import VarSet
  35 import Literal
  36 import PrimOp
  37 import Id
  38 import TyCon
  39 import Type
  40 import Maybes
  41 import ListSetOps
  42 import BasicTypes
  43 import Util
  44 import Outputable
  45 \end{code}
  46
  47 This module provides the support code for @StgToAbstractC@ to deal
  48 with STG {\em expressions}.  See also @CgClosure@, which deals
  49 with closures, and @CgCon@, which deals with constructors.
  50
  51 \begin{code}
  52 cgExpr  :: StgExpr              -- input
  53         -> Code                 -- output
  54 \end{code}
  55
  56 %********************************************************
  57 %*                                                      *
  58 %*              Tail calls                              *
  59 %*                                                      *
  60 %********************************************************
  61
  62 ``Applications'' mean {\em tail calls}, a service provided by module
  63 @CgTailCall@.  This includes literals, which show up as
  64 @(STGApp (StgLitArg 42) [])@.
  65
  66 \begin{code}
  67 cgExpr (StgApp fun args) = cgTailCall fun args
  68 \end{code}
  69
  70 %********************************************************
  71 %*                                                      *
  72 %*              STG ConApps  (for inline versions)      *
  73 %*                                                      *
  74 %********************************************************
  75
  76 \begin{code}
  77 cgExpr (StgConApp con args)
  78   = do  { amodes <- getArgAmodes args
  79         ; cgReturnDataCon con amodes }
  80 \end{code}
  81
  82 Literals are similar to constructors; they return by putting
  83 themselves in an appropriate register and returning to the address on
  84 top of the stack.
  85
  86 \begin{code}
  87 cgExpr (StgLit lit)
  88   = do  { cmm_lit <- cgLit lit
  89         ; performPrimReturn rep (CmmLit cmm_lit) }
  90   where
  91     rep = (typeCgRep) (literalType lit)
  92 \end{code}
  93
  94
  95 %********************************************************
  96 %*                                                      *
  97 %*      PrimOps and foreign calls.
  98 %*                                                      *
  99 %********************************************************
 100
 101 NOTE about "safe" foreign calls: a safe foreign call is never compiled
 102 inline in a case expression.  When we see
 103
 104         case (ccall ...) of { ... }
 105
 106 We generate a proper return address for the alternatives and push the
 107 stack frame before doing the call, so that in the event that the call
 108 re-enters the RTS the stack is in a sane state.
 109
 110 \begin{code}
 111 cgExpr (StgOpApp (StgFCallOp fcall _) stg_args res_ty) = do
 112     {-
 113         First, copy the args into temporaries.  We're going to push
 114         a return address right before doing the call, so the args
 115         must be out of the way.
 116     -}
 117     reps_n_amodes <- getArgAmodes stg_args
 118     let
 119         -- Get the *non-void* args, and jiggle them with shimForeignCall
 120         arg_exprs = [ (shimForeignCallArg stg_arg expr, stg_arg)
 121                     | (stg_arg, (rep,expr)) <- stg_args `zip` reps_n_amodes,
 122                       nonVoidArg rep]
 123
 124     arg_tmps <- sequence [ assignTemp arg
 125                          | (arg, _) <- arg_exprs]
 126     let arg_hints = zipWith CmmHinted arg_tmps (map (typeForeignHint.stgArgType) stg_args)
 127     {-
 128         Now, allocate some result regs.
 129     -}
 130     (res_reps,res_regs,res_hints)  <- newUnboxedTupleRegs res_ty
 131     ccallReturnUnboxedTuple (zip res_reps (map (CmmReg . CmmLocal) res_regs)) $
 132         emitForeignCall (zipWith CmmHinted res_regs res_hints) fcall
 133            arg_hints emptyVarSet{-no live vars-}
 134
 135 -- tagToEnum# is special: we need to pull the constructor out of the table,
 136 -- and perform an appropriate return.
 137
 138 cgExpr (StgOpApp (StgPrimOp TagToEnumOp) [arg] res_ty)
 139   = ASSERT(isEnumerationTyCon tycon)
 140     do  { (_rep,amode) <- getArgAmode arg
 141         ; amode' <- assignTemp amode    -- We're going to use it twice,
 142                                         -- so save in a temp if non-trivial
 143         ; stmtC (CmmAssign nodeReg (tagToClosure tycon amode'))
 144         ; performReturn emitReturnInstr }
 145    where
 146           -- If you're reading this code in the attempt to figure
 147           -- out why the compiler panic'ed here, it is probably because
 148           -- you used tagToEnum# in a non-monomorphic setting, e.g.,
 149           --         intToTg :: Enum a => Int -> a ; intToTg (I# x#) = tagToEnum# x#
 150           -- That won't work.
 151         tycon = tyConAppTyCon res_ty
 152
 153
 154 cgExpr (StgOpApp (StgPrimOp primop) args res_ty)
 155   | primOpOutOfLine primop
 156         = tailCallPrimOp primop args
 157
 158   | ReturnsPrim VoidRep <- result_info
 159         = do cgPrimOp [] primop args emptyVarSet
 160              performReturn emitReturnInstr
 161
 162   | ReturnsPrim rep <- result_info
 163         = do res <- newTemp (typeCmmType res_ty)
 164              cgPrimOp [res] primop args emptyVarSet
 165              performPrimReturn (primRepToCgRep rep) (CmmReg (CmmLocal res))
 166
 167   | ReturnsAlg tycon <- result_info, isUnboxedTupleTyCon tycon
 168         = do (reps, regs, _hints) <- newUnboxedTupleRegs res_ty
 169              cgPrimOp regs primop args emptyVarSet{-no live vars-}
 170              returnUnboxedTuple (zip reps (map (CmmReg . CmmLocal) regs))
 171
 172   | ReturnsAlg tycon <- result_info, isEnumerationTyCon tycon
 173         -- c.f. cgExpr (...TagToEnumOp...)
 174         = do tag_reg <- newTemp bWord   -- The tag is a word
 175              cgPrimOp [tag_reg] primop args emptyVarSet
 176              stmtC (CmmAssign nodeReg
 177                     (tagToClosure tycon
 178                      (CmmReg (CmmLocal tag_reg))))
 179              performReturn emitReturnInstr
 180   where
 181         result_info = getPrimOpResultInfo primop
 182 \end{code}
 183
 184 %********************************************************
 185 %*                                                      *
 186 %*              Case expressions                        *
 187 %*                                                      *
 188 %********************************************************
 189 Case-expression conversion is complicated enough to have its own
 190 module, @CgCase@.
 191 \begin{code}
 192
 193 cgExpr (StgCase expr live_vars save_vars bndr srt alt_type alts)
 194   = setSRT srt $ cgCase expr live_vars save_vars bndr alt_type alts
 195 \end{code}
 196
 197
 198 %********************************************************
 199 %*                                                      *
 200 %*              Let and letrec                          *
 201 %*                                                      *
 202 %********************************************************
 203 \subsection[let-and-letrec-codegen]{Converting @StgLet@ and @StgLetrec@}
 204
 205 \begin{code}
 206 cgExpr (StgLet (StgNonRec name rhs) expr)
 207   = cgRhs name rhs      `thenFC` \ (name, info) ->
 208     addBindC name info  `thenC`
 209     cgExpr expr
 210
 211 cgExpr (StgLet (StgRec pairs) expr)
 212   = fixC (\ new_bindings -> addBindsC new_bindings `thenC`
 213                             listFCs [ cgRhs b e | (b,e) <- pairs ]
 214     ) `thenFC` \ new_bindings ->
 215
 216     addBindsC new_bindings `thenC`
 217     cgExpr expr
 218 \end{code}
 219
 220 \begin{code}
 221 cgExpr (StgLetNoEscape live_in_whole_let live_in_rhss bindings body)
 222   = do  {       -- Figure out what volatile variables to save
 223         ; nukeDeadBindings live_in_whole_let
 224         ; (save_assts, rhs_eob_info, maybe_cc_slot)
 225                 <- saveVolatileVarsAndRegs live_in_rhss
 226
 227         -- Save those variables right now!
 228         ; emitStmts save_assts
 229
 230         -- Produce code for the rhss
 231         -- and add suitable bindings to the environment
 232         ; cgLetNoEscapeBindings live_in_rhss rhs_eob_info
 233                                 maybe_cc_slot bindings
 234
 235         -- Do the body
 236         ; setEndOfBlockInfo rhs_eob_info (cgExpr body) }
 237 \end{code}
 238
 239
 240 %********************************************************
 241 %*                                                      *
 242 %*              SCC Expressions                         *
 243 %*                                                      *
 244 %********************************************************
 245
 246 SCC expressions are treated specially. They set the current cost
 247 centre.
 248
 249 \begin{code}
 250 cgExpr (StgSCC cc expr) = do emitSetCCC cc; cgExpr expr
 251 \end{code}
 252
 253 %********************************************************
 254 %*                                                     *
 255 %*             Hpc Tick Boxes                          *
 256 %*                                                     *
 257 %********************************************************
 258
 259 \begin{code}
 260 cgExpr (StgTick m n expr) = do cgTickBox m n; cgExpr expr
 261 \end{code}
 262
 263 %********************************************************
 264 %*                                                     *
 265 %*             Anything else                           *
 266 %*                                                     *
 267 %********************************************************
 268
 269 \begin{code}
 270 cgExpr _ = panic "cgExpr"
 271 \end{code}
 272
 273 %********************************************************
 274 %*                                                      *
 275 %*              Non-top-level bindings                  *
 276 %*                                                      *
 277 %********************************************************
 278 \subsection[non-top-level-bindings]{Converting non-top-level bindings}
 279
 280 We rely on the support code in @CgCon@ (to do constructors) and
 281 in @CgClosure@ (to do closures).
 282
 283 \begin{code}
 284 cgRhs :: Id -> StgRhs -> FCode (Id, CgIdInfo)
 285         -- the Id is passed along so a binding can be set up
 286
 287 cgRhs name (StgRhsCon maybe_cc con args)
 288   = do  { amodes <- getArgAmodes args
 289         ; idinfo <- buildDynCon name maybe_cc con amodes
 290         ; returnFC (name, idinfo) }
 291
 292 cgRhs name (StgRhsClosure cc bi fvs upd_flag srt args body)
 293   = setSRT srt $ mkRhsClosure name cc bi fvs upd_flag args body
 294 \end{code}
 295
 296 mkRhsClosure looks for two special forms of the right-hand side:
 297         a) selector thunks.
 298         b) AP thunks
 299
 300 If neither happens, it just calls mkClosureLFInfo.  You might think
 301 that mkClosureLFInfo should do all this, but it seems wrong for the
 302 latter to look at the structure of an expression
 303
 304 Selectors
 305 ~~~~~~~~~
 306 We look at the body of the closure to see if it's a selector---turgid,
 307 but nothing deep.  We are looking for a closure of {\em exactly} the
 308 form:
 309
 310 ...  = [the_fv] \ u [] ->
 311          case the_fv of
 312            con a_1 ... a_n -> a_i
 313
 314
 315 \begin{code}
 316 mkRhsClosure :: Id -> CostCentreStack -> StgBinderInfo
 317              -> [Id] -> UpdateFlag -> [Id] -> GenStgExpr Id Id
 318              -> FCode (Id, CgIdInfo)
 319 mkRhsClosure    bndr cc bi
 320                 [the_fv]                -- Just one free var
 321                 upd_flag                -- Updatable thunk
 322                 []                      -- A thunk
 323                 body@(StgCase (StgApp scrutinee [{-no args-}])
 324                       _ _ _ srt   -- ignore uniq, etc.
 325                       (AlgAlt _)
 326                       [(DataAlt con, params, _use_mask,
 327                             (StgApp selectee [{-no args-}]))])
 328   |  the_fv == scrutinee                -- Scrutinee is the only free variable
 329   && maybeToBool maybe_offset           -- Selectee is a component of the tuple
 330   && offset_into_int <= mAX_SPEC_SELECTEE_SIZE  -- Offset is small enough
 331   = -- NOT TRUE: ASSERT(is_single_constructor)
 332     -- The simplifier may have statically determined that the single alternative
 333     -- is the only possible case and eliminated the others, even if there are
 334     -- other constructors in the datatype.  It's still ok to make a selector
 335     -- thunk in this case, because we *know* which constructor the scrutinee
 336     -- will evaluate to.
 337     setSRT srt $ cgStdRhsClosure bndr cc bi [the_fv] [] body lf_info [StgVarArg the_fv]
 338   where
 339     lf_info               = mkSelectorLFInfo bndr offset_into_int
 340                                  (isUpdatable upd_flag)
 341     (_, params_w_offsets) = layOutDynConstr con (addIdReps params)
 342                         -- Just want the layout
 343     maybe_offset          = assocMaybe params_w_offsets selectee
 344     Just the_offset       = maybe_offset
 345     offset_into_int       = the_offset - fixedHdrSize
 346 \end{code}
 347
 348 Ap thunks
 349 ~~~~~~~~~
 350
 351 A more generic AP thunk of the form
 352
 353         x = [ x_1...x_n ] \.. [] -> x_1 ... x_n
 354
 355 A set of these is compiled statically into the RTS, so we just use
 356 those.  We could extend the idea to thunks where some of the x_i are
 357 global ids (and hence not free variables), but this would entail
 358 generating a larger thunk.  It might be an option for non-optimising
 359 compilation, though.
 360
 361 We only generate an Ap thunk if all the free variables are pointers,
 362 for semi-obvious reasons.
 363
 364 \begin{code}
 365 mkRhsClosure    bndr cc bi
 366                 fvs
 367                 upd_flag
 368                 []                      -- No args; a thunk
 369                 body@(StgApp fun_id args)
 370
 371   | args `lengthIs` (arity-1)
 372         && all isFollowableArg (map idCgRep fvs)
 373         && isUpdatable upd_flag
 374         && arity <= mAX_SPEC_AP_SIZE
 375
 376                    -- Ha! an Ap thunk
 377         = cgStdRhsClosure bndr cc bi fvs [] body lf_info payload
 378
 379    where
 380         lf_info = mkApLFInfo bndr upd_flag arity
 381         -- the payload has to be in the correct order, hence we can't
 382         -- just use the fvs.
 383         payload = StgVarArg fun_id : args
 384         arity   = length fvs
 385 \end{code}
 386
 387 The default case
 388 ~~~~~~~~~~~~~~~~
 389 \begin{code}
 390 mkRhsClosure bndr cc bi fvs upd_flag args body
 391   = cgRhsClosure bndr cc bi fvs upd_flag args body
 392 \end{code}
 393
 394
 395 %********************************************************
 396 %*                                                      *
 397 %*              Let-no-escape bindings
 398 %*                                                      *
 399 %********************************************************
 400 \begin{code}
 401 cgLetNoEscapeBindings :: StgLiveVars -> EndOfBlockInfo
 402                       -> Maybe VirtualSpOffset -> GenStgBinding Id Id
 403                       -> Code
 404 cgLetNoEscapeBindings live_in_rhss rhs_eob_info maybe_cc_slot
 405         (StgNonRec binder rhs)
 406   = do  { (binder,info) <- cgLetNoEscapeRhs live_in_rhss rhs_eob_info
 407                                             maybe_cc_slot
 408                                             NonRecursive binder rhs
 409         ; addBindC binder info }
 410
 411 cgLetNoEscapeBindings live_in_rhss rhs_eob_info maybe_cc_slot (StgRec pairs)
 412   = do  { new_bindings <- fixC (\ new_bindings -> do
 413                 { addBindsC new_bindings
 414                 ; listFCs [ cgLetNoEscapeRhs full_live_in_rhss
 415                                 rhs_eob_info maybe_cc_slot Recursive b e
 416                           | (b,e) <- pairs ] })
 417
 418         ; addBindsC new_bindings }
 419   where
 420     -- We add the binders to the live-in-rhss set so that we don't
 421     -- delete the bindings for the binder from the environment!
 422     full_live_in_rhss = live_in_rhss `unionVarSet` (mkVarSet [b | (b,_) <- pairs])
 423
 424 cgLetNoEscapeRhs
 425     :: StgLiveVars      -- Live in rhss
 426     -> EndOfBlockInfo
 427     -> Maybe VirtualSpOffset
 428     -> RecFlag
 429     -> Id
 430     -> StgRhs
 431     -> FCode (Id, CgIdInfo)
 432
 433 cgLetNoEscapeRhs full_live_in_rhss rhs_eob_info maybe_cc_slot rec binder
 434                  (StgRhsClosure cc bi _ _upd_flag srt args body)
 435   = -- We could check the update flag, but currently we don't switch it off
 436     -- for let-no-escaped things, so we omit the check too!
 437     -- case upd_flag of
 438     --     Updatable -> panic "cgLetNoEscapeRhs"        -- Nothing to update!
 439     --     other     -> cgLetNoEscapeClosure binder cc bi live_in_whole_let live_in_rhss args body
 440     setSRT srt $ cgLetNoEscapeClosure binder cc bi full_live_in_rhss rhs_eob_info
 441         maybe_cc_slot rec args body
 442
 443 -- For a constructor RHS we want to generate a single chunk of code which
 444 -- can be jumped to from many places, which will return the constructor.
 445 -- It's easy; just behave as if it was an StgRhsClosure with a ConApp inside!
 446 cgLetNoEscapeRhs full_live_in_rhss rhs_eob_info maybe_cc_slot rec binder
 447                  (StgRhsCon cc con args)
 448   = setSRT NoSRT $ cgLetNoEscapeClosure binder cc noBinderInfo{-safe-}
 449                          full_live_in_rhss rhs_eob_info maybe_cc_slot rec
 450         []      --No args; the binder is data structure, not a function
 451         (StgConApp con args)
 452 \end{code}
 453
 454 Little helper for primitives that return unboxed tuples.
 455
 456 \begin{code}
 457 newUnboxedTupleRegs :: Type -> FCode ([CgRep], [LocalReg], [ForeignHint])
 458 newUnboxedTupleRegs res_ty =
 459    let
 460         ty_args = tyConAppArgs (repType res_ty)
 461         (reps,hints) = unzip [ (rep, typeForeignHint ty) | ty <- ty_args,
 462                                                     let rep = typeCgRep ty,
 463                                                     nonVoidArg rep ]
 464         make_new_temp rep = newTemp (argMachRep rep)
 465    in do
 466    regs <- mapM make_new_temp reps
 467    return (reps,regs,hints)
 468 \end{code}