compiler/deSugar/DsArrows.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Desugaring arrow commands
   7
   8 \begin{code}
   9 module DsArrows ( dsProcExpr ) where
  10
  11 #include "HsVersions.h"
  12
  13 import Match
  14 import DsUtils
  15 import DsMonad
  16
  17 import HsSyn
  18 import TcHsSyn
  19
  20 -- NB: The desugarer, which straddles the source and Core worlds, sometimes
  21 --     needs to see source types (newtypes etc), and sometimes not
  22 --     So WATCH OUT; check each use of split*Ty functions.
  23 -- Sigh.  This is a pain.
  24
  25 import {-# SOURCE #-} DsExpr ( dsExpr, dsLExpr, dsLocalBinds )
  26
  27 import TcType
  28 import Type
  29 import CoreSyn
  30 import CoreFVs
  31 import CoreUtils
  32
  33 import Id
  34 import Name
  35 import PrelInfo
  36 import DataCon
  37 import TysWiredIn
  38 import BasicTypes
  39 import PrelNames
  40 import Util
  41
  42 import HsUtils
  43 import VarSet
  44 import SrcLoc
  45 \end{code}
  46
  47 \begin{code}
  48 data DsCmdEnv = DsCmdEnv {
  49         meth_binds :: [CoreBind],
  50         arr_id, compose_id, first_id, app_id, choice_id, loop_id :: CoreExpr
  51     }
  52
  53 mkCmdEnv :: SyntaxTable Id -> DsM DsCmdEnv
  54 mkCmdEnv ids
  55   = dsSyntaxTable ids                   `thenDs` \ (meth_binds, ds_meths) ->
  56     return $ DsCmdEnv {
  57                 meth_binds = meth_binds,
  58                 arr_id     = Var (lookupEvidence ds_meths arrAName),
  59                 compose_id = Var (lookupEvidence ds_meths composeAName),
  60                 first_id   = Var (lookupEvidence ds_meths firstAName),
  61                 app_id     = Var (lookupEvidence ds_meths appAName),
  62                 choice_id  = Var (lookupEvidence ds_meths choiceAName),
  63                 loop_id    = Var (lookupEvidence ds_meths loopAName)
  64             }
  65
  66 bindCmdEnv :: DsCmdEnv -> CoreExpr -> CoreExpr
  67 bindCmdEnv ids body = foldr Let body (meth_binds ids)
  68
  69 -- arr :: forall b c. (b -> c) -> a b c
  70 do_arr :: DsCmdEnv -> Type -> Type -> CoreExpr -> CoreExpr
  71 do_arr ids b_ty c_ty f = mkApps (arr_id ids) [Type b_ty, Type c_ty, f]
  72
  73 -- (>>>) :: forall b c d. a b c -> a c d -> a b d
  74 do_compose :: DsCmdEnv -> Type -> Type -> Type ->
  75                 CoreExpr -> CoreExpr -> CoreExpr
  76 do_compose ids b_ty c_ty d_ty f g
  77   = mkApps (compose_id ids) [Type b_ty, Type c_ty, Type d_ty, f, g]
  78
  79 -- first :: forall b c d. a b c -> a (b,d) (c,d)
  80 do_first :: DsCmdEnv -> Type -> Type -> Type -> CoreExpr -> CoreExpr
  81 do_first ids b_ty c_ty d_ty f
  82   = mkApps (first_id ids) [Type b_ty, Type c_ty, Type d_ty, f]
  83
  84 -- app :: forall b c. a (a b c, b) c
  85 do_app :: DsCmdEnv -> Type -> Type -> CoreExpr
  86 do_app ids b_ty c_ty = mkApps (app_id ids) [Type b_ty, Type c_ty]
  87
  88 -- (|||) :: forall b d c. a b d -> a c d -> a (Either b c) d
  89 -- note the swapping of d and c
  90 do_choice :: DsCmdEnv -> Type -> Type -> Type ->
  91                 CoreExpr -> CoreExpr -> CoreExpr
  92 do_choice ids b_ty c_ty d_ty f g
  93   = mkApps (choice_id ids) [Type b_ty, Type d_ty, Type c_ty, f, g]
  94
  95 -- loop :: forall b d c. a (b,d) (c,d) -> a b c
  96 -- note the swapping of d and c
  97 do_loop :: DsCmdEnv -> Type -> Type -> Type -> CoreExpr -> CoreExpr
  98 do_loop ids b_ty c_ty d_ty f
  99   = mkApps (loop_id ids) [Type b_ty, Type d_ty, Type c_ty, f]
 100
 101 -- map_arrow (f :: b -> c) (g :: a c d) = arr f >>> g :: a b d
 102 do_map_arrow :: DsCmdEnv -> Type -> Type -> Type ->
 103                 CoreExpr -> CoreExpr -> CoreExpr
 104 do_map_arrow ids b_ty c_ty d_ty f c
 105   = do_compose ids b_ty c_ty d_ty (do_arr ids b_ty c_ty f) c
 106
 107 mkFailExpr :: HsMatchContext Id -> Type -> DsM CoreExpr
 108 mkFailExpr ctxt ty
 109   = mkErrorAppDs pAT_ERROR_ID ty (matchContextErrString ctxt)
 110
 111 -- construct CoreExpr for \ (a :: a_ty, b :: b_ty) -> b
 112 mkSndExpr :: Type -> Type -> DsM CoreExpr
 113 mkSndExpr a_ty b_ty
 114   = newSysLocalDs a_ty                  `thenDs` \ a_var ->
 115     newSysLocalDs b_ty                  `thenDs` \ b_var ->
 116     newSysLocalDs (mkCorePairTy a_ty b_ty)      `thenDs` \ pair_var ->
 117     returnDs (Lam pair_var
 118                   (coreCasePair pair_var a_var b_var (Var b_var)))
 119 \end{code}
 120
 121 Build case analysis of a tuple.  This cannot be done in the DsM monad,
 122 because the list of variables is typically not yet defined.
 123
 124 \begin{code}
 125 -- coreCaseTuple [u1..] v [x1..xn] body
 126 --      = case v of v { (x1, .., xn) -> body }
 127 -- But the matching may be nested if the tuple is very big
 128
 129 coreCaseTuple :: UniqSupply -> Id -> [Id] -> CoreExpr -> CoreExpr
 130 coreCaseTuple uniqs scrut_var vars body
 131   = mkTupleCase uniqs vars body scrut_var (Var scrut_var)
 132
 133 coreCasePair :: Id -> Id -> Id -> CoreExpr -> CoreExpr
 134 coreCasePair scrut_var var1 var2 body
 135   = Case (Var scrut_var) scrut_var (exprType body)
 136          [(DataAlt (tupleCon Boxed 2), [var1, var2], body)]
 137 \end{code}
 138
 139 \begin{code}
 140 mkCorePairTy :: Type -> Type -> Type
 141 mkCorePairTy t1 t2 = mkCoreTupTy [t1, t2]
 142
 143 mkCorePairExpr :: CoreExpr -> CoreExpr -> CoreExpr
 144 mkCorePairExpr e1 e2 = mkCoreTup [e1, e2]
 145 \end{code}
 146
 147 The input is divided into a local environment, which is a flat tuple
 148 (unless it's too big), and a stack, each element of which is paired
 149 with the stack in turn.  In general, the input has the form
 150
 151         (...((x1,...,xn),s1),...sk)
 152
 153 where xi are the environment values, and si the ones on the stack,
 154 with s1 being the "top", the first one to be matched with a lambda.
 155
 156 \begin{code}
 157 envStackType :: [Id] -> [Type] -> Type
 158 envStackType ids stack_tys = foldl mkCorePairTy (mkTupleType ids) stack_tys
 159
 160 ----------------------------------------------
 161 --              buildEnvStack
 162 --
 163 --      (...((x1,...,xn),s1),...sk)
 164
 165 buildEnvStack :: [Id] -> [Id] -> CoreExpr
 166 buildEnvStack env_ids stack_ids
 167   = foldl mkCorePairExpr (mkTupleExpr env_ids) (map Var stack_ids)
 168
 169 ----------------------------------------------
 170 --              matchEnvStack
 171 --
 172 --      \ (...((x1,...,xn),s1),...sk) -> e
 173 --      =>
 174 --      \ zk ->
 175 --      case zk of (zk-1,sk) ->
 176 --      ...
 177 --      case z1 of (z0,s1) ->
 178 --      case z0 of (x1,...,xn) ->
 179 --      e
 180
 181 matchEnvStack   :: [Id]         -- x1..xn
 182                 -> [Id]         -- s1..sk
 183                 -> CoreExpr     -- e
 184                 -> DsM CoreExpr
 185 matchEnvStack env_ids stack_ids body
 186   = newUniqueSupply                     `thenDs` \ uniqs ->
 187     newSysLocalDs (mkTupleType env_ids) `thenDs` \ tup_var ->
 188     matchVarStack tup_var stack_ids
 189                   (coreCaseTuple uniqs tup_var env_ids body)
 190
 191
 192 ----------------------------------------------
 193 --              matchVarStack
 194 --
 195 --      \ (...(z0,s1),...sk) -> e
 196 --      =>
 197 --      \ zk ->
 198 --      case zk of (zk-1,sk) ->
 199 --      ...
 200 --      case z1 of (z0,s1) ->
 201 --      e
 202
 203 matchVarStack :: Id             -- z0
 204               -> [Id]           -- s1..sk
 205               -> CoreExpr       -- e
 206               -> DsM CoreExpr
 207 matchVarStack env_id [] body
 208   = returnDs (Lam env_id body)
 209 matchVarStack env_id (stack_id:stack_ids) body
 210   = newSysLocalDs (mkCorePairTy (idType env_id) (idType stack_id))
 211                                         `thenDs` \ pair_id ->
 212     matchVarStack pair_id stack_ids
 213                   (coreCasePair pair_id env_id stack_id body)
 214 \end{code}
 215
 216 \begin{code}
 217 mkHsTupleExpr :: [HsExpr Id] -> HsExpr Id
 218 mkHsTupleExpr [e] = e
 219 mkHsTupleExpr es = ExplicitTuple (map noLoc es) Boxed
 220
 221 mkHsPairExpr :: HsExpr Id -> HsExpr Id -> HsExpr Id
 222 mkHsPairExpr e1 e2 = mkHsTupleExpr [e1, e2]
 223
 224 mkHsEnvStackExpr :: [Id] -> [Id] -> HsExpr Id
 225 mkHsEnvStackExpr env_ids stack_ids
 226   = foldl mkHsPairExpr (mkHsTupleExpr (map HsVar env_ids)) (map HsVar stack_ids)
 227 \end{code}
 228
 229 Translation of arrow abstraction
 230
 231 \begin{code}
 232
 233 --      A | xs |- c :: [] t'        ---> c'
 234 --      --------------------------
 235 --      A |- proc p -> c :: a t t'  ---> arr (\ p -> (xs)) >>> c'
 236 --
 237 --              where (xs) is the tuple of variables bound by p
 238
 239 dsProcExpr
 240         :: LPat Id
 241         -> LHsCmdTop Id
 242         -> DsM CoreExpr
 243 dsProcExpr pat (L _ (HsCmdTop cmd [] cmd_ty ids))
 244   = mkCmdEnv ids                        `thenDs` \ meth_ids ->
 245     let
 246         locals = mkVarSet (collectPatBinders pat)
 247     in
 248     dsfixCmd meth_ids locals [] cmd_ty cmd
 249                                 `thenDs` \ (core_cmd, free_vars, env_ids) ->
 250     let
 251         env_ty = mkTupleType env_ids
 252     in
 253     mkFailExpr ProcExpr env_ty          `thenDs` \ fail_expr ->
 254     selectSimpleMatchVarL pat           `thenDs` \ var ->
 255     matchSimply (Var var) ProcExpr pat (mkTupleExpr env_ids) fail_expr
 256                                         `thenDs` \ match_code ->
 257     let
 258         pat_ty = hsLPatType pat
 259         proc_code = do_map_arrow meth_ids pat_ty env_ty cmd_ty
 260                 (Lam var match_code)
 261                 core_cmd
 262     in
 263     returnDs (bindCmdEnv meth_ids proc_code)
 264 \end{code}
 265
 266 Translation of command judgements of the form
 267
 268         A | xs |- c :: [ts] t
 269
 270 \begin{code}
 271 dsLCmd ids local_vars env_ids stack res_ty cmd
 272   = dsCmd ids local_vars env_ids stack res_ty (unLoc cmd)
 273
 274 dsCmd   :: DsCmdEnv             -- arrow combinators
 275         -> IdSet                -- set of local vars available to this command
 276         -> [Id]                 -- list of vars in the input to this command
 277                                 -- This is typically fed back,
 278                                 -- so don't pull on it too early
 279         -> [Type]               -- type of the stack
 280         -> Type                 -- return type of the command
 281         -> HsCmd Id             -- command to desugar
 282         -> DsM (CoreExpr,       -- desugared expression
 283                 IdSet)          -- set of local vars that occur free
 284
 285 --      A |- f :: a (t*ts) t'
 286 --      A, xs |- arg :: t
 287 --      -----------------------------
 288 --      A | xs |- f -< arg :: [ts] t'
 289 --
 290 --              ---> arr (\ ((xs)*ts) -> (arg*ts)) >>> f
 291
 292 dsCmd ids local_vars env_ids stack res_ty
 293         (HsArrApp arrow arg arrow_ty HsFirstOrderApp _)
 294   = let
 295         (a_arg_ty, _res_ty') = tcSplitAppTy arrow_ty
 296         (_a_ty, arg_ty) = tcSplitAppTy a_arg_ty
 297         env_ty = mkTupleType env_ids
 298     in
 299     dsLExpr arrow                       `thenDs` \ core_arrow ->
 300     dsLExpr arg                         `thenDs` \ core_arg ->
 301     mappM newSysLocalDs stack           `thenDs` \ stack_ids ->
 302     matchEnvStack env_ids stack_ids
 303         (foldl mkCorePairExpr core_arg (map Var stack_ids))
 304                                         `thenDs` \ core_make_arg ->
 305     returnDs (do_map_arrow ids
 306                 (envStackType env_ids stack)
 307                 arg_ty
 308                 res_ty
 309                 core_make_arg
 310                 core_arrow,
 311               exprFreeVars core_arg `intersectVarSet` local_vars)
 312
 313 --      A, xs |- f :: a (t*ts) t'
 314 --      A, xs |- arg :: t
 315 --      ------------------------------
 316 --      A | xs |- f -<< arg :: [ts] t'
 317 --
 318 --              ---> arr (\ ((xs)*ts) -> (f,(arg*ts))) >>> app
 319
 320 dsCmd ids local_vars env_ids stack res_ty
 321         (HsArrApp arrow arg arrow_ty HsHigherOrderApp _)
 322   = let
 323         (a_arg_ty, _res_ty') = tcSplitAppTy arrow_ty
 324         (_a_ty, arg_ty) = tcSplitAppTy a_arg_ty
 325         env_ty = mkTupleType env_ids
 326     in
 327     dsLExpr arrow                       `thenDs` \ core_arrow ->
 328     dsLExpr arg                         `thenDs` \ core_arg ->
 329     mappM newSysLocalDs stack           `thenDs` \ stack_ids ->
 330     matchEnvStack env_ids stack_ids
 331         (mkCorePairExpr core_arrow
 332                 (foldl mkCorePairExpr core_arg (map Var stack_ids)))
 333                                         `thenDs` \ core_make_pair ->
 334     returnDs (do_map_arrow ids
 335                 (envStackType env_ids stack)
 336                 (mkCorePairTy arrow_ty arg_ty)
 337                 res_ty
 338                 core_make_pair
 339                 (do_app ids arg_ty res_ty),
 340               (exprFreeVars core_arrow `unionVarSet` exprFreeVars core_arg)
 341                 `intersectVarSet` local_vars)
 342
 343 --      A | ys |- c :: [t:ts] t'
 344 --      A, xs  |- e :: t
 345 --      ------------------------
 346 --      A | xs |- c e :: [ts] t'
 347 --
 348 --              ---> arr (\ ((xs)*ts) -> let z = e in (((ys),z)*ts)) >>> c
 349
 350 dsCmd ids local_vars env_ids stack res_ty (HsApp cmd arg)
 351   = dsLExpr arg                 `thenDs` \ core_arg ->
 352     let
 353         arg_ty = exprType core_arg
 354         stack' = arg_ty:stack
 355     in
 356     dsfixCmd ids local_vars stack' res_ty cmd
 357                                 `thenDs` \ (core_cmd, free_vars, env_ids') ->
 358     mappM newSysLocalDs stack   `thenDs` \ stack_ids ->
 359     newSysLocalDs arg_ty        `thenDs` \ arg_id ->
 360     -- push the argument expression onto the stack
 361     let
 362         core_body = bindNonRec arg_id core_arg
 363                         (buildEnvStack env_ids' (arg_id:stack_ids))
 364     in
 365     -- match the environment and stack against the input
 366     matchEnvStack env_ids stack_ids core_body
 367                                 `thenDs` \ core_map ->
 368     returnDs (do_map_arrow ids
 369                         (envStackType env_ids stack)
 370                         (envStackType env_ids' stack')
 371                         res_ty
 372                         core_map
 373                         core_cmd,
 374         (exprFreeVars core_arg `intersectVarSet` local_vars)
 375                 `unionVarSet` free_vars)
 376
 377 --      A | ys |- c :: [ts] t'
 378 --      -----------------------------------------------
 379 --      A | xs |- \ p1 ... pk -> c :: [t1:...:tk:ts] t'
 380 --
 381 --              ---> arr (\ ((((xs), p1), ... pk)*ts) -> ((ys)*ts)) >>> c
 382
 383 dsCmd ids local_vars env_ids stack res_ty
 384     (HsLam (MatchGroup [L _ (Match pats _ (GRHSs [L _ (GRHS [] body)] _ ))] _))
 385   = let
 386         pat_vars = mkVarSet (collectPatsBinders pats)
 387         local_vars' = local_vars `unionVarSet` pat_vars
 388         stack' = drop (length pats) stack
 389     in
 390     dsfixCmd ids local_vars' stack' res_ty body
 391                                 `thenDs` \ (core_body, free_vars, env_ids') ->
 392     mappM newSysLocalDs stack   `thenDs` \ stack_ids ->
 393
 394     -- the expression is built from the inside out, so the actions
 395     -- are presented in reverse order
 396
 397     let
 398         (actual_ids, stack_ids') = splitAt (length pats) stack_ids
 399         -- build a new environment, plus what's left of the stack
 400         core_expr = buildEnvStack env_ids' stack_ids'
 401         in_ty = envStackType env_ids stack
 402         in_ty' = envStackType env_ids' stack'
 403     in
 404     mkFailExpr LambdaExpr in_ty'        `thenDs` \ fail_expr ->
 405     -- match the patterns against the top of the old stack
 406     matchSimplys (map Var actual_ids) LambdaExpr pats core_expr fail_expr
 407                                         `thenDs` \ match_code ->
 408     -- match the old environment and stack against the input
 409     matchEnvStack env_ids stack_ids match_code
 410                                         `thenDs` \ select_code ->
 411     returnDs (do_map_arrow ids in_ty in_ty' res_ty select_code core_body,
 412              free_vars `minusVarSet` pat_vars)
 413
 414 dsCmd ids local_vars env_ids stack res_ty (HsPar cmd)
 415   = dsLCmd ids local_vars env_ids stack res_ty cmd
 416
 417 --      A, xs |- e :: Bool
 418 --      A | xs1 |- c1 :: [ts] t
 419 --      A | xs2 |- c2 :: [ts] t
 420 --      ----------------------------------------
 421 --      A | xs |- if e then c1 else c2 :: [ts] t
 422 --
 423 --              ---> arr (\ ((xs)*ts) ->
 424 --                      if e then Left ((xs1)*ts) else Right ((xs2)*ts)) >>>
 425 --                   c1 ||| c2
 426
 427 dsCmd ids local_vars env_ids stack res_ty (HsIf cond then_cmd else_cmd)
 428   = dsLExpr cond                        `thenDs` \ core_cond ->
 429     dsfixCmd ids local_vars stack res_ty then_cmd
 430                                 `thenDs` \ (core_then, fvs_then, then_ids) ->
 431     dsfixCmd ids local_vars stack res_ty else_cmd
 432                                 `thenDs` \ (core_else, fvs_else, else_ids) ->
 433     mappM newSysLocalDs stack           `thenDs` \ stack_ids ->
 434     dsLookupTyCon eitherTyConName       `thenDs` \ either_con ->
 435     dsLookupDataCon leftDataConName     `thenDs` \ left_con ->
 436     dsLookupDataCon rightDataConName    `thenDs` \ right_con ->
 437     let
 438         left_expr ty1 ty2 e = mkConApp left_con [Type ty1, Type ty2, e]
 439         right_expr ty1 ty2 e = mkConApp right_con [Type ty1, Type ty2, e]
 440
 441         in_ty = envStackType env_ids stack
 442         then_ty = envStackType then_ids stack
 443         else_ty = envStackType else_ids stack
 444         sum_ty = mkTyConApp either_con [then_ty, else_ty]
 445         fvs_cond = exprFreeVars core_cond `intersectVarSet` local_vars
 446     in
 447     matchEnvStack env_ids stack_ids
 448         (mkIfThenElse core_cond
 449             (left_expr then_ty else_ty (buildEnvStack then_ids stack_ids))
 450             (right_expr then_ty else_ty (buildEnvStack else_ids stack_ids)))
 451                                         `thenDs` \ core_if ->
 452     returnDs(do_map_arrow ids in_ty sum_ty res_ty
 453                 core_if
 454                 (do_choice ids then_ty else_ty res_ty core_then core_else),
 455         fvs_cond `unionVarSet` fvs_then `unionVarSet` fvs_else)
 456 \end{code}
 457
 458 Case commands are treated in much the same way as if commands
 459 (see above) except that there are more alternatives.  For example
 460
 461         case e of { p1 -> c1; p2 -> c2; p3 -> c3 }
 462
 463 is translated to
 464
 465         arr (\ ((xs)*ts) -> case e of
 466                 p1 -> (Left (Left (xs1)*ts))
 467                 p2 -> Left ((Right (xs2)*ts))
 468                 p3 -> Right ((xs3)*ts)) >>>
 469         (c1 ||| c2) ||| c3
 470
 471 The idea is to extract the commands from the case, build a balanced tree
 472 of choices, and replace the commands with expressions that build tagged
 473 tuples, obtaining a case expression that can be desugared normally.
 474 To build all this, we use quadruples decribing segments of the list of
 475 case bodies, containing the following fields:
 476 1. an IdSet containing the environment variables free in the case bodies
 477 2. a list of expressions of the form (Left|Right)* ((xs)*ts), to be put
 478    into the case replacing the commands
 479 3. a sum type that is the common type of these expressions, and also the
 480    input type of the arrow
 481 4. a CoreExpr for an arrow built by combining the translated command
 482    bodies with |||.
 483
 484 \begin{code}
 485 dsCmd ids local_vars env_ids stack res_ty (HsCase exp (MatchGroup matches match_ty))
 486   = dsLExpr exp                         `thenDs` \ core_exp ->
 487     mappM newSysLocalDs stack           `thenDs` \ stack_ids ->
 488
 489     -- Extract and desugar the leaf commands in the case, building tuple
 490     -- expressions that will (after tagging) replace these leaves
 491
 492     let
 493         leaves = concatMap leavesMatch matches
 494         make_branch (leaf, bound_vars)
 495           = dsfixCmd ids (local_vars `unionVarSet` bound_vars) stack res_ty leaf
 496                            `thenDs` \ (core_leaf, fvs, leaf_ids) ->
 497             returnDs (fvs `minusVarSet` bound_vars,
 498                       [noLoc $ mkHsEnvStackExpr leaf_ids stack_ids],
 499                       envStackType leaf_ids stack,
 500                       core_leaf)
 501     in
 502     mappM make_branch leaves            `thenDs` \ branches ->
 503     dsLookupTyCon eitherTyConName       `thenDs` \ either_con ->
 504     dsLookupDataCon leftDataConName     `thenDs` \ left_con ->
 505     dsLookupDataCon rightDataConName    `thenDs` \ right_con ->
 506     let
 507         left_id  = HsVar (dataConWrapId left_con)
 508         right_id = HsVar (dataConWrapId right_con)
 509         left_expr  ty1 ty2 e = noLoc $ HsApp (noLoc $ HsWrap (mkWpTyApps [ty1, ty2]) left_id ) e
 510         right_expr ty1 ty2 e = noLoc $ HsApp (noLoc $ HsWrap (mkWpTyApps [ty1, ty2]) right_id) e
 511
 512         -- Prefix each tuple with a distinct series of Left's and Right's,
 513         -- in a balanced way, keeping track of the types.
 514
 515         merge_branches (fvs1, builds1, in_ty1, core_exp1)
 516                        (fvs2, builds2, in_ty2, core_exp2)
 517           = (fvs1 `unionVarSet` fvs2,
 518              map (left_expr in_ty1 in_ty2) builds1 ++
 519                 map (right_expr in_ty1 in_ty2) builds2,
 520              mkTyConApp either_con [in_ty1, in_ty2],
 521              do_choice ids in_ty1 in_ty2 res_ty core_exp1 core_exp2)
 522         (fvs_alts, leaves', sum_ty, core_choices)
 523           = foldb merge_branches branches
 524
 525         -- Replace the commands in the case with these tagged tuples,
 526         -- yielding a HsExpr Id we can feed to dsExpr.
 527
 528         (_, matches') = mapAccumL (replaceLeavesMatch res_ty) leaves' matches
 529         in_ty = envStackType env_ids stack
 530         fvs_exp = exprFreeVars core_exp `intersectVarSet` local_vars
 531
 532         pat_ty    = funArgTy match_ty
 533         match_ty' = mkFunTy pat_ty sum_ty
 534         -- Note that we replace the HsCase result type by sum_ty,
 535         -- which is the type of matches'
 536     in
 537     dsExpr (HsCase exp (MatchGroup matches' match_ty')) `thenDs` \ core_body ->
 538     matchEnvStack env_ids stack_ids core_body
 539                                         `thenDs` \ core_matches ->
 540     returnDs(do_map_arrow ids in_ty sum_ty res_ty core_matches core_choices,
 541              fvs_exp `unionVarSet` fvs_alts)
 542
 543 --      A | ys |- c :: [ts] t
 544 --      ----------------------------------
 545 --      A | xs |- let binds in c :: [ts] t
 546 --
 547 --              ---> arr (\ ((xs)*ts) -> let binds in ((ys)*ts)) >>> c
 548
 549 dsCmd ids local_vars env_ids stack res_ty (HsLet binds body)
 550   = let
 551         defined_vars = mkVarSet (map unLoc (collectLocalBinders binds))
 552         local_vars' = local_vars `unionVarSet` defined_vars
 553     in
 554     dsfixCmd ids local_vars' stack res_ty body
 555                                 `thenDs` \ (core_body, free_vars, env_ids') ->
 556     mappM newSysLocalDs stack           `thenDs` \ stack_ids ->
 557     -- build a new environment, plus the stack, using the let bindings
 558     dsLocalBinds binds (buildEnvStack env_ids' stack_ids)
 559                                         `thenDs` \ core_binds ->
 560     -- match the old environment and stack against the input
 561     matchEnvStack env_ids stack_ids core_binds
 562                                         `thenDs` \ core_map ->
 563     returnDs (do_map_arrow ids
 564                         (envStackType env_ids stack)
 565                         (envStackType env_ids' stack)
 566                         res_ty
 567                         core_map
 568                         core_body,
 569         exprFreeVars core_binds `intersectVarSet` local_vars)
 570
 571 dsCmd ids local_vars env_ids [] res_ty (HsDo _ctxt stmts body _)
 572   = dsCmdDo ids local_vars env_ids res_ty stmts body
 573
 574 --      A |- e :: forall e. a1 (e*ts1) t1 -> ... an (e*tsn) tn -> a (e*ts) t
 575 --      A | xs |- ci :: [tsi] ti
 576 --      -----------------------------------
 577 --      A | xs |- (|e c1 ... cn|) :: [ts] t     ---> e [t_xs] c1 ... cn
 578
 579 dsCmd _ids local_vars env_ids _stack _res_ty (HsArrForm op _ args)
 580   = let
 581         env_ty = mkTupleType env_ids
 582     in
 583     dsLExpr op                          `thenDs` \ core_op ->
 584     mapAndUnzipDs (dsTrimCmdArg local_vars env_ids) args
 585                                         `thenDs` \ (core_args, fv_sets) ->
 586     returnDs (mkApps (App core_op (Type env_ty)) core_args,
 587               unionVarSets fv_sets)
 588
 589
 590 dsCmd ids local_vars env_ids stack res_ty (HsTick ix vars expr)
 591   = dsLCmd ids local_vars env_ids stack res_ty expr `thenDs` \ (expr1,id_set) ->
 592     mkTickBox ix vars expr1                         `thenDs` \ expr2 ->
 593     return (expr2,id_set)
 594
 595 --      A | ys |- c :: [ts] t   (ys <= xs)
 596 --      ---------------------
 597 --      A | xs |- c :: [ts] t   ---> arr_ts (\ (xs) -> (ys)) >>> c
 598
 599 dsTrimCmdArg
 600         :: IdSet                -- set of local vars available to this command
 601         -> [Id]                 -- list of vars in the input to this command
 602         -> LHsCmdTop Id -- command argument to desugar
 603         -> DsM (CoreExpr,       -- desugared expression
 604                 IdSet)          -- set of local vars that occur free
 605 dsTrimCmdArg local_vars env_ids (L _ (HsCmdTop cmd stack cmd_ty ids))
 606   = mkCmdEnv ids                        `thenDs` \ meth_ids ->
 607     dsfixCmd meth_ids local_vars stack cmd_ty cmd
 608                                 `thenDs` \ (core_cmd, free_vars, env_ids') ->
 609     mappM newSysLocalDs stack           `thenDs` \ stack_ids ->
 610     matchEnvStack env_ids stack_ids (buildEnvStack env_ids' stack_ids)
 611                                         `thenDs` \ trim_code ->
 612     let
 613         in_ty = envStackType env_ids stack
 614         in_ty' = envStackType env_ids' stack
 615         arg_code = if env_ids' == env_ids then core_cmd else
 616                 do_map_arrow meth_ids in_ty in_ty' cmd_ty trim_code core_cmd
 617     in
 618     returnDs (bindCmdEnv meth_ids arg_code, free_vars)
 619
 620 -- Given A | xs |- c :: [ts] t, builds c with xs fed back.
 621 -- Typically needs to be prefixed with arr (\p -> ((xs)*ts))
 622
 623 dsfixCmd
 624         :: DsCmdEnv             -- arrow combinators
 625         -> IdSet                -- set of local vars available to this command
 626         -> [Type]               -- type of the stack
 627         -> Type                 -- return type of the command
 628         -> LHsCmd Id            -- command to desugar
 629         -> DsM (CoreExpr,       -- desugared expression
 630                 IdSet,          -- set of local vars that occur free
 631                 [Id])           -- set as a list, fed back
 632 dsfixCmd ids local_vars stack cmd_ty cmd
 633   = fixDs (\ ~(_,_,env_ids') ->
 634         dsLCmd ids local_vars env_ids' stack cmd_ty cmd
 635                                         `thenDs` \ (core_cmd, free_vars) ->
 636         returnDs (core_cmd, free_vars, varSetElems free_vars))
 637
 638 \end{code}
 639
 640 Translation of command judgements of the form
 641
 642         A | xs |- do { ss } :: [] t
 643
 644 \begin{code}
 645
 646 dsCmdDo :: DsCmdEnv             -- arrow combinators
 647         -> IdSet                -- set of local vars available to this statement
 648         -> [Id]                 -- list of vars in the input to this statement
 649                                 -- This is typically fed back,
 650                                 -- so don't pull on it too early
 651         -> Type                 -- return type of the statement
 652         -> [LStmt Id]           -- statements to desugar
 653         -> LHsExpr Id           -- body
 654         -> DsM (CoreExpr,       -- desugared expression
 655                 IdSet)          -- set of local vars that occur free
 656
 657 --      A | xs |- c :: [] t
 658 --      --------------------------
 659 --      A | xs |- do { c } :: [] t
 660
 661 dsCmdDo ids local_vars env_ids res_ty [] body
 662   = dsLCmd ids local_vars env_ids [] res_ty body
 663
 664 dsCmdDo ids local_vars env_ids res_ty (stmt:stmts) body
 665   = let
 666         bound_vars = mkVarSet (map unLoc (collectLStmtBinders stmt))
 667         local_vars' = local_vars `unionVarSet` bound_vars
 668     in
 669     fixDs (\ ~(_,_,env_ids') ->
 670         dsCmdDo ids local_vars' env_ids' res_ty stmts body
 671                                         `thenDs` \ (core_stmts, fv_stmts) ->
 672         returnDs (core_stmts, fv_stmts, varSetElems fv_stmts))
 673                                 `thenDs` \ (core_stmts, fv_stmts, env_ids') ->
 674     dsCmdLStmt ids local_vars env_ids env_ids' stmt
 675                                 `thenDs` \ (core_stmt, fv_stmt) ->
 676     returnDs (do_compose ids
 677                 (mkTupleType env_ids)
 678                 (mkTupleType env_ids')
 679                 res_ty
 680                 core_stmt
 681                 core_stmts,
 682               fv_stmt)
 683
 684 \end{code}
 685 A statement maps one local environment to another, and is represented
 686 as an arrow from one tuple type to another.  A statement sequence is
 687 translated to a composition of such arrows.
 688 \begin{code}
 689 dsCmdLStmt ids local_vars env_ids out_ids cmd
 690   = dsCmdStmt ids local_vars env_ids out_ids (unLoc cmd)
 691
 692 dsCmdStmt
 693         :: DsCmdEnv             -- arrow combinators
 694         -> IdSet                -- set of local vars available to this statement
 695         -> [Id]                 -- list of vars in the input to this statement
 696                                 -- This is typically fed back,
 697                                 -- so don't pull on it too early
 698         -> [Id]                 -- list of vars in the output of this statement
 699         -> Stmt Id      -- statement to desugar
 700         -> DsM (CoreExpr,       -- desugared expression
 701                 IdSet)          -- set of local vars that occur free
 702
 703 --      A | xs1 |- c :: [] t
 704 --      A | xs' |- do { ss } :: [] t'
 705 --      ------------------------------
 706 --      A | xs |- do { c; ss } :: [] t'
 707 --
 708 --              ---> arr (\ (xs) -> ((xs1),(xs'))) >>> first c >>>
 709 --                      arr snd >>> ss
 710
 711 dsCmdStmt ids local_vars env_ids out_ids (ExprStmt cmd _ c_ty)
 712   = dsfixCmd ids local_vars [] c_ty cmd
 713                                 `thenDs` \ (core_cmd, fv_cmd, env_ids1) ->
 714     matchEnvStack env_ids []
 715         (mkCorePairExpr (mkTupleExpr env_ids1) (mkTupleExpr out_ids))
 716                                         `thenDs` \ core_mux ->
 717     let
 718         in_ty = mkTupleType env_ids
 719         in_ty1 = mkTupleType env_ids1
 720         out_ty = mkTupleType out_ids
 721         before_c_ty = mkCorePairTy in_ty1 out_ty
 722         after_c_ty = mkCorePairTy c_ty out_ty
 723     in
 724     mkSndExpr c_ty out_ty               `thenDs` \ snd_fn ->
 725     returnDs (do_map_arrow ids in_ty before_c_ty out_ty core_mux $
 726                 do_compose ids before_c_ty after_c_ty out_ty
 727                         (do_first ids in_ty1 c_ty out_ty core_cmd) $
 728                 do_arr ids after_c_ty out_ty snd_fn,
 729               extendVarSetList fv_cmd out_ids)
 730   where
 731
 732 --      A | xs1 |- c :: [] t
 733 --      A | xs' |- do { ss } :: [] t'           xs2 = xs' - defs(p)
 734 --      -----------------------------------
 735 --      A | xs |- do { p <- c; ss } :: [] t'
 736 --
 737 --              ---> arr (\ (xs) -> ((xs1),(xs2))) >>> first c >>>
 738 --                      arr (\ (p, (xs2)) -> (xs')) >>> ss
 739 --
 740 -- It would be simpler and more consistent to do this using second,
 741 -- but that's likely to be defined in terms of first.
 742
 743 dsCmdStmt ids local_vars env_ids out_ids (BindStmt pat cmd _ _)
 744   = dsfixCmd ids local_vars [] (hsLPatType pat) cmd
 745                                 `thenDs` \ (core_cmd, fv_cmd, env_ids1) ->
 746     let
 747         pat_ty = hsLPatType pat
 748         pat_vars = mkVarSet (collectPatBinders pat)
 749         env_ids2 = varSetElems (mkVarSet out_ids `minusVarSet` pat_vars)
 750         env_ty2 = mkTupleType env_ids2
 751     in
 752
 753     -- multiplexing function
 754     --          \ (xs) -> ((xs1),(xs2))
 755
 756     matchEnvStack env_ids []
 757         (mkCorePairExpr (mkTupleExpr env_ids1) (mkTupleExpr env_ids2))
 758                                         `thenDs` \ core_mux ->
 759
 760     -- projection function
 761     --          \ (p, (xs2)) -> (zs)
 762
 763     newSysLocalDs env_ty2               `thenDs` \ env_id ->
 764     newUniqueSupply                     `thenDs` \ uniqs ->
 765     let
 766         after_c_ty = mkCorePairTy pat_ty env_ty2
 767         out_ty = mkTupleType out_ids
 768         body_expr = coreCaseTuple uniqs env_id env_ids2 (mkTupleExpr out_ids)
 769     in
 770     mkFailExpr (StmtCtxt DoExpr) out_ty `thenDs` \ fail_expr ->
 771     selectSimpleMatchVarL pat           `thenDs` \ pat_id ->
 772     matchSimply (Var pat_id) (StmtCtxt DoExpr) pat body_expr fail_expr
 773                                         `thenDs` \ match_code ->
 774     newSysLocalDs after_c_ty            `thenDs` \ pair_id ->
 775     let
 776         proj_expr = Lam pair_id (coreCasePair pair_id pat_id env_id match_code)
 777     in
 778
 779     -- put it all together
 780     let
 781         in_ty = mkTupleType env_ids
 782         in_ty1 = mkTupleType env_ids1
 783         in_ty2 = mkTupleType env_ids2
 784         before_c_ty = mkCorePairTy in_ty1 in_ty2
 785     in
 786     returnDs (do_map_arrow ids in_ty before_c_ty out_ty core_mux $
 787                 do_compose ids before_c_ty after_c_ty out_ty
 788                         (do_first ids in_ty1 pat_ty in_ty2 core_cmd) $
 789                 do_arr ids after_c_ty out_ty proj_expr,
 790               fv_cmd `unionVarSet` (mkVarSet out_ids `minusVarSet` pat_vars))
 791
 792 --      A | xs' |- do { ss } :: [] t
 793 --      --------------------------------------
 794 --      A | xs |- do { let binds; ss } :: [] t
 795 --
 796 --              ---> arr (\ (xs) -> let binds in (xs')) >>> ss
 797
 798 dsCmdStmt ids local_vars env_ids out_ids (LetStmt binds)
 799     -- build a new environment using the let bindings
 800   = dsLocalBinds binds (mkTupleExpr out_ids)    `thenDs` \ core_binds ->
 801     -- match the old environment against the input
 802     matchEnvStack env_ids [] core_binds `thenDs` \ core_map ->
 803     returnDs (do_arr ids
 804                         (mkTupleType env_ids)
 805                         (mkTupleType out_ids)
 806                         core_map,
 807         exprFreeVars core_binds `intersectVarSet` local_vars)
 808
 809 --      A | ys |- do { ss; returnA -< ((xs1), (ys2)) } :: [] ...
 810 --      A | xs' |- do { ss' } :: [] t
 811 --      ------------------------------------
 812 --      A | xs |- do { rec ss; ss' } :: [] t
 813 --
 814 --                      xs1 = xs' /\ defs(ss)
 815 --                      xs2 = xs' - defs(ss)
 816 --                      ys1 = ys - defs(ss)
 817 --                      ys2 = ys /\ defs(ss)
 818 --
 819 --              ---> arr (\(xs) -> ((ys1),(xs2))) >>>
 820 --                      first (loop (arr (\((ys1),~(ys2)) -> (ys)) >>> ss)) >>>
 821 --                      arr (\((xs1),(xs2)) -> (xs')) >>> ss'
 822
 823 dsCmdStmt ids local_vars env_ids out_ids (RecStmt stmts later_ids rec_ids rhss binds)
 824   = let         -- ToDo: ****** binds not desugared; ROSS PLEASE FIX ********
 825         env2_id_set = mkVarSet out_ids `minusVarSet` mkVarSet later_ids
 826         env2_ids = varSetElems env2_id_set
 827         env2_ty = mkTupleType env2_ids
 828     in
 829
 830     -- post_loop_fn = \((later_ids),(env2_ids)) -> (out_ids)
 831
 832     newUniqueSupply             `thenDs` \ uniqs ->
 833     newSysLocalDs env2_ty       `thenDs` \ env2_id ->
 834     let
 835         later_ty = mkTupleType later_ids
 836         post_pair_ty = mkCorePairTy later_ty env2_ty
 837         post_loop_body = coreCaseTuple uniqs env2_id env2_ids (mkTupleExpr out_ids)
 838     in
 839     matchEnvStack later_ids [env2_id] post_loop_body
 840                                 `thenDs` \ post_loop_fn ->
 841
 842     --- loop (...)
 843
 844     dsRecCmd ids local_vars stmts later_ids rec_ids rhss
 845                                 `thenDs` \ (core_loop, env1_id_set, env1_ids) ->
 846
 847     -- pre_loop_fn = \(env_ids) -> ((env1_ids),(env2_ids))
 848
 849     let
 850         env1_ty = mkTupleType env1_ids
 851         pre_pair_ty = mkCorePairTy env1_ty env2_ty
 852         pre_loop_body = mkCorePairExpr (mkTupleExpr env1_ids)
 853                                         (mkTupleExpr env2_ids)
 854
 855     in
 856     matchEnvStack env_ids [] pre_loop_body
 857                                 `thenDs` \ pre_loop_fn ->
 858
 859     -- arr pre_loop_fn >>> first (loop (...)) >>> arr post_loop_fn
 860
 861     let
 862         env_ty = mkTupleType env_ids
 863         out_ty = mkTupleType out_ids
 864         core_body = do_map_arrow ids env_ty pre_pair_ty out_ty
 865                 pre_loop_fn
 866                 (do_compose ids pre_pair_ty post_pair_ty out_ty
 867                         (do_first ids env1_ty later_ty env2_ty
 868                                 core_loop)
 869                         (do_arr ids post_pair_ty out_ty
 870                                 post_loop_fn))
 871     in
 872     returnDs (core_body, env1_id_set `unionVarSet` env2_id_set)
 873
 874 --      loop (arr (\ ((env1_ids), ~(rec_ids)) -> (env_ids)) >>>
 875 --            ss >>>
 876 --            arr (\ (out_ids) -> ((later_ids),(rhss))) >>>
 877
 878 dsRecCmd ids local_vars stmts later_ids rec_ids rhss
 879   = let
 880         rec_id_set = mkVarSet rec_ids
 881         out_ids = varSetElems (mkVarSet later_ids `unionVarSet` rec_id_set)
 882         out_ty = mkTupleType out_ids
 883         local_vars' = local_vars `unionVarSet` rec_id_set
 884     in
 885
 886     -- mk_pair_fn = \ (out_ids) -> ((later_ids),(rhss))
 887
 888     mappM dsExpr rhss           `thenDs` \ core_rhss ->
 889     let
 890         later_tuple = mkTupleExpr later_ids
 891         later_ty = mkTupleType later_ids
 892         rec_tuple = mkBigCoreTup core_rhss
 893         rec_ty = mkTupleType rec_ids
 894         out_pair = mkCorePairExpr later_tuple rec_tuple
 895         out_pair_ty = mkCorePairTy later_ty rec_ty
 896     in
 897         matchEnvStack out_ids [] out_pair
 898                                 `thenDs` \ mk_pair_fn ->
 899
 900     -- ss
 901
 902     dsfixCmdStmts ids local_vars' out_ids stmts
 903                                 `thenDs` \ (core_stmts, fv_stmts, env_ids) ->
 904
 905     -- squash_pair_fn = \ ((env1_ids), ~(rec_ids)) -> (env_ids)
 906
 907     newSysLocalDs rec_ty        `thenDs` \ rec_id ->
 908     let
 909         env1_id_set = fv_stmts `minusVarSet` rec_id_set
 910         env1_ids = varSetElems env1_id_set
 911         env1_ty = mkTupleType env1_ids
 912         in_pair_ty = mkCorePairTy env1_ty rec_ty
 913         core_body = mkBigCoreTup (map selectVar env_ids)
 914           where
 915             selectVar v
 916                 | v `elemVarSet` rec_id_set
 917                   = mkTupleSelector rec_ids v rec_id (Var rec_id)
 918                 | otherwise = Var v
 919     in
 920     matchEnvStack env1_ids [rec_id] core_body
 921                                 `thenDs` \ squash_pair_fn ->
 922
 923     -- loop (arr squash_pair_fn >>> ss >>> arr mk_pair_fn)
 924
 925     let
 926         env_ty = mkTupleType env_ids
 927         core_loop = do_loop ids env1_ty later_ty rec_ty
 928                 (do_map_arrow ids in_pair_ty env_ty out_pair_ty
 929                         squash_pair_fn
 930                         (do_compose ids env_ty out_ty out_pair_ty
 931                                 core_stmts
 932                                 (do_arr ids out_ty out_pair_ty mk_pair_fn)))
 933     in
 934     returnDs (core_loop, env1_id_set, env1_ids)
 935
 936 \end{code}
 937 A sequence of statements (as in a rec) is desugared to an arrow between
 938 two environments
 939 \begin{code}
 940
 941 dsfixCmdStmts
 942         :: DsCmdEnv             -- arrow combinators
 943         -> IdSet                -- set of local vars available to this statement
 944         -> [Id]                 -- output vars of these statements
 945         -> [LStmt Id]   -- statements to desugar
 946         -> DsM (CoreExpr,       -- desugared expression
 947                 IdSet,          -- set of local vars that occur free
 948                 [Id])           -- input vars
 949
 950 dsfixCmdStmts ids local_vars out_ids stmts
 951   = fixDs (\ ~(_,_,env_ids) ->
 952         dsCmdStmts ids local_vars env_ids out_ids stmts
 953                                         `thenDs` \ (core_stmts, fv_stmts) ->
 954         returnDs (core_stmts, fv_stmts, varSetElems fv_stmts))
 955
 956 dsCmdStmts
 957         :: DsCmdEnv             -- arrow combinators
 958         -> IdSet                -- set of local vars available to this statement
 959         -> [Id]                 -- list of vars in the input to these statements
 960         -> [Id]                 -- output vars of these statements
 961         -> [LStmt Id]   -- statements to desugar
 962         -> DsM (CoreExpr,       -- desugared expression
 963                 IdSet)          -- set of local vars that occur free
 964
 965 dsCmdStmts ids local_vars env_ids out_ids [stmt]
 966   = dsCmdLStmt ids local_vars env_ids out_ids stmt
 967
 968 dsCmdStmts ids local_vars env_ids out_ids (stmt:stmts)
 969   = let
 970         bound_vars = mkVarSet (map unLoc (collectLStmtBinders stmt))
 971         local_vars' = local_vars `unionVarSet` bound_vars
 972     in
 973     dsfixCmdStmts ids local_vars' out_ids stmts
 974                                 `thenDs` \ (core_stmts, fv_stmts, env_ids') ->
 975     dsCmdLStmt ids local_vars env_ids env_ids' stmt
 976                                 `thenDs` \ (core_stmt, fv_stmt) ->
 977     returnDs (do_compose ids
 978                 (mkTupleType env_ids)
 979                 (mkTupleType env_ids')
 980                 (mkTupleType out_ids)
 981                 core_stmt
 982                 core_stmts,
 983               fv_stmt)
 984
 985 \end{code}
 986
 987 Match a list of expressions against a list of patterns, left-to-right.
 988
 989 \begin{code}
 990 matchSimplys :: [CoreExpr]              -- Scrutinees
 991              -> HsMatchContext Name     -- Match kind
 992              -> [LPat Id]               -- Patterns they should match
 993              -> CoreExpr                -- Return this if they all match
 994              -> CoreExpr                -- Return this if they don't
 995              -> DsM CoreExpr
 996 matchSimplys [] _ctxt [] result_expr _fail_expr = returnDs result_expr
 997 matchSimplys (exp:exps) ctxt (pat:pats) result_expr fail_expr
 998   = matchSimplys exps ctxt pats result_expr fail_expr
 999                                         `thenDs` \ match_code ->
1000     matchSimply exp ctxt pat match_code fail_expr
1001 \end{code}
1002
1003 List of leaf expressions, with set of variables bound in each
1004
1005 \begin{code}
1006 leavesMatch :: LMatch Id -> [(LHsExpr Id, IdSet)]
1007 leavesMatch (L _ (Match pats _ (GRHSs grhss binds)))
1008   = let
1009         defined_vars = mkVarSet (collectPatsBinders pats)
1010                         `unionVarSet`
1011                        mkVarSet (map unLoc (collectLocalBinders binds))
1012     in
1013     [(expr,
1014       mkVarSet (map unLoc (collectLStmtsBinders stmts))
1015         `unionVarSet` defined_vars)
1016     | L _ (GRHS stmts expr) <- grhss]
1017 \end{code}
1018
1019 Replace the leaf commands in a match
1020
1021 \begin{code}
1022 replaceLeavesMatch
1023         :: Type                 -- new result type
1024         -> [LHsExpr Id] -- replacement leaf expressions of that type
1025         -> LMatch Id    -- the matches of a case command
1026         -> ([LHsExpr Id],-- remaining leaf expressions
1027             LMatch Id)  -- updated match
1028 replaceLeavesMatch res_ty leaves (L loc (Match pat mt (GRHSs grhss binds)))
1029   = let
1030         (leaves', grhss') = mapAccumL replaceLeavesGRHS leaves grhss
1031     in
1032     (leaves', L loc (Match pat mt (GRHSs grhss' binds)))
1033
1034 replaceLeavesGRHS
1035         :: [LHsExpr Id] -- replacement leaf expressions of that type
1036         -> LGRHS Id     -- rhss of a case command
1037         -> ([LHsExpr Id],-- remaining leaf expressions
1038             LGRHS Id)   -- updated GRHS
1039 replaceLeavesGRHS (leaf:leaves) (L loc (GRHS stmts rhs))
1040   = (leaves, L loc (GRHS stmts leaf))
1041 \end{code}
1042
1043 Balanced fold of a non-empty list.
1044
1045 \begin{code}
1046 foldb :: (a -> a -> a) -> [a] -> a
1047 foldb _ [] = error "foldb of empty list"
1048 foldb _ [x] = x
1049 foldb f xs = foldb f (fold_pairs xs)
1050   where
1051     fold_pairs [] = []
1052     fold_pairs [x] = [x]
1053     fold_pairs (x1:x2:xs) = f x1 x2:fold_pairs xs
1054 \end{code}