compiler/coreSyn/PprExternalCore.lhs

   1 %
   2 % (c) The University of Glasgow 2001-2006
   3 %
   4
   5 \begin{code}
   6 module PprExternalCore () where
   7
   8 import Encoding
   9 import ExternalCore
  10
  11 import Pretty
  12 import Data.Char
  13 import Data.Ratio
  14
  15 instance Show Module where
  16   showsPrec _ m = shows (pmodule m)
  17
  18 instance Show Tdef where
  19   showsPrec _ t = shows (ptdef t)
  20
  21 instance Show Cdef where
  22   showsPrec _ c = shows (pcdef c)
  23
  24 instance Show Vdefg where
  25   showsPrec _ v = shows (pvdefg v)
  26
  27 instance Show Exp where
  28   showsPrec _ e = shows (pexp e)
  29
  30 instance Show Alt where
  31   showsPrec _ a = shows (palt a)
  32
  33 instance Show Ty where
  34   showsPrec _ t = shows (pty t)
  35
  36 instance Show Kind where
  37   showsPrec _ k = shows (pkind k)
  38
  39 instance Show Lit where
  40   showsPrec _ l = shows (plit l)
  41
  42
  43 indent :: Doc -> Doc
  44 indent = nest 2
  45
  46 pmodule :: Module -> Doc
  47 pmodule (Module mname tdefs vdefgs) =
  48   (text "%module" <+> text mname)
  49     $$ indent ((vcat (map ((<> char ';') . ptdef) tdefs))
  50                $$ (vcat (map ((<> char ';') . pvdefg) vdefgs)))
  51
  52 ptdef :: Tdef -> Doc
  53 ptdef (Data tcon tbinds cdefs) =
  54   (text "%data" <+> pqname tcon <+> (hsep (map ptbind tbinds)) <+> char '=')
  55   $$ indent (braces ((vcat (punctuate (char ';') (map pcdef cdefs)))))
  56
  57 ptdef (Newtype tcon coercion tbinds rep) =
  58   text "%newtype" <+> pqname tcon <+> pqname coercion
  59    <+> (hsep (map ptbind tbinds)) $$ indent repclause
  60        where repclause = char '=' <+> pty rep
  61
  62 pcdef :: Cdef -> Doc
  63 pcdef (Constr dcon tbinds tys)  =
  64   (pqname dcon) <+> (sep [hsep (map pattbind tbinds),sep (map paty tys)])
  65 pcdef (GadtConstr dcon ty)  =
  66   (pqname dcon) <+> text "::" <+> pty ty
  67
  68 pname :: Id -> Doc
  69 pname id = text (zEncodeString id)
  70
  71 pqname :: Qual Id -> Doc
  72 pqname ("",id) = pname id
  73 pqname (m,id)  = text m <> char '.' <> pname id
  74
  75 ptbind, pattbind :: Tbind -> Doc
  76 ptbind (t,Klifted) = pname t
  77 ptbind (t,k) = parens (pname t <> text "::" <> pkind k)
  78
  79 pattbind (t,k) = char '@' <> ptbind (t,k)
  80
  81 pakind, pkind :: Kind -> Doc
  82 pakind (Klifted) = char '*'
  83 pakind (Kunlifted) = char '#'
  84 pakind (Kopen) = char '?'
  85 pakind k = parens (pkind k)
  86
  87 pkind (Karrow k1 k2) = parens (pakind k1 <> text "->" <> pkind k2)
  88 pkind (Keq t1 t2) = parens (parens (pty t1) <+> text ":=:" <+>
  89                             parens (pty t2))
  90 pkind k = pakind k
  91
  92 paty, pbty, pty :: Ty -> Doc
  93 paty (Tvar n) = pname n
  94 paty (Tcon c) = pqname c
  95 paty t = parens (pty t)
  96
  97 pbty (Tapp(Tapp(Tcon tc) t1) t2) | tc == tcArrow = parens(fsep [pbty t1, text "->",pty t2])
  98 pbty (Tapp t1 t2) = parens $ pappty t1 [t2]
  99 pbty t = paty t
 100
 101 pty (Tapp(Tapp(Tcon tc) t1) t2) | tc == tcArrow = fsep [pbty t1, text "->",pty t2]
 102 pty (Tforall tb t) = text "%forall" <+> pforall [tb] t
 103 pty (TransCoercion t1 t2) =
 104   sep [text "%trans", paty t1, paty t2]
 105 pty (SymCoercion t) =
 106   sep [text "%sym", paty t]
 107 pty (UnsafeCoercion t1 t2) =
 108   sep [text "%unsafe", paty t1, paty t2]
 109 pty (NthCoercion n t) =
 110   sep [text "%nth", int n, paty t]
 111 pty (InstCoercion t1 t2) =
 112   sep [text "%inst", paty t1, paty t2]
 113 pty t = pbty t
 114
 115 pappty :: Ty -> [Ty] -> Doc
 116 pappty (Tapp t1 t2) ts = pappty t1 (t2:ts)
 117 pappty t ts = sep (map paty (t:ts))
 118
 119 pforall :: [Tbind] -> Ty -> Doc
 120 pforall tbs (Tforall tb t) = pforall (tbs ++ [tb]) t
 121 pforall tbs t = hsep (map ptbind tbs) <+> char '.' <+> pty t
 122
 123 pvdefg :: Vdefg -> Doc
 124 pvdefg (Rec vdefs) = text "%rec" $$ braces (indent (vcat (punctuate (char ';') (map pvdef vdefs))))
 125 pvdefg (Nonrec vdef) = pvdef vdef
 126
 127 pvdef :: Vdef -> Doc
 128 -- TODO: Think about whether %local annotations are actually needed.
 129 -- Right now, the local flag is never used, because the Core doc doesn't
 130 -- explain the meaning of %local.
 131 pvdef (_l,v,t,e) = sep [(pqname v <+> text "::" <+> pty t <+> char '='),
 132                     indent (pexp e)]
 133
 134 paexp, pfexp, pexp :: Exp -> Doc
 135 paexp (Var x) = pqname x
 136 paexp (Dcon x) = pqname x
 137 paexp (Lit l) = plit l
 138 paexp e = parens(pexp e)
 139
 140 plamexp :: [Bind] -> Exp -> Doc
 141 plamexp bs (Lam b e) = plamexp (bs ++ [b]) e
 142 plamexp bs e = sep [sep (map pbind bs) <+> text "->",
 143                     indent (pexp e)]
 144
 145 pbind :: Bind -> Doc
 146 pbind (Tb tb) = char '@' <+> ptbind tb
 147 pbind (Vb vb) = pvbind vb
 148
 149 pfexp (App e1 e2) = pappexp e1 [Left e2]
 150 pfexp (Appt e t) = pappexp e [Right t]
 151 pfexp e = paexp e
 152
 153 pappexp :: Exp -> [Either Exp Ty] -> Doc
 154 pappexp (App e1 e2) as = pappexp e1 (Left e2:as)
 155 pappexp (Appt e t) as = pappexp e (Right t:as)
 156 pappexp e as = fsep (paexp e : map pa as)
 157            where pa (Left e) = paexp e
 158                  pa (Right t) = char '@' <+> paty t
 159
 160 pexp (Lam b e) = char '\\' <+> plamexp [b] e
 161 pexp (Let vd e) = (text "%let" <+> pvdefg vd) $$ (text "%in" <+> pexp e)
 162 pexp (Case e vb ty alts) = sep [text "%case" <+> paty ty <+> paexp e,
 163                              text "%of" <+> pvbind vb]
 164                         $$ (indent (braces (vcat (punctuate (char ';') (map palt alts)))))
 165 pexp (Cast e co) = (text "%cast" <+> parens (pexp e)) $$ paty co
 166 pexp (Note s e) = (text "%note" <+> pstring s) $$ pexp e
 167 pexp (External n cc t) = (text "%external" <+> text cc <+> pstring n) $$ paty t
 168 pexp (DynExternal cc t) = (text "%dynexternal" <+> text cc) $$ paty t
 169 pexp (Label n) = (text "%label" <+> pstring n)
 170 pexp e = pfexp e
 171
 172 pvbind :: Vbind -> Doc
 173 pvbind (x,t) = parens(pname x <> text "::" <> pty t)
 174
 175 palt :: Alt -> Doc
 176 palt (Acon c tbs vbs e) =
 177         sep [pqname c,
 178              sep (map pattbind tbs),
 179              sep (map pvbind vbs) <+> text "->"]
 180         $$ indent (pexp e)
 181 palt (Alit l e) =
 182         (plit l <+>  text "->")
 183         $$ indent (pexp e)
 184 palt (Adefault e) =
 185         (text "%_ ->")
 186         $$ indent (pexp e)
 187
 188 plit :: Lit -> Doc
 189 plit (Lint i t) = parens (integer i <> text "::" <> pty t)
 190 -- we use (text (show (numerator r))) (and the same for denominator)
 191 -- because "(rational r)" was printing out things like "2.0e-2" (which
 192 -- isn't External Core), and (text (show r)) was printing out things
 193 -- like "((-1)/5)" which isn't either (it should be "(-1/5)").
 194 plit (Lrational r t) = parens (text (show (numerator r)) <+> char '%'
 195    <+> text (show (denominator r)) <>  text "::" <> pty t)
 196 plit (Lchar c t) = parens (text ("\'" ++ escape [c] ++ "\'") <> text "::" <> pty t)
 197 plit (Lstring s t) = parens (pstring s <> text "::" <> pty t)
 198
 199 pstring :: String -> Doc
 200 pstring s = doubleQuotes(text (escape s))
 201
 202 escape :: String -> String
 203 escape s = foldr f [] (map ord s)
 204     where
 205      f cv rest
 206         | cv > 0xFF = '\\':'x':hs ++ rest
 207         | (cv < 0x20 || cv > 0x7e || cv == 0x22 || cv == 0x27 || cv == 0x5c) =
 208          '\\':'x':h1:h0:rest
 209            where (q1,r1) = quotRem cv 16
 210                  h1 = intToDigit q1
 211                  h0 = intToDigit r1
 212                  hs = dropWhile (=='0') $ reverse $ mkHex cv
 213                  mkHex 0 = ""
 214                  mkHex cv = intToDigit r : mkHex q
 215                     where (q,r) = quotRem cv 16
 216      f cv rest = (chr cv):rest
 217
 218 \end{code}
 219
 220
 221
 222