compiler/deSugar/DsExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[DsExpr]{Matching expressions (Exprs)}
   5
   6 \begin{code}
   7 module DsExpr ( dsExpr, dsLExpr, dsLocalBinds, dsValBinds, dsLit ) where
   8
   9 #include "HsVersions.h"
  10 #if defined(GHCI) && defined(BREAKPOINT)
  11 import Foreign.StablePtr ( newStablePtr, castStablePtrToPtr )
  12 import GHC.Exts         ( Ptr(..), Int(..), addr2Int# )
  13 import IOEnv            ( ioToIOEnv )
  14 import PrelNames        ( breakpointJumpName, breakpointCondJumpName )
  15 import TysWiredIn       ( unitTy )
  16 import TypeRep          ( Type(..) )
  17 import TyCon            ( isUnLiftedTyCon )
  18 #endif
  19
  20 import Match            ( matchWrapper, matchSinglePat, matchEquations )
  21 import MatchLit         ( dsLit, dsOverLit )
  22 import DsBinds          ( dsLHsBinds, dsCoercion )
  23 import DsGRHSs          ( dsGuarded )
  24 import DsListComp       ( dsListComp, dsPArrComp )
  25 import DsUtils          ( mkErrorAppDs, mkStringExpr, mkConsExpr, mkNilExpr,
  26                           extractMatchResult, cantFailMatchResult, matchCanFail,
  27                           mkCoreTupTy, selectSimpleMatchVarL, lookupEvidence, selectMatchVar )
  28 import DsArrows         ( dsProcExpr )
  29 import DsMonad
  30
  31 #ifdef GHCI
  32         -- Template Haskell stuff iff bootstrapped
  33 import DsMeta           ( dsBracket )
  34 #endif
  35
  36 import HsSyn
  37 import TcHsSyn          ( hsLPatType, mkVanillaTuplePat )
  38
  39 -- NB: The desugarer, which straddles the source and Core worlds, sometimes
  40 --     needs to see source types (newtypes etc), and sometimes not
  41 --     So WATCH OUT; check each use of split*Ty functions.
  42 -- Sigh.  This is a pain.
  43
  44 import TcType           ( tcSplitAppTy, tcSplitFunTys, tcTyConAppTyCon,
  45                           tcTyConAppArgs, isUnLiftedType, Type, mkAppTy )
  46 import Type             ( splitFunTys, isUnboxedTupleType, mkFunTy )
  47 import CoreSyn
  48 import CoreUtils        ( exprType, mkIfThenElse, bindNonRec )
  49
  50 import CostCentre       ( mkUserCC )
  51 import Id               ( Id, idType, idName, idDataCon )
  52 import PrelInfo         ( rEC_CON_ERROR_ID )
  53 import DataCon          ( DataCon, dataConWrapId, dataConFieldLabels, dataConInstOrigArgTys )
  54 import DataCon          ( isVanillaDataCon )
  55 import TyCon            ( FieldLabel, tyConDataCons )
  56 import TysWiredIn       ( tupleCon )
  57 import BasicTypes       ( RecFlag(..), Boxity(..), ipNameName )
  58 import PrelNames        ( toPName,
  59                           returnMName, bindMName, thenMName, failMName,
  60                           mfixName )
  61 import SrcLoc           ( Located(..), unLoc, getLoc, noLoc )
  62 import Util             ( zipEqual, zipWithEqual )
  63 import Bag              ( bagToList )
  64 import Outputable
  65 import FastString
  66 \end{code}
  67
  68
  69 %************************************************************************
  70 %*                                                                      *
  71                 dsLocalBinds, dsValBinds
  72 %*                                                                      *
  73 %************************************************************************
  74
  75 \begin{code}
  76 dsLocalBinds :: HsLocalBinds Id -> CoreExpr -> DsM CoreExpr
  77 dsLocalBinds EmptyLocalBinds    body = return body
  78 dsLocalBinds (HsValBinds binds) body = dsValBinds binds body
  79 dsLocalBinds (HsIPBinds binds)  body = dsIPBinds  binds body
  80
  81 -------------------------
  82 dsValBinds :: HsValBinds Id -> CoreExpr -> DsM CoreExpr
  83 dsValBinds (ValBindsOut binds _) body = foldrDs ds_val_bind body binds
  84
  85 -------------------------
  86 dsIPBinds (IPBinds ip_binds dict_binds) body
  87   = do  { prs <- dsLHsBinds dict_binds
  88         ; let inner = Let (Rec prs) body
  89                 -- The dict bindings may not be in
  90                 -- dependency order; hence Rec
  91         ; foldrDs ds_ip_bind inner ip_binds }
  92   where
  93     ds_ip_bind (L _ (IPBind n e)) body
  94       = dsLExpr e       `thenDs` \ e' ->
  95         returnDs (Let (NonRec (ipNameName n) e') body)
  96
  97 -------------------------
  98 ds_val_bind :: (RecFlag, LHsBinds Id) -> CoreExpr -> DsM CoreExpr
  99 -- Special case for bindings which bind unlifted variables
 100 -- We need to do a case right away, rather than building
 101 -- a tuple and doing selections.
 102 -- Silently ignore INLINE and SPECIALISE pragmas...
 103 ds_val_bind (NonRecursive, hsbinds) body
 104   | [L _ (AbsBinds [] [] exports binds)] <- bagToList hsbinds,
 105     (L loc bind : null_binds) <- bagToList binds,
 106     isBangHsBind bind
 107     || isUnboxedTupleBind bind
 108     || or [isUnLiftedType (idType g) | (_, g, _, _) <- exports]
 109   = let
 110       body_w_exports                  = foldr bind_export body exports
 111       bind_export (tvs, g, l, _) body = ASSERT( null tvs )
 112                                         bindNonRec g (Var l) body
 113     in
 114     ASSERT (null null_binds)
 115         -- Non-recursive, non-overloaded bindings only come in ones
 116         -- ToDo: in some bizarre case it's conceivable that there
 117         --       could be dict binds in the 'binds'.  (See the notes
 118         --       below.  Then pattern-match would fail.  Urk.)
 119     putSrcSpanDs loc    $
 120     case bind of
 121       FunBind { fun_id = L _ fun, fun_matches = matches, fun_co_fn = co_fn }
 122         -> matchWrapper (FunRhs (idName fun)) matches           `thenDs` \ (args, rhs) ->
 123            ASSERT( null args )  -- Functions aren't lifted
 124            ASSERT( isIdHsWrapper co_fn )
 125            returnDs (bindNonRec fun rhs body_w_exports)
 126
 127       PatBind {pat_lhs = pat, pat_rhs = grhss, pat_rhs_ty = ty }
 128         ->      -- let C x# y# = rhs in body
 129                 -- ==> case rhs of C x# y# -> body
 130            putSrcSpanDs loc                     $
 131            do { rhs <- dsGuarded grhss ty
 132               ; let upat = unLoc pat
 133                     eqn = EqnInfo { eqn_pats = [upat],
 134                                     eqn_rhs = cantFailMatchResult body_w_exports }
 135               ; var    <- selectMatchVar upat
 136               ; result <- matchEquations PatBindRhs [var] [eqn] (exprType body)
 137               ; return (scrungleMatch var rhs result) }
 138
 139       other -> pprPanic "dsLet: unlifted" (pprLHsBinds hsbinds $$ ppr body)
 140
 141
 142 -- Ordinary case for bindings; none should be unlifted
 143 ds_val_bind (is_rec, binds) body
 144   = do  { prs <- dsLHsBinds binds
 145         ; ASSERT( not (any (isUnLiftedType . idType . fst) prs) )
 146           case prs of
 147             []    -> return body
 148             other -> return (Let (Rec prs) body) }
 149         -- Use a Rec regardless of is_rec.
 150         -- Why? Because it allows the binds to be all
 151         -- mixed up, which is what happens in one rare case
 152         -- Namely, for an AbsBind with no tyvars and no dicts,
 153         --         but which does have dictionary bindings.
 154         -- See notes with TcSimplify.inferLoop [NO TYVARS]
 155         -- It turned out that wrapping a Rec here was the easiest solution
 156         --
 157         -- NB The previous case dealt with unlifted bindings, so we
 158         --    only have to deal with lifted ones now; so Rec is ok
 159
 160 isUnboxedTupleBind :: HsBind Id -> Bool
 161 isUnboxedTupleBind (PatBind { pat_rhs_ty = ty }) = isUnboxedTupleType ty
 162 isUnboxedTupleBind other                         = False
 163
 164 scrungleMatch :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 165 -- Returns something like (let var = scrut in body)
 166 -- but if var is an unboxed-tuple type, it inlines it in a fragile way
 167 -- Special case to handle unboxed tuple patterns; they can't appear nested
 168 -- The idea is that
 169 --      case e of (# p1, p2 #) -> rhs
 170 -- should desugar to
 171 --      case e of (# x1, x2 #) -> ... match p1, p2 ...
 172 -- NOT
 173 --      let x = e in case x of ....
 174 --
 175 -- But there may be a big
 176 --      let fail = ... in case e of ...
 177 -- wrapping the whole case, which complicates matters slightly
 178 -- It all seems a bit fragile.  Test is dsrun013.
 179
 180 scrungleMatch var scrut body
 181   | isUnboxedTupleType (idType var) = scrungle body
 182   | otherwise                       = bindNonRec var scrut body
 183   where
 184     scrungle (Case (Var x) bndr ty alts)
 185                     | x == var = Case scrut bndr ty alts
 186     scrungle (Let binds body)  = Let binds (scrungle body)
 187     scrungle other = panic ("scrungleMatch: tuple pattern:\n" ++ showSDoc (ppr other))
 188 \end{code}
 189
 190 %************************************************************************
 191 %*                                                                      *
 192 \subsection[DsExpr-vars-and-cons]{Variables, constructors, literals}
 193 %*                                                                      *
 194 %************************************************************************
 195
 196 \begin{code}
 197 dsLExpr :: LHsExpr Id -> DsM CoreExpr
 198 dsLExpr (L loc e) = putSrcSpanDs loc $ dsExpr e
 199
 200 dsExpr :: HsExpr Id -> DsM CoreExpr
 201
 202 dsExpr (HsPar e)              = dsLExpr e
 203 dsExpr (ExprWithTySigOut e _) = dsLExpr e
 204 dsExpr (HsVar var)            = returnDs (Var var)
 205 dsExpr (HsIPVar ip)           = returnDs (Var (ipNameName ip))
 206 dsExpr (HsLit lit)            = dsLit lit
 207 dsExpr (HsOverLit lit)        = dsOverLit lit
 208 dsExpr (HsWrap co_fn e)     = dsCoercion co_fn (dsExpr e)
 209
 210 dsExpr (NegApp expr neg_expr)
 211   = do  { core_expr <- dsLExpr expr
 212         ; core_neg  <- dsExpr neg_expr
 213         ; return (core_neg `App` core_expr) }
 214
 215 dsExpr expr@(HsLam a_Match)
 216   = matchWrapper LambdaExpr a_Match     `thenDs` \ (binders, matching_code) ->
 217     returnDs (mkLams binders matching_code)
 218
 219 #if defined(GHCI) && defined(BREAKPOINT)
 220 dsExpr (HsApp (L _ (HsApp realFun@(L _ (HsWrap _ fun)) (L loc arg))) _)
 221     | HsVar funId <- fun
 222     , idName funId `elem` [breakpointJumpName, breakpointCondJumpName]
 223     , ids <- filter (isValidType . idType) (extractIds arg)
 224     = do warnDs (text "Extracted ids:" <+> ppr ids <+> ppr (map idType ids))
 225          stablePtr <- ioToIOEnv $ newStablePtr ids
 226          -- Yes, I know... I'm gonna burn in hell.
 227          let Ptr addr# = castStablePtrToPtr stablePtr
 228          funCore <- dsLExpr realFun
 229          argCore <- dsLExpr (L loc (HsLit (HsInt (fromIntegral (I# (addr2Int# addr#))))))
 230          hvalCore <- dsLExpr (L loc (extractHVals ids))
 231          return ((funCore `App` argCore) `App` hvalCore)
 232     where extractIds :: HsExpr Id -> [Id]
 233           extractIds (HsApp fn arg)
 234               | HsVar argId <- unLoc arg
 235               = argId:extractIds (unLoc fn)
 236               | HsWrap co_fn arg' <- unLoc arg
 237               , HsVar argId <- arg'             -- SLPJ: not sure what is going on here
 238               = error (showSDoc (ppr co_fn)) -- argId:extractIds (unLoc fn)
 239           extractIds x = []
 240           extractHVals ids = ExplicitList unitTy (map (L loc . HsVar) ids)
 241           -- checks for tyvars and unlifted kinds.
 242           isValidType (TyVarTy _) = False
 243           isValidType (FunTy a b) = isValidType a && isValidType b
 244           isValidType (NoteTy _ t) = isValidType t
 245           isValidType (AppTy a b) = isValidType a && isValidType b
 246           isValidType (TyConApp con ts) = not (isUnLiftedTyCon con) && all isValidType ts
 247           isValidType _ = True
 248 #endif
 249
 250 dsExpr expr@(HsApp fun arg)
 251   = dsLExpr fun         `thenDs` \ core_fun ->
 252     dsLExpr arg         `thenDs` \ core_arg ->
 253     returnDs (core_fun `App` core_arg)
 254 \end{code}
 255
 256 Operator sections.  At first it looks as if we can convert
 257 \begin{verbatim}
 258         (expr op)
 259 \end{verbatim}
 260 to
 261 \begin{verbatim}
 262         \x -> op expr x
 263 \end{verbatim}
 264
 265 But no!  expr might be a redex, and we can lose laziness badly this
 266 way.  Consider
 267 \begin{verbatim}
 268         map (expr op) xs
 269 \end{verbatim}
 270 for example.  So we convert instead to
 271 \begin{verbatim}
 272         let y = expr in \x -> op y x
 273 \end{verbatim}
 274 If \tr{expr} is actually just a variable, say, then the simplifier
 275 will sort it out.
 276
 277 \begin{code}
 278 dsExpr (OpApp e1 op _ e2)
 279   = dsLExpr op                                          `thenDs` \ core_op ->
 280     -- for the type of y, we need the type of op's 2nd argument
 281     dsLExpr e1                          `thenDs` \ x_core ->
 282     dsLExpr e2                          `thenDs` \ y_core ->
 283     returnDs (mkApps core_op [x_core, y_core])
 284
 285 dsExpr (SectionL expr op)       -- Desugar (e !) to ((!) e)
 286   = dsLExpr op                          `thenDs` \ core_op ->
 287     dsLExpr expr                        `thenDs` \ x_core ->
 288     returnDs (App core_op x_core)
 289
 290 -- dsLExpr (SectionR op expr)   -- \ x -> op x expr
 291 dsExpr (SectionR op expr)
 292   = dsLExpr op                  `thenDs` \ core_op ->
 293     -- for the type of x, we need the type of op's 2nd argument
 294     let
 295         (x_ty:y_ty:_, _) = splitFunTys (exprType core_op)
 296         -- See comment with SectionL
 297     in
 298     dsLExpr expr                                `thenDs` \ y_core ->
 299     newSysLocalDs x_ty                  `thenDs` \ x_id ->
 300     newSysLocalDs y_ty                  `thenDs` \ y_id ->
 301
 302     returnDs (bindNonRec y_id y_core $
 303               Lam x_id (mkApps core_op [Var x_id, Var y_id]))
 304
 305 dsExpr (HsSCC cc expr)
 306   = dsLExpr expr                        `thenDs` \ core_expr ->
 307     getModuleDs                 `thenDs` \ mod_name ->
 308     returnDs (Note (SCC (mkUserCC cc mod_name)) core_expr)
 309
 310
 311 -- hdaume: core annotation
 312
 313 dsExpr (HsCoreAnn fs expr)
 314   = dsLExpr expr        `thenDs` \ core_expr ->
 315     returnDs (Note (CoreNote $ unpackFS fs) core_expr)
 316
 317 dsExpr (HsCase discrim matches)
 318   = dsLExpr discrim                     `thenDs` \ core_discrim ->
 319     matchWrapper CaseAlt matches        `thenDs` \ ([discrim_var], matching_code) ->
 320     returnDs (scrungleMatch discrim_var core_discrim matching_code)
 321
 322 dsExpr (HsLet binds body)
 323   = dsLExpr body                `thenDs` \ body' ->
 324     dsLocalBinds binds body'
 325
 326 -- We need the `ListComp' form to use `deListComp' (rather than the "do" form)
 327 -- because the interpretation of `stmts' depends on what sort of thing it is.
 328 --
 329 dsExpr (HsDo ListComp stmts body result_ty)
 330   =     -- Special case for list comprehensions
 331     dsListComp stmts body elt_ty
 332   where
 333     [elt_ty] = tcTyConAppArgs result_ty
 334
 335 dsExpr (HsDo DoExpr stmts body result_ty)
 336   = dsDo stmts body result_ty
 337
 338 dsExpr (HsDo (MDoExpr tbl) stmts body result_ty)
 339   = dsMDo tbl stmts body result_ty
 340
 341 dsExpr (HsDo PArrComp stmts body result_ty)
 342   =     -- Special case for array comprehensions
 343     dsPArrComp (map unLoc stmts) body elt_ty
 344   where
 345     [elt_ty] = tcTyConAppArgs result_ty
 346
 347 dsExpr (HsIf guard_expr then_expr else_expr)
 348   = dsLExpr guard_expr  `thenDs` \ core_guard ->
 349     dsLExpr then_expr   `thenDs` \ core_then ->
 350     dsLExpr else_expr   `thenDs` \ core_else ->
 351     returnDs (mkIfThenElse core_guard core_then core_else)
 352 \end{code}
 353
 354
 355 \noindent
 356 \underline{\bf Various data construction things}
 357 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 358 \begin{code}
 359 dsExpr (ExplicitList ty xs)
 360   = go xs
 361   where
 362     go []     = returnDs (mkNilExpr ty)
 363     go (x:xs) = dsLExpr x                               `thenDs` \ core_x ->
 364                 go xs                                   `thenDs` \ core_xs ->
 365                 returnDs (mkConsExpr ty core_x core_xs)
 366
 367 -- we create a list from the array elements and convert them into a list using
 368 -- `PrelPArr.toP'
 369 --
 370 --  * the main disadvantage to this scheme is that `toP' traverses the list
 371 --   twice: once to determine the length and a second time to put to elements
 372 --   into the array; this inefficiency could be avoided by exposing some of
 373 --   the innards of `PrelPArr' to the compiler (ie, have a `PrelPArrBase') so
 374 --   that we can exploit the fact that we already know the length of the array
 375 --   here at compile time
 376 --
 377 dsExpr (ExplicitPArr ty xs)
 378   = dsLookupGlobalId toPName                            `thenDs` \toP      ->
 379     dsExpr (ExplicitList ty xs)                         `thenDs` \coreList ->
 380     returnDs (mkApps (Var toP) [Type ty, coreList])
 381
 382 dsExpr (ExplicitTuple expr_list boxity)
 383   = mappM dsLExpr expr_list       `thenDs` \ core_exprs  ->
 384     returnDs (mkConApp (tupleCon boxity (length expr_list))
 385                        (map (Type .  exprType) core_exprs ++ core_exprs))
 386
 387 dsExpr (ArithSeq expr (From from))
 388   = dsExpr expr           `thenDs` \ expr2 ->
 389     dsLExpr from          `thenDs` \ from2 ->
 390     returnDs (App expr2 from2)
 391
 392 dsExpr (ArithSeq expr (FromTo from two))
 393   = dsExpr expr           `thenDs` \ expr2 ->
 394     dsLExpr from          `thenDs` \ from2 ->
 395     dsLExpr two           `thenDs` \ two2 ->
 396     returnDs (mkApps expr2 [from2, two2])
 397
 398 dsExpr (ArithSeq expr (FromThen from thn))
 399   = dsExpr expr           `thenDs` \ expr2 ->
 400     dsLExpr from          `thenDs` \ from2 ->
 401     dsLExpr thn           `thenDs` \ thn2 ->
 402     returnDs (mkApps expr2 [from2, thn2])
 403
 404 dsExpr (ArithSeq expr (FromThenTo from thn two))
 405   = dsExpr expr           `thenDs` \ expr2 ->
 406     dsLExpr from          `thenDs` \ from2 ->
 407     dsLExpr thn           `thenDs` \ thn2 ->
 408     dsLExpr two           `thenDs` \ two2 ->
 409     returnDs (mkApps expr2 [from2, thn2, two2])
 410
 411 dsExpr (PArrSeq expr (FromTo from two))
 412   = dsExpr expr           `thenDs` \ expr2 ->
 413     dsLExpr from          `thenDs` \ from2 ->
 414     dsLExpr two           `thenDs` \ two2 ->
 415     returnDs (mkApps expr2 [from2, two2])
 416
 417 dsExpr (PArrSeq expr (FromThenTo from thn two))
 418   = dsExpr expr           `thenDs` \ expr2 ->
 419     dsLExpr from          `thenDs` \ from2 ->
 420     dsLExpr thn           `thenDs` \ thn2 ->
 421     dsLExpr two           `thenDs` \ two2 ->
 422     returnDs (mkApps expr2 [from2, thn2, two2])
 423
 424 dsExpr (PArrSeq expr _)
 425   = panic "DsExpr.dsExpr: Infinite parallel array!"
 426     -- the parser shouldn't have generated it and the renamer and typechecker
 427     -- shouldn't have let it through
 428 \end{code}
 429
 430 \noindent
 431 \underline{\bf Record construction and update}
 432 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 433 For record construction we do this (assuming T has three arguments)
 434 \begin{verbatim}
 435         T { op2 = e }
 436 ==>
 437         let err = /\a -> recConErr a
 438         T (recConErr t1 "M.lhs/230/op1")
 439           e
 440           (recConErr t1 "M.lhs/230/op3")
 441 \end{verbatim}
 442 @recConErr@ then converts its arugment string into a proper message
 443 before printing it as
 444 \begin{verbatim}
 445         M.lhs, line 230: missing field op1 was evaluated
 446 \end{verbatim}
 447
 448 We also handle @C{}@ as valid construction syntax for an unlabelled
 449 constructor @C@, setting all of @C@'s fields to bottom.
 450
 451 \begin{code}
 452 dsExpr (RecordCon (L _ data_con_id) con_expr rbinds)
 453   = dsExpr con_expr     `thenDs` \ con_expr' ->
 454     let
 455         (arg_tys, _) = tcSplitFunTys (exprType con_expr')
 456         -- A newtype in the corner should be opaque;
 457         -- hence TcType.tcSplitFunTys
 458
 459         mk_arg (arg_ty, lbl)    -- Selector id has the field label as its name
 460           = case [rhs | (L _ sel_id, rhs) <- rbinds, lbl == idName sel_id] of
 461               (rhs:rhss) -> ASSERT( null rhss )
 462                             dsLExpr rhs
 463               []         -> mkErrorAppDs rEC_CON_ERROR_ID arg_ty (showSDoc (ppr lbl))
 464         unlabelled_bottom arg_ty = mkErrorAppDs rEC_CON_ERROR_ID arg_ty ""
 465
 466         labels = dataConFieldLabels (idDataCon data_con_id)
 467         -- The data_con_id is guaranteed to be the wrapper id of the constructor
 468     in
 469
 470     (if null labels
 471         then mappM unlabelled_bottom arg_tys
 472         else mappM mk_arg (zipEqual "dsExpr:RecordCon" arg_tys labels))
 473         `thenDs` \ con_args ->
 474
 475     returnDs (mkApps con_expr' con_args)
 476 \end{code}
 477
 478 Record update is a little harder. Suppose we have the decl:
 479 \begin{verbatim}
 480         data T = T1 {op1, op2, op3 :: Int}
 481                | T2 {op4, op2 :: Int}
 482                | T3
 483 \end{verbatim}
 484 Then we translate as follows:
 485 \begin{verbatim}
 486         r { op2 = e }
 487 ===>
 488         let op2 = e in
 489         case r of
 490           T1 op1 _ op3 -> T1 op1 op2 op3
 491           T2 op4 _     -> T2 op4 op2
 492           other        -> recUpdError "M.lhs/230"
 493 \end{verbatim}
 494 It's important that we use the constructor Ids for @T1@, @T2@ etc on the
 495 RHSs, and do not generate a Core constructor application directly, because the constructor
 496 might do some argument-evaluation first; and may have to throw away some
 497 dictionaries.
 498
 499 \begin{code}
 500 dsExpr (RecordUpd record_expr [] record_in_ty record_out_ty)
 501   = dsLExpr record_expr
 502
 503 dsExpr expr@(RecordUpd record_expr rbinds record_in_ty record_out_ty)
 504   = dsLExpr record_expr         `thenDs` \ record_expr' ->
 505
 506         -- Desugar the rbinds, and generate let-bindings if
 507         -- necessary so that we don't lose sharing
 508
 509     let
 510         in_inst_tys  = tcTyConAppArgs record_in_ty      -- Newtype opaque
 511         out_inst_tys = tcTyConAppArgs record_out_ty     -- Newtype opaque
 512         in_out_ty    = mkFunTy record_in_ty record_out_ty
 513
 514         mk_val_arg field old_arg_id
 515           = case [rhs | (L _ sel_id, rhs) <- rbinds, field == idName sel_id] of
 516               (rhs:rest) -> ASSERT(null rest) rhs
 517               []         -> nlHsVar old_arg_id
 518
 519         mk_alt con
 520           = ASSERT( isVanillaDataCon con )
 521             newSysLocalsDs (dataConInstOrigArgTys con in_inst_tys) `thenDs` \ arg_ids ->
 522                 -- This call to dataConInstOrigArgTys won't work for existentials
 523                 -- but existentials don't have record types anyway
 524             let
 525                 val_args = zipWithEqual "dsExpr:RecordUpd" mk_val_arg
 526                                         (dataConFieldLabels con) arg_ids
 527                 rhs = foldl (\a b -> nlHsApp a b)
 528                             (nlHsTyApp (dataConWrapId con) out_inst_tys)
 529                             val_args
 530             in
 531             returnDs (mkSimpleMatch [mkPrefixConPat con (map nlVarPat arg_ids) record_in_ty] rhs)
 532     in
 533         -- Record stuff doesn't work for existentials
 534         -- The type checker checks for this, but we need
 535         -- worry only about the constructors that are to be updated
 536     ASSERT2( all isVanillaDataCon cons_to_upd, ppr expr )
 537
 538         -- It's important to generate the match with matchWrapper,
 539         -- and the right hand sides with applications of the wrapper Id
 540         -- so that everything works when we are doing fancy unboxing on the
 541         -- constructor aguments.
 542     mappM mk_alt cons_to_upd                            `thenDs` \ alts ->
 543     matchWrapper RecUpd (MatchGroup alts in_out_ty)     `thenDs` \ ([discrim_var], matching_code) ->
 544
 545     returnDs (bindNonRec discrim_var record_expr' matching_code)
 546
 547   where
 548     updated_fields :: [FieldLabel]
 549     updated_fields = [ idName sel_id | (L _ sel_id,_) <- rbinds]
 550
 551         -- Get the type constructor from the record_in_ty
 552         -- so that we are sure it'll have all its DataCons
 553         -- (In GHCI, it's possible that some TyCons may not have all
 554         --  their constructors, in a module-loop situation.)
 555     tycon       = tcTyConAppTyCon record_in_ty
 556     data_cons   = tyConDataCons tycon
 557     cons_to_upd = filter has_all_fields data_cons
 558
 559     has_all_fields :: DataCon -> Bool
 560     has_all_fields con_id
 561       = all (`elem` con_fields) updated_fields
 562       where
 563         con_fields = dataConFieldLabels con_id
 564 \end{code}
 565
 566 Here is where we desugar the Template Haskell brackets and escapes
 567
 568 \begin{code}
 569 -- Template Haskell stuff
 570
 571 #ifdef GHCI     /* Only if bootstrapping */
 572 dsExpr (HsBracketOut x ps) = dsBracket x ps
 573 dsExpr (HsSpliceE s)       = pprPanic "dsExpr:splice" (ppr s)
 574 #endif
 575
 576 -- Arrow notation extension
 577 dsExpr (HsProc pat cmd) = dsProcExpr pat cmd
 578 \end{code}
 579
 580
 581 \begin{code}
 582
 583 #ifdef DEBUG
 584 -- HsSyn constructs that just shouldn't be here:
 585 dsExpr (ExprWithTySig _ _)  = panic "dsExpr:ExprWithTySig"
 586 #endif
 587
 588 \end{code}
 589
 590 %--------------------------------------------------------------------
 591
 592 Desugar 'do' and 'mdo' expressions (NOT list comprehensions, they're
 593 handled in DsListComp).  Basically does the translation given in the
 594 Haskell 98 report:
 595
 596 \begin{code}
 597 dsDo    :: [LStmt Id]
 598         -> LHsExpr Id
 599         -> Type                 -- Type of the whole expression
 600         -> DsM CoreExpr
 601
 602 dsDo stmts body result_ty
 603   = go (map unLoc stmts)
 604   where
 605     go [] = dsLExpr body
 606
 607     go (ExprStmt rhs then_expr _ : stmts)
 608       = do { rhs2 <- dsLExpr rhs
 609            ; then_expr2 <- dsExpr then_expr
 610            ; rest <- go stmts
 611            ; returnDs (mkApps then_expr2 [rhs2, rest]) }
 612
 613     go (LetStmt binds : stmts)
 614       = do { rest <- go stmts
 615            ; dsLocalBinds binds rest }
 616
 617     go (BindStmt pat rhs bind_op fail_op : stmts)
 618       = do { body  <- go stmts
 619            ; var   <- selectSimpleMatchVarL pat
 620            ; match <- matchSinglePat (Var var) (StmtCtxt DoExpr) pat
 621                                   result_ty (cantFailMatchResult body)
 622            ; match_code <- handle_failure pat match fail_op
 623            ; rhs'       <- dsLExpr rhs
 624            ; bind_op'   <- dsExpr bind_op
 625            ; returnDs (mkApps bind_op' [rhs', Lam var match_code]) }
 626
 627     -- In a do expression, pattern-match failure just calls
 628     -- the monadic 'fail' rather than throwing an exception
 629     handle_failure pat match fail_op
 630       | matchCanFail match
 631       = do { fail_op' <- dsExpr fail_op
 632            ; fail_msg <- mkStringExpr (mk_fail_msg pat)
 633            ; extractMatchResult match (App fail_op' fail_msg) }
 634       | otherwise
 635       = extractMatchResult match (error "It can't fail")
 636
 637 mk_fail_msg pat = "Pattern match failure in do expression at " ++
 638                   showSDoc (ppr (getLoc pat))
 639 \end{code}
 640
 641 Translation for RecStmt's:
 642 -----------------------------
 643 We turn (RecStmt [v1,..vn] stmts) into:
 644
 645   (v1,..,vn) <- mfix (\~(v1,..vn). do stmts
 646                                       return (v1,..vn))
 647
 648 \begin{code}
 649 dsMDo   :: PostTcTable
 650         -> [LStmt Id]
 651         -> LHsExpr Id
 652         -> Type                 -- Type of the whole expression
 653         -> DsM CoreExpr
 654
 655 dsMDo tbl stmts body result_ty
 656   = go (map unLoc stmts)
 657   where
 658     (m_ty, b_ty) = tcSplitAppTy result_ty       -- result_ty must be of the form (m b)
 659     mfix_id   = lookupEvidence tbl mfixName
 660     return_id = lookupEvidence tbl returnMName
 661     bind_id   = lookupEvidence tbl bindMName
 662     then_id   = lookupEvidence tbl thenMName
 663     fail_id   = lookupEvidence tbl failMName
 664     ctxt      = MDoExpr tbl
 665
 666     go [] = dsLExpr body
 667
 668     go (LetStmt binds : stmts)
 669       = do { rest <- go stmts
 670            ; dsLocalBinds binds rest }
 671
 672     go (ExprStmt rhs _ rhs_ty : stmts)
 673       = do { rhs2 <- dsLExpr rhs
 674            ; rest <- go stmts
 675            ; returnDs (mkApps (Var then_id) [Type rhs_ty, Type b_ty, rhs2, rest]) }
 676
 677     go (BindStmt pat rhs _ _ : stmts)
 678       = do { body  <- go stmts
 679            ; var   <- selectSimpleMatchVarL pat
 680            ; match <- matchSinglePat (Var var) (StmtCtxt ctxt) pat
 681                                   result_ty (cantFailMatchResult body)
 682            ; fail_msg   <- mkStringExpr (mk_fail_msg pat)
 683            ; let fail_expr = mkApps (Var fail_id) [Type b_ty, fail_msg]
 684            ; match_code <- extractMatchResult match fail_expr
 685
 686            ; rhs'       <- dsLExpr rhs
 687            ; returnDs (mkApps (Var bind_id) [Type (hsLPatType pat), Type b_ty,
 688                                              rhs', Lam var match_code]) }
 689
 690     go (RecStmt rec_stmts later_ids rec_ids rec_rets binds : stmts)
 691       = ASSERT( length rec_ids > 0 )
 692         ASSERT( length rec_ids == length rec_rets )
 693         go (new_bind_stmt : let_stmt : stmts)
 694       where
 695         new_bind_stmt = mkBindStmt (mk_tup_pat later_pats) mfix_app
 696         let_stmt = LetStmt (HsValBinds (ValBindsOut [(Recursive, binds)] []))
 697
 698
 699                 -- Remove the later_ids that appear (without fancy coercions)
 700                 -- in rec_rets, because there's no need to knot-tie them separately
 701                 -- See Note [RecStmt] in HsExpr
 702         later_ids'   = filter (`notElem` mono_rec_ids) later_ids
 703         mono_rec_ids = [ id | HsVar id <- rec_rets ]
 704
 705         mfix_app = nlHsApp (nlHsTyApp mfix_id [tup_ty]) mfix_arg
 706         mfix_arg = noLoc $ HsLam (MatchGroup [mkSimpleMatch [mfix_pat] body]
 707                                              (mkFunTy tup_ty body_ty))
 708
 709         -- The rec_tup_pat must bind the rec_ids only; remember that the
 710         --      trimmed_laters may share the same Names
 711         -- Meanwhile, the later_pats must bind the later_vars
 712         rec_tup_pats = map mk_wild_pat later_ids' ++ map nlVarPat rec_ids
 713         later_pats   = map nlVarPat    later_ids' ++ map mk_later_pat rec_ids
 714         rets         = map nlHsVar     later_ids' ++ map noLoc rec_rets
 715
 716         mfix_pat = noLoc $ LazyPat $ mk_tup_pat rec_tup_pats
 717         body     = noLoc $ HsDo ctxt rec_stmts return_app body_ty
 718         body_ty = mkAppTy m_ty tup_ty
 719         tup_ty  = mkCoreTupTy (map idType (later_ids' ++ rec_ids))
 720                   -- mkCoreTupTy deals with singleton case
 721
 722         return_app  = nlHsApp (nlHsTyApp return_id [tup_ty])
 723                               (mk_ret_tup rets)
 724
 725         mk_wild_pat :: Id -> LPat Id
 726         mk_wild_pat v = noLoc $ WildPat $ idType v
 727
 728         mk_later_pat :: Id -> LPat Id
 729         mk_later_pat v | v `elem` later_ids' = mk_wild_pat v
 730                        | otherwise           = nlVarPat v
 731
 732         mk_tup_pat :: [LPat Id] -> LPat Id
 733         mk_tup_pat [p] = p
 734         mk_tup_pat ps  = noLoc $ mkVanillaTuplePat ps Boxed
 735
 736         mk_ret_tup :: [LHsExpr Id] -> LHsExpr Id
 737         mk_ret_tup [r] = r
 738         mk_ret_tup rs  = noLoc $ ExplicitTuple rs Boxed
 739 \end{code}