compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 -- | Commonly useful utilites for manipulating the Core language
  17 module CoreUtils (
  18         -- * Constructing expressions
  19         mkInlineMe, mkSCC, mkCoerce, mkCoerceI,
  20         bindNonRec, needsCaseBinding,
  21         mkAltExpr, mkPiType, mkPiTypes,
  22
  23         -- * Taking expressions apart
  24         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  25
  26         -- * Properties of expressions
  27         exprType, coreAltType, coreAltsType,
  28         exprIsDupable, exprIsTrivial, exprIsCheap, exprIsExpandable,
  29         exprIsHNF,exprOkForSpeculation, exprIsBig,
  30         exprIsConApp_maybe, exprIsBottom,
  31         rhsIsStatic,
  32
  33         -- * Expression and bindings size
  34         coreBindsSize, exprSize,
  35
  36         -- * Hashing
  37         hashExpr,
  38
  39         -- * Equality
  40         cheapEqExpr,
  41
  42         -- * Manipulating data constructors and types
  43         applyTypeToArgs, applyTypeToArg,
  44         dataConOrigInstPat, dataConRepInstPat, dataConRepFSInstPat
  45     ) where
  46
  47 #include "HsVersions.h"
  48
  49 import CoreSyn
  50 import PprCore
  51 import Var
  52 import SrcLoc
  53 import VarEnv
  54 import Name
  55 import Module
  56 #if mingw32_TARGET_OS
  57 import Packages
  58 #endif
  59 import Literal
  60 import DataCon
  61 import PrimOp
  62 import Id
  63 import IdInfo
  64 import NewDemand
  65 import Type
  66 import Coercion
  67 import TyCon
  68 import CostCentre
  69 import Unique
  70 import Outputable
  71 import TysPrim
  72 import FastString
  73 import Maybes
  74 import Util
  75 import Data.Word
  76 import Data.Bits
  77
  78 import GHC.Exts         -- For `xori`
  79 \end{code}
  80
  81
  82 %************************************************************************
  83 %*                                                                      *
  84 \subsection{Find the type of a Core atom/expression}
  85 %*                                                                      *
  86 %************************************************************************
  87
  88 \begin{code}
  89 exprType :: CoreExpr -> Type
  90 -- ^ Recover the type of a well-typed Core expression. Fails when
  91 -- applied to the actual 'CoreSyn.Type' expression as it cannot
  92 -- really be said to have a type
  93 exprType (Var var)           = idType var
  94 exprType (Lit lit)           = literalType lit
  95 exprType (Let _ body)        = exprType body
  96 exprType (Case _ _ ty _)     = ty
  97 exprType (Cast _ co)         = snd (coercionKind co)
  98 exprType (Note _ e)          = exprType e
  99 exprType (Lam binder expr)   = mkPiType binder (exprType expr)
 100 exprType e@(App _ _)
 101   = case collectArgs e of
 102         (fun, args) -> applyTypeToArgs e (exprType fun) args
 103
 104 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 105
 106 coreAltType :: CoreAlt -> Type
 107 -- ^ Returns the type of the alternatives right hand side
 108 coreAltType (_,_,rhs) = exprType rhs
 109
 110 coreAltsType :: [CoreAlt] -> Type
 111 -- ^ Returns the type of the first alternative, which should be the same as for all alternatives
 112 coreAltsType (alt:_) = coreAltType alt
 113 coreAltsType []      = panic "corAltsType"
 114 \end{code}
 115
 116 \begin{code}
 117 mkPiType  :: Var   -> Type -> Type
 118 -- ^ Makes a @(->)@ type or a forall type, depending
 119 -- on whether it is given a type variable or a term variable.
 120 mkPiTypes :: [Var] -> Type -> Type
 121 -- ^ 'mkPiType' for multiple type or value arguments
 122
 123 mkPiType v ty
 124    | isId v    = mkFunTy (idType v) ty
 125    | otherwise = mkForAllTy v ty
 126
 127 mkPiTypes vs ty = foldr mkPiType ty vs
 128 \end{code}
 129
 130 \begin{code}
 131 applyTypeToArg :: Type -> CoreExpr -> Type
 132 -- ^ Determines the type resulting from applying an expression to a function with the given type
 133 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 134 applyTypeToArg fun_ty _             = funResultTy fun_ty
 135
 136 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 137 -- ^ A more efficient version of 'applyTypeToArg' when we have several arguments.
 138 -- The first argument is just for debugging, and gives some context
 139 applyTypeToArgs _ op_ty [] = op_ty
 140
 141 applyTypeToArgs e op_ty (Type ty : args)
 142   =     -- Accumulate type arguments so we can instantiate all at once
 143     go [ty] args
 144   where
 145     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 146     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 147                                 where
 148                                   op_ty' = applyTysD msg op_ty (reverse rev_tys)
 149                                   msg = ptext (sLit "applyTypeToArgs") <+>
 150                                         panic_msg e op_ty
 151
 152 applyTypeToArgs e op_ty (_ : args)
 153   = case (splitFunTy_maybe op_ty) of
 154         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 155         Nothing -> pprPanic "applyTypeToArgs" (panic_msg e op_ty)
 156
 157 panic_msg :: CoreExpr -> Type -> SDoc
 158 panic_msg e op_ty = pprCoreExpr e $$ ppr op_ty
 159 \end{code}
 160
 161 %************************************************************************
 162 %*                                                                      *
 163 \subsection{Attaching notes}
 164 %*                                                                      *
 165 %************************************************************************
 166
 167 mkNote removes redundant coercions, and SCCs where possible
 168
 169 \begin{code}
 170 #ifdef UNUSED
 171 mkNote :: Note -> CoreExpr -> CoreExpr
 172 mkNote (SCC cc) expr               = mkSCC cc expr
 173 mkNote InlineMe expr               = mkInlineMe expr
 174 mkNote note     expr               = Note note expr
 175 #endif
 176 \end{code}
 177
 178 Drop trivial InlineMe's.  This is somewhat important, because if we have an unfolding
 179 that looks like (Note InlineMe (Var v)), the InlineMe doesn't go away because it may
 180 not be *applied* to anything.
 181
 182 We don't use exprIsTrivial here, though, because we sometimes generate worker/wrapper
 183 bindings like
 184         fw = ...
 185         f  = inline_me (coerce t fw)
 186 As usual, the inline_me prevents the worker from getting inlined back into the wrapper.
 187 We want the split, so that the coerces can cancel at the call site.
 188
 189 However, we can get left with tiresome type applications.  Notably, consider
 190         f = /\ a -> let t = e in (t, w)
 191 Then lifting the let out of the big lambda gives
 192         t' = /\a -> e
 193         f = /\ a -> let t = inline_me (t' a) in (t, w)
 194 The inline_me is to stop the simplifier inlining t' right back
 195 into t's RHS.  In the next phase we'll substitute for t (since
 196 its rhs is trivial) and *then* we could get rid of the inline_me.
 197 But it hardly seems worth it, so I don't bother.
 198
 199 \begin{code}
 200 -- | Wraps the given expression in an inlining hint unless the expression
 201 -- is trivial in some sense, so that doing so would usually hurt us
 202 mkInlineMe :: CoreExpr -> CoreExpr
 203 mkInlineMe (Var v) = Var v
 204 mkInlineMe e       = Note InlineMe e
 205 \end{code}
 206
 207 \begin{code}
 208 -- | Wrap the given expression in the coercion, dropping identity coercions and coalescing nested coercions
 209 mkCoerceI :: CoercionI -> CoreExpr -> CoreExpr
 210 mkCoerceI IdCo e = e
 211 mkCoerceI (ACo co) e = mkCoerce co e
 212
 213 -- | Wrap the given expression in the coercion safely, coalescing nested coercions
 214 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 215 mkCoerce co (Cast expr co2)
 216   = ASSERT(let { (from_ty, _to_ty) = coercionKind co;
 217                  (_from_ty2, to_ty2) = coercionKind co2} in
 218            from_ty `coreEqType` to_ty2 )
 219     mkCoerce (mkTransCoercion co2 co) expr
 220
 221 mkCoerce co expr
 222   = let (from_ty, _to_ty) = coercionKind co in
 223 --    if to_ty `coreEqType` from_ty
 224 --    then expr
 225 --    else
 226         ASSERT2(from_ty `coreEqType` (exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ ppr (coercionKindPredTy co))
 227          (Cast expr co)
 228 \end{code}
 229
 230 \begin{code}
 231 -- | Wraps the given expression in the cost centre unless
 232 -- in a way that maximises their utility to the user
 233 mkSCC :: CostCentre -> Expr b -> Expr b
 234         -- Note: Nested SCC's *are* preserved for the benefit of
 235         --       cost centre stack profiling
 236 mkSCC _  (Lit lit)          = Lit lit
 237 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 238 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 239 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 240 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 241 mkSCC cc expr               = Note (SCC cc) expr
 242 \end{code}
 243
 244
 245 %************************************************************************
 246 %*                                                                      *
 247 \subsection{Other expression construction}
 248 %*                                                                      *
 249 %************************************************************************
 250
 251 \begin{code}
 252 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 253 -- ^ @bindNonRec x r b@ produces either:
 254 --
 255 -- > let x = r in b
 256 --
 257 -- or:
 258 --
 259 -- > case r of x { _DEFAULT_ -> b }
 260 --
 261 -- depending on whether we have to use a @case@ or @let@
 262 -- binding for the expression (see 'needsCaseBinding').
 263 -- It's used by the desugarer to avoid building bindings
 264 -- that give Core Lint a heart attack, although actually
 265 -- the simplifier deals with them perfectly well. See
 266 -- also 'MkCore.mkCoreLet'
 267 bindNonRec bndr rhs body
 268   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT, [], body)]
 269   | otherwise                          = Let (NonRec bndr rhs) body
 270
 271 -- | Tests whether we have to use a @case@ rather than @let@ binding for this expression
 272 -- as per the invariants of 'CoreExpr': see "CoreSyn#let_app_invariant"
 273 needsCaseBinding :: Type -> CoreExpr -> Bool
 274 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 275         -- Make a case expression instead of a let
 276         -- These can arise either from the desugarer,
 277         -- or from beta reductions: (\x.e) (x +# y)
 278 \end{code}
 279
 280 \begin{code}
 281 mkAltExpr :: AltCon     -- ^ Case alternative constructor
 282           -> [CoreBndr] -- ^ Things bound by the pattern match
 283           -> [Type]     -- ^ The type arguments to the case alternative
 284           -> CoreExpr
 285 -- ^ This guy constructs the value that the scrutinee must have
 286 -- given that you are in one particular branch of a case
 287 mkAltExpr (DataAlt con) args inst_tys
 288   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 289 mkAltExpr (LitAlt lit) [] []
 290   = Lit lit
 291 mkAltExpr (LitAlt _) _ _ = panic "mkAltExpr LitAlt"
 292 mkAltExpr DEFAULT _ _ = panic "mkAltExpr DEFAULT"
 293 \end{code}
 294
 295
 296 %************************************************************************
 297 %*                                                                      *
 298 \subsection{Taking expressions apart}
 299 %*                                                                      *
 300 %************************************************************************
 301
 302 The default alternative must be first, if it exists at all.
 303 This makes it easy to find, though it makes matching marginally harder.
 304
 305 \begin{code}
 306 -- | Extract the default case alternative
 307 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 308 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 309 findDefault alts                        =                     (alts, Nothing)
 310
 311 isDefaultAlt :: CoreAlt -> Bool
 312 isDefaultAlt (DEFAULT, _, _) = True
 313 isDefaultAlt _               = False
 314
 315
 316 -- | Find the case alternative corresponding to a particular
 317 -- constructor: panics if no such constructor exists
 318 findAlt :: AltCon -> [CoreAlt] -> Maybe CoreAlt
 319     -- A "Nothing" result *is* legitmiate
 320     -- See Note [Unreachable code]
 321 findAlt con alts
 322   = case alts of
 323         (deflt@(DEFAULT,_,_):alts) -> go alts (Just deflt)
 324         _                          -> go alts Nothing
 325   where
 326     go []                     deflt = deflt
 327     go (alt@(con1,_,_) : alts) deflt
 328       = case con `cmpAltCon` con1 of
 329           LT -> deflt   -- Missed it already; the alts are in increasing order
 330           EQ -> Just alt
 331           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 332
 333 ---------------------------------
 334 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 335 -- ^ Merge alternatives preserving order; alternatives in
 336 -- the first argument shadow ones in the second
 337 mergeAlts [] as2 = as2
 338 mergeAlts as1 [] = as1
 339 mergeAlts (a1:as1) (a2:as2)
 340   = case a1 `cmpAlt` a2 of
 341         LT -> a1 : mergeAlts as1      (a2:as2)
 342         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 343         GT -> a2 : mergeAlts (a1:as1) as2
 344
 345
 346 ---------------------------------
 347 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 348 -- ^ Given:
 349 --
 350 -- > case (C a b x y) of
 351 -- >        C b x y -> ...
 352 --
 353 -- We want to drop the leading type argument of the scrutinee
 354 -- leaving the arguments to match agains the pattern
 355
 356 trimConArgs DEFAULT      args = ASSERT( null args ) []
 357 trimConArgs (LitAlt _)   args = ASSERT( null args ) []
 358 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 359 \end{code}
 360
 361 Note [Unreachable code]
 362 ~~~~~~~~~~~~~~~~~~~~~~~
 363 It is possible (although unusual) for GHC to find a case expression
 364 that cannot match.  For example:
 365
 366      data Col = Red | Green | Blue
 367      x = Red
 368      f v = case x of
 369               Red -> ...
 370               _ -> ...(case x of { Green -> e1; Blue -> e2 })...
 371
 372 Suppose that for some silly reason, x isn't substituted in the case
 373 expression.  (Perhaps there's a NOINLINE on it, or profiling SCC stuff
 374 gets in the way; cf Trac #3118.)  Then the full-lazines pass might produce
 375 this
 376
 377      x = Red
 378      lvl = case x of { Green -> e1; Blue -> e2 })
 379      f v = case x of
 380              Red -> ...
 381              _ -> ...lvl...
 382
 383 Now if x gets inlined, we won't be able to find a matching alternative
 384 for 'Red'.  That's because 'lvl' is unreachable.  So rather than crashing
 385 we generate (error "Inaccessible alternative").
 386
 387 Similar things can happen (augmented by GADTs) when the Simplifier
 388 filters down the matching alternatives in Simplify.rebuildCase.
 389
 390
 391
 392 %************************************************************************
 393 %*                                                                      *
 394 \subsection{Figuring out things about expressions}
 395 %*                                                                      *
 396 %************************************************************************
 397
 398 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 399                 duplicate; simple variables and constants, and type
 400                 applications.  Note that primop Ids aren't considered
 401                 trivial unless
 402
 403 There used to be a gruesome test for (hasNoBinding v) in the
 404 Var case:
 405         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 406 The idea here is that a constructor worker, like \$wJust, is
 407 really short for (\x -> \$wJust x), becuase \$wJust has no binding.
 408 So it should be treated like a lambda.  Ditto unsaturated primops.
 409 But now constructor workers are not "have-no-binding" Ids.  And
 410 completely un-applied primops and foreign-call Ids are sufficiently
 411 rare that I plan to allow them to be duplicated and put up with
 412 saturating them.
 413
 414 SCC notes.  We do not treat (_scc_ "foo" x) as trivial, because
 415   a) it really generates code, (and a heap object when it's
 416      a function arg) to capture the cost centre
 417   b) see the note [SCC-and-exprIsTrivial] in Simplify.simplLazyBind
 418
 419 \begin{code}
 420 exprIsTrivial :: CoreExpr -> Bool
 421 exprIsTrivial (Var _)          = True        -- See notes above
 422 exprIsTrivial (Type _)         = True
 423 exprIsTrivial (Lit lit)        = litIsTrivial lit
 424 exprIsTrivial (App e arg)      = not (isRuntimeArg arg) && exprIsTrivial e
 425 exprIsTrivial (Note (SCC _) _) = False       -- See notes above
 426 exprIsTrivial (Note _       e) = exprIsTrivial e
 427 exprIsTrivial (Cast e _)       = exprIsTrivial e
 428 exprIsTrivial (Lam b body)     = not (isRuntimeVar b) && exprIsTrivial body
 429 exprIsTrivial _                = False
 430 \end{code}
 431
 432
 433 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 434                 cost in code size.  This will only happen in different case
 435                 branches, so there's no issue about duplicating work.
 436
 437                 That is, exprIsDupable returns True of (f x) even if
 438                 f is very very expensive to call.
 439
 440                 Its only purpose is to avoid fruitless let-binding
 441                 and then inlining of case join points
 442
 443
 444 \begin{code}
 445 exprIsDupable :: CoreExpr -> Bool
 446 exprIsDupable (Type _)          = True
 447 exprIsDupable (Var _)           = True
 448 exprIsDupable (Lit lit)         = litIsDupable lit
 449 exprIsDupable (Note InlineMe _) = True
 450 exprIsDupable (Note _ e)        = exprIsDupable e
 451 exprIsDupable (Cast e _)        = exprIsDupable e
 452 exprIsDupable expr
 453   = go expr 0
 454   where
 455     go (Var _)   _      = True
 456     go (App f a) n_args =  n_args < dupAppSize
 457                         && exprIsDupable a
 458                         && go f (n_args+1)
 459     go _         _      = False
 460
 461 dupAppSize :: Int
 462 dupAppSize = 4          -- Size of application we are prepared to duplicate
 463 \end{code}
 464
 465 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 466 it is obviously in weak head normal form, or is cheap to get to WHNF.
 467 [Note that that's not the same as exprIsDupable; an expression might be
 468 big, and hence not dupable, but still cheap.]
 469
 470 By ``cheap'' we mean a computation we're willing to:
 471         push inside a lambda, or
 472         inline at more than one place
 473 That might mean it gets evaluated more than once, instead of being
 474 shared.  The main examples of things which aren't WHNF but are
 475 ``cheap'' are:
 476
 477   *     case e of
 478           pi -> ei
 479         (where e, and all the ei are cheap)
 480
 481   *     let x = e in b
 482         (where e and b are cheap)
 483
 484   *     op x1 ... xn
 485         (where op is a cheap primitive operator)
 486
 487   *     error "foo"
 488         (because we are happy to substitute it inside a lambda)
 489
 490 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 491 because sharing will make sure it is only evaluated once.
 492
 493 \begin{code}
 494 exprIsCheap' :: (Id -> Bool) -> CoreExpr -> Bool
 495 exprIsCheap' _          (Lit _)           = True
 496 exprIsCheap' _          (Type _)          = True
 497 exprIsCheap' _          (Var _)           = True
 498 exprIsCheap' _          (Note InlineMe _) = True
 499 exprIsCheap' is_conlike (Note _ e)        = exprIsCheap' is_conlike e
 500 exprIsCheap' is_conlike (Cast e _)        = exprIsCheap' is_conlike e
 501 exprIsCheap' is_conlike (Lam x e)         = isRuntimeVar x
 502                                             || exprIsCheap' is_conlike e
 503 exprIsCheap' is_conlike (Case e _ _ alts) = exprIsCheap' is_conlike e &&
 504                                 and [exprIsCheap' is_conlike rhs | (_,_,rhs) <- alts]
 505         -- Experimentally, treat (case x of ...) as cheap
 506         -- (and case __coerce x etc.)
 507         -- This improves arities of overloaded functions where
 508         -- there is only dictionary selection (no construction) involved
 509 exprIsCheap' is_conlike (Let (NonRec x _) e)
 510       | isUnLiftedType (idType x) = exprIsCheap' is_conlike e
 511       | otherwise                 = False
 512         -- strict lets always have cheap right hand sides,
 513         -- and do no allocation.
 514
 515 exprIsCheap' is_conlike other_expr      -- Applications and variables
 516   = go other_expr []
 517   where
 518         -- Accumulate value arguments, then decide
 519     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 520                           | otherwise      = go f val_args
 521
 522     go (Var _) [] = True        -- Just a type application of a variable
 523                                 -- (f t1 t2 t3) counts as WHNF
 524     go (Var f) args
 525         = case idDetails f of
 526                 RecSelId {}  -> go_sel args
 527                 ClassOpId _  -> go_sel args
 528                 PrimOpId op  -> go_primop op args
 529
 530                 _ | is_conlike f -> go_pap args
 531                   | length args < idArity f -> go_pap args
 532
 533                 _ -> isBottomingId f
 534                         -- Application of a function which
 535                         -- always gives bottom; we treat this as cheap
 536                         -- because it certainly doesn't need to be shared!
 537
 538     go _ _ = False
 539
 540     --------------
 541     go_pap args = all exprIsTrivial args
 542         -- For constructor applications and primops, check that all
 543         -- the args are trivial.  We don't want to treat as cheap, say,
 544         --      (1:2:3:4:5:[])
 545         -- We'll put up with one constructor application, but not dozens
 546
 547     --------------
 548     go_primop op args = primOpIsCheap op && all (exprIsCheap' is_conlike) args
 549         -- In principle we should worry about primops
 550         -- that return a type variable, since the result
 551         -- might be applied to something, but I'm not going
 552         -- to bother to check the number of args
 553
 554     --------------
 555     go_sel [arg] = exprIsCheap' is_conlike arg  -- I'm experimenting with making record selection
 556     go_sel _     = False                -- look cheap, so we will substitute it inside a
 557                                         -- lambda.  Particularly for dictionary field selection.
 558                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 559                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 560
 561 exprIsCheap :: CoreExpr -> Bool
 562 exprIsCheap = exprIsCheap' isDataConWorkId
 563
 564 exprIsExpandable :: CoreExpr -> Bool
 565 exprIsExpandable = exprIsCheap' isConLikeId
 566 \end{code}
 567
 568 \begin{code}
 569 -- | 'exprOkForSpeculation' returns True of an expression that is:
 570 --
 571 --  * Safe to evaluate even if normal order eval might not
 572 --    evaluate the expression at all, or
 573 --
 574 --  * Safe /not/ to evaluate even if normal order would do so
 575 --
 576 -- Precisely, it returns @True@ iff:
 577 --
 578 --  * The expression guarantees to terminate,
 579 --
 580 --  * soon,
 581 --
 582 --  * without raising an exception,
 583 --
 584 --  * without causing a side effect (e.g. writing a mutable variable)
 585 --
 586 -- Note that if @exprIsHNF e@, then @exprOkForSpecuation e@.
 587 -- As an example of the considerations in this test, consider:
 588 --
 589 -- > let x = case y# +# 1# of { r# -> I# r# }
 590 -- > in E
 591 --
 592 -- being translated to:
 593 --
 594 -- > case y# +# 1# of { r# ->
 595 -- >    let x = I# r#
 596 -- >    in E
 597 -- > }
 598 --
 599 -- We can only do this if the @y + 1@ is ok for speculation: it has no
 600 -- side effects, and can't diverge or raise an exception.
 601 exprOkForSpeculation :: CoreExpr -> Bool
 602 exprOkForSpeculation (Lit _)     = True
 603 exprOkForSpeculation (Type _)    = True
 604     -- Tick boxes are *not* suitable for speculation
 605 exprOkForSpeculation (Var v)     = isUnLiftedType (idType v)
 606                                  && not (isTickBoxOp v)
 607 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 608 exprOkForSpeculation (Cast e _)  = exprOkForSpeculation e
 609 exprOkForSpeculation other_expr
 610   = case collectArgs other_expr of
 611         (Var f, args) -> spec_ok (idDetails f) args
 612         _             -> False
 613
 614   where
 615     spec_ok (DataConWorkId _) _
 616       = True    -- The strictness of the constructor has already
 617                 -- been expressed by its "wrapper", so we don't need
 618                 -- to take the arguments into account
 619
 620     spec_ok (PrimOpId op) args
 621       | isDivOp op,             -- Special case for dividing operations that fail
 622         [arg1, Lit lit] <- args -- only if the divisor is zero
 623       = not (isZeroLit lit) && exprOkForSpeculation arg1
 624                 -- Often there is a literal divisor, and this
 625                 -- can get rid of a thunk in an inner looop
 626
 627       | otherwise
 628       = primOpOkForSpeculation op &&
 629         all exprOkForSpeculation args
 630                                 -- A bit conservative: we don't really need
 631                                 -- to care about lazy arguments, but this is easy
 632
 633     spec_ok _ _ = False
 634
 635 -- | True of dyadic operators that can fail only if the second arg is zero!
 636 isDivOp :: PrimOp -> Bool
 637 -- This function probably belongs in PrimOp, or even in
 638 -- an automagically generated file.. but it's such a
 639 -- special case I thought I'd leave it here for now.
 640 isDivOp IntQuotOp        = True
 641 isDivOp IntRemOp         = True
 642 isDivOp WordQuotOp       = True
 643 isDivOp WordRemOp        = True
 644 isDivOp IntegerQuotRemOp = True
 645 isDivOp IntegerDivModOp  = True
 646 isDivOp FloatDivOp       = True
 647 isDivOp DoubleDivOp      = True
 648 isDivOp _                = False
 649 \end{code}
 650
 651 \begin{code}
 652 -- | True of expressions that are guaranteed to diverge upon execution
 653 exprIsBottom :: CoreExpr -> Bool
 654 exprIsBottom e = go 0 e
 655                where
 656                 -- n is the number of args
 657                  go n (Note _ e)     = go n e
 658                  go n (Cast e _)     = go n e
 659                  go n (Let _ e)      = go n e
 660                  go _ (Case e _ _ _) = go 0 e   -- Just check the scrut
 661                  go n (App e _)      = go (n+1) e
 662                  go n (Var v)        = idAppIsBottom v n
 663                  go _ (Lit _)        = False
 664                  go _ (Lam _ _)      = False
 665                  go _ (Type _)       = False
 666
 667 idAppIsBottom :: Id -> Int -> Bool
 668 idAppIsBottom id n_val_args = appIsBottom (idNewStrictness id) n_val_args
 669 \end{code}
 670
 671 \begin{code}
 672
 673 -- | This returns true for expressions that are certainly /already/
 674 -- evaluated to /head/ normal form.  This is used to decide whether it's ok
 675 -- to change:
 676 --
 677 -- > case x of _ -> e
 678 --
 679 -- into:
 680 --
 681 -- > e
 682 --
 683 -- and to decide whether it's safe to discard a 'seq'.
 684 -- So, it does /not/ treat variables as evaluated, unless they say they are.
 685 -- However, it /does/ treat partial applications and constructor applications
 686 -- as values, even if their arguments are non-trivial, provided the argument
 687 -- type is lifted. For example, both of these are values:
 688 --
 689 -- > (:) (f x) (map f xs)
 690 -- > map (...redex...)
 691 --
 692 -- Because 'seq' on such things completes immediately.
 693 --
 694 -- For unlifted argument types, we have to be careful:
 695 --
 696 -- > C (f x :: Int#)
 697 --
 698 -- Suppose @f x@ diverges; then @C (f x)@ is not a value. However this can't
 699 -- happen: see "CoreSyn#let_app_invariant". This invariant states that arguments of
 700 -- unboxed type must be ok-for-speculation (or trivial).
 701 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 702 exprIsHNF (Var v)       -- NB: There are no value args at this point
 703   =  isDataConWorkId v  -- Catches nullary constructors,
 704                         --      so that [] and () are values, for example
 705   || idArity v > 0      -- Catches (e.g.) primops that don't have unfoldings
 706   || isEvaldUnfolding (idUnfolding v)
 707         -- Check the thing's unfolding; it might be bound to a value
 708         -- A worry: what if an Id's unfolding is just itself:
 709         -- then we could get an infinite loop...
 710
 711 exprIsHNF (Lit _)          = True
 712 exprIsHNF (Type _)         = True       -- Types are honorary Values;
 713                                         -- we don't mind copying them
 714 exprIsHNF (Lam b e)        = isRuntimeVar b || exprIsHNF e
 715 exprIsHNF (Note _ e)       = exprIsHNF e
 716 exprIsHNF (Cast e _)       = exprIsHNF e
 717 exprIsHNF (App e (Type _)) = exprIsHNF e
 718 exprIsHNF (App e a)        = app_is_value e [a]
 719 exprIsHNF _                = False
 720
 721 -- There is at least one value argument
 722 app_is_value :: CoreExpr -> [CoreArg] -> Bool
 723 app_is_value (Var fun) args
 724   = idArity fun > valArgCount args      -- Under-applied function
 725     ||  isDataConWorkId fun             --  or data constructor
 726 app_is_value (Note _ f) as = app_is_value f as
 727 app_is_value (Cast f _) as = app_is_value f as
 728 app_is_value (App f a)  as = app_is_value f (a:as)
 729 app_is_value _          _  = False
 730 \end{code}
 731
 732 These InstPat functions go here to avoid circularity between DataCon and Id
 733
 734 \begin{code}
 735 dataConRepInstPat, dataConOrigInstPat :: [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 736 dataConRepFSInstPat :: [FastString] -> [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 737
 738 dataConRepInstPat   = dataConInstPat dataConRepArgTys (repeat ((fsLit "ipv")))
 739 dataConRepFSInstPat = dataConInstPat dataConRepArgTys
 740 dataConOrigInstPat  = dataConInstPat dc_arg_tys       (repeat ((fsLit "ipv")))
 741   where
 742     dc_arg_tys dc = map mkPredTy (dataConEqTheta dc) ++ map mkPredTy (dataConDictTheta dc) ++ dataConOrigArgTys dc
 743         -- Remember to include the existential dictionaries
 744
 745 dataConInstPat :: (DataCon -> [Type])      -- function used to find arg tys
 746                   -> [FastString]          -- A long enough list of FSs to use for names
 747                   -> [Unique]              -- An equally long list of uniques, at least one for each binder
 748                   -> DataCon
 749                   -> [Type]                -- Types to instantiate the universally quantified tyvars
 750                -> ([TyVar], [CoVar], [Id]) -- Return instantiated variables
 751 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 752 -- (ex_tvs, co_tvs, arg_ids),
 753 --
 754 --   ex_tvs are intended to be used as binders for existential type args
 755 --
 756 --   co_tvs are intended to be used as binders for coercion args and the kinds
 757 --     of these vars have been instantiated by the inst_tys and the ex_tys
 758 --     The co_tvs include both GADT equalities (dcEqSpec) and
 759 --     programmer-specified equalities (dcEqTheta)
 760 --
 761 --   arg_ids are indended to be used as binders for value arguments,
 762 --     and their types have been instantiated with inst_tys and ex_tys
 763 --     The arg_ids include both dicts (dcDictTheta) and
 764 --     programmer-specified arguments (after rep-ing) (deRepArgTys)
 765 --
 766 -- Example.
 767 --  The following constructor T1
 768 --
 769 --  data T a where
 770 --    T1 :: forall b. Int -> b -> T(a,b)
 771 --    ...
 772 --
 773 --  has representation type
 774 --   forall a. forall a1. forall b. (a ~ (a1,b)) =>
 775 --     Int -> b -> T a
 776 --
 777 --  dataConInstPat fss us T1 (a1',b') will return
 778 --
 779 --  ([a1'', b''], [c :: (a1', b')~(a1'', b'')], [x :: Int, y :: b''])
 780 --
 781 --  where the double-primed variables are created with the FastStrings and
 782 --  Uniques given as fss and us
 783 dataConInstPat arg_fun fss uniqs con inst_tys
 784   = (ex_bndrs, co_bndrs, arg_ids)
 785   where
 786     univ_tvs = dataConUnivTyVars con
 787     ex_tvs   = dataConExTyVars con
 788     arg_tys  = arg_fun con
 789     eq_spec  = dataConEqSpec con
 790     eq_theta = dataConEqTheta con
 791     eq_preds = eqSpecPreds eq_spec ++ eq_theta
 792
 793     n_ex = length ex_tvs
 794     n_co = length eq_preds
 795
 796       -- split the Uniques and FastStrings
 797     (ex_uniqs, uniqs')   = splitAt n_ex uniqs
 798     (co_uniqs, id_uniqs) = splitAt n_co uniqs'
 799
 800     (ex_fss, fss')     = splitAt n_ex fss
 801     (co_fss, id_fss)   = splitAt n_co fss'
 802
 803       -- Make existential type variables
 804     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 805     mk_ex_var uniq fs var = mkTyVar new_name kind
 806       where
 807         new_name = mkSysTvName uniq fs
 808         kind     = tyVarKind var
 809
 810       -- Make the instantiating substitution
 811     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 812
 813       -- Make new coercion vars, instantiating kind
 814     co_bndrs = zipWith3 mk_co_var co_uniqs co_fss eq_preds
 815     mk_co_var uniq fs eq_pred = mkCoVar new_name co_kind
 816        where
 817          new_name = mkSysTvName uniq fs
 818          co_kind  = substTy subst (mkPredTy eq_pred)
 819
 820       -- make value vars, instantiating types
 821     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (substTy subst ty) noSrcSpan
 822     arg_ids = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 823
 824 -- | Returns @Just (dc, [x1..xn])@ if the argument expression is
 825 -- a constructor application of the form @dc x1 .. xn@
 826 exprIsConApp_maybe :: CoreExpr -> Maybe (DataCon, [CoreExpr])
 827 exprIsConApp_maybe (Cast expr co)
 828   =     -- Here we do the KPush reduction rule as described in the FC paper
 829     case exprIsConApp_maybe expr of {
 830         Nothing            -> Nothing ;
 831         Just (dc, dc_args) ->
 832
 833         -- The transformation applies iff we have
 834         --      (C e1 ... en) `cast` co
 835         -- where co :: (T t1 .. tn) ~ (T s1 ..sn)
 836         -- That is, with a T at the top of both sides
 837         -- The left-hand one must be a T, because exprIsConApp returned True
 838         -- but the right-hand one might not be.  (Though it usually will.)
 839
 840     let (from_ty, to_ty)           = coercionKind co
 841         (from_tc, from_tc_arg_tys) = splitTyConApp from_ty
 842                 -- The inner one must be a TyConApp
 843     in
 844     case splitTyConApp_maybe to_ty of {
 845         Nothing -> Nothing ;
 846         Just (to_tc, to_tc_arg_tys)
 847                 | from_tc /= to_tc -> Nothing
 848                 -- These two Nothing cases are possible; we might see
 849                 --      (C x y) `cast` (g :: T a ~ S [a]),
 850                 -- where S is a type function.  In fact, exprIsConApp
 851                 -- will probably not be called in such circumstances,
 852                 -- but there't nothing wrong with it
 853
 854                 | otherwise  ->
 855     let
 856         tc_arity = tyConArity from_tc
 857
 858         (univ_args, rest1)        = splitAt tc_arity dc_args
 859         (ex_args, rest2)          = splitAt n_ex_tvs rest1
 860         (co_args_spec, rest3)     = splitAt n_cos_spec rest2
 861         (co_args_theta, val_args) = splitAt n_cos_theta rest3
 862
 863         arg_tys             = dataConRepArgTys dc
 864         dc_univ_tyvars      = dataConUnivTyVars dc
 865         dc_ex_tyvars        = dataConExTyVars dc
 866         dc_eq_spec          = dataConEqSpec dc
 867         dc_eq_theta         = dataConEqTheta dc
 868         dc_tyvars           = dc_univ_tyvars ++ dc_ex_tyvars
 869         n_ex_tvs            = length dc_ex_tyvars
 870         n_cos_spec          = length dc_eq_spec
 871         n_cos_theta         = length dc_eq_theta
 872
 873         -- Make the "theta" from Fig 3 of the paper
 874         gammas              = decomposeCo tc_arity co
 875         new_tys             = gammas ++ map (\ (Type t) -> t) ex_args
 876         theta               = zipOpenTvSubst dc_tyvars new_tys
 877
 878           -- First we cast the existential coercion arguments
 879         cast_co_spec (tv, ty) co
 880           = cast_co_theta (mkEqPred (mkTyVarTy tv, ty)) co
 881         cast_co_theta eqPred (Type co)
 882           | (ty1, ty2) <- getEqPredTys eqPred
 883           = Type $ mkSymCoercion (substTy theta ty1)
 884                    `mkTransCoercion` co
 885                    `mkTransCoercion` (substTy theta ty2)
 886         new_co_args = zipWith cast_co_spec  dc_eq_spec  co_args_spec ++
 887                       zipWith cast_co_theta dc_eq_theta co_args_theta
 888
 889           -- ...and now value arguments
 890         new_val_args = zipWith cast_arg arg_tys val_args
 891         cast_arg arg_ty arg = mkCoerce (substTy theta arg_ty) arg
 892
 893     in
 894     ASSERT( length univ_args == tc_arity )
 895     ASSERT( from_tc == dataConTyCon dc )
 896     ASSERT( and (zipWith coreEqType [t | Type t <- univ_args] from_tc_arg_tys) )
 897     ASSERT( all isTypeArg (univ_args ++ ex_args) )
 898     ASSERT2( equalLength val_args arg_tys, ppr dc $$ ppr dc_tyvars $$ ppr dc_ex_tyvars $$ ppr arg_tys $$ ppr dc_args $$ ppr univ_args $$ ppr ex_args $$ ppr val_args $$ ppr arg_tys  )
 899
 900     Just (dc, map Type to_tc_arg_tys ++ ex_args ++ new_co_args ++ new_val_args)
 901     }}
 902
 903 {-
 904 -- We do not want to tell the world that we have a
 905 -- Cons, to *stop* Case of Known Cons, which removes
 906 -- the TickBox.
 907 exprIsConApp_maybe (Note (TickBox {}) expr)
 908   = Nothing
 909 exprIsConApp_maybe (Note (BinaryTickBox {}) expr)
 910   = Nothing
 911 -}
 912
 913 exprIsConApp_maybe (Note _ expr)
 914   = exprIsConApp_maybe expr
 915     -- We ignore InlineMe notes in case we have
 916     --  x = __inline_me__ (a,b)
 917     -- All part of making sure that INLINE pragmas never hurt
 918     -- Marcin tripped on this one when making dictionaries more inlinable
 919     --
 920     -- In fact, we ignore all notes.  For example,
 921     --          case _scc_ "foo" (C a b) of
 922     --                  C a b -> e
 923     -- should be optimised away, but it will be only if we look
 924     -- through the SCC note.
 925
 926 exprIsConApp_maybe expr = analyse (collectArgs expr)
 927   where
 928     analyse (Var fun, args)
 929         | Just con <- isDataConWorkId_maybe fun,
 930           args `lengthAtLeast` dataConRepArity con
 931                 -- Might be > because the arity excludes type args
 932         = Just (con,args)
 933
 934         -- Look through unfoldings, but only cheap ones, because
 935         -- we are effectively duplicating the unfolding
 936     analyse (Var fun, [])
 937         | let unf = idUnfolding fun,
 938           isExpandableUnfolding unf
 939         = exprIsConApp_maybe (unfoldingTemplate unf)
 940
 941     analyse _ = Nothing
 942 \end{code}
 943
 944
 945
 946 %************************************************************************
 947 %*                                                                      *
 948 \subsection{Equality}
 949 %*                                                                      *
 950 %************************************************************************
 951
 952 \begin{code}
 953 -- | A cheap equality test which bales out fast!
 954 --      If it returns @True@ the arguments are definitely equal,
 955 --      otherwise, they may or may not be equal.
 956 --
 957 -- See also 'exprIsBig'
 958 cheapEqExpr :: Expr b -> Expr b -> Bool
 959
 960 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
 961 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
 962 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
 963
 964 cheapEqExpr (App f1 a1) (App f2 a2)
 965   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
 966
 967 cheapEqExpr (Cast e1 t1) (Cast e2 t2)
 968   = e1 `cheapEqExpr` e2 && t1 `coreEqCoercion` t2
 969
 970 cheapEqExpr _ _ = False
 971
 972 exprIsBig :: Expr b -> Bool
 973 -- ^ Returns @True@ of expressions that are too big to be compared by 'cheapEqExpr'
 974 exprIsBig (Lit _)      = False
 975 exprIsBig (Var _)      = False
 976 exprIsBig (Type _)     = False
 977 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
 978 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
 979 exprIsBig _            = True
 980 \end{code}
 981
 982
 983
 984 %************************************************************************
 985 %*                                                                      *
 986 \subsection{The size of an expression}
 987 %*                                                                      *
 988 %************************************************************************
 989
 990 \begin{code}
 991 coreBindsSize :: [CoreBind] -> Int
 992 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
 993
 994 exprSize :: CoreExpr -> Int
 995 -- ^ A measure of the size of the expressions, strictly greater than 0
 996 -- It also forces the expression pretty drastically as a side effect
 997 exprSize (Var v)         = v `seq` 1
 998 exprSize (Lit lit)       = lit `seq` 1
 999 exprSize (App f a)       = exprSize f + exprSize a
1000 exprSize (Lam b e)       = varSize b + exprSize e
1001 exprSize (Let b e)       = bindSize b + exprSize e
1002 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1003 exprSize (Cast e co)     = (seqType co `seq` 1) + exprSize e
1004 exprSize (Note n e)      = noteSize n + exprSize e
1005 exprSize (Type t)        = seqType t `seq` 1
1006
1007 noteSize :: Note -> Int
1008 noteSize (SCC cc)       = cc `seq` 1
1009 noteSize InlineMe       = 1
1010 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1011
1012 varSize :: Var -> Int
1013 varSize b  | isTyVar b = 1
1014            | otherwise = seqType (idType b)             `seq`
1015                          megaSeqIdInfo (idInfo b)       `seq`
1016                          1
1017
1018 varsSize :: [Var] -> Int
1019 varsSize = sum . map varSize
1020
1021 bindSize :: CoreBind -> Int
1022 bindSize (NonRec b e) = varSize b + exprSize e
1023 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1024
1025 pairSize :: (Var, CoreExpr) -> Int
1026 pairSize (b,e) = varSize b + exprSize e
1027
1028 altSize :: CoreAlt -> Int
1029 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1030 \end{code}
1031
1032
1033 %************************************************************************
1034 %*                                                                      *
1035 \subsection{Hashing}
1036 %*                                                                      *
1037 %************************************************************************
1038
1039 \begin{code}
1040 hashExpr :: CoreExpr -> Int
1041 -- ^ Two expressions that hash to the same @Int@ may be equal (but may not be)
1042 -- Two expressions that hash to the different Ints are definitely unequal.
1043 --
1044 -- The emphasis is on a crude, fast hash, rather than on high precision.
1045 --
1046 -- But unequal here means \"not identical\"; two alpha-equivalent
1047 -- expressions may hash to the different Ints.
1048 --
1049 -- We must be careful that @\\x.x@ and @\\y.y@ map to the same hash code,
1050 -- (at least if we want the above invariant to be true).
1051
1052 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
1053              -- UniqFM doesn't like negative Ints
1054
1055 type HashEnv = (Int, VarEnv Int)  -- Hash code for bound variables
1056
1057 hash_expr :: HashEnv -> CoreExpr -> Word32
1058 -- Word32, because we're expecting overflows here, and overflowing
1059 -- signed types just isn't cool.  In C it's even undefined.
1060 hash_expr env (Note _ e)              = hash_expr env e
1061 hash_expr env (Cast e _)              = hash_expr env e
1062 hash_expr env (Var v)                 = hashVar env v
1063 hash_expr _   (Lit lit)               = fromIntegral (hashLiteral lit)
1064 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
1065 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
1066 hash_expr env (Let (Rec ((b,_):_)) e) = hash_expr (extend_env env b) e
1067 hash_expr env (Case e _ _ _)          = hash_expr env e
1068 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
1069 hash_expr _   (Type _)                = WARN(True, text "hash_expr: type") 1
1070 -- Shouldn't happen.  Better to use WARN than trace, because trace
1071 -- prevents the CPR optimisation kicking in for hash_expr.
1072
1073 fast_hash_expr :: HashEnv -> CoreExpr -> Word32
1074 fast_hash_expr env (Var v)      = hashVar env v
1075 fast_hash_expr env (Type t)     = fast_hash_type env t
1076 fast_hash_expr _   (Lit lit)    = fromIntegral (hashLiteral lit)
1077 fast_hash_expr env (Cast e _)   = fast_hash_expr env e
1078 fast_hash_expr env (Note _ e)   = fast_hash_expr env e
1079 fast_hash_expr env (App _ a)    = fast_hash_expr env a  -- A bit idiosyncratic ('a' not 'f')!
1080 fast_hash_expr _   _            = 1
1081
1082 fast_hash_type :: HashEnv -> Type -> Word32
1083 fast_hash_type env ty
1084   | Just tv <- getTyVar_maybe ty            = hashVar env tv
1085   | Just (tc,tys) <- splitTyConApp_maybe ty = let hash_tc = fromIntegral (hashName (tyConName tc))
1086                                               in foldr (\t n -> fast_hash_type env t + n) hash_tc tys
1087   | otherwise                               = 1
1088
1089 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1090 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1091
1092 hashVar :: HashEnv -> Var -> Word32
1093 hashVar (_,env) v
1094  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1095 \end{code}
1096
1097 %************************************************************************
1098 %*                                                                      *
1099 \subsection{Determining non-updatable right-hand-sides}
1100 %*                                                                      *
1101 %************************************************************************
1102
1103 Top-level constructor applications can usually be allocated
1104 statically, but they can't if the constructor, or any of the
1105 arguments, come from another DLL (because we can't refer to static
1106 labels in other DLLs).
1107
1108 If this happens we simply make the RHS into an updatable thunk,
1109 and 'execute' it rather than allocating it statically.
1110
1111 \begin{code}
1112 -- | This function is called only on *top-level* right-hand sides.
1113 -- Returns @True@ if the RHS can be allocated statically in the output,
1114 -- with no thunks involved at all.
1115 rhsIsStatic :: PackageId -> CoreExpr -> Bool
1116 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1117 -- refers to, CAFs; (ii) in CoreToStg to decide whether to put an
1118 -- update flag on it and (iii) in DsExpr to decide how to expand
1119 -- list literals
1120 --
1121 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1122 --      (a) a value lambda
1123 --      (b) a saturated constructor application with static args
1124 --
1125 -- BUT watch out for
1126 --  (i) Any cross-DLL references kill static-ness completely
1127 --      because they must be 'executed' not statically allocated
1128 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1129 --      this is not necessary)
1130 --
1131 -- (ii) We treat partial applications as redexes, because in fact we
1132 --      make a thunk for them that runs and builds a PAP
1133 --      at run-time.  The only appliations that are treated as
1134 --      static are *saturated* applications of constructors.
1135
1136 -- We used to try to be clever with nested structures like this:
1137 --              ys = (:) w ((:) w [])
1138 -- on the grounds that CorePrep will flatten ANF-ise it later.
1139 -- But supporting this special case made the function much more
1140 -- complicated, because the special case only applies if there are no
1141 -- enclosing type lambdas:
1142 --              ys = /\ a -> Foo (Baz ([] a))
1143 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1144 --
1145 -- But in fact, even without -O, nested structures at top level are
1146 -- flattened by the simplifier, so we don't need to be super-clever here.
1147 --
1148 -- Examples
1149 --
1150 --      f = \x::Int. x+7        TRUE
1151 --      p = (True,False)        TRUE
1152 --
1153 --      d = (fst p, False)      FALSE because there's a redex inside
1154 --                              (this particular one doesn't happen but...)
1155 --
1156 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1157 --      n = /\a. Nil a                  TRUE
1158 --
1159 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1160 --
1161 --
1162 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1163 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1164 --
1165 --    b) (C x xs), where C is a contructors is updatable if the application is
1166 --         dynamic
1167 --
1168 --    c) don't look through unfolding of f in (f x).
1169
1170 rhsIsStatic _this_pkg rhs = is_static False rhs
1171   where
1172   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1173           -> CoreExpr -> Bool
1174
1175   is_static False (Lam b e) = isRuntimeVar b || is_static False e
1176
1177   is_static _      (Note (SCC _) _) = False
1178   is_static in_arg (Note _ e)       = is_static in_arg e
1179   is_static in_arg (Cast e _)       = is_static in_arg e
1180
1181   is_static _      (Lit lit)
1182     = case lit of
1183         MachLabel _ _ _ -> False
1184         _             -> True
1185         -- A MachLabel (foreign import "&foo") in an argument
1186         -- prevents a constructor application from being static.  The
1187         -- reason is that it might give rise to unresolvable symbols
1188         -- in the object file: under Linux, references to "weak"
1189         -- symbols from the data segment give rise to "unresolvable
1190         -- relocation" errors at link time This might be due to a bug
1191         -- in the linker, but we'll work around it here anyway.
1192         -- SDM 24/2/2004
1193
1194   is_static in_arg other_expr = go other_expr 0
1195    where
1196     go (Var f) n_val_args
1197 #if mingw32_TARGET_OS
1198         | not (isDllName _this_pkg (idName f))
1199 #endif
1200         =  saturated_data_con f n_val_args
1201         || (in_arg && n_val_args == 0)
1202                 -- A naked un-applied variable is *not* deemed a static RHS
1203                 -- E.g.         f = g
1204                 -- Reason: better to update so that the indirection gets shorted
1205                 --         out, and the true value will be seen
1206                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1207                 --     are always updatable.  If you do so, make sure that non-updatable
1208                 --     ones have enough space for their static link field!
1209
1210     go (App f a) n_val_args
1211         | isTypeArg a                    = go f n_val_args
1212         | not in_arg && is_static True a = go f (n_val_args + 1)
1213         -- The (not in_arg) checks that we aren't in a constructor argument;
1214         -- if we are, we don't allow (value) applications of any sort
1215         --
1216         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1217         --   x = D# (1.0## /## 2.0##)
1218         -- can't float because /## can fail.
1219
1220     go (Note (SCC _) _) _          = False
1221     go (Note _ f)       n_val_args = go f n_val_args
1222     go (Cast e _)       n_val_args = go e n_val_args
1223
1224     go _                _          = False
1225
1226     saturated_data_con f n_val_args
1227         = case isDataConWorkId_maybe f of
1228             Just dc -> n_val_args == dataConRepArity dc
1229             Nothing -> False
1230 \end{code}