compiler/deSugar/DsBinds.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Pattern-matching bindings (HsBinds and MonoBinds)
   7
   8 Handles @HsBinds@; those at the top level require different handling,
   9 in that the @Rec@/@NonRec@/etc structure is thrown away (whereas at
  10 lower levels it is preserved with @let@/@letrec@s).
  11
  12 \begin{code}
  13 {-# OPTIONS -w #-}
  14 -- The above warning supression flag is a temporary kludge.
  15 -- While working on this module you are encouraged to remove it and fix
  16 -- any warnings in the module. See
  17 --     http://hackage.haskell.org/trac/ghc/wiki/CodingStyle#Warnings
  18 -- for details
  19
  20 module DsBinds ( dsTopLHsBinds, dsLHsBinds, decomposeRuleLhs,
  21                  dsCoercion,
  22                  AutoScc(..)
  23   ) where
  24
  25 #include "HsVersions.h"
  26
  27 import {-# SOURCE #-}   DsExpr( dsLExpr, dsExpr )
  28 import {-# SOURCE #-}   Match( matchWrapper )
  29
  30 import DsMonad
  31 import DsGRHSs
  32 import DsUtils
  33
  34 import HsSyn            -- lots of things
  35 import CoreSyn          -- lots of things
  36 import CoreUtils
  37
  38 import TcHsSyn          ( mkArbitraryType )     -- Mis-placed?
  39 import TcType
  40 import OccurAnal
  41 import CostCentre
  42 import Module
  43 import Id
  44 import Var      ( TyVar )
  45 import Rules
  46 import VarEnv
  47 import Type
  48 import Outputable
  49 import SrcLoc
  50 import Maybes
  51 import Bag
  52 import BasicTypes hiding ( TopLevel )
  53 import FastString
  54 import Util             ( mapSnd )
  55
  56 import Control.Monad
  57 import Data.List
  58 \end{code}
  59
  60 %************************************************************************
  61 %*                                                                      *
  62 \subsection[dsMonoBinds]{Desugaring a @MonoBinds@}
  63 %*                                                                      *
  64 %************************************************************************
  65
  66 \begin{code}
  67 dsTopLHsBinds :: AutoScc -> LHsBinds Id -> DsM [(Id,CoreExpr)]
  68 dsTopLHsBinds auto_scc binds = ds_lhs_binds auto_scc binds
  69
  70 dsLHsBinds :: LHsBinds Id -> DsM [(Id,CoreExpr)]
  71 dsLHsBinds binds = ds_lhs_binds NoSccs binds
  72
  73
  74 ------------------------
  75 ds_lhs_binds :: AutoScc -> LHsBinds Id -> DsM [(Id,CoreExpr)]
  76          -- scc annotation policy (see below)
  77 ds_lhs_binds auto_scc binds =  foldM (dsLHsBind auto_scc) [] (bagToList binds)
  78
  79 dsLHsBind :: AutoScc
  80          -> [(Id,CoreExpr)]     -- Put this on the end (avoid quadratic append)
  81          -> LHsBind Id
  82          -> DsM [(Id,CoreExpr)] -- Result
  83 dsLHsBind auto_scc rest (L loc bind)
  84   = putSrcSpanDs loc $ dsHsBind auto_scc rest bind
  85
  86 dsHsBind :: AutoScc
  87          -> [(Id,CoreExpr)]     -- Put this on the end (avoid quadratic append)
  88          -> HsBind Id
  89          -> DsM [(Id,CoreExpr)] -- Result
  90
  91 dsHsBind auto_scc rest (VarBind var expr)
  92   = dsLExpr expr                `thenDs` \ core_expr ->
  93
  94         -- Dictionary bindings are always VarMonoBinds, so
  95         -- we only need do this here
  96     addDictScc var core_expr    `thenDs` \ core_expr' ->
  97     returnDs ((var, core_expr') : rest)
  98
  99 dsHsBind auto_scc rest (FunBind { fun_id = L _ fun, fun_matches = matches,
 100                                   fun_co_fn = co_fn, fun_tick = tick, fun_infix = inf })
 101   = matchWrapper (FunRhs (idName fun) inf) matches      `thenDs` \ (args, body) ->
 102     mkOptTickBox tick body                              `thenDs` \ body' ->
 103     dsCoercion co_fn (return (mkLams args body'))       `thenDs` \ rhs ->
 104     returnDs ((fun,rhs) : rest)
 105
 106 dsHsBind auto_scc rest (PatBind { pat_lhs = pat, pat_rhs = grhss, pat_rhs_ty = ty })
 107   = dsGuarded grhss ty                          `thenDs` \ body_expr ->
 108     mkSelectorBinds pat body_expr               `thenDs` \ sel_binds ->
 109     returnDs (sel_binds ++ rest)
 110
 111 -- Note [Rules and inlining]
 112 -- Common special case: no type or dictionary abstraction
 113 -- This is a bit less trivial than you might suppose
 114 -- The naive way woudl be to desguar to something like
 115 --      f_lcl = ...f_lcl...     -- The "binds" from AbsBinds
 116 --      M.f = f_lcl             -- Generated from "exports"
 117 -- But we don't want that, because if M.f isn't exported,
 118 -- it'll be inlined unconditionally at every call site (its rhs is
 119 -- trivial).  That would be ok unless it has RULES, which would
 120 -- thereby be completely lost.  Bad, bad, bad.
 121 --
 122 -- Instead we want to generate
 123 --      M.f = ...f_lcl...
 124 --      f_lcl = M.f
 125 -- Now all is cool. The RULES are attached to M.f (by SimplCore),
 126 -- and f_lcl is rapidly inlined away.
 127 --
 128 -- This does not happen in the same way to polymorphic binds,
 129 -- because they desugar to
 130 --      M.f = /\a. let f_lcl = ...f_lcl... in f_lcl
 131 -- Although I'm a bit worried about whether full laziness might
 132 -- float the f_lcl binding out and then inline M.f at its call site
 133
 134 dsHsBind auto_scc rest (AbsBinds [] [] exports binds)
 135   = do  { core_prs <- ds_lhs_binds NoSccs binds
 136         ; let env = mkABEnv exports
 137               do_one (lcl_id, rhs) | Just (gbl_id, prags) <- lookupVarEnv env lcl_id
 138                                    = addInlinePrags prags gbl_id $
 139                                      addAutoScc auto_scc gbl_id rhs
 140                                    | otherwise = (lcl_id, rhs)
 141               locals'  = [(lcl_id, Var gbl_id) | (_, gbl_id, lcl_id, _) <- exports]
 142         ; return (map do_one core_prs ++ locals' ++ rest) }
 143                 -- No Rec needed here (contrast the other AbsBinds cases)
 144                 -- because we can rely on the enclosing dsBind to wrap in Rec
 145
 146         -- Another common case: one exported variable
 147         -- Non-recursive bindings come through this way
 148 dsHsBind auto_scc rest
 149      (AbsBinds all_tyvars dicts exports@[(tyvars, global, local, prags)] binds)
 150   = ASSERT( all (`elem` tyvars) all_tyvars )
 151     ds_lhs_binds NoSccs binds   `thenDs` \ core_prs ->
 152     let
 153         -- Always treat the binds as recursive, because the typechecker
 154         -- makes rather mixed-up dictionary bindings
 155         core_bind = Rec core_prs
 156     in
 157     mappM (dsSpec all_tyvars dicts tyvars global local core_bind)
 158           prags                         `thenDs` \ mb_specs ->
 159     let
 160         (spec_binds, rules) = unzip (catMaybes mb_specs)
 161         global' = addIdSpecialisations global rules
 162         rhs'    = mkLams tyvars $ mkLams dicts $ Let core_bind (Var local)
 163         bind    = addInlinePrags prags global' $ addAutoScc auto_scc global' rhs'
 164     in
 165     returnDs (bind  : spec_binds ++ rest)
 166
 167 dsHsBind auto_scc rest (AbsBinds all_tyvars dicts exports binds)
 168   = do  { core_prs <- ds_lhs_binds NoSccs binds
 169         ; let env = mkABEnv exports
 170               do_one (lcl_id,rhs) | Just (gbl_id, prags) <- lookupVarEnv env lcl_id
 171                                   = addInlinePrags prags lcl_id $
 172                                     addAutoScc auto_scc gbl_id rhs
 173                                   | otherwise = (lcl_id,rhs)
 174
 175                 -- Rec because of mixed-up dictionary bindings
 176               core_bind = Rec (map do_one core_prs)
 177
 178               tup_expr      = mkTupleExpr locals
 179               tup_ty        = exprType tup_expr
 180               poly_tup_expr = mkLams all_tyvars $ mkLams dicts $
 181                               Let core_bind tup_expr
 182               locals        = [local | (_, _, local, _) <- exports]
 183               local_tys     = map idType locals
 184
 185         ; poly_tup_id <- newSysLocalDs (exprType poly_tup_expr)
 186
 187         ; let dict_args = map Var dicts
 188
 189               mk_bind ((tyvars, global, local, prags), n)       -- locals !! n == local
 190                 =       -- Need to make fresh locals to bind in the selector, because
 191                         -- some of the tyvars will be bound to 'Any'
 192                   do { locals' <- newSysLocalsDs (map substitute local_tys)
 193                      ; tup_id  <- newSysLocalDs  (substitute tup_ty)
 194                      ; mb_specs <- mapM (dsSpec all_tyvars dicts tyvars global local core_bind)
 195                                          prags
 196                      ; let (spec_binds, rules) = unzip (catMaybes mb_specs)
 197                            global' = addIdSpecialisations global rules
 198                            rhs = mkLams tyvars $ mkLams dicts $
 199                                  mkTupleSelector locals' (locals' !! n) tup_id $
 200                                  mkApps (mkTyApps (Var poly_tup_id) ty_args) dict_args
 201                      ; returnDs ((global', rhs) : spec_binds) }
 202                 where
 203                   mk_ty_arg all_tyvar | all_tyvar `elem` tyvars = mkTyVarTy all_tyvar
 204                                       | otherwise               = mkArbitraryType all_tyvar
 205                   ty_args    = map mk_ty_arg all_tyvars
 206                   substitute = substTyWith all_tyvars ty_args
 207
 208         ; export_binds_s <- mappM mk_bind (exports `zip` [0..])
 209              -- don't scc (auto-)annotate the tuple itself.
 210
 211         ; returnDs ((poly_tup_id, poly_tup_expr) :
 212                     (concat export_binds_s ++ rest)) }
 213
 214 mkABEnv :: [([TyVar], Id, Id, [LPrag])] -> VarEnv (Id, [LPrag])
 215 -- Takes the exports of a AbsBinds, and returns a mapping
 216 --      lcl_id -> (gbl_id, prags)
 217 mkABEnv exports = mkVarEnv [ (lcl_id, (gbl_id, prags))
 218                            | (_, gbl_id, lcl_id, prags) <- exports]
 219
 220
 221 dsSpec :: [TyVar] -> [DictId] -> [TyVar]
 222        -> Id -> Id              -- Global, local
 223        -> CoreBind -> LPrag
 224        -> DsM (Maybe ((Id,CoreExpr),    -- Binding for specialised Id
 225                       CoreRule))        -- Rule for the Global Id
 226
 227 -- Example:
 228 --      f :: (Eq a, Ix b) => a -> b -> b
 229 --      {-# SPECIALISE f :: Ix b => Int -> b -> b #-}
 230 --
 231 --      AbsBinds [ab] [d1,d2] [([ab], f, f_mono, prags)] binds
 232 --
 233 --      SpecPrag (/\b.\(d:Ix b). f Int b dInt d)
 234 --               (forall b. Ix b => Int -> b -> b)
 235 --
 236 -- Rule:        forall b,(d:Ix b). f Int b dInt d = f_spec b d
 237 --
 238 -- Spec bind:   f_spec = Let f = /\ab \(d1:Eq a)(d2:Ix b). let binds in f_mono
 239 --                       /\b.\(d:Ix b). in f Int b dInt d
 240 --              The idea is that f occurs just once, so it'll be
 241 --              inlined and specialised
 242 --
 243 -- Given SpecPrag (/\as.\ds. f es) t, we have
 244 -- the defn             f_spec as ds = f es
 245 -- and the RULE         f es = f_spec as ds
 246 --
 247 -- It is *possible* that 'es' does not mention all of the dictionaries 'ds'
 248 -- (a bit silly, because then the
 249 dsSpec all_tvs dicts tvs poly_id mono_id mono_bind (L _ (InlinePrag {}))
 250   = return Nothing
 251
 252 dsSpec all_tvs dicts tvs poly_id mono_id mono_bind
 253        (L loc (SpecPrag spec_expr spec_ty _const_dicts inl))
 254         -- See Note [Const rule dicts]
 255   = putSrcSpanDs loc $
 256     do  { let poly_name = idName poly_id
 257         ; spec_name <- newLocalName poly_name
 258         ; ds_spec_expr  <- dsExpr spec_expr
 259         ; let (bndrs, body) = collectBinders (occurAnalyseExpr ds_spec_expr)
 260                 -- The occurrence-analysis does two things
 261                 -- (a) identifies unused binders: Note [Unused spec binders]
 262                 -- (b) sorts dict bindings into NonRecs
 263                 --      so they can be inlined by decomposeRuleLhs
 264               mb_lhs = decomposeRuleLhs body
 265
 266         -- Check for dead binders: Note [Unused spec binders]
 267         ; case filter isDeadBinder bndrs of {
 268                 bs | not (null bs) -> do { warnDs (dead_msg bs); return Nothing }
 269                    | otherwise ->
 270
 271           case mb_lhs of
 272             Nothing -> do { warnDs decomp_msg; return Nothing }
 273
 274             Just (var, args) -> return (Just (addInlineInfo inl spec_id spec_rhs, rule))
 275                 where
 276                   local_poly  = setIdNotExported poly_id
 277                         -- Very important to make the 'f' non-exported,
 278                         -- else it won't be inlined!
 279                   spec_id     = mkLocalId spec_name spec_ty
 280                   spec_rhs    = Let (NonRec local_poly poly_f_body) ds_spec_expr
 281                   poly_f_body = mkLams (tvs ++ dicts) $
 282                                 fix_up (Let mono_bind (Var mono_id))
 283
 284                   rule =  mkLocalRule (mkFastString ("SPEC " ++ showSDoc (ppr poly_name)))
 285                                 AlwaysActive poly_name
 286                                 bndrs args
 287                                 (mkVarApps (Var spec_id) bndrs)
 288         } }
 289   where
 290         -- Bind to Any any of all_ptvs that aren't
 291         -- relevant for this particular function
 292     fix_up body | null void_tvs = body
 293                 | otherwise     = mkTyApps (mkLams void_tvs body)
 294                                            (map mkArbitraryType void_tvs)
 295     void_tvs = all_tvs \\ tvs
 296
 297     dead_msg bs = vcat [ sep [ptext SLIT("Useless constraint") <> plural bs
 298                                  <+> ptext SLIT("in specialied type:"),
 299                              nest 2 (pprTheta (map get_pred bs))]
 300                        , ptext SLIT("SPECIALISE pragma ignored")]
 301     get_pred b = ASSERT( isId b ) expectJust "dsSpec" (tcSplitPredTy_maybe (idType b))
 302
 303     decomp_msg = hang (ptext SLIT("Specialisation too complicated to desugar; ignored"))
 304                     2 (ppr spec_expr)
 305 \end{code}
 306
 307 Note [Unused spec binders]
 308 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 309 Consider
 310         f :: a -> a
 311         {-# SPECIALISE f :: Eq a => a -> a #-}
 312 It's true that this *is* a more specialised type, but the rule
 313 we get is something like this:
 314         f_spec d = f
 315         RULE: f = f_spec d
 316 Note that the rule is bogus, becuase it mentions a 'd' that is
 317 not bound on the LHS!  But it's a silly specialisation anyway, becuase
 318 the constraint is unused.  We could bind 'd' to (error "unused")
 319 but it seems better to reject the program because it's almost certainly
 320 a mistake.  That's what the isDeadBinder call detects.
 321
 322 Note [Const rule dicts]
 323 ~~~~~~~~~~~~~~~~~~~~~~~
 324 A SpecPrag has a field for "constant dicts" in the RULE, but I think
 325 it's pretty useless.  See the place where it's generated in TcBinds.
 326 TcSimplify will discharge a constraint by binding it to, say,
 327 GHC.Base.$f2 :: Eq Int, withour putting anything in the LIE, so this
 328 dict won't show up in the const-dicts field.  It probably doesn't matter,
 329 because the rule will end up being something like
 330         f Int GHC.Base.$f2 = ...
 331 rather than
 332         forall d. f Int d = ...
 333 The latter is more general, but in practice I think it won't make any
 334 difference.
 335
 336
 337 %************************************************************************
 338 %*                                                                      *
 339 \subsection{Adding inline pragmas}
 340 %*                                                                      *
 341 %************************************************************************
 342
 343 \begin{code}
 344 decomposeRuleLhs :: CoreExpr -> Maybe (Id, [CoreExpr])
 345 -- Returns Nothing if the LHS isn't of the expected shape
 346 decomposeRuleLhs lhs
 347   = go emptyVarEnv (occurAnalyseExpr lhs)       -- Occurrence analysis sorts out the dict
 348                                                 -- bindings so we know if they are recursive
 349   where
 350         -- Substitute dicts in the LHS args, so that there
 351         -- aren't any lets getting in the way
 352         -- Note that we substitute the function too; we might have this as
 353         -- a LHS:       let f71 = M.f Int in f71
 354     go env (Let (NonRec dict rhs) body)
 355         = go (extendVarEnv env dict (simpleSubst env rhs)) body
 356     go env body
 357         = case collectArgs (simpleSubst env body) of
 358             (Var fn, args) -> Just (fn, args)
 359             other          -> Nothing
 360
 361 simpleSubst :: IdEnv CoreExpr -> CoreExpr -> CoreExpr
 362 -- Similar to CoreSubst.substExpr, except that
 363 -- (a) takes no account of capture; dictionary bindings use new names
 364 -- (b) can have a GlobalId (imported) in its domain
 365 -- (c) Ids only; no types are substituted
 366 --
 367 -- (b) is the reason we can't use CoreSubst... and it's no longer relevant
 368 --      so really we should replace simpleSubst
 369 simpleSubst subst expr
 370   = go expr
 371   where
 372     go (Var v)         = lookupVarEnv subst v `orElse` Var v
 373     go (Cast e co)     = Cast (go e) co
 374     go (Type ty)       = Type ty
 375     go (Lit lit)       = Lit lit
 376     go (App fun arg)   = App (go fun) (go arg)
 377     go (Note note e)   = Note note (go e)
 378     go (Lam bndr body) = Lam bndr (go body)
 379     go (Let (NonRec bndr rhs) body) = Let (NonRec bndr (go rhs)) (go body)
 380     go (Let (Rec pairs) body)       = Let (Rec (mapSnd go pairs)) (go body)
 381     go (Case scrut bndr ty alts)    = Case (go scrut) bndr ty
 382                                            [(c,bs,go r) | (c,bs,r) <- alts]
 383
 384 addInlinePrags :: [LPrag] -> Id -> CoreExpr -> (Id,CoreExpr)
 385 addInlinePrags prags bndr rhs
 386   = case [inl | L _ (InlinePrag inl) <- prags] of
 387         []      -> (bndr, rhs)
 388         (inl:_) -> addInlineInfo inl bndr rhs
 389
 390 addInlineInfo :: InlineSpec -> Id -> CoreExpr -> (Id,CoreExpr)
 391 addInlineInfo (Inline phase is_inline) bndr rhs
 392   = (attach_phase bndr phase, wrap_inline is_inline rhs)
 393   where
 394     attach_phase bndr phase
 395         | isAlwaysActive phase = bndr   -- Default phase
 396         | otherwise            = bndr `setInlinePragma` phase
 397
 398     wrap_inline True  body = mkInlineMe body
 399     wrap_inline False body = body
 400 \end{code}
 401
 402
 403 %************************************************************************
 404 %*                                                                      *
 405 \subsection[addAutoScc]{Adding automatic sccs}
 406 %*                                                                      *
 407 %************************************************************************
 408
 409 \begin{code}
 410 data AutoScc = NoSccs
 411              | AddSccs Module (Id -> Bool)
 412 -- The (Id->Bool) says which Ids to add SCCs to
 413
 414 addAutoScc :: AutoScc
 415            -> Id        -- Binder
 416            -> CoreExpr  -- Rhs
 417            -> CoreExpr  -- Scc'd Rhs
 418
 419 addAutoScc NoSccs _ rhs
 420   = rhs
 421 addAutoScc (AddSccs mod add_scc) id rhs
 422   | add_scc id = mkSCC (mkAutoCC id mod NotCafCC) rhs
 423   | otherwise  = rhs
 424 \end{code}
 425
 426 If profiling and dealing with a dict binding,
 427 wrap the dict in @_scc_ DICT <dict>@:
 428
 429 \begin{code}
 430 addDictScc var rhs = returnDs rhs
 431
 432 {- DISABLED for now (need to somehow make up a name for the scc) -- SDM
 433   | not ( opt_SccProfilingOn && opt_AutoSccsOnDicts)
 434     || not (isDictId var)
 435   = returnDs rhs                                -- That's easy: do nothing
 436
 437   | otherwise
 438   = getModuleAndGroupDs         `thenDs` \ (mod, grp) ->
 439         -- ToDo: do -dicts-all flag (mark dict things with individual CCs)
 440     returnDs (Note (SCC (mkAllDictsCC mod grp False)) rhs)
 441 -}
 442 \end{code}
 443
 444
 445 %************************************************************************
 446 %*                                                                      *
 447                 Desugaring coercions
 448 %*                                                                      *
 449 %************************************************************************
 450
 451
 452 \begin{code}
 453 dsCoercion :: HsWrapper -> DsM CoreExpr -> DsM CoreExpr
 454 dsCoercion WpHole            thing_inside = thing_inside
 455 dsCoercion (WpCompose c1 c2) thing_inside = dsCoercion c1 (dsCoercion c2 thing_inside)
 456 dsCoercion (WpCo co)     thing_inside = do { expr <- thing_inside
 457                                                ; return (Cast expr co) }
 458 dsCoercion (WpLam id)        thing_inside = do { expr <- thing_inside
 459                                                ; return (Lam id expr) }
 460 dsCoercion (WpTyLam tv)      thing_inside = do { expr <- thing_inside
 461                                                ; return (Lam tv expr) }
 462 dsCoercion (WpApp id)        thing_inside = do { expr <- thing_inside
 463                                                ; return (App expr (Var id)) }
 464 dsCoercion (WpTyApp ty)      thing_inside = do { expr <- thing_inside
 465                                                ; return (App expr (Type ty)) }
 466 dsCoercion (WpLet bs)        thing_inside = do { prs <- dsLHsBinds bs
 467                                                ; expr <- thing_inside
 468                                                ; return (Let (Rec prs) expr) }
 469 \end{code}