compiler/deSugar/Coverage.lhs

   1 %
   2 % (c) Galois, 2006
   3 % (c) University of Glasgow, 2007
   4 %
   5 \section[Coverage]{@coverage@: the main function}
   6
   7 \begin{code}
   8 module Coverage (addCoverageTicksToBinds, hpcInitCode) where
   9
  10 import HsSyn
  11 import Module
  12 import Outputable
  13 import DynFlags
  14 import Control.Monad
  15 import SrcLoc
  16 import ErrUtils
  17 import Name
  18 import Bag
  19 import Id
  20 import VarSet
  21 import Data.List
  22 import FastString
  23 import HscTypes
  24 import StaticFlags
  25 import TyCon
  26 import MonadUtils
  27 import Maybes
  28 import CLabel
  29 import Util
  30
  31 import Data.Array
  32 import System.Directory ( createDirectoryIfMissing )
  33
  34 import Trace.Hpc.Mix
  35 import Trace.Hpc.Util
  36
  37 import BreakArray
  38 import Data.HashTable   ( hashString )
  39 import Data.Map (Map)
  40 import qualified Data.Map as Map
  41 \end{code}
  42
  43
  44 %************************************************************************
  45 %*                                                                      *
  46 %*              The main function: addCoverageTicksToBinds
  47 %*                                                                      *
  48 %************************************************************************
  49
  50 \begin{code}
  51 addCoverageTicksToBinds
  52         :: DynFlags
  53         -> Module
  54         -> ModLocation          -- of the current module
  55         -> [TyCon]              -- type constructor in this module
  56         -> LHsBinds Id
  57         -> IO (LHsBinds Id, HpcInfo, ModBreaks)
  58
  59 addCoverageTicksToBinds dflags mod mod_loc tyCons binds =
  60  case ml_hs_file mod_loc of
  61  Nothing -> return (binds, emptyHpcInfo False, emptyModBreaks)
  62  Just orig_file -> do
  63
  64   if "boot" `isSuffixOf` orig_file then return (binds, emptyHpcInfo False, emptyModBreaks) else do
  65
  66   -- Now, we try look for a file generated from a .hsc file to a .hs file, by peeking ahead.
  67
  68   let top_pos = catMaybes $ foldrBag (\ (L pos _) rest -> srcSpanFileName_maybe pos : rest) [] binds
  69   let orig_file2 = case top_pos of
  70                      (file_name:_)
  71                        | ".hsc" `isSuffixOf` unpackFS file_name -> unpackFS file_name
  72                      _ -> orig_file
  73
  74   let mod_name = moduleNameString (moduleName mod)
  75
  76   let (binds1,_,st)
  77                  = unTM (addTickLHsBinds binds)
  78                    (TTE
  79                        { fileName    = mkFastString orig_file2
  80                       , declPath     = []
  81                       , inScope      = emptyVarSet
  82                       , blackList    = Map.fromList [ (getSrcSpan (tyConName tyCon),())
  83                                                     | tyCon <- tyCons ]
  84                        })
  85                    (TT
  86                       { tickBoxCount = 0
  87                       , mixEntries   = []
  88                       })
  89
  90   let entries = reverse $ mixEntries st
  91
  92   -- write the mix entries for this module
  93   hashNo <- if opt_Hpc then do
  94      let hpc_dir = hpcDir dflags
  95
  96      let hpc_mod_dir = if modulePackageId mod == mainPackageId
  97                        then hpc_dir
  98                        else hpc_dir ++ "/" ++ packageIdString (modulePackageId mod)
  99
 100      let tabStop = 1 -- <tab> counts as a normal char in GHC's location ranges.
 101      createDirectoryIfMissing True hpc_mod_dir
 102      modTime <- getModificationTime orig_file2
 103      let entries' = [ (hpcPos, box)
 104                     | (span,_,_,box) <- entries, hpcPos <- [mkHpcPos span] ]
 105      when (length entries' /= tickBoxCount st) $ do
 106        panic "the number of .mix entries are inconsistent"
 107      let hashNo = mixHash orig_file2 modTime tabStop entries'
 108      mixCreate hpc_mod_dir mod_name
 109                $ Mix orig_file2 modTime (toHash hashNo) tabStop entries'
 110      return $ hashNo
 111    else do
 112      return $ 0
 113
 114   -- Todo: use proper src span type
 115   breakArray <- newBreakArray $ length entries
 116
 117   let locsTicks = listArray (0,tickBoxCount st-1)
 118                      [ span | (span,_,_,_) <- entries ]
 119       varsTicks = listArray (0,tickBoxCount st-1)
 120                      [ vars | (_,_,vars,_) <- entries ]
 121       declsTicks= listArray (0,tickBoxCount st-1)
 122                      [ decls | (_,decls,_,_) <- entries ]
 123       modBreaks = emptyModBreaks
 124                   { modBreaks_flags = breakArray
 125                   , modBreaks_locs  = locsTicks
 126                   , modBreaks_vars  = varsTicks
 127                   , modBreaks_decls = declsTicks
 128                   }
 129
 130   doIfSet_dyn dflags  Opt_D_dump_hpc $ do
 131           printDump (pprLHsBinds binds1)
 132
 133   return (binds1, HpcInfo (tickBoxCount st) hashNo, modBreaks)
 134 \end{code}
 135
 136
 137 \begin{code}
 138 liftL :: (Monad m) => (a -> m a) -> Located a -> m (Located a)
 139 liftL f (L loc a) = do
 140   a' <- f a
 141   return $ L loc a'
 142
 143 addTickLHsBinds :: LHsBinds Id -> TM (LHsBinds Id)
 144 addTickLHsBinds binds = mapBagM addTickLHsBind binds
 145
 146 addTickLHsBind :: LHsBind Id -> TM (LHsBind Id)
 147 addTickLHsBind (L pos bind@(AbsBinds { abs_binds = binds })) = do
 148   binds' <- addTickLHsBinds binds
 149   return $ L pos $ bind { abs_binds = binds' }
 150 addTickLHsBind (L pos (funBind@(FunBind { fun_id = (L _ id)  }))) = do
 151   let name = getOccString id
 152   decl_path <- getPathEntry
 153
 154   (fvs, (MatchGroup matches' ty)) <-
 155         getFreeVars $
 156         addPathEntry name $
 157         addTickMatchGroup (fun_matches funBind)
 158
 159   blackListed <- isBlackListed pos
 160
 161   -- Todo: we don't want redundant ticks on simple pattern bindings
 162   -- We don't want to generate code for blacklisted positions
 163   if blackListed || (not opt_Hpc && isSimplePatBind funBind)
 164      then
 165         return $ L pos $ funBind { fun_matches = MatchGroup matches' ty
 166                                  , fun_tick = Nothing
 167                                  }
 168      else do
 169         tick_no <- allocATickBox (if null decl_path
 170                                      then TopLevelBox [name]
 171                                      else LocalBox (decl_path ++ [name]))
 172                                 pos fvs
 173
 174         return $ L pos $ funBind { fun_matches = MatchGroup matches' ty
 175                                  , fun_tick = tick_no
 176                                  }
 177    where
 178    -- a binding is a simple pattern binding if it is a funbind with zero patterns
 179    isSimplePatBind :: HsBind a -> Bool
 180    isSimplePatBind funBind = matchGroupArity (fun_matches funBind) == 0
 181
 182 -- TODO: Revisit this
 183 addTickLHsBind (L pos (pat@(PatBind { pat_rhs = rhs }))) = do
 184   let name = "(...)"
 185   rhs' <- addPathEntry name $ addTickGRHSs False rhs
 186 {-
 187   decl_path <- getPathEntry
 188   tick_me <- allocTickBox (if null decl_path
 189                            then TopLevelBox [name]
 190                            else LocalBox (name : decl_path))
 191 -}
 192   return $ L pos $ pat { pat_rhs = rhs' }
 193
 194 -- Only internal stuff, not from source, uses VarBind, so we ignore it.
 195 addTickLHsBind var_bind@(L _ (VarBind {})) = return var_bind
 196
 197 -- Add a tick to the expression no matter what it is.  There is one exception:
 198 -- for the debugger, if the expression is a 'let', then we don't want to add
 199 -- a tick here because there will definititely be a tick on the body anyway.
 200 addTickLHsExprAlways :: LHsExpr Id -> TM (LHsExpr Id)
 201 addTickLHsExprAlways (L pos e0)
 202   | not opt_Hpc, HsLet _ _ <- e0 = addTickLHsExprNever (L pos e0)
 203   | otherwise = allocTickBox (ExpBox False) pos $ addTickHsExpr e0
 204
 205 addTickLHsExprNeverOrAlways :: LHsExpr Id -> TM (LHsExpr Id)
 206 addTickLHsExprNeverOrAlways e
 207     | opt_Hpc   = addTickLHsExprNever e
 208     | otherwise = addTickLHsExprAlways e
 209
 210 addTickLHsExprNeverOrMaybe :: LHsExpr Id -> TM (LHsExpr Id)
 211 addTickLHsExprNeverOrMaybe e
 212     | opt_Hpc   = addTickLHsExprNever e
 213     | otherwise = addTickLHsExpr e
 214
 215 -- version of addTick that does not actually add a tick,
 216 -- because the scope of this tick is completely subsumed by
 217 -- another.
 218 addTickLHsExprNever :: LHsExpr Id -> TM (LHsExpr Id)
 219 addTickLHsExprNever (L pos e0) = do
 220     e1 <- addTickHsExpr e0
 221     return $ L pos e1
 222
 223 -- selectively add ticks to interesting expressions
 224 addTickLHsExpr :: LHsExpr Id -> TM (LHsExpr Id)
 225 addTickLHsExpr (L pos e0) = do
 226     if opt_Hpc || isGoodBreakExpr e0
 227        then do
 228           allocTickBox (ExpBox False) pos $ addTickHsExpr e0
 229        else do
 230           e1 <- addTickHsExpr e0
 231           return $ L pos e1
 232
 233 -- general heuristic: expressions which do not denote values are good break points
 234 isGoodBreakExpr :: HsExpr Id -> Bool
 235 isGoodBreakExpr (HsApp {})     = True
 236 isGoodBreakExpr (OpApp {})     = True
 237 isGoodBreakExpr (NegApp {})    = True
 238 isGoodBreakExpr (HsCase {})    = True
 239 isGoodBreakExpr (HsIf {})      = True
 240 isGoodBreakExpr (RecordCon {}) = True
 241 isGoodBreakExpr (RecordUpd {}) = True
 242 isGoodBreakExpr (ArithSeq {})  = True
 243 isGoodBreakExpr (PArrSeq {})   = True
 244 isGoodBreakExpr _other         = False
 245
 246 addTickLHsExprOptAlt :: Bool -> LHsExpr Id -> TM (LHsExpr Id)
 247 addTickLHsExprOptAlt oneOfMany (L pos e0)
 248   | not opt_Hpc = addTickLHsExpr (L pos e0)
 249   | otherwise =
 250     allocTickBox (ExpBox oneOfMany) pos $
 251         addTickHsExpr e0
 252
 253 addBinTickLHsExpr :: (Bool -> BoxLabel) -> LHsExpr Id -> TM (LHsExpr Id)
 254 addBinTickLHsExpr boxLabel (L pos e0) =
 255     allocBinTickBox boxLabel pos $
 256         addTickHsExpr e0
 257
 258 addTickHsExpr :: HsExpr Id -> TM (HsExpr Id)
 259 addTickHsExpr e@(HsVar id) = do freeVar id; return e
 260 addTickHsExpr e@(HsIPVar _) = return e
 261 addTickHsExpr e@(HsOverLit _) = return e
 262 addTickHsExpr e@(HsLit _) = return e
 263 addTickHsExpr (HsLam matchgroup) =
 264         liftM HsLam (addTickMatchGroup matchgroup)
 265 addTickHsExpr (HsApp e1 e2) =
 266         liftM2 HsApp (addTickLHsExprNever e1) (addTickLHsExpr e2)
 267 addTickHsExpr (OpApp e1 e2 fix e3) =
 268         liftM4 OpApp
 269                 (addTickLHsExpr e1)
 270                 (addTickLHsExprNever e2)
 271                 (return fix)
 272                 (addTickLHsExpr e3)
 273 addTickHsExpr (NegApp e neg) =
 274         liftM2 NegApp
 275                 (addTickLHsExpr e)
 276                 (addTickSyntaxExpr hpcSrcSpan neg)
 277 addTickHsExpr (HsPar e) = liftM HsPar (addTickLHsExprNeverOrMaybe e)
 278 addTickHsExpr (SectionL e1 e2) =
 279         liftM2 SectionL
 280                 (addTickLHsExpr e1)
 281                 (addTickLHsExpr e2)
 282 addTickHsExpr (SectionR e1 e2) =
 283         liftM2 SectionR
 284                 (addTickLHsExpr e1)
 285                 (addTickLHsExpr e2)
 286 addTickHsExpr (ExplicitTuple es boxity) =
 287         liftM2 ExplicitTuple
 288                 (mapM addTickTupArg es)
 289                 (return boxity)
 290 addTickHsExpr (HsCase e mgs) =
 291         liftM2 HsCase
 292                 (addTickLHsExpr e)
 293                 (addTickMatchGroup mgs)
 294 addTickHsExpr (HsIf cnd e1 e2 e3) =
 295         liftM3 (HsIf cnd)
 296                 (addBinTickLHsExpr (BinBox CondBinBox) e1)
 297                 (addTickLHsExprOptAlt True e2)
 298                 (addTickLHsExprOptAlt True e3)
 299 addTickHsExpr (HsLet binds e) =
 300         bindLocals (collectLocalBinders binds) $
 301         liftM2 HsLet
 302                 (addTickHsLocalBinds binds) -- to think about: !patterns.
 303                 (addTickLHsExprNeverOrAlways e)
 304 addTickHsExpr (HsDo cxt stmts srcloc)
 305   = do { (stmts', _) <- addTickLStmts' forQual stmts (return ())
 306        ; return (HsDo cxt stmts' srcloc) }
 307   where
 308         forQual = case cxt of
 309                     ListComp -> Just $ BinBox QualBinBox
 310                     _        -> Nothing
 311 addTickHsExpr (ExplicitList ty es) =
 312         liftM2 ExplicitList
 313                 (return ty)
 314                 (mapM (addTickLHsExpr) es)
 315 addTickHsExpr (ExplicitPArr ty es) =
 316         liftM2 ExplicitPArr
 317                 (return ty)
 318                 (mapM (addTickLHsExpr) es)
 319 addTickHsExpr (RecordCon id ty rec_binds) =
 320         liftM3 RecordCon
 321                 (return id)
 322                 (return ty)
 323                 (addTickHsRecordBinds rec_binds)
 324 addTickHsExpr (RecordUpd e rec_binds cons tys1 tys2) =
 325         liftM5 RecordUpd
 326                 (addTickLHsExpr e)
 327                 (addTickHsRecordBinds rec_binds)
 328                 (return cons) (return tys1) (return tys2)
 329
 330 addTickHsExpr (ExprWithTySigOut e ty) =
 331         liftM2 ExprWithTySigOut
 332                 (addTickLHsExprNever e) -- No need to tick the inner expression
 333                                     -- for expressions with signatures
 334                 (return ty)
 335 addTickHsExpr (ArithSeq  ty arith_seq) =
 336         liftM2 ArithSeq
 337                 (return ty)
 338                 (addTickArithSeqInfo arith_seq)
 339 addTickHsExpr (HsTickPragma _ (L pos e0)) = do
 340     e2 <- allocTickBox (ExpBox False) pos $
 341                 addTickHsExpr e0
 342     return $ unLoc e2
 343 addTickHsExpr (PArrSeq   ty arith_seq) =
 344         liftM2 PArrSeq
 345                 (return ty)
 346                 (addTickArithSeqInfo arith_seq)
 347 addTickHsExpr (HsSCC nm e) =
 348         liftM2 HsSCC
 349                 (return nm)
 350                 (addTickLHsExpr e)
 351 addTickHsExpr (HsCoreAnn nm e) =
 352         liftM2 HsCoreAnn
 353                 (return nm)
 354                 (addTickLHsExpr e)
 355 addTickHsExpr e@(HsBracket     {}) = return e
 356 addTickHsExpr e@(HsBracketOut  {}) = return e
 357 addTickHsExpr e@(HsSpliceE  {}) = return e
 358 addTickHsExpr (HsProc pat cmdtop) =
 359         liftM2 HsProc
 360                 (addTickLPat pat)
 361                 (liftL (addTickHsCmdTop) cmdtop)
 362 addTickHsExpr (HsWrap w e) =
 363         liftM2 HsWrap
 364                 (return w)
 365                 (addTickHsExpr e)       -- explicitly no tick on inside
 366
 367 addTickHsExpr (HsArrApp  e1 e2 ty1 arr_ty lr) =
 368         liftM5 HsArrApp
 369                (addTickLHsExpr e1)
 370                (addTickLHsExpr e2)
 371                (return ty1)
 372                (return arr_ty)
 373                (return lr)
 374
 375 addTickHsExpr (HsArrForm e fix cmdtop) =
 376         liftM3 HsArrForm
 377                (addTickLHsExpr e)
 378                (return fix)
 379                (mapM (liftL (addTickHsCmdTop)) cmdtop)
 380
 381 addTickHsExpr e@(HsType _) = return e
 382
 383 -- Others dhould never happen in expression content.
 384 addTickHsExpr e  = pprPanic "addTickHsExpr" (ppr e)
 385
 386 addTickTupArg :: HsTupArg Id -> TM (HsTupArg Id)
 387 addTickTupArg (Present e)  = do { e' <- addTickLHsExpr e; return (Present e') }
 388 addTickTupArg (Missing ty) = return (Missing ty)
 389
 390 addTickMatchGroup :: MatchGroup Id -> TM (MatchGroup Id)
 391 addTickMatchGroup (MatchGroup matches ty) = do
 392   let isOneOfMany = matchesOneOfMany matches
 393   matches' <- mapM (liftL (addTickMatch isOneOfMany)) matches
 394   return $ MatchGroup matches' ty
 395
 396 addTickMatch :: Bool -> Match Id -> TM (Match Id)
 397 addTickMatch isOneOfMany (Match pats opSig gRHSs) =
 398   bindLocals (collectPatsBinders pats) $ do
 399     gRHSs' <- addTickGRHSs isOneOfMany gRHSs
 400     return $ Match pats opSig gRHSs'
 401
 402 addTickGRHSs :: Bool -> GRHSs Id -> TM (GRHSs Id)
 403 addTickGRHSs isOneOfMany (GRHSs guarded local_binds) = do
 404   bindLocals binders $ do
 405     local_binds' <- addTickHsLocalBinds local_binds
 406     guarded' <- mapM (liftL (addTickGRHS isOneOfMany)) guarded
 407     return $ GRHSs guarded' local_binds'
 408   where
 409     binders = collectLocalBinders local_binds
 410
 411 addTickGRHS :: Bool -> GRHS Id -> TM (GRHS Id)
 412 addTickGRHS isOneOfMany (GRHS stmts expr) = do
 413   (stmts',expr') <- addTickLStmts' (Just $ BinBox $ GuardBinBox) stmts
 414                         (if opt_Hpc then addTickLHsExprOptAlt isOneOfMany expr
 415                                     else addTickLHsExprAlways expr)
 416   return $ GRHS stmts' expr'
 417
 418 addTickLStmts :: (Maybe (Bool -> BoxLabel)) -> [LStmt Id] -> TM [LStmt Id]
 419 addTickLStmts isGuard stmts = do
 420   (stmts, _) <- addTickLStmts' isGuard stmts (return ())
 421   return stmts
 422
 423 addTickLStmts' :: (Maybe (Bool -> BoxLabel)) -> [LStmt Id] -> TM a
 424                -> TM ([LStmt Id], a)
 425 addTickLStmts' isGuard lstmts res
 426   = bindLocals (collectLStmtsBinders lstmts) $
 427     do { lstmts' <- mapM (liftL (addTickStmt isGuard)) lstmts
 428        ; a <- res
 429        ; return (lstmts', a) }
 430
 431 addTickStmt :: (Maybe (Bool -> BoxLabel)) -> Stmt Id -> TM (Stmt Id)
 432 addTickStmt _isGuard (LastStmt e ret) = do
 433         liftM2 LastStmt
 434                 (addTickLHsExpr e)
 435                 (addTickSyntaxExpr hpcSrcSpan ret)
 436 addTickStmt _isGuard (BindStmt pat e bind fail) = do
 437         liftM4 BindStmt
 438                 (addTickLPat pat)
 439                 (addTickLHsExprAlways e)
 440                 (addTickSyntaxExpr hpcSrcSpan bind)
 441                 (addTickSyntaxExpr hpcSrcSpan fail)
 442 addTickStmt isGuard (ExprStmt e bind' guard' ty) = do
 443         liftM4 ExprStmt
 444                 (addTick isGuard e)
 445                 (addTickSyntaxExpr hpcSrcSpan bind')
 446                 (addTickSyntaxExpr hpcSrcSpan guard')
 447                 (return ty)
 448 addTickStmt _isGuard (LetStmt binds) = do
 449         liftM LetStmt
 450                 (addTickHsLocalBinds binds)
 451 addTickStmt isGuard (ParStmt pairs mzipExpr bindExpr returnExpr) = do
 452     liftM4 ParStmt
 453         (mapM (addTickStmtAndBinders isGuard) pairs)
 454         (addTickSyntaxExpr hpcSrcSpan mzipExpr)
 455         (addTickSyntaxExpr hpcSrcSpan bindExpr)
 456         (addTickSyntaxExpr hpcSrcSpan returnExpr)
 457
 458 addTickStmt isGuard stmt@(TransStmt { trS_stmts = stmts
 459                                     , trS_by = by, trS_using = using
 460                                     , trS_ret = returnExpr, trS_bind = bindExpr
 461                                     , trS_fmap = liftMExpr }) = do
 462     t_s <- addTickLStmts isGuard stmts
 463     t_y <- fmapMaybeM  addTickLHsExprAlways by
 464     t_u <- addTickLHsExprAlways using
 465     t_f <- addTickSyntaxExpr hpcSrcSpan returnExpr
 466     t_b <- addTickSyntaxExpr hpcSrcSpan bindExpr
 467     t_m <- addTickSyntaxExpr hpcSrcSpan liftMExpr
 468     return $ stmt { trS_stmts = t_s, trS_by = t_y, trS_using = t_u
 469                   , trS_ret = t_f, trS_bind = t_b, trS_fmap = t_m }
 470
 471 addTickStmt isGuard stmt@(RecStmt {})
 472   = do { stmts' <- addTickLStmts isGuard (recS_stmts stmt)
 473        ; ret'   <- addTickSyntaxExpr hpcSrcSpan (recS_ret_fn stmt)
 474        ; mfix'  <- addTickSyntaxExpr hpcSrcSpan (recS_mfix_fn stmt)
 475        ; bind'  <- addTickSyntaxExpr hpcSrcSpan (recS_bind_fn stmt)
 476        ; return (stmt { recS_stmts = stmts', recS_ret_fn = ret'
 477                       , recS_mfix_fn = mfix', recS_bind_fn = bind' }) }
 478
 479 addTick :: Maybe (Bool -> BoxLabel) -> LHsExpr Id -> TM (LHsExpr Id)
 480 addTick isGuard e | Just fn <- isGuard = addBinTickLHsExpr fn e
 481                   | otherwise          = addTickLHsExprAlways e
 482
 483 addTickStmtAndBinders :: Maybe (Bool -> BoxLabel) -> ([LStmt Id], a)
 484                       -> TM ([LStmt Id], a)
 485 addTickStmtAndBinders isGuard (stmts, ids) =
 486     liftM2 (,)
 487         (addTickLStmts isGuard stmts)
 488         (return ids)
 489
 490 addTickHsLocalBinds :: HsLocalBinds Id -> TM (HsLocalBinds Id)
 491 addTickHsLocalBinds (HsValBinds binds) =
 492         liftM HsValBinds
 493                 (addTickHsValBinds binds)
 494 addTickHsLocalBinds (HsIPBinds binds)  =
 495         liftM HsIPBinds
 496                 (addTickHsIPBinds binds)
 497 addTickHsLocalBinds (EmptyLocalBinds)  = return EmptyLocalBinds
 498
 499 addTickHsValBinds :: HsValBindsLR Id a -> TM (HsValBindsLR Id b)
 500 addTickHsValBinds (ValBindsOut binds sigs) =
 501         liftM2 ValBindsOut
 502                 (mapM (\ (rec,binds') ->
 503                                 liftM2 (,)
 504                                         (return rec)
 505                                         (addTickLHsBinds binds'))
 506                         binds)
 507                 (return sigs)
 508 addTickHsValBinds _ = panic "addTickHsValBinds"
 509
 510 addTickHsIPBinds :: HsIPBinds Id -> TM (HsIPBinds Id)
 511 addTickHsIPBinds (IPBinds ipbinds dictbinds) =
 512         liftM2 IPBinds
 513                 (mapM (liftL (addTickIPBind)) ipbinds)
 514                 (return dictbinds)
 515
 516 addTickIPBind :: IPBind Id -> TM (IPBind Id)
 517 addTickIPBind (IPBind nm e) =
 518         liftM2 IPBind
 519                 (return nm)
 520                 (addTickLHsExpr e)
 521
 522 -- There is no location here, so we might need to use a context location??
 523 addTickSyntaxExpr :: SrcSpan -> SyntaxExpr Id -> TM (SyntaxExpr Id)
 524 addTickSyntaxExpr pos x = do
 525         L _ x' <- addTickLHsExpr (L pos x)
 526         return $ x'
 527 -- we do not walk into patterns.
 528 addTickLPat :: LPat Id -> TM (LPat Id)
 529 addTickLPat pat = return pat
 530
 531 addTickHsCmdTop :: HsCmdTop Id -> TM (HsCmdTop Id)
 532 addTickHsCmdTop (HsCmdTop cmd tys ty syntaxtable) =
 533         liftM4 HsCmdTop
 534                 (addTickLHsCmd cmd)
 535                 (return tys)
 536                 (return ty)
 537                 (return syntaxtable)
 538
 539 addTickLHsCmd ::  LHsCmd Id -> TM (LHsCmd Id)
 540 addTickLHsCmd (L pos c0) = do
 541         c1 <- addTickHsCmd c0
 542         return $ L pos c1
 543
 544 addTickHsCmd :: HsCmd Id -> TM (HsCmd Id)
 545 addTickHsCmd (HsLam matchgroup) =
 546         liftM HsLam (addTickCmdMatchGroup matchgroup)
 547 addTickHsCmd (HsApp e1 e2) =
 548         liftM2 HsApp (addTickLHsExprNever e1) (addTickLHsExpr e2)
 549 addTickHsCmd (OpApp e1 c2 fix c3) =
 550         liftM4 OpApp
 551                 (addTickLHsExpr e1)
 552                 (addTickLHsCmd c2)
 553                 (return fix)
 554                 (addTickLHsCmd c3)
 555 addTickHsCmd (HsPar e) = liftM HsPar (addTickLHsCmd e)
 556 addTickHsCmd (HsCase e mgs) =
 557         liftM2 HsCase
 558                 (addTickLHsExpr e)
 559                 (addTickCmdMatchGroup mgs)
 560 addTickHsCmd (HsIf cnd e1 c2 c3) =
 561         liftM3 (HsIf cnd)
 562                 (addBinTickLHsExpr (BinBox CondBinBox) e1)
 563                 (addTickLHsCmd c2)
 564                 (addTickLHsCmd c3)
 565 addTickHsCmd (HsLet binds c) =
 566         bindLocals (collectLocalBinders binds) $
 567         liftM2 HsLet
 568                 (addTickHsLocalBinds binds) -- to think about: !patterns.
 569                 (addTickLHsCmd c)
 570 addTickHsCmd (HsDo cxt stmts srcloc)
 571   = do { (stmts', _) <- addTickLCmdStmts' stmts (return ())
 572        ; return (HsDo cxt stmts' srcloc) }
 573
 574 addTickHsCmd (HsArrApp   e1 e2 ty1 arr_ty lr) =
 575         liftM5 HsArrApp
 576                (addTickLHsExpr e1)
 577                (addTickLHsExpr e2)
 578                (return ty1)
 579                (return arr_ty)
 580                (return lr)
 581 addTickHsCmd (HsArrForm e fix cmdtop) =
 582         liftM3 HsArrForm
 583                (addTickLHsExpr e)
 584                (return fix)
 585                (mapM (liftL (addTickHsCmdTop)) cmdtop)
 586
 587 -- Others should never happen in a command context.
 588 addTickHsCmd e  = pprPanic "addTickHsCmd" (ppr e)
 589
 590 addTickCmdMatchGroup :: MatchGroup Id -> TM (MatchGroup Id)
 591 addTickCmdMatchGroup (MatchGroup matches ty) = do
 592   matches' <- mapM (liftL addTickCmdMatch) matches
 593   return $ MatchGroup matches' ty
 594
 595 addTickCmdMatch :: Match Id -> TM (Match Id)
 596 addTickCmdMatch (Match pats opSig gRHSs) =
 597   bindLocals (collectPatsBinders pats) $ do
 598     gRHSs' <- addTickCmdGRHSs gRHSs
 599     return $ Match pats opSig gRHSs'
 600
 601 addTickCmdGRHSs :: GRHSs Id -> TM (GRHSs Id)
 602 addTickCmdGRHSs (GRHSs guarded local_binds) = do
 603   bindLocals binders $ do
 604     local_binds' <- addTickHsLocalBinds local_binds
 605     guarded' <- mapM (liftL addTickCmdGRHS) guarded
 606     return $ GRHSs guarded' local_binds'
 607   where
 608     binders = collectLocalBinders local_binds
 609
 610 addTickCmdGRHS :: GRHS Id -> TM (GRHS Id)
 611 addTickCmdGRHS (GRHS stmts cmd) = do
 612   (stmts',expr') <- addTickLCmdStmts' stmts (addTickLHsCmd cmd)
 613   return $ GRHS stmts' expr'
 614
 615 addTickLCmdStmts :: [LStmt Id] -> TM [LStmt Id]
 616 addTickLCmdStmts stmts = do
 617   (stmts, _) <- addTickLCmdStmts' stmts (return ())
 618   return stmts
 619
 620 addTickLCmdStmts' :: [LStmt Id] -> TM a -> TM ([LStmt Id], a)
 621 addTickLCmdStmts' lstmts res
 622   = bindLocals binders $ do
 623         lstmts' <- mapM (liftL addTickCmdStmt) lstmts
 624         a <- res
 625         return (lstmts', a)
 626   where
 627         binders = collectLStmtsBinders lstmts
 628
 629 addTickCmdStmt :: Stmt Id -> TM (Stmt Id)
 630 addTickCmdStmt (BindStmt pat c bind fail) = do
 631         liftM4 BindStmt
 632                 (addTickLPat pat)
 633                 (addTickLHsCmd c)
 634                 (return bind)
 635                 (return fail)
 636 addTickCmdStmt (LastStmt c ret) = do
 637         liftM2 LastStmt
 638                 (addTickLHsCmd c)
 639                 (addTickSyntaxExpr hpcSrcSpan ret)
 640 addTickCmdStmt (ExprStmt c bind' guard' ty) = do
 641         liftM4 ExprStmt
 642                 (addTickLHsCmd c)
 643                 (addTickSyntaxExpr hpcSrcSpan bind')
 644                 (addTickSyntaxExpr hpcSrcSpan guard')
 645                 (return ty)
 646 addTickCmdStmt (LetStmt binds) = do
 647         liftM LetStmt
 648                 (addTickHsLocalBinds binds)
 649 addTickCmdStmt stmt@(RecStmt {})
 650   = do { stmts' <- addTickLCmdStmts (recS_stmts stmt)
 651        ; ret'   <- addTickSyntaxExpr hpcSrcSpan (recS_ret_fn stmt)
 652        ; mfix'  <- addTickSyntaxExpr hpcSrcSpan (recS_mfix_fn stmt)
 653        ; bind'  <- addTickSyntaxExpr hpcSrcSpan (recS_bind_fn stmt)
 654        ; return (stmt { recS_stmts = stmts', recS_ret_fn = ret'
 655                       , recS_mfix_fn = mfix', recS_bind_fn = bind' }) }
 656
 657 -- Others should never happen in a command context.
 658 addTickCmdStmt stmt  = pprPanic "addTickHsCmd" (ppr stmt)
 659
 660 addTickHsRecordBinds :: HsRecordBinds Id -> TM (HsRecordBinds Id)
 661 addTickHsRecordBinds (HsRecFields fields dd)
 662   = do  { fields' <- mapM process fields
 663         ; return (HsRecFields fields' dd) }
 664   where
 665     process (HsRecField ids expr doc)
 666         = do { expr' <- addTickLHsExpr expr
 667              ; return (HsRecField ids expr' doc) }
 668
 669 addTickArithSeqInfo :: ArithSeqInfo Id -> TM (ArithSeqInfo Id)
 670 addTickArithSeqInfo (From e1) =
 671         liftM From
 672                 (addTickLHsExpr e1)
 673 addTickArithSeqInfo (FromThen e1 e2) =
 674         liftM2 FromThen
 675                 (addTickLHsExpr e1)
 676                 (addTickLHsExpr e2)
 677 addTickArithSeqInfo (FromTo e1 e2) =
 678         liftM2 FromTo
 679                 (addTickLHsExpr e1)
 680                 (addTickLHsExpr e2)
 681 addTickArithSeqInfo (FromThenTo e1 e2 e3) =
 682         liftM3 FromThenTo
 683                 (addTickLHsExpr e1)
 684                 (addTickLHsExpr e2)
 685                 (addTickLHsExpr e3)
 686 \end{code}
 687
 688 \begin{code}
 689 data TickTransState = TT { tickBoxCount:: Int
 690                          , mixEntries  :: [MixEntry_]
 691                          }
 692
 693 data TickTransEnv = TTE { fileName      :: FastString
 694                         , declPath     :: [String]
 695                         , inScope      :: VarSet
 696                         , blackList   :: Map SrcSpan ()
 697                         }
 698
 699 --      deriving Show
 700
 701 type FreeVars = OccEnv Id
 702 noFVs :: FreeVars
 703 noFVs = emptyOccEnv
 704
 705 -- Note [freevars]
 706 --   For breakpoints we want to collect the free variables of an
 707 --   expression for pinning on the HsTick.  We don't want to collect
 708 --   *all* free variables though: in particular there's no point pinning
 709 --   on free variables that are will otherwise be in scope at the GHCi
 710 --   prompt, which means all top-level bindings.  Unfortunately detecting
 711 --   top-level bindings isn't easy (collectHsBindsBinders on the top-level
 712 --   bindings doesn't do it), so we keep track of a set of "in-scope"
 713 --   variables in addition to the free variables, and the former is used
 714 --   to filter additions to the latter.  This gives us complete control
 715 --   over what free variables we track.
 716
 717 data TM a = TM { unTM :: TickTransEnv -> TickTransState -> (a,FreeVars,TickTransState) }
 718         -- a combination of a state monad (TickTransState) and a writer
 719         -- monad (FreeVars).
 720
 721 instance Monad TM where
 722   return a = TM $ \ _env st -> (a,noFVs,st)
 723   (TM m) >>= k = TM $ \ env st ->
 724                                 case m env st of
 725                                   (r1,fv1,st1) ->
 726                                      case unTM (k r1) env st1 of
 727                                        (r2,fv2,st2) ->
 728                                           (r2, fv1 `plusOccEnv` fv2, st2)
 729
 730 -- getState :: TM TickTransState
 731 -- getState = TM $ \ env st -> (st, noFVs, st)
 732
 733 -- setState :: (TickTransState -> TickTransState) -> TM ()
 734 -- setState f = TM $ \ env st -> ((), noFVs, f st)
 735
 736 getEnv :: TM TickTransEnv
 737 getEnv = TM $ \ env st -> (env, noFVs, st)
 738
 739 withEnv :: (TickTransEnv -> TickTransEnv) -> TM a -> TM a
 740 withEnv f (TM m) = TM $ \ env st ->
 741                                  case m (f env) st of
 742                                    (a, fvs, st') -> (a, fvs, st')
 743
 744 getFreeVars :: TM a -> TM (FreeVars, a)
 745 getFreeVars (TM m)
 746   = TM $ \ env st -> case m env st of (a, fv, st') -> ((fv,a), fv, st')
 747
 748 freeVar :: Id -> TM ()
 749 freeVar id = TM $ \ env st ->
 750                 if id `elemVarSet` inScope env
 751                    then ((), unitOccEnv (nameOccName (idName id)) id, st)
 752                    else ((), noFVs, st)
 753
 754 addPathEntry :: String -> TM a -> TM a
 755 addPathEntry nm = withEnv (\ env -> env { declPath = declPath env ++ [nm] })
 756
 757 getPathEntry :: TM [String]
 758 getPathEntry = declPath `liftM` getEnv
 759
 760 getFileName :: TM FastString
 761 getFileName = fileName `liftM` getEnv
 762
 763 sameFileName :: SrcSpan -> TM a -> TM a -> TM a
 764 sameFileName pos out_of_scope in_scope = do
 765   file_name <- getFileName
 766   case srcSpanFileName_maybe pos of
 767     Just file_name2
 768       | file_name == file_name2 -> in_scope
 769     _ -> out_of_scope
 770
 771 bindLocals :: [Id] -> TM a -> TM a
 772 bindLocals new_ids (TM m)
 773   = TM $ \ env st ->
 774                  case m env{ inScope = inScope env `extendVarSetList` new_ids } st of
 775                    (r, fv, st') -> (r, fv `delListFromOccEnv` occs, st')
 776   where occs = [ nameOccName (idName id) | id <- new_ids ]
 777
 778 isBlackListed :: SrcSpan -> TM Bool
 779 isBlackListed pos = TM $ \ env st ->
 780               case Map.lookup pos (blackList env) of
 781                 Nothing -> (False,noFVs,st)
 782                 Just () -> (True,noFVs,st)
 783
 784 -- the tick application inherits the source position of its
 785 -- expression argument to support nested box allocations
 786 allocTickBox :: BoxLabel -> SrcSpan -> TM (HsExpr Id) -> TM (LHsExpr Id)
 787 allocTickBox boxLabel pos m | isGoodSrcSpan' pos =
 788   sameFileName pos
 789     (do e <- m; return (L pos e)) $ do
 790   (fvs, e) <- getFreeVars m
 791   TM $ \ env st ->
 792     let c = tickBoxCount st
 793         ids = occEnvElts fvs
 794         mes = mixEntries st
 795         me = (pos, declPath env, map (nameOccName.idName) ids, boxLabel)
 796     in
 797     ( L pos (HsTick c ids (L pos e))
 798     , fvs
 799     , st {tickBoxCount=c+1,mixEntries=me:mes}
 800     )
 801 allocTickBox _boxLabel pos m = do e <- m; return (L pos e)
 802
 803 -- the tick application inherits the source position of its
 804 -- expression argument to support nested box allocations
 805 allocATickBox :: BoxLabel -> SrcSpan -> FreeVars -> TM (Maybe (Int,[Id]))
 806 allocATickBox boxLabel pos fvs | isGoodSrcSpan' pos =
 807   sameFileName pos
 808     (return Nothing) $ TM $ \ env st ->
 809   let mydecl_path
 810         | null (declPath env), TopLevelBox x <- boxLabel = x
 811         | otherwise = declPath env
 812       me = (pos, mydecl_path, map (nameOccName.idName) ids, boxLabel)
 813       c = tickBoxCount st
 814       mes = mixEntries st
 815       ids = occEnvElts fvs
 816   in ( Just (c, ids)
 817      , noFVs
 818      , st {tickBoxCount=c+1, mixEntries=me:mes}
 819      )
 820 allocATickBox _boxLabel _pos _fvs = return Nothing
 821
 822 allocBinTickBox :: (Bool -> BoxLabel) -> SrcSpan -> TM (HsExpr Id)
 823                 -> TM (LHsExpr Id)
 824 allocBinTickBox boxLabel pos m
 825  | not opt_Hpc = allocTickBox (ExpBox False) pos m
 826  | isGoodSrcSpan' pos =
 827  do
 828  e <- m
 829  TM $ \ env st ->
 830   let meT = (pos,declPath env, [],boxLabel True)
 831       meF = (pos,declPath env, [],boxLabel False)
 832       meE = (pos,declPath env, [],ExpBox False)
 833       c = tickBoxCount st
 834       mes = mixEntries st
 835   in
 836              ( L pos $ HsTick c [] $ L pos $ HsBinTick (c+1) (c+2) (L pos e)
 837            -- notice that F and T are reversed,
 838            -- because we are building the list in
 839            -- reverse...
 840              , noFVs
 841              , st {tickBoxCount=c+3 , mixEntries=meF:meT:meE:mes}
 842              )
 843 allocBinTickBox _boxLabel pos m = do e <- m; return (L pos e)
 844
 845 isGoodSrcSpan' :: SrcSpan -> Bool
 846 isGoodSrcSpan' pos
 847    | not (isGoodSrcSpan pos) = False
 848    | start == end            = False
 849    | otherwise               = True
 850   where
 851    start = srcSpanStart pos
 852    end   = srcSpanEnd pos
 853
 854 mkHpcPos :: SrcSpan -> HpcPos
 855 mkHpcPos pos
 856    | not (isGoodSrcSpan' pos) = panic "bad source span; expected such spans to be filtered out"
 857    | otherwise                = hpcPos
 858   where
 859    start = srcSpanStart pos
 860    end   = srcSpanEnd pos
 861    hpcPos = toHpcPos ( srcLocLine start
 862                      , srcLocCol start
 863                      , srcLocLine end
 864                      , srcLocCol end - 1
 865                      )
 866
 867 hpcSrcSpan :: SrcSpan
 868 hpcSrcSpan = mkGeneralSrcSpan (fsLit "Haskell Program Coverage internals")
 869 \end{code}
 870
 871
 872 \begin{code}
 873 matchesOneOfMany :: [LMatch Id] -> Bool
 874 matchesOneOfMany lmatches = sum (map matchCount lmatches) > 1
 875   where
 876         matchCount (L _ (Match _pats _ty (GRHSs grhss _binds))) = length grhss
 877 \end{code}
 878
 879
 880 \begin{code}
 881 type MixEntry_ = (SrcSpan, [String], [OccName], BoxLabel)
 882
 883 -- For the hash value, we hash everything: the file name,
 884 --  the timestamp of the original source file, the tab stop,
 885 --  and the mix entries. We cheat, and hash the show'd string.
 886 -- This hash only has to be hashed at Mix creation time,
 887 -- and is for sanity checking only.
 888
 889 mixHash :: FilePath -> Integer -> Int -> [MixEntry] -> Int
 890 mixHash file tm tabstop entries = fromIntegral $ hashString
 891         (show $ Mix file tm 0 tabstop entries)
 892 \end{code}
 893
 894 %************************************************************************
 895 %*                                                                      *
 896 %*              initialisation
 897 %*                                                                      *
 898 %************************************************************************
 899
 900 Each module compiled with -fhpc declares an initialisation function of
 901 the form `hpc_init_<module>()`, which is emitted into the _stub.c file
 902 and annotated with __attribute__((constructor)) so that it gets
 903 executed at startup time.
 904
 905 The function's purpose is to call hs_hpc_module to register this
 906 module with the RTS, and it looks something like this:
 907
 908 static void hpc_init_Main(void) __attribute__((constructor));
 909 static void hpc_init_Main(void)
 910 {extern StgWord64 _hpc_tickboxes_Main_hpc[];
 911  hs_hpc_module("Main",8,1150288664,_hpc_tickboxes_Main_hpc);}
 912
 913 \begin{code}
 914 hpcInitCode :: Module -> HpcInfo -> SDoc
 915 hpcInitCode _ (NoHpcInfo {}) = empty
 916 hpcInitCode this_mod (HpcInfo tickCount hashNo)
 917  = vcat
 918     [ text "static void hpc_init_" <> ppr this_mod
 919          <> text "(void) __attribute__((constructor));"
 920     , text "static void hpc_init_" <> ppr this_mod <> text "(void)"
 921     , braces (vcat [
 922         ptext (sLit "extern StgWord64 ") <> tickboxes <>
 923                ptext (sLit "[]") <> semi,
 924         ptext (sLit "hs_hpc_module") <>
 925           parens (hcat (punctuate comma [
 926               doubleQuotes full_name_str,
 927               int tickCount, -- really StgWord32
 928               int hashNo,    -- really StgWord32
 929               tickboxes
 930             ])) <> semi
 931        ])
 932     ]
 933   where
 934     tickboxes = pprCLabel (mkHpcTicksLabel $ this_mod)
 935
 936     module_name  = hcat (map (text.charToC) $
 937                          bytesFS (moduleNameFS (Module.moduleName this_mod)))
 938     package_name = hcat (map (text.charToC) $
 939                          bytesFS (packageIdFS  (modulePackageId this_mod)))
 940     full_name_str
 941        | modulePackageId this_mod == mainPackageId
 942        = module_name
 943        | otherwise
 944        = package_name <> char '/' <> module_name
 945 \end{code}