compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 -- | Commonly useful utilites for manipulating the Core language
  17 module CoreUtils (
  18         -- * Constructing expressions
  19         mkSCC, mkCoerce, mkCoerceI,
  20         bindNonRec, needsCaseBinding,
  21         mkAltExpr, mkPiType, mkPiTypes,
  22
  23         -- * Taking expressions apart
  24         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  25
  26         -- * Properties of expressions
  27         exprType, coreAltType, coreAltsType,
  28         exprIsDupable, exprIsTrivial, exprIsCheap, exprIsExpandable,
  29         exprIsHNF, exprOkForSpeculation, exprIsBig, exprIsConLike,
  30         rhsIsStatic, isCheapApp, isExpandableApp,
  31
  32         -- * Expression and bindings size
  33         coreBindsSize, exprSize,
  34
  35         -- * Hashing
  36         hashExpr,
  37
  38         -- * Equality
  39         cheapEqExpr, eqExpr, eqExprX,
  40
  41         -- * Manipulating data constructors and types
  42         applyTypeToArgs, applyTypeToArg,
  43         dataConOrigInstPat, dataConRepInstPat, dataConRepFSInstPat
  44     ) where
  45
  46 #include "HsVersions.h"
  47
  48 import CoreSyn
  49 import PprCore
  50 import Var
  51 import SrcLoc
  52 import VarEnv
  53 import VarSet
  54 import Name
  55 import Module
  56 #if mingw32_TARGET_OS
  57 import Packages
  58 #endif
  59 import Literal
  60 import DataCon
  61 import PrimOp
  62 import Id
  63 import IdInfo
  64 import TcType   ( isPredTy )
  65 import Type
  66 import Coercion
  67 import TyCon
  68 import CostCentre
  69 import Unique
  70 import Outputable
  71 import TysPrim
  72 import FastString
  73 import Maybes
  74 import Util
  75 import Data.Word
  76 import Data.Bits
  77 \end{code}
  78
  79
  80 %************************************************************************
  81 %*                                                                      *
  82 \subsection{Find the type of a Core atom/expression}
  83 %*                                                                      *
  84 %************************************************************************
  85
  86 \begin{code}
  87 exprType :: CoreExpr -> Type
  88 -- ^ Recover the type of a well-typed Core expression. Fails when
  89 -- applied to the actual 'CoreSyn.Type' expression as it cannot
  90 -- really be said to have a type
  91 exprType (Var var)           = idType var
  92 exprType (Lit lit)           = literalType lit
  93 exprType (Let _ body)        = exprType body
  94 exprType (Case _ _ ty _)     = ty
  95 exprType (Cast _ co)         = snd (coercionKind co)
  96 exprType (Note _ e)          = exprType e
  97 exprType (Lam binder expr)   = mkPiType binder (exprType expr)
  98 exprType e@(App _ _)
  99   = case collectArgs e of
 100         (fun, args) -> applyTypeToArgs e (exprType fun) args
 101
 102 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 103
 104 coreAltType :: CoreAlt -> Type
 105 -- ^ Returns the type of the alternatives right hand side
 106 coreAltType (_,bs,rhs)
 107   | any bad_binder bs = expandTypeSynonyms ty
 108   | otherwise         = ty    -- Note [Existential variables and silly type synonyms]
 109   where
 110     ty           = exprType rhs
 111     free_tvs     = tyVarsOfType ty
 112     bad_binder b = isTyVar b && b `elemVarSet` free_tvs
 113
 114 coreAltsType :: [CoreAlt] -> Type
 115 -- ^ Returns the type of the first alternative, which should be the same as for all alternatives
 116 coreAltsType (alt:_) = coreAltType alt
 117 coreAltsType []      = panic "corAltsType"
 118 \end{code}
 119
 120 Note [Existential variables and silly type synonyms]
 121 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 122 Consider
 123         data T = forall a. T (Funny a)
 124         type Funny a = Bool
 125         f :: T -> Bool
 126         f (T x) = x
 127
 128 Now, the type of 'x' is (Funny a), where 'a' is existentially quantified.
 129 That means that 'exprType' and 'coreAltsType' may give a result that *appears*
 130 to mention an out-of-scope type variable.  See Trac #3409 for a more real-world
 131 example.
 132
 133 Various possibilities suggest themselves:
 134
 135  - Ignore the problem, and make Lint not complain about such variables
 136
 137  - Expand all type synonyms (or at least all those that discard arguments)
 138       This is tricky, because at least for top-level things we want to
 139       retain the type the user originally specified.
 140
 141  - Expand synonyms on the fly, when the problem arises. That is what
 142    we are doing here.  It's not too expensive, I think.
 143
 144 \begin{code}
 145 mkPiType  :: Var   -> Type -> Type
 146 -- ^ Makes a @(->)@ type or a forall type, depending
 147 -- on whether it is given a type variable or a term variable.
 148 mkPiTypes :: [Var] -> Type -> Type
 149 -- ^ 'mkPiType' for multiple type or value arguments
 150
 151 mkPiType v ty
 152    | isId v    = mkFunTy (idType v) ty
 153    | otherwise = mkForAllTy v ty
 154
 155 mkPiTypes vs ty = foldr mkPiType ty vs
 156 \end{code}
 157
 158 \begin{code}
 159 applyTypeToArg :: Type -> CoreExpr -> Type
 160 -- ^ Determines the type resulting from applying an expression to a function with the given type
 161 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 162 applyTypeToArg fun_ty _             = funResultTy fun_ty
 163
 164 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 165 -- ^ A more efficient version of 'applyTypeToArg' when we have several arguments.
 166 -- The first argument is just for debugging, and gives some context
 167 applyTypeToArgs _ op_ty [] = op_ty
 168
 169 applyTypeToArgs e op_ty (Type ty : args)
 170   =     -- Accumulate type arguments so we can instantiate all at once
 171     go [ty] args
 172   where
 173     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 174     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 175                                 where
 176                                   op_ty' = applyTysD msg op_ty (reverse rev_tys)
 177                                   msg = ptext (sLit "applyTypeToArgs") <+>
 178                                         panic_msg e op_ty
 179
 180 applyTypeToArgs e op_ty (_ : args)
 181   = case (splitFunTy_maybe op_ty) of
 182         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 183         Nothing -> pprPanic "applyTypeToArgs" (panic_msg e op_ty)
 184
 185 panic_msg :: CoreExpr -> Type -> SDoc
 186 panic_msg e op_ty = pprCoreExpr e $$ ppr op_ty
 187 \end{code}
 188
 189 %************************************************************************
 190 %*                                                                      *
 191 \subsection{Attaching notes}
 192 %*                                                                      *
 193 %************************************************************************
 194
 195 \begin{code}
 196 -- | Wrap the given expression in the coercion, dropping identity coercions and coalescing nested coercions
 197 mkCoerceI :: CoercionI -> CoreExpr -> CoreExpr
 198 mkCoerceI IdCo e = e
 199 mkCoerceI (ACo co) e = mkCoerce co e
 200
 201 -- | Wrap the given expression in the coercion safely, coalescing nested coercions
 202 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 203 mkCoerce co (Cast expr co2)
 204   = ASSERT(let { (from_ty, _to_ty) = coercionKind co;
 205                  (_from_ty2, to_ty2) = coercionKind co2} in
 206            from_ty `coreEqType` to_ty2 )
 207     mkCoerce (mkTransCoercion co2 co) expr
 208
 209 mkCoerce co expr
 210   = let (from_ty, _to_ty) = coercionKind co in
 211 --    if to_ty `coreEqType` from_ty
 212 --    then expr
 213 --    else
 214         WARN(not (from_ty `coreEqType` exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ pprEqPred (coercionKind co))
 215          (Cast expr co)
 216 \end{code}
 217
 218 \begin{code}
 219 -- | Wraps the given expression in the cost centre unless
 220 -- in a way that maximises their utility to the user
 221 mkSCC :: CostCentre -> Expr b -> Expr b
 222         -- Note: Nested SCC's *are* preserved for the benefit of
 223         --       cost centre stack profiling
 224 mkSCC _  (Lit lit)          = Lit lit
 225 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 226 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 227 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 228 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 229 mkSCC cc expr               = Note (SCC cc) expr
 230 \end{code}
 231
 232
 233 %************************************************************************
 234 %*                                                                      *
 235 \subsection{Other expression construction}
 236 %*                                                                      *
 237 %************************************************************************
 238
 239 \begin{code}
 240 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 241 -- ^ @bindNonRec x r b@ produces either:
 242 --
 243 -- > let x = r in b
 244 --
 245 -- or:
 246 --
 247 -- > case r of x { _DEFAULT_ -> b }
 248 --
 249 -- depending on whether we have to use a @case@ or @let@
 250 -- binding for the expression (see 'needsCaseBinding').
 251 -- It's used by the desugarer to avoid building bindings
 252 -- that give Core Lint a heart attack, although actually
 253 -- the simplifier deals with them perfectly well. See
 254 -- also 'MkCore.mkCoreLet'
 255 bindNonRec bndr rhs body
 256   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT, [], body)]
 257   | otherwise                          = Let (NonRec bndr rhs) body
 258
 259 -- | Tests whether we have to use a @case@ rather than @let@ binding for this expression
 260 -- as per the invariants of 'CoreExpr': see "CoreSyn#let_app_invariant"
 261 needsCaseBinding :: Type -> CoreExpr -> Bool
 262 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 263         -- Make a case expression instead of a let
 264         -- These can arise either from the desugarer,
 265         -- or from beta reductions: (\x.e) (x +# y)
 266 \end{code}
 267
 268 \begin{code}
 269 mkAltExpr :: AltCon     -- ^ Case alternative constructor
 270           -> [CoreBndr] -- ^ Things bound by the pattern match
 271           -> [Type]     -- ^ The type arguments to the case alternative
 272           -> CoreExpr
 273 -- ^ This guy constructs the value that the scrutinee must have
 274 -- given that you are in one particular branch of a case
 275 mkAltExpr (DataAlt con) args inst_tys
 276   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 277 mkAltExpr (LitAlt lit) [] []
 278   = Lit lit
 279 mkAltExpr (LitAlt _) _ _ = panic "mkAltExpr LitAlt"
 280 mkAltExpr DEFAULT _ _ = panic "mkAltExpr DEFAULT"
 281 \end{code}
 282
 283
 284 %************************************************************************
 285 %*                                                                      *
 286 \subsection{Taking expressions apart}
 287 %*                                                                      *
 288 %************************************************************************
 289
 290 The default alternative must be first, if it exists at all.
 291 This makes it easy to find, though it makes matching marginally harder.
 292
 293 \begin{code}
 294 -- | Extract the default case alternative
 295 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 296 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 297 findDefault alts                        =                     (alts, Nothing)
 298
 299 isDefaultAlt :: CoreAlt -> Bool
 300 isDefaultAlt (DEFAULT, _, _) = True
 301 isDefaultAlt _               = False
 302
 303
 304 -- | Find the case alternative corresponding to a particular
 305 -- constructor: panics if no such constructor exists
 306 findAlt :: AltCon -> [CoreAlt] -> Maybe CoreAlt
 307     -- A "Nothing" result *is* legitmiate
 308     -- See Note [Unreachable code]
 309 findAlt con alts
 310   = case alts of
 311         (deflt@(DEFAULT,_,_):alts) -> go alts (Just deflt)
 312         _                          -> go alts Nothing
 313   where
 314     go []                     deflt = deflt
 315     go (alt@(con1,_,_) : alts) deflt
 316       = case con `cmpAltCon` con1 of
 317           LT -> deflt   -- Missed it already; the alts are in increasing order
 318           EQ -> Just alt
 319           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 320
 321 ---------------------------------
 322 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 323 -- ^ Merge alternatives preserving order; alternatives in
 324 -- the first argument shadow ones in the second
 325 mergeAlts [] as2 = as2
 326 mergeAlts as1 [] = as1
 327 mergeAlts (a1:as1) (a2:as2)
 328   = case a1 `cmpAlt` a2 of
 329         LT -> a1 : mergeAlts as1      (a2:as2)
 330         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 331         GT -> a2 : mergeAlts (a1:as1) as2
 332
 333
 334 ---------------------------------
 335 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 336 -- ^ Given:
 337 --
 338 -- > case (C a b x y) of
 339 -- >        C b x y -> ...
 340 --
 341 -- We want to drop the leading type argument of the scrutinee
 342 -- leaving the arguments to match agains the pattern
 343
 344 trimConArgs DEFAULT      args = ASSERT( null args ) []
 345 trimConArgs (LitAlt _)   args = ASSERT( null args ) []
 346 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 347 \end{code}
 348
 349 Note [Unreachable code]
 350 ~~~~~~~~~~~~~~~~~~~~~~~
 351 It is possible (although unusual) for GHC to find a case expression
 352 that cannot match.  For example:
 353
 354      data Col = Red | Green | Blue
 355      x = Red
 356      f v = case x of
 357               Red -> ...
 358               _ -> ...(case x of { Green -> e1; Blue -> e2 })...
 359
 360 Suppose that for some silly reason, x isn't substituted in the case
 361 expression.  (Perhaps there's a NOINLINE on it, or profiling SCC stuff
 362 gets in the way; cf Trac #3118.)  Then the full-lazines pass might produce
 363 this
 364
 365      x = Red
 366      lvl = case x of { Green -> e1; Blue -> e2 })
 367      f v = case x of
 368              Red -> ...
 369              _ -> ...lvl...
 370
 371 Now if x gets inlined, we won't be able to find a matching alternative
 372 for 'Red'.  That's because 'lvl' is unreachable.  So rather than crashing
 373 we generate (error "Inaccessible alternative").
 374
 375 Similar things can happen (augmented by GADTs) when the Simplifier
 376 filters down the matching alternatives in Simplify.rebuildCase.
 377
 378
 379 %************************************************************************
 380 %*                                                                      *
 381              exprIsTrivial
 382 %*                                                                      *
 383 %************************************************************************
 384
 385 Note [exprIsTrivial]
 386 ~~~~~~~~~~~~~~~~~~~~
 387 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 388                 duplicate; simple variables and constants, and type
 389                 applications.  Note that primop Ids aren't considered
 390                 trivial unless
 391
 392 Note [Variable are trivial]
 393 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 394 There used to be a gruesome test for (hasNoBinding v) in the
 395 Var case:
 396         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 397 The idea here is that a constructor worker, like \$wJust, is
 398 really short for (\x -> \$wJust x), becuase \$wJust has no binding.
 399 So it should be treated like a lambda.  Ditto unsaturated primops.
 400 But now constructor workers are not "have-no-binding" Ids.  And
 401 completely un-applied primops and foreign-call Ids are sufficiently
 402 rare that I plan to allow them to be duplicated and put up with
 403 saturating them.
 404
 405 Note [SCCs are trivial]
 406 ~~~~~~~~~~~~~~~~~~~~~~~
 407 We used not to treat (_scc_ "foo" x) as trivial, because it really
 408 generates code, (and a heap object when it's a function arg) to
 409 capture the cost centre.  However, the profiling system discounts the
 410 allocation costs for such "boxing thunks" whereas the extra costs of
 411 *not* inlining otherwise-trivial bindings can be high, and are hard to
 412 discount.
 413
 414 \begin{code}
 415 exprIsTrivial :: CoreExpr -> Bool
 416 exprIsTrivial (Var _)          = True        -- See Note [Variables are trivial]
 417 exprIsTrivial (Type _)         = True
 418 exprIsTrivial (Lit lit)        = litIsTrivial lit
 419 exprIsTrivial (App e arg)      = not (isRuntimeArg arg) && exprIsTrivial e
 420 exprIsTrivial (Note _       e) = exprIsTrivial e  -- See Note [SCCs are trivial]
 421 exprIsTrivial (Cast e _)       = exprIsTrivial e
 422 exprIsTrivial (Lam b body)     = not (isRuntimeVar b) && exprIsTrivial body
 423 exprIsTrivial _                = False
 424 \end{code}
 425
 426
 427 %************************************************************************
 428 %*                                                                      *
 429              exprIsDupable
 430 %*                                                                      *
 431 %************************************************************************
 432
 433 Note [exprIsDupable]
 434 ~~~~~~~~~~~~~~~~~~~~
 435 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 436                 cost in code size.  This will only happen in different case
 437                 branches, so there's no issue about duplicating work.
 438
 439                 That is, exprIsDupable returns True of (f x) even if
 440                 f is very very expensive to call.
 441
 442                 Its only purpose is to avoid fruitless let-binding
 443                 and then inlining of case join points
 444
 445
 446 \begin{code}
 447 exprIsDupable :: CoreExpr -> Bool
 448 exprIsDupable (Type _)   = True
 449 exprIsDupable (Var _)    = True
 450 exprIsDupable (Lit lit)  = litIsDupable lit
 451 exprIsDupable (Note _ e) = exprIsDupable e
 452 exprIsDupable (Cast e _) = exprIsDupable e
 453 exprIsDupable expr
 454   = go expr 0
 455   where
 456     go (Var _)   _      = True
 457     go (App f a) n_args =  n_args < dupAppSize
 458                         && exprIsDupable a
 459                         && go f (n_args+1)
 460     go _         _      = False
 461
 462 dupAppSize :: Int
 463 dupAppSize = 4          -- Size of application we are prepared to duplicate
 464 \end{code}
 465
 466 %************************************************************************
 467 %*                                                                      *
 468              exprIsCheap, exprIsExpandable
 469 %*                                                                      *
 470 %************************************************************************
 471
 472 Note [exprIsCheap]   See also Note [Interaction of exprIsCheap and lone variables]
 473 ~~~~~~~~~~~~~~~~~~   in CoreUnfold.lhs
 474 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 475 it is obviously in weak head normal form, or is cheap to get to WHNF.
 476 [Note that that's not the same as exprIsDupable; an expression might be
 477 big, and hence not dupable, but still cheap.]
 478
 479 By ``cheap'' we mean a computation we're willing to:
 480         push inside a lambda, or
 481         inline at more than one place
 482 That might mean it gets evaluated more than once, instead of being
 483 shared.  The main examples of things which aren't WHNF but are
 484 ``cheap'' are:
 485
 486   *     case e of
 487           pi -> ei
 488         (where e, and all the ei are cheap)
 489
 490   *     let x = e in b
 491         (where e and b are cheap)
 492
 493   *     op x1 ... xn
 494         (where op is a cheap primitive operator)
 495
 496   *     error "foo"
 497         (because we are happy to substitute it inside a lambda)
 498
 499 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 500 because sharing will make sure it is only evaluated once.
 501
 502 Note [exprIsCheap and exprIsHNF]
 503 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 504 Note that exprIsHNF does not imply exprIsCheap.  Eg
 505         let x = fac 20 in Just x
 506 This responds True to exprIsHNF (you can discard a seq), but
 507 False to exprIsCheap.
 508
 509 \begin{code}
 510 exprIsCheap :: CoreExpr -> Bool
 511 exprIsCheap = exprIsCheap' isCheapApp
 512
 513 exprIsExpandable :: CoreExpr -> Bool
 514 exprIsExpandable = exprIsCheap' isExpandableApp -- See Note [CONLIKE pragma] in BasicTypes
 515
 516
 517 exprIsCheap' :: (Id -> Int -> Bool) -> CoreExpr -> Bool
 518 exprIsCheap' _          (Lit _)   = True
 519 exprIsCheap' _          (Type _)  = True
 520 exprIsCheap' _          (Var _)   = True
 521 exprIsCheap' good_app (Note _ e)  = exprIsCheap' good_app e
 522 exprIsCheap' good_app (Cast e _)  = exprIsCheap' good_app e
 523 exprIsCheap' good_app (Lam x e)   = isRuntimeVar x
 524                                  || exprIsCheap' good_app e
 525
 526 exprIsCheap' good_app (Case e _ _ alts) = exprIsCheap' good_app e &&
 527                                           and [exprIsCheap' good_app rhs | (_,_,rhs) <- alts]
 528         -- Experimentally, treat (case x of ...) as cheap
 529         -- (and case __coerce x etc.)
 530         -- This improves arities of overloaded functions where
 531         -- there is only dictionary selection (no construction) involved
 532
 533 exprIsCheap' good_app (Let (NonRec x _) e)
 534   | isUnLiftedType (idType x) = exprIsCheap' good_app e
 535   | otherwise                 = False
 536         -- Strict lets always have cheap right hand sides,
 537         -- and do no allocation, so just look at the body
 538         -- Non-strict lets do allocation so we don't treat them as cheap
 539         -- See also
 540
 541 exprIsCheap' good_app other_expr        -- Applications and variables
 542   = go other_expr []
 543   where
 544         -- Accumulate value arguments, then decide
 545     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 546                           | otherwise      = go f val_args
 547
 548     go (Var _) [] = True        -- Just a type application of a variable
 549                                 -- (f t1 t2 t3) counts as WHNF
 550     go (Var f) args
 551         = case idDetails f of
 552                 RecSelId {}                  -> go_sel args
 553                 ClassOpId {}                 -> go_sel args
 554                 PrimOpId op                  -> go_primop op args
 555                 _ | good_app f (length args) -> go_pap args
 556                   | isBottomingId f          -> True
 557                   | otherwise                -> False
 558                         -- Application of a function which
 559                         -- always gives bottom; we treat this as cheap
 560                         -- because it certainly doesn't need to be shared!
 561
 562     go _ _ = False
 563
 564     --------------
 565     go_pap args = all exprIsTrivial args
 566         -- For constructor applications and primops, check that all
 567         -- the args are trivial.  We don't want to treat as cheap, say,
 568         --      (1:2:3:4:5:[])
 569         -- We'll put up with one constructor application, but not dozens
 570
 571     --------------
 572     go_primop op args = primOpIsCheap op && all (exprIsCheap' good_app) args
 573         -- In principle we should worry about primops
 574         -- that return a type variable, since the result
 575         -- might be applied to something, but I'm not going
 576         -- to bother to check the number of args
 577
 578     --------------
 579     go_sel [arg] = exprIsCheap' good_app arg    -- I'm experimenting with making record selection
 580     go_sel _     = False                -- look cheap, so we will substitute it inside a
 581                                         -- lambda.  Particularly for dictionary field selection.
 582                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 583                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 584
 585 isCheapApp :: Id -> Int -> Bool
 586 isCheapApp fn n_val_args
 587   = isDataConWorkId fn
 588   || n_val_args < idArity fn
 589
 590 isExpandableApp :: Id -> Int -> Bool
 591 isExpandableApp fn n_val_args
 592   =  isConLikeId fn
 593   || n_val_args < idArity fn
 594   || go n_val_args (idType fn)
 595   where
 596   -- See if all the arguments are PredTys (implicit params or classes)
 597   -- If so we'll regard it as expandable; see Note [Expandable overloadings]
 598      go 0 _ = True
 599      go n_val_args ty
 600        | Just (_, ty) <- splitForAllTy_maybe ty   = go n_val_args ty
 601        | Just (arg, ty) <- splitFunTy_maybe ty
 602        , isPredTy arg                             = go (n_val_args-1) ty
 603        | otherwise                                = False
 604 \end{code}
 605
 606 Note [Expandable overloadings]
 607 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 608 Suppose the user wrote this
 609    {-# RULE  forall x. foo (negate x) = h x #-}
 610    f x = ....(foo (negate x))....
 611 He'd expect the rule to fire. But since negate is overloaded, we might
 612 get this:
 613     f = \d -> let n = negate d in \x -> ...foo (n x)...
 614 So we treat the application of a function (negate in this case) to a
 615 *dictionary* as expandable.  In effect, every function is CONLIKE when
 616 it's applied only to dictionaries.
 617
 618
 619 %************************************************************************
 620 %*                                                                      *
 621              exprOkForSpeculation
 622 %*                                                                      *
 623 %************************************************************************
 624
 625 \begin{code}
 626 -- | 'exprOkForSpeculation' returns True of an expression that is:
 627 --
 628 --  * Safe to evaluate even if normal order eval might not
 629 --    evaluate the expression at all, or
 630 --
 631 --  * Safe /not/ to evaluate even if normal order would do so
 632 --
 633 -- Precisely, it returns @True@ iff:
 634 --
 635 --  * The expression guarantees to terminate,
 636 --  * soon,
 637 --  * without raising an exception,
 638 --  * without causing a side effect (e.g. writing a mutable variable)
 639 --
 640 -- Note that if @exprIsHNF e@, then @exprOkForSpecuation e@.
 641 -- As an example of the considerations in this test, consider:
 642 --
 643 -- > let x = case y# +# 1# of { r# -> I# r# }
 644 -- > in E
 645 --
 646 -- being translated to:
 647 --
 648 -- > case y# +# 1# of { r# ->
 649 -- >    let x = I# r#
 650 -- >    in E
 651 -- > }
 652 --
 653 -- We can only do this if the @y + 1@ is ok for speculation: it has no
 654 -- side effects, and can't diverge or raise an exception.
 655 exprOkForSpeculation :: CoreExpr -> Bool
 656 exprOkForSpeculation (Lit _)     = True
 657 exprOkForSpeculation (Type _)    = True
 658     -- Tick boxes are *not* suitable for speculation
 659 exprOkForSpeculation (Var v)     = isUnLiftedType (idType v)
 660                                  && not (isTickBoxOp v)
 661 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 662 exprOkForSpeculation (Cast e _)  = exprOkForSpeculation e
 663
 664 exprOkForSpeculation (Case e _ _ alts)
 665   =  exprOkForSpeculation e  -- Note [exprOkForSpeculation: case expressions]
 666   && all (\(_,_,rhs) -> exprOkForSpeculation rhs) alts
 667
 668 exprOkForSpeculation other_expr
 669   = case collectArgs other_expr of
 670         (Var f, args) -> spec_ok (idDetails f) args
 671         _             -> False
 672
 673   where
 674     spec_ok (DataConWorkId _) _
 675       = True    -- The strictness of the constructor has already
 676                 -- been expressed by its "wrapper", so we don't need
 677                 -- to take the arguments into account
 678
 679     spec_ok (PrimOpId op) args
 680       | isDivOp op,             -- Special case for dividing operations that fail
 681         [arg1, Lit lit] <- args -- only if the divisor is zero
 682       = not (isZeroLit lit) && exprOkForSpeculation arg1
 683                 -- Often there is a literal divisor, and this
 684                 -- can get rid of a thunk in an inner looop
 685
 686       | otherwise
 687       = primOpOkForSpeculation op &&
 688         all exprOkForSpeculation args
 689                                 -- A bit conservative: we don't really need
 690                                 -- to care about lazy arguments, but this is easy
 691
 692     spec_ok (DFunId new_type) _ = not new_type
 693          -- DFuns terminate, unless the dict is implemented with a newtype
 694          -- in which case they may not
 695
 696     spec_ok _ _ = False
 697
 698 -- | True of dyadic operators that can fail only if the second arg is zero!
 699 isDivOp :: PrimOp -> Bool
 700 -- This function probably belongs in PrimOp, or even in
 701 -- an automagically generated file.. but it's such a
 702 -- special case I thought I'd leave it here for now.
 703 isDivOp IntQuotOp        = True
 704 isDivOp IntRemOp         = True
 705 isDivOp WordQuotOp       = True
 706 isDivOp WordRemOp        = True
 707 isDivOp FloatDivOp       = True
 708 isDivOp DoubleDivOp      = True
 709 isDivOp _                = False
 710 \end{code}
 711
 712 Note [exprOkForSpeculation: case expressions]
 713 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 714
 715 It's always sound for exprOkForSpeculation to return False, and we
 716 don't want it to take too long, so it bales out on complicated-looking
 717 terms.  Notably lets, which can be stacked very deeply; and in any
 718 case the argument of exprOkForSpeculation is usually in a strict context,
 719 so any lets will have been floated away.
 720
 721 However, we keep going on case-expressions.  An example like this one
 722 showed up in DPH code:
 723     foo :: Int -> Int
 724     foo 0 = 0
 725     foo n = (if n < 5 then 1 else 2) `seq` foo (n-1)
 726
 727 If exprOkForSpeculation doesn't look through case expressions, you get this:
 728     T.$wfoo =
 729       \ (ww :: GHC.Prim.Int#) ->
 730         case ww of ds {
 731           __DEFAULT -> case (case <# ds 5 of _ {
 732                           GHC.Bool.False -> lvl1;
 733                           GHC.Bool.True -> lvl})
 734                        of _ { __DEFAULT ->
 735                        T.$wfoo (GHC.Prim.-# ds_XkE 1) };
 736           0 -> 0
 737         }
 738
 739 The inner case is redundant, and should be nuked.
 740
 741
 742 %************************************************************************
 743 %*                                                                      *
 744              exprIsHNF, exprIsConLike
 745 %*                                                                      *
 746 %************************************************************************
 747
 748 \begin{code}
 749 -- Note [exprIsHNF]             See also Note [exprIsCheap and exprIsHNF]
 750 -- ~~~~~~~~~~~~~~~~
 751 -- | exprIsHNF returns true for expressions that are certainly /already/
 752 -- evaluated to /head/ normal form.  This is used to decide whether it's ok
 753 -- to change:
 754 --
 755 -- > case x of _ -> e
 756 --
 757 --    into:
 758 --
 759 -- > e
 760 --
 761 -- and to decide whether it's safe to discard a 'seq'.
 762 --
 763 -- So, it does /not/ treat variables as evaluated, unless they say they are.
 764 -- However, it /does/ treat partial applications and constructor applications
 765 -- as values, even if their arguments are non-trivial, provided the argument
 766 -- type is lifted. For example, both of these are values:
 767 --
 768 -- > (:) (f x) (map f xs)
 769 -- > map (...redex...)
 770 --
 771 -- because 'seq' on such things completes immediately.
 772 --
 773 -- For unlifted argument types, we have to be careful:
 774 --
 775 -- > C (f x :: Int#)
 776 --
 777 -- Suppose @f x@ diverges; then @C (f x)@ is not a value. However this can't
 778 -- happen: see "CoreSyn#let_app_invariant". This invariant states that arguments of
 779 -- unboxed type must be ok-for-speculation (or trivial).
 780 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 781 exprIsHNF = exprIsHNFlike isDataConWorkId isEvaldUnfolding
 782 \end{code}
 783
 784 \begin{code}
 785 -- | Similar to 'exprIsHNF' but includes CONLIKE functions as well as
 786 -- data constructors. Conlike arguments are considered interesting by the
 787 -- inliner.
 788 exprIsConLike :: CoreExpr -> Bool       -- True => lambda, conlike, PAP
 789 exprIsConLike = exprIsHNFlike isConLikeId isConLikeUnfolding
 790
 791 -- | Returns true for values or value-like expressions. These are lambdas,
 792 -- constructors / CONLIKE functions (as determined by the function argument)
 793 -- or PAPs.
 794 --
 795 exprIsHNFlike :: (Var -> Bool) -> (Unfolding -> Bool) -> CoreExpr -> Bool
 796 exprIsHNFlike is_con is_con_unf = is_hnf_like
 797   where
 798     is_hnf_like (Var v) -- NB: There are no value args at this point
 799       =  is_con v       -- Catches nullary constructors,
 800                         --      so that [] and () are values, for example
 801       || idArity v > 0  -- Catches (e.g.) primops that don't have unfoldings
 802       || is_con_unf (idUnfolding v)
 803         -- Check the thing's unfolding; it might be bound to a value
 804         -- We don't look through loop breakers here, which is a bit conservative
 805         -- but otherwise I worry that if an Id's unfolding is just itself,
 806         -- we could get an infinite loop
 807
 808     is_hnf_like (Lit _)          = True
 809     is_hnf_like (Type _)         = True       -- Types are honorary Values;
 810                                               -- we don't mind copying them
 811     is_hnf_like (Lam b e)        = isRuntimeVar b || is_hnf_like e
 812     is_hnf_like (Note _ e)       = is_hnf_like e
 813     is_hnf_like (Cast e _)       = is_hnf_like e
 814     is_hnf_like (App e (Type _)) = is_hnf_like e
 815     is_hnf_like (App e a)        = app_is_value e [a]
 816     is_hnf_like (Let _ e)        = is_hnf_like e  -- Lazy let(rec)s don't affect us
 817     is_hnf_like _                = False
 818
 819     -- There is at least one value argument
 820     app_is_value :: CoreExpr -> [CoreArg] -> Bool
 821     app_is_value (Var fun) args
 822       = idArity fun > valArgCount args    -- Under-applied function
 823         || is_con fun                     --  or constructor-like
 824     app_is_value (Note _ f) as = app_is_value f as
 825     app_is_value (Cast f _) as = app_is_value f as
 826     app_is_value (App f a)  as = app_is_value f (a:as)
 827     app_is_value _          _  = False
 828 \end{code}
 829
 830
 831 %************************************************************************
 832 %*                                                                      *
 833              Instantiating data constructors
 834 %*                                                                      *
 835 %************************************************************************
 836
 837 These InstPat functions go here to avoid circularity between DataCon and Id
 838
 839 \begin{code}
 840 dataConRepInstPat, dataConOrigInstPat :: [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 841 dataConRepFSInstPat :: [FastString] -> [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 842
 843 dataConRepInstPat   = dataConInstPat dataConRepArgTys (repeat ((fsLit "ipv")))
 844 dataConRepFSInstPat = dataConInstPat dataConRepArgTys
 845 dataConOrigInstPat  = dataConInstPat dc_arg_tys       (repeat ((fsLit "ipv")))
 846   where
 847     dc_arg_tys dc = map mkPredTy (dataConEqTheta dc) ++ map mkPredTy (dataConDictTheta dc) ++ dataConOrigArgTys dc
 848         -- Remember to include the existential dictionaries
 849
 850 dataConInstPat :: (DataCon -> [Type])      -- function used to find arg tys
 851                   -> [FastString]          -- A long enough list of FSs to use for names
 852                   -> [Unique]              -- An equally long list of uniques, at least one for each binder
 853                   -> DataCon
 854                   -> [Type]                -- Types to instantiate the universally quantified tyvars
 855                -> ([TyVar], [CoVar], [Id]) -- Return instantiated variables
 856 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 857 -- (ex_tvs, co_tvs, arg_ids),
 858 --
 859 --   ex_tvs are intended to be used as binders for existential type args
 860 --
 861 --   co_tvs are intended to be used as binders for coercion args and the kinds
 862 --     of these vars have been instantiated by the inst_tys and the ex_tys
 863 --     The co_tvs include both GADT equalities (dcEqSpec) and
 864 --     programmer-specified equalities (dcEqTheta)
 865 --
 866 --   arg_ids are indended to be used as binders for value arguments,
 867 --     and their types have been instantiated with inst_tys and ex_tys
 868 --     The arg_ids include both dicts (dcDictTheta) and
 869 --     programmer-specified arguments (after rep-ing) (deRepArgTys)
 870 --
 871 -- Example.
 872 --  The following constructor T1
 873 --
 874 --  data T a where
 875 --    T1 :: forall b. Int -> b -> T(a,b)
 876 --    ...
 877 --
 878 --  has representation type
 879 --   forall a. forall a1. forall b. (a ~ (a1,b)) =>
 880 --     Int -> b -> T a
 881 --
 882 --  dataConInstPat fss us T1 (a1',b') will return
 883 --
 884 --  ([a1'', b''], [c :: (a1', b')~(a1'', b'')], [x :: Int, y :: b''])
 885 --
 886 --  where the double-primed variables are created with the FastStrings and
 887 --  Uniques given as fss and us
 888 dataConInstPat arg_fun fss uniqs con inst_tys
 889   = (ex_bndrs, co_bndrs, arg_ids)
 890   where
 891     univ_tvs = dataConUnivTyVars con
 892     ex_tvs   = dataConExTyVars con
 893     arg_tys  = arg_fun con
 894     eq_spec  = dataConEqSpec con
 895     eq_theta = dataConEqTheta con
 896     eq_preds = eqSpecPreds eq_spec ++ eq_theta
 897
 898     n_ex = length ex_tvs
 899     n_co = length eq_preds
 900
 901       -- split the Uniques and FastStrings
 902     (ex_uniqs, uniqs')   = splitAt n_ex uniqs
 903     (co_uniqs, id_uniqs) = splitAt n_co uniqs'
 904
 905     (ex_fss, fss')     = splitAt n_ex fss
 906     (co_fss, id_fss)   = splitAt n_co fss'
 907
 908       -- Make existential type variables
 909     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 910     mk_ex_var uniq fs var = mkTyVar new_name kind
 911       where
 912         new_name = mkSysTvName uniq fs
 913         kind     = tyVarKind var
 914
 915       -- Make the instantiating substitution
 916     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 917
 918       -- Make new coercion vars, instantiating kind
 919     co_bndrs = zipWith3 mk_co_var co_uniqs co_fss eq_preds
 920     mk_co_var uniq fs eq_pred = mkCoVar new_name co_kind
 921        where
 922          new_name = mkSysTvName uniq fs
 923          co_kind  = substTy subst (mkPredTy eq_pred)
 924
 925       -- make value vars, instantiating types
 926     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (substTy subst ty) noSrcSpan
 927     arg_ids = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 928
 929 \end{code}
 930
 931 %************************************************************************
 932 %*                                                                      *
 933          Equality
 934 %*                                                                      *
 935 %************************************************************************
 936
 937 \begin{code}
 938 -- | A cheap equality test which bales out fast!
 939 --      If it returns @True@ the arguments are definitely equal,
 940 --      otherwise, they may or may not be equal.
 941 --
 942 -- See also 'exprIsBig'
 943 cheapEqExpr :: Expr b -> Expr b -> Bool
 944
 945 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
 946 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
 947 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
 948
 949 cheapEqExpr (App f1 a1) (App f2 a2)
 950   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
 951
 952 cheapEqExpr (Cast e1 t1) (Cast e2 t2)
 953   = e1 `cheapEqExpr` e2 && t1 `coreEqCoercion` t2
 954
 955 cheapEqExpr _ _ = False
 956 \end{code}
 957
 958 \begin{code}
 959 exprIsBig :: Expr b -> Bool
 960 -- ^ Returns @True@ of expressions that are too big to be compared by 'cheapEqExpr'
 961 exprIsBig (Lit _)      = False
 962 exprIsBig (Var _)      = False
 963 exprIsBig (Type _)     = False
 964 exprIsBig (Lam _ e)    = exprIsBig e
 965 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
 966 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
 967 exprIsBig _            = True
 968 \end{code}
 969
 970 \begin{code}
 971 eqExpr :: InScopeSet -> CoreExpr -> CoreExpr -> Bool
 972 -- Compares for equality, modulo alpha
 973 eqExpr in_scope e1 e2
 974   = eqExprX id_unf (mkRnEnv2 in_scope) e1 e2
 975   where
 976     id_unf _ = noUnfolding      -- Don't expand
 977 \end{code}
 978
 979 \begin{code}
 980 eqExprX :: IdUnfoldingFun -> RnEnv2 -> CoreExpr -> CoreExpr -> Bool
 981 -- ^ Compares expressions for equality, modulo alpha.
 982 -- Does /not/ look through newtypes or predicate types
 983 -- Used in rule matching, and also CSE
 984
 985 eqExprX id_unfolding_fun env e1 e2
 986   = go env e1 e2
 987   where
 988     go env (Var v1) (Var v2)
 989       | rnOccL env v1 == rnOccR env v2
 990       = True
 991
 992     -- The next two rules expand non-local variables
 993     -- C.f. Note [Expanding variables] in Rules.lhs
 994     -- and  Note [Do not expand locally-bound variables] in Rules.lhs
 995     go env (Var v1) e2
 996       | not (locallyBoundL env v1)
 997       , Just e1' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v1))
 998       = go (nukeRnEnvL env) e1' e2
 999
1000     go env e1 (Var v2)
1001       | not (locallyBoundR env v2)
1002       , Just e2' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v2))
1003       = go (nukeRnEnvR env) e1 e2'
1004
1005     go _   (Lit lit1)    (Lit lit2)    = lit1 == lit2
1006     go env (Type t1)     (Type t2)     = tcEqTypeX env t1 t2
1007     go env (Cast e1 co1) (Cast e2 co2) = tcEqTypeX env co1 co2 && go env e1 e2
1008     go env (App f1 a1)   (App f2 a2)   = go env f1 f2 && go env a1 a2
1009     go env (Note n1 e1)  (Note n2 e2)  = go_note n1 n2 && go env e1 e2
1010
1011     go env (Lam b1 e1)  (Lam b2 e2)
1012       =  tcEqTypeX env (varType b1) (varType b2)   -- False for Id/TyVar combination
1013       && go (rnBndr2 env b1 b2) e1 e2
1014
1015     go env (Let (NonRec v1 r1) e1) (Let (NonRec v2 r2) e2)
1016       =  go env r1 r2  -- No need to check binder types, since RHSs match
1017       && go (rnBndr2 env v1 v2) e1 e2
1018
1019     go env (Let (Rec ps1) e1) (Let (Rec ps2) e2)
1020       = all2 (go env') rs1 rs2 && go env' e1 e2
1021       where
1022         (bs1,rs1) = unzip ps1
1023         (bs2,rs2) = unzip ps2
1024         env' = rnBndrs2 env bs1 bs2
1025
1026     go env (Case e1 b1 _ a1) (Case e2 b2 _ a2)
1027       =  go env e1 e2
1028       && tcEqTypeX env (idType b1) (idType b2)
1029       && all2 (go_alt (rnBndr2 env b1 b2)) a1 a2
1030
1031     go _ _ _ = False
1032
1033     -----------
1034     go_alt env (c1, bs1, e1) (c2, bs2, e2)
1035       = c1 == c2 && go (rnBndrs2 env bs1 bs2) e1 e2
1036
1037     -----------
1038     go_note (SCC cc1)     (SCC cc2)      = cc1 == cc2
1039     go_note (CoreNote s1) (CoreNote s2)  = s1 == s2
1040     go_note _             _              = False
1041 \end{code}
1042
1043 Auxiliary functions
1044
1045 \begin{code}
1046 locallyBoundL, locallyBoundR :: RnEnv2 -> Var -> Bool
1047 locallyBoundL rn_env v = inRnEnvL rn_env v
1048 locallyBoundR rn_env v = inRnEnvR rn_env v
1049 \end{code}
1050
1051
1052 %************************************************************************
1053 %*                                                                      *
1054 \subsection{The size of an expression}
1055 %*                                                                      *
1056 %************************************************************************
1057
1058 \begin{code}
1059 coreBindsSize :: [CoreBind] -> Int
1060 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
1061
1062 exprSize :: CoreExpr -> Int
1063 -- ^ A measure of the size of the expressions, strictly greater than 0
1064 -- It also forces the expression pretty drastically as a side effect
1065 exprSize (Var v)         = v `seq` 1
1066 exprSize (Lit lit)       = lit `seq` 1
1067 exprSize (App f a)       = exprSize f + exprSize a
1068 exprSize (Lam b e)       = varSize b + exprSize e
1069 exprSize (Let b e)       = bindSize b + exprSize e
1070 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1071 exprSize (Cast e co)     = (seqType co `seq` 1) + exprSize e
1072 exprSize (Note n e)      = noteSize n + exprSize e
1073 exprSize (Type t)        = seqType t `seq` 1
1074
1075 noteSize :: Note -> Int
1076 noteSize (SCC cc)       = cc `seq` 1
1077 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1078
1079 varSize :: Var -> Int
1080 varSize b  | isTyVar b = 1
1081            | otherwise = seqType (idType b)             `seq`
1082                          megaSeqIdInfo (idInfo b)       `seq`
1083                          1
1084
1085 varsSize :: [Var] -> Int
1086 varsSize = sum . map varSize
1087
1088 bindSize :: CoreBind -> Int
1089 bindSize (NonRec b e) = varSize b + exprSize e
1090 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1091
1092 pairSize :: (Var, CoreExpr) -> Int
1093 pairSize (b,e) = varSize b + exprSize e
1094
1095 altSize :: CoreAlt -> Int
1096 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1097 \end{code}
1098
1099
1100 %************************************************************************
1101 %*                                                                      *
1102 \subsection{Hashing}
1103 %*                                                                      *
1104 %************************************************************************
1105
1106 \begin{code}
1107 hashExpr :: CoreExpr -> Int
1108 -- ^ Two expressions that hash to the same @Int@ may be equal (but may not be)
1109 -- Two expressions that hash to the different Ints are definitely unequal.
1110 --
1111 -- The emphasis is on a crude, fast hash, rather than on high precision.
1112 --
1113 -- But unequal here means \"not identical\"; two alpha-equivalent
1114 -- expressions may hash to the different Ints.
1115 --
1116 -- We must be careful that @\\x.x@ and @\\y.y@ map to the same hash code,
1117 -- (at least if we want the above invariant to be true).
1118
1119 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
1120              -- UniqFM doesn't like negative Ints
1121
1122 type HashEnv = (Int, VarEnv Int)  -- Hash code for bound variables
1123
1124 hash_expr :: HashEnv -> CoreExpr -> Word32
1125 -- Word32, because we're expecting overflows here, and overflowing
1126 -- signed types just isn't cool.  In C it's even undefined.
1127 hash_expr env (Note _ e)              = hash_expr env e
1128 hash_expr env (Cast e _)              = hash_expr env e
1129 hash_expr env (Var v)                 = hashVar env v
1130 hash_expr _   (Lit lit)               = fromIntegral (hashLiteral lit)
1131 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
1132 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
1133 hash_expr env (Let (Rec ((b,_):_)) e) = hash_expr (extend_env env b) e
1134 hash_expr env (Case e _ _ _)          = hash_expr env e
1135 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
1136 hash_expr _   (Type _)                = WARN(True, text "hash_expr: type") 1
1137 -- Shouldn't happen.  Better to use WARN than trace, because trace
1138 -- prevents the CPR optimisation kicking in for hash_expr.
1139
1140 fast_hash_expr :: HashEnv -> CoreExpr -> Word32
1141 fast_hash_expr env (Var v)      = hashVar env v
1142 fast_hash_expr env (Type t)     = fast_hash_type env t
1143 fast_hash_expr _   (Lit lit)    = fromIntegral (hashLiteral lit)
1144 fast_hash_expr env (Cast e _)   = fast_hash_expr env e
1145 fast_hash_expr env (Note _ e)   = fast_hash_expr env e
1146 fast_hash_expr env (App _ a)    = fast_hash_expr env a  -- A bit idiosyncratic ('a' not 'f')!
1147 fast_hash_expr _   _            = 1
1148
1149 fast_hash_type :: HashEnv -> Type -> Word32
1150 fast_hash_type env ty
1151   | Just tv <- getTyVar_maybe ty            = hashVar env tv
1152   | Just (tc,tys) <- splitTyConApp_maybe ty = let hash_tc = fromIntegral (hashName (tyConName tc))
1153                                               in foldr (\t n -> fast_hash_type env t + n) hash_tc tys
1154   | otherwise                               = 1
1155
1156 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1157 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1158
1159 hashVar :: HashEnv -> Var -> Word32
1160 hashVar (_,env) v
1161  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1162 \end{code}
1163
1164 %************************************************************************
1165 %*                                                                      *
1166 \subsection{Determining non-updatable right-hand-sides}
1167 %*                                                                      *
1168 %************************************************************************
1169
1170 Top-level constructor applications can usually be allocated
1171 statically, but they can't if the constructor, or any of the
1172 arguments, come from another DLL (because we can't refer to static
1173 labels in other DLLs).
1174
1175 If this happens we simply make the RHS into an updatable thunk,
1176 and 'execute' it rather than allocating it statically.
1177
1178 \begin{code}
1179 -- | This function is called only on *top-level* right-hand sides.
1180 -- Returns @True@ if the RHS can be allocated statically in the output,
1181 -- with no thunks involved at all.
1182 rhsIsStatic :: PackageId -> CoreExpr -> Bool
1183 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1184 -- refers to, CAFs; (ii) in CoreToStg to decide whether to put an
1185 -- update flag on it and (iii) in DsExpr to decide how to expand
1186 -- list literals
1187 --
1188 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1189 --      (a) a value lambda
1190 --      (b) a saturated constructor application with static args
1191 --
1192 -- BUT watch out for
1193 --  (i) Any cross-DLL references kill static-ness completely
1194 --      because they must be 'executed' not statically allocated
1195 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1196 --      this is not necessary)
1197 --
1198 -- (ii) We treat partial applications as redexes, because in fact we
1199 --      make a thunk for them that runs and builds a PAP
1200 --      at run-time.  The only appliations that are treated as
1201 --      static are *saturated* applications of constructors.
1202
1203 -- We used to try to be clever with nested structures like this:
1204 --              ys = (:) w ((:) w [])
1205 -- on the grounds that CorePrep will flatten ANF-ise it later.
1206 -- But supporting this special case made the function much more
1207 -- complicated, because the special case only applies if there are no
1208 -- enclosing type lambdas:
1209 --              ys = /\ a -> Foo (Baz ([] a))
1210 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1211 --
1212 -- But in fact, even without -O, nested structures at top level are
1213 -- flattened by the simplifier, so we don't need to be super-clever here.
1214 --
1215 -- Examples
1216 --
1217 --      f = \x::Int. x+7        TRUE
1218 --      p = (True,False)        TRUE
1219 --
1220 --      d = (fst p, False)      FALSE because there's a redex inside
1221 --                              (this particular one doesn't happen but...)
1222 --
1223 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1224 --      n = /\a. Nil a                  TRUE
1225 --
1226 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1227 --
1228 --
1229 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1230 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1231 --
1232 --    b) (C x xs), where C is a contructor is updatable if the application is
1233 --         dynamic
1234 --
1235 --    c) don't look through unfolding of f in (f x).
1236
1237 rhsIsStatic _this_pkg rhs = is_static False rhs
1238   where
1239   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1240           -> CoreExpr -> Bool
1241
1242   is_static False (Lam b e) = isRuntimeVar b || is_static False e
1243
1244   is_static _      (Note (SCC _) _) = False
1245   is_static in_arg (Note _ e)       = is_static in_arg e
1246   is_static in_arg (Cast e _)       = is_static in_arg e
1247
1248   is_static _      (Lit lit)
1249     = case lit of
1250         MachLabel _ _ _ -> False
1251         _             -> True
1252         -- A MachLabel (foreign import "&foo") in an argument
1253         -- prevents a constructor application from being static.  The
1254         -- reason is that it might give rise to unresolvable symbols
1255         -- in the object file: under Linux, references to "weak"
1256         -- symbols from the data segment give rise to "unresolvable
1257         -- relocation" errors at link time This might be due to a bug
1258         -- in the linker, but we'll work around it here anyway.
1259         -- SDM 24/2/2004
1260
1261   is_static in_arg other_expr = go other_expr 0
1262    where
1263     go (Var f) n_val_args
1264 #if mingw32_TARGET_OS
1265         | not (isDllName _this_pkg (idName f))
1266 #endif
1267         =  saturated_data_con f n_val_args
1268         || (in_arg && n_val_args == 0)
1269                 -- A naked un-applied variable is *not* deemed a static RHS
1270                 -- E.g.         f = g
1271                 -- Reason: better to update so that the indirection gets shorted
1272                 --         out, and the true value will be seen
1273                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1274                 --     are always updatable.  If you do so, make sure that non-updatable
1275                 --     ones have enough space for their static link field!
1276
1277     go (App f a) n_val_args
1278         | isTypeArg a                    = go f n_val_args
1279         | not in_arg && is_static True a = go f (n_val_args + 1)
1280         -- The (not in_arg) checks that we aren't in a constructor argument;
1281         -- if we are, we don't allow (value) applications of any sort
1282         --
1283         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1284         --   x = D# (1.0## /## 2.0##)
1285         -- can't float because /## can fail.
1286
1287     go (Note (SCC _) _) _          = False
1288     go (Note _ f)       n_val_args = go f n_val_args
1289     go (Cast e _)       n_val_args = go e n_val_args
1290
1291     go _                _          = False
1292
1293     saturated_data_con f n_val_args
1294         = case isDataConWorkId_maybe f of
1295             Just dc -> n_val_args == dataConRepArity dc
1296             Nothing -> False
1297 \end{code}