compiler/codeGen/StgCmmPrim.hs

   1 -----------------------------------------------------------------------------
   2 --
   3 -- Stg to C--: primitive operations
   4 --
   5 -- (c) The University of Glasgow 2004-2006
   6 --
   7 -----------------------------------------------------------------------------
   8
   9 module StgCmmPrim (
  10    cgOpApp
  11  ) where
  12
  13 #include "HsVersions.h"
  14
  15 import StgCmmLayout
  16 import StgCmmForeign
  17 import StgCmmEnv
  18 import StgCmmMonad
  19 import StgCmmUtils
  20
  21 import MkZipCfgCmm
  22 import StgSyn
  23 import Cmm
  24 import Type     ( Type, tyConAppTyCon )
  25 import TyCon
  26 import CLabel
  27 import CmmUtils
  28 import PrimOp
  29 import SMRep
  30 import Constants
  31 import Module
  32 import FastString
  33 import Outputable
  34
  35 ------------------------------------------------------------------------
  36 --      Primitive operations and foreign calls
  37 ------------------------------------------------------------------------
  38
  39 {- Note [Foreign call results]
  40    ~~~~~~~~~~~~~~~~~~~~~~~~~~~
  41 A foreign call always returns an unboxed tuple of results, one
  42 of which is the state token.  This seems to happen even for pure
  43 calls.
  44
  45 Even if we returned a single result for pure calls, it'd still be
  46 right to wrap it in a singleton unboxed tuple, because the result
  47 might be a Haskell closure pointer, we don't want to evaluate it. -}
  48
  49 ----------------------------------
  50 cgOpApp :: StgOp        -- The op
  51         -> [StgArg]     -- Arguments
  52         -> Type         -- Result type (always an unboxed tuple)
  53         -> FCode ()
  54
  55 -- Foreign calls
  56 cgOpApp (StgFCallOp fcall _) stg_args res_ty
  57   = do  { (res_regs, res_hints) <- newUnboxedTupleRegs res_ty
  58                 -- Choose result regs r1, r2
  59                 -- Note [Foreign call results]
  60         ; cgForeignCall res_regs res_hints fcall stg_args
  61                 -- r1, r2 = foo( x, y )
  62         ; emitReturn (map (CmmReg . CmmLocal) res_regs) }
  63                 -- return (r1, r2)
  64
  65 -- tagToEnum# is special: we need to pull the constructor
  66 -- out of the table, and perform an appropriate return.
  67
  68 cgOpApp (StgPrimOp TagToEnumOp) [arg] res_ty
  69   = ASSERT(isEnumerationTyCon tycon)
  70     do  { args' <- getNonVoidArgAmodes [arg]
  71         ; let amode = case args' of [amode] -> amode
  72                                     _ -> panic "TagToEnumOp had void arg"
  73         ; emitReturn [tagToClosure tycon amode] }
  74    where
  75           -- If you're reading this code in the attempt to figure
  76           -- out why the compiler panic'ed here, it is probably because
  77           -- you used tagToEnum# in a non-monomorphic setting, e.g.,
  78           --         intToTg :: Enum a => Int -> a ; intToTg (I# x#) = tagToEnum# x#
  79           -- That won't work.
  80         tycon = tyConAppTyCon res_ty
  81
  82 cgOpApp (StgPrimOp primop) args res_ty
  83   | primOpOutOfLine primop
  84   = do  { cmm_args <- getNonVoidArgAmodes args
  85         ; let fun = CmmLit (CmmLabel (mkRtsPrimOpLabel primop))
  86         ; emitCall (PrimOpCall, PrimOpReturn) fun cmm_args }
  87
  88   | ReturnsPrim VoidRep <- result_info
  89   = do cgPrimOp [] primop args
  90        emitReturn []
  91
  92   | ReturnsPrim rep <- result_info
  93   = do res <- newTemp (primRepCmmType rep)
  94        cgPrimOp [res] primop args
  95        emitReturn [CmmReg (CmmLocal res)]
  96
  97   | ReturnsAlg tycon <- result_info, isUnboxedTupleTyCon tycon
  98   = do (regs, _hints) <- newUnboxedTupleRegs res_ty
  99        cgPrimOp regs primop args
 100        emitReturn (map (CmmReg . CmmLocal) regs)
 101
 102   | ReturnsAlg tycon <- result_info
 103   , isEnumerationTyCon tycon
 104         -- c.f. cgExpr (...TagToEnumOp...)
 105   = do  tag_reg <- newTemp bWord
 106         cgPrimOp [tag_reg] primop args
 107         emitReturn [tagToClosure tycon
 108                         (CmmReg (CmmLocal tag_reg))]
 109
 110   | otherwise = panic "cgPrimop"
 111   where
 112      result_info = getPrimOpResultInfo primop
 113
 114 cgOpApp (StgPrimCallOp primcall) args _res_ty
 115   = do  { cmm_args <- getNonVoidArgAmodes args
 116         ; let fun = CmmLit (CmmLabel (mkPrimCallLabel primcall))
 117         ; emitCall (PrimOpCall, PrimOpReturn) fun cmm_args }
 118
 119 ---------------------------------------------------
 120 cgPrimOp   :: [LocalReg]        -- where to put the results
 121            -> PrimOp            -- the op
 122            -> [StgArg]          -- arguments
 123            -> FCode ()
 124
 125 cgPrimOp results op args
 126   = do arg_exprs <- getNonVoidArgAmodes args
 127        emitPrimOp results op arg_exprs
 128
 129
 130 ------------------------------------------------------------------------
 131 --      Emitting code for a primop
 132 ------------------------------------------------------------------------
 133
 134 emitPrimOp :: [LocalReg]        -- where to put the results
 135            -> PrimOp            -- the op
 136            -> [CmmExpr]         -- arguments
 137            -> FCode ()
 138
 139 -- First we handle various awkward cases specially.  The remaining
 140 -- easy cases are then handled by translateOp, defined below.
 141
 142 emitPrimOp [res_r,res_c] IntAddCOp [aa,bb]
 143 {-
 144    With some bit-twiddling, we can define int{Add,Sub}Czh portably in
 145    C, and without needing any comparisons.  This may not be the
 146    fastest way to do it - if you have better code, please send it! --SDM
 147
 148    Return : r = a + b,  c = 0 if no overflow, 1 on overflow.
 149
 150    We currently don't make use of the r value if c is != 0 (i.e.
 151    overflow), we just convert to big integers and try again.  This
 152    could be improved by making r and c the correct values for
 153    plugging into a new J#.
 154
 155    { r = ((I_)(a)) + ((I_)(b));                                 \
 156      c = ((StgWord)(~(((I_)(a))^((I_)(b))) & (((I_)(a))^r)))    \
 157          >> (BITS_IN (I_) - 1);                                 \
 158    }
 159    Wading through the mass of bracketry, it seems to reduce to:
 160    c = ( (~(a^b)) & (a^r) ) >>unsigned (BITS_IN(I_)-1)
 161
 162 -}
 163    = emit $ catAGraphs [
 164         mkAssign (CmmLocal res_r) (CmmMachOp mo_wordAdd [aa,bb]),
 165         mkAssign (CmmLocal res_c) $
 166           CmmMachOp mo_wordUShr [
 167                 CmmMachOp mo_wordAnd [
 168                     CmmMachOp mo_wordNot [CmmMachOp mo_wordXor [aa,bb]],
 169                     CmmMachOp mo_wordXor [aa, CmmReg (CmmLocal res_r)]
 170                 ],
 171                 CmmLit (mkIntCLit (wORD_SIZE_IN_BITS - 1))
 172           ]
 173      ]
 174
 175
 176 emitPrimOp [res_r,res_c] IntSubCOp [aa,bb]
 177 {- Similarly:
 178    #define subIntCzh(r,c,a,b)                                   \
 179    { r = ((I_)(a)) - ((I_)(b));                                 \
 180      c = ((StgWord)((((I_)(a))^((I_)(b))) & (((I_)(a))^r)))     \
 181          >> (BITS_IN (I_) - 1);                                 \
 182    }
 183
 184    c =  ((a^b) & (a^r)) >>unsigned (BITS_IN(I_)-1)
 185 -}
 186    = emit $ catAGraphs [
 187         mkAssign (CmmLocal res_r) (CmmMachOp mo_wordSub [aa,bb]),
 188         mkAssign (CmmLocal res_c) $
 189           CmmMachOp mo_wordUShr [
 190                 CmmMachOp mo_wordAnd [
 191                     CmmMachOp mo_wordXor [aa,bb],
 192                     CmmMachOp mo_wordXor [aa, CmmReg (CmmLocal res_r)]
 193                 ],
 194                 CmmLit (mkIntCLit (wORD_SIZE_IN_BITS - 1))
 195           ]
 196      ]
 197
 198
 199 emitPrimOp [res] ParOp [arg]
 200   =
 201         -- for now, just implement this in a C function
 202         -- later, we might want to inline it.
 203     emitCCall
 204         [(res,NoHint)]
 205         (CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "newSpark"))))
 206         [(CmmReg (CmmGlobal BaseReg), AddrHint), (arg,AddrHint)]
 207
 208 emitPrimOp [res] ReadMutVarOp [mutv]
 209    = emit (mkAssign (CmmLocal res) (cmmLoadIndexW mutv fixedHdrSize gcWord))
 210
 211 emitPrimOp [] WriteMutVarOp [mutv,var]
 212    = do
 213         emit (mkStore (cmmOffsetW mutv fixedHdrSize) var)
 214         emitCCall
 215                 [{-no results-}]
 216                 (CmmLit (CmmLabel mkDirty_MUT_VAR_Label))
 217                 [(CmmReg (CmmGlobal BaseReg), AddrHint), (mutv,AddrHint)]
 218
 219 --  #define sizzeofByteArrayzh(r,a) \
 220 --     r = (((StgArrWords *)(a))->words * sizeof(W_))
 221 emitPrimOp [res] SizeofByteArrayOp [arg]
 222    = emit $
 223         mkAssign (CmmLocal res) (CmmMachOp mo_wordMul [
 224                           cmmLoadIndexW arg fixedHdrSize bWord,
 225                           CmmLit (mkIntCLit wORD_SIZE)
 226                         ])
 227
 228 --  #define sizzeofMutableByteArrayzh(r,a) \
 229 --      r = (((StgArrWords *)(a))->words * sizeof(W_))
 230 emitPrimOp [res] SizeofMutableByteArrayOp [arg]
 231    = emitPrimOp [res] SizeofByteArrayOp [arg]
 232
 233
 234 --  #define touchzh(o)                  /* nothing */
 235 emitPrimOp [] TouchOp [_arg]
 236    = nopC
 237
 238 --  #define byteArrayContentszh(r,a) r = BYTE_ARR_CTS(a)
 239 emitPrimOp [res] ByteArrayContents_Char [arg]
 240    = emit (mkAssign (CmmLocal res) (cmmOffsetB arg arrWordsHdrSize))
 241
 242 --  #define stableNameToIntzh(r,s)   (r = ((StgStableName *)s)->sn)
 243 emitPrimOp [res] StableNameToIntOp [arg]
 244    = emit (mkAssign (CmmLocal res) (cmmLoadIndexW arg fixedHdrSize bWord))
 245
 246 --  #define eqStableNamezh(r,sn1,sn2)                                   \
 247 --    (r = (((StgStableName *)sn1)->sn == ((StgStableName *)sn2)->sn))
 248 emitPrimOp [res] EqStableNameOp [arg1,arg2]
 249    = emit (mkAssign (CmmLocal res) (CmmMachOp mo_wordEq [
 250                                 cmmLoadIndexW arg1 fixedHdrSize bWord,
 251                                 cmmLoadIndexW arg2 fixedHdrSize bWord
 252                          ]))
 253
 254
 255 emitPrimOp [res] ReallyUnsafePtrEqualityOp [arg1,arg2]
 256    = emit (mkAssign (CmmLocal res) (CmmMachOp mo_wordEq [arg1,arg2]))
 257
 258 --  #define addrToHValuezh(r,a) r=(P_)a
 259 emitPrimOp [res] AddrToHValueOp [arg]
 260    = emit (mkAssign (CmmLocal res) arg)
 261
 262 --  #define dataToTagzh(r,a)  r=(GET_TAG(((StgClosure *)a)->header.info))
 263 --  Note: argument may be tagged!
 264 emitPrimOp [res] DataToTagOp [arg]
 265    = emit (mkAssign (CmmLocal res) (getConstrTag (cmmUntag arg)))
 266
 267 {- Freezing arrays-of-ptrs requires changing an info table, for the
 268    benefit of the generational collector.  It needs to scavenge mutable
 269    objects, even if they are in old space.  When they become immutable,
 270    they can be removed from this scavenge list.  -}
 271
 272 --  #define unsafeFreezzeArrayzh(r,a)
 273 --      {
 274 --        SET_INFO((StgClosure *)a,&stg_MUT_ARR_PTRS_FROZEN0_info);
 275 --        r = a;
 276 --      }
 277 emitPrimOp [res] UnsafeFreezeArrayOp [arg]
 278    = emit $ catAGraphs
 279          [ setInfo arg (CmmLit (CmmLabel mkMAP_FROZEN_infoLabel)),
 280            mkAssign (CmmLocal res) arg ]
 281
 282 --  #define unsafeFreezzeByteArrayzh(r,a)       r=(a)
 283 emitPrimOp [res] UnsafeFreezeByteArrayOp [arg]
 284    = emit (mkAssign (CmmLocal res) arg)
 285
 286 -- Reading/writing pointer arrays
 287
 288 emitPrimOp [r] ReadArrayOp  [obj,ix]    = doReadPtrArrayOp r obj ix
 289 emitPrimOp [r] IndexArrayOp [obj,ix]    = doReadPtrArrayOp r obj ix
 290 emitPrimOp []  WriteArrayOp [obj,ix,v]  = doWritePtrArrayOp obj ix v
 291
 292 -- IndexXXXoffAddr
 293
 294 emitPrimOp res IndexOffAddrOp_Char      args = doIndexOffAddrOp (Just mo_u_8ToWord) b8 res args
 295 emitPrimOp res IndexOffAddrOp_WideChar  args = doIndexOffAddrOp (Just mo_u_32ToWord) b32 res args
 296 emitPrimOp res IndexOffAddrOp_Int       args = doIndexOffAddrOp Nothing bWord res args
 297 emitPrimOp res IndexOffAddrOp_Word      args = doIndexOffAddrOp Nothing bWord res args
 298 emitPrimOp res IndexOffAddrOp_Addr      args = doIndexOffAddrOp Nothing bWord res args
 299 emitPrimOp res IndexOffAddrOp_Float     args = doIndexOffAddrOp Nothing f32 res args
 300 emitPrimOp res IndexOffAddrOp_Double    args = doIndexOffAddrOp Nothing f64 res args
 301 emitPrimOp res IndexOffAddrOp_StablePtr args = doIndexOffAddrOp Nothing bWord res args
 302 emitPrimOp res IndexOffAddrOp_Int8      args = doIndexOffAddrOp (Just mo_s_8ToWord) b8  res args
 303 emitPrimOp res IndexOffAddrOp_Int16     args = doIndexOffAddrOp (Just mo_s_16ToWord) b16 res args
 304 emitPrimOp res IndexOffAddrOp_Int32     args = doIndexOffAddrOp (Just mo_s_32ToWord) b32 res args
 305 emitPrimOp res IndexOffAddrOp_Int64     args = doIndexOffAddrOp Nothing b64 res args
 306 emitPrimOp res IndexOffAddrOp_Word8     args = doIndexOffAddrOp (Just mo_u_8ToWord) b8  res args
 307 emitPrimOp res IndexOffAddrOp_Word16    args = doIndexOffAddrOp (Just mo_u_16ToWord) b16 res args
 308 emitPrimOp res IndexOffAddrOp_Word32    args = doIndexOffAddrOp (Just mo_u_32ToWord) b32 res args
 309 emitPrimOp res IndexOffAddrOp_Word64    args = doIndexOffAddrOp Nothing b64 res args
 310
 311 -- ReadXXXoffAddr, which are identical, for our purposes, to IndexXXXoffAddr.
 312
 313 emitPrimOp res ReadOffAddrOp_Char      args = doIndexOffAddrOp (Just mo_u_8ToWord) b8 res args
 314 emitPrimOp res ReadOffAddrOp_WideChar  args = doIndexOffAddrOp (Just mo_u_32ToWord) b32 res args
 315 emitPrimOp res ReadOffAddrOp_Int       args = doIndexOffAddrOp Nothing bWord res args
 316 emitPrimOp res ReadOffAddrOp_Word      args = doIndexOffAddrOp Nothing bWord res args
 317 emitPrimOp res ReadOffAddrOp_Addr      args = doIndexOffAddrOp Nothing bWord res args
 318 emitPrimOp res ReadOffAddrOp_Float     args = doIndexOffAddrOp Nothing f32 res args
 319 emitPrimOp res ReadOffAddrOp_Double    args = doIndexOffAddrOp Nothing f64 res args
 320 emitPrimOp res ReadOffAddrOp_StablePtr args = doIndexOffAddrOp Nothing bWord res args
 321 emitPrimOp res ReadOffAddrOp_Int8      args = doIndexOffAddrOp (Just mo_s_8ToWord) b8  res args
 322 emitPrimOp res ReadOffAddrOp_Int16     args = doIndexOffAddrOp (Just mo_s_16ToWord) b16 res args
 323 emitPrimOp res ReadOffAddrOp_Int32     args = doIndexOffAddrOp (Just mo_s_32ToWord) b32 res args
 324 emitPrimOp res ReadOffAddrOp_Int64     args = doIndexOffAddrOp Nothing b64 res args
 325 emitPrimOp res ReadOffAddrOp_Word8     args = doIndexOffAddrOp (Just mo_u_8ToWord) b8  res args
 326 emitPrimOp res ReadOffAddrOp_Word16    args = doIndexOffAddrOp (Just mo_u_16ToWord) b16 res args
 327 emitPrimOp res ReadOffAddrOp_Word32    args = doIndexOffAddrOp (Just mo_u_32ToWord) b32 res args
 328 emitPrimOp res ReadOffAddrOp_Word64    args = doIndexOffAddrOp Nothing b64 res args
 329
 330 -- IndexXXXArray
 331
 332 emitPrimOp res IndexByteArrayOp_Char      args = doIndexByteArrayOp (Just mo_u_8ToWord) b8 res args
 333 emitPrimOp res IndexByteArrayOp_WideChar  args = doIndexByteArrayOp (Just mo_u_32ToWord) b32 res args
 334 emitPrimOp res IndexByteArrayOp_Int       args = doIndexByteArrayOp Nothing bWord res args
 335 emitPrimOp res IndexByteArrayOp_Word      args = doIndexByteArrayOp Nothing bWord res args
 336 emitPrimOp res IndexByteArrayOp_Addr      args = doIndexByteArrayOp Nothing bWord res args
 337 emitPrimOp res IndexByteArrayOp_Float     args = doIndexByteArrayOp Nothing f32 res args
 338 emitPrimOp res IndexByteArrayOp_Double    args = doIndexByteArrayOp Nothing f64 res args
 339 emitPrimOp res IndexByteArrayOp_StablePtr args = doIndexByteArrayOp Nothing bWord res args
 340 emitPrimOp res IndexByteArrayOp_Int8      args = doIndexByteArrayOp (Just mo_s_8ToWord) b8  res args
 341 emitPrimOp res IndexByteArrayOp_Int16     args = doIndexByteArrayOp (Just mo_s_16ToWord) b16  res args
 342 emitPrimOp res IndexByteArrayOp_Int32     args = doIndexByteArrayOp (Just mo_s_32ToWord) b32  res args
 343 emitPrimOp res IndexByteArrayOp_Int64     args = doIndexByteArrayOp Nothing b64  res args
 344 emitPrimOp res IndexByteArrayOp_Word8     args = doIndexByteArrayOp (Just mo_u_8ToWord) b8  res args
 345 emitPrimOp res IndexByteArrayOp_Word16    args = doIndexByteArrayOp (Just mo_u_16ToWord) b16  res args
 346 emitPrimOp res IndexByteArrayOp_Word32    args = doIndexByteArrayOp (Just mo_u_32ToWord) b32  res args
 347 emitPrimOp res IndexByteArrayOp_Word64    args = doIndexByteArrayOp Nothing b64  res args
 348
 349 -- ReadXXXArray, identical to IndexXXXArray.
 350
 351 emitPrimOp res ReadByteArrayOp_Char       args = doIndexByteArrayOp (Just mo_u_8ToWord) b8 res args
 352 emitPrimOp res ReadByteArrayOp_WideChar   args = doIndexByteArrayOp (Just mo_u_32ToWord) b32 res args
 353 emitPrimOp res ReadByteArrayOp_Int        args = doIndexByteArrayOp Nothing bWord res args
 354 emitPrimOp res ReadByteArrayOp_Word       args = doIndexByteArrayOp Nothing bWord res args
 355 emitPrimOp res ReadByteArrayOp_Addr       args = doIndexByteArrayOp Nothing bWord res args
 356 emitPrimOp res ReadByteArrayOp_Float      args = doIndexByteArrayOp Nothing f32 res args
 357 emitPrimOp res ReadByteArrayOp_Double     args = doIndexByteArrayOp Nothing f64 res args
 358 emitPrimOp res ReadByteArrayOp_StablePtr  args = doIndexByteArrayOp Nothing bWord res args
 359 emitPrimOp res ReadByteArrayOp_Int8       args = doIndexByteArrayOp (Just mo_s_8ToWord) b8  res args
 360 emitPrimOp res ReadByteArrayOp_Int16      args = doIndexByteArrayOp (Just mo_s_16ToWord) b16  res args
 361 emitPrimOp res ReadByteArrayOp_Int32      args = doIndexByteArrayOp (Just mo_s_32ToWord) b32  res args
 362 emitPrimOp res ReadByteArrayOp_Int64      args = doIndexByteArrayOp Nothing b64  res args
 363 emitPrimOp res ReadByteArrayOp_Word8      args = doIndexByteArrayOp (Just mo_u_8ToWord) b8  res args
 364 emitPrimOp res ReadByteArrayOp_Word16     args = doIndexByteArrayOp (Just mo_u_16ToWord) b16  res args
 365 emitPrimOp res ReadByteArrayOp_Word32     args = doIndexByteArrayOp (Just mo_u_32ToWord) b32  res args
 366 emitPrimOp res ReadByteArrayOp_Word64     args = doIndexByteArrayOp Nothing b64  res args
 367
 368 -- WriteXXXoffAddr
 369
 370 emitPrimOp res WriteOffAddrOp_Char       args = doWriteOffAddrOp (Just mo_WordTo8)  res args
 371 emitPrimOp res WriteOffAddrOp_WideChar   args = doWriteOffAddrOp (Just mo_WordTo32) res args
 372 emitPrimOp res WriteOffAddrOp_Int        args = doWriteOffAddrOp Nothing res args
 373 emitPrimOp res WriteOffAddrOp_Word       args = doWriteOffAddrOp Nothing res args
 374 emitPrimOp res WriteOffAddrOp_Addr       args = doWriteOffAddrOp Nothing res args
 375 emitPrimOp res WriteOffAddrOp_Float      args = doWriteOffAddrOp Nothing res args
 376 emitPrimOp res WriteOffAddrOp_Double     args = doWriteOffAddrOp Nothing res args
 377 emitPrimOp res WriteOffAddrOp_StablePtr  args = doWriteOffAddrOp Nothing res args
 378 emitPrimOp res WriteOffAddrOp_Int8       args = doWriteOffAddrOp (Just mo_WordTo8)  res args
 379 emitPrimOp res WriteOffAddrOp_Int16      args = doWriteOffAddrOp (Just mo_WordTo16) res args
 380 emitPrimOp res WriteOffAddrOp_Int32      args = doWriteOffAddrOp (Just mo_WordTo32) res args
 381 emitPrimOp res WriteOffAddrOp_Int64      args = doWriteOffAddrOp Nothing res args
 382 emitPrimOp res WriteOffAddrOp_Word8      args = doWriteOffAddrOp (Just mo_WordTo8)  res args
 383 emitPrimOp res WriteOffAddrOp_Word16     args = doWriteOffAddrOp (Just mo_WordTo16) res args
 384 emitPrimOp res WriteOffAddrOp_Word32     args = doWriteOffAddrOp (Just mo_WordTo32) res args
 385 emitPrimOp res WriteOffAddrOp_Word64     args = doWriteOffAddrOp Nothing res args
 386
 387 -- WriteXXXArray
 388
 389 emitPrimOp res WriteByteArrayOp_Char      args = doWriteByteArrayOp (Just mo_WordTo8)  res args
 390 emitPrimOp res WriteByteArrayOp_WideChar  args = doWriteByteArrayOp (Just mo_WordTo32) res args
 391 emitPrimOp res WriteByteArrayOp_Int       args = doWriteByteArrayOp Nothing res args
 392 emitPrimOp res WriteByteArrayOp_Word      args = doWriteByteArrayOp Nothing res args
 393 emitPrimOp res WriteByteArrayOp_Addr      args = doWriteByteArrayOp Nothing res args
 394 emitPrimOp res WriteByteArrayOp_Float     args = doWriteByteArrayOp Nothing res args
 395 emitPrimOp res WriteByteArrayOp_Double    args = doWriteByteArrayOp Nothing res args
 396 emitPrimOp res WriteByteArrayOp_StablePtr args = doWriteByteArrayOp Nothing res args
 397 emitPrimOp res WriteByteArrayOp_Int8      args = doWriteByteArrayOp (Just mo_WordTo8)  res args
 398 emitPrimOp res WriteByteArrayOp_Int16     args = doWriteByteArrayOp (Just mo_WordTo16) res args
 399 emitPrimOp res WriteByteArrayOp_Int32     args = doWriteByteArrayOp (Just mo_WordTo32) res args
 400 emitPrimOp res WriteByteArrayOp_Int64     args = doWriteByteArrayOp Nothing  res args
 401 emitPrimOp res WriteByteArrayOp_Word8     args = doWriteByteArrayOp (Just mo_WordTo8)  res args
 402 emitPrimOp res WriteByteArrayOp_Word16    args = doWriteByteArrayOp (Just mo_WordTo16) res args
 403 emitPrimOp res WriteByteArrayOp_Word32    args = doWriteByteArrayOp (Just mo_WordTo32) res args
 404 emitPrimOp res WriteByteArrayOp_Word64    args = doWriteByteArrayOp Nothing res args
 405
 406
 407 -- The rest just translate straightforwardly
 408 emitPrimOp [res] op [arg]
 409    | nopOp op
 410    = emit (mkAssign (CmmLocal res) arg)
 411
 412    | Just (mop,rep) <- narrowOp op
 413    = emit (mkAssign (CmmLocal res) $
 414            CmmMachOp (mop rep wordWidth) [CmmMachOp (mop wordWidth rep) [arg]])
 415
 416 emitPrimOp [res] op args
 417    | Just prim <- callishOp op
 418    = do emitPrimCall res prim args
 419
 420    | Just mop <- translateOp op
 421    = let stmt = mkAssign (CmmLocal res) (CmmMachOp mop args) in
 422      emit stmt
 423
 424 emitPrimOp _ op _
 425  = pprPanic "emitPrimOp: can't translate PrimOp" (ppr op)
 426
 427
 428 -- These PrimOps are NOPs in Cmm
 429
 430 nopOp :: PrimOp -> Bool
 431 nopOp Int2WordOp     = True
 432 nopOp Word2IntOp     = True
 433 nopOp Int2AddrOp     = True
 434 nopOp Addr2IntOp     = True
 435 nopOp ChrOp          = True  -- Int# and Char# are rep'd the same
 436 nopOp OrdOp          = True
 437 nopOp _              = False
 438
 439 -- These PrimOps turn into double casts
 440
 441 narrowOp :: PrimOp -> Maybe (Width -> Width -> MachOp, Width)
 442 narrowOp Narrow8IntOp   = Just (MO_SS_Conv, W8)
 443 narrowOp Narrow16IntOp  = Just (MO_SS_Conv, W16)
 444 narrowOp Narrow32IntOp  = Just (MO_SS_Conv, W32)
 445 narrowOp Narrow8WordOp  = Just (MO_UU_Conv, W8)
 446 narrowOp Narrow16WordOp = Just (MO_UU_Conv, W16)
 447 narrowOp Narrow32WordOp = Just (MO_UU_Conv, W32)
 448 narrowOp _              = Nothing
 449
 450 -- Native word signless ops
 451
 452 translateOp :: PrimOp -> Maybe MachOp
 453 translateOp IntAddOp       = Just mo_wordAdd
 454 translateOp IntSubOp       = Just mo_wordSub
 455 translateOp WordAddOp      = Just mo_wordAdd
 456 translateOp WordSubOp      = Just mo_wordSub
 457 translateOp AddrAddOp      = Just mo_wordAdd
 458 translateOp AddrSubOp      = Just mo_wordSub
 459
 460 translateOp IntEqOp        = Just mo_wordEq
 461 translateOp IntNeOp        = Just mo_wordNe
 462 translateOp WordEqOp       = Just mo_wordEq
 463 translateOp WordNeOp       = Just mo_wordNe
 464 translateOp AddrEqOp       = Just mo_wordEq
 465 translateOp AddrNeOp       = Just mo_wordNe
 466
 467 translateOp AndOp          = Just mo_wordAnd
 468 translateOp OrOp           = Just mo_wordOr
 469 translateOp XorOp          = Just mo_wordXor
 470 translateOp NotOp          = Just mo_wordNot
 471 translateOp SllOp          = Just mo_wordShl
 472 translateOp SrlOp          = Just mo_wordUShr
 473
 474 translateOp AddrRemOp      = Just mo_wordURem
 475
 476 -- Native word signed ops
 477
 478 translateOp IntMulOp        = Just mo_wordMul
 479 translateOp IntMulMayOfloOp = Just (MO_S_MulMayOflo wordWidth)
 480 translateOp IntQuotOp       = Just mo_wordSQuot
 481 translateOp IntRemOp        = Just mo_wordSRem
 482 translateOp IntNegOp        = Just mo_wordSNeg
 483
 484
 485 translateOp IntGeOp        = Just mo_wordSGe
 486 translateOp IntLeOp        = Just mo_wordSLe
 487 translateOp IntGtOp        = Just mo_wordSGt
 488 translateOp IntLtOp        = Just mo_wordSLt
 489
 490 translateOp ISllOp         = Just mo_wordShl
 491 translateOp ISraOp         = Just mo_wordSShr
 492 translateOp ISrlOp         = Just mo_wordUShr
 493
 494 -- Native word unsigned ops
 495
 496 translateOp WordGeOp       = Just mo_wordUGe
 497 translateOp WordLeOp       = Just mo_wordULe
 498 translateOp WordGtOp       = Just mo_wordUGt
 499 translateOp WordLtOp       = Just mo_wordULt
 500
 501 translateOp WordMulOp      = Just mo_wordMul
 502 translateOp WordQuotOp     = Just mo_wordUQuot
 503 translateOp WordRemOp      = Just mo_wordURem
 504
 505 translateOp AddrGeOp       = Just mo_wordUGe
 506 translateOp AddrLeOp       = Just mo_wordULe
 507 translateOp AddrGtOp       = Just mo_wordUGt
 508 translateOp AddrLtOp       = Just mo_wordULt
 509
 510 -- Char# ops
 511
 512 translateOp CharEqOp       = Just (MO_Eq wordWidth)
 513 translateOp CharNeOp       = Just (MO_Ne wordWidth)
 514 translateOp CharGeOp       = Just (MO_U_Ge wordWidth)
 515 translateOp CharLeOp       = Just (MO_U_Le wordWidth)
 516 translateOp CharGtOp       = Just (MO_U_Gt wordWidth)
 517 translateOp CharLtOp       = Just (MO_U_Lt wordWidth)
 518
 519 -- Double ops
 520
 521 translateOp DoubleEqOp     = Just (MO_F_Eq W64)
 522 translateOp DoubleNeOp     = Just (MO_F_Ne W64)
 523 translateOp DoubleGeOp     = Just (MO_F_Ge W64)
 524 translateOp DoubleLeOp     = Just (MO_F_Le W64)
 525 translateOp DoubleGtOp     = Just (MO_F_Gt W64)
 526 translateOp DoubleLtOp     = Just (MO_F_Lt W64)
 527
 528 translateOp DoubleAddOp    = Just (MO_F_Add W64)
 529 translateOp DoubleSubOp    = Just (MO_F_Sub W64)
 530 translateOp DoubleMulOp    = Just (MO_F_Mul W64)
 531 translateOp DoubleDivOp    = Just (MO_F_Quot W64)
 532 translateOp DoubleNegOp    = Just (MO_F_Neg W64)
 533
 534 -- Float ops
 535
 536 translateOp FloatEqOp     = Just (MO_F_Eq W32)
 537 translateOp FloatNeOp     = Just (MO_F_Ne W32)
 538 translateOp FloatGeOp     = Just (MO_F_Ge W32)
 539 translateOp FloatLeOp     = Just (MO_F_Le W32)
 540 translateOp FloatGtOp     = Just (MO_F_Gt W32)
 541 translateOp FloatLtOp     = Just (MO_F_Lt W32)
 542
 543 translateOp FloatAddOp    = Just (MO_F_Add  W32)
 544 translateOp FloatSubOp    = Just (MO_F_Sub  W32)
 545 translateOp FloatMulOp    = Just (MO_F_Mul  W32)
 546 translateOp FloatDivOp    = Just (MO_F_Quot W32)
 547 translateOp FloatNegOp    = Just (MO_F_Neg  W32)
 548
 549 -- Conversions
 550
 551 translateOp Int2DoubleOp   = Just (MO_SF_Conv wordWidth W64)
 552 translateOp Double2IntOp   = Just (MO_FS_Conv W64 wordWidth)
 553
 554 translateOp Int2FloatOp    = Just (MO_SF_Conv wordWidth W32)
 555 translateOp Float2IntOp    = Just (MO_FS_Conv W32 wordWidth)
 556
 557 translateOp Float2DoubleOp = Just (MO_FF_Conv W32 W64)
 558 translateOp Double2FloatOp = Just (MO_FF_Conv W64 W32)
 559
 560 -- Word comparisons masquerading as more exotic things.
 561
 562 translateOp SameMutVarOp           = Just mo_wordEq
 563 translateOp SameMVarOp             = Just mo_wordEq
 564 translateOp SameMutableArrayOp     = Just mo_wordEq
 565 translateOp SameMutableByteArrayOp = Just mo_wordEq
 566 translateOp SameTVarOp             = Just mo_wordEq
 567 translateOp EqStablePtrOp          = Just mo_wordEq
 568
 569 translateOp _ = Nothing
 570
 571 -- These primops are implemented by CallishMachOps, because they sometimes
 572 -- turn into foreign calls depending on the backend.
 573
 574 callishOp :: PrimOp -> Maybe CallishMachOp
 575 callishOp DoublePowerOp  = Just MO_F64_Pwr
 576 callishOp DoubleSinOp    = Just MO_F64_Sin
 577 callishOp DoubleCosOp    = Just MO_F64_Cos
 578 callishOp DoubleTanOp    = Just MO_F64_Tan
 579 callishOp DoubleSinhOp   = Just MO_F64_Sinh
 580 callishOp DoubleCoshOp   = Just MO_F64_Cosh
 581 callishOp DoubleTanhOp   = Just MO_F64_Tanh
 582 callishOp DoubleAsinOp   = Just MO_F64_Asin
 583 callishOp DoubleAcosOp   = Just MO_F64_Acos
 584 callishOp DoubleAtanOp   = Just MO_F64_Atan
 585 callishOp DoubleLogOp    = Just MO_F64_Log
 586 callishOp DoubleExpOp    = Just MO_F64_Exp
 587 callishOp DoubleSqrtOp   = Just MO_F64_Sqrt
 588
 589 callishOp FloatPowerOp  = Just MO_F32_Pwr
 590 callishOp FloatSinOp    = Just MO_F32_Sin
 591 callishOp FloatCosOp    = Just MO_F32_Cos
 592 callishOp FloatTanOp    = Just MO_F32_Tan
 593 callishOp FloatSinhOp   = Just MO_F32_Sinh
 594 callishOp FloatCoshOp   = Just MO_F32_Cosh
 595 callishOp FloatTanhOp   = Just MO_F32_Tanh
 596 callishOp FloatAsinOp   = Just MO_F32_Asin
 597 callishOp FloatAcosOp   = Just MO_F32_Acos
 598 callishOp FloatAtanOp   = Just MO_F32_Atan
 599 callishOp FloatLogOp    = Just MO_F32_Log
 600 callishOp FloatExpOp    = Just MO_F32_Exp
 601 callishOp FloatSqrtOp   = Just MO_F32_Sqrt
 602
 603 callishOp _ = Nothing
 604
 605 ------------------------------------------------------------------------------
 606 -- Helpers for translating various minor variants of array indexing.
 607
 608 doIndexOffAddrOp :: Maybe MachOp -> CmmType -> [LocalReg] -> [CmmExpr] -> FCode ()
 609 doIndexOffAddrOp maybe_post_read_cast rep [res] [addr,idx]
 610    = mkBasicIndexedRead 0 maybe_post_read_cast rep res addr idx
 611 doIndexOffAddrOp _ _ _ _
 612    = panic "CgPrimOp: doIndexOffAddrOp"
 613
 614 doIndexByteArrayOp :: Maybe MachOp -> CmmType -> [LocalReg] -> [CmmExpr] -> FCode ()
 615 doIndexByteArrayOp maybe_post_read_cast rep [res] [addr,idx]
 616    = mkBasicIndexedRead arrWordsHdrSize maybe_post_read_cast rep res addr idx
 617 doIndexByteArrayOp _ _ _ _
 618    = panic "CgPrimOp: doIndexByteArrayOp"
 619
 620 doReadPtrArrayOp ::  LocalReg -> CmmExpr -> CmmExpr -> FCode ()
 621 doReadPtrArrayOp res addr idx
 622    = mkBasicIndexedRead arrPtrsHdrSize Nothing gcWord res addr idx
 623
 624
 625 doWriteOffAddrOp :: Maybe MachOp -> [LocalReg] -> [CmmExpr] -> FCode ()
 626 doWriteOffAddrOp maybe_pre_write_cast [] [addr,idx,val]
 627    = mkBasicIndexedWrite 0 maybe_pre_write_cast addr idx val
 628 doWriteOffAddrOp _ _ _
 629    = panic "CgPrimOp: doWriteOffAddrOp"
 630
 631 doWriteByteArrayOp :: Maybe MachOp -> [LocalReg] -> [CmmExpr] -> FCode ()
 632 doWriteByteArrayOp maybe_pre_write_cast [] [addr,idx,val]
 633    = mkBasicIndexedWrite arrWordsHdrSize maybe_pre_write_cast addr idx val
 634 doWriteByteArrayOp _ _ _
 635    = panic "CgPrimOp: doWriteByteArrayOp"
 636
 637 doWritePtrArrayOp :: CmmExpr -> CmmExpr -> CmmExpr -> FCode ()
 638 doWritePtrArrayOp addr idx val
 639    = do emit (setInfo addr (CmmLit (CmmLabel mkMAP_DIRTY_infoLabel)))
 640         mkBasicIndexedWrite arrPtrsHdrSize Nothing addr idx val
 641
 642 mkBasicIndexedRead :: ByteOff -> Maybe MachOp -> CmmType
 643                    -> LocalReg -> CmmExpr -> CmmExpr -> FCode ()
 644 mkBasicIndexedRead off Nothing read_rep res base idx
 645    = emit (mkAssign (CmmLocal res) (cmmLoadIndexOffExpr off read_rep base idx))
 646 mkBasicIndexedRead off (Just cast) read_rep res base idx
 647    = emit (mkAssign (CmmLocal res) (CmmMachOp cast [
 648                                 cmmLoadIndexOffExpr off read_rep base idx]))
 649
 650 mkBasicIndexedWrite :: ByteOff -> Maybe MachOp
 651                    -> CmmExpr -> CmmExpr -> CmmExpr -> FCode ()
 652 mkBasicIndexedWrite off Nothing base idx val
 653    = emit (mkStore (cmmIndexOffExpr off (typeWidth (cmmExprType val)) base idx) val)
 654 mkBasicIndexedWrite off (Just cast) base idx val
 655    = mkBasicIndexedWrite off Nothing base idx (CmmMachOp cast [val])
 656
 657 -- ----------------------------------------------------------------------------
 658 -- Misc utils
 659
 660 cmmIndexOffExpr :: ByteOff -> Width -> CmmExpr -> CmmExpr -> CmmExpr
 661 cmmIndexOffExpr off width base idx
 662    = cmmIndexExpr width (cmmOffsetB base off) idx
 663
 664 cmmLoadIndexOffExpr :: ByteOff -> CmmType -> CmmExpr -> CmmExpr -> CmmExpr
 665 cmmLoadIndexOffExpr off ty base idx
 666    = CmmLoad (cmmIndexOffExpr off (typeWidth ty) base idx) ty
 667
 668 setInfo :: CmmExpr -> CmmExpr -> CmmAGraph
 669 setInfo closure_ptr info_ptr = mkStore closure_ptr info_ptr
 670