compiler/deSugar/DsArrows.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Desugaring arrow commands
   7
   8 \begin{code}
   9 module DsArrows ( dsProcExpr ) where
  10
  11 #include "HsVersions.h"
  12
  13 import Match
  14 import DsUtils
  15 import DsMonad
  16
  17 import HsSyn    hiding (collectPatBinders, collectPatsBinders )
  18 import TcHsSyn
  19
  20 -- NB: The desugarer, which straddles the source and Core worlds, sometimes
  21 --     needs to see source types (newtypes etc), and sometimes not
  22 --     So WATCH OUT; check each use of split*Ty functions.
  23 -- Sigh.  This is a pain.
  24
  25 import {-# SOURCE #-} DsExpr ( dsExpr, dsLExpr, dsLocalBinds )
  26
  27 import TcType
  28 import Type
  29 import CoreSyn
  30 import CoreFVs
  31 import CoreUtils
  32 import MkCore
  33
  34 import Name
  35 import Var
  36 import Id
  37 import DataCon
  38 import TysWiredIn
  39 import BasicTypes
  40 import PrelNames
  41 import Outputable
  42 import Bag
  43 import VarSet
  44 import SrcLoc
  45
  46 import Data.List
  47 \end{code}
  48
  49 \begin{code}
  50 data DsCmdEnv = DsCmdEnv {
  51         meth_binds :: [CoreBind],
  52         arr_id, compose_id, first_id, app_id, choice_id, loop_id :: CoreExpr
  53     }
  54
  55 mkCmdEnv :: SyntaxTable Id -> DsM DsCmdEnv
  56 mkCmdEnv ids = do
  57     (meth_binds, ds_meths) <- dsSyntaxTable ids
  58     return $ DsCmdEnv {
  59                meth_binds = meth_binds,
  60                arr_id     = Var (lookupEvidence ds_meths arrAName),
  61                compose_id = Var (lookupEvidence ds_meths composeAName),
  62                first_id   = Var (lookupEvidence ds_meths firstAName),
  63                app_id     = Var (lookupEvidence ds_meths appAName),
  64                choice_id  = Var (lookupEvidence ds_meths choiceAName),
  65                loop_id    = Var (lookupEvidence ds_meths loopAName)
  66              }
  67
  68 bindCmdEnv :: DsCmdEnv -> CoreExpr -> CoreExpr
  69 bindCmdEnv ids body = foldr Let body (meth_binds ids)
  70
  71 -- arr :: forall b c. (b -> c) -> a b c
  72 do_arr :: DsCmdEnv -> Type -> Type -> CoreExpr -> CoreExpr
  73 do_arr ids b_ty c_ty f = mkApps (arr_id ids) [Type b_ty, Type c_ty, f]
  74
  75 -- (>>>) :: forall b c d. a b c -> a c d -> a b d
  76 do_compose :: DsCmdEnv -> Type -> Type -> Type ->
  77                 CoreExpr -> CoreExpr -> CoreExpr
  78 do_compose ids b_ty c_ty d_ty f g
  79   = mkApps (compose_id ids) [Type b_ty, Type c_ty, Type d_ty, f, g]
  80
  81 -- first :: forall b c d. a b c -> a (b,d) (c,d)
  82 do_first :: DsCmdEnv -> Type -> Type -> Type -> CoreExpr -> CoreExpr
  83 do_first ids b_ty c_ty d_ty f
  84   = mkApps (first_id ids) [Type b_ty, Type c_ty, Type d_ty, f]
  85
  86 -- app :: forall b c. a (a b c, b) c
  87 do_app :: DsCmdEnv -> Type -> Type -> CoreExpr
  88 do_app ids b_ty c_ty = mkApps (app_id ids) [Type b_ty, Type c_ty]
  89
  90 -- (|||) :: forall b d c. a b d -> a c d -> a (Either b c) d
  91 -- note the swapping of d and c
  92 do_choice :: DsCmdEnv -> Type -> Type -> Type ->
  93                 CoreExpr -> CoreExpr -> CoreExpr
  94 do_choice ids b_ty c_ty d_ty f g
  95   = mkApps (choice_id ids) [Type b_ty, Type d_ty, Type c_ty, f, g]
  96
  97 -- loop :: forall b d c. a (b,d) (c,d) -> a b c
  98 -- note the swapping of d and c
  99 do_loop :: DsCmdEnv -> Type -> Type -> Type -> CoreExpr -> CoreExpr
 100 do_loop ids b_ty c_ty d_ty f
 101   = mkApps (loop_id ids) [Type b_ty, Type d_ty, Type c_ty, f]
 102
 103 -- map_arrow (f :: b -> c) (g :: a c d) = arr f >>> g :: a b d
 104 do_map_arrow :: DsCmdEnv -> Type -> Type -> Type ->
 105                 CoreExpr -> CoreExpr -> CoreExpr
 106 do_map_arrow ids b_ty c_ty d_ty f c
 107    = do_compose ids b_ty c_ty d_ty (do_arr ids b_ty c_ty f) c
 108
 109 mkFailExpr :: HsMatchContext Id -> Type -> DsM CoreExpr
 110 mkFailExpr ctxt ty
 111   = mkErrorAppDs pAT_ERROR_ID ty (matchContextErrString ctxt)
 112
 113 -- construct CoreExpr for \ (a :: a_ty, b :: b_ty) -> b
 114 mkSndExpr :: Type -> Type -> DsM CoreExpr
 115 mkSndExpr a_ty b_ty = do
 116     a_var <- newSysLocalDs a_ty
 117     b_var <- newSysLocalDs b_ty
 118     pair_var <- newSysLocalDs (mkCorePairTy a_ty b_ty)
 119     return (Lam pair_var
 120                (coreCasePair pair_var a_var b_var (Var b_var)))
 121 \end{code}
 122
 123 Build case analysis of a tuple.  This cannot be done in the DsM monad,
 124 because the list of variables is typically not yet defined.
 125
 126 \begin{code}
 127 -- coreCaseTuple [u1..] v [x1..xn] body
 128 --      = case v of v { (x1, .., xn) -> body }
 129 -- But the matching may be nested if the tuple is very big
 130
 131 coreCaseTuple :: UniqSupply -> Id -> [Id] -> CoreExpr -> CoreExpr
 132 coreCaseTuple uniqs scrut_var vars body
 133   = mkTupleCase uniqs vars body scrut_var (Var scrut_var)
 134
 135 coreCasePair :: Id -> Id -> Id -> CoreExpr -> CoreExpr
 136 coreCasePair scrut_var var1 var2 body
 137   = Case (Var scrut_var) scrut_var (exprType body)
 138          [(DataAlt (tupleCon Boxed 2), [var1, var2], body)]
 139 \end{code}
 140
 141 \begin{code}
 142 mkCorePairTy :: Type -> Type -> Type
 143 mkCorePairTy t1 t2 = mkBoxedTupleTy [t1, t2]
 144
 145 mkCorePairExpr :: CoreExpr -> CoreExpr -> CoreExpr
 146 mkCorePairExpr e1 e2 = mkCoreTup [e1, e2]
 147 \end{code}
 148
 149 The input is divided into a local environment, which is a flat tuple
 150 (unless it's too big), and a stack, each element of which is paired
 151 with the environment in turn.  In general, the input has the form
 152
 153         (...((x1,...,xn),s1),...sk)
 154
 155 where xi are the environment values, and si the ones on the stack,
 156 with s1 being the "top", the first one to be matched with a lambda.
 157
 158 \begin{code}
 159 envStackType :: [Id] -> [Type] -> Type
 160 envStackType ids stack_tys = foldl mkCorePairTy (mkBigCoreVarTupTy ids) stack_tys
 161
 162 ----------------------------------------------
 163 --              buildEnvStack
 164 --
 165 --      (...((x1,...,xn),s1),...sk)
 166
 167 buildEnvStack :: [Id] -> [Id] -> CoreExpr
 168 buildEnvStack env_ids stack_ids
 169   = foldl mkCorePairExpr (mkBigCoreVarTup env_ids) (map Var stack_ids)
 170
 171 ----------------------------------------------
 172 --              matchEnvStack
 173 --
 174 --      \ (...((x1,...,xn),s1),...sk) -> e
 175 --      =>
 176 --      \ zk ->
 177 --      case zk of (zk-1,sk) ->
 178 --      ...
 179 --      case z1 of (z0,s1) ->
 180 --      case z0 of (x1,...,xn) ->
 181 --      e
 182
 183 matchEnvStack   :: [Id]         -- x1..xn
 184                 -> [Id]         -- s1..sk
 185                 -> CoreExpr     -- e
 186                 -> DsM CoreExpr
 187 matchEnvStack env_ids stack_ids body = do
 188     uniqs <- newUniqueSupply
 189     tup_var <- newSysLocalDs (mkBigCoreVarTupTy env_ids)
 190     matchVarStack tup_var stack_ids
 191                (coreCaseTuple uniqs tup_var env_ids body)
 192
 193
 194 ----------------------------------------------
 195 --              matchVarStack
 196 --
 197 --      \ (...(z0,s1),...sk) -> e
 198 --      =>
 199 --      \ zk ->
 200 --      case zk of (zk-1,sk) ->
 201 --      ...
 202 --      case z1 of (z0,s1) ->
 203 --      e
 204
 205 matchVarStack :: Id             -- z0
 206               -> [Id]           -- s1..sk
 207               -> CoreExpr       -- e
 208               -> DsM CoreExpr
 209 matchVarStack env_id [] body
 210   = return (Lam env_id body)
 211 matchVarStack env_id (stack_id:stack_ids) body = do
 212     pair_id <- newSysLocalDs (mkCorePairTy (idType env_id) (idType stack_id))
 213     matchVarStack pair_id stack_ids
 214                (coreCasePair pair_id env_id stack_id body)
 215 \end{code}
 216
 217 \begin{code}
 218 mkHsEnvStackExpr :: [Id] -> [Id] -> LHsExpr Id
 219 mkHsEnvStackExpr env_ids stack_ids
 220   = foldl (\a b -> mkLHsTupleExpr [a,b])
 221           (mkLHsVarTuple env_ids)
 222           (map nlHsVar stack_ids)
 223 \end{code}
 224
 225 Translation of arrow abstraction
 226
 227 \begin{code}
 228
 229 --      A | xs |- c :: [] t'        ---> c'
 230 --      --------------------------
 231 --      A |- proc p -> c :: a t t'  ---> arr (\ p -> (xs)) >>> c'
 232 --
 233 --              where (xs) is the tuple of variables bound by p
 234
 235 dsProcExpr
 236         :: LPat Id
 237         -> LHsCmdTop Id
 238         -> DsM CoreExpr
 239 dsProcExpr pat (L _ (HsCmdTop cmd [] cmd_ty ids)) = do
 240     meth_ids <- mkCmdEnv ids
 241     let locals = mkVarSet (collectPatBinders pat)
 242     (core_cmd, _free_vars, env_ids) <- dsfixCmd meth_ids locals [] cmd_ty cmd
 243     let env_ty = mkBigCoreVarTupTy env_ids
 244     fail_expr <- mkFailExpr ProcExpr env_ty
 245     var <- selectSimpleMatchVarL pat
 246     match_code <- matchSimply (Var var) ProcExpr pat (mkBigCoreVarTup env_ids) fail_expr
 247     let pat_ty = hsLPatType pat
 248         proc_code = do_map_arrow meth_ids pat_ty env_ty cmd_ty
 249                     (Lam var match_code)
 250                     core_cmd
 251     return (bindCmdEnv meth_ids proc_code)
 252 dsProcExpr _ c = pprPanic "dsProcExpr" (ppr c)
 253 \end{code}
 254
 255 Translation of command judgements of the form
 256
 257         A | xs |- c :: [ts] t
 258
 259 \begin{code}
 260 dsLCmd :: DsCmdEnv -> IdSet -> [Id] -> [Type] -> Type -> LHsCmd Id
 261        -> DsM (CoreExpr, IdSet)
 262 dsLCmd ids local_vars env_ids stack res_ty cmd
 263   = dsCmd ids local_vars env_ids stack res_ty (unLoc cmd)
 264
 265 dsCmd   :: DsCmdEnv             -- arrow combinators
 266         -> IdSet                -- set of local vars available to this command
 267         -> [Id]                 -- list of vars in the input to this command
 268                                 -- This is typically fed back,
 269                                 -- so don't pull on it too early
 270         -> [Type]               -- type of the stack
 271         -> Type                 -- return type of the command
 272         -> HsCmd Id             -- command to desugar
 273         -> DsM (CoreExpr,       -- desugared expression
 274                 IdSet)          -- set of local vars that occur free
 275
 276 --      A |- f :: a (t*ts) t'
 277 --      A, xs |- arg :: t
 278 --      -----------------------------
 279 --      A | xs |- f -< arg :: [ts] t'
 280 --
 281 --              ---> arr (\ ((xs)*ts) -> (arg*ts)) >>> f
 282
 283 dsCmd ids local_vars env_ids stack res_ty
 284         (HsArrApp arrow arg arrow_ty HsFirstOrderApp _)= do
 285     let
 286         (a_arg_ty, _res_ty') = tcSplitAppTy arrow_ty
 287         (_a_ty, arg_ty) = tcSplitAppTy a_arg_ty
 288     core_arrow <- dsLExpr arrow
 289     core_arg   <- dsLExpr arg
 290     stack_ids  <- mapM newSysLocalDs stack
 291     core_make_arg <- matchEnvStack env_ids stack_ids
 292                       (foldl mkCorePairExpr core_arg (map Var stack_ids))
 293     return (do_map_arrow ids
 294               (envStackType env_ids stack)
 295               arg_ty
 296               res_ty
 297               core_make_arg
 298               core_arrow,
 299                exprFreeVars core_arg `intersectVarSet` local_vars)
 300
 301 --      A, xs |- f :: a (t*ts) t'
 302 --      A, xs |- arg :: t
 303 --      ------------------------------
 304 --      A | xs |- f -<< arg :: [ts] t'
 305 --
 306 --              ---> arr (\ ((xs)*ts) -> (f,(arg*ts))) >>> app
 307
 308 dsCmd ids local_vars env_ids stack res_ty
 309         (HsArrApp arrow arg arrow_ty HsHigherOrderApp _) = do
 310     let
 311         (a_arg_ty, _res_ty') = tcSplitAppTy arrow_ty
 312         (_a_ty, arg_ty) = tcSplitAppTy a_arg_ty
 313
 314     core_arrow <- dsLExpr arrow
 315     core_arg   <- dsLExpr arg
 316     stack_ids  <- mapM newSysLocalDs stack
 317     core_make_pair <- matchEnvStack env_ids stack_ids
 318           (mkCorePairExpr core_arrow
 319              (foldl mkCorePairExpr core_arg (map Var stack_ids)))
 320
 321     return (do_map_arrow ids
 322               (envStackType env_ids stack)
 323               (mkCorePairTy arrow_ty arg_ty)
 324               res_ty
 325               core_make_pair
 326               (do_app ids arg_ty res_ty),
 327             (exprFreeVars core_arrow `unionVarSet` exprFreeVars core_arg)
 328               `intersectVarSet` local_vars)
 329
 330 --      A | ys |- c :: [t:ts] t'
 331 --      A, xs  |- e :: t
 332 --      ------------------------
 333 --      A | xs |- c e :: [ts] t'
 334 --
 335 --              ---> arr (\ ((xs)*ts) -> let z = e in (((ys),z)*ts)) >>> c
 336
 337 dsCmd ids local_vars env_ids stack res_ty (HsApp cmd arg) = do
 338     core_arg <- dsLExpr arg
 339     let
 340         arg_ty = exprType core_arg
 341         stack' = arg_ty:stack
 342     (core_cmd, free_vars, env_ids')
 343              <- dsfixCmd ids local_vars stack' res_ty cmd
 344     stack_ids <- mapM newSysLocalDs stack
 345     arg_id <- newSysLocalDs arg_ty
 346     -- push the argument expression onto the stack
 347     let
 348         core_body = bindNonRec arg_id core_arg
 349                         (buildEnvStack env_ids' (arg_id:stack_ids))
 350     -- match the environment and stack against the input
 351     core_map <- matchEnvStack env_ids stack_ids core_body
 352     return (do_map_arrow ids
 353                       (envStackType env_ids stack)
 354                       (envStackType env_ids' stack')
 355                       res_ty
 356                       core_map
 357                       core_cmd,
 358       (exprFreeVars core_arg `intersectVarSet` local_vars)
 359               `unionVarSet` free_vars)
 360
 361 --      A | ys |- c :: [ts] t'
 362 --      -----------------------------------------------
 363 --      A | xs |- \ p1 ... pk -> c :: [t1:...:tk:ts] t'
 364 --
 365 --              ---> arr (\ ((((xs), p1), ... pk)*ts) -> ((ys)*ts)) >>> c
 366
 367 dsCmd ids local_vars env_ids stack res_ty
 368     (HsLam (MatchGroup [L _ (Match pats _ (GRHSs [L _ (GRHS [] body)] _ ))] _)) = do
 369     let
 370         pat_vars = mkVarSet (collectPatsBinders pats)
 371         local_vars' = local_vars `unionVarSet` pat_vars
 372         stack' = drop (length pats) stack
 373     (core_body, free_vars, env_ids') <- dsfixCmd ids local_vars' stack' res_ty body
 374     stack_ids <- mapM newSysLocalDs stack
 375
 376     -- the expression is built from the inside out, so the actions
 377     -- are presented in reverse order
 378
 379     let
 380         (actual_ids, stack_ids') = splitAt (length pats) stack_ids
 381         -- build a new environment, plus what's left of the stack
 382         core_expr = buildEnvStack env_ids' stack_ids'
 383         in_ty = envStackType env_ids stack
 384         in_ty' = envStackType env_ids' stack'
 385
 386     fail_expr <- mkFailExpr LambdaExpr in_ty'
 387     -- match the patterns against the top of the old stack
 388     match_code <- matchSimplys (map Var actual_ids) LambdaExpr pats core_expr fail_expr
 389     -- match the old environment and stack against the input
 390     select_code <- matchEnvStack env_ids stack_ids match_code
 391     return (do_map_arrow ids in_ty in_ty' res_ty select_code core_body,
 392             free_vars `minusVarSet` pat_vars)
 393
 394 dsCmd ids local_vars env_ids stack res_ty (HsPar cmd)
 395   = dsLCmd ids local_vars env_ids stack res_ty cmd
 396
 397 --      A, xs |- e :: Bool
 398 --      A | xs1 |- c1 :: [ts] t
 399 --      A | xs2 |- c2 :: [ts] t
 400 --      ----------------------------------------
 401 --      A | xs |- if e then c1 else c2 :: [ts] t
 402 --
 403 --              ---> arr (\ ((xs)*ts) ->
 404 --                      if e then Left ((xs1)*ts) else Right ((xs2)*ts)) >>>
 405 --                   c1 ||| c2
 406
 407 dsCmd ids local_vars env_ids stack res_ty (HsIf mb_fun cond then_cmd else_cmd) = do
 408     core_cond <- dsLExpr cond
 409     (core_then, fvs_then, then_ids) <- dsfixCmd ids local_vars stack res_ty then_cmd
 410     (core_else, fvs_else, else_ids) <- dsfixCmd ids local_vars stack res_ty else_cmd
 411     stack_ids  <- mapM newSysLocalDs stack
 412     either_con <- dsLookupTyCon eitherTyConName
 413     left_con   <- dsLookupDataCon leftDataConName
 414     right_con  <- dsLookupDataCon rightDataConName
 415
 416     let mk_left_expr ty1 ty2 e = mkConApp left_con [Type ty1, Type ty2, e]
 417         mk_right_expr ty1 ty2 e = mkConApp right_con [Type ty1, Type ty2, e]
 418
 419         in_ty = envStackType env_ids stack
 420         then_ty = envStackType then_ids stack
 421         else_ty = envStackType else_ids stack
 422         sum_ty = mkTyConApp either_con [then_ty, else_ty]
 423         fvs_cond = exprFreeVars core_cond `intersectVarSet` local_vars
 424
 425         core_left  = mk_left_expr  then_ty else_ty (buildEnvStack then_ids stack_ids)
 426         core_right = mk_right_expr then_ty else_ty (buildEnvStack else_ids stack_ids)
 427
 428     core_if <- case mb_fun of
 429        Just fun -> do { core_fun <- dsExpr fun
 430                       ; matchEnvStack env_ids stack_ids $
 431                         mkCoreApps core_fun [core_cond, core_left, core_right] }
 432        Nothing  -> matchEnvStack env_ids stack_ids $
 433                    mkIfThenElse core_cond core_left core_right
 434
 435     return (do_map_arrow ids in_ty sum_ty res_ty
 436                 core_if
 437                 (do_choice ids then_ty else_ty res_ty core_then core_else),
 438         fvs_cond `unionVarSet` fvs_then `unionVarSet` fvs_else)
 439 \end{code}
 440
 441 Case commands are treated in much the same way as if commands
 442 (see above) except that there are more alternatives.  For example
 443
 444         case e of { p1 -> c1; p2 -> c2; p3 -> c3 }
 445
 446 is translated to
 447
 448         arr (\ ((xs)*ts) -> case e of
 449                 p1 -> (Left (Left (xs1)*ts))
 450                 p2 -> Left ((Right (xs2)*ts))
 451                 p3 -> Right ((xs3)*ts)) >>>
 452         (c1 ||| c2) ||| c3
 453
 454 The idea is to extract the commands from the case, build a balanced tree
 455 of choices, and replace the commands with expressions that build tagged
 456 tuples, obtaining a case expression that can be desugared normally.
 457 To build all this, we use triples describing segments of the list of
 458 case bodies, containing the following fields:
 459  * a list of expressions of the form (Left|Right)* ((xs)*ts), to be put
 460    into the case replacing the commands
 461  * a sum type that is the common type of these expressions, and also the
 462    input type of the arrow
 463  * a CoreExpr for an arrow built by combining the translated command
 464    bodies with |||.
 465
 466 \begin{code}
 467 dsCmd ids local_vars env_ids stack res_ty (HsCase exp (MatchGroup matches match_ty)) = do
 468     stack_ids <- mapM newSysLocalDs stack
 469
 470     -- Extract and desugar the leaf commands in the case, building tuple
 471     -- expressions that will (after tagging) replace these leaves
 472
 473     let
 474         leaves = concatMap leavesMatch matches
 475         make_branch (leaf, bound_vars) = do
 476             (core_leaf, _fvs, leaf_ids) <-
 477                   dsfixCmd ids (local_vars `unionVarSet` bound_vars) stack res_ty leaf
 478             return ([mkHsEnvStackExpr leaf_ids stack_ids],
 479                     envStackType leaf_ids stack,
 480                     core_leaf)
 481
 482     branches <- mapM make_branch leaves
 483     either_con <- dsLookupTyCon eitherTyConName
 484     left_con <- dsLookupDataCon leftDataConName
 485     right_con <- dsLookupDataCon rightDataConName
 486     let
 487         left_id  = HsVar (dataConWrapId left_con)
 488         right_id = HsVar (dataConWrapId right_con)
 489         left_expr  ty1 ty2 e = noLoc $ HsApp (noLoc $ HsWrap (mkWpTyApps [ty1, ty2]) left_id ) e
 490         right_expr ty1 ty2 e = noLoc $ HsApp (noLoc $ HsWrap (mkWpTyApps [ty1, ty2]) right_id) e
 491
 492         -- Prefix each tuple with a distinct series of Left's and Right's,
 493         -- in a balanced way, keeping track of the types.
 494
 495         merge_branches (builds1, in_ty1, core_exp1)
 496                        (builds2, in_ty2, core_exp2)
 497           = (map (left_expr in_ty1 in_ty2) builds1 ++
 498                 map (right_expr in_ty1 in_ty2) builds2,
 499              mkTyConApp either_con [in_ty1, in_ty2],
 500              do_choice ids in_ty1 in_ty2 res_ty core_exp1 core_exp2)
 501         (leaves', sum_ty, core_choices) = foldb merge_branches branches
 502
 503         -- Replace the commands in the case with these tagged tuples,
 504         -- yielding a HsExpr Id we can feed to dsExpr.
 505
 506         (_, matches') = mapAccumL (replaceLeavesMatch res_ty) leaves' matches
 507         in_ty = envStackType env_ids stack
 508
 509         pat_ty    = funArgTy match_ty
 510         match_ty' = mkFunTy pat_ty sum_ty
 511         -- Note that we replace the HsCase result type by sum_ty,
 512         -- which is the type of matches'
 513
 514     core_body <- dsExpr (HsCase exp (MatchGroup matches' match_ty'))
 515     core_matches <- matchEnvStack env_ids stack_ids core_body
 516     return (do_map_arrow ids in_ty sum_ty res_ty core_matches core_choices,
 517             exprFreeVars core_body `intersectVarSet` local_vars)
 518
 519 --      A | ys |- c :: [ts] t
 520 --      ----------------------------------
 521 --      A | xs |- let binds in c :: [ts] t
 522 --
 523 --              ---> arr (\ ((xs)*ts) -> let binds in ((ys)*ts)) >>> c
 524
 525 dsCmd ids local_vars env_ids stack res_ty (HsLet binds body) = do
 526     let
 527         defined_vars = mkVarSet (collectLocalBinders binds)
 528         local_vars' = local_vars `unionVarSet` defined_vars
 529
 530     (core_body, _free_vars, env_ids') <- dsfixCmd ids local_vars' stack res_ty body
 531     stack_ids <- mapM newSysLocalDs stack
 532     -- build a new environment, plus the stack, using the let bindings
 533     core_binds <- dsLocalBinds binds (buildEnvStack env_ids' stack_ids)
 534     -- match the old environment and stack against the input
 535     core_map <- matchEnvStack env_ids stack_ids core_binds
 536     return (do_map_arrow ids
 537                         (envStackType env_ids stack)
 538                         (envStackType env_ids' stack)
 539                         res_ty
 540                         core_map
 541                         core_body,
 542         exprFreeVars core_binds `intersectVarSet` local_vars)
 543
 544 dsCmd ids local_vars env_ids [] res_ty (HsDo _ctxt stmts body _)
 545   = dsCmdDo ids local_vars env_ids res_ty stmts body
 546
 547 --      A |- e :: forall e. a1 (e*ts1) t1 -> ... an (e*tsn) tn -> a (e*ts) t
 548 --      A | xs |- ci :: [tsi] ti
 549 --      -----------------------------------
 550 --      A | xs |- (|e c1 ... cn|) :: [ts] t     ---> e [t_xs] c1 ... cn
 551
 552 dsCmd _ids local_vars env_ids _stack _res_ty (HsArrForm op _ args) = do
 553     let env_ty = mkBigCoreVarTupTy env_ids
 554     core_op <- dsLExpr op
 555     (core_args, fv_sets) <- mapAndUnzipM (dsTrimCmdArg local_vars env_ids) args
 556     return (mkApps (App core_op (Type env_ty)) core_args,
 557             unionVarSets fv_sets)
 558
 559
 560 dsCmd ids local_vars env_ids stack res_ty (HsTick ix vars expr) = do
 561     (expr1,id_set) <- dsLCmd ids local_vars env_ids stack res_ty expr
 562     expr2 <- mkTickBox ix vars expr1
 563     return (expr2,id_set)
 564
 565 dsCmd _ _ _ _ _ c = pprPanic "dsCmd" (ppr c)
 566
 567 --      A | ys |- c :: [ts] t   (ys <= xs)
 568 --      ---------------------
 569 --      A | xs |- c :: [ts] t   ---> arr_ts (\ (xs) -> (ys)) >>> c
 570
 571 dsTrimCmdArg
 572         :: IdSet                -- set of local vars available to this command
 573         -> [Id]                 -- list of vars in the input to this command
 574         -> LHsCmdTop Id -- command argument to desugar
 575         -> DsM (CoreExpr,       -- desugared expression
 576                 IdSet)          -- set of local vars that occur free
 577 dsTrimCmdArg local_vars env_ids (L _ (HsCmdTop cmd stack cmd_ty ids)) = do
 578     meth_ids <- mkCmdEnv ids
 579     (core_cmd, free_vars, env_ids') <- dsfixCmd meth_ids local_vars stack cmd_ty cmd
 580     stack_ids <- mapM newSysLocalDs stack
 581     trim_code <- matchEnvStack env_ids stack_ids (buildEnvStack env_ids' stack_ids)
 582     let
 583         in_ty = envStackType env_ids stack
 584         in_ty' = envStackType env_ids' stack
 585         arg_code = if env_ids' == env_ids then core_cmd else
 586                 do_map_arrow meth_ids in_ty in_ty' cmd_ty trim_code core_cmd
 587     return (bindCmdEnv meth_ids arg_code, free_vars)
 588
 589 -- Given A | xs |- c :: [ts] t, builds c with xs fed back.
 590 -- Typically needs to be prefixed with arr (\p -> ((xs)*ts))
 591
 592 dsfixCmd
 593         :: DsCmdEnv             -- arrow combinators
 594         -> IdSet                -- set of local vars available to this command
 595         -> [Type]               -- type of the stack
 596         -> Type                 -- return type of the command
 597         -> LHsCmd Id            -- command to desugar
 598         -> DsM (CoreExpr,       -- desugared expression
 599                 IdSet,          -- set of local vars that occur free
 600                 [Id])           -- set as a list, fed back
 601 dsfixCmd ids local_vars stack cmd_ty cmd
 602   = fixDs (\ ~(_,_,env_ids') -> do
 603         (core_cmd, free_vars) <- dsLCmd ids local_vars env_ids' stack cmd_ty cmd
 604         return (core_cmd, free_vars, varSetElems free_vars))
 605
 606 \end{code}
 607
 608 Translation of command judgements of the form
 609
 610         A | xs |- do { ss } :: [] t
 611
 612 \begin{code}
 613
 614 dsCmdDo :: DsCmdEnv             -- arrow combinators
 615         -> IdSet                -- set of local vars available to this statement
 616         -> [Id]                 -- list of vars in the input to this statement
 617                                 -- This is typically fed back,
 618                                 -- so don't pull on it too early
 619         -> Type                 -- return type of the statement
 620         -> [LStmt Id]           -- statements to desugar
 621         -> LHsExpr Id           -- body
 622         -> DsM (CoreExpr,       -- desugared expression
 623                 IdSet)          -- set of local vars that occur free
 624
 625 --      A | xs |- c :: [] t
 626 --      --------------------------
 627 --      A | xs |- do { c } :: [] t
 628
 629 dsCmdDo ids local_vars env_ids res_ty [] body
 630   = dsLCmd ids local_vars env_ids [] res_ty body
 631
 632 dsCmdDo ids local_vars env_ids res_ty (stmt:stmts) body = do
 633     let
 634         bound_vars = mkVarSet (collectLStmtBinders stmt)
 635         local_vars' = local_vars `unionVarSet` bound_vars
 636     (core_stmts, _, env_ids') <- fixDs (\ ~(_,_,env_ids') -> do
 637         (core_stmts, fv_stmts) <- dsCmdDo ids local_vars' env_ids' res_ty stmts body
 638         return (core_stmts, fv_stmts, varSetElems fv_stmts))
 639     (core_stmt, fv_stmt) <- dsCmdLStmt ids local_vars env_ids env_ids' stmt
 640     return (do_compose ids
 641                 (mkBigCoreVarTupTy env_ids)
 642                 (mkBigCoreVarTupTy env_ids')
 643                 res_ty
 644                 core_stmt
 645                 core_stmts,
 646               fv_stmt)
 647
 648 \end{code}
 649 A statement maps one local environment to another, and is represented
 650 as an arrow from one tuple type to another.  A statement sequence is
 651 translated to a composition of such arrows.
 652 \begin{code}
 653 dsCmdLStmt :: DsCmdEnv -> IdSet -> [Id] -> [Id] -> LStmt Id
 654            -> DsM (CoreExpr, IdSet)
 655 dsCmdLStmt ids local_vars env_ids out_ids cmd
 656   = dsCmdStmt ids local_vars env_ids out_ids (unLoc cmd)
 657
 658 dsCmdStmt
 659         :: DsCmdEnv             -- arrow combinators
 660         -> IdSet                -- set of local vars available to this statement
 661         -> [Id]                 -- list of vars in the input to this statement
 662                                 -- This is typically fed back,
 663                                 -- so don't pull on it too early
 664         -> [Id]                 -- list of vars in the output of this statement
 665         -> Stmt Id      -- statement to desugar
 666         -> DsM (CoreExpr,       -- desugared expression
 667                 IdSet)          -- set of local vars that occur free
 668
 669 --      A | xs1 |- c :: [] t
 670 --      A | xs' |- do { ss } :: [] t'
 671 --      ------------------------------
 672 --      A | xs |- do { c; ss } :: [] t'
 673 --
 674 --              ---> arr (\ (xs) -> ((xs1),(xs'))) >>> first c >>>
 675 --                      arr snd >>> ss
 676
 677 dsCmdStmt ids local_vars env_ids out_ids (ExprStmt cmd _ c_ty) = do
 678     (core_cmd, fv_cmd, env_ids1) <- dsfixCmd ids local_vars [] c_ty cmd
 679     core_mux <- matchEnvStack env_ids []
 680         (mkCorePairExpr (mkBigCoreVarTup env_ids1) (mkBigCoreVarTup out_ids))
 681     let
 682         in_ty = mkBigCoreVarTupTy env_ids
 683         in_ty1 = mkBigCoreVarTupTy env_ids1
 684         out_ty = mkBigCoreVarTupTy out_ids
 685         before_c_ty = mkCorePairTy in_ty1 out_ty
 686         after_c_ty = mkCorePairTy c_ty out_ty
 687     snd_fn <- mkSndExpr c_ty out_ty
 688     return (do_map_arrow ids in_ty before_c_ty out_ty core_mux $
 689                 do_compose ids before_c_ty after_c_ty out_ty
 690                         (do_first ids in_ty1 c_ty out_ty core_cmd) $
 691                 do_arr ids after_c_ty out_ty snd_fn,
 692               extendVarSetList fv_cmd out_ids)
 693   where
 694
 695 --      A | xs1 |- c :: [] t
 696 --      A | xs' |- do { ss } :: [] t'           xs2 = xs' - defs(p)
 697 --      -----------------------------------
 698 --      A | xs |- do { p <- c; ss } :: [] t'
 699 --
 700 --              ---> arr (\ (xs) -> ((xs1),(xs2))) >>> first c >>>
 701 --                      arr (\ (p, (xs2)) -> (xs')) >>> ss
 702 --
 703 -- It would be simpler and more consistent to do this using second,
 704 -- but that's likely to be defined in terms of first.
 705
 706 dsCmdStmt ids local_vars env_ids out_ids (BindStmt pat cmd _ _) = do
 707     (core_cmd, fv_cmd, env_ids1) <- dsfixCmd ids local_vars [] (hsLPatType pat) cmd
 708     let
 709         pat_ty = hsLPatType pat
 710         pat_vars = mkVarSet (collectPatBinders pat)
 711         env_ids2 = varSetElems (mkVarSet out_ids `minusVarSet` pat_vars)
 712         env_ty2 = mkBigCoreVarTupTy env_ids2
 713
 714     -- multiplexing function
 715     --          \ (xs) -> ((xs1),(xs2))
 716
 717     core_mux <- matchEnvStack env_ids []
 718         (mkCorePairExpr (mkBigCoreVarTup env_ids1) (mkBigCoreVarTup env_ids2))
 719
 720     -- projection function
 721     --          \ (p, (xs2)) -> (zs)
 722
 723     env_id <- newSysLocalDs env_ty2
 724     uniqs <- newUniqueSupply
 725     let
 726         after_c_ty = mkCorePairTy pat_ty env_ty2
 727         out_ty = mkBigCoreVarTupTy out_ids
 728         body_expr = coreCaseTuple uniqs env_id env_ids2 (mkBigCoreVarTup out_ids)
 729
 730     fail_expr <- mkFailExpr (StmtCtxt DoExpr) out_ty
 731     pat_id    <- selectSimpleMatchVarL pat
 732     match_code <- matchSimply (Var pat_id) (StmtCtxt DoExpr) pat body_expr fail_expr
 733     pair_id   <- newSysLocalDs after_c_ty
 734     let
 735         proj_expr = Lam pair_id (coreCasePair pair_id pat_id env_id match_code)
 736
 737     -- put it all together
 738     let
 739         in_ty = mkBigCoreVarTupTy env_ids
 740         in_ty1 = mkBigCoreVarTupTy env_ids1
 741         in_ty2 = mkBigCoreVarTupTy env_ids2
 742         before_c_ty = mkCorePairTy in_ty1 in_ty2
 743     return (do_map_arrow ids in_ty before_c_ty out_ty core_mux $
 744                 do_compose ids before_c_ty after_c_ty out_ty
 745                         (do_first ids in_ty1 pat_ty in_ty2 core_cmd) $
 746                 do_arr ids after_c_ty out_ty proj_expr,
 747               fv_cmd `unionVarSet` (mkVarSet out_ids `minusVarSet` pat_vars))
 748
 749 --      A | xs' |- do { ss } :: [] t
 750 --      --------------------------------------
 751 --      A | xs |- do { let binds; ss } :: [] t
 752 --
 753 --              ---> arr (\ (xs) -> let binds in (xs')) >>> ss
 754
 755 dsCmdStmt ids local_vars env_ids out_ids (LetStmt binds) = do
 756     -- build a new environment using the let bindings
 757     core_binds <- dsLocalBinds binds (mkBigCoreVarTup out_ids)
 758     -- match the old environment against the input
 759     core_map <- matchEnvStack env_ids [] core_binds
 760     return (do_arr ids
 761                         (mkBigCoreVarTupTy env_ids)
 762                         (mkBigCoreVarTupTy out_ids)
 763                         core_map,
 764         exprFreeVars core_binds `intersectVarSet` local_vars)
 765
 766 --      A | ys |- do { ss; returnA -< ((xs1), (ys2)) } :: [] ...
 767 --      A | xs' |- do { ss' } :: [] t
 768 --      ------------------------------------
 769 --      A | xs |- do { rec ss; ss' } :: [] t
 770 --
 771 --                      xs1 = xs' /\ defs(ss)
 772 --                      xs2 = xs' - defs(ss)
 773 --                      ys1 = ys - defs(ss)
 774 --                      ys2 = ys /\ defs(ss)
 775 --
 776 --              ---> arr (\(xs) -> ((ys1),(xs2))) >>>
 777 --                      first (loop (arr (\((ys1),~(ys2)) -> (ys)) >>> ss)) >>>
 778 --                      arr (\((xs1),(xs2)) -> (xs')) >>> ss'
 779
 780 dsCmdStmt ids local_vars env_ids out_ids
 781           (RecStmt { recS_stmts = stmts, recS_later_ids = later_ids, recS_rec_ids = rec_ids
 782                    , recS_rec_rets = rhss }) = do
 783     let
 784         env2_id_set = mkVarSet out_ids `minusVarSet` mkVarSet later_ids
 785         env2_ids = varSetElems env2_id_set
 786         env2_ty = mkBigCoreVarTupTy env2_ids
 787
 788     -- post_loop_fn = \((later_ids),(env2_ids)) -> (out_ids)
 789
 790     uniqs <- newUniqueSupply
 791     env2_id <- newSysLocalDs env2_ty
 792     let
 793         later_ty = mkBigCoreVarTupTy later_ids
 794         post_pair_ty = mkCorePairTy later_ty env2_ty
 795         post_loop_body = coreCaseTuple uniqs env2_id env2_ids (mkBigCoreVarTup out_ids)
 796
 797     post_loop_fn <- matchEnvStack later_ids [env2_id] post_loop_body
 798
 799     --- loop (...)
 800
 801     (core_loop, env1_id_set, env1_ids)
 802                <- dsRecCmd ids local_vars stmts later_ids rec_ids rhss
 803
 804     -- pre_loop_fn = \(env_ids) -> ((env1_ids),(env2_ids))
 805
 806     let
 807         env1_ty = mkBigCoreVarTupTy env1_ids
 808         pre_pair_ty = mkCorePairTy env1_ty env2_ty
 809         pre_loop_body = mkCorePairExpr (mkBigCoreVarTup env1_ids)
 810                                         (mkBigCoreVarTup env2_ids)
 811
 812     pre_loop_fn <- matchEnvStack env_ids [] pre_loop_body
 813
 814     -- arr pre_loop_fn >>> first (loop (...)) >>> arr post_loop_fn
 815
 816     let
 817         env_ty = mkBigCoreVarTupTy env_ids
 818         out_ty = mkBigCoreVarTupTy out_ids
 819         core_body = do_map_arrow ids env_ty pre_pair_ty out_ty
 820                 pre_loop_fn
 821                 (do_compose ids pre_pair_ty post_pair_ty out_ty
 822                         (do_first ids env1_ty later_ty env2_ty
 823                                 core_loop)
 824                         (do_arr ids post_pair_ty out_ty
 825                                 post_loop_fn))
 826
 827     return (core_body, env1_id_set `unionVarSet` env2_id_set)
 828
 829 dsCmdStmt _ _ _ _ s = pprPanic "dsCmdStmt" (ppr s)
 830
 831 --      loop (arr (\ ((env1_ids), ~(rec_ids)) -> (env_ids)) >>>
 832 --            ss >>>
 833 --            arr (\ (out_ids) -> ((later_ids),(rhss))) >>>
 834
 835 dsRecCmd :: DsCmdEnv -> VarSet -> [LStmt Id] -> [Var] -> [Var] -> [HsExpr Id]
 836          -> DsM (CoreExpr, VarSet, [Var])
 837 dsRecCmd ids local_vars stmts later_ids rec_ids rhss = do
 838     let
 839         rec_id_set = mkVarSet rec_ids
 840         out_ids = varSetElems (mkVarSet later_ids `unionVarSet` rec_id_set)
 841         out_ty = mkBigCoreVarTupTy out_ids
 842         local_vars' = local_vars `unionVarSet` rec_id_set
 843
 844     -- mk_pair_fn = \ (out_ids) -> ((later_ids),(rhss))
 845
 846     core_rhss <- mapM dsExpr rhss
 847     let
 848         later_tuple = mkBigCoreVarTup later_ids
 849         later_ty = mkBigCoreVarTupTy later_ids
 850         rec_tuple = mkBigCoreTup core_rhss
 851         rec_ty = mkBigCoreVarTupTy rec_ids
 852         out_pair = mkCorePairExpr later_tuple rec_tuple
 853         out_pair_ty = mkCorePairTy later_ty rec_ty
 854
 855     mk_pair_fn <- matchEnvStack out_ids [] out_pair
 856
 857     -- ss
 858
 859     (core_stmts, fv_stmts, env_ids) <- dsfixCmdStmts ids local_vars' out_ids stmts
 860
 861     -- squash_pair_fn = \ ((env1_ids), ~(rec_ids)) -> (env_ids)
 862
 863     rec_id <- newSysLocalDs rec_ty
 864     let
 865         env1_id_set = fv_stmts `minusVarSet` rec_id_set
 866         env1_ids = varSetElems env1_id_set
 867         env1_ty = mkBigCoreVarTupTy env1_ids
 868         in_pair_ty = mkCorePairTy env1_ty rec_ty
 869         core_body = mkBigCoreTup (map selectVar env_ids)
 870           where
 871             selectVar v
 872                 | v `elemVarSet` rec_id_set
 873                   = mkTupleSelector rec_ids v rec_id (Var rec_id)
 874                 | otherwise = Var v
 875
 876     squash_pair_fn <- matchEnvStack env1_ids [rec_id] core_body
 877
 878     -- loop (arr squash_pair_fn >>> ss >>> arr mk_pair_fn)
 879
 880     let
 881         env_ty = mkBigCoreVarTupTy env_ids
 882         core_loop = do_loop ids env1_ty later_ty rec_ty
 883                 (do_map_arrow ids in_pair_ty env_ty out_pair_ty
 884                         squash_pair_fn
 885                         (do_compose ids env_ty out_ty out_pair_ty
 886                                 core_stmts
 887                                 (do_arr ids out_ty out_pair_ty mk_pair_fn)))
 888
 889     return (core_loop, env1_id_set, env1_ids)
 890
 891 \end{code}
 892 A sequence of statements (as in a rec) is desugared to an arrow between
 893 two environments
 894 \begin{code}
 895
 896 dsfixCmdStmts
 897         :: DsCmdEnv             -- arrow combinators
 898         -> IdSet                -- set of local vars available to this statement
 899         -> [Id]                 -- output vars of these statements
 900         -> [LStmt Id]   -- statements to desugar
 901         -> DsM (CoreExpr,       -- desugared expression
 902                 IdSet,          -- set of local vars that occur free
 903                 [Id])           -- input vars
 904
 905 dsfixCmdStmts ids local_vars out_ids stmts
 906   = fixDs (\ ~(_,_,env_ids) -> do
 907         (core_stmts, fv_stmts) <- dsCmdStmts ids local_vars env_ids out_ids stmts
 908         return (core_stmts, fv_stmts, varSetElems fv_stmts))
 909
 910 dsCmdStmts
 911         :: DsCmdEnv             -- arrow combinators
 912         -> IdSet                -- set of local vars available to this statement
 913         -> [Id]                 -- list of vars in the input to these statements
 914         -> [Id]                 -- output vars of these statements
 915         -> [LStmt Id]   -- statements to desugar
 916         -> DsM (CoreExpr,       -- desugared expression
 917                 IdSet)          -- set of local vars that occur free
 918
 919 dsCmdStmts ids local_vars env_ids out_ids [stmt]
 920   = dsCmdLStmt ids local_vars env_ids out_ids stmt
 921
 922 dsCmdStmts ids local_vars env_ids out_ids (stmt:stmts) = do
 923     let
 924         bound_vars = mkVarSet (collectLStmtBinders stmt)
 925         local_vars' = local_vars `unionVarSet` bound_vars
 926     (core_stmts, _fv_stmts, env_ids') <- dsfixCmdStmts ids local_vars' out_ids stmts
 927     (core_stmt, fv_stmt) <- dsCmdLStmt ids local_vars env_ids env_ids' stmt
 928     return (do_compose ids
 929                 (mkBigCoreVarTupTy env_ids)
 930                 (mkBigCoreVarTupTy env_ids')
 931                 (mkBigCoreVarTupTy out_ids)
 932                 core_stmt
 933                 core_stmts,
 934               fv_stmt)
 935
 936 dsCmdStmts _ _ _ _ [] = panic "dsCmdStmts []"
 937
 938 \end{code}
 939
 940 Match a list of expressions against a list of patterns, left-to-right.
 941
 942 \begin{code}
 943 matchSimplys :: [CoreExpr]              -- Scrutinees
 944              -> HsMatchContext Name     -- Match kind
 945              -> [LPat Id]               -- Patterns they should match
 946              -> CoreExpr                -- Return this if they all match
 947              -> CoreExpr                -- Return this if they don't
 948              -> DsM CoreExpr
 949 matchSimplys [] _ctxt [] result_expr _fail_expr = return result_expr
 950 matchSimplys (exp:exps) ctxt (pat:pats) result_expr fail_expr = do
 951     match_code <- matchSimplys exps ctxt pats result_expr fail_expr
 952     matchSimply exp ctxt pat match_code fail_expr
 953 matchSimplys _ _ _ _ _ = panic "matchSimplys"
 954 \end{code}
 955
 956 List of leaf expressions, with set of variables bound in each
 957
 958 \begin{code}
 959 leavesMatch :: LMatch Id -> [(LHsExpr Id, IdSet)]
 960 leavesMatch (L _ (Match pats _ (GRHSs grhss binds)))
 961   = let
 962         defined_vars = mkVarSet (collectPatsBinders pats)
 963                         `unionVarSet`
 964                        mkVarSet (collectLocalBinders binds)
 965     in
 966     [(expr,
 967       mkVarSet (collectLStmtsBinders stmts)
 968         `unionVarSet` defined_vars)
 969     | L _ (GRHS stmts expr) <- grhss]
 970 \end{code}
 971
 972 Replace the leaf commands in a match
 973
 974 \begin{code}
 975 replaceLeavesMatch
 976         :: Type                 -- new result type
 977         -> [LHsExpr Id] -- replacement leaf expressions of that type
 978         -> LMatch Id    -- the matches of a case command
 979         -> ([LHsExpr Id],-- remaining leaf expressions
 980             LMatch Id)  -- updated match
 981 replaceLeavesMatch _res_ty leaves (L loc (Match pat mt (GRHSs grhss binds)))
 982   = let
 983         (leaves', grhss') = mapAccumL replaceLeavesGRHS leaves grhss
 984     in
 985     (leaves', L loc (Match pat mt (GRHSs grhss' binds)))
 986
 987 replaceLeavesGRHS
 988         :: [LHsExpr Id] -- replacement leaf expressions of that type
 989         -> LGRHS Id     -- rhss of a case command
 990         -> ([LHsExpr Id],-- remaining leaf expressions
 991             LGRHS Id)   -- updated GRHS
 992 replaceLeavesGRHS (leaf:leaves) (L loc (GRHS stmts _))
 993   = (leaves, L loc (GRHS stmts leaf))
 994 replaceLeavesGRHS [] _ = panic "replaceLeavesGRHS []"
 995 \end{code}
 996
 997 Balanced fold of a non-empty list.
 998
 999 \begin{code}
1000 foldb :: (a -> a -> a) -> [a] -> a
1001 foldb _ [] = error "foldb of empty list"
1002 foldb _ [x] = x
1003 foldb f xs = foldb f (fold_pairs xs)
1004   where
1005     fold_pairs [] = []
1006     fold_pairs [x] = [x]
1007     fold_pairs (x1:x2:xs) = f x1 x2:fold_pairs xs
1008 \end{code}
1009
1010 Note [Dictionary binders in ConPatOut] See also same Note in HsUtils
1011 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1012 The following functions to collect value variables from patterns are
1013 copied from HsUtils, with one change: we also collect the dictionary
1014 bindings (pat_binds) from ConPatOut.  We need them for cases like
1015
1016 h :: Arrow a => Int -> a (Int,Int) Int
1017 h x = proc (y,z) -> case compare x y of
1018                 GT -> returnA -< z+x
1019
1020 The type checker turns the case into
1021
1022                 case compare x y of
1023                   GT { p77 = plusInt } -> returnA -< p77 z x
1024
1025 Here p77 is a local binding for the (+) operation.
1026
1027 See comments in HsUtils for why the other version does not include
1028 these bindings.
1029
1030 \begin{code}
1031 collectPatBinders :: LPat Id -> [Id]
1032 collectPatBinders pat = collectl pat []
1033
1034 collectPatsBinders :: [LPat Id] -> [Id]
1035 collectPatsBinders pats = foldr collectl [] pats
1036
1037 ---------------------
1038 collectl :: LPat Id -> [Id] -> [Id]
1039 -- See Note [Dictionary binders in ConPatOut]
1040 collectl (L _ pat) bndrs
1041   = go pat
1042   where
1043     go (VarPat var)               = var : bndrs
1044     go (WildPat _)                = bndrs
1045     go (LazyPat pat)              = collectl pat bndrs
1046     go (BangPat pat)              = collectl pat bndrs
1047     go (AsPat (L _ a) pat)        = a : collectl pat bndrs
1048     go (ParPat  pat)              = collectl pat bndrs
1049
1050     go (ListPat pats _)           = foldr collectl bndrs pats
1051     go (PArrPat pats _)           = foldr collectl bndrs pats
1052     go (TuplePat pats _ _)        = foldr collectl bndrs pats
1053
1054     go (ConPatIn _ ps)            = foldr collectl bndrs (hsConPatArgs ps)
1055     go (ConPatOut {pat_args=ps, pat_binds=ds}) =
1056                                     collectEvBinders ds
1057                                     ++ foldr collectl bndrs (hsConPatArgs ps)
1058     go (LitPat _)                 = bndrs
1059     go (NPat _ _ _)               = bndrs
1060     go (NPlusKPat (L _ n) _ _ _)  = n : bndrs
1061
1062     go (SigPatIn pat _)           = collectl pat bndrs
1063     go (SigPatOut pat _)          = collectl pat bndrs
1064     go (CoPat _ pat _)            = collectl (noLoc pat) bndrs
1065     go (ViewPat _ pat _)          = collectl pat bndrs
1066     go p@(QuasiQuotePat {})       = pprPanic "collectl/go" (ppr p)
1067
1068 collectEvBinders :: TcEvBinds -> [Id]
1069 collectEvBinders (EvBinds bs)   = foldrBag add_ev_bndr [] bs
1070 collectEvBinders (TcEvBinds {}) = panic "ToDo: collectEvBinders"
1071
1072 add_ev_bndr :: EvBind -> [Id] -> [Id]
1073 add_ev_bndr (EvBind b _) bs | isId b    = b:bs
1074                             | otherwise = bs
1075   -- A worry: what about coercion variable binders??
1076 \end{code}