compiler/deSugar/DsArrows.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Desugaring arrow commands
   7
   8 \begin{code}
   9 module DsArrows ( dsProcExpr ) where
  10
  11 #include "HsVersions.h"
  12
  13 import Match
  14 import DsUtils
  15 import DsMonad
  16
  17 import HsSyn    hiding (collectPatBinders, collectPatsBinders )
  18 import TcHsSyn
  19
  20 -- NB: The desugarer, which straddles the source and Core worlds, sometimes
  21 --     needs to see source types (newtypes etc), and sometimes not
  22 --     So WATCH OUT; check each use of split*Ty functions.
  23 -- Sigh.  This is a pain.
  24
  25 import {-# SOURCE #-} DsExpr ( dsExpr, dsLExpr, dsLocalBinds )
  26
  27 import TcType
  28 import Type
  29 import CoreSyn
  30 import CoreFVs
  31 import CoreUtils
  32 import MkCore
  33
  34 import Name
  35 import Var
  36 import Id
  37 import PrelInfo
  38 import DataCon
  39 import TysWiredIn
  40 import BasicTypes
  41 import PrelNames
  42 import Outputable
  43
  44 import VarSet
  45 import SrcLoc
  46
  47 import Data.List
  48 \end{code}
  49
  50 \begin{code}
  51 data DsCmdEnv = DsCmdEnv {
  52         meth_binds :: [CoreBind],
  53         arr_id, compose_id, first_id, app_id, choice_id, loop_id :: CoreExpr
  54     }
  55
  56 mkCmdEnv :: SyntaxTable Id -> DsM DsCmdEnv
  57 mkCmdEnv ids = do
  58     (meth_binds, ds_meths) <- dsSyntaxTable ids
  59     return $ DsCmdEnv {
  60                meth_binds = meth_binds,
  61                arr_id     = Var (lookupEvidence ds_meths arrAName),
  62                compose_id = Var (lookupEvidence ds_meths composeAName),
  63                first_id   = Var (lookupEvidence ds_meths firstAName),
  64                app_id     = Var (lookupEvidence ds_meths appAName),
  65                choice_id  = Var (lookupEvidence ds_meths choiceAName),
  66                loop_id    = Var (lookupEvidence ds_meths loopAName)
  67              }
  68
  69 bindCmdEnv :: DsCmdEnv -> CoreExpr -> CoreExpr
  70 bindCmdEnv ids body = foldr Let body (meth_binds ids)
  71
  72 -- arr :: forall b c. (b -> c) -> a b c
  73 do_arr :: DsCmdEnv -> Type -> Type -> CoreExpr -> CoreExpr
  74 do_arr ids b_ty c_ty f = mkApps (arr_id ids) [Type b_ty, Type c_ty, f]
  75
  76 -- (>>>) :: forall b c d. a b c -> a c d -> a b d
  77 do_compose :: DsCmdEnv -> Type -> Type -> Type ->
  78                 CoreExpr -> CoreExpr -> CoreExpr
  79 do_compose ids b_ty c_ty d_ty f g
  80   = mkApps (compose_id ids) [Type b_ty, Type c_ty, Type d_ty, f, g]
  81
  82 -- first :: forall b c d. a b c -> a (b,d) (c,d)
  83 do_first :: DsCmdEnv -> Type -> Type -> Type -> CoreExpr -> CoreExpr
  84 do_first ids b_ty c_ty d_ty f
  85   = mkApps (first_id ids) [Type b_ty, Type c_ty, Type d_ty, f]
  86
  87 -- app :: forall b c. a (a b c, b) c
  88 do_app :: DsCmdEnv -> Type -> Type -> CoreExpr
  89 do_app ids b_ty c_ty = mkApps (app_id ids) [Type b_ty, Type c_ty]
  90
  91 -- (|||) :: forall b d c. a b d -> a c d -> a (Either b c) d
  92 -- note the swapping of d and c
  93 do_choice :: DsCmdEnv -> Type -> Type -> Type ->
  94                 CoreExpr -> CoreExpr -> CoreExpr
  95 do_choice ids b_ty c_ty d_ty f g
  96   = mkApps (choice_id ids) [Type b_ty, Type d_ty, Type c_ty, f, g]
  97
  98 -- loop :: forall b d c. a (b,d) (c,d) -> a b c
  99 -- note the swapping of d and c
 100 do_loop :: DsCmdEnv -> Type -> Type -> Type -> CoreExpr -> CoreExpr
 101 do_loop ids b_ty c_ty d_ty f
 102   = mkApps (loop_id ids) [Type b_ty, Type d_ty, Type c_ty, f]
 103
 104 -- map_arrow (f :: b -> c) (g :: a c d) = arr f >>> g :: a b d
 105 do_map_arrow :: DsCmdEnv -> Type -> Type -> Type ->
 106                 CoreExpr -> CoreExpr -> CoreExpr
 107 do_map_arrow ids b_ty c_ty d_ty f c
 108    = do_compose ids b_ty c_ty d_ty (do_arr ids b_ty c_ty f) c
 109
 110 mkFailExpr :: HsMatchContext Id -> Type -> DsM CoreExpr
 111 mkFailExpr ctxt ty
 112   = mkErrorAppDs pAT_ERROR_ID ty (matchContextErrString ctxt)
 113
 114 -- construct CoreExpr for \ (a :: a_ty, b :: b_ty) -> b
 115 mkSndExpr :: Type -> Type -> DsM CoreExpr
 116 mkSndExpr a_ty b_ty = do
 117     a_var <- newSysLocalDs a_ty
 118     b_var <- newSysLocalDs b_ty
 119     pair_var <- newSysLocalDs (mkCorePairTy a_ty b_ty)
 120     return (Lam pair_var
 121                (coreCasePair pair_var a_var b_var (Var b_var)))
 122 \end{code}
 123
 124 Build case analysis of a tuple.  This cannot be done in the DsM monad,
 125 because the list of variables is typically not yet defined.
 126
 127 \begin{code}
 128 -- coreCaseTuple [u1..] v [x1..xn] body
 129 --      = case v of v { (x1, .., xn) -> body }
 130 -- But the matching may be nested if the tuple is very big
 131
 132 coreCaseTuple :: UniqSupply -> Id -> [Id] -> CoreExpr -> CoreExpr
 133 coreCaseTuple uniqs scrut_var vars body
 134   = mkTupleCase uniqs vars body scrut_var (Var scrut_var)
 135
 136 coreCasePair :: Id -> Id -> Id -> CoreExpr -> CoreExpr
 137 coreCasePair scrut_var var1 var2 body
 138   = Case (Var scrut_var) scrut_var (exprType body)
 139          [(DataAlt (tupleCon Boxed 2), [var1, var2], body)]
 140 \end{code}
 141
 142 \begin{code}
 143 mkCorePairTy :: Type -> Type -> Type
 144 mkCorePairTy t1 t2 = mkBoxedTupleTy [t1, t2]
 145
 146 mkCorePairExpr :: CoreExpr -> CoreExpr -> CoreExpr
 147 mkCorePairExpr e1 e2 = mkCoreTup [e1, e2]
 148 \end{code}
 149
 150 The input is divided into a local environment, which is a flat tuple
 151 (unless it's too big), and a stack, each element of which is paired
 152 with the environment in turn.  In general, the input has the form
 153
 154         (...((x1,...,xn),s1),...sk)
 155
 156 where xi are the environment values, and si the ones on the stack,
 157 with s1 being the "top", the first one to be matched with a lambda.
 158
 159 \begin{code}
 160 envStackType :: [Id] -> [Type] -> Type
 161 envStackType ids stack_tys = foldl mkCorePairTy (mkBigCoreVarTupTy ids) stack_tys
 162
 163 ----------------------------------------------
 164 --              buildEnvStack
 165 --
 166 --      (...((x1,...,xn),s1),...sk)
 167
 168 buildEnvStack :: [Id] -> [Id] -> CoreExpr
 169 buildEnvStack env_ids stack_ids
 170   = foldl mkCorePairExpr (mkBigCoreVarTup env_ids) (map Var stack_ids)
 171
 172 ----------------------------------------------
 173 --              matchEnvStack
 174 --
 175 --      \ (...((x1,...,xn),s1),...sk) -> e
 176 --      =>
 177 --      \ zk ->
 178 --      case zk of (zk-1,sk) ->
 179 --      ...
 180 --      case z1 of (z0,s1) ->
 181 --      case z0 of (x1,...,xn) ->
 182 --      e
 183
 184 matchEnvStack   :: [Id]         -- x1..xn
 185                 -> [Id]         -- s1..sk
 186                 -> CoreExpr     -- e
 187                 -> DsM CoreExpr
 188 matchEnvStack env_ids stack_ids body = do
 189     uniqs <- newUniqueSupply
 190     tup_var <- newSysLocalDs (mkBigCoreVarTupTy env_ids)
 191     matchVarStack tup_var stack_ids
 192                (coreCaseTuple uniqs tup_var env_ids body)
 193
 194
 195 ----------------------------------------------
 196 --              matchVarStack
 197 --
 198 --      \ (...(z0,s1),...sk) -> e
 199 --      =>
 200 --      \ zk ->
 201 --      case zk of (zk-1,sk) ->
 202 --      ...
 203 --      case z1 of (z0,s1) ->
 204 --      e
 205
 206 matchVarStack :: Id             -- z0
 207               -> [Id]           -- s1..sk
 208               -> CoreExpr       -- e
 209               -> DsM CoreExpr
 210 matchVarStack env_id [] body
 211   = return (Lam env_id body)
 212 matchVarStack env_id (stack_id:stack_ids) body = do
 213     pair_id <- newSysLocalDs (mkCorePairTy (idType env_id) (idType stack_id))
 214     matchVarStack pair_id stack_ids
 215                (coreCasePair pair_id env_id stack_id body)
 216 \end{code}
 217
 218 \begin{code}
 219 mkHsEnvStackExpr :: [Id] -> [Id] -> LHsExpr Id
 220 mkHsEnvStackExpr env_ids stack_ids
 221   = foldl (\a b -> mkLHsTupleExpr [a,b])
 222           (mkLHsVarTuple env_ids)
 223           (map nlHsVar stack_ids)
 224 \end{code}
 225
 226 Translation of arrow abstraction
 227
 228 \begin{code}
 229
 230 --      A | xs |- c :: [] t'        ---> c'
 231 --      --------------------------
 232 --      A |- proc p -> c :: a t t'  ---> arr (\ p -> (xs)) >>> c'
 233 --
 234 --              where (xs) is the tuple of variables bound by p
 235
 236 dsProcExpr
 237         :: LPat Id
 238         -> LHsCmdTop Id
 239         -> DsM CoreExpr
 240 dsProcExpr pat (L _ (HsCmdTop cmd [] cmd_ty ids)) = do
 241     meth_ids <- mkCmdEnv ids
 242     let locals = mkVarSet (collectPatBinders pat)
 243     (core_cmd, _free_vars, env_ids) <- dsfixCmd meth_ids locals [] cmd_ty cmd
 244     let env_ty = mkBigCoreVarTupTy env_ids
 245     fail_expr <- mkFailExpr ProcExpr env_ty
 246     var <- selectSimpleMatchVarL pat
 247     match_code <- matchSimply (Var var) ProcExpr pat (mkBigCoreVarTup env_ids) fail_expr
 248     let pat_ty = hsLPatType pat
 249         proc_code = do_map_arrow meth_ids pat_ty env_ty cmd_ty
 250                     (Lam var match_code)
 251                     core_cmd
 252     return (bindCmdEnv meth_ids proc_code)
 253 dsProcExpr _ c = pprPanic "dsProcExpr" (ppr c)
 254 \end{code}
 255
 256 Translation of command judgements of the form
 257
 258         A | xs |- c :: [ts] t
 259
 260 \begin{code}
 261 dsLCmd :: DsCmdEnv -> IdSet -> [Id] -> [Type] -> Type -> LHsCmd Id
 262        -> DsM (CoreExpr, IdSet)
 263 dsLCmd ids local_vars env_ids stack res_ty cmd
 264   = dsCmd ids local_vars env_ids stack res_ty (unLoc cmd)
 265
 266 dsCmd   :: DsCmdEnv             -- arrow combinators
 267         -> IdSet                -- set of local vars available to this command
 268         -> [Id]                 -- list of vars in the input to this command
 269                                 -- This is typically fed back,
 270                                 -- so don't pull on it too early
 271         -> [Type]               -- type of the stack
 272         -> Type                 -- return type of the command
 273         -> HsCmd Id             -- command to desugar
 274         -> DsM (CoreExpr,       -- desugared expression
 275                 IdSet)          -- set of local vars that occur free
 276
 277 --      A |- f :: a (t*ts) t'
 278 --      A, xs |- arg :: t
 279 --      -----------------------------
 280 --      A | xs |- f -< arg :: [ts] t'
 281 --
 282 --              ---> arr (\ ((xs)*ts) -> (arg*ts)) >>> f
 283
 284 dsCmd ids local_vars env_ids stack res_ty
 285         (HsArrApp arrow arg arrow_ty HsFirstOrderApp _)= do
 286     let
 287         (a_arg_ty, _res_ty') = tcSplitAppTy arrow_ty
 288         (_a_ty, arg_ty) = tcSplitAppTy a_arg_ty
 289     core_arrow <- dsLExpr arrow
 290     core_arg   <- dsLExpr arg
 291     stack_ids  <- mapM newSysLocalDs stack
 292     core_make_arg <- matchEnvStack env_ids stack_ids
 293                       (foldl mkCorePairExpr core_arg (map Var stack_ids))
 294     return (do_map_arrow ids
 295               (envStackType env_ids stack)
 296               arg_ty
 297               res_ty
 298               core_make_arg
 299               core_arrow,
 300                exprFreeVars core_arg `intersectVarSet` local_vars)
 301
 302 --      A, xs |- f :: a (t*ts) t'
 303 --      A, xs |- arg :: t
 304 --      ------------------------------
 305 --      A | xs |- f -<< arg :: [ts] t'
 306 --
 307 --              ---> arr (\ ((xs)*ts) -> (f,(arg*ts))) >>> app
 308
 309 dsCmd ids local_vars env_ids stack res_ty
 310         (HsArrApp arrow arg arrow_ty HsHigherOrderApp _) = do
 311     let
 312         (a_arg_ty, _res_ty') = tcSplitAppTy arrow_ty
 313         (_a_ty, arg_ty) = tcSplitAppTy a_arg_ty
 314
 315     core_arrow <- dsLExpr arrow
 316     core_arg   <- dsLExpr arg
 317     stack_ids  <- mapM newSysLocalDs stack
 318     core_make_pair <- matchEnvStack env_ids stack_ids
 319           (mkCorePairExpr core_arrow
 320              (foldl mkCorePairExpr core_arg (map Var stack_ids)))
 321
 322     return (do_map_arrow ids
 323               (envStackType env_ids stack)
 324               (mkCorePairTy arrow_ty arg_ty)
 325               res_ty
 326               core_make_pair
 327               (do_app ids arg_ty res_ty),
 328             (exprFreeVars core_arrow `unionVarSet` exprFreeVars core_arg)
 329               `intersectVarSet` local_vars)
 330
 331 --      A | ys |- c :: [t:ts] t'
 332 --      A, xs  |- e :: t
 333 --      ------------------------
 334 --      A | xs |- c e :: [ts] t'
 335 --
 336 --              ---> arr (\ ((xs)*ts) -> let z = e in (((ys),z)*ts)) >>> c
 337
 338 dsCmd ids local_vars env_ids stack res_ty (HsApp cmd arg) = do
 339     core_arg <- dsLExpr arg
 340     let
 341         arg_ty = exprType core_arg
 342         stack' = arg_ty:stack
 343     (core_cmd, free_vars, env_ids')
 344              <- dsfixCmd ids local_vars stack' res_ty cmd
 345     stack_ids <- mapM newSysLocalDs stack
 346     arg_id <- newSysLocalDs arg_ty
 347     -- push the argument expression onto the stack
 348     let
 349         core_body = bindNonRec arg_id core_arg
 350                         (buildEnvStack env_ids' (arg_id:stack_ids))
 351     -- match the environment and stack against the input
 352     core_map <- matchEnvStack env_ids stack_ids core_body
 353     return (do_map_arrow ids
 354                       (envStackType env_ids stack)
 355                       (envStackType env_ids' stack')
 356                       res_ty
 357                       core_map
 358                       core_cmd,
 359       (exprFreeVars core_arg `intersectVarSet` local_vars)
 360               `unionVarSet` free_vars)
 361
 362 --      A | ys |- c :: [ts] t'
 363 --      -----------------------------------------------
 364 --      A | xs |- \ p1 ... pk -> c :: [t1:...:tk:ts] t'
 365 --
 366 --              ---> arr (\ ((((xs), p1), ... pk)*ts) -> ((ys)*ts)) >>> c
 367
 368 dsCmd ids local_vars env_ids stack res_ty
 369     (HsLam (MatchGroup [L _ (Match pats _ (GRHSs [L _ (GRHS [] body)] _ ))] _)) = do
 370     let
 371         pat_vars = mkVarSet (collectPatsBinders pats)
 372         local_vars' = local_vars `unionVarSet` pat_vars
 373         stack' = drop (length pats) stack
 374     (core_body, free_vars, env_ids') <- dsfixCmd ids local_vars' stack' res_ty body
 375     stack_ids <- mapM newSysLocalDs stack
 376
 377     -- the expression is built from the inside out, so the actions
 378     -- are presented in reverse order
 379
 380     let
 381         (actual_ids, stack_ids') = splitAt (length pats) stack_ids
 382         -- build a new environment, plus what's left of the stack
 383         core_expr = buildEnvStack env_ids' stack_ids'
 384         in_ty = envStackType env_ids stack
 385         in_ty' = envStackType env_ids' stack'
 386
 387     fail_expr <- mkFailExpr LambdaExpr in_ty'
 388     -- match the patterns against the top of the old stack
 389     match_code <- matchSimplys (map Var actual_ids) LambdaExpr pats core_expr fail_expr
 390     -- match the old environment and stack against the input
 391     select_code <- matchEnvStack env_ids stack_ids match_code
 392     return (do_map_arrow ids in_ty in_ty' res_ty select_code core_body,
 393             free_vars `minusVarSet` pat_vars)
 394
 395 dsCmd ids local_vars env_ids stack res_ty (HsPar cmd)
 396   = dsLCmd ids local_vars env_ids stack res_ty cmd
 397
 398 --      A, xs |- e :: Bool
 399 --      A | xs1 |- c1 :: [ts] t
 400 --      A | xs2 |- c2 :: [ts] t
 401 --      ----------------------------------------
 402 --      A | xs |- if e then c1 else c2 :: [ts] t
 403 --
 404 --              ---> arr (\ ((xs)*ts) ->
 405 --                      if e then Left ((xs1)*ts) else Right ((xs2)*ts)) >>>
 406 --                   c1 ||| c2
 407
 408 dsCmd ids local_vars env_ids stack res_ty (HsIf cond then_cmd else_cmd) = do
 409     core_cond <- dsLExpr cond
 410     (core_then, fvs_then, then_ids) <- dsfixCmd ids local_vars stack res_ty then_cmd
 411     (core_else, fvs_else, else_ids) <- dsfixCmd ids local_vars stack res_ty else_cmd
 412     stack_ids  <- mapM newSysLocalDs stack
 413     either_con <- dsLookupTyCon eitherTyConName
 414     left_con   <- dsLookupDataCon leftDataConName
 415     right_con  <- dsLookupDataCon rightDataConName
 416     let
 417         left_expr ty1 ty2 e = mkConApp left_con [Type ty1, Type ty2, e]
 418         right_expr ty1 ty2 e = mkConApp right_con [Type ty1, Type ty2, e]
 419
 420         in_ty = envStackType env_ids stack
 421         then_ty = envStackType then_ids stack
 422         else_ty = envStackType else_ids stack
 423         sum_ty = mkTyConApp either_con [then_ty, else_ty]
 424         fvs_cond = exprFreeVars core_cond `intersectVarSet` local_vars
 425
 426     core_if <- matchEnvStack env_ids stack_ids
 427                 (mkIfThenElse core_cond
 428                     (left_expr  then_ty else_ty (buildEnvStack then_ids stack_ids))
 429                     (right_expr then_ty else_ty (buildEnvStack else_ids stack_ids)))
 430     return (do_map_arrow ids in_ty sum_ty res_ty
 431                 core_if
 432                 (do_choice ids then_ty else_ty res_ty core_then core_else),
 433         fvs_cond `unionVarSet` fvs_then `unionVarSet` fvs_else)
 434 \end{code}
 435
 436 Case commands are treated in much the same way as if commands
 437 (see above) except that there are more alternatives.  For example
 438
 439         case e of { p1 -> c1; p2 -> c2; p3 -> c3 }
 440
 441 is translated to
 442
 443         arr (\ ((xs)*ts) -> case e of
 444                 p1 -> (Left (Left (xs1)*ts))
 445                 p2 -> Left ((Right (xs2)*ts))
 446                 p3 -> Right ((xs3)*ts)) >>>
 447         (c1 ||| c2) ||| c3
 448
 449 The idea is to extract the commands from the case, build a balanced tree
 450 of choices, and replace the commands with expressions that build tagged
 451 tuples, obtaining a case expression that can be desugared normally.
 452 To build all this, we use triples describing segments of the list of
 453 case bodies, containing the following fields:
 454  * a list of expressions of the form (Left|Right)* ((xs)*ts), to be put
 455    into the case replacing the commands
 456  * a sum type that is the common type of these expressions, and also the
 457    input type of the arrow
 458  * a CoreExpr for an arrow built by combining the translated command
 459    bodies with |||.
 460
 461 \begin{code}
 462 dsCmd ids local_vars env_ids stack res_ty (HsCase exp (MatchGroup matches match_ty)) = do
 463     stack_ids <- mapM newSysLocalDs stack
 464
 465     -- Extract and desugar the leaf commands in the case, building tuple
 466     -- expressions that will (after tagging) replace these leaves
 467
 468     let
 469         leaves = concatMap leavesMatch matches
 470         make_branch (leaf, bound_vars) = do
 471             (core_leaf, _fvs, leaf_ids) <-
 472                   dsfixCmd ids (local_vars `unionVarSet` bound_vars) stack res_ty leaf
 473             return ([mkHsEnvStackExpr leaf_ids stack_ids],
 474                     envStackType leaf_ids stack,
 475                     core_leaf)
 476
 477     branches <- mapM make_branch leaves
 478     either_con <- dsLookupTyCon eitherTyConName
 479     left_con <- dsLookupDataCon leftDataConName
 480     right_con <- dsLookupDataCon rightDataConName
 481     let
 482         left_id  = HsVar (dataConWrapId left_con)
 483         right_id = HsVar (dataConWrapId right_con)
 484         left_expr  ty1 ty2 e = noLoc $ HsApp (noLoc $ HsWrap (mkWpTyApps [ty1, ty2]) left_id ) e
 485         right_expr ty1 ty2 e = noLoc $ HsApp (noLoc $ HsWrap (mkWpTyApps [ty1, ty2]) right_id) e
 486
 487         -- Prefix each tuple with a distinct series of Left's and Right's,
 488         -- in a balanced way, keeping track of the types.
 489
 490         merge_branches (builds1, in_ty1, core_exp1)
 491                        (builds2, in_ty2, core_exp2)
 492           = (map (left_expr in_ty1 in_ty2) builds1 ++
 493                 map (right_expr in_ty1 in_ty2) builds2,
 494              mkTyConApp either_con [in_ty1, in_ty2],
 495              do_choice ids in_ty1 in_ty2 res_ty core_exp1 core_exp2)
 496         (leaves', sum_ty, core_choices) = foldb merge_branches branches
 497
 498         -- Replace the commands in the case with these tagged tuples,
 499         -- yielding a HsExpr Id we can feed to dsExpr.
 500
 501         (_, matches') = mapAccumL (replaceLeavesMatch res_ty) leaves' matches
 502         in_ty = envStackType env_ids stack
 503
 504         pat_ty    = funArgTy match_ty
 505         match_ty' = mkFunTy pat_ty sum_ty
 506         -- Note that we replace the HsCase result type by sum_ty,
 507         -- which is the type of matches'
 508
 509     core_body <- dsExpr (HsCase exp (MatchGroup matches' match_ty'))
 510     core_matches <- matchEnvStack env_ids stack_ids core_body
 511     return (do_map_arrow ids in_ty sum_ty res_ty core_matches core_choices,
 512             exprFreeVars core_body `intersectVarSet` local_vars)
 513
 514 --      A | ys |- c :: [ts] t
 515 --      ----------------------------------
 516 --      A | xs |- let binds in c :: [ts] t
 517 --
 518 --              ---> arr (\ ((xs)*ts) -> let binds in ((ys)*ts)) >>> c
 519
 520 dsCmd ids local_vars env_ids stack res_ty (HsLet binds body) = do
 521     let
 522         defined_vars = mkVarSet (collectLocalBinders binds)
 523         local_vars' = local_vars `unionVarSet` defined_vars
 524
 525     (core_body, _free_vars, env_ids') <- dsfixCmd ids local_vars' stack res_ty body
 526     stack_ids <- mapM newSysLocalDs stack
 527     -- build a new environment, plus the stack, using the let bindings
 528     core_binds <- dsLocalBinds binds (buildEnvStack env_ids' stack_ids)
 529     -- match the old environment and stack against the input
 530     core_map <- matchEnvStack env_ids stack_ids core_binds
 531     return (do_map_arrow ids
 532                         (envStackType env_ids stack)
 533                         (envStackType env_ids' stack)
 534                         res_ty
 535                         core_map
 536                         core_body,
 537         exprFreeVars core_binds `intersectVarSet` local_vars)
 538
 539 dsCmd ids local_vars env_ids [] res_ty (HsDo _ctxt stmts body _)
 540   = dsCmdDo ids local_vars env_ids res_ty stmts body
 541
 542 --      A |- e :: forall e. a1 (e*ts1) t1 -> ... an (e*tsn) tn -> a (e*ts) t
 543 --      A | xs |- ci :: [tsi] ti
 544 --      -----------------------------------
 545 --      A | xs |- (|e c1 ... cn|) :: [ts] t     ---> e [t_xs] c1 ... cn
 546
 547 dsCmd _ids local_vars env_ids _stack _res_ty (HsArrForm op _ args) = do
 548     let env_ty = mkBigCoreVarTupTy env_ids
 549     core_op <- dsLExpr op
 550     (core_args, fv_sets) <- mapAndUnzipM (dsTrimCmdArg local_vars env_ids) args
 551     return (mkApps (App core_op (Type env_ty)) core_args,
 552             unionVarSets fv_sets)
 553
 554
 555 dsCmd ids local_vars env_ids stack res_ty (HsTick ix vars expr) = do
 556     (expr1,id_set) <- dsLCmd ids local_vars env_ids stack res_ty expr
 557     expr2 <- mkTickBox ix vars expr1
 558     return (expr2,id_set)
 559
 560 dsCmd _ _ _ _ _ c = pprPanic "dsCmd" (ppr c)
 561
 562 --      A | ys |- c :: [ts] t   (ys <= xs)
 563 --      ---------------------
 564 --      A | xs |- c :: [ts] t   ---> arr_ts (\ (xs) -> (ys)) >>> c
 565
 566 dsTrimCmdArg
 567         :: IdSet                -- set of local vars available to this command
 568         -> [Id]                 -- list of vars in the input to this command
 569         -> LHsCmdTop Id -- command argument to desugar
 570         -> DsM (CoreExpr,       -- desugared expression
 571                 IdSet)          -- set of local vars that occur free
 572 dsTrimCmdArg local_vars env_ids (L _ (HsCmdTop cmd stack cmd_ty ids)) = do
 573     meth_ids <- mkCmdEnv ids
 574     (core_cmd, free_vars, env_ids') <- dsfixCmd meth_ids local_vars stack cmd_ty cmd
 575     stack_ids <- mapM newSysLocalDs stack
 576     trim_code <- matchEnvStack env_ids stack_ids (buildEnvStack env_ids' stack_ids)
 577     let
 578         in_ty = envStackType env_ids stack
 579         in_ty' = envStackType env_ids' stack
 580         arg_code = if env_ids' == env_ids then core_cmd else
 581                 do_map_arrow meth_ids in_ty in_ty' cmd_ty trim_code core_cmd
 582     return (bindCmdEnv meth_ids arg_code, free_vars)
 583
 584 -- Given A | xs |- c :: [ts] t, builds c with xs fed back.
 585 -- Typically needs to be prefixed with arr (\p -> ((xs)*ts))
 586
 587 dsfixCmd
 588         :: DsCmdEnv             -- arrow combinators
 589         -> IdSet                -- set of local vars available to this command
 590         -> [Type]               -- type of the stack
 591         -> Type                 -- return type of the command
 592         -> LHsCmd Id            -- command to desugar
 593         -> DsM (CoreExpr,       -- desugared expression
 594                 IdSet,          -- set of local vars that occur free
 595                 [Id])           -- set as a list, fed back
 596 dsfixCmd ids local_vars stack cmd_ty cmd
 597   = fixDs (\ ~(_,_,env_ids') -> do
 598         (core_cmd, free_vars) <- dsLCmd ids local_vars env_ids' stack cmd_ty cmd
 599         return (core_cmd, free_vars, varSetElems free_vars))
 600
 601 \end{code}
 602
 603 Translation of command judgements of the form
 604
 605         A | xs |- do { ss } :: [] t
 606
 607 \begin{code}
 608
 609 dsCmdDo :: DsCmdEnv             -- arrow combinators
 610         -> IdSet                -- set of local vars available to this statement
 611         -> [Id]                 -- list of vars in the input to this statement
 612                                 -- This is typically fed back,
 613                                 -- so don't pull on it too early
 614         -> Type                 -- return type of the statement
 615         -> [LStmt Id]           -- statements to desugar
 616         -> LHsExpr Id           -- body
 617         -> DsM (CoreExpr,       -- desugared expression
 618                 IdSet)          -- set of local vars that occur free
 619
 620 --      A | xs |- c :: [] t
 621 --      --------------------------
 622 --      A | xs |- do { c } :: [] t
 623
 624 dsCmdDo ids local_vars env_ids res_ty [] body
 625   = dsLCmd ids local_vars env_ids [] res_ty body
 626
 627 dsCmdDo ids local_vars env_ids res_ty (stmt:stmts) body = do
 628     let
 629         bound_vars = mkVarSet (collectLStmtBinders stmt)
 630         local_vars' = local_vars `unionVarSet` bound_vars
 631     (core_stmts, _, env_ids') <- fixDs (\ ~(_,_,env_ids') -> do
 632         (core_stmts, fv_stmts) <- dsCmdDo ids local_vars' env_ids' res_ty stmts body
 633         return (core_stmts, fv_stmts, varSetElems fv_stmts))
 634     (core_stmt, fv_stmt) <- dsCmdLStmt ids local_vars env_ids env_ids' stmt
 635     return (do_compose ids
 636                 (mkBigCoreVarTupTy env_ids)
 637                 (mkBigCoreVarTupTy env_ids')
 638                 res_ty
 639                 core_stmt
 640                 core_stmts,
 641               fv_stmt)
 642
 643 \end{code}
 644 A statement maps one local environment to another, and is represented
 645 as an arrow from one tuple type to another.  A statement sequence is
 646 translated to a composition of such arrows.
 647 \begin{code}
 648 dsCmdLStmt :: DsCmdEnv -> IdSet -> [Id] -> [Id] -> LStmt Id
 649            -> DsM (CoreExpr, IdSet)
 650 dsCmdLStmt ids local_vars env_ids out_ids cmd
 651   = dsCmdStmt ids local_vars env_ids out_ids (unLoc cmd)
 652
 653 dsCmdStmt
 654         :: DsCmdEnv             -- arrow combinators
 655         -> IdSet                -- set of local vars available to this statement
 656         -> [Id]                 -- list of vars in the input to this statement
 657                                 -- This is typically fed back,
 658                                 -- so don't pull on it too early
 659         -> [Id]                 -- list of vars in the output of this statement
 660         -> Stmt Id      -- statement to desugar
 661         -> DsM (CoreExpr,       -- desugared expression
 662                 IdSet)          -- set of local vars that occur free
 663
 664 --      A | xs1 |- c :: [] t
 665 --      A | xs' |- do { ss } :: [] t'
 666 --      ------------------------------
 667 --      A | xs |- do { c; ss } :: [] t'
 668 --
 669 --              ---> arr (\ (xs) -> ((xs1),(xs'))) >>> first c >>>
 670 --                      arr snd >>> ss
 671
 672 dsCmdStmt ids local_vars env_ids out_ids (ExprStmt cmd _ c_ty) = do
 673     (core_cmd, fv_cmd, env_ids1) <- dsfixCmd ids local_vars [] c_ty cmd
 674     core_mux <- matchEnvStack env_ids []
 675         (mkCorePairExpr (mkBigCoreVarTup env_ids1) (mkBigCoreVarTup out_ids))
 676     let
 677         in_ty = mkBigCoreVarTupTy env_ids
 678         in_ty1 = mkBigCoreVarTupTy env_ids1
 679         out_ty = mkBigCoreVarTupTy out_ids
 680         before_c_ty = mkCorePairTy in_ty1 out_ty
 681         after_c_ty = mkCorePairTy c_ty out_ty
 682     snd_fn <- mkSndExpr c_ty out_ty
 683     return (do_map_arrow ids in_ty before_c_ty out_ty core_mux $
 684                 do_compose ids before_c_ty after_c_ty out_ty
 685                         (do_first ids in_ty1 c_ty out_ty core_cmd) $
 686                 do_arr ids after_c_ty out_ty snd_fn,
 687               extendVarSetList fv_cmd out_ids)
 688   where
 689
 690 --      A | xs1 |- c :: [] t
 691 --      A | xs' |- do { ss } :: [] t'           xs2 = xs' - defs(p)
 692 --      -----------------------------------
 693 --      A | xs |- do { p <- c; ss } :: [] t'
 694 --
 695 --              ---> arr (\ (xs) -> ((xs1),(xs2))) >>> first c >>>
 696 --                      arr (\ (p, (xs2)) -> (xs')) >>> ss
 697 --
 698 -- It would be simpler and more consistent to do this using second,
 699 -- but that's likely to be defined in terms of first.
 700
 701 dsCmdStmt ids local_vars env_ids out_ids (BindStmt pat cmd _ _) = do
 702     (core_cmd, fv_cmd, env_ids1) <- dsfixCmd ids local_vars [] (hsLPatType pat) cmd
 703     let
 704         pat_ty = hsLPatType pat
 705         pat_vars = mkVarSet (collectPatBinders pat)
 706         env_ids2 = varSetElems (mkVarSet out_ids `minusVarSet` pat_vars)
 707         env_ty2 = mkBigCoreVarTupTy env_ids2
 708
 709     -- multiplexing function
 710     --          \ (xs) -> ((xs1),(xs2))
 711
 712     core_mux <- matchEnvStack env_ids []
 713         (mkCorePairExpr (mkBigCoreVarTup env_ids1) (mkBigCoreVarTup env_ids2))
 714
 715     -- projection function
 716     --          \ (p, (xs2)) -> (zs)
 717
 718     env_id <- newSysLocalDs env_ty2
 719     uniqs <- newUniqueSupply
 720     let
 721         after_c_ty = mkCorePairTy pat_ty env_ty2
 722         out_ty = mkBigCoreVarTupTy out_ids
 723         body_expr = coreCaseTuple uniqs env_id env_ids2 (mkBigCoreVarTup out_ids)
 724
 725     fail_expr <- mkFailExpr (StmtCtxt DoExpr) out_ty
 726     pat_id    <- selectSimpleMatchVarL pat
 727     match_code <- matchSimply (Var pat_id) (StmtCtxt DoExpr) pat body_expr fail_expr
 728     pair_id   <- newSysLocalDs after_c_ty
 729     let
 730         proj_expr = Lam pair_id (coreCasePair pair_id pat_id env_id match_code)
 731
 732     -- put it all together
 733     let
 734         in_ty = mkBigCoreVarTupTy env_ids
 735         in_ty1 = mkBigCoreVarTupTy env_ids1
 736         in_ty2 = mkBigCoreVarTupTy env_ids2
 737         before_c_ty = mkCorePairTy in_ty1 in_ty2
 738     return (do_map_arrow ids in_ty before_c_ty out_ty core_mux $
 739                 do_compose ids before_c_ty after_c_ty out_ty
 740                         (do_first ids in_ty1 pat_ty in_ty2 core_cmd) $
 741                 do_arr ids after_c_ty out_ty proj_expr,
 742               fv_cmd `unionVarSet` (mkVarSet out_ids `minusVarSet` pat_vars))
 743
 744 --      A | xs' |- do { ss } :: [] t
 745 --      --------------------------------------
 746 --      A | xs |- do { let binds; ss } :: [] t
 747 --
 748 --              ---> arr (\ (xs) -> let binds in (xs')) >>> ss
 749
 750 dsCmdStmt ids local_vars env_ids out_ids (LetStmt binds) = do
 751     -- build a new environment using the let bindings
 752     core_binds <- dsLocalBinds binds (mkBigCoreVarTup out_ids)
 753     -- match the old environment against the input
 754     core_map <- matchEnvStack env_ids [] core_binds
 755     return (do_arr ids
 756                         (mkBigCoreVarTupTy env_ids)
 757                         (mkBigCoreVarTupTy out_ids)
 758                         core_map,
 759         exprFreeVars core_binds `intersectVarSet` local_vars)
 760
 761 --      A | ys |- do { ss; returnA -< ((xs1), (ys2)) } :: [] ...
 762 --      A | xs' |- do { ss' } :: [] t
 763 --      ------------------------------------
 764 --      A | xs |- do { rec ss; ss' } :: [] t
 765 --
 766 --                      xs1 = xs' /\ defs(ss)
 767 --                      xs2 = xs' - defs(ss)
 768 --                      ys1 = ys - defs(ss)
 769 --                      ys2 = ys /\ defs(ss)
 770 --
 771 --              ---> arr (\(xs) -> ((ys1),(xs2))) >>>
 772 --                      first (loop (arr (\((ys1),~(ys2)) -> (ys)) >>> ss)) >>>
 773 --                      arr (\((xs1),(xs2)) -> (xs')) >>> ss'
 774
 775 dsCmdStmt ids local_vars env_ids out_ids
 776           (RecStmt { recS_stmts = stmts, recS_later_ids = later_ids, recS_rec_ids = rec_ids
 777                    , recS_rec_rets = rhss, recS_dicts = _binds }) = do
 778     let         -- ToDo: ****** binds not desugared; ROSS PLEASE FIX ********
 779         env2_id_set = mkVarSet out_ids `minusVarSet` mkVarSet later_ids
 780         env2_ids = varSetElems env2_id_set
 781         env2_ty = mkBigCoreVarTupTy env2_ids
 782
 783     -- post_loop_fn = \((later_ids),(env2_ids)) -> (out_ids)
 784
 785     uniqs <- newUniqueSupply
 786     env2_id <- newSysLocalDs env2_ty
 787     let
 788         later_ty = mkBigCoreVarTupTy later_ids
 789         post_pair_ty = mkCorePairTy later_ty env2_ty
 790         post_loop_body = coreCaseTuple uniqs env2_id env2_ids (mkBigCoreVarTup out_ids)
 791
 792     post_loop_fn <- matchEnvStack later_ids [env2_id] post_loop_body
 793
 794     --- loop (...)
 795
 796     (core_loop, env1_id_set, env1_ids)
 797                <- dsRecCmd ids local_vars stmts later_ids rec_ids rhss
 798
 799     -- pre_loop_fn = \(env_ids) -> ((env1_ids),(env2_ids))
 800
 801     let
 802         env1_ty = mkBigCoreVarTupTy env1_ids
 803         pre_pair_ty = mkCorePairTy env1_ty env2_ty
 804         pre_loop_body = mkCorePairExpr (mkBigCoreVarTup env1_ids)
 805                                         (mkBigCoreVarTup env2_ids)
 806
 807     pre_loop_fn <- matchEnvStack env_ids [] pre_loop_body
 808
 809     -- arr pre_loop_fn >>> first (loop (...)) >>> arr post_loop_fn
 810
 811     let
 812         env_ty = mkBigCoreVarTupTy env_ids
 813         out_ty = mkBigCoreVarTupTy out_ids
 814         core_body = do_map_arrow ids env_ty pre_pair_ty out_ty
 815                 pre_loop_fn
 816                 (do_compose ids pre_pair_ty post_pair_ty out_ty
 817                         (do_first ids env1_ty later_ty env2_ty
 818                                 core_loop)
 819                         (do_arr ids post_pair_ty out_ty
 820                                 post_loop_fn))
 821
 822     return (core_body, env1_id_set `unionVarSet` env2_id_set)
 823
 824 dsCmdStmt _ _ _ _ s = pprPanic "dsCmdStmt" (ppr s)
 825
 826 --      loop (arr (\ ((env1_ids), ~(rec_ids)) -> (env_ids)) >>>
 827 --            ss >>>
 828 --            arr (\ (out_ids) -> ((later_ids),(rhss))) >>>
 829
 830 dsRecCmd :: DsCmdEnv -> VarSet -> [LStmt Id] -> [Var] -> [Var] -> [HsExpr Id]
 831          -> DsM (CoreExpr, VarSet, [Var])
 832 dsRecCmd ids local_vars stmts later_ids rec_ids rhss = do
 833     let
 834         rec_id_set = mkVarSet rec_ids
 835         out_ids = varSetElems (mkVarSet later_ids `unionVarSet` rec_id_set)
 836         out_ty = mkBigCoreVarTupTy out_ids
 837         local_vars' = local_vars `unionVarSet` rec_id_set
 838
 839     -- mk_pair_fn = \ (out_ids) -> ((later_ids),(rhss))
 840
 841     core_rhss <- mapM dsExpr rhss
 842     let
 843         later_tuple = mkBigCoreVarTup later_ids
 844         later_ty = mkBigCoreVarTupTy later_ids
 845         rec_tuple = mkBigCoreTup core_rhss
 846         rec_ty = mkBigCoreVarTupTy rec_ids
 847         out_pair = mkCorePairExpr later_tuple rec_tuple
 848         out_pair_ty = mkCorePairTy later_ty rec_ty
 849
 850     mk_pair_fn <- matchEnvStack out_ids [] out_pair
 851
 852     -- ss
 853
 854     (core_stmts, fv_stmts, env_ids) <- dsfixCmdStmts ids local_vars' out_ids stmts
 855
 856     -- squash_pair_fn = \ ((env1_ids), ~(rec_ids)) -> (env_ids)
 857
 858     rec_id <- newSysLocalDs rec_ty
 859     let
 860         env1_id_set = fv_stmts `minusVarSet` rec_id_set
 861         env1_ids = varSetElems env1_id_set
 862         env1_ty = mkBigCoreVarTupTy env1_ids
 863         in_pair_ty = mkCorePairTy env1_ty rec_ty
 864         core_body = mkBigCoreTup (map selectVar env_ids)
 865           where
 866             selectVar v
 867                 | v `elemVarSet` rec_id_set
 868                   = mkTupleSelector rec_ids v rec_id (Var rec_id)
 869                 | otherwise = Var v
 870
 871     squash_pair_fn <- matchEnvStack env1_ids [rec_id] core_body
 872
 873     -- loop (arr squash_pair_fn >>> ss >>> arr mk_pair_fn)
 874
 875     let
 876         env_ty = mkBigCoreVarTupTy env_ids
 877         core_loop = do_loop ids env1_ty later_ty rec_ty
 878                 (do_map_arrow ids in_pair_ty env_ty out_pair_ty
 879                         squash_pair_fn
 880                         (do_compose ids env_ty out_ty out_pair_ty
 881                                 core_stmts
 882                                 (do_arr ids out_ty out_pair_ty mk_pair_fn)))
 883
 884     return (core_loop, env1_id_set, env1_ids)
 885
 886 \end{code}
 887 A sequence of statements (as in a rec) is desugared to an arrow between
 888 two environments
 889 \begin{code}
 890
 891 dsfixCmdStmts
 892         :: DsCmdEnv             -- arrow combinators
 893         -> IdSet                -- set of local vars available to this statement
 894         -> [Id]                 -- output vars of these statements
 895         -> [LStmt Id]   -- statements to desugar
 896         -> DsM (CoreExpr,       -- desugared expression
 897                 IdSet,          -- set of local vars that occur free
 898                 [Id])           -- input vars
 899
 900 dsfixCmdStmts ids local_vars out_ids stmts
 901   = fixDs (\ ~(_,_,env_ids) -> do
 902         (core_stmts, fv_stmts) <- dsCmdStmts ids local_vars env_ids out_ids stmts
 903         return (core_stmts, fv_stmts, varSetElems fv_stmts))
 904
 905 dsCmdStmts
 906         :: DsCmdEnv             -- arrow combinators
 907         -> IdSet                -- set of local vars available to this statement
 908         -> [Id]                 -- list of vars in the input to these statements
 909         -> [Id]                 -- output vars of these statements
 910         -> [LStmt Id]   -- statements to desugar
 911         -> DsM (CoreExpr,       -- desugared expression
 912                 IdSet)          -- set of local vars that occur free
 913
 914 dsCmdStmts ids local_vars env_ids out_ids [stmt]
 915   = dsCmdLStmt ids local_vars env_ids out_ids stmt
 916
 917 dsCmdStmts ids local_vars env_ids out_ids (stmt:stmts) = do
 918     let
 919         bound_vars = mkVarSet (collectLStmtBinders stmt)
 920         local_vars' = local_vars `unionVarSet` bound_vars
 921     (core_stmts, _fv_stmts, env_ids') <- dsfixCmdStmts ids local_vars' out_ids stmts
 922     (core_stmt, fv_stmt) <- dsCmdLStmt ids local_vars env_ids env_ids' stmt
 923     return (do_compose ids
 924                 (mkBigCoreVarTupTy env_ids)
 925                 (mkBigCoreVarTupTy env_ids')
 926                 (mkBigCoreVarTupTy out_ids)
 927                 core_stmt
 928                 core_stmts,
 929               fv_stmt)
 930
 931 dsCmdStmts _ _ _ _ [] = panic "dsCmdStmts []"
 932
 933 \end{code}
 934
 935 Match a list of expressions against a list of patterns, left-to-right.
 936
 937 \begin{code}
 938 matchSimplys :: [CoreExpr]              -- Scrutinees
 939              -> HsMatchContext Name     -- Match kind
 940              -> [LPat Id]               -- Patterns they should match
 941              -> CoreExpr                -- Return this if they all match
 942              -> CoreExpr                -- Return this if they don't
 943              -> DsM CoreExpr
 944 matchSimplys [] _ctxt [] result_expr _fail_expr = return result_expr
 945 matchSimplys (exp:exps) ctxt (pat:pats) result_expr fail_expr = do
 946     match_code <- matchSimplys exps ctxt pats result_expr fail_expr
 947     matchSimply exp ctxt pat match_code fail_expr
 948 matchSimplys _ _ _ _ _ = panic "matchSimplys"
 949 \end{code}
 950
 951 List of leaf expressions, with set of variables bound in each
 952
 953 \begin{code}
 954 leavesMatch :: LMatch Id -> [(LHsExpr Id, IdSet)]
 955 leavesMatch (L _ (Match pats _ (GRHSs grhss binds)))
 956   = let
 957         defined_vars = mkVarSet (collectPatsBinders pats)
 958                         `unionVarSet`
 959                        mkVarSet (collectLocalBinders binds)
 960     in
 961     [(expr,
 962       mkVarSet (collectLStmtsBinders stmts)
 963         `unionVarSet` defined_vars)
 964     | L _ (GRHS stmts expr) <- grhss]
 965 \end{code}
 966
 967 Replace the leaf commands in a match
 968
 969 \begin{code}
 970 replaceLeavesMatch
 971         :: Type                 -- new result type
 972         -> [LHsExpr Id] -- replacement leaf expressions of that type
 973         -> LMatch Id    -- the matches of a case command
 974         -> ([LHsExpr Id],-- remaining leaf expressions
 975             LMatch Id)  -- updated match
 976 replaceLeavesMatch _res_ty leaves (L loc (Match pat mt (GRHSs grhss binds)))
 977   = let
 978         (leaves', grhss') = mapAccumL replaceLeavesGRHS leaves grhss
 979     in
 980     (leaves', L loc (Match pat mt (GRHSs grhss' binds)))
 981
 982 replaceLeavesGRHS
 983         :: [LHsExpr Id] -- replacement leaf expressions of that type
 984         -> LGRHS Id     -- rhss of a case command
 985         -> ([LHsExpr Id],-- remaining leaf expressions
 986             LGRHS Id)   -- updated GRHS
 987 replaceLeavesGRHS (leaf:leaves) (L loc (GRHS stmts _))
 988   = (leaves, L loc (GRHS stmts leaf))
 989 replaceLeavesGRHS [] _ = panic "replaceLeavesGRHS []"
 990 \end{code}
 991
 992 Balanced fold of a non-empty list.
 993
 994 \begin{code}
 995 foldb :: (a -> a -> a) -> [a] -> a
 996 foldb _ [] = error "foldb of empty list"
 997 foldb _ [x] = x
 998 foldb f xs = foldb f (fold_pairs xs)
 999   where
1000     fold_pairs [] = []
1001     fold_pairs [x] = [x]
1002     fold_pairs (x1:x2:xs) = f x1 x2:fold_pairs xs
1003 \end{code}
1004
1005 Note [Dictionary binders in ConPatOut] See also same Note in HsUtils
1006 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1007 The following functions to collect value variables from patterns are
1008 copied from HsUtils, with one change: we also collect the dictionary
1009 bindings (pat_binds) from ConPatOut.  We need them for cases like
1010
1011 h :: Arrow a => Int -> a (Int,Int) Int
1012 h x = proc (y,z) -> case compare x y of
1013                 GT -> returnA -< z+x
1014
1015 The type checker turns the case into
1016
1017                 case compare x y of
1018                   GT { p77 = plusInt } -> returnA -< p77 z x
1019
1020 Here p77 is a local binding for the (+) operation.
1021
1022 See comments in HsUtils for why the other version does not include
1023 these bindings.
1024
1025 \begin{code}
1026 collectPatBinders :: OutputableBndr a => LPat a -> [a]
1027 collectPatBinders pat = collectl pat []
1028
1029 collectPatsBinders :: OutputableBndr a => [LPat a] -> [a]
1030 collectPatsBinders pats = foldr collectl [] pats
1031
1032 ---------------------
1033 collectl :: OutputableBndr a => LPat a -> [a] -> [a]
1034 -- See Note [Dictionary binders in ConPatOut]
1035 collectl (L _ pat) bndrs
1036   = go pat
1037   where
1038     go (VarPat var)               = var : bndrs
1039     go (VarPatOut var bs)         = var : collectHsBindsBinders bs
1040                                     ++ bndrs
1041     go (WildPat _)                = bndrs
1042     go (LazyPat pat)              = collectl pat bndrs
1043     go (BangPat pat)              = collectl pat bndrs
1044     go (AsPat (L _ a) pat)        = a : collectl pat bndrs
1045     go (ParPat  pat)              = collectl pat bndrs
1046
1047     go (ListPat pats _)           = foldr collectl bndrs pats
1048     go (PArrPat pats _)           = foldr collectl bndrs pats
1049     go (TuplePat pats _ _)        = foldr collectl bndrs pats
1050
1051     go (ConPatIn _ ps)            = foldr collectl bndrs (hsConPatArgs ps)
1052     go (ConPatOut {pat_args=ps, pat_binds=ds}) =
1053                                     collectHsBindsBinders ds
1054                                     ++ foldr collectl bndrs (hsConPatArgs ps)
1055     go (LitPat _)                 = bndrs
1056     go (NPat _ _ _)               = bndrs
1057     go (NPlusKPat (L _ n) _ _ _)  = n : bndrs
1058
1059     go (SigPatIn pat _)           = collectl pat bndrs
1060     go (SigPatOut pat _)          = collectl pat bndrs
1061     go (TypePat _)                = bndrs
1062     go (CoPat _ pat _)            = collectl (noLoc pat) bndrs
1063     go (ViewPat _ pat _)          = collectl pat bndrs
1064     go p@(QuasiQuotePat {})       = pprPanic "collectl/go" (ppr p)
1065 \end{code}