compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 -- | Commonly useful utilites for manipulating the Core language
  17 module CoreUtils (
  18         -- * Constructing expressions
  19         mkSCC, mkCoerce,
  20         bindNonRec, needsCaseBinding,
  21         mkAltExpr, mkPiType, mkPiTypes,
  22
  23         -- * Taking expressions apart
  24         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  25
  26         -- * Properties of expressions
  27         exprType, coreAltType, coreAltsType,
  28         exprIsDupable, exprIsTrivial, exprIsBottom,
  29         exprIsCheap, exprIsExpandable, exprIsCheap', CheapAppFun,
  30         exprIsHNF, exprOkForSpeculation, exprIsBig, exprIsConLike,
  31         rhsIsStatic, isCheapApp, isExpandableApp,
  32
  33         -- * Expression and bindings size
  34         coreBindsSize, exprSize,
  35         CoreStats(..), coreBindsStats,
  36
  37         -- * Hashing
  38         hashExpr,
  39
  40         -- * Equality
  41         cheapEqExpr, eqExpr, eqExprX,
  42
  43         -- * Eta reduction
  44         tryEtaReduce,
  45
  46         -- * Manipulating data constructors and types
  47         applyTypeToArgs, applyTypeToArg,
  48         dataConRepInstPat, dataConRepFSInstPat
  49     ) where
  50
  51 #include "HsVersions.h"
  52
  53 import CoreSyn
  54 import PprCore
  55 import Var
  56 import SrcLoc
  57 import VarEnv
  58 import VarSet
  59 import Name
  60 import Literal
  61 import DataCon
  62 import PrimOp
  63 import Id
  64 import IdInfo
  65 import Type
  66 import Coercion
  67 import TyCon
  68 import CostCentre
  69 import Unique
  70 import Outputable
  71 import TysPrim
  72 import FastString
  73 import Maybes
  74 import Util
  75 import Pair
  76 import Data.Word
  77 import Data.Bits
  78 \end{code}
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83 \subsection{Find the type of a Core atom/expression}
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 exprType :: CoreExpr -> Type
  89 -- ^ Recover the type of a well-typed Core expression. Fails when
  90 -- applied to the actual 'CoreSyn.Type' expression as it cannot
  91 -- really be said to have a type
  92 exprType (Var var)           = idType var
  93 exprType (Lit lit)           = literalType lit
  94 exprType (Coercion co)       = coercionType co
  95 exprType (Let _ body)        = exprType body
  96 exprType (Case _ _ ty _)     = ty
  97 exprType (Cast _ co)         = pSnd (coercionKind co)
  98 exprType (Note _ e)          = exprType e
  99 exprType (Lam binder expr)   = mkPiType binder (exprType expr)
 100 exprType e@(App _ _)
 101   = case collectArgs e of
 102         (fun, args) -> applyTypeToArgs e (exprType fun) args
 103
 104 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 105
 106 coreAltType :: CoreAlt -> Type
 107 -- ^ Returns the type of the alternatives right hand side
 108 coreAltType (_,bs,rhs)
 109   | any bad_binder bs = expandTypeSynonyms ty
 110   | otherwise         = ty    -- Note [Existential variables and silly type synonyms]
 111   where
 112     ty           = exprType rhs
 113     free_tvs     = tyVarsOfType ty
 114     bad_binder b = isTyVar b && b `elemVarSet` free_tvs
 115
 116 coreAltsType :: [CoreAlt] -> Type
 117 -- ^ Returns the type of the first alternative, which should be the same as for all alternatives
 118 coreAltsType (alt:_) = coreAltType alt
 119 coreAltsType []      = panic "corAltsType"
 120 \end{code}
 121
 122 Note [Existential variables and silly type synonyms]
 123 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 124 Consider
 125         data T = forall a. T (Funny a)
 126         type Funny a = Bool
 127         f :: T -> Bool
 128         f (T x) = x
 129
 130 Now, the type of 'x' is (Funny a), where 'a' is existentially quantified.
 131 That means that 'exprType' and 'coreAltsType' may give a result that *appears*
 132 to mention an out-of-scope type variable.  See Trac #3409 for a more real-world
 133 example.
 134
 135 Various possibilities suggest themselves:
 136
 137  - Ignore the problem, and make Lint not complain about such variables
 138
 139  - Expand all type synonyms (or at least all those that discard arguments)
 140       This is tricky, because at least for top-level things we want to
 141       retain the type the user originally specified.
 142
 143  - Expand synonyms on the fly, when the problem arises. That is what
 144    we are doing here.  It's not too expensive, I think.
 145
 146 \begin{code}
 147 mkPiType  :: Var -> Type -> Type
 148 -- ^ Makes a @(->)@ type or a forall type, depending
 149 -- on whether it is given a type variable or a term variable.
 150 mkPiTypes :: [Var] -> Type -> Type
 151 -- ^ 'mkPiType' for multiple type or value arguments
 152
 153 mkPiType v ty
 154    | isId v    = mkFunTy (idType v) ty
 155    | otherwise = mkForAllTy v ty
 156
 157 mkPiTypes vs ty = foldr mkPiType ty vs
 158 \end{code}
 159
 160 \begin{code}
 161 applyTypeToArg :: Type -> CoreExpr -> Type
 162 -- ^ Determines the type resulting from applying an expression to a function with the given type
 163 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 164 applyTypeToArg fun_ty _             = funResultTy fun_ty
 165
 166 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 167 -- ^ A more efficient version of 'applyTypeToArg' when we have several arguments.
 168 -- The first argument is just for debugging, and gives some context
 169 applyTypeToArgs _ op_ty [] = op_ty
 170
 171 applyTypeToArgs e op_ty (Type ty : args)
 172   =     -- Accumulate type arguments so we can instantiate all at once
 173     go [ty] args
 174   where
 175     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 176     go rev_tys rest_args         = applyTypeToArgs e op_ty' rest_args
 177                                  where
 178                                    op_ty' = applyTysD msg op_ty (reverse rev_tys)
 179                                    msg = ptext (sLit "applyTypeToArgs") <+>
 180                                          panic_msg e op_ty
 181
 182 applyTypeToArgs e op_ty (_ : args)
 183   = case (splitFunTy_maybe op_ty) of
 184         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 185         Nothing -> pprPanic "applyTypeToArgs" (panic_msg e op_ty)
 186
 187 panic_msg :: CoreExpr -> Type -> SDoc
 188 panic_msg e op_ty = pprCoreExpr e $$ ppr op_ty
 189 \end{code}
 190
 191 %************************************************************************
 192 %*                                                                      *
 193 \subsection{Attaching notes}
 194 %*                                                                      *
 195 %************************************************************************
 196
 197 \begin{code}
 198 -- | Wrap the given expression in the coercion safely, dropping
 199 -- identity coercions and coalescing nested coercions
 200 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 201 mkCoerce co e | isReflCo co = e
 202 mkCoerce co (Cast expr co2)
 203   = ASSERT(let { Pair  from_ty  _to_ty  = coercionKind co;
 204                  Pair _from_ty2  to_ty2 = coercionKind co2} in
 205            from_ty `eqType` to_ty2 )
 206     mkCoerce (mkTransCo co2 co) expr
 207
 208 mkCoerce co expr
 209   = let Pair from_ty _to_ty = coercionKind co in
 210 --    if to_ty `eqType` from_ty
 211 --    then expr
 212 --    else
 213         WARN(not (from_ty `eqType` exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ pprEqPred (coercionKind co))
 214          (Cast expr co)
 215 \end{code}
 216
 217 \begin{code}
 218 -- | Wraps the given expression in the cost centre unless
 219 -- in a way that maximises their utility to the user
 220 mkSCC :: CostCentre -> Expr b -> Expr b
 221         -- Note: Nested SCC's *are* preserved for the benefit of
 222         --       cost centre stack profiling
 223 mkSCC _  (Lit lit)          = Lit lit
 224 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 225 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 226 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 227 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 228 mkSCC cc expr               = Note (SCC cc) expr
 229 \end{code}
 230
 231
 232 %************************************************************************
 233 %*                                                                      *
 234 \subsection{Other expression construction}
 235 %*                                                                      *
 236 %************************************************************************
 237
 238 \begin{code}
 239 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 240 -- ^ @bindNonRec x r b@ produces either:
 241 --
 242 -- > let x = r in b
 243 --
 244 -- or:
 245 --
 246 -- > case r of x { _DEFAULT_ -> b }
 247 --
 248 -- depending on whether we have to use a @case@ or @let@
 249 -- binding for the expression (see 'needsCaseBinding').
 250 -- It's used by the desugarer to avoid building bindings
 251 -- that give Core Lint a heart attack, although actually
 252 -- the simplifier deals with them perfectly well. See
 253 -- also 'MkCore.mkCoreLet'
 254 bindNonRec bndr rhs body
 255   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT, [], body)]
 256   | otherwise                          = Let (NonRec bndr rhs) body
 257
 258 -- | Tests whether we have to use a @case@ rather than @let@ binding for this expression
 259 -- as per the invariants of 'CoreExpr': see "CoreSyn#let_app_invariant"
 260 needsCaseBinding :: Type -> CoreExpr -> Bool
 261 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 262         -- Make a case expression instead of a let
 263         -- These can arise either from the desugarer,
 264         -- or from beta reductions: (\x.e) (x +# y)
 265 \end{code}
 266
 267 \begin{code}
 268 mkAltExpr :: AltCon     -- ^ Case alternative constructor
 269           -> [CoreBndr] -- ^ Things bound by the pattern match
 270           -> [Type]     -- ^ The type arguments to the case alternative
 271           -> CoreExpr
 272 -- ^ This guy constructs the value that the scrutinee must have
 273 -- given that you are in one particular branch of a case
 274 mkAltExpr (DataAlt con) args inst_tys
 275   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 276 mkAltExpr (LitAlt lit) [] []
 277   = Lit lit
 278 mkAltExpr (LitAlt _) _ _ = panic "mkAltExpr LitAlt"
 279 mkAltExpr DEFAULT _ _ = panic "mkAltExpr DEFAULT"
 280 \end{code}
 281
 282
 283 %************************************************************************
 284 %*                                                                      *
 285 \subsection{Taking expressions apart}
 286 %*                                                                      *
 287 %************************************************************************
 288
 289 The default alternative must be first, if it exists at all.
 290 This makes it easy to find, though it makes matching marginally harder.
 291
 292 \begin{code}
 293 -- | Extract the default case alternative
 294 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 295 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 296 findDefault alts                        =                     (alts, Nothing)
 297
 298 isDefaultAlt :: CoreAlt -> Bool
 299 isDefaultAlt (DEFAULT, _, _) = True
 300 isDefaultAlt _               = False
 301
 302
 303 -- | Find the case alternative corresponding to a particular
 304 -- constructor: panics if no such constructor exists
 305 findAlt :: AltCon -> [CoreAlt] -> Maybe CoreAlt
 306     -- A "Nothing" result *is* legitmiate
 307     -- See Note [Unreachable code]
 308 findAlt con alts
 309   = case alts of
 310         (deflt@(DEFAULT,_,_):alts) -> go alts (Just deflt)
 311         _                          -> go alts Nothing
 312   where
 313     go []                     deflt = deflt
 314     go (alt@(con1,_,_) : alts) deflt
 315       = case con `cmpAltCon` con1 of
 316           LT -> deflt   -- Missed it already; the alts are in increasing order
 317           EQ -> Just alt
 318           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 319
 320 ---------------------------------
 321 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 322 -- ^ Merge alternatives preserving order; alternatives in
 323 -- the first argument shadow ones in the second
 324 mergeAlts [] as2 = as2
 325 mergeAlts as1 [] = as1
 326 mergeAlts (a1:as1) (a2:as2)
 327   = case a1 `cmpAlt` a2 of
 328         LT -> a1 : mergeAlts as1      (a2:as2)
 329         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 330         GT -> a2 : mergeAlts (a1:as1) as2
 331
 332
 333 ---------------------------------
 334 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 335 -- ^ Given:
 336 --
 337 -- > case (C a b x y) of
 338 -- >        C b x y -> ...
 339 --
 340 -- We want to drop the leading type argument of the scrutinee
 341 -- leaving the arguments to match agains the pattern
 342
 343 trimConArgs DEFAULT      args = ASSERT( null args ) []
 344 trimConArgs (LitAlt _)   args = ASSERT( null args ) []
 345 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 346 \end{code}
 347
 348 Note [Unreachable code]
 349 ~~~~~~~~~~~~~~~~~~~~~~~
 350 It is possible (although unusual) for GHC to find a case expression
 351 that cannot match.  For example:
 352
 353      data Col = Red | Green | Blue
 354      x = Red
 355      f v = case x of
 356               Red -> ...
 357               _ -> ...(case x of { Green -> e1; Blue -> e2 })...
 358
 359 Suppose that for some silly reason, x isn't substituted in the case
 360 expression.  (Perhaps there's a NOINLINE on it, or profiling SCC stuff
 361 gets in the way; cf Trac #3118.)  Then the full-lazines pass might produce
 362 this
 363
 364      x = Red
 365      lvl = case x of { Green -> e1; Blue -> e2 })
 366      f v = case x of
 367              Red -> ...
 368              _ -> ...lvl...
 369
 370 Now if x gets inlined, we won't be able to find a matching alternative
 371 for 'Red'.  That's because 'lvl' is unreachable.  So rather than crashing
 372 we generate (error "Inaccessible alternative").
 373
 374 Similar things can happen (augmented by GADTs) when the Simplifier
 375 filters down the matching alternatives in Simplify.rebuildCase.
 376
 377
 378 %************************************************************************
 379 %*                                                                      *
 380              exprIsTrivial
 381 %*                                                                      *
 382 %************************************************************************
 383
 384 Note [exprIsTrivial]
 385 ~~~~~~~~~~~~~~~~~~~~
 386 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 387                 duplicate; simple variables and constants, and type
 388                 applications.  Note that primop Ids aren't considered
 389                 trivial unless
 390
 391 Note [Variable are trivial]
 392 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 393 There used to be a gruesome test for (hasNoBinding v) in the
 394 Var case:
 395         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 396 The idea here is that a constructor worker, like \$wJust, is
 397 really short for (\x -> \$wJust x), becuase \$wJust has no binding.
 398 So it should be treated like a lambda.  Ditto unsaturated primops.
 399 But now constructor workers are not "have-no-binding" Ids.  And
 400 completely un-applied primops and foreign-call Ids are sufficiently
 401 rare that I plan to allow them to be duplicated and put up with
 402 saturating them.
 403
 404 Note [SCCs are trivial]
 405 ~~~~~~~~~~~~~~~~~~~~~~~
 406 We used not to treat (_scc_ "foo" x) as trivial, because it really
 407 generates code, (and a heap object when it's a function arg) to
 408 capture the cost centre.  However, the profiling system discounts the
 409 allocation costs for such "boxing thunks" whereas the extra costs of
 410 *not* inlining otherwise-trivial bindings can be high, and are hard to
 411 discount.
 412
 413 \begin{code}
 414 exprIsTrivial :: CoreExpr -> Bool
 415 exprIsTrivial (Var _)          = True        -- See Note [Variables are trivial]
 416 exprIsTrivial (Type _)        = True
 417 exprIsTrivial (Coercion _)     = True
 418 exprIsTrivial (Lit lit)        = litIsTrivial lit
 419 exprIsTrivial (App e arg)      = not (isRuntimeArg arg) && exprIsTrivial e
 420 exprIsTrivial (Note _       e) = exprIsTrivial e  -- See Note [SCCs are trivial]
 421 exprIsTrivial (Cast e _)       = exprIsTrivial e
 422 exprIsTrivial (Lam b body)     = not (isRuntimeVar b) && exprIsTrivial body
 423 exprIsTrivial _                = False
 424 \end{code}
 425
 426 exprIsBottom is a very cheap and cheerful function; it may return
 427 False for bottoming expressions, but it never costs much to ask.
 428 See also CoreArity.exprBotStrictness_maybe, but that's a bit more
 429 expensive.
 430
 431 \begin{code}
 432 exprIsBottom :: CoreExpr -> Bool
 433 exprIsBottom e
 434   = go 0 e
 435   where
 436     go n (Var v) = isBottomingId v &&  n >= idArity v
 437     go n (App e a) | isTypeArg a = go n e
 438                    | otherwise   = go (n+1) e
 439     go n (Note _ e)              = go n e
 440     go n (Cast e _)              = go n e
 441     go n (Let _ e)               = go n e
 442     go _ _                       = False
 443 \end{code}
 444
 445
 446 %************************************************************************
 447 %*                                                                      *
 448              exprIsDupable
 449 %*                                                                      *
 450 %************************************************************************
 451
 452 Note [exprIsDupable]
 453 ~~~~~~~~~~~~~~~~~~~~
 454 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 455                 cost in code size.  This will only happen in different case
 456                 branches, so there's no issue about duplicating work.
 457
 458                 That is, exprIsDupable returns True of (f x) even if
 459                 f is very very expensive to call.
 460
 461                 Its only purpose is to avoid fruitless let-binding
 462                 and then inlining of case join points
 463
 464
 465 \begin{code}
 466 exprIsDupable :: CoreExpr -> Bool
 467 exprIsDupable e
 468   = isJust (go dupAppSize e)
 469   where
 470     go :: Int -> CoreExpr -> Maybe Int
 471     go n (Type {})     = Just n
 472     go n (Coercion {}) = Just n
 473     go n (Var {})      = decrement n
 474     go n (Note _ e)    = go n e
 475     go n (Cast e _)    = go n e
 476     go n (App f a) | Just n' <- go n a = go n' f
 477     go n (Lit lit) | litIsDupable lit = decrement n
 478     go _ _ = Nothing
 479
 480     decrement :: Int -> Maybe Int
 481     decrement 0 = Nothing
 482     decrement n = Just (n-1)
 483
 484 dupAppSize :: Int
 485 dupAppSize = 8   -- Size of term we are prepared to duplicate
 486                  -- This is *just* big enough to make test MethSharing
 487                  -- inline enough join points.  Really it should be
 488                  -- smaller, and could be if we fixed Trac #4960.
 489 \end{code}
 490
 491 %************************************************************************
 492 %*                                                                      *
 493              exprIsCheap, exprIsExpandable
 494 %*                                                                      *
 495 %************************************************************************
 496
 497 Note [exprIsCheap]   See also Note [Interaction of exprIsCheap and lone variables]
 498 ~~~~~~~~~~~~~~~~~~   in CoreUnfold.lhs
 499 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 500 it is obviously in weak head normal form, or is cheap to get to WHNF.
 501 [Note that that's not the same as exprIsDupable; an expression might be
 502 big, and hence not dupable, but still cheap.]
 503
 504 By ``cheap'' we mean a computation we're willing to:
 505         push inside a lambda, or
 506         inline at more than one place
 507 That might mean it gets evaluated more than once, instead of being
 508 shared.  The main examples of things which aren't WHNF but are
 509 ``cheap'' are:
 510
 511   *     case e of
 512           pi -> ei
 513         (where e, and all the ei are cheap)
 514
 515   *     let x = e in b
 516         (where e and b are cheap)
 517
 518   *     op x1 ... xn
 519         (where op is a cheap primitive operator)
 520
 521   *     error "foo"
 522         (because we are happy to substitute it inside a lambda)
 523
 524 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 525 because sharing will make sure it is only evaluated once.
 526
 527 Note [exprIsCheap and exprIsHNF]
 528 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 529 Note that exprIsHNF does not imply exprIsCheap.  Eg
 530         let x = fac 20 in Just x
 531 This responds True to exprIsHNF (you can discard a seq), but
 532 False to exprIsCheap.
 533
 534 \begin{code}
 535 exprIsCheap :: CoreExpr -> Bool
 536 exprIsCheap = exprIsCheap' isCheapApp
 537
 538 exprIsExpandable :: CoreExpr -> Bool
 539 exprIsExpandable = exprIsCheap' isExpandableApp -- See Note [CONLIKE pragma] in BasicTypes
 540
 541 type CheapAppFun = Id -> Int -> Bool
 542 exprIsCheap' :: CheapAppFun -> CoreExpr -> Bool
 543 exprIsCheap' _        (Lit _)      = True
 544 exprIsCheap' _        (Type _)    = True
 545 exprIsCheap' _        (Coercion _) = True
 546 exprIsCheap' _        (Var _)      = True
 547 exprIsCheap' good_app (Note _ e)   = exprIsCheap' good_app e
 548 exprIsCheap' good_app (Cast e _)   = exprIsCheap' good_app e
 549 exprIsCheap' good_app (Lam x e)    = isRuntimeVar x
 550                                   || exprIsCheap' good_app e
 551
 552 exprIsCheap' good_app (Case e _ _ alts) = exprIsCheap' good_app e &&
 553                                           and [exprIsCheap' good_app rhs | (_,_,rhs) <- alts]
 554         -- Experimentally, treat (case x of ...) as cheap
 555         -- (and case __coerce x etc.)
 556         -- This improves arities of overloaded functions where
 557         -- there is only dictionary selection (no construction) involved
 558
 559 exprIsCheap' good_app (Let (NonRec x _) e)
 560   | isUnLiftedType (idType x) = exprIsCheap' good_app e
 561   | otherwise                 = False
 562         -- Strict lets always have cheap right hand sides,
 563         -- and do no allocation, so just look at the body
 564         -- Non-strict lets do allocation so we don't treat them as cheap
 565         -- See also
 566
 567 exprIsCheap' good_app other_expr        -- Applications and variables
 568   = go other_expr []
 569   where
 570         -- Accumulate value arguments, then decide
 571     go (Cast e _) val_args                 = go e val_args
 572     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 573                           | otherwise      = go f val_args
 574
 575     go (Var _) [] = True        -- Just a type application of a variable
 576                                 -- (f t1 t2 t3) counts as WHNF
 577     go (Var f) args
 578         = case idDetails f of
 579                 RecSelId {}                  -> go_sel args
 580                 ClassOpId {}                 -> go_sel args
 581                 PrimOpId op                  -> go_primop op args
 582                 _ | good_app f (length args) -> go_pap args
 583                   | isBottomingId f          -> True
 584                   | otherwise                -> False
 585                         -- Application of a function which
 586                         -- always gives bottom; we treat this as cheap
 587                         -- because it certainly doesn't need to be shared!
 588
 589     go _ _ = False
 590
 591     --------------
 592     go_pap args = all (exprIsCheap' good_app) args
 593         -- Used to be "all exprIsTrivial args" due to concerns about
 594         -- duplicating nested constructor applications, but see #4978.
 595
 596     --------------
 597     go_primop op args = primOpIsCheap op && all (exprIsCheap' good_app) args
 598         -- In principle we should worry about primops
 599         -- that return a type variable, since the result
 600         -- might be applied to something, but I'm not going
 601         -- to bother to check the number of args
 602
 603     --------------
 604     go_sel [arg] = exprIsCheap' good_app arg    -- I'm experimenting with making record selection
 605     go_sel _     = False                -- look cheap, so we will substitute it inside a
 606                                         -- lambda.  Particularly for dictionary field selection.
 607                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 608                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 609
 610 isCheapApp :: CheapAppFun
 611 isCheapApp fn n_val_args
 612   = isDataConWorkId fn
 613   || n_val_args < idArity fn
 614
 615 isExpandableApp :: CheapAppFun
 616 isExpandableApp fn n_val_args
 617   =  isConLikeId fn
 618   || n_val_args < idArity fn
 619   || go n_val_args (idType fn)
 620   where
 621   -- See if all the arguments are PredTys (implicit params or classes)
 622   -- If so we'll regard it as expandable; see Note [Expandable overloadings]
 623      go 0 _ = True
 624      go n_val_args ty
 625        | Just (_, ty) <- splitForAllTy_maybe ty   = go n_val_args ty
 626        | Just (arg, ty) <- splitFunTy_maybe ty
 627        , isPredTy arg                             = go (n_val_args-1) ty
 628        | otherwise                                = False
 629 \end{code}
 630
 631 Note [Expandable overloadings]
 632 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 633 Suppose the user wrote this
 634    {-# RULE  forall x. foo (negate x) = h x #-}
 635    f x = ....(foo (negate x))....
 636 He'd expect the rule to fire. But since negate is overloaded, we might
 637 get this:
 638     f = \d -> let n = negate d in \x -> ...foo (n x)...
 639 So we treat the application of a function (negate in this case) to a
 640 *dictionary* as expandable.  In effect, every function is CONLIKE when
 641 it's applied only to dictionaries.
 642
 643
 644 %************************************************************************
 645 %*                                                                      *
 646              exprOkForSpeculation
 647 %*                                                                      *
 648 %************************************************************************
 649
 650 \begin{code}
 651 -- | 'exprOkForSpeculation' returns True of an expression that is:
 652 --
 653 --  * Safe to evaluate even if normal order eval might not
 654 --    evaluate the expression at all, or
 655 --
 656 --  * Safe /not/ to evaluate even if normal order would do so
 657 --
 658 -- It is usually called on arguments of unlifted type, but not always
 659 -- In particular, Simplify.rebuildCase calls it on lifted types
 660 -- when a 'case' is a plain 'seq'. See the example in
 661 -- Note [exprOkForSpeculation: case expressions] below
 662 --
 663 -- Precisely, it returns @True@ iff:
 664 --
 665 --  * The expression guarantees to terminate,
 666 --  * soon,
 667 --  * without raising an exception,
 668 --  * without causing a side effect (e.g. writing a mutable variable)
 669 --
 670 -- Note that if @exprIsHNF e@, then @exprOkForSpecuation e@.
 671 -- As an example of the considerations in this test, consider:
 672 --
 673 -- > let x = case y# +# 1# of { r# -> I# r# }
 674 -- > in E
 675 --
 676 -- being translated to:
 677 --
 678 -- > case y# +# 1# of { r# ->
 679 -- >    let x = I# r#
 680 -- >    in E
 681 -- > }
 682 --
 683 -- We can only do this if the @y + 1@ is ok for speculation: it has no
 684 -- side effects, and can't diverge or raise an exception.
 685 exprOkForSpeculation :: CoreExpr -> Bool
 686 exprOkForSpeculation (Lit _)      = True
 687 exprOkForSpeculation (Type _)     = True
 688 exprOkForSpeculation (Coercion _) = True
 689
 690 exprOkForSpeculation (Var v)
 691   | isTickBoxOp v = False     -- Tick boxes are *not* suitable for speculation
 692   | otherwise     =  isUnLiftedType (idType v)  -- c.f. the Var case of exprIsHNF
 693                   || isDataConWorkId v          -- Nullary constructors
 694                   || idArity v > 0              -- Functions
 695                   || isEvaldUnfolding (idUnfolding v)   -- Let-bound values
 696
 697 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 698 exprOkForSpeculation (Cast e _)  = exprOkForSpeculation e
 699
 700 exprOkForSpeculation (Case e _ _ alts)
 701   =  exprOkForSpeculation e  -- Note [exprOkForSpeculation: case expressions]
 702   && all (\(_,_,rhs) -> exprOkForSpeculation rhs) alts
 703
 704 exprOkForSpeculation other_expr
 705   = case collectArgs other_expr of
 706         (Var f, args) -> spec_ok (idDetails f) args
 707         _             -> False
 708
 709   where
 710     spec_ok (DataConWorkId _) _
 711       = True    -- The strictness of the constructor has already
 712                 -- been expressed by its "wrapper", so we don't need
 713                 -- to take the arguments into account
 714
 715     spec_ok (PrimOpId op) args
 716       | isDivOp op,             -- Special case for dividing operations that fail
 717         [arg1, Lit lit] <- args -- only if the divisor is zero
 718       = not (isZeroLit lit) && exprOkForSpeculation arg1
 719                 -- Often there is a literal divisor, and this
 720                 -- can get rid of a thunk in an inner looop
 721
 722       | DataToTagOp <- op      -- See Note [dataToTag speculation]
 723       = True
 724
 725       | otherwise
 726       = primOpOkForSpeculation op &&
 727         all exprOkForSpeculation args
 728                                 -- A bit conservative: we don't really need
 729                                 -- to care about lazy arguments, but this is easy
 730
 731     spec_ok (DFunId _ new_type) _ = not new_type
 732          -- DFuns terminate, unless the dict is implemented with a newtype
 733          -- in which case they may not
 734
 735     spec_ok _ _ = False
 736
 737 -- | True of dyadic operators that can fail only if the second arg is zero!
 738 isDivOp :: PrimOp -> Bool
 739 -- This function probably belongs in PrimOp, or even in
 740 -- an automagically generated file.. but it's such a
 741 -- special case I thought I'd leave it here for now.
 742 isDivOp IntQuotOp        = True
 743 isDivOp IntRemOp         = True
 744 isDivOp WordQuotOp       = True
 745 isDivOp WordRemOp        = True
 746 isDivOp FloatDivOp       = True
 747 isDivOp DoubleDivOp      = True
 748 isDivOp _                = False
 749 \end{code}
 750
 751 Note [exprOkForSpeculation: case expressions]
 752 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 753 It's always sound for exprOkForSpeculation to return False, and we
 754 don't want it to take too long, so it bales out on complicated-looking
 755 terms.  Notably lets, which can be stacked very deeply; and in any
 756 case the argument of exprOkForSpeculation is usually in a strict context,
 757 so any lets will have been floated away.
 758
 759 However, we keep going on case-expressions.  An example like this one
 760 showed up in DPH code (Trac #3717):
 761     foo :: Int -> Int
 762     foo 0 = 0
 763     foo n = (if n < 5 then 1 else 2) `seq` foo (n-1)
 764
 765 If exprOkForSpeculation doesn't look through case expressions, you get this:
 766     T.$wfoo =
 767       \ (ww :: GHC.Prim.Int#) ->
 768         case ww of ds {
 769           __DEFAULT -> case (case <# ds 5 of _ {
 770                           GHC.Types.False -> lvl1;
 771                           GHC.Types.True -> lvl})
 772                        of _ { __DEFAULT ->
 773                        T.$wfoo (GHC.Prim.-# ds_XkE 1) };
 774           0 -> 0
 775         }
 776
 777 The inner case is redundant, and should be nuked.
 778
 779 Note [dataToTag speculation]
 780 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 781 Is this OK?
 782    f x = let v::Int# = dataToTag# x
 783          in ...
 784 We say "yes", even though 'x' may not be evaluated.  Reasons
 785
 786   * dataToTag#'s strictness means that its argument often will be
 787     evaluated, but FloatOut makes that temporarily untrue
 788          case x of y -> let v = dataToTag# y in ...
 789     -->
 790          case x of y -> let v = dataToTag# x in ...
 791     Note that we look at 'x' instead of 'y' (this is to improve
 792     floating in FloatOut).  So Lint complains.
 793
 794     Moreover, it really *might* improve floating to let the
 795     v-binding float out
 796
 797   * CorePrep makes sure dataToTag#'s argument is evaluated, just
 798     before code gen.  Until then, it's not guaranteed
 799
 800
 801 %************************************************************************
 802 %*                                                                      *
 803              exprIsHNF, exprIsConLike
 804 %*                                                                      *
 805 %************************************************************************
 806
 807 \begin{code}
 808 -- Note [exprIsHNF]             See also Note [exprIsCheap and exprIsHNF]
 809 -- ~~~~~~~~~~~~~~~~
 810 -- | exprIsHNF returns true for expressions that are certainly /already/
 811 -- evaluated to /head/ normal form.  This is used to decide whether it's ok
 812 -- to change:
 813 --
 814 -- > case x of _ -> e
 815 --
 816 --    into:
 817 --
 818 -- > e
 819 --
 820 -- and to decide whether it's safe to discard a 'seq'.
 821 --
 822 -- So, it does /not/ treat variables as evaluated, unless they say they are.
 823 -- However, it /does/ treat partial applications and constructor applications
 824 -- as values, even if their arguments are non-trivial, provided the argument
 825 -- type is lifted. For example, both of these are values:
 826 --
 827 -- > (:) (f x) (map f xs)
 828 -- > map (...redex...)
 829 --
 830 -- because 'seq' on such things completes immediately.
 831 --
 832 -- For unlifted argument types, we have to be careful:
 833 --
 834 -- > C (f x :: Int#)
 835 --
 836 -- Suppose @f x@ diverges; then @C (f x)@ is not a value. However this can't
 837 -- happen: see "CoreSyn#let_app_invariant". This invariant states that arguments of
 838 -- unboxed type must be ok-for-speculation (or trivial).
 839 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 840 exprIsHNF = exprIsHNFlike isDataConWorkId isEvaldUnfolding
 841 \end{code}
 842
 843 \begin{code}
 844 -- | Similar to 'exprIsHNF' but includes CONLIKE functions as well as
 845 -- data constructors. Conlike arguments are considered interesting by the
 846 -- inliner.
 847 exprIsConLike :: CoreExpr -> Bool       -- True => lambda, conlike, PAP
 848 exprIsConLike = exprIsHNFlike isConLikeId isConLikeUnfolding
 849
 850 -- | Returns true for values or value-like expressions. These are lambdas,
 851 -- constructors / CONLIKE functions (as determined by the function argument)
 852 -- or PAPs.
 853 --
 854 exprIsHNFlike :: (Var -> Bool) -> (Unfolding -> Bool) -> CoreExpr -> Bool
 855 exprIsHNFlike is_con is_con_unf = is_hnf_like
 856   where
 857     is_hnf_like (Var v) -- NB: There are no value args at this point
 858       =  is_con v       -- Catches nullary constructors,
 859                         --      so that [] and () are values, for example
 860       || idArity v > 0  -- Catches (e.g.) primops that don't have unfoldings
 861       || is_con_unf (idUnfolding v)
 862         -- Check the thing's unfolding; it might be bound to a value
 863         -- We don't look through loop breakers here, which is a bit conservative
 864         -- but otherwise I worry that if an Id's unfolding is just itself,
 865         -- we could get an infinite loop
 866
 867     is_hnf_like (Lit _)          = True
 868     is_hnf_like (Type _)        = True       -- Types are honorary Values;
 869                                               -- we don't mind copying them
 870     is_hnf_like (Coercion _)     = True       -- Same for coercions
 871     is_hnf_like (Lam b e)        = isRuntimeVar b || is_hnf_like e
 872     is_hnf_like (Note _ e)       = is_hnf_like e
 873     is_hnf_like (Cast e _)       = is_hnf_like e
 874     is_hnf_like (App e (Type _))    = is_hnf_like e
 875     is_hnf_like (App e (Coercion _)) = is_hnf_like e
 876     is_hnf_like (App e a)        = app_is_value e [a]
 877     is_hnf_like (Let _ e)        = is_hnf_like e  -- Lazy let(rec)s don't affect us
 878     is_hnf_like _                = False
 879
 880     -- There is at least one value argument
 881     app_is_value :: CoreExpr -> [CoreArg] -> Bool
 882     app_is_value (Var fun) args
 883       = idArity fun > valArgCount args    -- Under-applied function
 884         || is_con fun                     --  or constructor-like
 885     app_is_value (Note _ f) as = app_is_value f as
 886     app_is_value (Cast f _) as = app_is_value f as
 887     app_is_value (App f a)  as = app_is_value f (a:as)
 888     app_is_value _          _  = False
 889 \end{code}
 890
 891
 892 %************************************************************************
 893 %*                                                                      *
 894              Instantiating data constructors
 895 %*                                                                      *
 896 %************************************************************************
 897
 898 These InstPat functions go here to avoid circularity between DataCon and Id
 899
 900 \begin{code}
 901 dataConRepInstPat   ::                 [Unique] -> DataCon -> [Type] -> ([TyVar], [Id])
 902 dataConRepFSInstPat :: [FastString] -> [Unique] -> DataCon -> [Type] -> ([TyVar], [Id])
 903
 904 dataConRepInstPat   = dataConInstPat (repeat ((fsLit "ipv")))
 905 dataConRepFSInstPat = dataConInstPat
 906
 907 dataConInstPat :: [FastString]          -- A long enough list of FSs to use for names
 908                -> [Unique]              -- An equally long list of uniques, at least one for each binder
 909                -> DataCon
 910                -> [Type]                -- Types to instantiate the universally quantified tyvars
 911                -> ([TyVar], [Id])          -- Return instantiated variables
 912 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 913 -- (ex_tvs, arg_ids),
 914 --
 915 --   ex_tvs are intended to be used as binders for existential type args
 916 --
 917 --   arg_ids are indended to be used as binders for value arguments,
 918 --     and their types have been instantiated with inst_tys and ex_tys
 919 --     The arg_ids include both evidence and
 920 --     programmer-specified arguments (both after rep-ing)
 921 --
 922 -- Example.
 923 --  The following constructor T1
 924 --
 925 --  data T a where
 926 --    T1 :: forall b. Int -> b -> T(a,b)
 927 --    ...
 928 --
 929 --  has representation type
 930 --   forall a. forall a1. forall b. (a ~ (a1,b)) =>
 931 --     Int -> b -> T a
 932 --
 933 --  dataConInstPat fss us T1 (a1',b') will return
 934 --
 935 --  ([a1'', b''], [c :: (a1', b')~(a1'', b''), x :: Int, y :: b''])
 936 --
 937 --  where the double-primed variables are created with the FastStrings and
 938 --  Uniques given as fss and us
 939 dataConInstPat fss uniqs con inst_tys
 940   = (ex_bndrs, arg_ids)
 941   where
 942     univ_tvs = dataConUnivTyVars con
 943     ex_tvs   = dataConExTyVars con
 944     arg_tys  = dataConRepArgTys con
 945
 946     n_ex = length ex_tvs
 947
 948       -- split the Uniques and FastStrings
 949     (ex_uniqs, id_uniqs) = splitAt n_ex uniqs
 950     (ex_fss,   id_fss)   = splitAt n_ex fss
 951
 952       -- Make existential type variables
 953     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 954     mk_ex_var uniq fs var = mkTyVar new_name kind
 955       where
 956         new_name = mkSysTvName uniq fs
 957         kind     = tyVarKind var
 958
 959       -- Make the instantiating substitution
 960     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 961
 962       -- Make value vars, instantiating types
 963     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (Type.substTy subst ty) noSrcSpan
 964     arg_ids = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 965 \end{code}
 966
 967 %************************************************************************
 968 %*                                                                      *
 969          Equality
 970 %*                                                                      *
 971 %************************************************************************
 972
 973 \begin{code}
 974 -- | A cheap equality test which bales out fast!
 975 --      If it returns @True@ the arguments are definitely equal,
 976 --      otherwise, they may or may not be equal.
 977 --
 978 -- See also 'exprIsBig'
 979 cheapEqExpr :: Expr b -> Expr b -> Bool
 980
 981 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
 982 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
 983 cheapEqExpr (Type t1) (Type t2) = t1 `eqType` t2
 984 cheapEqExpr (Coercion c1) (Coercion c2) = c1 `coreEqCoercion` c2
 985
 986 cheapEqExpr (App f1 a1) (App f2 a2)
 987   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
 988
 989 cheapEqExpr (Cast e1 t1) (Cast e2 t2)
 990   = e1 `cheapEqExpr` e2 && t1 `coreEqCoercion` t2
 991
 992 cheapEqExpr _ _ = False
 993 \end{code}
 994
 995 \begin{code}
 996 exprIsBig :: Expr b -> Bool
 997 -- ^ Returns @True@ of expressions that are too big to be compared by 'cheapEqExpr'
 998 exprIsBig (Lit _)      = False
 999 exprIsBig (Var _)      = False
1000 exprIsBig (Type _)    = False
1001 exprIsBig (Coercion _) = False
1002 exprIsBig (Lam _ e)    = exprIsBig e
1003 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
1004 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
1005 exprIsBig _            = True
1006 \end{code}
1007
1008 \begin{code}
1009 eqExpr :: InScopeSet -> CoreExpr -> CoreExpr -> Bool
1010 -- Compares for equality, modulo alpha
1011 eqExpr in_scope e1 e2
1012   = eqExprX id_unf (mkRnEnv2 in_scope) e1 e2
1013   where
1014     id_unf _ = noUnfolding      -- Don't expand
1015 \end{code}
1016
1017 \begin{code}
1018 eqExprX :: IdUnfoldingFun -> RnEnv2 -> CoreExpr -> CoreExpr -> Bool
1019 -- ^ Compares expressions for equality, modulo alpha.
1020 -- Does /not/ look through newtypes or predicate types
1021 -- Used in rule matching, and also CSE
1022
1023 eqExprX id_unfolding_fun env e1 e2
1024   = go env e1 e2
1025   where
1026     go env (Var v1) (Var v2)
1027       | rnOccL env v1 == rnOccR env v2
1028       = True
1029
1030     -- The next two rules expand non-local variables
1031     -- C.f. Note [Expanding variables] in Rules.lhs
1032     -- and  Note [Do not expand locally-bound variables] in Rules.lhs
1033     go env (Var v1) e2
1034       | not (locallyBoundL env v1)
1035       , Just e1' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v1))
1036       = go (nukeRnEnvL env) e1' e2
1037
1038     go env e1 (Var v2)
1039       | not (locallyBoundR env v2)
1040       , Just e2' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v2))
1041       = go (nukeRnEnvR env) e1 e2'
1042
1043     go _   (Lit lit1)    (Lit lit2)      = lit1 == lit2
1044     go env (Type t1)    (Type t2)        = eqTypeX env t1 t2
1045     go env (Coercion co1) (Coercion co2) = coreEqCoercion2 env co1 co2
1046     go env (Cast e1 co1) (Cast e2 co2) = coreEqCoercion2 env co1 co2 && go env e1 e2
1047     go env (App f1 a1)   (App f2 a2)   = go env f1 f2 && go env a1 a2
1048     go env (Note n1 e1)  (Note n2 e2)  = go_note n1 n2 && go env e1 e2
1049
1050     go env (Lam b1 e1)  (Lam b2 e2)
1051       =  eqTypeX env (varType b1) (varType b2)   -- False for Id/TyVar combination
1052       && go (rnBndr2 env b1 b2) e1 e2
1053
1054     go env (Let (NonRec v1 r1) e1) (Let (NonRec v2 r2) e2)
1055       =  go env r1 r2  -- No need to check binder types, since RHSs match
1056       && go (rnBndr2 env v1 v2) e1 e2
1057
1058     go env (Let (Rec ps1) e1) (Let (Rec ps2) e2)
1059       = all2 (go env') rs1 rs2 && go env' e1 e2
1060       where
1061         (bs1,rs1) = unzip ps1
1062         (bs2,rs2) = unzip ps2
1063         env' = rnBndrs2 env bs1 bs2
1064
1065     go env (Case e1 b1 _ a1) (Case e2 b2 _ a2)
1066       =  go env e1 e2
1067       && eqTypeX env (idType b1) (idType b2)
1068       && all2 (go_alt (rnBndr2 env b1 b2)) a1 a2
1069
1070     go _ _ _ = False
1071
1072     -----------
1073     go_alt env (c1, bs1, e1) (c2, bs2, e2)
1074       = c1 == c2 && go (rnBndrs2 env bs1 bs2) e1 e2
1075
1076     -----------
1077     go_note (SCC cc1)     (SCC cc2)      = cc1 == cc2
1078     go_note (CoreNote s1) (CoreNote s2)  = s1 == s2
1079     go_note _             _              = False
1080 \end{code}
1081
1082 Auxiliary functions
1083
1084 \begin{code}
1085 locallyBoundL, locallyBoundR :: RnEnv2 -> Var -> Bool
1086 locallyBoundL rn_env v = inRnEnvL rn_env v
1087 locallyBoundR rn_env v = inRnEnvR rn_env v
1088 \end{code}
1089
1090
1091 %************************************************************************
1092 %*                                                                      *
1093 \subsection{The size of an expression}
1094 %*                                                                      *
1095 %************************************************************************
1096
1097 \begin{code}
1098 coreBindsSize :: [CoreBind] -> Int
1099 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
1100
1101 exprSize :: CoreExpr -> Int
1102 -- ^ A measure of the size of the expressions, strictly greater than 0
1103 -- It also forces the expression pretty drastically as a side effect
1104 -- Counts *leaves*, not internal nodes. Types and coercions are not counted.
1105 exprSize (Var v)         = v `seq` 1
1106 exprSize (Lit lit)       = lit `seq` 1
1107 exprSize (App f a)       = exprSize f + exprSize a
1108 exprSize (Lam b e)       = varSize b + exprSize e
1109 exprSize (Let b e)       = bindSize b + exprSize e
1110 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1111 exprSize (Cast e co)     = (seqCo co `seq` 1) + exprSize e
1112 exprSize (Note n e)      = noteSize n + exprSize e
1113 exprSize (Type t)       = seqType t `seq` 1
1114 exprSize (Coercion co)   = seqCo co `seq` 1
1115
1116 noteSize :: Note -> Int
1117 noteSize (SCC cc)       = cc `seq` 1
1118 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1119
1120 varSize :: Var -> Int
1121 varSize b  | isTyVar b = 1
1122            | otherwise = seqType (idType b)             `seq`
1123                          megaSeqIdInfo (idInfo b)       `seq`
1124                          1
1125
1126 varsSize :: [Var] -> Int
1127 varsSize = sum . map varSize
1128
1129 bindSize :: CoreBind -> Int
1130 bindSize (NonRec b e) = varSize b + exprSize e
1131 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1132
1133 pairSize :: (Var, CoreExpr) -> Int
1134 pairSize (b,e) = varSize b + exprSize e
1135
1136 altSize :: CoreAlt -> Int
1137 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1138 \end{code}
1139
1140 \begin{code}
1141 data CoreStats = CS { cs_tm, cs_ty, cs_co :: Int }
1142
1143 plusCS :: CoreStats -> CoreStats -> CoreStats
1144 plusCS (CS { cs_tm = p1, cs_ty = q1, cs_co = r1 })
1145        (CS { cs_tm = p2, cs_ty = q2, cs_co = r2 })
1146   = CS { cs_tm = p1+p2, cs_ty = q1+q2, cs_co = r1+r2 }
1147
1148 zeroCS, oneTM :: CoreStats
1149 zeroCS = CS { cs_tm = 0, cs_ty = 0, cs_co = 0 }
1150 oneTM  = zeroCS { cs_tm = 1 }
1151
1152 sumCS :: (a -> CoreStats) -> [a] -> CoreStats
1153 sumCS f = foldr (plusCS . f) zeroCS
1154
1155 coreBindsStats :: [CoreBind] -> CoreStats
1156 coreBindsStats = sumCS bindStats
1157
1158 bindStats :: CoreBind -> CoreStats
1159 bindStats (NonRec v r) = bindingStats v r
1160 bindStats (Rec prs)    = sumCS (\(v,r) -> bindingStats v r) prs
1161
1162 bindingStats :: Var -> CoreExpr -> CoreStats
1163 bindingStats v r = bndrStats v `plusCS` exprStats r
1164
1165 bndrStats :: Var -> CoreStats
1166 bndrStats v = oneTM `plusCS` tyStats (varType v)
1167
1168 exprStats :: CoreExpr -> CoreStats
1169 exprStats (Var {})        = oneTM
1170 exprStats (Lit {})        = oneTM
1171 exprStats (Type t)        = tyStats t
1172 exprStats (Coercion c)    = coStats c
1173 exprStats (App f a)       = exprStats f `plusCS` exprStats a
1174 exprStats (Lam b e)       = bndrStats b `plusCS` exprStats e
1175 exprStats (Let b e)       = bindStats b `plusCS` exprStats e
1176 exprStats (Case e b _ as) = exprStats e `plusCS` bndrStats b `plusCS` sumCS altStats as
1177 exprStats (Cast e co)     = coStats co `plusCS` exprStats e
1178 exprStats (Note _ e)      = exprStats e
1179
1180 altStats :: CoreAlt -> CoreStats
1181 altStats (_, bs, r) = sumCS bndrStats bs `plusCS` exprStats r
1182
1183 tyStats :: Type -> CoreStats
1184 tyStats ty = zeroCS { cs_ty = typeSize ty }
1185
1186 coStats :: Coercion -> CoreStats
1187 coStats co = zeroCS { cs_co = coercionSize co }
1188 \end{code}
1189
1190 %************************************************************************
1191 %*                                                                      *
1192 \subsection{Hashing}
1193 %*                                                                      *
1194 %************************************************************************
1195
1196 \begin{code}
1197 hashExpr :: CoreExpr -> Int
1198 -- ^ Two expressions that hash to the same @Int@ may be equal (but may not be)
1199 -- Two expressions that hash to the different Ints are definitely unequal.
1200 --
1201 -- The emphasis is on a crude, fast hash, rather than on high precision.
1202 --
1203 -- But unequal here means \"not identical\"; two alpha-equivalent
1204 -- expressions may hash to the different Ints.
1205 --
1206 -- We must be careful that @\\x.x@ and @\\y.y@ map to the same hash code,
1207 -- (at least if we want the above invariant to be true).
1208
1209 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
1210              -- UniqFM doesn't like negative Ints
1211
1212 type HashEnv = (Int, VarEnv Int)  -- Hash code for bound variables
1213
1214 hash_expr :: HashEnv -> CoreExpr -> Word32
1215 -- Word32, because we're expecting overflows here, and overflowing
1216 -- signed types just isn't cool.  In C it's even undefined.
1217 hash_expr env (Note _ e)              = hash_expr env e
1218 hash_expr env (Cast e _)              = hash_expr env e
1219 hash_expr env (Var v)                 = hashVar env v
1220 hash_expr _   (Lit lit)               = fromIntegral (hashLiteral lit)
1221 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
1222 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
1223 hash_expr env (Let (Rec ((b,_):_)) e) = hash_expr (extend_env env b) e
1224 hash_expr env (Case e _ _ _)          = hash_expr env e
1225 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
1226 hash_expr _   (Type _)                = WARN(True, text "hash_expr: type") 1
1227 -- Shouldn't happen.  Better to use WARN than trace, because trace
1228 -- prevents the CPR optimisation kicking in for hash_expr.
1229 hash_expr _   (Coercion _)            = WARN(True, text "hash_expr: coercion") 1
1230
1231 fast_hash_expr :: HashEnv -> CoreExpr -> Word32
1232 fast_hash_expr env (Var v)       = hashVar env v
1233 fast_hash_expr env (Type t)      = fast_hash_type env t
1234 fast_hash_expr env (Coercion co) = fast_hash_co env co
1235 fast_hash_expr _   (Lit lit)     = fromIntegral (hashLiteral lit)
1236 fast_hash_expr env (Cast e _)    = fast_hash_expr env e
1237 fast_hash_expr env (Note _ e)    = fast_hash_expr env e
1238 fast_hash_expr env (App _ a)     = fast_hash_expr env a -- A bit idiosyncratic ('a' not 'f')!
1239 fast_hash_expr _   _             = 1
1240
1241 fast_hash_type :: HashEnv -> Type -> Word32
1242 fast_hash_type env ty
1243   | Just tv <- getTyVar_maybe ty            = hashVar env tv
1244   | Just (tc,tys) <- splitTyConApp_maybe ty = let hash_tc = fromIntegral (hashName (tyConName tc))
1245                                               in foldr (\t n -> fast_hash_type env t + n) hash_tc tys
1246   | otherwise                               = 1
1247
1248 fast_hash_co :: HashEnv -> Coercion -> Word32
1249 fast_hash_co env co
1250   | Just cv <- getCoVar_maybe co              = hashVar env cv
1251   | Just (tc,cos) <- splitTyConAppCo_maybe co = let hash_tc = fromIntegral (hashName (tyConName tc))
1252                                                 in foldr (\c n -> fast_hash_co env c + n) hash_tc cos
1253   | otherwise                                 = 1
1254
1255 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1256 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1257
1258 hashVar :: HashEnv -> Var -> Word32
1259 hashVar (_,env) v
1260  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1261 \end{code}
1262
1263
1264 %************************************************************************
1265 %*                                                                      *
1266                 Eta reduction
1267 %*                                                                      *
1268 %************************************************************************
1269
1270 Note [Eta reduction conditions]
1271 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1272 We try for eta reduction here, but *only* if we get all the way to an
1273 trivial expression.  We don't want to remove extra lambdas unless we
1274 are going to avoid allocating this thing altogether.
1275
1276 There are some particularly delicate points here:
1277
1278 * Eta reduction is not valid in general:
1279         \x. bot  /=  bot
1280   This matters, partly for old-fashioned correctness reasons but,
1281   worse, getting it wrong can yield a seg fault. Consider
1282         f = \x.f x
1283         h y = case (case y of { True -> f `seq` True; False -> False }) of
1284                 True -> ...; False -> ...
1285
1286   If we (unsoundly) eta-reduce f to get f=f, the strictness analyser
1287   says f=bottom, and replaces the (f `seq` True) with just
1288   (f `cast` unsafe-co).  BUT, as thing stand, 'f' got arity 1, and it
1289   *keeps* arity 1 (perhaps also wrongly).  So CorePrep eta-expands
1290   the definition again, so that it does not termninate after all.
1291   Result: seg-fault because the boolean case actually gets a function value.
1292   See Trac #1947.
1293
1294   So it's important to to the right thing.
1295
1296 * Note [Arity care]: we need to be careful if we just look at f's
1297   arity. Currently (Dec07), f's arity is visible in its own RHS (see
1298   Note [Arity robustness] in SimplEnv) so we must *not* trust the
1299   arity when checking that 'f' is a value.  Otherwise we will
1300   eta-reduce
1301       f = \x. f x
1302   to
1303       f = f
1304   Which might change a terminiating program (think (f `seq` e)) to a
1305   non-terminating one.  So we check for being a loop breaker first.
1306
1307   However for GlobalIds we can look at the arity; and for primops we
1308   must, since they have no unfolding.
1309
1310 * Regardless of whether 'f' is a value, we always want to
1311   reduce (/\a -> f a) to f
1312   This came up in a RULE: foldr (build (/\a -> g a))
1313   did not match           foldr (build (/\b -> ...something complex...))
1314   The type checker can insert these eta-expanded versions,
1315   with both type and dictionary lambdas; hence the slightly
1316   ad-hoc isDictId
1317
1318 * Never *reduce* arity. For example
1319       f = \xy. g x y
1320   Then if h has arity 1 we don't want to eta-reduce because then
1321   f's arity would decrease, and that is bad
1322
1323 These delicacies are why we don't use exprIsTrivial and exprIsHNF here.
1324 Alas.
1325
1326 Note [Eta reduction with casted arguments]
1327 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1328 Consider
1329     (\(x:t3). f (x |> g)) :: t3 -> t2
1330   where
1331     f :: t1 -> t2
1332     g :: t3 ~ t1
1333 This should be eta-reduced to
1334
1335     f |> (sym g -> t2)
1336
1337 So we need to accumulate a coercion, pushing it inward (past
1338 variable arguments only) thus:
1339    f (x |> co_arg) |> co  -->  (f |> (sym co_arg -> co)) x
1340    f (x:t)         |> co  -->  (f |> (t -> co)) x
1341    f @ a           |> co  -->  (f |> (forall a.co)) @ a
1342    f @ (g:t1~t2)   |> co  -->  (f |> (t1~t2 => co)) @ (g:t1~t2)
1343 These are the equations for ok_arg.
1344
1345 It's true that we could also hope to eta reduce these:
1346     (\xy. (f x |> g) y)
1347     (\xy. (f x y) |> g)
1348 But the simplifier pushes those casts outwards, so we don't
1349 need to address that here.
1350
1351 \begin{code}
1352 tryEtaReduce :: [Var] -> CoreExpr -> Maybe CoreExpr
1353 tryEtaReduce bndrs body
1354   = go (reverse bndrs) body (mkReflCo (exprType body))
1355   where
1356     incoming_arity = count isId bndrs
1357
1358     go :: [Var]            -- Binders, innermost first, types [a3,a2,a1]
1359        -> CoreExpr         -- Of type tr
1360        -> Coercion         -- Of type tr ~ ts
1361        -> Maybe CoreExpr   -- Of type a1 -> a2 -> a3 -> ts
1362     -- See Note [Eta reduction with casted arguments]
1363     -- for why we have an accumulating coercion
1364     go [] fun co
1365       | ok_fun fun = Just (mkCoerce co fun)
1366
1367     go (b : bs) (App fun arg) co
1368       | Just co' <- ok_arg b arg co
1369       = go bs fun co'
1370
1371     go _ _ _  = Nothing         -- Failure!
1372
1373     ---------------
1374     -- Note [Eta reduction conditions]
1375     ok_fun (App fun (Type ty))
1376         | not (any (`elemVarSet` tyVarsOfType ty) bndrs)
1377         =  ok_fun fun
1378     ok_fun (Var fun_id)
1379         =  not (fun_id `elem` bndrs)
1380         && (ok_fun_id fun_id || all ok_lam bndrs)
1381     ok_fun _fun = False
1382
1383     ---------------
1384     ok_fun_id fun = fun_arity fun >= incoming_arity
1385
1386     ---------------
1387     fun_arity fun             -- See Note [Arity care]
1388        | isLocalId fun && isLoopBreaker (idOccInfo fun) = 0
1389        | otherwise = idArity fun
1390
1391     ---------------
1392     ok_lam v = isTyVar v || isEvVar v
1393
1394     ---------------
1395     ok_arg :: Var              -- Of type bndr_t
1396            -> CoreExpr         -- Of type arg_t
1397            -> Coercion         -- Of kind (t1~t2)
1398            -> Maybe Coercion   -- Of type (arg_t -> t1 ~  bndr_t -> t2)
1399                                --   (and similarly for tyvars, coercion args)
1400     -- See Note [Eta reduction with casted arguments]
1401     ok_arg bndr (Type ty) co
1402        | Just tv <- getTyVar_maybe ty
1403        , bndr == tv  = Just (mkForAllCo tv co)
1404     ok_arg bndr (Var v) co
1405        | bndr == v   = Just (mkFunCo (mkReflCo (idType bndr)) co)
1406     ok_arg bndr (Cast (Var v) co_arg) co
1407        | bndr == v  = Just (mkFunCo (mkSymCo co_arg) co)
1408        -- The simplifier combines multiple casts into one,
1409        -- so we can have a simple-minded pattern match here
1410     ok_arg _ _ _ = Nothing
1411 \end{code}
1412
1413
1414 %************************************************************************
1415 %*                                                                      *
1416 \subsection{Determining non-updatable right-hand-sides}
1417 %*                                                                      *
1418 %************************************************************************
1419
1420 Top-level constructor applications can usually be allocated
1421 statically, but they can't if the constructor, or any of the
1422 arguments, come from another DLL (because we can't refer to static
1423 labels in other DLLs).
1424
1425 If this happens we simply make the RHS into an updatable thunk,
1426 and 'execute' it rather than allocating it statically.
1427
1428 \begin{code}
1429 -- | This function is called only on *top-level* right-hand sides.
1430 -- Returns @True@ if the RHS can be allocated statically in the output,
1431 -- with no thunks involved at all.
1432 rhsIsStatic :: (Name -> Bool) -> CoreExpr -> Bool
1433 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1434 -- refers to, CAFs; (ii) in CoreToStg to decide whether to put an
1435 -- update flag on it and (iii) in DsExpr to decide how to expand
1436 -- list literals
1437 --
1438 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1439 --      (a) a value lambda
1440 --      (b) a saturated constructor application with static args
1441 --
1442 -- BUT watch out for
1443 --  (i) Any cross-DLL references kill static-ness completely
1444 --      because they must be 'executed' not statically allocated
1445 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1446 --      this is not necessary)
1447 --
1448 -- (ii) We treat partial applications as redexes, because in fact we
1449 --      make a thunk for them that runs and builds a PAP
1450 --      at run-time.  The only appliations that are treated as
1451 --      static are *saturated* applications of constructors.
1452
1453 -- We used to try to be clever with nested structures like this:
1454 --              ys = (:) w ((:) w [])
1455 -- on the grounds that CorePrep will flatten ANF-ise it later.
1456 -- But supporting this special case made the function much more
1457 -- complicated, because the special case only applies if there are no
1458 -- enclosing type lambdas:
1459 --              ys = /\ a -> Foo (Baz ([] a))
1460 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1461 --
1462 -- But in fact, even without -O, nested structures at top level are
1463 -- flattened by the simplifier, so we don't need to be super-clever here.
1464 --
1465 -- Examples
1466 --
1467 --      f = \x::Int. x+7        TRUE
1468 --      p = (True,False)        TRUE
1469 --
1470 --      d = (fst p, False)      FALSE because there's a redex inside
1471 --                              (this particular one doesn't happen but...)
1472 --
1473 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1474 --      n = /\a. Nil a                  TRUE
1475 --
1476 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1477 --
1478 --
1479 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1480 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1481 --
1482 --    b) (C x xs), where C is a contructor is updatable if the application is
1483 --         dynamic
1484 --
1485 --    c) don't look through unfolding of f in (f x).
1486
1487 rhsIsStatic _is_dynamic_name rhs = is_static False rhs
1488   where
1489   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1490           -> CoreExpr -> Bool
1491
1492   is_static False (Lam b e)   = isRuntimeVar b || is_static False e
1493   is_static in_arg (Note n e) = notSccNote n && is_static in_arg e
1494   is_static in_arg (Cast e _) = is_static in_arg e
1495
1496   is_static _      (Lit lit)
1497     = case lit of
1498         MachLabel _ _ _ -> False
1499         _             -> True
1500         -- A MachLabel (foreign import "&foo") in an argument
1501         -- prevents a constructor application from being static.  The
1502         -- reason is that it might give rise to unresolvable symbols
1503         -- in the object file: under Linux, references to "weak"
1504         -- symbols from the data segment give rise to "unresolvable
1505         -- relocation" errors at link time This might be due to a bug
1506         -- in the linker, but we'll work around it here anyway.
1507         -- SDM 24/2/2004
1508
1509   is_static in_arg other_expr = go other_expr 0
1510    where
1511     go (Var f) n_val_args
1512 #if mingw32_TARGET_OS
1513         | not (_is_dynamic_name (idName f))
1514 #endif
1515         =  saturated_data_con f n_val_args
1516         || (in_arg && n_val_args == 0)
1517                 -- A naked un-applied variable is *not* deemed a static RHS
1518                 -- E.g.         f = g
1519                 -- Reason: better to update so that the indirection gets shorted
1520                 --         out, and the true value will be seen
1521                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1522                 --     are always updatable.  If you do so, make sure that non-updatable
1523                 --     ones have enough space for their static link field!
1524
1525     go (App f a) n_val_args
1526         | isTypeArg a                    = go f n_val_args
1527         | not in_arg && is_static True a = go f (n_val_args + 1)
1528         -- The (not in_arg) checks that we aren't in a constructor argument;
1529         -- if we are, we don't allow (value) applications of any sort
1530         --
1531         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1532         --   x = D# (1.0## /## 2.0##)
1533         -- can't float because /## can fail.
1534
1535     go (Note n f) n_val_args = notSccNote n && go f n_val_args
1536     go (Cast e _) n_val_args = go e n_val_args
1537     go _          _          = False
1538
1539     saturated_data_con f n_val_args
1540         = case isDataConWorkId_maybe f of
1541             Just dc -> n_val_args == dataConRepArity dc
1542             Nothing -> False
1543 \end{code}