compiler/coreSyn/CoreSyn.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7
   8 -- | CoreSyn holds all the main data types for use by for the Glasgow Haskell Compiler midsection
   9 module CoreSyn (
  10         -- * Main data types
  11         Expr(..), Alt, Bind(..), AltCon(..), Arg, Note(..),
  12         CoreExpr, CoreAlt, CoreBind, CoreArg, CoreBndr,
  13         TaggedExpr, TaggedAlt, TaggedBind, TaggedArg, TaggedBndr(..),
  14
  15         -- ** 'Expr' construction
  16         mkLets, mkLams,
  17         mkApps, mkTyApps, mkVarApps,
  18
  19         mkIntLit, mkIntLitInt,
  20         mkWordLit, mkWordLitWord,
  21         mkCharLit, mkStringLit,
  22         mkFloatLit, mkFloatLitFloat,
  23         mkDoubleLit, mkDoubleLitDouble,
  24
  25         mkConApp, mkTyBind,
  26         varToCoreExpr, varsToCoreExprs,
  27
  28         isTyVar, isId, cmpAltCon, cmpAlt, ltAlt,
  29
  30         -- ** Simple 'Expr' access functions and predicates
  31         bindersOf, bindersOfBinds, rhssOfBind, rhssOfAlts,
  32         collectBinders, collectTyBinders, collectValBinders, collectTyAndValBinders,
  33         collectArgs, coreExprCc, flattenBinds,
  34
  35         isValArg, isTypeArg, valArgCount, valBndrCount, isRuntimeArg, isRuntimeVar,
  36
  37         -- * Unfolding data types
  38         Unfolding(..),  UnfoldingGuidance(..), UnfoldingSource(..),
  39                 -- Abstract everywhere but in CoreUnfold.lhs
  40
  41         -- ** Constructing 'Unfolding's
  42         noUnfolding, evaldUnfolding, mkOtherCon,
  43         unSaturatedOk, needSaturated, boringCxtOk, boringCxtNotOk,
  44
  45         -- ** Predicates and deconstruction on 'Unfolding'
  46         unfoldingTemplate, setUnfoldingTemplate, expandUnfolding_maybe,
  47         maybeUnfoldingTemplate, otherCons, unfoldingArity,
  48         isValueUnfolding, isEvaldUnfolding, isCheapUnfolding,
  49         isExpandableUnfolding, isConLikeUnfolding, isCompulsoryUnfolding,
  50         isInlineRule, isInlineRule_maybe, isClosedUnfolding, hasSomeUnfolding,
  51         isStableUnfolding, canUnfold, neverUnfoldGuidance, isInlineRuleSource,
  52
  53         -- * Strictness
  54         seqExpr, seqExprs, seqUnfolding,
  55
  56         -- * Annotated expression data types
  57         AnnExpr, AnnExpr'(..), AnnBind(..), AnnAlt,
  58
  59         -- ** Operations on annotations
  60         deAnnotate, deAnnotate', deAnnAlt, collectAnnBndrs,
  61
  62         -- * Core rule data types
  63         CoreRule(..),   -- CoreSubst, CoreTidy, CoreFVs, PprCore only
  64         RuleName, IdUnfoldingFun,
  65
  66         -- ** Operations on 'CoreRule's
  67         seqRules, ruleArity, ruleName, ruleIdName, ruleActivation_maybe,
  68         setRuleIdName,
  69         isBuiltinRule, isLocalRule
  70     ) where
  71
  72 #include "HsVersions.h"
  73
  74 import CostCentre
  75 import Var
  76 import Type
  77 import Coercion
  78 import Name
  79 import Literal
  80 import DataCon
  81 import BasicTypes
  82 import FastString
  83 import Outputable
  84 import Util
  85
  86 import Data.Word
  87
  88 infixl 4 `mkApps`, `mkTyApps`, `mkVarApps`
  89 -- Left associative, so that we can say (f `mkTyApps` xs `mkVarApps` ys)
  90 \end{code}
  91
  92 %************************************************************************
  93 %*                                                                      *
  94 \subsection{The main data types}
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 These data types are the heart of the compiler
  99
 100 \begin{code}
 101 infixl 8 `App`  -- App brackets to the left
 102
 103 -- | This is the data type that represents GHCs core intermediate language. Currently
 104 -- GHC uses System FC <http://research.microsoft.com/~simonpj/papers/ext-f/> for this purpose,
 105 -- which is closely related to the simpler and better known System F <http://en.wikipedia.org/wiki/System_F>.
 106 --
 107 -- We get from Haskell source to this Core language in a number of stages:
 108 --
 109 -- 1. The source code is parsed into an abstract syntax tree, which is represented
 110 --    by the data type 'HsExpr.HsExpr' with the names being 'RdrName.RdrNames'
 111 --
 112 -- 2. This syntax tree is /renamed/, which attaches a 'Unique.Unique' to every 'RdrName.RdrName'
 113 --    (yielding a 'Name.Name') to disambiguate identifiers which are lexically identical.
 114 --    For example, this program:
 115 --
 116 -- @
 117 --      f x = let f x = x + 1
 118 --            in f (x - 2)
 119 -- @
 120 --
 121 --    Would be renamed by having 'Unique's attached so it looked something like this:
 122 --
 123 -- @
 124 --      f_1 x_2 = let f_3 x_4 = x_4 + 1
 125 --                in f_3 (x_2 - 2)
 126 -- @
 127 --
 128 -- 3. The resulting syntax tree undergoes type checking (which also deals with instantiating
 129 --    type class arguments) to yield a 'HsExpr.HsExpr' type that has 'Id.Id' as it's names.
 130 --
 131 -- 4. Finally the syntax tree is /desugared/ from the expressive 'HsExpr.HsExpr' type into
 132 --    this 'Expr' type, which has far fewer constructors and hence is easier to perform
 133 --    optimization, analysis and code generation on.
 134 --
 135 -- The type parameter @b@ is for the type of binders in the expression tree.
 136 data Expr b
 137   = Var   Id                            -- ^ Variables
 138   | Lit   Literal                       -- ^ Primitive literals
 139   | App   (Expr b) (Arg b)              -- ^ Applications: note that the argument may be a 'Type'.
 140                                         --
 141                                         -- See "CoreSyn#let_app_invariant" for another invariant
 142   | Lam   b (Expr b)                    -- ^ Lambda abstraction
 143   | Let   (Bind b) (Expr b)             -- ^ Recursive and non recursive @let@s. Operationally
 144                                         -- this corresponds to allocating a thunk for the things
 145                                         -- bound and then executing the sub-expression.
 146                                         --
 147                                         -- #top_level_invariant#
 148                                         -- #letrec_invariant#
 149                                         --
 150                                         -- The right hand sides of all top-level and recursive @let@s
 151                                         -- /must/ be of lifted type (see "Type#type_classification" for
 152                                         -- the meaning of /lifted/ vs. /unlifted/).
 153                                         --
 154                                         -- #let_app_invariant#
 155                                         -- The right hand side of of a non-recursive 'Let' _and_ the argument of an 'App',
 156                                         -- /may/ be of unlifted type, but only if the expression
 157                                         -- is ok-for-speculation.  This means that the let can be floated around
 158                                         -- without difficulty. For example, this is OK:
 159                                         --
 160                                         -- > y::Int# = x +# 1#
 161                                         --
 162                                         -- But this is not, as it may affect termination if the expression is floated out:
 163                                         --
 164                                         -- > y::Int# = fac 4#
 165                                         --
 166                                         -- In this situation you should use @case@ rather than a @let@. The function
 167                                         -- 'CoreUtils.needsCaseBinding' can help you determine which to generate, or
 168                                         -- alternatively use 'MkCore.mkCoreLet' rather than this constructor directly,
 169                                         -- which will generate a @case@ if necessary
 170                                         --
 171                                         -- #type_let#
 172                                         -- We allow a /non-recursive/ let to bind a type variable, thus:
 173                                         --
 174                                         -- > Let (NonRec tv (Type ty)) body
 175                                         --
 176                                         -- This can be very convenient for postponing type substitutions until
 177                                         -- the next run of the simplifier.
 178                                         --
 179                                         -- At the moment, the rest of the compiler only deals with type-let
 180                                         -- in a Let expression, rather than at top level.  We may want to revist
 181                                         -- this choice.
 182   | Case  (Expr b) b Type [Alt b]       -- ^ Case split. Operationally this corresponds to evaluating
 183                                         -- the scrutinee (expression examined) to weak head normal form
 184                                         -- and then examining at most one level of resulting constructor (i.e. you
 185                                         -- cannot do nested pattern matching directly with this).
 186                                         --
 187                                         -- The binder gets bound to the value of the scrutinee,
 188                                         -- and the 'Type' must be that of all the case alternatives
 189                                         --
 190                                         -- #case_invariants#
 191                                         -- This is one of the more complicated elements of the Core language, and comes
 192                                         -- with a number of restrictions:
 193                                         --
 194                                         -- The 'DEFAULT' case alternative must be first in the list, if it occurs at all.
 195                                         --
 196                                         -- The remaining cases are in order of increasing
 197                                         --      tag     (for 'DataAlts') or
 198                                         --      lit     (for 'LitAlts').
 199                                         -- This makes finding the relevant constructor easy, and makes comparison easier too.
 200                                         --
 201                                         -- The list of alternatives must be exhaustive. An /exhaustive/ case
 202                                         -- does not necessarily mention all constructors:
 203                                         --
 204                                         -- @
 205                                         --      data Foo = Red | Green | Blue
 206                                         -- ... case x of
 207                                         --      Red   -> True
 208                                         --      other -> f (case x of
 209                                         --                      Green -> ...
 210                                         --                      Blue  -> ... ) ...
 211                                         -- @
 212                                         --
 213                                         -- The inner case does not need a @Red@ alternative, because @x@ can't be @Red@ at
 214                                         -- that program point.
 215   | Cast  (Expr b) Coercion             -- ^ Cast an expression to a particular type. This is used to implement @newtype@s
 216                                         -- (a @newtype@ constructor or destructor just becomes a 'Cast' in Core) and GADTs.
 217   | Note  Note (Expr b)                 -- ^ Notes. These allow general information to be
 218                                         -- added to expressions in the syntax tree
 219   | Type  Type                          -- ^ A type: this should only show up at the top
 220                                         -- level of an Arg
 221
 222 -- | Type synonym for expressions that occur in function argument positions.
 223 -- Only 'Arg' should contain a 'Type' at top level, general 'Expr' should not
 224 type Arg b = Expr b
 225
 226 -- | A case split alternative. Consists of the constructor leading to the alternative,
 227 -- the variables bound from the constructor, and the expression to be executed given that binding.
 228 -- The default alternative is @(DEFAULT, [], rhs)@
 229 type Alt b = (AltCon, [b], Expr b)
 230
 231 -- | A case alternative constructor (i.e. pattern match)
 232 data AltCon = DataAlt DataCon   -- ^ A plain data constructor: @case e of { Foo x -> ... }@.
 233                                 -- Invariant: the 'DataCon' is always from a @data@ type, and never from a @newtype@
 234             | LitAlt  Literal   -- ^ A literal: @case e of { 1 -> ... }@
 235             | DEFAULT           -- ^ Trivial alternative: @case e of { _ -> ... }@
 236          deriving (Eq, Ord)
 237
 238 -- | Binding, used for top level bindings in a module and local bindings in a @let@.
 239 data Bind b = NonRec b (Expr b)
 240             | Rec [(b, (Expr b))]
 241 \end{code}
 242
 243 -------------------------- CoreSyn INVARIANTS ---------------------------
 244
 245 Note [CoreSyn top-level invariant]
 246 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 247 See #toplevel_invariant#
 248
 249 Note [CoreSyn letrec invariant]
 250 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 251 See #letrec_invariant#
 252
 253 Note [CoreSyn let/app invariant]
 254 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 255 See #let_app_invariant#
 256
 257 This is intially enforced by DsUtils.mkCoreLet and mkCoreApp
 258
 259 Note [CoreSyn case invariants]
 260 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 261 See #case_invariants#
 262
 263 Note [CoreSyn let goal]
 264 ~~~~~~~~~~~~~~~~~~~~~~~
 265 * The simplifier tries to ensure that if the RHS of a let is a constructor
 266   application, its arguments are trivial, so that the constructor can be
 267   inlined vigorously.
 268
 269
 270 Note [Type let]
 271 ~~~~~~~~~~~~~~~
 272 See #type_let#
 273
 274 \begin{code}
 275
 276 -- | Allows attaching extra information to points in expressions rather than e.g. identifiers.
 277 data Note
 278   = SCC CostCentre      -- ^ A cost centre annotation for profiling
 279   | CoreNote String     -- ^ A generic core annotation, propagated but not used by GHC
 280 \end{code}
 281
 282
 283 %************************************************************************
 284 %*                                                                      *
 285 \subsection{Transformation rules}
 286 %*                                                                      *
 287 %************************************************************************
 288
 289 The CoreRule type and its friends are dealt with mainly in CoreRules,
 290 but CoreFVs, Subst, PprCore, CoreTidy also inspect the representation.
 291
 292 \begin{code}
 293 -- | A 'CoreRule' is:
 294 --
 295 -- * \"Local\" if the function it is a rule for is defined in the
 296 --   same module as the rule itself.
 297 --
 298 -- * \"Orphan\" if nothing on the LHS is defined in the same module
 299 --   as the rule itself
 300 data CoreRule
 301   = Rule {
 302         ru_name :: RuleName,            -- ^ Name of the rule, for communication with the user
 303         ru_act  :: Activation,          -- ^ When the rule is active
 304
 305         -- Rough-matching stuff
 306         -- see comments with InstEnv.Instance( is_cls, is_rough )
 307         ru_fn    :: Name,               -- ^ Name of the 'Id.Id' at the head of this rule
 308         ru_rough :: [Maybe Name],       -- ^ Name at the head of each argument to the left hand side
 309
 310         -- Proper-matching stuff
 311         -- see comments with InstEnv.Instance( is_tvs, is_tys )
 312         ru_bndrs :: [CoreBndr],         -- ^ Variables quantified over
 313         ru_args  :: [CoreExpr],         -- ^ Left hand side arguments
 314
 315         -- And the right-hand side
 316         ru_rhs   :: CoreExpr,           -- ^ Right hand side of the rule
 317                                         -- Occurrence info is guaranteed correct
 318                                         -- See Note [OccInfo in unfoldings and rules]
 319
 320         -- Locality
 321         ru_local :: Bool        -- ^ @True@ iff the fn at the head of the rule is
 322                                 -- defined in the same module as the rule
 323                                 -- and is not an implicit 'Id' (like a record selector,
 324                                 -- class operation, or data constructor)
 325
 326                 -- NB: ru_local is *not* used to decide orphan-hood
 327                 --      c.g. MkIface.coreRuleToIfaceRule
 328     }
 329
 330   -- | Built-in rules are used for constant folding
 331   -- and suchlike.  They have no free variables.
 332   | BuiltinRule {
 333         ru_name  :: RuleName,   -- ^ As above
 334         ru_fn    :: Name,       -- ^ As above
 335         ru_nargs :: Int,        -- ^ Number of arguments that 'ru_try' consumes,
 336                                 -- if it fires, including type arguments
 337         ru_try  :: IdUnfoldingFun -> [CoreExpr] -> Maybe CoreExpr
 338                 -- ^ This function does the rewrite.  It given too many
 339                 -- arguments, it simply discards them; the returned 'CoreExpr'
 340                 -- is just the rewrite of 'ru_fn' applied to the first 'ru_nargs' args
 341     }
 342                 -- See Note [Extra args in rule matching] in Rules.lhs
 343
 344 type IdUnfoldingFun = Id -> Unfolding
 345 -- A function that embodies how to unfold an Id if you need
 346 -- to do that in the Rule.  The reason we need to pass this info in
 347 -- is that whether an Id is unfoldable depends on the simplifier phase
 348
 349 isBuiltinRule :: CoreRule -> Bool
 350 isBuiltinRule (BuiltinRule {}) = True
 351 isBuiltinRule _                = False
 352
 353 -- | The number of arguments the 'ru_fn' must be applied
 354 -- to before the rule can match on it
 355 ruleArity :: CoreRule -> Int
 356 ruleArity (BuiltinRule {ru_nargs = n}) = n
 357 ruleArity (Rule {ru_args = args})      = length args
 358
 359 ruleName :: CoreRule -> RuleName
 360 ruleName = ru_name
 361
 362 ruleActivation_maybe :: CoreRule -> Maybe Activation
 363 ruleActivation_maybe (BuiltinRule { })       = Nothing
 364 ruleActivation_maybe (Rule { ru_act = act }) = Just act
 365
 366 -- | The 'Name' of the 'Id.Id' at the head of the rule left hand side
 367 ruleIdName :: CoreRule -> Name
 368 ruleIdName = ru_fn
 369
 370 isLocalRule :: CoreRule -> Bool
 371 isLocalRule = ru_local
 372
 373 -- | Set the 'Name' of the 'Id.Id' at the head of the rule left hand side
 374 setRuleIdName :: Name -> CoreRule -> CoreRule
 375 setRuleIdName nm ru = ru { ru_fn = nm }
 376 \end{code}
 377
 378
 379 %************************************************************************
 380 %*                                                                      *
 381                 Unfoldings
 382 %*                                                                      *
 383 %************************************************************************
 384
 385 The @Unfolding@ type is declared here to avoid numerous loops
 386
 387 \begin{code}
 388 -- | Records the /unfolding/ of an identifier, which is approximately the form the
 389 -- identifier would have if we substituted its definition in for the identifier.
 390 -- This type should be treated as abstract everywhere except in "CoreUnfold"
 391 data Unfolding
 392   = NoUnfolding        -- ^ We have no information about the unfolding
 393
 394   | OtherCon [AltCon]  -- ^ It ain't one of these constructors.
 395                        -- @OtherCon xs@ also indicates that something has been evaluated
 396                        -- and hence there's no point in re-evaluating it.
 397                        -- @OtherCon []@ is used even for non-data-type values
 398                        -- to indicated evaluated-ness.  Notably:
 399                        --
 400                        -- > data C = C !(Int -> Int)
 401                        -- > case x of { C f -> ... }
 402                        --
 403                        -- Here, @f@ gets an @OtherCon []@ unfolding.
 404
 405   | DFunUnfolding DataCon [CoreExpr]
 406                         -- The Unfolding of a DFunId
 407                         --     df = /\a1..am. \d1..dn. MkD (op1 a1..am d1..dn)
 408                         --                                 (op2 a1..am d1..dn)
 409                         -- where Arity = n, the number of dict args to the dfun
 410                         -- The [CoreExpr] are the superclasses and methods [op1,op2],
 411                         -- in positional order.
 412                         -- They are usually variables, but can be trivial expressions
 413                         -- instead (e.g. a type application).
 414
 415   | CoreUnfolding {             -- An unfolding for an Id with no pragma, or perhaps a NOINLINE pragma
 416                                 -- (For NOINLINE, the phase, if any, is in the InlinePragInfo for this Id.)
 417         uf_tmpl       :: CoreExpr,        -- Template; occurrence info is correct
 418         uf_src        :: UnfoldingSource, -- Where the unfolding came from
 419         uf_is_top     :: Bool,          -- True <=> top level binding
 420         uf_arity      :: Arity,         -- Number of value arguments expected
 421         uf_is_value   :: Bool,          -- exprIsHNF template (cached); it is ok to discard a `seq` on
 422                                         --      this variable
 423         uf_is_conlike :: Bool,          -- True <=> application of constructor or CONLIKE function
 424                                         --      Cached version of exprIsConLike
 425         uf_is_cheap   :: Bool,          -- True <=> doesn't waste (much) work to expand inside an inlining
 426                                         --      Cached version of exprIsCheap
 427         uf_expandable :: Bool,          -- True <=> can expand in RULE matching
 428                                         --      Cached version of exprIsExpandable
 429         uf_guidance   :: UnfoldingGuidance      -- Tells about the *size* of the template.
 430     }
 431   -- ^ An unfolding with redundant cached information. Parameters:
 432   --
 433   --  uf_tmpl: Template used to perform unfolding;
 434   --           NB: Occurrence info is guaranteed correct:
 435   --               see Note [OccInfo in unfoldings and rules]
 436   --
 437   --  uf_is_top: Is this a top level binding?
 438   --
 439   --  uf_is_value: 'exprIsHNF' template (cached); it is ok to discard a 'seq' on
 440   --     this variable
 441   --
 442   --  uf_is_cheap:  Does this waste only a little work if we expand it inside an inlining?
 443   --     Basically this is a cached version of 'exprIsCheap'
 444   --
 445   --  uf_guidance:  Tells us about the /size/ of the unfolding template
 446
 447 ------------------------------------------------
 448 data UnfoldingSource
 449   = InlineCompulsory   -- Something that *has* no binding, so you *must* inline it
 450                        -- Only a few primop-like things have this property
 451                        -- (see MkId.lhs, calls to mkCompulsoryUnfolding).
 452                        -- Inline absolutely always, however boring the context.
 453
 454   | InlineRule         -- From an {-# INLINE #-} pragma; See Note [InlineRules]
 455
 456   | InlineWrapper Id   -- This unfolding is a the wrapper in a
 457                        --     worker/wrapper split from the strictness analyser
 458                        -- The Id is the worker-id
 459                        -- Used to abbreviate the uf_tmpl in interface files
 460                        --       which don't need to contain the RHS;
 461                        --       it can be derived from the strictness info
 462
 463   | InlineRhs          -- The current rhs of the function
 464
 465    -- For InlineRhs, the uf_tmpl is replaced each time around
 466    -- For all the others we leave uf_tmpl alone
 467
 468
 469 -- | 'UnfoldingGuidance' says when unfolding should take place
 470 data UnfoldingGuidance
 471   = UnfWhen {   -- Inline without thinking about the *size* of the uf_tmpl
 472                 -- Used (a) for small *and* cheap unfoldings
 473                 --      (b) for INLINE functions
 474                 -- See Note [INLINE for small functions] in CoreUnfold
 475       ug_unsat_ok  :: Bool,     -- True <=> ok to inline even if unsaturated
 476       ug_boring_ok :: Bool      -- True <=> ok to inline even if the context is boring
 477     }
 478
 479   | UnfIfGoodArgs {     -- Arose from a normal Id; the info here is the
 480                         -- result of a simple analysis of the RHS
 481
 482       ug_args ::  [Int],  -- Discount if the argument is evaluated.
 483                           -- (i.e., a simplification will definitely
 484                           -- be possible).  One elt of the list per *value* arg.
 485
 486       ug_size :: Int,     -- The "size" of the unfolding.
 487
 488       ug_res :: Int       -- Scrutinee discount: the discount to substract if the thing is in
 489     }                     -- a context (case (thing args) of ...),
 490                           -- (where there are the right number of arguments.)
 491
 492   | UnfNever        -- The RHS is big, so don't inline it
 493
 494 -- Constants for the UnfWhen constructor
 495 needSaturated, unSaturatedOk :: Bool
 496 needSaturated = False
 497 unSaturatedOk = True
 498
 499 boringCxtNotOk, boringCxtOk :: Bool
 500 boringCxtOk    = True
 501 boringCxtNotOk = False
 502
 503 ------------------------------------------------
 504 noUnfolding :: Unfolding
 505 -- ^ There is no known 'Unfolding'
 506 evaldUnfolding :: Unfolding
 507 -- ^ This unfolding marks the associated thing as being evaluated
 508
 509 noUnfolding    = NoUnfolding
 510 evaldUnfolding = OtherCon []
 511
 512 mkOtherCon :: [AltCon] -> Unfolding
 513 mkOtherCon = OtherCon
 514
 515 seqUnfolding :: Unfolding -> ()
 516 seqUnfolding (CoreUnfolding { uf_tmpl = e, uf_is_top = top,
 517                 uf_is_value = b1, uf_is_cheap = b2,
 518                 uf_expandable = b3, uf_is_conlike = b4,
 519                 uf_arity = a, uf_guidance = g})
 520   = seqExpr e `seq` top `seq` b1 `seq` a `seq` b2 `seq` b3 `seq` b4 `seq` seqGuidance g
 521
 522 seqUnfolding _ = ()
 523
 524 seqGuidance :: UnfoldingGuidance -> ()
 525 seqGuidance (UnfIfGoodArgs ns n b) = n `seq` sum ns `seq` b `seq` ()
 526 seqGuidance _                      = ()
 527 \end{code}
 528
 529 \begin{code}
 530 isInlineRuleSource :: UnfoldingSource -> Bool
 531 isInlineRuleSource InlineCompulsory   = True
 532 isInlineRuleSource InlineRule         = True
 533 isInlineRuleSource (InlineWrapper {}) = True
 534 isInlineRuleSource InlineRhs          = False
 535
 536 -- | Retrieves the template of an unfolding: panics if none is known
 537 unfoldingTemplate :: Unfolding -> CoreExpr
 538 unfoldingTemplate = uf_tmpl
 539
 540 setUnfoldingTemplate :: Unfolding -> CoreExpr -> Unfolding
 541 setUnfoldingTemplate unf rhs = unf { uf_tmpl = rhs }
 542
 543 -- | Retrieves the template of an unfolding if possible
 544 maybeUnfoldingTemplate :: Unfolding -> Maybe CoreExpr
 545 maybeUnfoldingTemplate (CoreUnfolding { uf_tmpl = expr })       = Just expr
 546 maybeUnfoldingTemplate _                                        = Nothing
 547
 548 -- | The constructors that the unfolding could never be:
 549 -- returns @[]@ if no information is available
 550 otherCons :: Unfolding -> [AltCon]
 551 otherCons (OtherCon cons) = cons
 552 otherCons _               = []
 553
 554 -- | Determines if it is certainly the case that the unfolding will
 555 -- yield a value (something in HNF): returns @False@ if unsure
 556 isValueUnfolding :: Unfolding -> Bool
 557         -- Returns False for OtherCon
 558 isValueUnfolding (CoreUnfolding { uf_is_value = is_evald }) = is_evald
 559 isValueUnfolding _                                          = False
 560
 561 -- | Determines if it possibly the case that the unfolding will
 562 -- yield a value. Unlike 'isValueUnfolding' it returns @True@
 563 -- for 'OtherCon'
 564 isEvaldUnfolding :: Unfolding -> Bool
 565         -- Returns True for OtherCon
 566 isEvaldUnfolding (OtherCon _)                               = True
 567 isEvaldUnfolding (CoreUnfolding { uf_is_value = is_evald }) = is_evald
 568 isEvaldUnfolding _                                          = False
 569
 570 -- | @True@ if the unfolding is a constructor application, the application
 571 -- of a CONLIKE function or 'OtherCon'
 572 isConLikeUnfolding :: Unfolding -> Bool
 573 isConLikeUnfolding (OtherCon _)                             = True
 574 isConLikeUnfolding (CoreUnfolding { uf_is_conlike = con })  = con
 575 isConLikeUnfolding _                                        = False
 576
 577 -- | Is the thing we will unfold into certainly cheap?
 578 isCheapUnfolding :: Unfolding -> Bool
 579 isCheapUnfolding (CoreUnfolding { uf_is_cheap = is_cheap }) = is_cheap
 580 isCheapUnfolding _                                          = False
 581
 582 isExpandableUnfolding :: Unfolding -> Bool
 583 isExpandableUnfolding (CoreUnfolding { uf_expandable = is_expable }) = is_expable
 584 isExpandableUnfolding _                                              = False
 585
 586 expandUnfolding_maybe :: Unfolding -> Maybe CoreExpr
 587 -- Expand an expandable unfolding; this is used in rule matching
 588 --   See Note [Expanding variables] in Rules.lhs
 589 -- The key point here is that CONLIKE things can be expanded
 590 expandUnfolding_maybe (CoreUnfolding { uf_expandable = True, uf_tmpl = rhs }) = Just rhs
 591 expandUnfolding_maybe _                                                       = Nothing
 592
 593 isInlineRule :: Unfolding -> Bool
 594 isInlineRule (CoreUnfolding { uf_src = src }) = isInlineRuleSource src
 595 isInlineRule _                                = False
 596
 597 isInlineRule_maybe :: Unfolding -> Maybe (UnfoldingSource, Bool)
 598 isInlineRule_maybe (CoreUnfolding { uf_src = src, uf_guidance = guide })
 599    | isInlineRuleSource src
 600    = Just (src, unsat_ok)
 601    where
 602      unsat_ok = case guide of
 603                   UnfWhen unsat_ok _ -> unsat_ok
 604                   _                  -> needSaturated
 605 isInlineRule_maybe _ = Nothing
 606
 607 isCompulsoryUnfolding :: Unfolding -> Bool
 608 isCompulsoryUnfolding (CoreUnfolding { uf_src = InlineCompulsory }) = True
 609 isCompulsoryUnfolding _                                             = False
 610
 611 isStableUnfolding :: Unfolding -> Bool
 612 -- True of unfoldings that should not be overwritten
 613 -- by a CoreUnfolding for the RHS of a let-binding
 614 isStableUnfolding (CoreUnfolding { uf_src = src }) = isInlineRuleSource src
 615 isStableUnfolding (DFunUnfolding {})               = True
 616 isStableUnfolding _                                = False
 617
 618 unfoldingArity :: Unfolding -> Arity
 619 unfoldingArity (CoreUnfolding { uf_arity = arity }) = arity
 620 unfoldingArity _                                    = panic "unfoldingArity"
 621
 622 isClosedUnfolding :: Unfolding -> Bool          -- No free variables
 623 isClosedUnfolding (CoreUnfolding {}) = False
 624 isClosedUnfolding _                  = True
 625
 626 -- | Only returns False if there is no unfolding information available at all
 627 hasSomeUnfolding :: Unfolding -> Bool
 628 hasSomeUnfolding NoUnfolding = False
 629 hasSomeUnfolding _           = True
 630
 631 neverUnfoldGuidance :: UnfoldingGuidance -> Bool
 632 neverUnfoldGuidance UnfNever = True
 633 neverUnfoldGuidance _        = False
 634
 635 canUnfold :: Unfolding -> Bool
 636 canUnfold (CoreUnfolding { uf_guidance = g }) = not (neverUnfoldGuidance g)
 637 canUnfold _                                   = False
 638 \end{code}
 639
 640 Note [InlineRules]
 641 ~~~~~~~~~~~~~~~~~
 642 When you say
 643       {-# INLINE f #-}
 644       f x = <rhs>
 645 you intend that calls (f e) are replaced by <rhs>[e/x] So we
 646 should capture (\x.<rhs>) in the Unfolding of 'f', and never meddle
 647 with it.  Meanwhile, we can optimise <rhs> to our heart's content,
 648 leaving the original unfolding intact in Unfolding of 'f'. For example
 649         all xs = foldr (&&) True xs
 650         any p = all . map p  {-# INLINE any #-}
 651 We optimise any's RHS fully, but leave the InlineRule saying "all . map p",
 652 which deforests well at the call site.
 653
 654 So INLINE pragma gives rise to an InlineRule, which captures the original RHS.
 655
 656 Moreover, it's only used when 'f' is applied to the
 657 specified number of arguments; that is, the number of argument on
 658 the LHS of the '=' sign in the original source definition.
 659 For example, (.) is now defined in the libraries like this
 660    {-# INLINE (.) #-}
 661    (.) f g = \x -> f (g x)
 662 so that it'll inline when applied to two arguments. If 'x' appeared
 663 on the left, thus
 664    (.) f g x = f (g x)
 665 it'd only inline when applied to three arguments.  This slightly-experimental
 666 change was requested by Roman, but it seems to make sense.
 667
 668 See also Note [Inlining an InlineRule] in CoreUnfold.
 669
 670
 671 Note [OccInfo in unfoldings and rules]
 672 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 673 In unfoldings and rules, we guarantee that the template is occ-analysed,
 674 so that the occurence info on the binders is correct.  This is important,
 675 because the Simplifier does not re-analyse the template when using it. If
 676 the occurrence info is wrong
 677   - We may get more simpifier iterations than necessary, because
 678     once-occ info isn't there
 679   - More seriously, we may get an infinite loop if there's a Rec
 680     without a loop breaker marked
 681
 682
 683 %************************************************************************
 684 %*                                                                      *
 685 \subsection{The main data type}
 686 %*                                                                      *
 687 %************************************************************************
 688
 689 \begin{code}
 690 -- The Ord is needed for the FiniteMap used in the lookForConstructor
 691 -- in SimplEnv.  If you declared that lookForConstructor *ignores*
 692 -- constructor-applications with LitArg args, then you could get
 693 -- rid of this Ord.
 694
 695 instance Outputable AltCon where
 696   ppr (DataAlt dc) = ppr dc
 697   ppr (LitAlt lit) = ppr lit
 698   ppr DEFAULT      = ptext (sLit "__DEFAULT")
 699
 700 instance Show AltCon where
 701   showsPrec p con = showsPrecSDoc p (ppr con)
 702
 703 cmpAlt :: Alt b -> Alt b -> Ordering
 704 cmpAlt (con1, _, _) (con2, _, _) = con1 `cmpAltCon` con2
 705
 706 ltAlt :: Alt b -> Alt b -> Bool
 707 ltAlt a1 a2 = (a1 `cmpAlt` a2) == LT
 708
 709 cmpAltCon :: AltCon -> AltCon -> Ordering
 710 -- ^ Compares 'AltCon's within a single list of alternatives
 711 cmpAltCon DEFAULT      DEFAULT     = EQ
 712 cmpAltCon DEFAULT      _           = LT
 713
 714 cmpAltCon (DataAlt d1) (DataAlt d2) = dataConTag d1 `compare` dataConTag d2
 715 cmpAltCon (DataAlt _)  DEFAULT      = GT
 716 cmpAltCon (LitAlt  l1) (LitAlt  l2) = l1 `compare` l2
 717 cmpAltCon (LitAlt _)   DEFAULT      = GT
 718
 719 cmpAltCon con1 con2 = WARN( True, text "Comparing incomparable AltCons" <+>
 720                                   ppr con1 <+> ppr con2 )
 721                       LT
 722 \end{code}
 723
 724 %************************************************************************
 725 %*                                                                      *
 726 \subsection{Useful synonyms}
 727 %*                                                                      *
 728 %************************************************************************
 729
 730 \begin{code}
 731 -- | The common case for the type of binders and variables when
 732 -- we are manipulating the Core language within GHC
 733 type CoreBndr = Var
 734 -- | Expressions where binders are 'CoreBndr's
 735 type CoreExpr = Expr CoreBndr
 736 -- | Argument expressions where binders are 'CoreBndr's
 737 type CoreArg  = Arg  CoreBndr
 738 -- | Binding groups where binders are 'CoreBndr's
 739 type CoreBind = Bind CoreBndr
 740 -- | Case alternatives where binders are 'CoreBndr's
 741 type CoreAlt  = Alt  CoreBndr
 742 \end{code}
 743
 744 %************************************************************************
 745 %*                                                                      *
 746 \subsection{Tagging}
 747 %*                                                                      *
 748 %************************************************************************
 749
 750 \begin{code}
 751 -- | Binders are /tagged/ with a t
 752 data TaggedBndr t = TB CoreBndr t       -- TB for "tagged binder"
 753
 754 type TaggedBind t = Bind (TaggedBndr t)
 755 type TaggedExpr t = Expr (TaggedBndr t)
 756 type TaggedArg  t = Arg  (TaggedBndr t)
 757 type TaggedAlt  t = Alt  (TaggedBndr t)
 758
 759 instance Outputable b => Outputable (TaggedBndr b) where
 760   ppr (TB b l) = char '<' <> ppr b <> comma <> ppr l <> char '>'
 761
 762 instance Outputable b => OutputableBndr (TaggedBndr b) where
 763   pprBndr _ b = ppr b   -- Simple
 764 \end{code}
 765
 766
 767 %************************************************************************
 768 %*                                                                      *
 769 \subsection{Core-constructing functions with checking}
 770 %*                                                                      *
 771 %************************************************************************
 772
 773 \begin{code}
 774 -- | Apply a list of argument expressions to a function expression in a nested fashion. Prefer to
 775 -- use 'CoreUtils.mkCoreApps' if possible
 776 mkApps    :: Expr b -> [Arg b]  -> Expr b
 777 -- | Apply a list of type argument expressions to a function expression in a nested fashion
 778 mkTyApps  :: Expr b -> [Type]   -> Expr b
 779 -- | Apply a list of type or value variables to a function expression in a nested fashion
 780 mkVarApps :: Expr b -> [Var] -> Expr b
 781 -- | Apply a list of argument expressions to a data constructor in a nested fashion. Prefer to
 782 -- use 'MkCore.mkCoreConApps' if possible
 783 mkConApp      :: DataCon -> [Arg b] -> Expr b
 784
 785 mkApps    f args = foldl App                       f args
 786 mkTyApps  f args = foldl (\ e a -> App e (Type a)) f args
 787 mkVarApps f vars = foldl (\ e a -> App e (varToCoreExpr a)) f vars
 788 mkConApp con args = mkApps (Var (dataConWorkId con)) args
 789
 790
 791 -- | Create a machine integer literal expression of type @Int#@ from an @Integer@.
 792 -- If you want an expression of type @Int@ use 'MkCore.mkIntExpr'
 793 mkIntLit      :: Integer -> Expr b
 794 -- | Create a machine integer literal expression of type @Int#@ from an @Int@.
 795 -- If you want an expression of type @Int@ use 'MkCore.mkIntExpr'
 796 mkIntLitInt   :: Int     -> Expr b
 797
 798 mkIntLit    n = Lit (mkMachInt n)
 799 mkIntLitInt n = Lit (mkMachInt (toInteger n))
 800
 801 -- | Create a machine word literal expression of type  @Word#@ from an @Integer@.
 802 -- If you want an expression of type @Word@ use 'MkCore.mkWordExpr'
 803 mkWordLit     :: Integer -> Expr b
 804 -- | Create a machine word literal expression of type  @Word#@ from a @Word@.
 805 -- If you want an expression of type @Word@ use 'MkCore.mkWordExpr'
 806 mkWordLitWord :: Word -> Expr b
 807
 808 mkWordLit     w = Lit (mkMachWord w)
 809 mkWordLitWord w = Lit (mkMachWord (toInteger w))
 810
 811 -- | Create a machine character literal expression of type @Char#@.
 812 -- If you want an expression of type @Char@ use 'MkCore.mkCharExpr'
 813 mkCharLit :: Char -> Expr b
 814 -- | Create a machine string literal expression of type @Addr#@.
 815 -- If you want an expression of type @String@ use 'MkCore.mkStringExpr'
 816 mkStringLit :: String -> Expr b
 817
 818 mkCharLit   c = Lit (mkMachChar c)
 819 mkStringLit s = Lit (mkMachString s)
 820
 821 -- | Create a machine single precision literal expression of type @Float#@ from a @Rational@.
 822 -- If you want an expression of type @Float@ use 'MkCore.mkFloatExpr'
 823 mkFloatLit :: Rational -> Expr b
 824 -- | Create a machine single precision literal expression of type @Float#@ from a @Float@.
 825 -- If you want an expression of type @Float@ use 'MkCore.mkFloatExpr'
 826 mkFloatLitFloat :: Float -> Expr b
 827
 828 mkFloatLit      f = Lit (mkMachFloat f)
 829 mkFloatLitFloat f = Lit (mkMachFloat (toRational f))
 830
 831 -- | Create a machine double precision literal expression of type @Double#@ from a @Rational@.
 832 -- If you want an expression of type @Double@ use 'MkCore.mkDoubleExpr'
 833 mkDoubleLit :: Rational -> Expr b
 834 -- | Create a machine double precision literal expression of type @Double#@ from a @Double@.
 835 -- If you want an expression of type @Double@ use 'MkCore.mkDoubleExpr'
 836 mkDoubleLitDouble :: Double -> Expr b
 837
 838 mkDoubleLit       d = Lit (mkMachDouble d)
 839 mkDoubleLitDouble d = Lit (mkMachDouble (toRational d))
 840
 841 -- | Bind all supplied binding groups over an expression in a nested let expression. Prefer to
 842 -- use 'CoreUtils.mkCoreLets' if possible
 843 mkLets        :: [Bind b] -> Expr b -> Expr b
 844 -- | Bind all supplied binders over an expression in a nested lambda expression. Prefer to
 845 -- use 'CoreUtils.mkCoreLams' if possible
 846 mkLams        :: [b] -> Expr b -> Expr b
 847
 848 mkLams binders body = foldr Lam body binders
 849 mkLets binds body   = foldr Let body binds
 850
 851
 852 -- | Create a binding group where a type variable is bound to a type. Per "CoreSyn#type_let",
 853 -- this can only be used to bind something in a non-recursive @let@ expression
 854 mkTyBind :: TyVar -> Type -> CoreBind
 855 mkTyBind tv ty      = NonRec tv (Type ty)
 856
 857 -- | Convert a binder into either a 'Var' or 'Type' 'Expr' appropriately
 858 varToCoreExpr :: CoreBndr -> Expr b
 859 varToCoreExpr v | isId v = Var v
 860                 | otherwise = Type (mkTyVarTy v)
 861
 862 varsToCoreExprs :: [CoreBndr] -> [Expr b]
 863 varsToCoreExprs vs = map varToCoreExpr vs
 864 \end{code}
 865
 866
 867 %************************************************************************
 868 %*                                                                      *
 869 \subsection{Simple access functions}
 870 %*                                                                      *
 871 %************************************************************************
 872
 873 \begin{code}
 874 -- | Extract every variable by this group
 875 bindersOf  :: Bind b -> [b]
 876 bindersOf (NonRec binder _) = [binder]
 877 bindersOf (Rec pairs)       = [binder | (binder, _) <- pairs]
 878
 879 -- | 'bindersOf' applied to a list of binding groups
 880 bindersOfBinds :: [Bind b] -> [b]
 881 bindersOfBinds binds = foldr ((++) . bindersOf) [] binds
 882
 883 rhssOfBind :: Bind b -> [Expr b]
 884 rhssOfBind (NonRec _ rhs) = [rhs]
 885 rhssOfBind (Rec pairs)    = [rhs | (_,rhs) <- pairs]
 886
 887 rhssOfAlts :: [Alt b] -> [Expr b]
 888 rhssOfAlts alts = [e | (_,_,e) <- alts]
 889
 890 -- | Collapse all the bindings in the supplied groups into a single
 891 -- list of lhs\/rhs pairs suitable for binding in a 'Rec' binding group
 892 flattenBinds :: [Bind b] -> [(b, Expr b)]
 893 flattenBinds (NonRec b r : binds) = (b,r) : flattenBinds binds
 894 flattenBinds (Rec prs1   : binds) = prs1 ++ flattenBinds binds
 895 flattenBinds []                   = []
 896 \end{code}
 897
 898 \begin{code}
 899 -- | We often want to strip off leading lambdas before getting down to
 900 -- business. This function is your friend.
 901 collectBinders               :: Expr b -> ([b],         Expr b)
 902 -- | Collect as many type bindings as possible from the front of a nested lambda
 903 collectTyBinders             :: CoreExpr -> ([TyVar],     CoreExpr)
 904 -- | Collect as many value bindings as possible from the front of a nested lambda
 905 collectValBinders            :: CoreExpr -> ([Id],        CoreExpr)
 906 -- | Collect type binders from the front of the lambda first,
 907 -- then follow up by collecting as many value bindings as possible
 908 -- from the resulting stripped expression
 909 collectTyAndValBinders       :: CoreExpr -> ([TyVar], [Id], CoreExpr)
 910
 911 collectBinders expr
 912   = go [] expr
 913   where
 914     go bs (Lam b e) = go (b:bs) e
 915     go bs e          = (reverse bs, e)
 916
 917 collectTyAndValBinders expr
 918   = (tvs, ids, body)
 919   where
 920     (tvs, body1) = collectTyBinders expr
 921     (ids, body)  = collectValBinders body1
 922
 923 collectTyBinders expr
 924   = go [] expr
 925   where
 926     go tvs (Lam b e) | isTyVar b = go (b:tvs) e
 927     go tvs e                     = (reverse tvs, e)
 928
 929 collectValBinders expr
 930   = go [] expr
 931   where
 932     go ids (Lam b e) | isId b = go (b:ids) e
 933     go ids body               = (reverse ids, body)
 934 \end{code}
 935
 936 \begin{code}
 937 -- | Takes a nested application expression and returns the the function
 938 -- being applied and the arguments to which it is applied
 939 collectArgs :: Expr b -> (Expr b, [Arg b])
 940 collectArgs expr
 941   = go expr []
 942   where
 943     go (App f a) as = go f (a:as)
 944     go e         as = (e, as)
 945 \end{code}
 946
 947 \begin{code}
 948 -- | Gets the cost centre enclosing an expression, if any.
 949 -- It looks inside lambdas because @(scc \"foo\" \\x.e) = \\x. scc \"foo\" e@
 950 coreExprCc :: Expr b -> CostCentre
 951 coreExprCc (Note (SCC cc) _)   = cc
 952 coreExprCc (Note _ e)          = coreExprCc e
 953 coreExprCc (Lam _ e)           = coreExprCc e
 954 coreExprCc _                   = noCostCentre
 955 \end{code}
 956
 957 %************************************************************************
 958 %*                                                                      *
 959 \subsection{Predicates}
 960 %*                                                                      *
 961 %************************************************************************
 962
 963 At one time we optionally carried type arguments through to runtime.
 964 @isRuntimeVar v@ returns if (Lam v _) really becomes a lambda at runtime,
 965 i.e. if type applications are actual lambdas because types are kept around
 966 at runtime.  Similarly isRuntimeArg.
 967
 968 \begin{code}
 969 -- | Will this variable exist at runtime?
 970 isRuntimeVar :: Var -> Bool
 971 isRuntimeVar = isId
 972
 973 -- | Will this argument expression exist at runtime?
 974 isRuntimeArg :: CoreExpr -> Bool
 975 isRuntimeArg = isValArg
 976
 977 -- | Returns @False@ iff the expression is a 'Type' expression at its top level
 978 isValArg :: Expr b -> Bool
 979 isValArg (Type _) = False
 980 isValArg _        = True
 981
 982 -- | Returns @True@ iff the expression is a 'Type' expression at its top level
 983 isTypeArg :: Expr b -> Bool
 984 isTypeArg (Type _) = True
 985 isTypeArg _        = False
 986
 987 -- | The number of binders that bind values rather than types
 988 valBndrCount :: [CoreBndr] -> Int
 989 valBndrCount = count isId
 990
 991 -- | The number of argument expressions that are values rather than types at their top level
 992 valArgCount :: [Arg b] -> Int
 993 valArgCount = count isValArg
 994 \end{code}
 995
 996
 997 %************************************************************************
 998 %*                                                                      *
 999 \subsection{Seq stuff}
1000 %*                                                                      *
1001 %************************************************************************
1002
1003 \begin{code}
1004 seqExpr :: CoreExpr -> ()
1005 seqExpr (Var v)         = v `seq` ()
1006 seqExpr (Lit lit)       = lit `seq` ()
1007 seqExpr (App f a)       = seqExpr f `seq` seqExpr a
1008 seqExpr (Lam b e)       = seqBndr b `seq` seqExpr e
1009 seqExpr (Let b e)       = seqBind b `seq` seqExpr e
1010 seqExpr (Case e b t as) = seqExpr e `seq` seqBndr b `seq` seqType t `seq` seqAlts as
1011 seqExpr (Cast e co)     = seqExpr e `seq` seqType co
1012 seqExpr (Note n e)      = seqNote n `seq` seqExpr e
1013 seqExpr (Type t)        = seqType t
1014
1015 seqExprs :: [CoreExpr] -> ()
1016 seqExprs [] = ()
1017 seqExprs (e:es) = seqExpr e `seq` seqExprs es
1018
1019 seqNote :: Note -> ()
1020 seqNote (CoreNote s)   = s `seq` ()
1021 seqNote _              = ()
1022
1023 seqBndr :: CoreBndr -> ()
1024 seqBndr b = b `seq` ()
1025
1026 seqBndrs :: [CoreBndr] -> ()
1027 seqBndrs [] = ()
1028 seqBndrs (b:bs) = seqBndr b `seq` seqBndrs bs
1029
1030 seqBind :: Bind CoreBndr -> ()
1031 seqBind (NonRec b e) = seqBndr b `seq` seqExpr e
1032 seqBind (Rec prs)    = seqPairs prs
1033
1034 seqPairs :: [(CoreBndr, CoreExpr)] -> ()
1035 seqPairs [] = ()
1036 seqPairs ((b,e):prs) = seqBndr b `seq` seqExpr e `seq` seqPairs prs
1037
1038 seqAlts :: [CoreAlt] -> ()
1039 seqAlts [] = ()
1040 seqAlts ((c,bs,e):alts) = c `seq` seqBndrs bs `seq` seqExpr e `seq` seqAlts alts
1041
1042 seqRules :: [CoreRule] -> ()
1043 seqRules [] = ()
1044 seqRules (Rule { ru_bndrs = bndrs, ru_args = args, ru_rhs = rhs } : rules)
1045   = seqBndrs bndrs `seq` seqExprs (rhs:args) `seq` seqRules rules
1046 seqRules (BuiltinRule {} : rules) = seqRules rules
1047 \end{code}
1048
1049 %************************************************************************
1050 %*                                                                      *
1051 \subsection{Annotated core}
1052 %*                                                                      *
1053 %************************************************************************
1054
1055 \begin{code}
1056 -- | Annotated core: allows annotation at every node in the tree
1057 type AnnExpr bndr annot = (annot, AnnExpr' bndr annot)
1058
1059 -- | A clone of the 'Expr' type but allowing annotation at every tree node
1060 data AnnExpr' bndr annot
1061   = AnnVar      Id
1062   | AnnLit      Literal
1063   | AnnLam      bndr (AnnExpr bndr annot)
1064   | AnnApp      (AnnExpr bndr annot) (AnnExpr bndr annot)
1065   | AnnCase     (AnnExpr bndr annot) bndr Type [AnnAlt bndr annot]
1066   | AnnLet      (AnnBind bndr annot) (AnnExpr bndr annot)
1067   | AnnCast     (AnnExpr bndr annot) Coercion
1068   | AnnNote     Note (AnnExpr bndr annot)
1069   | AnnType     Type
1070
1071 -- | A clone of the 'Alt' type but allowing annotation at every tree node
1072 type AnnAlt bndr annot = (AltCon, [bndr], AnnExpr bndr annot)
1073
1074 -- | A clone of the 'Bind' type but allowing annotation at every tree node
1075 data AnnBind bndr annot
1076   = AnnNonRec bndr (AnnExpr bndr annot)
1077   | AnnRec    [(bndr, AnnExpr bndr annot)]
1078 \end{code}
1079
1080 \begin{code}
1081 deAnnotate :: AnnExpr bndr annot -> Expr bndr
1082 deAnnotate (_, e) = deAnnotate' e
1083
1084 deAnnotate' :: AnnExpr' bndr annot -> Expr bndr
1085 deAnnotate' (AnnType t)           = Type t
1086 deAnnotate' (AnnVar  v)           = Var v
1087 deAnnotate' (AnnLit  lit)         = Lit lit
1088 deAnnotate' (AnnLam  binder body) = Lam binder (deAnnotate body)
1089 deAnnotate' (AnnApp  fun arg)     = App (deAnnotate fun) (deAnnotate arg)
1090 deAnnotate' (AnnCast e co)        = Cast (deAnnotate e) co
1091 deAnnotate' (AnnNote note body)   = Note note (deAnnotate body)
1092
1093 deAnnotate' (AnnLet bind body)
1094   = Let (deAnnBind bind) (deAnnotate body)
1095   where
1096     deAnnBind (AnnNonRec var rhs) = NonRec var (deAnnotate rhs)
1097     deAnnBind (AnnRec pairs) = Rec [(v,deAnnotate rhs) | (v,rhs) <- pairs]
1098
1099 deAnnotate' (AnnCase scrut v t alts)
1100   = Case (deAnnotate scrut) v t (map deAnnAlt alts)
1101
1102 deAnnAlt :: AnnAlt bndr annot -> Alt bndr
1103 deAnnAlt (con,args,rhs) = (con,args,deAnnotate rhs)
1104 \end{code}
1105
1106 \begin{code}
1107 -- | As 'collectBinders' but for 'AnnExpr' rather than 'Expr'
1108 collectAnnBndrs :: AnnExpr bndr annot -> ([bndr], AnnExpr bndr annot)
1109 collectAnnBndrs e
1110   = collect [] e
1111   where
1112     collect bs (_, AnnLam b body) = collect (b:bs) body
1113     collect bs body               = (reverse bs, body)
1114 \end{code}