compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 -- | Commonly useful utilites for manipulating the Core language
  17 module CoreUtils (
  18         -- * Constructing expressions
  19         mkSCC, mkCoerce, mkCoerceI,
  20         bindNonRec, needsCaseBinding,
  21         mkAltExpr, mkPiType, mkPiTypes,
  22
  23         -- * Taking expressions apart
  24         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  25
  26         -- * Properties of expressions
  27         exprType, coreAltType, coreAltsType,
  28         exprIsDupable, exprIsTrivial, exprIsBottom,
  29         exprIsCheap, exprIsExpandable, exprIsCheap', CheapAppFun,
  30         exprIsHNF, exprOkForSpeculation, exprIsBig, exprIsConLike,
  31         rhsIsStatic, isCheapApp, isExpandableApp,
  32
  33         -- * Expression and bindings size
  34         coreBindsSize, exprSize,
  35         CoreStats(..), coreBindsStats,
  36
  37         -- * Hashing
  38         hashExpr,
  39
  40         -- * Equality
  41         cheapEqExpr, eqExpr, eqExprX,
  42
  43         -- * Eta reduction
  44         tryEtaReduce,
  45
  46         -- * Manipulating data constructors and types
  47         applyTypeToArgs, applyTypeToArg,
  48         dataConOrigInstPat, dataConRepInstPat, dataConRepFSInstPat
  49     ) where
  50
  51 #include "HsVersions.h"
  52
  53 import CoreSyn
  54 import PprCore
  55 import Var
  56 import SrcLoc
  57 import VarEnv
  58 import VarSet
  59 import Name
  60 import Literal
  61 import DataCon
  62 import PrimOp
  63 import Id
  64 import IdInfo
  65 import TcType   ( isPredTy )
  66 import Type
  67 import Coercion
  68 import TyCon
  69 import CostCentre
  70 import Unique
  71 import Outputable
  72 import TysPrim
  73 import FastString
  74 import Maybes
  75 import Util
  76 import Data.Word
  77 import Data.Bits
  78 \end{code}
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83 \subsection{Find the type of a Core atom/expression}
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 exprType :: CoreExpr -> Type
  89 -- ^ Recover the type of a well-typed Core expression. Fails when
  90 -- applied to the actual 'CoreSyn.Type' expression as it cannot
  91 -- really be said to have a type
  92 exprType (Var var)           = idType var
  93 exprType (Lit lit)           = literalType lit
  94 exprType (Let _ body)        = exprType body
  95 exprType (Case _ _ ty _)     = ty
  96 exprType (Cast _ co)         = snd (coercionKind co)
  97 exprType (Note _ e)          = exprType e
  98 exprType (Lam binder expr)   = mkPiType binder (exprType expr)
  99 exprType e@(App _ _)
 100   = case collectArgs e of
 101         (fun, args) -> applyTypeToArgs e (exprType fun) args
 102
 103 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 104
 105 coreAltType :: CoreAlt -> Type
 106 -- ^ Returns the type of the alternatives right hand side
 107 coreAltType (_,bs,rhs)
 108   | any bad_binder bs = expandTypeSynonyms ty
 109   | otherwise         = ty    -- Note [Existential variables and silly type synonyms]
 110   where
 111     ty           = exprType rhs
 112     free_tvs     = tyVarsOfType ty
 113     bad_binder b = isTyCoVar b && b `elemVarSet` free_tvs
 114
 115 coreAltsType :: [CoreAlt] -> Type
 116 -- ^ Returns the type of the first alternative, which should be the same as for all alternatives
 117 coreAltsType (alt:_) = coreAltType alt
 118 coreAltsType []      = panic "corAltsType"
 119 \end{code}
 120
 121 Note [Existential variables and silly type synonyms]
 122 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 123 Consider
 124         data T = forall a. T (Funny a)
 125         type Funny a = Bool
 126         f :: T -> Bool
 127         f (T x) = x
 128
 129 Now, the type of 'x' is (Funny a), where 'a' is existentially quantified.
 130 That means that 'exprType' and 'coreAltsType' may give a result that *appears*
 131 to mention an out-of-scope type variable.  See Trac #3409 for a more real-world
 132 example.
 133
 134 Various possibilities suggest themselves:
 135
 136  - Ignore the problem, and make Lint not complain about such variables
 137
 138  - Expand all type synonyms (or at least all those that discard arguments)
 139       This is tricky, because at least for top-level things we want to
 140       retain the type the user originally specified.
 141
 142  - Expand synonyms on the fly, when the problem arises. That is what
 143    we are doing here.  It's not too expensive, I think.
 144
 145 \begin{code}
 146 mkPiType  :: EvVar -> Type -> Type
 147 -- ^ Makes a @(->)@ type or a forall type, depending
 148 -- on whether it is given a type variable or a term variable.
 149 mkPiTypes :: [EvVar] -> Type -> Type
 150 -- ^ 'mkPiType' for multiple type or value arguments
 151
 152 mkPiType v ty
 153    | isId v    = mkFunTy (idType v) ty
 154    | otherwise = mkForAllTy v ty
 155
 156 mkPiTypes vs ty = foldr mkPiType ty vs
 157 \end{code}
 158
 159 \begin{code}
 160 applyTypeToArg :: Type -> CoreExpr -> Type
 161 -- ^ Determines the type resulting from applying an expression to a function with the given type
 162 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 163 applyTypeToArg fun_ty _             = funResultTy fun_ty
 164
 165 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 166 -- ^ A more efficient version of 'applyTypeToArg' when we have several arguments.
 167 -- The first argument is just for debugging, and gives some context
 168 applyTypeToArgs _ op_ty [] = op_ty
 169
 170 applyTypeToArgs e op_ty (Type ty : args)
 171   =     -- Accumulate type arguments so we can instantiate all at once
 172     go [ty] args
 173   where
 174     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 175     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 176                                 where
 177                                   op_ty' = applyTysD msg op_ty (reverse rev_tys)
 178                                   msg = ptext (sLit "applyTypeToArgs") <+>
 179                                         panic_msg e op_ty
 180
 181 applyTypeToArgs e op_ty (_ : args)
 182   = case (splitFunTy_maybe op_ty) of
 183         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 184         Nothing -> pprPanic "applyTypeToArgs" (panic_msg e op_ty)
 185
 186 panic_msg :: CoreExpr -> Type -> SDoc
 187 panic_msg e op_ty = pprCoreExpr e $$ ppr op_ty
 188 \end{code}
 189
 190 %************************************************************************
 191 %*                                                                      *
 192 \subsection{Attaching notes}
 193 %*                                                                      *
 194 %************************************************************************
 195
 196 \begin{code}
 197 -- | Wrap the given expression in the coercion, dropping identity coercions and coalescing nested coercions
 198 mkCoerceI :: CoercionI -> CoreExpr -> CoreExpr
 199 mkCoerceI (IdCo _) e = e
 200 mkCoerceI (ACo co) e = mkCoerce co e
 201
 202 -- | Wrap the given expression in the coercion safely, coalescing nested coercions
 203 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 204 mkCoerce co (Cast expr co2)
 205   = ASSERT(let { (from_ty, _to_ty) = coercionKind co;
 206                  (_from_ty2, to_ty2) = coercionKind co2} in
 207            from_ty `coreEqType` to_ty2 )
 208     mkCoerce (mkTransCoercion co2 co) expr
 209
 210 mkCoerce co expr
 211   = let (from_ty, _to_ty) = coercionKind co in
 212 --    if to_ty `coreEqType` from_ty
 213 --    then expr
 214 --    else
 215         WARN(not (from_ty `coreEqType` exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ pprEqPred (coercionKind co))
 216          (Cast expr co)
 217 \end{code}
 218
 219 \begin{code}
 220 -- | Wraps the given expression in the cost centre unless
 221 -- in a way that maximises their utility to the user
 222 mkSCC :: CostCentre -> Expr b -> Expr b
 223         -- Note: Nested SCC's *are* preserved for the benefit of
 224         --       cost centre stack profiling
 225 mkSCC _  (Lit lit)          = Lit lit
 226 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 227 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 228 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 229 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 230 mkSCC cc expr               = Note (SCC cc) expr
 231 \end{code}
 232
 233
 234 %************************************************************************
 235 %*                                                                      *
 236 \subsection{Other expression construction}
 237 %*                                                                      *
 238 %************************************************************************
 239
 240 \begin{code}
 241 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 242 -- ^ @bindNonRec x r b@ produces either:
 243 --
 244 -- > let x = r in b
 245 --
 246 -- or:
 247 --
 248 -- > case r of x { _DEFAULT_ -> b }
 249 --
 250 -- depending on whether we have to use a @case@ or @let@
 251 -- binding for the expression (see 'needsCaseBinding').
 252 -- It's used by the desugarer to avoid building bindings
 253 -- that give Core Lint a heart attack, although actually
 254 -- the simplifier deals with them perfectly well. See
 255 -- also 'MkCore.mkCoreLet'
 256 bindNonRec bndr rhs body
 257   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT, [], body)]
 258   | otherwise                          = Let (NonRec bndr rhs) body
 259
 260 -- | Tests whether we have to use a @case@ rather than @let@ binding for this expression
 261 -- as per the invariants of 'CoreExpr': see "CoreSyn#let_app_invariant"
 262 needsCaseBinding :: Type -> CoreExpr -> Bool
 263 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 264         -- Make a case expression instead of a let
 265         -- These can arise either from the desugarer,
 266         -- or from beta reductions: (\x.e) (x +# y)
 267 \end{code}
 268
 269 \begin{code}
 270 mkAltExpr :: AltCon     -- ^ Case alternative constructor
 271           -> [CoreBndr] -- ^ Things bound by the pattern match
 272           -> [Type]     -- ^ The type arguments to the case alternative
 273           -> CoreExpr
 274 -- ^ This guy constructs the value that the scrutinee must have
 275 -- given that you are in one particular branch of a case
 276 mkAltExpr (DataAlt con) args inst_tys
 277   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 278 mkAltExpr (LitAlt lit) [] []
 279   = Lit lit
 280 mkAltExpr (LitAlt _) _ _ = panic "mkAltExpr LitAlt"
 281 mkAltExpr DEFAULT _ _ = panic "mkAltExpr DEFAULT"
 282 \end{code}
 283
 284
 285 %************************************************************************
 286 %*                                                                      *
 287 \subsection{Taking expressions apart}
 288 %*                                                                      *
 289 %************************************************************************
 290
 291 The default alternative must be first, if it exists at all.
 292 This makes it easy to find, though it makes matching marginally harder.
 293
 294 \begin{code}
 295 -- | Extract the default case alternative
 296 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 297 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 298 findDefault alts                        =                     (alts, Nothing)
 299
 300 isDefaultAlt :: CoreAlt -> Bool
 301 isDefaultAlt (DEFAULT, _, _) = True
 302 isDefaultAlt _               = False
 303
 304
 305 -- | Find the case alternative corresponding to a particular
 306 -- constructor: panics if no such constructor exists
 307 findAlt :: AltCon -> [CoreAlt] -> Maybe CoreAlt
 308     -- A "Nothing" result *is* legitmiate
 309     -- See Note [Unreachable code]
 310 findAlt con alts
 311   = case alts of
 312         (deflt@(DEFAULT,_,_):alts) -> go alts (Just deflt)
 313         _                          -> go alts Nothing
 314   where
 315     go []                     deflt = deflt
 316     go (alt@(con1,_,_) : alts) deflt
 317       = case con `cmpAltCon` con1 of
 318           LT -> deflt   -- Missed it already; the alts are in increasing order
 319           EQ -> Just alt
 320           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 321
 322 ---------------------------------
 323 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 324 -- ^ Merge alternatives preserving order; alternatives in
 325 -- the first argument shadow ones in the second
 326 mergeAlts [] as2 = as2
 327 mergeAlts as1 [] = as1
 328 mergeAlts (a1:as1) (a2:as2)
 329   = case a1 `cmpAlt` a2 of
 330         LT -> a1 : mergeAlts as1      (a2:as2)
 331         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 332         GT -> a2 : mergeAlts (a1:as1) as2
 333
 334
 335 ---------------------------------
 336 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 337 -- ^ Given:
 338 --
 339 -- > case (C a b x y) of
 340 -- >        C b x y -> ...
 341 --
 342 -- We want to drop the leading type argument of the scrutinee
 343 -- leaving the arguments to match agains the pattern
 344
 345 trimConArgs DEFAULT      args = ASSERT( null args ) []
 346 trimConArgs (LitAlt _)   args = ASSERT( null args ) []
 347 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 348 \end{code}
 349
 350 Note [Unreachable code]
 351 ~~~~~~~~~~~~~~~~~~~~~~~
 352 It is possible (although unusual) for GHC to find a case expression
 353 that cannot match.  For example:
 354
 355      data Col = Red | Green | Blue
 356      x = Red
 357      f v = case x of
 358               Red -> ...
 359               _ -> ...(case x of { Green -> e1; Blue -> e2 })...
 360
 361 Suppose that for some silly reason, x isn't substituted in the case
 362 expression.  (Perhaps there's a NOINLINE on it, or profiling SCC stuff
 363 gets in the way; cf Trac #3118.)  Then the full-lazines pass might produce
 364 this
 365
 366      x = Red
 367      lvl = case x of { Green -> e1; Blue -> e2 })
 368      f v = case x of
 369              Red -> ...
 370              _ -> ...lvl...
 371
 372 Now if x gets inlined, we won't be able to find a matching alternative
 373 for 'Red'.  That's because 'lvl' is unreachable.  So rather than crashing
 374 we generate (error "Inaccessible alternative").
 375
 376 Similar things can happen (augmented by GADTs) when the Simplifier
 377 filters down the matching alternatives in Simplify.rebuildCase.
 378
 379
 380 %************************************************************************
 381 %*                                                                      *
 382              exprIsTrivial
 383 %*                                                                      *
 384 %************************************************************************
 385
 386 Note [exprIsTrivial]
 387 ~~~~~~~~~~~~~~~~~~~~
 388 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 389                 duplicate; simple variables and constants, and type
 390                 applications.  Note that primop Ids aren't considered
 391                 trivial unless
 392
 393 Note [Variable are trivial]
 394 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 395 There used to be a gruesome test for (hasNoBinding v) in the
 396 Var case:
 397         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 398 The idea here is that a constructor worker, like \$wJust, is
 399 really short for (\x -> \$wJust x), becuase \$wJust has no binding.
 400 So it should be treated like a lambda.  Ditto unsaturated primops.
 401 But now constructor workers are not "have-no-binding" Ids.  And
 402 completely un-applied primops and foreign-call Ids are sufficiently
 403 rare that I plan to allow them to be duplicated and put up with
 404 saturating them.
 405
 406 Note [SCCs are trivial]
 407 ~~~~~~~~~~~~~~~~~~~~~~~
 408 We used not to treat (_scc_ "foo" x) as trivial, because it really
 409 generates code, (and a heap object when it's a function arg) to
 410 capture the cost centre.  However, the profiling system discounts the
 411 allocation costs for such "boxing thunks" whereas the extra costs of
 412 *not* inlining otherwise-trivial bindings can be high, and are hard to
 413 discount.
 414
 415 \begin{code}
 416 exprIsTrivial :: CoreExpr -> Bool
 417 exprIsTrivial (Var _)          = True        -- See Note [Variables are trivial]
 418 exprIsTrivial (Type _)         = True
 419 exprIsTrivial (Lit lit)        = litIsTrivial lit
 420 exprIsTrivial (App e arg)      = not (isRuntimeArg arg) && exprIsTrivial e
 421 exprIsTrivial (Note _       e) = exprIsTrivial e  -- See Note [SCCs are trivial]
 422 exprIsTrivial (Cast e _)       = exprIsTrivial e
 423 exprIsTrivial (Lam b body)     = not (isRuntimeVar b) && exprIsTrivial body
 424 exprIsTrivial _                = False
 425 \end{code}
 426
 427 exprIsBottom is a very cheap and cheerful function; it may return
 428 False for bottoming expressions, but it never costs much to ask.
 429 See also CoreArity.exprBotStrictness_maybe, but that's a bit more
 430 expensive.
 431
 432 \begin{code}
 433 exprIsBottom :: CoreExpr -> Bool
 434 exprIsBottom e
 435   = go 0 e
 436   where
 437     go n (Var v) = isBottomingId v &&  n >= idArity v
 438     go n (App e a) | isTypeArg a = go n e
 439                    | otherwise   = go (n+1) e
 440     go n (Note _ e)              = go n e
 441     go n (Cast e _)              = go n e
 442     go n (Let _ e)               = go n e
 443     go _ _                       = False
 444 \end{code}
 445
 446
 447 %************************************************************************
 448 %*                                                                      *
 449              exprIsDupable
 450 %*                                                                      *
 451 %************************************************************************
 452
 453 Note [exprIsDupable]
 454 ~~~~~~~~~~~~~~~~~~~~
 455 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 456                 cost in code size.  This will only happen in different case
 457                 branches, so there's no issue about duplicating work.
 458
 459                 That is, exprIsDupable returns True of (f x) even if
 460                 f is very very expensive to call.
 461
 462                 Its only purpose is to avoid fruitless let-binding
 463                 and then inlining of case join points
 464
 465
 466 \begin{code}
 467 exprIsDupable :: CoreExpr -> Bool
 468 exprIsDupable e
 469   = isJust (go dupAppSize e)
 470   where
 471     go :: Int -> CoreExpr -> Maybe Int
 472     go n (Type {}) = Just n
 473     go n (Var {})  = decrement n
 474     go n (Note _ e) = go n e
 475     go n (Cast e _) = go n e
 476     go n (App f a) | Just n' <- go n a = go n' f
 477     go n (Lit lit) | litIsDupable lit = decrement n
 478     go _ _ = Nothing
 479
 480     decrement :: Int -> Maybe Int
 481     decrement 0 = Nothing
 482     decrement n = Just (n-1)
 483
 484 dupAppSize :: Int
 485 dupAppSize = 8   -- Size of term we are prepared to duplicate
 486                  -- This is *just* big enough to make test MethSharing
 487                  -- inline enough join points.  Really it should be
 488                  -- smaller, and could be if we fixed Trac #4960.
 489 \end{code}
 490
 491 %************************************************************************
 492 %*                                                                      *
 493              exprIsCheap, exprIsExpandable
 494 %*                                                                      *
 495 %************************************************************************
 496
 497 Note [exprIsCheap]   See also Note [Interaction of exprIsCheap and lone variables]
 498 ~~~~~~~~~~~~~~~~~~   in CoreUnfold.lhs
 499 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 500 it is obviously in weak head normal form, or is cheap to get to WHNF.
 501 [Note that that's not the same as exprIsDupable; an expression might be
 502 big, and hence not dupable, but still cheap.]
 503
 504 By ``cheap'' we mean a computation we're willing to:
 505         push inside a lambda, or
 506         inline at more than one place
 507 That might mean it gets evaluated more than once, instead of being
 508 shared.  The main examples of things which aren't WHNF but are
 509 ``cheap'' are:
 510
 511   *     case e of
 512           pi -> ei
 513         (where e, and all the ei are cheap)
 514
 515   *     let x = e in b
 516         (where e and b are cheap)
 517
 518   *     op x1 ... xn
 519         (where op is a cheap primitive operator)
 520
 521   *     error "foo"
 522         (because we are happy to substitute it inside a lambda)
 523
 524 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 525 because sharing will make sure it is only evaluated once.
 526
 527 Note [exprIsCheap and exprIsHNF]
 528 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 529 Note that exprIsHNF does not imply exprIsCheap.  Eg
 530         let x = fac 20 in Just x
 531 This responds True to exprIsHNF (you can discard a seq), but
 532 False to exprIsCheap.
 533
 534 \begin{code}
 535 exprIsCheap :: CoreExpr -> Bool
 536 exprIsCheap = exprIsCheap' isCheapApp
 537
 538 exprIsExpandable :: CoreExpr -> Bool
 539 exprIsExpandable = exprIsCheap' isExpandableApp -- See Note [CONLIKE pragma] in BasicTypes
 540
 541 type CheapAppFun = Id -> Int -> Bool
 542 exprIsCheap' :: CheapAppFun -> CoreExpr -> Bool
 543 exprIsCheap' _          (Lit _)   = True
 544 exprIsCheap' _          (Type _)  = True
 545 exprIsCheap' _          (Var _)   = True
 546 exprIsCheap' good_app (Note _ e)  = exprIsCheap' good_app e
 547 exprIsCheap' good_app (Cast e _)  = exprIsCheap' good_app e
 548 exprIsCheap' good_app (Lam x e)   = isRuntimeVar x
 549                                  || exprIsCheap' good_app e
 550
 551 exprIsCheap' good_app (Case e _ _ alts) = exprIsCheap' good_app e &&
 552                                           and [exprIsCheap' good_app rhs | (_,_,rhs) <- alts]
 553         -- Experimentally, treat (case x of ...) as cheap
 554         -- (and case __coerce x etc.)
 555         -- This improves arities of overloaded functions where
 556         -- there is only dictionary selection (no construction) involved
 557
 558 exprIsCheap' good_app (Let (NonRec x _) e)
 559   | isUnLiftedType (idType x) = exprIsCheap' good_app e
 560   | otherwise                 = False
 561         -- Strict lets always have cheap right hand sides,
 562         -- and do no allocation, so just look at the body
 563         -- Non-strict lets do allocation so we don't treat them as cheap
 564         -- See also
 565
 566 exprIsCheap' good_app other_expr        -- Applications and variables
 567   = go other_expr []
 568   where
 569         -- Accumulate value arguments, then decide
 570     go (Cast e _) val_args                 = go e val_args
 571     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 572                           | otherwise      = go f val_args
 573
 574     go (Var _) [] = True        -- Just a type application of a variable
 575                                 -- (f t1 t2 t3) counts as WHNF
 576     go (Var f) args
 577         = case idDetails f of
 578                 RecSelId {}                  -> go_sel args
 579                 ClassOpId {}                 -> go_sel args
 580                 PrimOpId op                  -> go_primop op args
 581                 _ | good_app f (length args) -> go_pap args
 582                   | isBottomingId f          -> True
 583                   | otherwise                -> False
 584                         -- Application of a function which
 585                         -- always gives bottom; we treat this as cheap
 586                         -- because it certainly doesn't need to be shared!
 587
 588     go _ _ = False
 589
 590     --------------
 591     go_pap args = all exprIsTrivial args
 592         -- For constructor applications and primops, check that all
 593         -- the args are trivial.  We don't want to treat as cheap, say,
 594         --      (1:2:3:4:5:[])
 595         -- We'll put up with one constructor application, but not dozens
 596
 597     --------------
 598     go_primop op args = primOpIsCheap op && all (exprIsCheap' good_app) args
 599         -- In principle we should worry about primops
 600         -- that return a type variable, since the result
 601         -- might be applied to something, but I'm not going
 602         -- to bother to check the number of args
 603
 604     --------------
 605     go_sel [arg] = exprIsCheap' good_app arg    -- I'm experimenting with making record selection
 606     go_sel _     = False                -- look cheap, so we will substitute it inside a
 607                                         -- lambda.  Particularly for dictionary field selection.
 608                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 609                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 610
 611 isCheapApp :: CheapAppFun
 612 isCheapApp fn n_val_args
 613   = isDataConWorkId fn
 614   || n_val_args < idArity fn
 615
 616 isExpandableApp :: CheapAppFun
 617 isExpandableApp fn n_val_args
 618   =  isConLikeId fn
 619   || n_val_args < idArity fn
 620   || go n_val_args (idType fn)
 621   where
 622   -- See if all the arguments are PredTys (implicit params or classes)
 623   -- If so we'll regard it as expandable; see Note [Expandable overloadings]
 624      go 0 _ = True
 625      go n_val_args ty
 626        | Just (_, ty) <- splitForAllTy_maybe ty   = go n_val_args ty
 627        | Just (arg, ty) <- splitFunTy_maybe ty
 628        , isPredTy arg                             = go (n_val_args-1) ty
 629        | otherwise                                = False
 630 \end{code}
 631
 632 Note [Expandable overloadings]
 633 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 634 Suppose the user wrote this
 635    {-# RULE  forall x. foo (negate x) = h x #-}
 636    f x = ....(foo (negate x))....
 637 He'd expect the rule to fire. But since negate is overloaded, we might
 638 get this:
 639     f = \d -> let n = negate d in \x -> ...foo (n x)...
 640 So we treat the application of a function (negate in this case) to a
 641 *dictionary* as expandable.  In effect, every function is CONLIKE when
 642 it's applied only to dictionaries.
 643
 644
 645 %************************************************************************
 646 %*                                                                      *
 647              exprOkForSpeculation
 648 %*                                                                      *
 649 %************************************************************************
 650
 651 \begin{code}
 652 -- | 'exprOkForSpeculation' returns True of an expression that is:
 653 --
 654 --  * Safe to evaluate even if normal order eval might not
 655 --    evaluate the expression at all, or
 656 --
 657 --  * Safe /not/ to evaluate even if normal order would do so
 658 --
 659 -- It is usually called on arguments of unlifted type, but not always
 660 -- In particular, Simplify.rebuildCase calls it on lifted types
 661 -- when a 'case' is a plain 'seq'. See the example in
 662 -- Note [exprOkForSpeculation: case expressions] below
 663 --
 664 -- Precisely, it returns @True@ iff:
 665 --
 666 --  * The expression guarantees to terminate,
 667 --  * soon,
 668 --  * without raising an exception,
 669 --  * without causing a side effect (e.g. writing a mutable variable)
 670 --
 671 -- Note that if @exprIsHNF e@, then @exprOkForSpecuation e@.
 672 -- As an example of the considerations in this test, consider:
 673 --
 674 -- > let x = case y# +# 1# of { r# -> I# r# }
 675 -- > in E
 676 --
 677 -- being translated to:
 678 --
 679 -- > case y# +# 1# of { r# ->
 680 -- >    let x = I# r#
 681 -- >    in E
 682 -- > }
 683 --
 684 -- We can only do this if the @y + 1@ is ok for speculation: it has no
 685 -- side effects, and can't diverge or raise an exception.
 686 exprOkForSpeculation :: CoreExpr -> Bool
 687 exprOkForSpeculation (Lit _)     = True
 688 exprOkForSpeculation (Type _)    = True
 689
 690 exprOkForSpeculation (Var v)
 691   | isTickBoxOp v = False     -- Tick boxes are *not* suitable for speculation
 692   | otherwise     =  isUnLiftedType (idType v)  -- c.f. the Var case of exprIsHNF
 693                   || isDataConWorkId v          -- Nullary constructors
 694                   || idArity v > 0              -- Functions
 695                   || isEvaldUnfolding (idUnfolding v)   -- Let-bound values
 696
 697 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 698 exprOkForSpeculation (Cast e _)  = exprOkForSpeculation e
 699
 700 exprOkForSpeculation (Case e _ _ alts)
 701   =  exprOkForSpeculation e  -- Note [exprOkForSpeculation: case expressions]
 702   && all (\(_,_,rhs) -> exprOkForSpeculation rhs) alts
 703
 704 exprOkForSpeculation other_expr
 705   = case collectArgs other_expr of
 706         (Var f, args) -> spec_ok (idDetails f) args
 707         _             -> False
 708
 709   where
 710     spec_ok (DataConWorkId _) _
 711       = True    -- The strictness of the constructor has already
 712                 -- been expressed by its "wrapper", so we don't need
 713                 -- to take the arguments into account
 714
 715     spec_ok (PrimOpId op) args
 716       | isDivOp op,             -- Special case for dividing operations that fail
 717         [arg1, Lit lit] <- args -- only if the divisor is zero
 718       = not (isZeroLit lit) && exprOkForSpeculation arg1
 719                 -- Often there is a literal divisor, and this
 720                 -- can get rid of a thunk in an inner looop
 721
 722       | DataToTagOp <- op      -- See Note [dataToTag speculation]
 723       = True
 724
 725       | otherwise
 726       = primOpOkForSpeculation op &&
 727         all exprOkForSpeculation args
 728                                 -- A bit conservative: we don't really need
 729                                 -- to care about lazy arguments, but this is easy
 730
 731     spec_ok (DFunId _ new_type) _ = not new_type
 732          -- DFuns terminate, unless the dict is implemented with a newtype
 733          -- in which case they may not
 734
 735     spec_ok _ _ = False
 736
 737 -- | True of dyadic operators that can fail only if the second arg is zero!
 738 isDivOp :: PrimOp -> Bool
 739 -- This function probably belongs in PrimOp, or even in
 740 -- an automagically generated file.. but it's such a
 741 -- special case I thought I'd leave it here for now.
 742 isDivOp IntQuotOp        = True
 743 isDivOp IntRemOp         = True
 744 isDivOp WordQuotOp       = True
 745 isDivOp WordRemOp        = True
 746 isDivOp FloatDivOp       = True
 747 isDivOp DoubleDivOp      = True
 748 isDivOp _                = False
 749 \end{code}
 750
 751 Note [exprOkForSpeculation: case expressions]
 752 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 753 It's always sound for exprOkForSpeculation to return False, and we
 754 don't want it to take too long, so it bales out on complicated-looking
 755 terms.  Notably lets, which can be stacked very deeply; and in any
 756 case the argument of exprOkForSpeculation is usually in a strict context,
 757 so any lets will have been floated away.
 758
 759 However, we keep going on case-expressions.  An example like this one
 760 showed up in DPH code (Trac #3717):
 761     foo :: Int -> Int
 762     foo 0 = 0
 763     foo n = (if n < 5 then 1 else 2) `seq` foo (n-1)
 764
 765 If exprOkForSpeculation doesn't look through case expressions, you get this:
 766     T.$wfoo =
 767       \ (ww :: GHC.Prim.Int#) ->
 768         case ww of ds {
 769           __DEFAULT -> case (case <# ds 5 of _ {
 770                           GHC.Types.False -> lvl1;
 771                           GHC.Types.True -> lvl})
 772                        of _ { __DEFAULT ->
 773                        T.$wfoo (GHC.Prim.-# ds_XkE 1) };
 774           0 -> 0
 775         }
 776
 777 The inner case is redundant, and should be nuked.
 778
 779 Note [dataToTag speculation]
 780 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 781 Is this OK?
 782    f x = let v::Int# = dataToTag# x
 783          in ...
 784 We say "yes", even though 'x' may not be evaluated.  Reasons
 785
 786   * dataToTag#'s strictness means that its argument often will be
 787     evaluated, but FloatOut makes that temporarily untrue
 788          case x of y -> let v = dataToTag# y in ...
 789     -->
 790          case x of y -> let v = dataToTag# x in ...
 791     Note that we look at 'x' instead of 'y' (this is to improve
 792     floating in FloatOut).  So Lint complains.
 793
 794     Moreover, it really *might* improve floating to let the
 795     v-binding float out
 796
 797   * CorePrep makes sure dataToTag#'s argument is evaluated, just
 798     before code gen.  Until then, it's not guaranteed
 799
 800
 801 %************************************************************************
 802 %*                                                                      *
 803              exprIsHNF, exprIsConLike
 804 %*                                                                      *
 805 %************************************************************************
 806
 807 \begin{code}
 808 -- Note [exprIsHNF]             See also Note [exprIsCheap and exprIsHNF]
 809 -- ~~~~~~~~~~~~~~~~
 810 -- | exprIsHNF returns true for expressions that are certainly /already/
 811 -- evaluated to /head/ normal form.  This is used to decide whether it's ok
 812 -- to change:
 813 --
 814 -- > case x of _ -> e
 815 --
 816 --    into:
 817 --
 818 -- > e
 819 --
 820 -- and to decide whether it's safe to discard a 'seq'.
 821 --
 822 -- So, it does /not/ treat variables as evaluated, unless they say they are.
 823 -- However, it /does/ treat partial applications and constructor applications
 824 -- as values, even if their arguments are non-trivial, provided the argument
 825 -- type is lifted. For example, both of these are values:
 826 --
 827 -- > (:) (f x) (map f xs)
 828 -- > map (...redex...)
 829 --
 830 -- because 'seq' on such things completes immediately.
 831 --
 832 -- For unlifted argument types, we have to be careful:
 833 --
 834 -- > C (f x :: Int#)
 835 --
 836 -- Suppose @f x@ diverges; then @C (f x)@ is not a value. However this can't
 837 -- happen: see "CoreSyn#let_app_invariant". This invariant states that arguments of
 838 -- unboxed type must be ok-for-speculation (or trivial).
 839 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 840 exprIsHNF = exprIsHNFlike isDataConWorkId isEvaldUnfolding
 841 \end{code}
 842
 843 \begin{code}
 844 -- | Similar to 'exprIsHNF' but includes CONLIKE functions as well as
 845 -- data constructors. Conlike arguments are considered interesting by the
 846 -- inliner.
 847 exprIsConLike :: CoreExpr -> Bool       -- True => lambda, conlike, PAP
 848 exprIsConLike = exprIsHNFlike isConLikeId isConLikeUnfolding
 849
 850 -- | Returns true for values or value-like expressions. These are lambdas,
 851 -- constructors / CONLIKE functions (as determined by the function argument)
 852 -- or PAPs.
 853 --
 854 exprIsHNFlike :: (Var -> Bool) -> (Unfolding -> Bool) -> CoreExpr -> Bool
 855 exprIsHNFlike is_con is_con_unf = is_hnf_like
 856   where
 857     is_hnf_like (Var v) -- NB: There are no value args at this point
 858       =  is_con v       -- Catches nullary constructors,
 859                         --      so that [] and () are values, for example
 860       || idArity v > 0  -- Catches (e.g.) primops that don't have unfoldings
 861       || is_con_unf (idUnfolding v)
 862         -- Check the thing's unfolding; it might be bound to a value
 863         -- We don't look through loop breakers here, which is a bit conservative
 864         -- but otherwise I worry that if an Id's unfolding is just itself,
 865         -- we could get an infinite loop
 866
 867     is_hnf_like (Lit _)          = True
 868     is_hnf_like (Type _)         = True       -- Types are honorary Values;
 869                                               -- we don't mind copying them
 870     is_hnf_like (Lam b e)        = isRuntimeVar b || is_hnf_like e
 871     is_hnf_like (Note _ e)       = is_hnf_like e
 872     is_hnf_like (Cast e _)       = is_hnf_like e
 873     is_hnf_like (App e (Type _)) = is_hnf_like e
 874     is_hnf_like (App e a)        = app_is_value e [a]
 875     is_hnf_like (Let _ e)        = is_hnf_like e  -- Lazy let(rec)s don't affect us
 876     is_hnf_like _                = False
 877
 878     -- There is at least one value argument
 879     app_is_value :: CoreExpr -> [CoreArg] -> Bool
 880     app_is_value (Var fun) args
 881       = idArity fun > valArgCount args    -- Under-applied function
 882         || is_con fun                     --  or constructor-like
 883     app_is_value (Note _ f) as = app_is_value f as
 884     app_is_value (Cast f _) as = app_is_value f as
 885     app_is_value (App f a)  as = app_is_value f (a:as)
 886     app_is_value _          _  = False
 887 \end{code}
 888
 889
 890 %************************************************************************
 891 %*                                                                      *
 892              Instantiating data constructors
 893 %*                                                                      *
 894 %************************************************************************
 895
 896 These InstPat functions go here to avoid circularity between DataCon and Id
 897
 898 \begin{code}
 899 dataConRepInstPat, dataConOrigInstPat :: [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 900 dataConRepFSInstPat :: [FastString] -> [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 901
 902 dataConRepInstPat   = dataConInstPat dataConRepArgTys (repeat ((fsLit "ipv")))
 903 dataConRepFSInstPat = dataConInstPat dataConRepArgTys
 904 dataConOrigInstPat  = dataConInstPat dc_arg_tys       (repeat ((fsLit "ipv")))
 905   where
 906     dc_arg_tys dc = map mkPredTy (dataConEqTheta dc) ++ map mkPredTy (dataConDictTheta dc) ++ dataConOrigArgTys dc
 907         -- Remember to include the existential dictionaries
 908
 909 dataConInstPat :: (DataCon -> [Type])      -- function used to find arg tys
 910                   -> [FastString]          -- A long enough list of FSs to use for names
 911                   -> [Unique]              -- An equally long list of uniques, at least one for each binder
 912                   -> DataCon
 913                   -> [Type]                -- Types to instantiate the universally quantified tyvars
 914                -> ([TyVar], [CoVar], [Id]) -- Return instantiated variables
 915 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 916 -- (ex_tvs, co_tvs, arg_ids),
 917 --
 918 --   ex_tvs are intended to be used as binders for existential type args
 919 --
 920 --   co_tvs are intended to be used as binders for coercion args and the kinds
 921 --     of these vars have been instantiated by the inst_tys and the ex_tys
 922 --     The co_tvs include both GADT equalities (dcEqSpec) and
 923 --     programmer-specified equalities (dcEqTheta)
 924 --
 925 --   arg_ids are indended to be used as binders for value arguments,
 926 --     and their types have been instantiated with inst_tys and ex_tys
 927 --     The arg_ids include both dicts (dcDictTheta) and
 928 --     programmer-specified arguments (after rep-ing) (deRepArgTys)
 929 --
 930 -- Example.
 931 --  The following constructor T1
 932 --
 933 --  data T a where
 934 --    T1 :: forall b. Int -> b -> T(a,b)
 935 --    ...
 936 --
 937 --  has representation type
 938 --   forall a. forall a1. forall b. (a ~ (a1,b)) =>
 939 --     Int -> b -> T a
 940 --
 941 --  dataConInstPat fss us T1 (a1',b') will return
 942 --
 943 --  ([a1'', b''], [c :: (a1', b')~(a1'', b'')], [x :: Int, y :: b''])
 944 --
 945 --  where the double-primed variables are created with the FastStrings and
 946 --  Uniques given as fss and us
 947 dataConInstPat arg_fun fss uniqs con inst_tys
 948   = (ex_bndrs, co_bndrs, arg_ids)
 949   where
 950     univ_tvs = dataConUnivTyVars con
 951     ex_tvs   = dataConExTyVars con
 952     arg_tys  = arg_fun con
 953     eq_spec  = dataConEqSpec con
 954     eq_theta = dataConEqTheta con
 955     eq_preds = eqSpecPreds eq_spec ++ eq_theta
 956
 957     n_ex = length ex_tvs
 958     n_co = length eq_preds
 959
 960       -- split the Uniques and FastStrings
 961     (ex_uniqs, uniqs')   = splitAt n_ex uniqs
 962     (co_uniqs, id_uniqs) = splitAt n_co uniqs'
 963
 964     (ex_fss, fss')     = splitAt n_ex fss
 965     (co_fss, id_fss)   = splitAt n_co fss'
 966
 967       -- Make existential type variables
 968     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 969     mk_ex_var uniq fs var = mkTyVar new_name kind
 970       where
 971         new_name = mkSysTvName uniq fs
 972         kind     = tyVarKind var
 973
 974       -- Make the instantiating substitution
 975     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 976
 977       -- Make new coercion vars, instantiating kind
 978     co_bndrs = zipWith3 mk_co_var co_uniqs co_fss eq_preds
 979     mk_co_var uniq fs eq_pred = mkCoVar new_name co_kind
 980        where
 981          new_name = mkSysTvName uniq fs
 982          co_kind  = substTy subst (mkPredTy eq_pred)
 983
 984       -- make value vars, instantiating types
 985     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (substTy subst ty) noSrcSpan
 986     arg_ids = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 987
 988 \end{code}
 989
 990 %************************************************************************
 991 %*                                                                      *
 992          Equality
 993 %*                                                                      *
 994 %************************************************************************
 995
 996 \begin{code}
 997 -- | A cheap equality test which bales out fast!
 998 --      If it returns @True@ the arguments are definitely equal,
 999 --      otherwise, they may or may not be equal.
1000 --
1001 -- See also 'exprIsBig'
1002 cheapEqExpr :: Expr b -> Expr b -> Bool
1003
1004 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
1005 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
1006 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
1007
1008 cheapEqExpr (App f1 a1) (App f2 a2)
1009   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
1010
1011 cheapEqExpr (Cast e1 t1) (Cast e2 t2)
1012   = e1 `cheapEqExpr` e2 && t1 `coreEqCoercion` t2
1013
1014 cheapEqExpr _ _ = False
1015 \end{code}
1016
1017 \begin{code}
1018 exprIsBig :: Expr b -> Bool
1019 -- ^ Returns @True@ of expressions that are too big to be compared by 'cheapEqExpr'
1020 exprIsBig (Lit _)      = False
1021 exprIsBig (Var _)      = False
1022 exprIsBig (Type _)     = False
1023 exprIsBig (Lam _ e)    = exprIsBig e
1024 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
1025 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
1026 exprIsBig _            = True
1027 \end{code}
1028
1029 \begin{code}
1030 eqExpr :: InScopeSet -> CoreExpr -> CoreExpr -> Bool
1031 -- Compares for equality, modulo alpha
1032 eqExpr in_scope e1 e2
1033   = eqExprX id_unf (mkRnEnv2 in_scope) e1 e2
1034   where
1035     id_unf _ = noUnfolding      -- Don't expand
1036 \end{code}
1037
1038 \begin{code}
1039 eqExprX :: IdUnfoldingFun -> RnEnv2 -> CoreExpr -> CoreExpr -> Bool
1040 -- ^ Compares expressions for equality, modulo alpha.
1041 -- Does /not/ look through newtypes or predicate types
1042 -- Used in rule matching, and also CSE
1043
1044 eqExprX id_unfolding_fun env e1 e2
1045   = go env e1 e2
1046   where
1047     go env (Var v1) (Var v2)
1048       | rnOccL env v1 == rnOccR env v2
1049       = True
1050
1051     -- The next two rules expand non-local variables
1052     -- C.f. Note [Expanding variables] in Rules.lhs
1053     -- and  Note [Do not expand locally-bound variables] in Rules.lhs
1054     go env (Var v1) e2
1055       | not (locallyBoundL env v1)
1056       , Just e1' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v1))
1057       = go (nukeRnEnvL env) e1' e2
1058
1059     go env e1 (Var v2)
1060       | not (locallyBoundR env v2)
1061       , Just e2' <- expandUnfolding_maybe (id_unfolding_fun (lookupRnInScope env v2))
1062       = go (nukeRnEnvR env) e1 e2'
1063
1064     go _   (Lit lit1)    (Lit lit2)    = lit1 == lit2
1065     go env (Type t1)     (Type t2)     = tcEqTypeX env t1 t2
1066     go env (Cast e1 co1) (Cast e2 co2) = tcEqTypeX env co1 co2 && go env e1 e2
1067     go env (App f1 a1)   (App f2 a2)   = go env f1 f2 && go env a1 a2
1068     go env (Note n1 e1)  (Note n2 e2)  = go_note n1 n2 && go env e1 e2
1069
1070     go env (Lam b1 e1)  (Lam b2 e2)
1071       =  tcEqTypeX env (varType b1) (varType b2)   -- False for Id/TyVar combination
1072       && go (rnBndr2 env b1 b2) e1 e2
1073
1074     go env (Let (NonRec v1 r1) e1) (Let (NonRec v2 r2) e2)
1075       =  go env r1 r2  -- No need to check binder types, since RHSs match
1076       && go (rnBndr2 env v1 v2) e1 e2
1077
1078     go env (Let (Rec ps1) e1) (Let (Rec ps2) e2)
1079       = all2 (go env') rs1 rs2 && go env' e1 e2
1080       where
1081         (bs1,rs1) = unzip ps1
1082         (bs2,rs2) = unzip ps2
1083         env' = rnBndrs2 env bs1 bs2
1084
1085     go env (Case e1 b1 _ a1) (Case e2 b2 _ a2)
1086       =  go env e1 e2
1087       && tcEqTypeX env (idType b1) (idType b2)
1088       && all2 (go_alt (rnBndr2 env b1 b2)) a1 a2
1089
1090     go _ _ _ = False
1091
1092     -----------
1093     go_alt env (c1, bs1, e1) (c2, bs2, e2)
1094       = c1 == c2 && go (rnBndrs2 env bs1 bs2) e1 e2
1095
1096     -----------
1097     go_note (SCC cc1)     (SCC cc2)      = cc1 == cc2
1098     go_note (CoreNote s1) (CoreNote s2)  = s1 == s2
1099     go_note _             _              = False
1100 \end{code}
1101
1102 Auxiliary functions
1103
1104 \begin{code}
1105 locallyBoundL, locallyBoundR :: RnEnv2 -> Var -> Bool
1106 locallyBoundL rn_env v = inRnEnvL rn_env v
1107 locallyBoundR rn_env v = inRnEnvR rn_env v
1108 \end{code}
1109
1110
1111 %************************************************************************
1112 %*                                                                      *
1113 \subsection{The size of an expression}
1114 %*                                                                      *
1115 %************************************************************************
1116
1117 \begin{code}
1118 coreBindsSize :: [CoreBind] -> Int
1119 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
1120
1121 exprSize :: CoreExpr -> Int
1122 -- ^ A measure of the size of the expressions, strictly greater than 0
1123 -- It also forces the expression pretty drastically as a side effect
1124 -- Counts *leaves*, not internal nodes. Types and coercions are not counted.
1125 exprSize (Var v)         = v `seq` 1
1126 exprSize (Lit lit)       = lit `seq` 1
1127 exprSize (App f a)       = exprSize f + exprSize a
1128 exprSize (Lam b e)       = varSize b + exprSize e
1129 exprSize (Let b e)       = bindSize b + exprSize e
1130 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
1131 exprSize (Cast e co)     = (seqType co `seq` 1) + exprSize e
1132 exprSize (Note n e)      = noteSize n + exprSize e
1133 exprSize (Type t)        = seqType t `seq` 1
1134
1135 noteSize :: Note -> Int
1136 noteSize (SCC cc)       = cc `seq` 1
1137 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
1138
1139 varSize :: Var -> Int
1140 varSize b  | isTyCoVar b = 1
1141            | otherwise = seqType (idType b)             `seq`
1142                          megaSeqIdInfo (idInfo b)       `seq`
1143                          1
1144
1145 varsSize :: [Var] -> Int
1146 varsSize = sum . map varSize
1147
1148 bindSize :: CoreBind -> Int
1149 bindSize (NonRec b e) = varSize b + exprSize e
1150 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
1151
1152 pairSize :: (Var, CoreExpr) -> Int
1153 pairSize (b,e) = varSize b + exprSize e
1154
1155 altSize :: CoreAlt -> Int
1156 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
1157 \end{code}
1158
1159 \begin{code}
1160 data CoreStats = CS { cs_tm, cs_ty, cs_co :: Int }
1161
1162 plusCS :: CoreStats -> CoreStats -> CoreStats
1163 plusCS (CS { cs_tm = p1, cs_ty = q1, cs_co = r1 })
1164        (CS { cs_tm = p2, cs_ty = q2, cs_co = r2 })
1165   = CS { cs_tm = p1+p2, cs_ty = q1+q2, cs_co = r1+r2 }
1166
1167 zeroCS, oneTM :: CoreStats
1168 zeroCS = CS { cs_tm = 0, cs_ty = 0, cs_co = 0 }
1169 oneTM  = zeroCS { cs_tm = 1 }
1170
1171 sumCS :: (a -> CoreStats) -> [a] -> CoreStats
1172 sumCS f = foldr (plusCS . f) zeroCS
1173
1174 coreBindsStats :: [CoreBind] -> CoreStats
1175 coreBindsStats = sumCS bindStats
1176
1177 bindStats :: CoreBind -> CoreStats
1178 bindStats (NonRec v r) = bindingStats v r
1179 bindStats (Rec prs)    = sumCS (\(v,r) -> bindingStats v r) prs
1180
1181 bindingStats :: Var -> CoreExpr -> CoreStats
1182 bindingStats v r = bndrStats v `plusCS` exprStats r
1183
1184 bndrStats :: Var -> CoreStats
1185 bndrStats v = oneTM `plusCS` tyStats (varType v)
1186
1187 exprStats :: CoreExpr -> CoreStats
1188 exprStats (Var {})        = oneTM
1189 exprStats (Lit {})        = oneTM
1190 exprStats (App f (Type t))= tyCoStats (exprType f) t
1191 exprStats (App f a)       = exprStats f `plusCS` exprStats a
1192 exprStats (Lam b e)       = bndrStats b `plusCS` exprStats e
1193 exprStats (Let b e)       = bindStats b `plusCS` exprStats e
1194 exprStats (Case e b _ as) = exprStats e `plusCS` bndrStats b `plusCS` sumCS altStats as
1195 exprStats (Cast e co)     = coStats co `plusCS` exprStats e
1196 exprStats (Note _ e)      = exprStats e
1197 exprStats (Type ty)       = zeroCS { cs_ty = typeSize ty }
1198           -- Ugh (might be a co)
1199
1200 altStats :: CoreAlt -> CoreStats
1201 altStats (_, bs, r) = sumCS bndrStats bs `plusCS` exprStats r
1202
1203 tyCoStats :: Type -> Type -> CoreStats
1204 tyCoStats fun_ty arg
1205   = case splitForAllTy_maybe fun_ty of
1206       Just (tv,_) | isCoVar tv -> coStats arg
1207       _                        -> tyStats arg
1208
1209 tyStats :: Type -> CoreStats
1210 tyStats ty = zeroCS { cs_ty = typeSize ty }
1211
1212 coStats :: Coercion -> CoreStats
1213 coStats co = zeroCS { cs_co = typeSize co }
1214 \end{code}
1215
1216 %************************************************************************
1217 %*                                                                      *
1218 \subsection{Hashing}
1219 %*                                                                      *
1220 %************************************************************************
1221
1222 \begin{code}
1223 hashExpr :: CoreExpr -> Int
1224 -- ^ Two expressions that hash to the same @Int@ may be equal (but may not be)
1225 -- Two expressions that hash to the different Ints are definitely unequal.
1226 --
1227 -- The emphasis is on a crude, fast hash, rather than on high precision.
1228 --
1229 -- But unequal here means \"not identical\"; two alpha-equivalent
1230 -- expressions may hash to the different Ints.
1231 --
1232 -- We must be careful that @\\x.x@ and @\\y.y@ map to the same hash code,
1233 -- (at least if we want the above invariant to be true).
1234
1235 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
1236              -- UniqFM doesn't like negative Ints
1237
1238 type HashEnv = (Int, VarEnv Int)  -- Hash code for bound variables
1239
1240 hash_expr :: HashEnv -> CoreExpr -> Word32
1241 -- Word32, because we're expecting overflows here, and overflowing
1242 -- signed types just isn't cool.  In C it's even undefined.
1243 hash_expr env (Note _ e)              = hash_expr env e
1244 hash_expr env (Cast e _)              = hash_expr env e
1245 hash_expr env (Var v)                 = hashVar env v
1246 hash_expr _   (Lit lit)               = fromIntegral (hashLiteral lit)
1247 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
1248 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
1249 hash_expr env (Let (Rec ((b,_):_)) e) = hash_expr (extend_env env b) e
1250 hash_expr env (Case e _ _ _)          = hash_expr env e
1251 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
1252 hash_expr _   (Type _)                = WARN(True, text "hash_expr: type") 1
1253 -- Shouldn't happen.  Better to use WARN than trace, because trace
1254 -- prevents the CPR optimisation kicking in for hash_expr.
1255
1256 fast_hash_expr :: HashEnv -> CoreExpr -> Word32
1257 fast_hash_expr env (Var v)      = hashVar env v
1258 fast_hash_expr env (Type t)     = fast_hash_type env t
1259 fast_hash_expr _   (Lit lit)    = fromIntegral (hashLiteral lit)
1260 fast_hash_expr env (Cast e _)   = fast_hash_expr env e
1261 fast_hash_expr env (Note _ e)   = fast_hash_expr env e
1262 fast_hash_expr env (App _ a)    = fast_hash_expr env a  -- A bit idiosyncratic ('a' not 'f')!
1263 fast_hash_expr _   _            = 1
1264
1265 fast_hash_type :: HashEnv -> Type -> Word32
1266 fast_hash_type env ty
1267   | Just tv <- getTyVar_maybe ty            = hashVar env tv
1268   | Just (tc,tys) <- splitTyConApp_maybe ty = let hash_tc = fromIntegral (hashName (tyConName tc))
1269                                               in foldr (\t n -> fast_hash_type env t + n) hash_tc tys
1270   | otherwise                               = 1
1271
1272 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1273 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1274
1275 hashVar :: HashEnv -> Var -> Word32
1276 hashVar (_,env) v
1277  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1278 \end{code}
1279
1280
1281 %************************************************************************
1282 %*                                                                      *
1283                 Eta reduction
1284 %*                                                                      *
1285 %************************************************************************
1286
1287 Note [Eta reduction conditions]
1288 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1289 We try for eta reduction here, but *only* if we get all the way to an
1290 trivial expression.  We don't want to remove extra lambdas unless we
1291 are going to avoid allocating this thing altogether.
1292
1293 There are some particularly delicate points here:
1294
1295 * Eta reduction is not valid in general:
1296         \x. bot  /=  bot
1297   This matters, partly for old-fashioned correctness reasons but,
1298   worse, getting it wrong can yield a seg fault. Consider
1299         f = \x.f x
1300         h y = case (case y of { True -> f `seq` True; False -> False }) of
1301                 True -> ...; False -> ...
1302
1303   If we (unsoundly) eta-reduce f to get f=f, the strictness analyser
1304   says f=bottom, and replaces the (f `seq` True) with just
1305   (f `cast` unsafe-co).  BUT, as thing stand, 'f' got arity 1, and it
1306   *keeps* arity 1 (perhaps also wrongly).  So CorePrep eta-expands
1307   the definition again, so that it does not termninate after all.
1308   Result: seg-fault because the boolean case actually gets a function value.
1309   See Trac #1947.
1310
1311   So it's important to to the right thing.
1312
1313 * Note [Arity care]: we need to be careful if we just look at f's
1314   arity. Currently (Dec07), f's arity is visible in its own RHS (see
1315   Note [Arity robustness] in SimplEnv) so we must *not* trust the
1316   arity when checking that 'f' is a value.  Otherwise we will
1317   eta-reduce
1318       f = \x. f x
1319   to
1320       f = f
1321   Which might change a terminiating program (think (f `seq` e)) to a
1322   non-terminating one.  So we check for being a loop breaker first.
1323
1324   However for GlobalIds we can look at the arity; and for primops we
1325   must, since they have no unfolding.
1326
1327 * Regardless of whether 'f' is a value, we always want to
1328   reduce (/\a -> f a) to f
1329   This came up in a RULE: foldr (build (/\a -> g a))
1330   did not match           foldr (build (/\b -> ...something complex...))
1331   The type checker can insert these eta-expanded versions,
1332   with both type and dictionary lambdas; hence the slightly
1333   ad-hoc isDictId
1334
1335 * Never *reduce* arity. For example
1336       f = \xy. g x y
1337   Then if h has arity 1 we don't want to eta-reduce because then
1338   f's arity would decrease, and that is bad
1339
1340 These delicacies are why we don't use exprIsTrivial and exprIsHNF here.
1341 Alas.
1342
1343 Note [Eta reduction with casted arguments]
1344 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1345 Consider
1346     (\(x:t3). f (x |> g)) :: t3 -> t2
1347   where
1348     f :: t1 -> t2
1349     g :: t3 ~ t1
1350 This should be eta-reduced to
1351
1352     f |> (sym g -> t2)
1353
1354 So we need to accumulate a coercion, pushing it inward (past
1355 variable arguments only) thus:
1356    f (x |> co_arg) |> co  -->  (f |> (sym co_arg -> co)) x
1357    f (x:t)         |> co  -->  (f |> (t -> co)) x
1358    f @ a           |> co  -->  (f |> (forall a.co)) @ a
1359    f @ (g:t1~t2)   |> co  -->  (f |> (t1~t2 => co)) @ (g:t1~t2)
1360 These are the equations for ok_arg.
1361
1362 It's true that we could also hope to eta reduce these:
1363     (\xy. (f x |> g) y)
1364     (\xy. (f x y) |> g)
1365 But the simplifier pushes those casts outwards, so we don't
1366 need to address that here.
1367
1368 \begin{code}
1369 tryEtaReduce :: [Var] -> CoreExpr -> Maybe CoreExpr
1370 tryEtaReduce bndrs body
1371   = go (reverse bndrs) body (IdCo (exprType body))
1372   where
1373     incoming_arity = count isId bndrs
1374
1375     go :: [Var]            -- Binders, innermost first, types [a3,a2,a1]
1376        -> CoreExpr         -- Of type tr
1377        -> CoercionI        -- Of type tr ~ ts
1378        -> Maybe CoreExpr   -- Of type a1 -> a2 -> a3 -> ts
1379     -- See Note [Eta reduction with casted arguments]
1380     -- for why we have an accumulating coercion
1381     go [] fun co
1382       | ok_fun fun = Just (mkCoerceI co fun)
1383
1384     go (b : bs) (App fun arg) co
1385       | Just co' <- ok_arg b arg co
1386       = go bs fun co'
1387
1388     go _ _ _  = Nothing         -- Failure!
1389
1390     ---------------
1391     -- Note [Eta reduction conditions]
1392     ok_fun (App fun (Type ty))
1393         | not (any (`elemVarSet` tyVarsOfType ty) bndrs)
1394         =  ok_fun fun
1395     ok_fun (Var fun_id)
1396         =  not (fun_id `elem` bndrs)
1397         && (ok_fun_id fun_id || all ok_lam bndrs)
1398     ok_fun _fun = False
1399
1400     ---------------
1401     ok_fun_id fun = fun_arity fun >= incoming_arity
1402
1403     ---------------
1404     fun_arity fun             -- See Note [Arity care]
1405        | isLocalId fun && isLoopBreaker (idOccInfo fun) = 0
1406        | otherwise = idArity fun
1407
1408     ---------------
1409     ok_lam v = isTyCoVar v || isDictId v
1410
1411     ---------------
1412     ok_arg :: Var               -- Of type bndr_t
1413            -> CoreExpr          -- Of type arg_t
1414            -> CoercionI         -- Of kind (t1~t2)
1415            -> Maybe CoercionI   -- Of type (arg_t -> t1 ~  bndr_t -> t2)
1416                                 --   (and similarly for tyvars, coercion args)
1417     -- See Note [Eta reduction with casted arguments]
1418     ok_arg bndr (Type ty) co
1419        | Just tv <- getTyVar_maybe ty
1420        , bndr == tv  = Just (mkForAllTyCoI tv co)
1421     ok_arg bndr (Var v) co
1422        | bndr == v   = Just (mkFunTyCoI (IdCo (idType bndr)) co)
1423     ok_arg bndr (Cast (Var v) co_arg) co
1424        | bndr == v  = Just (mkFunTyCoI (ACo (mkSymCoercion co_arg)) co)
1425        -- The simplifier combines multiple casts into one,
1426        -- so we can have a simple-minded pattern match here
1427     ok_arg _ _ _ = Nothing
1428 \end{code}
1429
1430
1431 %************************************************************************
1432 %*                                                                      *
1433 \subsection{Determining non-updatable right-hand-sides}
1434 %*                                                                      *
1435 %************************************************************************
1436
1437 Top-level constructor applications can usually be allocated
1438 statically, but they can't if the constructor, or any of the
1439 arguments, come from another DLL (because we can't refer to static
1440 labels in other DLLs).
1441
1442 If this happens we simply make the RHS into an updatable thunk,
1443 and 'execute' it rather than allocating it statically.
1444
1445 \begin{code}
1446 -- | This function is called only on *top-level* right-hand sides.
1447 -- Returns @True@ if the RHS can be allocated statically in the output,
1448 -- with no thunks involved at all.
1449 rhsIsStatic :: (Name -> Bool) -> CoreExpr -> Bool
1450 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1451 -- refers to, CAFs; (ii) in CoreToStg to decide whether to put an
1452 -- update flag on it and (iii) in DsExpr to decide how to expand
1453 -- list literals
1454 --
1455 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1456 --      (a) a value lambda
1457 --      (b) a saturated constructor application with static args
1458 --
1459 -- BUT watch out for
1460 --  (i) Any cross-DLL references kill static-ness completely
1461 --      because they must be 'executed' not statically allocated
1462 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1463 --      this is not necessary)
1464 --
1465 -- (ii) We treat partial applications as redexes, because in fact we
1466 --      make a thunk for them that runs and builds a PAP
1467 --      at run-time.  The only appliations that are treated as
1468 --      static are *saturated* applications of constructors.
1469
1470 -- We used to try to be clever with nested structures like this:
1471 --              ys = (:) w ((:) w [])
1472 -- on the grounds that CorePrep will flatten ANF-ise it later.
1473 -- But supporting this special case made the function much more
1474 -- complicated, because the special case only applies if there are no
1475 -- enclosing type lambdas:
1476 --              ys = /\ a -> Foo (Baz ([] a))
1477 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1478 --
1479 -- But in fact, even without -O, nested structures at top level are
1480 -- flattened by the simplifier, so we don't need to be super-clever here.
1481 --
1482 -- Examples
1483 --
1484 --      f = \x::Int. x+7        TRUE
1485 --      p = (True,False)        TRUE
1486 --
1487 --      d = (fst p, False)      FALSE because there's a redex inside
1488 --                              (this particular one doesn't happen but...)
1489 --
1490 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1491 --      n = /\a. Nil a                  TRUE
1492 --
1493 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1494 --
1495 --
1496 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1497 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1498 --
1499 --    b) (C x xs), where C is a contructor is updatable if the application is
1500 --         dynamic
1501 --
1502 --    c) don't look through unfolding of f in (f x).
1503
1504 rhsIsStatic _is_dynamic_name rhs = is_static False rhs
1505   where
1506   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1507           -> CoreExpr -> Bool
1508
1509   is_static False (Lam b e)   = isRuntimeVar b || is_static False e
1510   is_static in_arg (Note n e) = notSccNote n && is_static in_arg e
1511   is_static in_arg (Cast e _) = is_static in_arg e
1512
1513   is_static _      (Lit lit)
1514     = case lit of
1515         MachLabel _ _ _ -> False
1516         _             -> True
1517         -- A MachLabel (foreign import "&foo") in an argument
1518         -- prevents a constructor application from being static.  The
1519         -- reason is that it might give rise to unresolvable symbols
1520         -- in the object file: under Linux, references to "weak"
1521         -- symbols from the data segment give rise to "unresolvable
1522         -- relocation" errors at link time This might be due to a bug
1523         -- in the linker, but we'll work around it here anyway.
1524         -- SDM 24/2/2004
1525
1526   is_static in_arg other_expr = go other_expr 0
1527    where
1528     go (Var f) n_val_args
1529 #if mingw32_TARGET_OS
1530         | not (_is_dynamic_name (idName f))
1531 #endif
1532         =  saturated_data_con f n_val_args
1533         || (in_arg && n_val_args == 0)
1534                 -- A naked un-applied variable is *not* deemed a static RHS
1535                 -- E.g.         f = g
1536                 -- Reason: better to update so that the indirection gets shorted
1537                 --         out, and the true value will be seen
1538                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1539                 --     are always updatable.  If you do so, make sure that non-updatable
1540                 --     ones have enough space for their static link field!
1541
1542     go (App f a) n_val_args
1543         | isTypeArg a                    = go f n_val_args
1544         | not in_arg && is_static True a = go f (n_val_args + 1)
1545         -- The (not in_arg) checks that we aren't in a constructor argument;
1546         -- if we are, we don't allow (value) applications of any sort
1547         --
1548         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1549         --   x = D# (1.0## /## 2.0##)
1550         -- can't float because /## can fail.
1551
1552     go (Note n f) n_val_args = notSccNote n && go f n_val_args
1553     go (Cast e _) n_val_args = go e n_val_args
1554     go _          _          = False
1555
1556     saturated_data_con f n_val_args
1557         = case isDataConWorkId_maybe f of
1558             Just dc -> n_val_args == dataConRepArity dc
1559             Nothing -> False
1560 \end{code}