compiler/deSugar/Coverage.lhs

   1 %
   2 % (c) Galois, 2006
   3 % (c) University of Glasgow, 2007
   4 %
   5 \section[Coverage]{@coverage@: the main function}
   6
   7 \begin{code}
   8 module Coverage (addCoverageTicksToBinds, hpcInitCode) where
   9
  10 import HsSyn
  11 import Module
  12 import Outputable
  13 import DynFlags
  14 import Control.Monad
  15 import SrcLoc
  16 import ErrUtils
  17 import Name
  18 import Bag
  19 import Id
  20 import VarSet
  21 import Data.List
  22 import FastString
  23 import HscTypes
  24 import StaticFlags
  25 import TyCon
  26 import MonadUtils
  27 import Maybes
  28 import CLabel
  29 import Util
  30
  31 import Data.Array
  32 import System.Directory ( createDirectoryIfMissing )
  33
  34 import Trace.Hpc.Mix
  35 import Trace.Hpc.Util
  36
  37 import BreakArray
  38 import Data.HashTable   ( hashString )
  39 import Data.Map (Map)
  40 import qualified Data.Map as Map
  41 \end{code}
  42
  43
  44 %************************************************************************
  45 %*                                                                      *
  46 %*              The main function: addCoverageTicksToBinds
  47 %*                                                                      *
  48 %************************************************************************
  49
  50 \begin{code}
  51 addCoverageTicksToBinds
  52         :: DynFlags
  53         -> Module
  54         -> ModLocation          -- of the current module
  55         -> [TyCon]              -- type constructor in this module
  56         -> LHsBinds Id
  57         -> IO (LHsBinds Id, HpcInfo, ModBreaks)
  58
  59 addCoverageTicksToBinds dflags mod mod_loc tyCons binds =
  60  case ml_hs_file mod_loc of
  61  Nothing -> return (binds, emptyHpcInfo False, emptyModBreaks)
  62  Just orig_file -> do
  63
  64   if "boot" `isSuffixOf` orig_file then return (binds, emptyHpcInfo False, emptyModBreaks) else do
  65
  66   -- Now, we try look for a file generated from a .hsc file to a .hs file, by peeking ahead.
  67
  68   let top_pos = catMaybes $ foldrBag (\ (L pos _) rest -> srcSpanFileName_maybe pos : rest) [] binds
  69   let orig_file2 = case top_pos of
  70                      (file_name:_)
  71                        | ".hsc" `isSuffixOf` unpackFS file_name -> unpackFS file_name
  72                      _ -> orig_file
  73
  74   let mod_name = moduleNameString (moduleName mod)
  75
  76   let (binds1,_,st)
  77                  = unTM (addTickLHsBinds binds)
  78                    (TTE
  79                        { fileName    = mkFastString orig_file2
  80                       , declPath     = []
  81                       , inScope      = emptyVarSet
  82                       , blackList    = Map.fromList [ (getSrcSpan (tyConName tyCon),())
  83                                                     | tyCon <- tyCons ]
  84                        })
  85                    (TT
  86                       { tickBoxCount = 0
  87                       , mixEntries   = []
  88                       })
  89
  90   let entries = reverse $ mixEntries st
  91
  92   -- write the mix entries for this module
  93   hashNo <- if opt_Hpc then do
  94      let hpc_dir = hpcDir dflags
  95
  96      let hpc_mod_dir = if modulePackageId mod == mainPackageId
  97                        then hpc_dir
  98                        else hpc_dir ++ "/" ++ packageIdString (modulePackageId mod)
  99
 100      let tabStop = 1 -- <tab> counts as a normal char in GHC's location ranges.
 101      createDirectoryIfMissing True hpc_mod_dir
 102      modTime <- getModificationTime orig_file2
 103      let entries' = [ (hpcPos, box)
 104                     | (span,_,_,box) <- entries, hpcPos <- [mkHpcPos span] ]
 105      when (length entries' /= tickBoxCount st) $ do
 106        panic "the number of .mix entries are inconsistent"
 107      let hashNo = mixHash orig_file2 modTime tabStop entries'
 108      mixCreate hpc_mod_dir mod_name
 109                $ Mix orig_file2 modTime (toHash hashNo) tabStop entries'
 110      return $ hashNo
 111    else do
 112      return $ 0
 113
 114   -- Todo: use proper src span type
 115   breakArray <- newBreakArray $ length entries
 116
 117   let locsTicks = listArray (0,tickBoxCount st-1)
 118                      [ span | (span,_,_,_) <- entries ]
 119       varsTicks = listArray (0,tickBoxCount st-1)
 120                      [ vars | (_,_,vars,_) <- entries ]
 121       declsTicks= listArray (0,tickBoxCount st-1)
 122                      [ decls | (_,decls,_,_) <- entries ]
 123       modBreaks = emptyModBreaks
 124                   { modBreaks_flags = breakArray
 125                   , modBreaks_locs  = locsTicks
 126                   , modBreaks_vars  = varsTicks
 127                   , modBreaks_decls = declsTicks
 128                   }
 129
 130   doIfSet_dyn dflags  Opt_D_dump_hpc $ do
 131           printDump (pprLHsBinds binds1)
 132
 133   return (binds1, HpcInfo (tickBoxCount st) hashNo, modBreaks)
 134 \end{code}
 135
 136
 137 \begin{code}
 138 liftL :: (Monad m) => (a -> m a) -> Located a -> m (Located a)
 139 liftL f (L loc a) = do
 140   a' <- f a
 141   return $ L loc a'
 142
 143 addTickLHsBinds :: LHsBinds Id -> TM (LHsBinds Id)
 144 addTickLHsBinds binds = mapBagM addTickLHsBind binds
 145
 146 addTickLHsBind :: LHsBind Id -> TM (LHsBind Id)
 147 addTickLHsBind (L pos bind@(AbsBinds { abs_binds = binds })) = do
 148   binds' <- addTickLHsBinds binds
 149   return $ L pos $ bind { abs_binds = binds' }
 150 addTickLHsBind (L pos (funBind@(FunBind { fun_id = (L _ id)  }))) = do
 151   let name = getOccString id
 152   decl_path <- getPathEntry
 153
 154   (fvs, (MatchGroup matches' ty)) <-
 155         getFreeVars $
 156         addPathEntry name $
 157         addTickMatchGroup (fun_matches funBind)
 158
 159   blackListed <- isBlackListed pos
 160
 161   -- Todo: we don't want redundant ticks on simple pattern bindings
 162   -- We don't want to generate code for blacklisted positions
 163   if blackListed || (not opt_Hpc && isSimplePatBind funBind)
 164      then
 165         return $ L pos $ funBind { fun_matches = MatchGroup matches' ty
 166                                  , fun_tick = Nothing
 167                                  }
 168      else do
 169         tick_no <- allocATickBox (if null decl_path
 170                                      then TopLevelBox [name]
 171                                      else LocalBox (decl_path ++ [name]))
 172                                 pos fvs
 173
 174         return $ L pos $ funBind { fun_matches = MatchGroup matches' ty
 175                                  , fun_tick = tick_no
 176                                  }
 177    where
 178    -- a binding is a simple pattern binding if it is a funbind with zero patterns
 179    isSimplePatBind :: HsBind a -> Bool
 180    isSimplePatBind funBind = matchGroupArity (fun_matches funBind) == 0
 181
 182 -- TODO: Revisit this
 183 addTickLHsBind (L pos (pat@(PatBind { pat_rhs = rhs }))) = do
 184   let name = "(...)"
 185   rhs' <- addPathEntry name $ addTickGRHSs False rhs
 186 {-
 187   decl_path <- getPathEntry
 188   tick_me <- allocTickBox (if null decl_path
 189                            then TopLevelBox [name]
 190                            else LocalBox (name : decl_path))
 191 -}
 192   return $ L pos $ pat { pat_rhs = rhs' }
 193
 194 -- Only internal stuff, not from source, uses VarBind, so we ignore it.
 195 addTickLHsBind var_bind@(L _ (VarBind {})) = return var_bind
 196
 197 -- Add a tick to the expression no matter what it is.  There is one exception:
 198 -- for the debugger, if the expression is a 'let', then we don't want to add
 199 -- a tick here because there will definititely be a tick on the body anyway.
 200 addTickLHsExprAlways :: LHsExpr Id -> TM (LHsExpr Id)
 201 addTickLHsExprAlways (L pos e0)
 202   | not opt_Hpc, HsLet _ _ <- e0 = addTickLHsExprNever (L pos e0)
 203   | otherwise = allocTickBox (ExpBox False) pos $ addTickHsExpr e0
 204
 205 addTickLHsExprNeverOrAlways :: LHsExpr Id -> TM (LHsExpr Id)
 206 addTickLHsExprNeverOrAlways e
 207     | opt_Hpc   = addTickLHsExprNever e
 208     | otherwise = addTickLHsExprAlways e
 209
 210 addTickLHsExprNeverOrMaybe :: LHsExpr Id -> TM (LHsExpr Id)
 211 addTickLHsExprNeverOrMaybe e
 212     | opt_Hpc   = addTickLHsExprNever e
 213     | otherwise = addTickLHsExpr e
 214
 215 -- version of addTick that does not actually add a tick,
 216 -- because the scope of this tick is completely subsumed by
 217 -- another.
 218 addTickLHsExprNever :: LHsExpr Id -> TM (LHsExpr Id)
 219 addTickLHsExprNever (L pos e0) = do
 220     e1 <- addTickHsExpr e0
 221     return $ L pos e1
 222
 223 -- selectively add ticks to interesting expressions
 224 addTickLHsExpr :: LHsExpr Id -> TM (LHsExpr Id)
 225 addTickLHsExpr (L pos e0) = do
 226     if opt_Hpc || isGoodBreakExpr e0
 227        then do
 228           allocTickBox (ExpBox False) pos $ addTickHsExpr e0
 229        else do
 230           e1 <- addTickHsExpr e0
 231           return $ L pos e1
 232
 233 -- general heuristic: expressions which do not denote values are good break points
 234 isGoodBreakExpr :: HsExpr Id -> Bool
 235 isGoodBreakExpr (HsApp {})     = True
 236 isGoodBreakExpr (OpApp {})     = True
 237 isGoodBreakExpr (NegApp {})    = True
 238 isGoodBreakExpr (HsCase {})    = True
 239 isGoodBreakExpr (HsIf {})      = True
 240 isGoodBreakExpr (RecordCon {}) = True
 241 isGoodBreakExpr (RecordUpd {}) = True
 242 isGoodBreakExpr (ArithSeq {})  = True
 243 isGoodBreakExpr (PArrSeq {})   = True
 244 isGoodBreakExpr _other         = False
 245
 246 addTickLHsExprOptAlt :: Bool -> LHsExpr Id -> TM (LHsExpr Id)
 247 addTickLHsExprOptAlt oneOfMany (L pos e0)
 248   | not opt_Hpc = addTickLHsExpr (L pos e0)
 249   | otherwise =
 250     allocTickBox (ExpBox oneOfMany) pos $
 251         addTickHsExpr e0
 252
 253 addBinTickLHsExpr :: (Bool -> BoxLabel) -> LHsExpr Id -> TM (LHsExpr Id)
 254 addBinTickLHsExpr boxLabel (L pos e0) =
 255     allocBinTickBox boxLabel pos $
 256         addTickHsExpr e0
 257
 258 addTickHsExpr :: HsExpr Id -> TM (HsExpr Id)
 259 addTickHsExpr e@(HsVar id) = do freeVar id; return e
 260 addTickHsExpr e@(HsIPVar _) = return e
 261 addTickHsExpr e@(HsOverLit _) = return e
 262 addTickHsExpr e@(HsLit _) = return e
 263 addTickHsExpr (HsLam matchgroup) =
 264         liftM HsLam (addTickMatchGroup matchgroup)
 265 addTickHsExpr (HsApp e1 e2) =
 266         liftM2 HsApp (addTickLHsExprNever e1) (addTickLHsExpr e2)
 267 addTickHsExpr (OpApp e1 e2 fix e3) =
 268         liftM4 OpApp
 269                 (addTickLHsExpr e1)
 270                 (addTickLHsExprNever e2)
 271                 (return fix)
 272                 (addTickLHsExpr e3)
 273 addTickHsExpr (NegApp e neg) =
 274         liftM2 NegApp
 275                 (addTickLHsExpr e)
 276                 (addTickSyntaxExpr hpcSrcSpan neg)
 277 addTickHsExpr (HsPar e) = liftM HsPar (addTickLHsExprNeverOrMaybe e)
 278 addTickHsExpr (SectionL e1 e2) =
 279         liftM2 SectionL
 280                 (addTickLHsExpr e1)
 281                 (addTickLHsExpr e2)
 282 addTickHsExpr (SectionR e1 e2) =
 283         liftM2 SectionR
 284                 (addTickLHsExpr e1)
 285                 (addTickLHsExpr e2)
 286 addTickHsExpr (ExplicitTuple es boxity) =
 287         liftM2 ExplicitTuple
 288                 (mapM addTickTupArg es)
 289                 (return boxity)
 290 addTickHsExpr (HsCase e mgs) =
 291         liftM2 HsCase
 292                 (addTickLHsExpr e)
 293                 (addTickMatchGroup mgs)
 294 addTickHsExpr (HsIf cnd e1 e2 e3) =
 295         liftM3 (HsIf cnd)
 296                 (addBinTickLHsExpr (BinBox CondBinBox) e1)
 297                 (addTickLHsExprOptAlt True e2)
 298                 (addTickLHsExprOptAlt True e3)
 299 addTickHsExpr (HsLet binds e) =
 300         bindLocals (collectLocalBinders binds) $
 301         liftM2 HsLet
 302                 (addTickHsLocalBinds binds) -- to think about: !patterns.
 303                 (addTickLHsExprNeverOrAlways e)
 304 addTickHsExpr (HsDo cxt stmts srcloc)
 305   = do { (stmts', _) <- addTickLStmts' forQual stmts (return ())
 306        ; return (HsDo cxt stmts' srcloc) }
 307   where
 308         forQual = case cxt of
 309                     ListComp -> Just $ BinBox QualBinBox
 310                     _        -> Nothing
 311 addTickHsExpr (ExplicitList ty es) =
 312         liftM2 ExplicitList
 313                 (return ty)
 314                 (mapM (addTickLHsExpr) es)
 315 addTickHsExpr (ExplicitPArr ty es) =
 316         liftM2 ExplicitPArr
 317                 (return ty)
 318                 (mapM (addTickLHsExpr) es)
 319 addTickHsExpr (RecordCon id ty rec_binds) =
 320         liftM3 RecordCon
 321                 (return id)
 322                 (return ty)
 323                 (addTickHsRecordBinds rec_binds)
 324 addTickHsExpr (RecordUpd e rec_binds cons tys1 tys2) =
 325         liftM5 RecordUpd
 326                 (addTickLHsExpr e)
 327                 (addTickHsRecordBinds rec_binds)
 328                 (return cons) (return tys1) (return tys2)
 329
 330 addTickHsExpr (ExprWithTySigOut e ty) =
 331         liftM2 ExprWithTySigOut
 332                 (addTickLHsExprNever e) -- No need to tick the inner expression
 333                                     -- for expressions with signatures
 334                 (return ty)
 335 addTickHsExpr (ArithSeq  ty arith_seq) =
 336         liftM2 ArithSeq
 337                 (return ty)
 338                 (addTickArithSeqInfo arith_seq)
 339 addTickHsExpr (HsTickPragma _ (L pos e0)) = do
 340     e2 <- allocTickBox (ExpBox False) pos $
 341                 addTickHsExpr e0
 342     return $ unLoc e2
 343 addTickHsExpr (PArrSeq   ty arith_seq) =
 344         liftM2 PArrSeq
 345                 (return ty)
 346                 (addTickArithSeqInfo arith_seq)
 347 addTickHsExpr (HsSCC nm e) =
 348         liftM2 HsSCC
 349                 (return nm)
 350                 (addTickLHsExpr e)
 351 addTickHsExpr (HsCoreAnn nm e) =
 352         liftM2 HsCoreAnn
 353                 (return nm)
 354                 (addTickLHsExpr e)
 355 addTickHsExpr e@(HsBracket     {}) = return e
 356 addTickHsExpr e@(HsBracketOut  {}) = return e
 357 addTickHsExpr e@(HsSpliceE  {}) = return e
 358 addTickHsExpr (HsProc pat cmdtop) =
 359         liftM2 HsProc
 360                 (addTickLPat pat)
 361                 (liftL (addTickHsCmdTop) cmdtop)
 362 addTickHsExpr (HsWrap w e) =
 363         liftM2 HsWrap
 364                 (return w)
 365                 (addTickHsExpr e)       -- explicitly no tick on inside
 366
 367 addTickHsExpr (HsArrApp  e1 e2 ty1 arr_ty lr) =
 368         liftM5 HsArrApp
 369                (addTickLHsExpr e1)
 370                (addTickLHsExpr e2)
 371                (return ty1)
 372                (return arr_ty)
 373                (return lr)
 374
 375 addTickHsExpr (HsArrForm e fix cmdtop) =
 376         liftM3 HsArrForm
 377                (addTickLHsExpr e)
 378                (return fix)
 379                (mapM (liftL (addTickHsCmdTop)) cmdtop)
 380
 381 addTickHsExpr e@(HsType _) = return e
 382
 383 -- Others dhould never happen in expression content.
 384 addTickHsExpr e  = pprPanic "addTickHsExpr" (ppr e)
 385
 386 addTickTupArg :: HsTupArg Id -> TM (HsTupArg Id)
 387 addTickTupArg (Present e)  = do { e' <- addTickLHsExpr e; return (Present e') }
 388 addTickTupArg (Missing ty) = return (Missing ty)
 389
 390 addTickMatchGroup :: MatchGroup Id -> TM (MatchGroup Id)
 391 addTickMatchGroup (MatchGroup matches ty) = do
 392   let isOneOfMany = matchesOneOfMany matches
 393   matches' <- mapM (liftL (addTickMatch isOneOfMany)) matches
 394   return $ MatchGroup matches' ty
 395
 396 addTickMatch :: Bool -> Match Id -> TM (Match Id)
 397 addTickMatch isOneOfMany (Match pats opSig gRHSs) =
 398   bindLocals (collectPatsBinders pats) $ do
 399     gRHSs' <- addTickGRHSs isOneOfMany gRHSs
 400     return $ Match pats opSig gRHSs'
 401
 402 addTickGRHSs :: Bool -> GRHSs Id -> TM (GRHSs Id)
 403 addTickGRHSs isOneOfMany (GRHSs guarded local_binds) = do
 404   bindLocals binders $ do
 405     local_binds' <- addTickHsLocalBinds local_binds
 406     guarded' <- mapM (liftL (addTickGRHS isOneOfMany)) guarded
 407     return $ GRHSs guarded' local_binds'
 408   where
 409     binders = collectLocalBinders local_binds
 410
 411 addTickGRHS :: Bool -> GRHS Id -> TM (GRHS Id)
 412 addTickGRHS isOneOfMany (GRHS stmts expr) = do
 413   (stmts',expr') <- addTickLStmts' (Just $ BinBox $ GuardBinBox) stmts
 414                         (if opt_Hpc then addTickLHsExprOptAlt isOneOfMany expr
 415                                     else addTickLHsExprAlways expr)
 416   return $ GRHS stmts' expr'
 417
 418 addTickLStmts :: (Maybe (Bool -> BoxLabel)) -> [LStmt Id] -> TM [LStmt Id]
 419 addTickLStmts isGuard stmts = do
 420   (stmts, _) <- addTickLStmts' isGuard stmts (return ())
 421   return stmts
 422
 423 addTickLStmts' :: (Maybe (Bool -> BoxLabel)) -> [LStmt Id] -> TM a
 424                -> TM ([LStmt Id], a)
 425 addTickLStmts' isGuard lstmts res
 426   = bindLocals (collectLStmtsBinders lstmts) $
 427     do { lstmts' <- mapM (liftL (addTickStmt isGuard)) lstmts
 428        ; a <- res
 429        ; return (lstmts', a) }
 430
 431 addTickStmt :: (Maybe (Bool -> BoxLabel)) -> Stmt Id -> TM (Stmt Id)
 432 addTickStmt _isGuard (LastStmt e ret) = do
 433         liftM2 LastStmt
 434                 (addTickLHsExprAlways e)
 435                 (addTickSyntaxExpr hpcSrcSpan ret)
 436 addTickStmt _isGuard (BindStmt pat e bind fail) = do
 437         liftM4 BindStmt
 438                 (addTickLPat pat)
 439                 (addTickLHsExprAlways e)
 440                 (addTickSyntaxExpr hpcSrcSpan bind)
 441                 (addTickSyntaxExpr hpcSrcSpan fail)
 442 addTickStmt isGuard (ExprStmt e bind' guard' ty) = do
 443         liftM4 ExprStmt
 444                 (addTick isGuard e)
 445                 (addTickSyntaxExpr hpcSrcSpan bind')
 446                 (addTickSyntaxExpr hpcSrcSpan guard')
 447                 (return ty)
 448 addTickStmt _isGuard (LetStmt binds) = do
 449         liftM LetStmt
 450                 (addTickHsLocalBinds binds)
 451 addTickStmt isGuard (ParStmt pairs mzipExpr bindExpr returnExpr) = do
 452     liftM4 ParStmt
 453         (mapM (addTickStmtAndBinders isGuard) pairs)
 454         (addTickSyntaxExpr hpcSrcSpan mzipExpr)
 455         (addTickSyntaxExpr hpcSrcSpan bindExpr)
 456         (addTickSyntaxExpr hpcSrcSpan returnExpr)
 457
 458 addTickStmt isGuard (TransformStmt stmts ids usingExpr maybeByExpr returnExpr bindExpr) = do
 459     t_s <- (addTickLStmts isGuard stmts)
 460     t_u <- (addTickLHsExprAlways usingExpr)
 461     t_m <- (addTickMaybeByLHsExpr maybeByExpr)
 462     t_r <- (addTickSyntaxExpr hpcSrcSpan returnExpr)
 463     t_b <- (addTickSyntaxExpr hpcSrcSpan bindExpr)
 464     return $ TransformStmt t_s ids t_u t_m t_r t_b
 465
 466 addTickStmt isGuard (GroupStmt stmts binderMap by using returnExpr bindExpr liftMExpr) = do
 467     t_s <- (addTickLStmts isGuard stmts)
 468     t_y <- (fmapMaybeM  addTickLHsExprAlways by)
 469     t_u <- (fmapEitherM addTickLHsExprAlways (addTickSyntaxExpr hpcSrcSpan) using)
 470     t_f <- (addTickSyntaxExpr hpcSrcSpan returnExpr)
 471     t_b <- (addTickSyntaxExpr hpcSrcSpan bindExpr)
 472     t_m <- (addTickSyntaxExpr hpcSrcSpan liftMExpr)
 473     return $ GroupStmt t_s binderMap t_y t_u t_b t_f t_m
 474
 475 addTickStmt isGuard stmt@(RecStmt {})
 476   = do { stmts' <- addTickLStmts isGuard (recS_stmts stmt)
 477        ; ret'   <- addTickSyntaxExpr hpcSrcSpan (recS_ret_fn stmt)
 478        ; mfix'  <- addTickSyntaxExpr hpcSrcSpan (recS_mfix_fn stmt)
 479        ; bind'  <- addTickSyntaxExpr hpcSrcSpan (recS_bind_fn stmt)
 480        ; return (stmt { recS_stmts = stmts', recS_ret_fn = ret'
 481                       , recS_mfix_fn = mfix', recS_bind_fn = bind' }) }
 482
 483 addTick :: Maybe (Bool -> BoxLabel) -> LHsExpr Id -> TM (LHsExpr Id)
 484 addTick isGuard e | Just fn <- isGuard = addBinTickLHsExpr fn e
 485                   | otherwise          = addTickLHsExprAlways e
 486
 487 addTickStmtAndBinders :: Maybe (Bool -> BoxLabel) -> ([LStmt Id], a)
 488                       -> TM ([LStmt Id], a)
 489 addTickStmtAndBinders isGuard (stmts, ids) =
 490     liftM2 (,)
 491         (addTickLStmts isGuard stmts)
 492         (return ids)
 493
 494 addTickMaybeByLHsExpr :: Maybe (LHsExpr Id) -> TM (Maybe (LHsExpr Id))
 495 addTickMaybeByLHsExpr maybeByExpr =
 496     case maybeByExpr of
 497         Nothing -> return Nothing
 498         Just byExpr -> addTickLHsExprAlways byExpr >>= (return . Just)
 499
 500 addTickHsLocalBinds :: HsLocalBinds Id -> TM (HsLocalBinds Id)
 501 addTickHsLocalBinds (HsValBinds binds) =
 502         liftM HsValBinds
 503                 (addTickHsValBinds binds)
 504 addTickHsLocalBinds (HsIPBinds binds)  =
 505         liftM HsIPBinds
 506                 (addTickHsIPBinds binds)
 507 addTickHsLocalBinds (EmptyLocalBinds)  = return EmptyLocalBinds
 508
 509 addTickHsValBinds :: HsValBindsLR Id a -> TM (HsValBindsLR Id b)
 510 addTickHsValBinds (ValBindsOut binds sigs) =
 511         liftM2 ValBindsOut
 512                 (mapM (\ (rec,binds') ->
 513                                 liftM2 (,)
 514                                         (return rec)
 515                                         (addTickLHsBinds binds'))
 516                         binds)
 517                 (return sigs)
 518 addTickHsValBinds _ = panic "addTickHsValBinds"
 519
 520 addTickHsIPBinds :: HsIPBinds Id -> TM (HsIPBinds Id)
 521 addTickHsIPBinds (IPBinds ipbinds dictbinds) =
 522         liftM2 IPBinds
 523                 (mapM (liftL (addTickIPBind)) ipbinds)
 524                 (return dictbinds)
 525
 526 addTickIPBind :: IPBind Id -> TM (IPBind Id)
 527 addTickIPBind (IPBind nm e) =
 528         liftM2 IPBind
 529                 (return nm)
 530                 (addTickLHsExpr e)
 531
 532 -- There is no location here, so we might need to use a context location??
 533 addTickSyntaxExpr :: SrcSpan -> SyntaxExpr Id -> TM (SyntaxExpr Id)
 534 addTickSyntaxExpr pos x = do
 535         L _ x' <- addTickLHsExpr (L pos x)
 536         return $ x'
 537 -- we do not walk into patterns.
 538 addTickLPat :: LPat Id -> TM (LPat Id)
 539 addTickLPat pat = return pat
 540
 541 addTickHsCmdTop :: HsCmdTop Id -> TM (HsCmdTop Id)
 542 addTickHsCmdTop (HsCmdTop cmd tys ty syntaxtable) =
 543         liftM4 HsCmdTop
 544                 (addTickLHsCmd cmd)
 545                 (return tys)
 546                 (return ty)
 547                 (return syntaxtable)
 548
 549 addTickLHsCmd ::  LHsCmd Id -> TM (LHsCmd Id)
 550 addTickLHsCmd (L pos c0) = do
 551         c1 <- addTickHsCmd c0
 552         return $ L pos c1
 553
 554 addTickHsCmd :: HsCmd Id -> TM (HsCmd Id)
 555 addTickHsCmd (HsLam matchgroup) =
 556         liftM HsLam (addTickCmdMatchGroup matchgroup)
 557 addTickHsCmd (HsApp e1 e2) =
 558         liftM2 HsApp (addTickLHsExprNever e1) (addTickLHsExpr e2)
 559 addTickHsCmd (OpApp e1 c2 fix c3) =
 560         liftM4 OpApp
 561                 (addTickLHsExpr e1)
 562                 (addTickLHsCmd c2)
 563                 (return fix)
 564                 (addTickLHsCmd c3)
 565 addTickHsCmd (HsPar e) = liftM HsPar (addTickLHsCmd e)
 566 addTickHsCmd (HsCase e mgs) =
 567         liftM2 HsCase
 568                 (addTickLHsExpr e)
 569                 (addTickCmdMatchGroup mgs)
 570 addTickHsCmd (HsIf cnd e1 c2 c3) =
 571         liftM3 (HsIf cnd)
 572                 (addBinTickLHsExpr (BinBox CondBinBox) e1)
 573                 (addTickLHsCmd c2)
 574                 (addTickLHsCmd c3)
 575 addTickHsCmd (HsLet binds c) =
 576         bindLocals (collectLocalBinders binds) $
 577         liftM2 HsLet
 578                 (addTickHsLocalBinds binds) -- to think about: !patterns.
 579                 (addTickLHsCmd c)
 580 addTickHsCmd (HsDo cxt stmts srcloc)
 581   = do { (stmts', _) <- addTickLCmdStmts' stmts (return ())
 582        ; return (HsDo cxt stmts' srcloc) }
 583
 584 addTickHsCmd (HsArrApp   e1 e2 ty1 arr_ty lr) =
 585         liftM5 HsArrApp
 586                (addTickLHsExpr e1)
 587                (addTickLHsExpr e2)
 588                (return ty1)
 589                (return arr_ty)
 590                (return lr)
 591 addTickHsCmd (HsArrForm e fix cmdtop) =
 592         liftM3 HsArrForm
 593                (addTickLHsExpr e)
 594                (return fix)
 595                (mapM (liftL (addTickHsCmdTop)) cmdtop)
 596
 597 -- Others should never happen in a command context.
 598 addTickHsCmd e  = pprPanic "addTickHsCmd" (ppr e)
 599
 600 addTickCmdMatchGroup :: MatchGroup Id -> TM (MatchGroup Id)
 601 addTickCmdMatchGroup (MatchGroup matches ty) = do
 602   matches' <- mapM (liftL addTickCmdMatch) matches
 603   return $ MatchGroup matches' ty
 604
 605 addTickCmdMatch :: Match Id -> TM (Match Id)
 606 addTickCmdMatch (Match pats opSig gRHSs) =
 607   bindLocals (collectPatsBinders pats) $ do
 608     gRHSs' <- addTickCmdGRHSs gRHSs
 609     return $ Match pats opSig gRHSs'
 610
 611 addTickCmdGRHSs :: GRHSs Id -> TM (GRHSs Id)
 612 addTickCmdGRHSs (GRHSs guarded local_binds) = do
 613   bindLocals binders $ do
 614     local_binds' <- addTickHsLocalBinds local_binds
 615     guarded' <- mapM (liftL addTickCmdGRHS) guarded
 616     return $ GRHSs guarded' local_binds'
 617   where
 618     binders = collectLocalBinders local_binds
 619
 620 addTickCmdGRHS :: GRHS Id -> TM (GRHS Id)
 621 addTickCmdGRHS (GRHS stmts cmd) = do
 622   (stmts',expr') <- addTickLCmdStmts' stmts (addTickLHsCmd cmd)
 623   return $ GRHS stmts' expr'
 624
 625 addTickLCmdStmts :: [LStmt Id] -> TM [LStmt Id]
 626 addTickLCmdStmts stmts = do
 627   (stmts, _) <- addTickLCmdStmts' stmts (return ())
 628   return stmts
 629
 630 addTickLCmdStmts' :: [LStmt Id] -> TM a -> TM ([LStmt Id], a)
 631 addTickLCmdStmts' lstmts res
 632   = bindLocals binders $ do
 633         lstmts' <- mapM (liftL addTickCmdStmt) lstmts
 634         a <- res
 635         return (lstmts', a)
 636   where
 637         binders = collectLStmtsBinders lstmts
 638
 639 addTickCmdStmt :: Stmt Id -> TM (Stmt Id)
 640 addTickCmdStmt (BindStmt pat c bind fail) = do
 641         liftM4 BindStmt
 642                 (addTickLPat pat)
 643                 (addTickLHsCmd c)
 644                 (return bind)
 645                 (return fail)
 646 addTickCmdStmt (ExprStmt c bind' guard' ty) = do
 647         liftM4 ExprStmt
 648                 (addTickLHsCmd c)
 649                 (addTickSyntaxExpr hpcSrcSpan bind')
 650                 (addTickSyntaxExpr hpcSrcSpan guard')
 651                 (return ty)
 652 addTickCmdStmt (LetStmt binds) = do
 653         liftM LetStmt
 654                 (addTickHsLocalBinds binds)
 655 addTickCmdStmt stmt@(RecStmt {})
 656   = do { stmts' <- addTickLCmdStmts (recS_stmts stmt)
 657        ; ret'   <- addTickSyntaxExpr hpcSrcSpan (recS_ret_fn stmt)
 658        ; mfix'  <- addTickSyntaxExpr hpcSrcSpan (recS_mfix_fn stmt)
 659        ; bind'  <- addTickSyntaxExpr hpcSrcSpan (recS_bind_fn stmt)
 660        ; return (stmt { recS_stmts = stmts', recS_ret_fn = ret'
 661                       , recS_mfix_fn = mfix', recS_bind_fn = bind' }) }
 662
 663 -- Others should never happen in a command context.
 664 addTickCmdStmt stmt  = pprPanic "addTickHsCmd" (ppr stmt)
 665
 666 addTickHsRecordBinds :: HsRecordBinds Id -> TM (HsRecordBinds Id)
 667 addTickHsRecordBinds (HsRecFields fields dd)
 668   = do  { fields' <- mapM process fields
 669         ; return (HsRecFields fields' dd) }
 670   where
 671     process (HsRecField ids expr doc)
 672         = do { expr' <- addTickLHsExpr expr
 673              ; return (HsRecField ids expr' doc) }
 674
 675 addTickArithSeqInfo :: ArithSeqInfo Id -> TM (ArithSeqInfo Id)
 676 addTickArithSeqInfo (From e1) =
 677         liftM From
 678                 (addTickLHsExpr e1)
 679 addTickArithSeqInfo (FromThen e1 e2) =
 680         liftM2 FromThen
 681                 (addTickLHsExpr e1)
 682                 (addTickLHsExpr e2)
 683 addTickArithSeqInfo (FromTo e1 e2) =
 684         liftM2 FromTo
 685                 (addTickLHsExpr e1)
 686                 (addTickLHsExpr e2)
 687 addTickArithSeqInfo (FromThenTo e1 e2 e3) =
 688         liftM3 FromThenTo
 689                 (addTickLHsExpr e1)
 690                 (addTickLHsExpr e2)
 691                 (addTickLHsExpr e3)
 692 \end{code}
 693
 694 \begin{code}
 695 data TickTransState = TT { tickBoxCount:: Int
 696                          , mixEntries  :: [MixEntry_]
 697                          }
 698
 699 data TickTransEnv = TTE { fileName      :: FastString
 700                         , declPath     :: [String]
 701                         , inScope      :: VarSet
 702                         , blackList   :: Map SrcSpan ()
 703                         }
 704
 705 --      deriving Show
 706
 707 type FreeVars = OccEnv Id
 708 noFVs :: FreeVars
 709 noFVs = emptyOccEnv
 710
 711 -- Note [freevars]
 712 --   For breakpoints we want to collect the free variables of an
 713 --   expression for pinning on the HsTick.  We don't want to collect
 714 --   *all* free variables though: in particular there's no point pinning
 715 --   on free variables that are will otherwise be in scope at the GHCi
 716 --   prompt, which means all top-level bindings.  Unfortunately detecting
 717 --   top-level bindings isn't easy (collectHsBindsBinders on the top-level
 718 --   bindings doesn't do it), so we keep track of a set of "in-scope"
 719 --   variables in addition to the free variables, and the former is used
 720 --   to filter additions to the latter.  This gives us complete control
 721 --   over what free variables we track.
 722
 723 data TM a = TM { unTM :: TickTransEnv -> TickTransState -> (a,FreeVars,TickTransState) }
 724         -- a combination of a state monad (TickTransState) and a writer
 725         -- monad (FreeVars).
 726
 727 instance Monad TM where
 728   return a = TM $ \ _env st -> (a,noFVs,st)
 729   (TM m) >>= k = TM $ \ env st ->
 730                                 case m env st of
 731                                   (r1,fv1,st1) ->
 732                                      case unTM (k r1) env st1 of
 733                                        (r2,fv2,st2) ->
 734                                           (r2, fv1 `plusOccEnv` fv2, st2)
 735
 736 -- getState :: TM TickTransState
 737 -- getState = TM $ \ env st -> (st, noFVs, st)
 738
 739 -- setState :: (TickTransState -> TickTransState) -> TM ()
 740 -- setState f = TM $ \ env st -> ((), noFVs, f st)
 741
 742 getEnv :: TM TickTransEnv
 743 getEnv = TM $ \ env st -> (env, noFVs, st)
 744
 745 withEnv :: (TickTransEnv -> TickTransEnv) -> TM a -> TM a
 746 withEnv f (TM m) = TM $ \ env st ->
 747                                  case m (f env) st of
 748                                    (a, fvs, st') -> (a, fvs, st')
 749
 750 getFreeVars :: TM a -> TM (FreeVars, a)
 751 getFreeVars (TM m)
 752   = TM $ \ env st -> case m env st of (a, fv, st') -> ((fv,a), fv, st')
 753
 754 freeVar :: Id -> TM ()
 755 freeVar id = TM $ \ env st ->
 756                 if id `elemVarSet` inScope env
 757                    then ((), unitOccEnv (nameOccName (idName id)) id, st)
 758                    else ((), noFVs, st)
 759
 760 addPathEntry :: String -> TM a -> TM a
 761 addPathEntry nm = withEnv (\ env -> env { declPath = declPath env ++ [nm] })
 762
 763 getPathEntry :: TM [String]
 764 getPathEntry = declPath `liftM` getEnv
 765
 766 getFileName :: TM FastString
 767 getFileName = fileName `liftM` getEnv
 768
 769 sameFileName :: SrcSpan -> TM a -> TM a -> TM a
 770 sameFileName pos out_of_scope in_scope = do
 771   file_name <- getFileName
 772   case srcSpanFileName_maybe pos of
 773     Just file_name2
 774       | file_name == file_name2 -> in_scope
 775     _ -> out_of_scope
 776
 777 bindLocals :: [Id] -> TM a -> TM a
 778 bindLocals new_ids (TM m)
 779   = TM $ \ env st ->
 780                  case m env{ inScope = inScope env `extendVarSetList` new_ids } st of
 781                    (r, fv, st') -> (r, fv `delListFromOccEnv` occs, st')
 782   where occs = [ nameOccName (idName id) | id <- new_ids ]
 783
 784 isBlackListed :: SrcSpan -> TM Bool
 785 isBlackListed pos = TM $ \ env st ->
 786               case Map.lookup pos (blackList env) of
 787                 Nothing -> (False,noFVs,st)
 788                 Just () -> (True,noFVs,st)
 789
 790 -- the tick application inherits the source position of its
 791 -- expression argument to support nested box allocations
 792 allocTickBox :: BoxLabel -> SrcSpan -> TM (HsExpr Id) -> TM (LHsExpr Id)
 793 allocTickBox boxLabel pos m | isGoodSrcSpan' pos =
 794   sameFileName pos
 795     (do e <- m; return (L pos e)) $ do
 796   (fvs, e) <- getFreeVars m
 797   TM $ \ env st ->
 798     let c = tickBoxCount st
 799         ids = occEnvElts fvs
 800         mes = mixEntries st
 801         me = (pos, declPath env, map (nameOccName.idName) ids, boxLabel)
 802     in
 803     ( L pos (HsTick c ids (L pos e))
 804     , fvs
 805     , st {tickBoxCount=c+1,mixEntries=me:mes}
 806     )
 807 allocTickBox _boxLabel pos m = do e <- m; return (L pos e)
 808
 809 -- the tick application inherits the source position of its
 810 -- expression argument to support nested box allocations
 811 allocATickBox :: BoxLabel -> SrcSpan -> FreeVars -> TM (Maybe (Int,[Id]))
 812 allocATickBox boxLabel pos fvs | isGoodSrcSpan' pos =
 813   sameFileName pos
 814     (return Nothing) $ TM $ \ env st ->
 815   let mydecl_path
 816         | null (declPath env), TopLevelBox x <- boxLabel = x
 817         | otherwise = declPath env
 818       me = (pos, mydecl_path, map (nameOccName.idName) ids, boxLabel)
 819       c = tickBoxCount st
 820       mes = mixEntries st
 821       ids = occEnvElts fvs
 822   in ( Just (c, ids)
 823      , noFVs
 824      , st {tickBoxCount=c+1, mixEntries=me:mes}
 825      )
 826 allocATickBox _boxLabel _pos _fvs = return Nothing
 827
 828 allocBinTickBox :: (Bool -> BoxLabel) -> SrcSpan -> TM (HsExpr Id)
 829                 -> TM (LHsExpr Id)
 830 allocBinTickBox boxLabel pos m
 831  | not opt_Hpc = allocTickBox (ExpBox False) pos m
 832  | isGoodSrcSpan' pos =
 833  do
 834  e <- m
 835  TM $ \ env st ->
 836   let meT = (pos,declPath env, [],boxLabel True)
 837       meF = (pos,declPath env, [],boxLabel False)
 838       meE = (pos,declPath env, [],ExpBox False)
 839       c = tickBoxCount st
 840       mes = mixEntries st
 841   in
 842              ( L pos $ HsTick c [] $ L pos $ HsBinTick (c+1) (c+2) (L pos e)
 843            -- notice that F and T are reversed,
 844            -- because we are building the list in
 845            -- reverse...
 846              , noFVs
 847              , st {tickBoxCount=c+3 , mixEntries=meF:meT:meE:mes}
 848              )
 849 allocBinTickBox _boxLabel pos m = do e <- m; return (L pos e)
 850
 851 isGoodSrcSpan' :: SrcSpan -> Bool
 852 isGoodSrcSpan' pos
 853    | not (isGoodSrcSpan pos) = False
 854    | start == end            = False
 855    | otherwise               = True
 856   where
 857    start = srcSpanStart pos
 858    end   = srcSpanEnd pos
 859
 860 mkHpcPos :: SrcSpan -> HpcPos
 861 mkHpcPos pos
 862    | not (isGoodSrcSpan' pos) = panic "bad source span; expected such spans to be filtered out"
 863    | otherwise                = hpcPos
 864   where
 865    start = srcSpanStart pos
 866    end   = srcSpanEnd pos
 867    hpcPos = toHpcPos ( srcLocLine start
 868                      , srcLocCol start
 869                      , srcLocLine end
 870                      , srcLocCol end - 1
 871                      )
 872
 873 hpcSrcSpan :: SrcSpan
 874 hpcSrcSpan = mkGeneralSrcSpan (fsLit "Haskell Program Coverage internals")
 875 \end{code}
 876
 877
 878 \begin{code}
 879 matchesOneOfMany :: [LMatch Id] -> Bool
 880 matchesOneOfMany lmatches = sum (map matchCount lmatches) > 1
 881   where
 882         matchCount (L _ (Match _pats _ty (GRHSs grhss _binds))) = length grhss
 883 \end{code}
 884
 885
 886 \begin{code}
 887 type MixEntry_ = (SrcSpan, [String], [OccName], BoxLabel)
 888
 889 -- For the hash value, we hash everything: the file name,
 890 --  the timestamp of the original source file, the tab stop,
 891 --  and the mix entries. We cheat, and hash the show'd string.
 892 -- This hash only has to be hashed at Mix creation time,
 893 -- and is for sanity checking only.
 894
 895 mixHash :: FilePath -> Integer -> Int -> [MixEntry] -> Int
 896 mixHash file tm tabstop entries = fromIntegral $ hashString
 897         (show $ Mix file tm 0 tabstop entries)
 898 \end{code}
 899
 900 %************************************************************************
 901 %*                                                                      *
 902 %*              initialisation
 903 %*                                                                      *
 904 %************************************************************************
 905
 906 Each module compiled with -fhpc declares an initialisation function of
 907 the form `hpc_init_<module>()`, which is emitted into the _stub.c file
 908 and annotated with __attribute__((constructor)) so that it gets
 909 executed at startup time.
 910
 911 The function's purpose is to call hs_hpc_module to register this
 912 module with the RTS, and it looks something like this:
 913
 914 static void hpc_init_Main(void) __attribute__((constructor));
 915 static void hpc_init_Main(void)
 916 {extern StgWord64 _hpc_tickboxes_Main_hpc[];
 917  hs_hpc_module("Main",8,1150288664,_hpc_tickboxes_Main_hpc);}
 918
 919 \begin{code}
 920 hpcInitCode :: Module -> HpcInfo -> SDoc
 921 hpcInitCode _ (NoHpcInfo {}) = empty
 922 hpcInitCode this_mod (HpcInfo tickCount hashNo)
 923  = vcat
 924     [ text "static void hpc_init_" <> ppr this_mod
 925          <> text "(void) __attribute__((constructor));"
 926     , text "static void hpc_init_" <> ppr this_mod <> text "(void)"
 927     , braces (vcat [
 928         ptext (sLit "extern StgWord64 ") <> tickboxes <>
 929                ptext (sLit "[]") <> semi,
 930         ptext (sLit "hs_hpc_module") <>
 931           parens (hcat (punctuate comma [
 932               doubleQuotes full_name_str,
 933               int tickCount, -- really StgWord32
 934               int hashNo,    -- really StgWord32
 935               tickboxes
 936             ])) <> semi
 937        ])
 938     ]
 939   where
 940     tickboxes = pprCLabel (mkHpcTicksLabel $ this_mod)
 941
 942     module_name  = hcat (map (text.charToC) $
 943                          bytesFS (moduleNameFS (Module.moduleName this_mod)))
 944     package_name = hcat (map (text.charToC) $
 945                          bytesFS (packageIdFS  (modulePackageId this_mod)))
 946     full_name_str
 947        | modulePackageId this_mod == mainPackageId
 948        = module_name
 949        | otherwise
 950        = package_name <> char '/' <> module_name
 951 \end{code}