compiler/deSugar/Desugar.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[Desugar]{@deSugar@: the main function}
   5
   6 \begin{code}
   7 module Desugar ( deSugar, deSugarExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import DynFlags         ( DynFlag(..), DynFlags(..), dopt, GhcMode(..) )
  12 import StaticFlags      ( opt_SccProfilingOn )
  13 import DriverPhases     ( isHsBoot )
  14 import HscTypes         ( ModGuts(..), HscEnv(..),
  15                           Dependencies(..), ForeignStubs(..), TypeEnv, IsBootInterface )
  16 import HsSyn            ( RuleDecl(..), RuleBndr(..), LHsExpr, LRuleDecl )
  17 import TcRnTypes        ( TcGblEnv(..), ImportAvails(..) )
  18 import MkIface          ( mkUsageInfo )
  19 import Id               ( Id, setIdExported, idName )
  20 import Name             ( Name, isExternalName, nameIsLocalOrFrom, nameOccName )
  21 import CoreSyn
  22 import PprCore          ( pprRules, pprCoreExpr )
  23 import DsMonad
  24 import DsExpr           ( dsLExpr )
  25 import DsBinds          ( dsTopLHsBinds, decomposeRuleLhs, AutoScc(..) )
  26 import DsForeign        ( dsForeigns )
  27 import DsExpr           ()      -- Forces DsExpr to be compiled; DsBinds only
  28                                 -- depends on DsExpr.hi-boot.
  29 import Module
  30 import UniqFM           ( eltsUFM, delFromUFM )
  31 import PackageConfig    ( thPackageId )
  32 import RdrName          ( GlobalRdrEnv )
  33 import NameSet
  34 import VarSet
  35 import Rules            ( roughTopNames )
  36 import CoreLint         ( showPass, endPass )
  37 import CoreFVs          ( ruleRhsFreeVars, exprsFreeNames )
  38 import ErrUtils         ( doIfSet, dumpIfSet_dyn )
  39 import ListSetOps       ( insertList )
  40 import Outputable
  41 import SrcLoc           ( Located(..) )
  42 import DATA_IOREF       ( readIORef )
  43 import Maybes           ( catMaybes )
  44 import FastString
  45 import Util             ( sortLe )
  46 \end{code}
  47
  48 %************************************************************************
  49 %*                                                                      *
  50 %*              The main function: deSugar
  51 %*                                                                      *
  52 %************************************************************************
  53
  54 \begin{code}
  55 deSugar :: HscEnv -> TcGblEnv -> IO (Maybe ModGuts)
  56 -- Can modify PCS by faulting in more declarations
  57
  58 deSugar hsc_env
  59         tcg_env@(TcGblEnv { tcg_mod       = mod,
  60                             tcg_src       = hsc_src,
  61                             tcg_type_env  = type_env,
  62                             tcg_imports   = imports,
  63                             tcg_exports   = exports,
  64                             tcg_dus       = dus,
  65                             tcg_inst_uses = dfun_uses_var,
  66                             tcg_th_used   = th_var,
  67                             tcg_keep      = keep_var,
  68                             tcg_rdr_env   = rdr_env,
  69                             tcg_fix_env   = fix_env,
  70                             tcg_deprecs   = deprecs,
  71                             tcg_binds     = binds,
  72                             tcg_fords     = fords,
  73                             tcg_rules     = rules,
  74                             tcg_insts     = insts })
  75   = do  { showPass dflags "Desugar"
  76
  77         -- Desugar the program
  78         ; mb_res <- case ghcMode dflags of
  79                      JustTypecheck -> return (Just ([], [], NoStubs))
  80                      _             -> initDs hsc_env mod rdr_env type_env $ do
  81                                         { core_prs <- dsTopLHsBinds auto_scc binds
  82                                         ; (ds_fords, foreign_prs) <- dsForeigns fords
  83                                         ; let all_prs = foreign_prs ++ core_prs
  84                                               local_bndrs = mkVarSet (map fst all_prs)
  85                                         ; ds_rules <- mappM (dsRule mod local_bndrs) rules
  86                                         ; return (all_prs, catMaybes ds_rules, ds_fords)
  87                                         }
  88         ; case mb_res of {
  89            Nothing -> return Nothing ;
  90            Just (all_prs, ds_rules, ds_fords) -> do
  91
  92         {       -- Add export flags to bindings
  93           keep_alive <- readIORef keep_var
  94         ; let final_prs = addExportFlags ghci_mode exports keep_alive
  95                                          all_prs ds_rules
  96               ds_binds  = [Rec final_prs]
  97         -- Notice that we put the whole lot in a big Rec, even the foreign binds
  98         -- When compiling PrelFloat, which defines data Float = F# Float#
  99         -- we want F# to be in scope in the foreign marshalling code!
 100         -- You might think it doesn't matter, but the simplifier brings all top-level
 101         -- things into the in-scope set before simplifying; so we get no unfolding for F#!
 102
 103         -- Lint result if necessary
 104         ; endPass dflags "Desugar" Opt_D_dump_ds ds_binds
 105
 106         -- Dump output
 107         ; doIfSet (dopt Opt_D_dump_ds dflags)
 108                   (printDump (ppr_ds_rules ds_rules))
 109
 110         ; dfun_uses <- readIORef dfun_uses_var          -- What dfuns are used
 111         ; th_used   <- readIORef th_var                 -- Whether TH is used
 112         ; let used_names = allUses dus `unionNameSets` dfun_uses
 113               pkgs | th_used   = insertList thPackageId (imp_dep_pkgs imports)
 114                    | otherwise = imp_dep_pkgs imports
 115
 116               dep_mods = eltsUFM (delFromUFM (imp_dep_mods imports) (moduleName mod))
 117                 -- M.hi-boot can be in the imp_dep_mods, but we must remove
 118                 -- it before recording the modules on which this one depends!
 119                 -- (We want to retain M.hi-boot in imp_dep_mods so that
 120                 --  loadHiBootInterface can see if M's direct imports depend
 121                 --  on M.hi-boot, and hence that we should do the hi-boot consistency
 122                 --  check.)
 123
 124               dir_imp_mods = imp_mods imports
 125
 126         ; usages <- mkUsageInfo hsc_env dir_imp_mods dep_mods used_names
 127
 128         ; let
 129                 -- Modules don't compare lexicographically usually,
 130                 -- but we want them to do so here.
 131              le_mod :: Module -> Module -> Bool
 132              le_mod m1 m2 = moduleNameFS (moduleName m1)
 133                                 <= moduleNameFS (moduleName m2)
 134              le_dep_mod :: (ModuleName, IsBootInterface) -> (ModuleName, IsBootInterface) -> Bool
 135              le_dep_mod (m1,_) (m2,_) = moduleNameFS m1 <= moduleNameFS m2
 136
 137              deps = Deps { dep_mods  = sortLe le_dep_mod dep_mods,
 138                            dep_pkgs  = sortLe (<=)   pkgs,
 139                            dep_orphs = sortLe le_mod (imp_orphs imports) }
 140                 -- sort to get into canonical order
 141
 142              mod_guts = ModGuts {
 143                 mg_module   = mod,
 144                 mg_boot     = isHsBoot hsc_src,
 145                 mg_exports  = exports,
 146                 mg_deps     = deps,
 147                 mg_usages   = usages,
 148                 mg_dir_imps = [m | (m,_,_) <- moduleEnvElts dir_imp_mods],
 149                 mg_rdr_env  = rdr_env,
 150                 mg_fix_env  = fix_env,
 151                 mg_deprecs  = deprecs,
 152                 mg_types    = type_env,
 153                 mg_insts    = insts,
 154                 mg_rules    = ds_rules,
 155                 mg_binds    = ds_binds,
 156                 mg_foreign  = ds_fords }
 157
 158         ; return (Just mod_guts)
 159         }}}
 160
 161   where
 162     dflags    = hsc_dflags hsc_env
 163     ghci_mode = ghcMode (hsc_dflags hsc_env)
 164     auto_scc | opt_SccProfilingOn = TopLevel
 165              | otherwise          = NoSccs
 166
 167 deSugarExpr :: HscEnv
 168             -> Module -> GlobalRdrEnv -> TypeEnv
 169             -> LHsExpr Id
 170             -> IO (Maybe CoreExpr)
 171 -- Prints its own errors; returns Nothing if error occurred
 172
 173 deSugarExpr hsc_env this_mod rdr_env type_env tc_expr
 174   = do  { let dflags = hsc_dflags hsc_env
 175         ; showPass dflags "Desugar"
 176
 177         -- Do desugaring
 178         ; mb_core_expr <- initDs hsc_env this_mod rdr_env type_env $
 179                           dsLExpr tc_expr
 180
 181         ; case mb_core_expr of {
 182             Nothing   -> return Nothing ;
 183             Just expr -> do {
 184
 185                 -- Dump output
 186           dumpIfSet_dyn dflags Opt_D_dump_ds "Desugared" (pprCoreExpr expr)
 187
 188         ; return (Just expr) } } }
 189
 190 --              addExportFlags
 191 -- Set the no-discard flag if either
 192 --      a) the Id is exported
 193 --      b) it's mentioned in the RHS of an orphan rule
 194 --      c) it's in the keep-alive set
 195 --
 196 -- It means that the binding won't be discarded EVEN if the binding
 197 -- ends up being trivial (v = w) -- the simplifier would usually just
 198 -- substitute w for v throughout, but we don't apply the substitution to
 199 -- the rules (maybe we should?), so this substitution would make the rule
 200 -- bogus.
 201
 202 -- You might wonder why exported Ids aren't already marked as such;
 203 -- it's just because the type checker is rather busy already and
 204 -- I didn't want to pass in yet another mapping.
 205
 206 addExportFlags ghci_mode exports keep_alive prs rules
 207   = [(add_export bndr, rhs) | (bndr,rhs) <- prs]
 208   where
 209     add_export bndr
 210         | dont_discard bndr = setIdExported bndr
 211         | otherwise         = bndr
 212
 213     orph_rhs_fvs = unionVarSets [ ruleRhsFreeVars rule
 214                                 | rule <- rules,
 215                                   not (isLocalRule rule) ]
 216         -- A non-local rule keeps alive the free vars of its right-hand side.
 217         -- (A "non-local" is one whose head function is not locally defined.)
 218         -- Local rules are (later, after gentle simplification)
 219         -- attached to the Id, and that keeps the rhs free vars alive.
 220
 221     dont_discard bndr = is_exported name
 222                      || name `elemNameSet` keep_alive
 223                      || bndr `elemVarSet` orph_rhs_fvs
 224                      where
 225                         name = idName bndr
 226
 227         -- In interactive mode, we don't want to discard any top-level
 228         -- entities at all (eg. do not inline them away during
 229         -- simplification), and retain them all in the TypeEnv so they are
 230         -- available from the command line.
 231         --
 232         -- isExternalName separates the user-defined top-level names from those
 233         -- introduced by the type checker.
 234     is_exported :: Name -> Bool
 235     is_exported | ghci_mode == Interactive = isExternalName
 236                 | otherwise                = (`elemNameSet` exports)
 237
 238 ppr_ds_rules [] = empty
 239 ppr_ds_rules rules
 240   = text "" $$ text "-------------- DESUGARED RULES -----------------" $$
 241     pprRules rules
 242 \end{code}
 243
 244
 245
 246 %************************************************************************
 247 %*                                                                      *
 248 %*              Desugaring transformation rules
 249 %*                                                                      *
 250 %************************************************************************
 251
 252 \begin{code}
 253 dsRule :: Module -> IdSet -> LRuleDecl Id -> DsM (Maybe CoreRule)
 254 dsRule mod in_scope (L loc (HsRule name act vars lhs tv_lhs rhs fv_rhs))
 255   = putSrcSpanDs loc $
 256     do  { let bndrs     = [var | RuleBndr (L _ var) <- vars]
 257         ; lhs'  <- dsLExpr lhs
 258         ; rhs'  <- dsLExpr rhs
 259
 260         ; case decomposeRuleLhs bndrs lhs' of {
 261                 Nothing -> do { warnDs msg; return Nothing } ;
 262                 Just (bndrs', fn_id, args) -> do
 263
 264         -- Substitute the dict bindings eagerly,
 265         -- and take the body apart into a (f args) form
 266         { let local_rule = nameIsLocalOrFrom mod fn_name
 267                 -- NB we can't use isLocalId in the orphan test,
 268                 -- because isLocalId isn't true of class methods
 269               fn_name   = idName fn_id
 270               lhs_names = fn_name : nameSetToList (exprsFreeNames args)
 271                 -- No need to delete bndrs, because
 272                 -- exprsFreeNames finds only External names
 273               orph = case filter (nameIsLocalOrFrom mod) lhs_names of
 274                         (n:ns) -> Just (nameOccName n)
 275                         []     -> Nothing
 276
 277               rule = Rule { ru_name = name, ru_fn = fn_name, ru_act = act,
 278                             ru_bndrs = bndrs', ru_args = args, ru_rhs = rhs',
 279                             ru_rough = roughTopNames args,
 280                             ru_local = local_rule, ru_orph = orph }
 281         ; return (Just rule)
 282         } } }
 283   where
 284     msg = hang (ptext SLIT("RULE left-hand side too complicated to desugar; ignored"))
 285              2 (ppr lhs)
 286 \end{code}