compiler/coreSyn/CoreUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utility functions on @Core@ syntax
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 -- | Commonly useful utilites for manipulating the Core language
  17 module CoreUtils (
  18         -- * Constructing expressions
  19         mkSCC, mkCoerce, mkCoerceI,
  20         bindNonRec, needsCaseBinding,
  21         mkAltExpr, mkPiType, mkPiTypes,
  22
  23         -- * Taking expressions apart
  24         findDefault, findAlt, isDefaultAlt, mergeAlts, trimConArgs,
  25
  26         -- * Properties of expressions
  27         exprType, coreAltType, coreAltsType,
  28         exprIsDupable, exprIsTrivial, exprIsCheap, exprIsExpandable,
  29         exprIsHNF, exprOkForSpeculation, exprIsBig, exprIsConLike,
  30         rhsIsStatic,
  31
  32         -- * Expression and bindings size
  33         coreBindsSize, exprSize,
  34
  35         -- * Hashing
  36         hashExpr,
  37
  38         -- * Equality
  39         cheapEqExpr,
  40
  41         -- * Manipulating data constructors and types
  42         applyTypeToArgs, applyTypeToArg,
  43         dataConOrigInstPat, dataConRepInstPat, dataConRepFSInstPat
  44     ) where
  45
  46 #include "HsVersions.h"
  47
  48 import CoreSyn
  49 import PprCore
  50 import Var
  51 import SrcLoc
  52 import VarEnv
  53 import VarSet
  54 import Name
  55 import Module
  56 #if mingw32_TARGET_OS
  57 import Packages
  58 #endif
  59 import Literal
  60 import DataCon
  61 import PrimOp
  62 import Id
  63 import IdInfo
  64 import Type
  65 import Coercion
  66 import TyCon
  67 import CostCentre
  68 import Unique
  69 import Outputable
  70 import TysPrim
  71 import FastString
  72 import Maybes
  73 import Util
  74 import Data.Word
  75 import Data.Bits
  76 \end{code}
  77
  78
  79 %************************************************************************
  80 %*                                                                      *
  81 \subsection{Find the type of a Core atom/expression}
  82 %*                                                                      *
  83 %************************************************************************
  84
  85 \begin{code}
  86 exprType :: CoreExpr -> Type
  87 -- ^ Recover the type of a well-typed Core expression. Fails when
  88 -- applied to the actual 'CoreSyn.Type' expression as it cannot
  89 -- really be said to have a type
  90 exprType (Var var)           = idType var
  91 exprType (Lit lit)           = literalType lit
  92 exprType (Let _ body)        = exprType body
  93 exprType (Case _ _ ty _)     = ty
  94 exprType (Cast _ co)         = snd (coercionKind co)
  95 exprType (Note _ e)          = exprType e
  96 exprType (Lam binder expr)   = mkPiType binder (exprType expr)
  97 exprType e@(App _ _)
  98   = case collectArgs e of
  99         (fun, args) -> applyTypeToArgs e (exprType fun) args
 100
 101 exprType other = pprTrace "exprType" (pprCoreExpr other) alphaTy
 102
 103 coreAltType :: CoreAlt -> Type
 104 -- ^ Returns the type of the alternatives right hand side
 105 coreAltType (_,bs,rhs)
 106   | any bad_binder bs = expandTypeSynonyms ty
 107   | otherwise         = ty    -- Note [Existential variables and silly type synonyms]
 108   where
 109     ty           = exprType rhs
 110     free_tvs     = tyVarsOfType ty
 111     bad_binder b = isTyVar b && b `elemVarSet` free_tvs
 112
 113 coreAltsType :: [CoreAlt] -> Type
 114 -- ^ Returns the type of the first alternative, which should be the same as for all alternatives
 115 coreAltsType (alt:_) = coreAltType alt
 116 coreAltsType []      = panic "corAltsType"
 117 \end{code}
 118
 119 Note [Existential variables and silly type synonyms]
 120 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 121 Consider
 122         data T = forall a. T (Funny a)
 123         type Funny a = Bool
 124         f :: T -> Bool
 125         f (T x) = x
 126
 127 Now, the type of 'x' is (Funny a), where 'a' is existentially quantified.
 128 That means that 'exprType' and 'coreAltsType' may give a result that *appears*
 129 to mention an out-of-scope type variable.  See Trac #3409 for a more real-world
 130 example.
 131
 132 Various possibilities suggest themselves:
 133
 134  - Ignore the problem, and make Lint not complain about such variables
 135
 136  - Expand all type synonyms (or at least all those that discard arguments)
 137       This is tricky, because at least for top-level things we want to
 138       retain the type the user originally specified.
 139
 140  - Expand synonyms on the fly, when the problem arises. That is what
 141    we are doing here.  It's not too expensive, I think.
 142
 143 \begin{code}
 144 mkPiType  :: Var   -> Type -> Type
 145 -- ^ Makes a @(->)@ type or a forall type, depending
 146 -- on whether it is given a type variable or a term variable.
 147 mkPiTypes :: [Var] -> Type -> Type
 148 -- ^ 'mkPiType' for multiple type or value arguments
 149
 150 mkPiType v ty
 151    | isId v    = mkFunTy (idType v) ty
 152    | otherwise = mkForAllTy v ty
 153
 154 mkPiTypes vs ty = foldr mkPiType ty vs
 155 \end{code}
 156
 157 \begin{code}
 158 applyTypeToArg :: Type -> CoreExpr -> Type
 159 -- ^ Determines the type resulting from applying an expression to a function with the given type
 160 applyTypeToArg fun_ty (Type arg_ty) = applyTy fun_ty arg_ty
 161 applyTypeToArg fun_ty _             = funResultTy fun_ty
 162
 163 applyTypeToArgs :: CoreExpr -> Type -> [CoreExpr] -> Type
 164 -- ^ A more efficient version of 'applyTypeToArg' when we have several arguments.
 165 -- The first argument is just for debugging, and gives some context
 166 applyTypeToArgs _ op_ty [] = op_ty
 167
 168 applyTypeToArgs e op_ty (Type ty : args)
 169   =     -- Accumulate type arguments so we can instantiate all at once
 170     go [ty] args
 171   where
 172     go rev_tys (Type ty : args) = go (ty:rev_tys) args
 173     go rev_tys rest_args        = applyTypeToArgs e op_ty' rest_args
 174                                 where
 175                                   op_ty' = applyTysD msg op_ty (reverse rev_tys)
 176                                   msg = ptext (sLit "applyTypeToArgs") <+>
 177                                         panic_msg e op_ty
 178
 179 applyTypeToArgs e op_ty (_ : args)
 180   = case (splitFunTy_maybe op_ty) of
 181         Just (_, res_ty) -> applyTypeToArgs e res_ty args
 182         Nothing -> pprPanic "applyTypeToArgs" (panic_msg e op_ty)
 183
 184 panic_msg :: CoreExpr -> Type -> SDoc
 185 panic_msg e op_ty = pprCoreExpr e $$ ppr op_ty
 186 \end{code}
 187
 188 %************************************************************************
 189 %*                                                                      *
 190 \subsection{Attaching notes}
 191 %*                                                                      *
 192 %************************************************************************
 193
 194 \begin{code}
 195 -- | Wrap the given expression in the coercion, dropping identity coercions and coalescing nested coercions
 196 mkCoerceI :: CoercionI -> CoreExpr -> CoreExpr
 197 mkCoerceI IdCo e = e
 198 mkCoerceI (ACo co) e = mkCoerce co e
 199
 200 -- | Wrap the given expression in the coercion safely, coalescing nested coercions
 201 mkCoerce :: Coercion -> CoreExpr -> CoreExpr
 202 mkCoerce co (Cast expr co2)
 203   = ASSERT(let { (from_ty, _to_ty) = coercionKind co;
 204                  (_from_ty2, to_ty2) = coercionKind co2} in
 205            from_ty `coreEqType` to_ty2 )
 206     mkCoerce (mkTransCoercion co2 co) expr
 207
 208 mkCoerce co expr
 209   = let (from_ty, _to_ty) = coercionKind co in
 210 --    if to_ty `coreEqType` from_ty
 211 --    then expr
 212 --    else
 213         WARN(not (from_ty `coreEqType` exprType expr), text "Trying to coerce" <+> text "(" <> ppr expr $$ text "::" <+> ppr (exprType expr) <> text ")" $$ ppr co $$ pprEqPred (coercionKind co))
 214          (Cast expr co)
 215 \end{code}
 216
 217 \begin{code}
 218 -- | Wraps the given expression in the cost centre unless
 219 -- in a way that maximises their utility to the user
 220 mkSCC :: CostCentre -> Expr b -> Expr b
 221         -- Note: Nested SCC's *are* preserved for the benefit of
 222         --       cost centre stack profiling
 223 mkSCC _  (Lit lit)          = Lit lit
 224 mkSCC cc (Lam x e)          = Lam x (mkSCC cc e)  -- Move _scc_ inside lambda
 225 mkSCC cc (Note (SCC cc') e) = Note (SCC cc) (Note (SCC cc') e)
 226 mkSCC cc (Note n e)         = Note n (mkSCC cc e) -- Move _scc_ inside notes
 227 mkSCC cc (Cast e co)        = Cast (mkSCC cc e) co -- Move _scc_ inside cast
 228 mkSCC cc expr               = Note (SCC cc) expr
 229 \end{code}
 230
 231
 232 %************************************************************************
 233 %*                                                                      *
 234 \subsection{Other expression construction}
 235 %*                                                                      *
 236 %************************************************************************
 237
 238 \begin{code}
 239 bindNonRec :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 240 -- ^ @bindNonRec x r b@ produces either:
 241 --
 242 -- > let x = r in b
 243 --
 244 -- or:
 245 --
 246 -- > case r of x { _DEFAULT_ -> b }
 247 --
 248 -- depending on whether we have to use a @case@ or @let@
 249 -- binding for the expression (see 'needsCaseBinding').
 250 -- It's used by the desugarer to avoid building bindings
 251 -- that give Core Lint a heart attack, although actually
 252 -- the simplifier deals with them perfectly well. See
 253 -- also 'MkCore.mkCoreLet'
 254 bindNonRec bndr rhs body
 255   | needsCaseBinding (idType bndr) rhs = Case rhs bndr (exprType body) [(DEFAULT, [], body)]
 256   | otherwise                          = Let (NonRec bndr rhs) body
 257
 258 -- | Tests whether we have to use a @case@ rather than @let@ binding for this expression
 259 -- as per the invariants of 'CoreExpr': see "CoreSyn#let_app_invariant"
 260 needsCaseBinding :: Type -> CoreExpr -> Bool
 261 needsCaseBinding ty rhs = isUnLiftedType ty && not (exprOkForSpeculation rhs)
 262         -- Make a case expression instead of a let
 263         -- These can arise either from the desugarer,
 264         -- or from beta reductions: (\x.e) (x +# y)
 265 \end{code}
 266
 267 \begin{code}
 268 mkAltExpr :: AltCon     -- ^ Case alternative constructor
 269           -> [CoreBndr] -- ^ Things bound by the pattern match
 270           -> [Type]     -- ^ The type arguments to the case alternative
 271           -> CoreExpr
 272 -- ^ This guy constructs the value that the scrutinee must have
 273 -- given that you are in one particular branch of a case
 274 mkAltExpr (DataAlt con) args inst_tys
 275   = mkConApp con (map Type inst_tys ++ varsToCoreExprs args)
 276 mkAltExpr (LitAlt lit) [] []
 277   = Lit lit
 278 mkAltExpr (LitAlt _) _ _ = panic "mkAltExpr LitAlt"
 279 mkAltExpr DEFAULT _ _ = panic "mkAltExpr DEFAULT"
 280 \end{code}
 281
 282
 283 %************************************************************************
 284 %*                                                                      *
 285 \subsection{Taking expressions apart}
 286 %*                                                                      *
 287 %************************************************************************
 288
 289 The default alternative must be first, if it exists at all.
 290 This makes it easy to find, though it makes matching marginally harder.
 291
 292 \begin{code}
 293 -- | Extract the default case alternative
 294 findDefault :: [CoreAlt] -> ([CoreAlt], Maybe CoreExpr)
 295 findDefault ((DEFAULT,args,rhs) : alts) = ASSERT( null args ) (alts, Just rhs)
 296 findDefault alts                        =                     (alts, Nothing)
 297
 298 isDefaultAlt :: CoreAlt -> Bool
 299 isDefaultAlt (DEFAULT, _, _) = True
 300 isDefaultAlt _               = False
 301
 302
 303 -- | Find the case alternative corresponding to a particular
 304 -- constructor: panics if no such constructor exists
 305 findAlt :: AltCon -> [CoreAlt] -> Maybe CoreAlt
 306     -- A "Nothing" result *is* legitmiate
 307     -- See Note [Unreachable code]
 308 findAlt con alts
 309   = case alts of
 310         (deflt@(DEFAULT,_,_):alts) -> go alts (Just deflt)
 311         _                          -> go alts Nothing
 312   where
 313     go []                     deflt = deflt
 314     go (alt@(con1,_,_) : alts) deflt
 315       = case con `cmpAltCon` con1 of
 316           LT -> deflt   -- Missed it already; the alts are in increasing order
 317           EQ -> Just alt
 318           GT -> ASSERT( not (con1 == DEFAULT) ) go alts deflt
 319
 320 ---------------------------------
 321 mergeAlts :: [CoreAlt] -> [CoreAlt] -> [CoreAlt]
 322 -- ^ Merge alternatives preserving order; alternatives in
 323 -- the first argument shadow ones in the second
 324 mergeAlts [] as2 = as2
 325 mergeAlts as1 [] = as1
 326 mergeAlts (a1:as1) (a2:as2)
 327   = case a1 `cmpAlt` a2 of
 328         LT -> a1 : mergeAlts as1      (a2:as2)
 329         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
 330         GT -> a2 : mergeAlts (a1:as1) as2
 331
 332
 333 ---------------------------------
 334 trimConArgs :: AltCon -> [CoreArg] -> [CoreArg]
 335 -- ^ Given:
 336 --
 337 -- > case (C a b x y) of
 338 -- >        C b x y -> ...
 339 --
 340 -- We want to drop the leading type argument of the scrutinee
 341 -- leaving the arguments to match agains the pattern
 342
 343 trimConArgs DEFAULT      args = ASSERT( null args ) []
 344 trimConArgs (LitAlt _)   args = ASSERT( null args ) []
 345 trimConArgs (DataAlt dc) args = dropList (dataConUnivTyVars dc) args
 346 \end{code}
 347
 348 Note [Unreachable code]
 349 ~~~~~~~~~~~~~~~~~~~~~~~
 350 It is possible (although unusual) for GHC to find a case expression
 351 that cannot match.  For example:
 352
 353      data Col = Red | Green | Blue
 354      x = Red
 355      f v = case x of
 356               Red -> ...
 357               _ -> ...(case x of { Green -> e1; Blue -> e2 })...
 358
 359 Suppose that for some silly reason, x isn't substituted in the case
 360 expression.  (Perhaps there's a NOINLINE on it, or profiling SCC stuff
 361 gets in the way; cf Trac #3118.)  Then the full-lazines pass might produce
 362 this
 363
 364      x = Red
 365      lvl = case x of { Green -> e1; Blue -> e2 })
 366      f v = case x of
 367              Red -> ...
 368              _ -> ...lvl...
 369
 370 Now if x gets inlined, we won't be able to find a matching alternative
 371 for 'Red'.  That's because 'lvl' is unreachable.  So rather than crashing
 372 we generate (error "Inaccessible alternative").
 373
 374 Similar things can happen (augmented by GADTs) when the Simplifier
 375 filters down the matching alternatives in Simplify.rebuildCase.
 376
 377
 378 %************************************************************************
 379 %*                                                                      *
 380              exprIsTrivial
 381 %*                                                                      *
 382 %************************************************************************
 383
 384 Note [exprIsTrivial]
 385 ~~~~~~~~~~~~~~~~~~~~
 386 @exprIsTrivial@ is true of expressions we are unconditionally happy to
 387                 duplicate; simple variables and constants, and type
 388                 applications.  Note that primop Ids aren't considered
 389                 trivial unless
 390
 391 Note [Variable are trivial]
 392 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 393 There used to be a gruesome test for (hasNoBinding v) in the
 394 Var case:
 395         exprIsTrivial (Var v) | hasNoBinding v = idArity v == 0
 396 The idea here is that a constructor worker, like \$wJust, is
 397 really short for (\x -> \$wJust x), becuase \$wJust has no binding.
 398 So it should be treated like a lambda.  Ditto unsaturated primops.
 399 But now constructor workers are not "have-no-binding" Ids.  And
 400 completely un-applied primops and foreign-call Ids are sufficiently
 401 rare that I plan to allow them to be duplicated and put up with
 402 saturating them.
 403
 404 Note [SCCs are trivial]
 405 ~~~~~~~~~~~~~~~~~~~~~~~
 406 We used not to treat (_scc_ "foo" x) as trivial, because it really
 407 generates code, (and a heap object when it's a function arg) to
 408 capture the cost centre.  However, the profiling system discounts the
 409 allocation costs for such "boxing thunks" whereas the extra costs of
 410 *not* inlining otherwise-trivial bindings can be high, and are hard to
 411 discount.
 412
 413 \begin{code}
 414 exprIsTrivial :: CoreExpr -> Bool
 415 exprIsTrivial (Var _)          = True        -- See Note [Variables are trivial]
 416 exprIsTrivial (Type _)         = True
 417 exprIsTrivial (Lit lit)        = litIsTrivial lit
 418 exprIsTrivial (App e arg)      = not (isRuntimeArg arg) && exprIsTrivial e
 419 exprIsTrivial (Note _       e) = exprIsTrivial e  -- See Note [SCCs are trivial]
 420 exprIsTrivial (Cast e _)       = exprIsTrivial e
 421 exprIsTrivial (Lam b body)     = not (isRuntimeVar b) && exprIsTrivial body
 422 exprIsTrivial _                = False
 423 \end{code}
 424
 425
 426 %************************************************************************
 427 %*                                                                      *
 428              exprIsDupable
 429 %*                                                                      *
 430 %************************************************************************
 431
 432 Note [exprIsDupable]
 433 ~~~~~~~~~~~~~~~~~~~~
 434 @exprIsDupable@ is true of expressions that can be duplicated at a modest
 435                 cost in code size.  This will only happen in different case
 436                 branches, so there's no issue about duplicating work.
 437
 438                 That is, exprIsDupable returns True of (f x) even if
 439                 f is very very expensive to call.
 440
 441                 Its only purpose is to avoid fruitless let-binding
 442                 and then inlining of case join points
 443
 444
 445 \begin{code}
 446 exprIsDupable :: CoreExpr -> Bool
 447 exprIsDupable (Type _)   = True
 448 exprIsDupable (Var _)    = True
 449 exprIsDupable (Lit lit)  = litIsDupable lit
 450 exprIsDupable (Note _ e) = exprIsDupable e
 451 exprIsDupable (Cast e _) = exprIsDupable e
 452 exprIsDupable expr
 453   = go expr 0
 454   where
 455     go (Var _)   _      = True
 456     go (App f a) n_args =  n_args < dupAppSize
 457                         && exprIsDupable a
 458                         && go f (n_args+1)
 459     go _         _      = False
 460
 461 dupAppSize :: Int
 462 dupAppSize = 4          -- Size of application we are prepared to duplicate
 463 \end{code}
 464
 465 %************************************************************************
 466 %*                                                                      *
 467              exprIsCheap, exprIsExpandable
 468 %*                                                                      *
 469 %************************************************************************
 470
 471 Note [exprIsCheap]
 472 ~~~~~~~~~~~~~~~~~~
 473 @exprIsCheap@ looks at a Core expression and returns \tr{True} if
 474 it is obviously in weak head normal form, or is cheap to get to WHNF.
 475 [Note that that's not the same as exprIsDupable; an expression might be
 476 big, and hence not dupable, but still cheap.]
 477
 478 By ``cheap'' we mean a computation we're willing to:
 479         push inside a lambda, or
 480         inline at more than one place
 481 That might mean it gets evaluated more than once, instead of being
 482 shared.  The main examples of things which aren't WHNF but are
 483 ``cheap'' are:
 484
 485   *     case e of
 486           pi -> ei
 487         (where e, and all the ei are cheap)
 488
 489   *     let x = e in b
 490         (where e and b are cheap)
 491
 492   *     op x1 ... xn
 493         (where op is a cheap primitive operator)
 494
 495   *     error "foo"
 496         (because we are happy to substitute it inside a lambda)
 497
 498 Notice that a variable is considered 'cheap': we can push it inside a lambda,
 499 because sharing will make sure it is only evaluated once.
 500
 501 \begin{code}
 502 exprIsCheap' :: (Id -> Bool) -> CoreExpr -> Bool
 503 exprIsCheap' _          (Lit _)           = True
 504 exprIsCheap' _          (Type _)          = True
 505 exprIsCheap' _          (Var _)           = True
 506 exprIsCheap' is_conlike (Note _ e)        = exprIsCheap' is_conlike e
 507 exprIsCheap' is_conlike (Cast e _)        = exprIsCheap' is_conlike e
 508 exprIsCheap' is_conlike (Lam x e)         = isRuntimeVar x
 509                                             || exprIsCheap' is_conlike e
 510
 511 exprIsCheap' is_conlike (Case e _ _ alts) = exprIsCheap' is_conlike e &&
 512                                             and [exprIsCheap' is_conlike rhs | (_,_,rhs) <- alts]
 513         -- Experimentally, treat (case x of ...) as cheap
 514         -- (and case __coerce x etc.)
 515         -- This improves arities of overloaded functions where
 516         -- there is only dictionary selection (no construction) involved
 517
 518 exprIsCheap' is_conlike (Let (NonRec x _) e)
 519       | isUnLiftedType (idType x) = exprIsCheap' is_conlike e
 520       | otherwise                 = False
 521         -- Strict lets always have cheap right hand sides,
 522         -- and do no allocation, so just look at the body
 523         -- Non-strict lets do allocation so we don't treat them as cheap
 524
 525 exprIsCheap' is_conlike other_expr      -- Applications and variables
 526   = go other_expr []
 527   where
 528         -- Accumulate value arguments, then decide
 529     go (App f a) val_args | isRuntimeArg a = go f (a:val_args)
 530                           | otherwise      = go f val_args
 531
 532     go (Var _) [] = True        -- Just a type application of a variable
 533                                 -- (f t1 t2 t3) counts as WHNF
 534     go (Var f) args
 535         = case idDetails f of
 536                 RecSelId {}  -> go_sel args
 537                 ClassOpId {} -> go_sel args
 538                 PrimOpId op  -> go_primop op args
 539
 540                 _ | is_conlike f -> go_pap args
 541                   | length args < idArity f -> go_pap args
 542
 543                 _ -> isBottomingId f
 544                         -- Application of a function which
 545                         -- always gives bottom; we treat this as cheap
 546                         -- because it certainly doesn't need to be shared!
 547
 548     go _ _ = False
 549
 550     --------------
 551     go_pap args = all exprIsTrivial args
 552         -- For constructor applications and primops, check that all
 553         -- the args are trivial.  We don't want to treat as cheap, say,
 554         --      (1:2:3:4:5:[])
 555         -- We'll put up with one constructor application, but not dozens
 556
 557     --------------
 558     go_primop op args = primOpIsCheap op && all (exprIsCheap' is_conlike) args
 559         -- In principle we should worry about primops
 560         -- that return a type variable, since the result
 561         -- might be applied to something, but I'm not going
 562         -- to bother to check the number of args
 563
 564     --------------
 565     go_sel [arg] = exprIsCheap' is_conlike arg  -- I'm experimenting with making record selection
 566     go_sel _     = False                -- look cheap, so we will substitute it inside a
 567                                         -- lambda.  Particularly for dictionary field selection.
 568                 -- BUT: Take care with (sel d x)!  The (sel d) might be cheap, but
 569                 --      there's no guarantee that (sel d x) will be too.  Hence (n_val_args == 1)
 570
 571 exprIsCheap :: CoreExpr -> Bool
 572 exprIsCheap = exprIsCheap' isDataConWorkId
 573
 574 exprIsExpandable :: CoreExpr -> Bool
 575 exprIsExpandable = exprIsCheap' isConLikeId     -- See Note [CONLIKE pragma] in BasicTypes
 576 \end{code}
 577
 578 %************************************************************************
 579 %*                                                                      *
 580              exprOkForSpeculation
 581 %*                                                                      *
 582 %************************************************************************
 583
 584 \begin{code}
 585 -- | 'exprOkForSpeculation' returns True of an expression that is:
 586 --
 587 --  * Safe to evaluate even if normal order eval might not
 588 --    evaluate the expression at all, or
 589 --
 590 --  * Safe /not/ to evaluate even if normal order would do so
 591 --
 592 -- Precisely, it returns @True@ iff:
 593 --
 594 --  * The expression guarantees to terminate,
 595 --
 596 --  * soon,
 597 --
 598 --  * without raising an exception,
 599 --
 600 --  * without causing a side effect (e.g. writing a mutable variable)
 601 --
 602 -- Note that if @exprIsHNF e@, then @exprOkForSpecuation e@.
 603 -- As an example of the considerations in this test, consider:
 604 --
 605 -- > let x = case y# +# 1# of { r# -> I# r# }
 606 -- > in E
 607 --
 608 -- being translated to:
 609 --
 610 -- > case y# +# 1# of { r# ->
 611 -- >    let x = I# r#
 612 -- >    in E
 613 -- > }
 614 --
 615 -- We can only do this if the @y + 1@ is ok for speculation: it has no
 616 -- side effects, and can't diverge or raise an exception.
 617 exprOkForSpeculation :: CoreExpr -> Bool
 618 exprOkForSpeculation (Lit _)     = True
 619 exprOkForSpeculation (Type _)    = True
 620     -- Tick boxes are *not* suitable for speculation
 621 exprOkForSpeculation (Var v)     = isUnLiftedType (idType v)
 622                                  && not (isTickBoxOp v)
 623 exprOkForSpeculation (Note _ e)  = exprOkForSpeculation e
 624 exprOkForSpeculation (Cast e _)  = exprOkForSpeculation e
 625 exprOkForSpeculation other_expr
 626   = case collectArgs other_expr of
 627         (Var f, args) -> spec_ok (idDetails f) args
 628         _             -> False
 629
 630   where
 631     spec_ok (DataConWorkId _) _
 632       = True    -- The strictness of the constructor has already
 633                 -- been expressed by its "wrapper", so we don't need
 634                 -- to take the arguments into account
 635
 636     spec_ok (PrimOpId op) args
 637       | isDivOp op,             -- Special case for dividing operations that fail
 638         [arg1, Lit lit] <- args -- only if the divisor is zero
 639       = not (isZeroLit lit) && exprOkForSpeculation arg1
 640                 -- Often there is a literal divisor, and this
 641                 -- can get rid of a thunk in an inner looop
 642
 643       | otherwise
 644       = primOpOkForSpeculation op &&
 645         all exprOkForSpeculation args
 646                                 -- A bit conservative: we don't really need
 647                                 -- to care about lazy arguments, but this is easy
 648
 649     spec_ok (DFunId new_type) _ = not new_type
 650          -- DFuns terminate, unless the dict is implemented with a newtype
 651          -- in which case they may not
 652
 653     spec_ok _ _ = False
 654
 655 -- | True of dyadic operators that can fail only if the second arg is zero!
 656 isDivOp :: PrimOp -> Bool
 657 -- This function probably belongs in PrimOp, or even in
 658 -- an automagically generated file.. but it's such a
 659 -- special case I thought I'd leave it here for now.
 660 isDivOp IntQuotOp        = True
 661 isDivOp IntRemOp         = True
 662 isDivOp WordQuotOp       = True
 663 isDivOp WordRemOp        = True
 664 isDivOp FloatDivOp       = True
 665 isDivOp DoubleDivOp      = True
 666 isDivOp _                = False
 667 \end{code}
 668
 669 %************************************************************************
 670 %*                                                                      *
 671              exprIsHNF, exprIsConLike
 672 %*                                                                      *
 673 %************************************************************************
 674
 675 \begin{code}
 676 -- Note [exprIsHNF]
 677 -- ~~~~~~~~~~~~~~~~
 678 -- | exprIsHNF returns true for expressions that are certainly /already/
 679 -- evaluated to /head/ normal form.  This is used to decide whether it's ok
 680 -- to change:
 681 --
 682 -- > case x of _ -> e
 683 --
 684 --    into:
 685 --
 686 -- > e
 687 --
 688 -- and to decide whether it's safe to discard a 'seq'.
 689 --
 690 -- So, it does /not/ treat variables as evaluated, unless they say they are.
 691 -- However, it /does/ treat partial applications and constructor applications
 692 -- as values, even if their arguments are non-trivial, provided the argument
 693 -- type is lifted. For example, both of these are values:
 694 --
 695 -- > (:) (f x) (map f xs)
 696 -- > map (...redex...)
 697 --
 698 -- because 'seq' on such things completes immediately.
 699 --
 700 -- For unlifted argument types, we have to be careful:
 701 --
 702 -- > C (f x :: Int#)
 703 --
 704 -- Suppose @f x@ diverges; then @C (f x)@ is not a value. However this can't
 705 -- happen: see "CoreSyn#let_app_invariant". This invariant states that arguments of
 706 -- unboxed type must be ok-for-speculation (or trivial).
 707 exprIsHNF :: CoreExpr -> Bool           -- True => Value-lambda, constructor, PAP
 708 exprIsHNF = exprIsHNFlike isDataConWorkId isEvaldUnfolding
 709 \end{code}
 710
 711 \begin{code}
 712 -- | Similar to 'exprIsHNF' but includes CONLIKE functions as well as
 713 -- data constructors. Conlike arguments are considered interesting by the
 714 -- inliner.
 715 exprIsConLike :: CoreExpr -> Bool       -- True => lambda, conlike, PAP
 716 exprIsConLike = exprIsHNFlike isConLikeId isConLikeUnfolding
 717
 718 -- | Returns true for values or value-like expressions. These are lambdas,
 719 -- constructors / CONLIKE functions (as determined by the function argument)
 720 -- or PAPs.
 721 --
 722 exprIsHNFlike :: (Var -> Bool) -> (Unfolding -> Bool) -> CoreExpr -> Bool
 723 exprIsHNFlike is_con is_con_unf = is_hnf_like
 724   where
 725     is_hnf_like (Var v) -- NB: There are no value args at this point
 726       =  is_con v       -- Catches nullary constructors,
 727                         --      so that [] and () are values, for example
 728       || idArity v > 0  -- Catches (e.g.) primops that don't have unfoldings
 729       || is_con_unf (idUnfolding v)
 730         -- Check the thing's unfolding; it might be bound to a value
 731         -- We don't look through loop breakers here, which is a bit conservative
 732         -- but otherwise I worry that if an Id's unfolding is just itself,
 733         -- we could get an infinite loop
 734
 735     is_hnf_like (Lit _)          = True
 736     is_hnf_like (Type _)         = True       -- Types are honorary Values;
 737                                               -- we don't mind copying them
 738     is_hnf_like (Lam b e)        = isRuntimeVar b || is_hnf_like e
 739     is_hnf_like (Note _ e)       = is_hnf_like e
 740     is_hnf_like (Cast e _)       = is_hnf_like e
 741     is_hnf_like (App e (Type _)) = is_hnf_like e
 742     is_hnf_like (App e a)        = app_is_value e [a]
 743     is_hnf_like (Let _ e)        = is_hnf_like e  -- Lazy let(rec)s don't affect us
 744     is_hnf_like _                = False
 745
 746     -- There is at least one value argument
 747     app_is_value :: CoreExpr -> [CoreArg] -> Bool
 748     app_is_value (Var fun) args
 749       = idArity fun > valArgCount args    -- Under-applied function
 750         || is_con fun                     --  or constructor-like
 751     app_is_value (Note _ f) as = app_is_value f as
 752     app_is_value (Cast f _) as = app_is_value f as
 753     app_is_value (App f a)  as = app_is_value f (a:as)
 754     app_is_value _          _  = False
 755 \end{code}
 756
 757
 758 %************************************************************************
 759 %*                                                                      *
 760              Instantiating data constructors
 761 %*                                                                      *
 762 %************************************************************************
 763
 764 These InstPat functions go here to avoid circularity between DataCon and Id
 765
 766 \begin{code}
 767 dataConRepInstPat, dataConOrigInstPat :: [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 768 dataConRepFSInstPat :: [FastString] -> [Unique] -> DataCon -> [Type] -> ([TyVar], [CoVar], [Id])
 769
 770 dataConRepInstPat   = dataConInstPat dataConRepArgTys (repeat ((fsLit "ipv")))
 771 dataConRepFSInstPat = dataConInstPat dataConRepArgTys
 772 dataConOrigInstPat  = dataConInstPat dc_arg_tys       (repeat ((fsLit "ipv")))
 773   where
 774     dc_arg_tys dc = map mkPredTy (dataConEqTheta dc) ++ map mkPredTy (dataConDictTheta dc) ++ dataConOrigArgTys dc
 775         -- Remember to include the existential dictionaries
 776
 777 dataConInstPat :: (DataCon -> [Type])      -- function used to find arg tys
 778                   -> [FastString]          -- A long enough list of FSs to use for names
 779                   -> [Unique]              -- An equally long list of uniques, at least one for each binder
 780                   -> DataCon
 781                   -> [Type]                -- Types to instantiate the universally quantified tyvars
 782                -> ([TyVar], [CoVar], [Id]) -- Return instantiated variables
 783 -- dataConInstPat arg_fun fss us con inst_tys returns a triple
 784 -- (ex_tvs, co_tvs, arg_ids),
 785 --
 786 --   ex_tvs are intended to be used as binders for existential type args
 787 --
 788 --   co_tvs are intended to be used as binders for coercion args and the kinds
 789 --     of these vars have been instantiated by the inst_tys and the ex_tys
 790 --     The co_tvs include both GADT equalities (dcEqSpec) and
 791 --     programmer-specified equalities (dcEqTheta)
 792 --
 793 --   arg_ids are indended to be used as binders for value arguments,
 794 --     and their types have been instantiated with inst_tys and ex_tys
 795 --     The arg_ids include both dicts (dcDictTheta) and
 796 --     programmer-specified arguments (after rep-ing) (deRepArgTys)
 797 --
 798 -- Example.
 799 --  The following constructor T1
 800 --
 801 --  data T a where
 802 --    T1 :: forall b. Int -> b -> T(a,b)
 803 --    ...
 804 --
 805 --  has representation type
 806 --   forall a. forall a1. forall b. (a ~ (a1,b)) =>
 807 --     Int -> b -> T a
 808 --
 809 --  dataConInstPat fss us T1 (a1',b') will return
 810 --
 811 --  ([a1'', b''], [c :: (a1', b')~(a1'', b'')], [x :: Int, y :: b''])
 812 --
 813 --  where the double-primed variables are created with the FastStrings and
 814 --  Uniques given as fss and us
 815 dataConInstPat arg_fun fss uniqs con inst_tys
 816   = (ex_bndrs, co_bndrs, arg_ids)
 817   where
 818     univ_tvs = dataConUnivTyVars con
 819     ex_tvs   = dataConExTyVars con
 820     arg_tys  = arg_fun con
 821     eq_spec  = dataConEqSpec con
 822     eq_theta = dataConEqTheta con
 823     eq_preds = eqSpecPreds eq_spec ++ eq_theta
 824
 825     n_ex = length ex_tvs
 826     n_co = length eq_preds
 827
 828       -- split the Uniques and FastStrings
 829     (ex_uniqs, uniqs')   = splitAt n_ex uniqs
 830     (co_uniqs, id_uniqs) = splitAt n_co uniqs'
 831
 832     (ex_fss, fss')     = splitAt n_ex fss
 833     (co_fss, id_fss)   = splitAt n_co fss'
 834
 835       -- Make existential type variables
 836     ex_bndrs = zipWith3 mk_ex_var ex_uniqs ex_fss ex_tvs
 837     mk_ex_var uniq fs var = mkTyVar new_name kind
 838       where
 839         new_name = mkSysTvName uniq fs
 840         kind     = tyVarKind var
 841
 842       -- Make the instantiating substitution
 843     subst = zipOpenTvSubst (univ_tvs ++ ex_tvs) (inst_tys ++ map mkTyVarTy ex_bndrs)
 844
 845       -- Make new coercion vars, instantiating kind
 846     co_bndrs = zipWith3 mk_co_var co_uniqs co_fss eq_preds
 847     mk_co_var uniq fs eq_pred = mkCoVar new_name co_kind
 848        where
 849          new_name = mkSysTvName uniq fs
 850          co_kind  = substTy subst (mkPredTy eq_pred)
 851
 852       -- make value vars, instantiating types
 853     mk_id_var uniq fs ty = mkUserLocal (mkVarOccFS fs) uniq (substTy subst ty) noSrcSpan
 854     arg_ids = zipWith3 mk_id_var id_uniqs id_fss arg_tys
 855
 856 \end{code}
 857
 858 %************************************************************************
 859 %*                                                                      *
 860          Equality
 861 %*                                                                      *
 862 %************************************************************************
 863
 864 \begin{code}
 865 -- | A cheap equality test which bales out fast!
 866 --      If it returns @True@ the arguments are definitely equal,
 867 --      otherwise, they may or may not be equal.
 868 --
 869 -- See also 'exprIsBig'
 870 cheapEqExpr :: Expr b -> Expr b -> Bool
 871
 872 cheapEqExpr (Var v1)   (Var v2)   = v1==v2
 873 cheapEqExpr (Lit lit1) (Lit lit2) = lit1 == lit2
 874 cheapEqExpr (Type t1)  (Type t2)  = t1 `coreEqType` t2
 875
 876 cheapEqExpr (App f1 a1) (App f2 a2)
 877   = f1 `cheapEqExpr` f2 && a1 `cheapEqExpr` a2
 878
 879 cheapEqExpr (Cast e1 t1) (Cast e2 t2)
 880   = e1 `cheapEqExpr` e2 && t1 `coreEqCoercion` t2
 881
 882 cheapEqExpr _ _ = False
 883
 884 exprIsBig :: Expr b -> Bool
 885 -- ^ Returns @True@ of expressions that are too big to be compared by 'cheapEqExpr'
 886 exprIsBig (Lit _)      = False
 887 exprIsBig (Var _)      = False
 888 exprIsBig (Type _)     = False
 889 exprIsBig (Lam _ e)    = exprIsBig e
 890 exprIsBig (App f a)    = exprIsBig f || exprIsBig a
 891 exprIsBig (Cast e _)   = exprIsBig e    -- Hopefully coercions are not too big!
 892 exprIsBig _            = True
 893 \end{code}
 894
 895
 896
 897 %************************************************************************
 898 %*                                                                      *
 899 \subsection{The size of an expression}
 900 %*                                                                      *
 901 %************************************************************************
 902
 903 \begin{code}
 904 coreBindsSize :: [CoreBind] -> Int
 905 coreBindsSize bs = foldr ((+) . bindSize) 0 bs
 906
 907 exprSize :: CoreExpr -> Int
 908 -- ^ A measure of the size of the expressions, strictly greater than 0
 909 -- It also forces the expression pretty drastically as a side effect
 910 exprSize (Var v)         = v `seq` 1
 911 exprSize (Lit lit)       = lit `seq` 1
 912 exprSize (App f a)       = exprSize f + exprSize a
 913 exprSize (Lam b e)       = varSize b + exprSize e
 914 exprSize (Let b e)       = bindSize b + exprSize e
 915 exprSize (Case e b t as) = seqType t `seq` exprSize e + varSize b + 1 + foldr ((+) . altSize) 0 as
 916 exprSize (Cast e co)     = (seqType co `seq` 1) + exprSize e
 917 exprSize (Note n e)      = noteSize n + exprSize e
 918 exprSize (Type t)        = seqType t `seq` 1
 919
 920 noteSize :: Note -> Int
 921 noteSize (SCC cc)       = cc `seq` 1
 922 noteSize (CoreNote s)   = s `seq` 1  -- hdaume: core annotations
 923
 924 varSize :: Var -> Int
 925 varSize b  | isTyVar b = 1
 926            | otherwise = seqType (idType b)             `seq`
 927                          megaSeqIdInfo (idInfo b)       `seq`
 928                          1
 929
 930 varsSize :: [Var] -> Int
 931 varsSize = sum . map varSize
 932
 933 bindSize :: CoreBind -> Int
 934 bindSize (NonRec b e) = varSize b + exprSize e
 935 bindSize (Rec prs)    = foldr ((+) . pairSize) 0 prs
 936
 937 pairSize :: (Var, CoreExpr) -> Int
 938 pairSize (b,e) = varSize b + exprSize e
 939
 940 altSize :: CoreAlt -> Int
 941 altSize (c,bs,e) = c `seq` varsSize bs + exprSize e
 942 \end{code}
 943
 944
 945 %************************************************************************
 946 %*                                                                      *
 947 \subsection{Hashing}
 948 %*                                                                      *
 949 %************************************************************************
 950
 951 \begin{code}
 952 hashExpr :: CoreExpr -> Int
 953 -- ^ Two expressions that hash to the same @Int@ may be equal (but may not be)
 954 -- Two expressions that hash to the different Ints are definitely unequal.
 955 --
 956 -- The emphasis is on a crude, fast hash, rather than on high precision.
 957 --
 958 -- But unequal here means \"not identical\"; two alpha-equivalent
 959 -- expressions may hash to the different Ints.
 960 --
 961 -- We must be careful that @\\x.x@ and @\\y.y@ map to the same hash code,
 962 -- (at least if we want the above invariant to be true).
 963
 964 hashExpr e = fromIntegral (hash_expr (1,emptyVarEnv) e .&. 0x7fffffff)
 965              -- UniqFM doesn't like negative Ints
 966
 967 type HashEnv = (Int, VarEnv Int)  -- Hash code for bound variables
 968
 969 hash_expr :: HashEnv -> CoreExpr -> Word32
 970 -- Word32, because we're expecting overflows here, and overflowing
 971 -- signed types just isn't cool.  In C it's even undefined.
 972 hash_expr env (Note _ e)              = hash_expr env e
 973 hash_expr env (Cast e _)              = hash_expr env e
 974 hash_expr env (Var v)                 = hashVar env v
 975 hash_expr _   (Lit lit)               = fromIntegral (hashLiteral lit)
 976 hash_expr env (App f e)               = hash_expr env f * fast_hash_expr env e
 977 hash_expr env (Let (NonRec b r) e)    = hash_expr (extend_env env b) e * fast_hash_expr env r
 978 hash_expr env (Let (Rec ((b,_):_)) e) = hash_expr (extend_env env b) e
 979 hash_expr env (Case e _ _ _)          = hash_expr env e
 980 hash_expr env (Lam b e)               = hash_expr (extend_env env b) e
 981 hash_expr _   (Type _)                = WARN(True, text "hash_expr: type") 1
 982 -- Shouldn't happen.  Better to use WARN than trace, because trace
 983 -- prevents the CPR optimisation kicking in for hash_expr.
 984
 985 fast_hash_expr :: HashEnv -> CoreExpr -> Word32
 986 fast_hash_expr env (Var v)      = hashVar env v
 987 fast_hash_expr env (Type t)     = fast_hash_type env t
 988 fast_hash_expr _   (Lit lit)    = fromIntegral (hashLiteral lit)
 989 fast_hash_expr env (Cast e _)   = fast_hash_expr env e
 990 fast_hash_expr env (Note _ e)   = fast_hash_expr env e
 991 fast_hash_expr env (App _ a)    = fast_hash_expr env a  -- A bit idiosyncratic ('a' not 'f')!
 992 fast_hash_expr _   _            = 1
 993
 994 fast_hash_type :: HashEnv -> Type -> Word32
 995 fast_hash_type env ty
 996   | Just tv <- getTyVar_maybe ty            = hashVar env tv
 997   | Just (tc,tys) <- splitTyConApp_maybe ty = let hash_tc = fromIntegral (hashName (tyConName tc))
 998                                               in foldr (\t n -> fast_hash_type env t + n) hash_tc tys
 999   | otherwise                               = 1
1000
1001 extend_env :: HashEnv -> Var -> (Int, VarEnv Int)
1002 extend_env (n,env) b = (n+1, extendVarEnv env b n)
1003
1004 hashVar :: HashEnv -> Var -> Word32
1005 hashVar (_,env) v
1006  = fromIntegral (lookupVarEnv env v `orElse` hashName (idName v))
1007 \end{code}
1008
1009 %************************************************************************
1010 %*                                                                      *
1011 \subsection{Determining non-updatable right-hand-sides}
1012 %*                                                                      *
1013 %************************************************************************
1014
1015 Top-level constructor applications can usually be allocated
1016 statically, but they can't if the constructor, or any of the
1017 arguments, come from another DLL (because we can't refer to static
1018 labels in other DLLs).
1019
1020 If this happens we simply make the RHS into an updatable thunk,
1021 and 'execute' it rather than allocating it statically.
1022
1023 \begin{code}
1024 -- | This function is called only on *top-level* right-hand sides.
1025 -- Returns @True@ if the RHS can be allocated statically in the output,
1026 -- with no thunks involved at all.
1027 rhsIsStatic :: PackageId -> CoreExpr -> Bool
1028 -- It's called (i) in TidyPgm.hasCafRefs to decide if the rhs is, or
1029 -- refers to, CAFs; (ii) in CoreToStg to decide whether to put an
1030 -- update flag on it and (iii) in DsExpr to decide how to expand
1031 -- list literals
1032 --
1033 -- The basic idea is that rhsIsStatic returns True only if the RHS is
1034 --      (a) a value lambda
1035 --      (b) a saturated constructor application with static args
1036 --
1037 -- BUT watch out for
1038 --  (i) Any cross-DLL references kill static-ness completely
1039 --      because they must be 'executed' not statically allocated
1040 --      ("DLL" here really only refers to Windows DLLs, on other platforms,
1041 --      this is not necessary)
1042 --
1043 -- (ii) We treat partial applications as redexes, because in fact we
1044 --      make a thunk for them that runs and builds a PAP
1045 --      at run-time.  The only appliations that are treated as
1046 --      static are *saturated* applications of constructors.
1047
1048 -- We used to try to be clever with nested structures like this:
1049 --              ys = (:) w ((:) w [])
1050 -- on the grounds that CorePrep will flatten ANF-ise it later.
1051 -- But supporting this special case made the function much more
1052 -- complicated, because the special case only applies if there are no
1053 -- enclosing type lambdas:
1054 --              ys = /\ a -> Foo (Baz ([] a))
1055 -- Here the nested (Baz []) won't float out to top level in CorePrep.
1056 --
1057 -- But in fact, even without -O, nested structures at top level are
1058 -- flattened by the simplifier, so we don't need to be super-clever here.
1059 --
1060 -- Examples
1061 --
1062 --      f = \x::Int. x+7        TRUE
1063 --      p = (True,False)        TRUE
1064 --
1065 --      d = (fst p, False)      FALSE because there's a redex inside
1066 --                              (this particular one doesn't happen but...)
1067 --
1068 --      h = D# (1.0## /## 2.0##)        FALSE (redex again)
1069 --      n = /\a. Nil a                  TRUE
1070 --
1071 --      t = /\a. (:) (case w a of ...) (Nil a)  FALSE (redex)
1072 --
1073 --
1074 -- This is a bit like CoreUtils.exprIsHNF, with the following differences:
1075 --    a) scc "foo" (\x -> ...) is updatable (so we catch the right SCC)
1076 --
1077 --    b) (C x xs), where C is a contructor is updatable if the application is
1078 --         dynamic
1079 --
1080 --    c) don't look through unfolding of f in (f x).
1081
1082 rhsIsStatic _this_pkg rhs = is_static False rhs
1083   where
1084   is_static :: Bool     -- True <=> in a constructor argument; must be atomic
1085           -> CoreExpr -> Bool
1086
1087   is_static False (Lam b e) = isRuntimeVar b || is_static False e
1088
1089   is_static _      (Note (SCC _) _) = False
1090   is_static in_arg (Note _ e)       = is_static in_arg e
1091   is_static in_arg (Cast e _)       = is_static in_arg e
1092
1093   is_static _      (Lit lit)
1094     = case lit of
1095         MachLabel _ _ _ -> False
1096         _             -> True
1097         -- A MachLabel (foreign import "&foo") in an argument
1098         -- prevents a constructor application from being static.  The
1099         -- reason is that it might give rise to unresolvable symbols
1100         -- in the object file: under Linux, references to "weak"
1101         -- symbols from the data segment give rise to "unresolvable
1102         -- relocation" errors at link time This might be due to a bug
1103         -- in the linker, but we'll work around it here anyway.
1104         -- SDM 24/2/2004
1105
1106   is_static in_arg other_expr = go other_expr 0
1107    where
1108     go (Var f) n_val_args
1109 #if mingw32_TARGET_OS
1110         | not (isDllName _this_pkg (idName f))
1111 #endif
1112         =  saturated_data_con f n_val_args
1113         || (in_arg && n_val_args == 0)
1114                 -- A naked un-applied variable is *not* deemed a static RHS
1115                 -- E.g.         f = g
1116                 -- Reason: better to update so that the indirection gets shorted
1117                 --         out, and the true value will be seen
1118                 -- NB: if you change this, you'll break the invariant that THUNK_STATICs
1119                 --     are always updatable.  If you do so, make sure that non-updatable
1120                 --     ones have enough space for their static link field!
1121
1122     go (App f a) n_val_args
1123         | isTypeArg a                    = go f n_val_args
1124         | not in_arg && is_static True a = go f (n_val_args + 1)
1125         -- The (not in_arg) checks that we aren't in a constructor argument;
1126         -- if we are, we don't allow (value) applications of any sort
1127         --
1128         -- NB. In case you wonder, args are sometimes not atomic.  eg.
1129         --   x = D# (1.0## /## 2.0##)
1130         -- can't float because /## can fail.
1131
1132     go (Note (SCC _) _) _          = False
1133     go (Note _ f)       n_val_args = go f n_val_args
1134     go (Cast e _)       n_val_args = go e n_val_args
1135
1136     go _                _          = False
1137
1138     saturated_data_con f n_val_args
1139         = case isDataConWorkId_maybe f of
1140             Just dc -> n_val_args == dataConRepArity dc
1141             Nothing -> False
1142 \end{code}