compiler/deSugar/DsExpr.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Desugaring exporessions.
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 module DsExpr ( dsExpr, dsLExpr, dsLocalBinds, dsValBinds, dsLit ) where
  17
  18 #include "HsVersions.h"
  19
  20 import Match
  21 import MatchLit
  22 import DsBinds
  23 import DsGRHSs
  24 import DsListComp
  25 import DsUtils
  26 import DsArrows
  27 import DsMonad
  28 import Name
  29 import NameEnv
  30
  31 #ifdef GHCI
  32         -- Template Haskell stuff iff bootstrapped
  33 import DsMeta
  34 #endif
  35
  36 import HsSyn
  37
  38 -- NB: The desugarer, which straddles the source and Core worlds, sometimes
  39 --     needs to see source types
  40 import TcType
  41 import Type
  42 import Coercion
  43 import CoreSyn
  44 import CoreUtils
  45 import CoreFVs
  46 import MkCore
  47
  48 import DynFlags
  49 import StaticFlags
  50 import CostCentre
  51 import Id
  52 import VarSet
  53 import VarEnv
  54 import DataCon
  55 import TysWiredIn
  56 import BasicTypes
  57 import PrelNames
  58 import Maybes
  59 import SrcLoc
  60 import Util
  61 import Bag
  62 import Outputable
  63 import FastString
  64
  65 import Control.Monad
  66 \end{code}
  67
  68
  69 %************************************************************************
  70 %*                                                                      *
  71                 dsLocalBinds, dsValBinds
  72 %*                                                                      *
  73 %************************************************************************
  74
  75 \begin{code}
  76 dsLocalBinds :: HsLocalBinds Id -> CoreExpr -> DsM CoreExpr
  77 dsLocalBinds EmptyLocalBinds    body = return body
  78 dsLocalBinds (HsValBinds binds) body = dsValBinds binds body
  79 dsLocalBinds (HsIPBinds binds)  body = dsIPBinds  binds body
  80
  81 -------------------------
  82 dsValBinds :: HsValBinds Id -> CoreExpr -> DsM CoreExpr
  83 dsValBinds (ValBindsOut binds _) body = foldrM ds_val_bind body binds
  84
  85 -------------------------
  86 dsIPBinds :: HsIPBinds Id -> CoreExpr -> DsM CoreExpr
  87 dsIPBinds (IPBinds ip_binds ev_binds) body
  88   = do  { ds_ev_binds <- dsTcEvBinds ev_binds
  89         ; let inner = wrapDsEvBinds ds_ev_binds body
  90                 -- The dict bindings may not be in
  91                 -- dependency order; hence Rec
  92         ; foldrM ds_ip_bind inner ip_binds }
  93   where
  94     ds_ip_bind (L _ (IPBind n e)) body
  95       = do e' <- dsLExpr e
  96            return (Let (NonRec (ipNameName n) e') body)
  97
  98 -------------------------
  99 ds_val_bind :: (RecFlag, LHsBinds Id) -> CoreExpr -> DsM CoreExpr
 100 -- Special case for bindings which bind unlifted variables
 101 -- We need to do a case right away, rather than building
 102 -- a tuple and doing selections.
 103 -- Silently ignore INLINE and SPECIALISE pragmas...
 104 ds_val_bind (NonRecursive, hsbinds) body
 105   | [L loc bind] <- bagToList hsbinds,
 106         -- Non-recursive, non-overloaded bindings only come in ones
 107         -- ToDo: in some bizarre case it's conceivable that there
 108         --       could be dict binds in the 'binds'.  (See the notes
 109         --       below.  Then pattern-match would fail.  Urk.)
 110     strictMatchOnly bind
 111   = putSrcSpanDs loc (dsStrictBind bind body)
 112
 113 -- Ordinary case for bindings; none should be unlifted
 114 ds_val_bind (_is_rec, binds) body
 115   = do  { prs <- dsLHsBinds binds
 116         ; ASSERT2( not (any (isUnLiftedType . idType . fst) prs), ppr _is_rec $$ ppr binds )
 117           case prs of
 118             [] -> return body
 119             _  -> return (Let (Rec prs) body) }
 120         -- Use a Rec regardless of is_rec.
 121         -- Why? Because it allows the binds to be all
 122         -- mixed up, which is what happens in one rare case
 123         -- Namely, for an AbsBind with no tyvars and no dicts,
 124         --         but which does have dictionary bindings.
 125         -- See notes with TcSimplify.inferLoop [NO TYVARS]
 126         -- It turned out that wrapping a Rec here was the easiest solution
 127         --
 128         -- NB The previous case dealt with unlifted bindings, so we
 129         --    only have to deal with lifted ones now; so Rec is ok
 130
 131 ------------------
 132 dsStrictBind :: HsBind Id -> CoreExpr -> DsM CoreExpr
 133 dsStrictBind (AbsBinds { abs_tvs = [], abs_ev_vars = []
 134                , abs_exports = exports
 135                , abs_ev_binds = ev_binds
 136                , abs_binds = binds }) body
 137   = do { ds_ev_binds <- dsTcEvBinds ev_binds
 138        ; let body1 = foldr bind_export body exports
 139              bind_export (_, g, l, _) b = bindNonRec g (Var l) b
 140        ; body2 <- foldlBagM (\body bind -> dsStrictBind (unLoc bind) body)
 141                             body1 binds
 142        ; return (wrapDsEvBinds ds_ev_binds body2) }
 143
 144 dsStrictBind (FunBind { fun_id = L _ fun, fun_matches = matches, fun_co_fn = co_fn
 145                       , fun_tick = tick, fun_infix = inf }) body
 146                 -- Can't be a bang pattern (that looks like a PatBind)
 147                 -- so must be simply unboxed
 148   = do { (args, rhs) <- matchWrapper (FunRhs (idName fun ) inf) matches
 149        ; MASSERT( null args ) -- Functions aren't lifted
 150        ; MASSERT( isIdHsWrapper co_fn )
 151        ; rhs' <- mkOptTickBox tick rhs
 152        ; return (bindNonRec fun rhs' body) }
 153
 154 dsStrictBind (PatBind {pat_lhs = pat, pat_rhs = grhss, pat_rhs_ty = ty }) body
 155   =     -- let C x# y# = rhs in body
 156         -- ==> case rhs of C x# y# -> body
 157     do { rhs <- dsGuarded grhss ty
 158        ; let upat = unLoc pat
 159              eqn = EqnInfo { eqn_pats = [upat],
 160                              eqn_rhs = cantFailMatchResult body }
 161        ; var    <- selectMatchVar upat
 162        ; result <- matchEquations PatBindRhs [var] [eqn] (exprType body)
 163        ; return (scrungleMatch var rhs result) }
 164
 165 dsStrictBind bind body = pprPanic "dsLet: unlifted" (ppr bind $$ ppr body)
 166
 167 ----------------------
 168 strictMatchOnly :: HsBind Id -> Bool
 169 strictMatchOnly (AbsBinds { abs_binds = binds })
 170   = anyBag (strictMatchOnly . unLoc) binds
 171 strictMatchOnly (PatBind { pat_lhs = lpat, pat_rhs_ty = ty })
 172   =  isUnboxedTupleType ty
 173   || isBangLPat lpat
 174   || any (isUnLiftedType . idType) (collectPatBinders lpat)
 175 strictMatchOnly (FunBind { fun_id = L _ id })
 176   = isUnLiftedType (idType id)
 177 strictMatchOnly _ = False -- I hope!  Checked immediately by caller in fact
 178
 179 scrungleMatch :: Id -> CoreExpr -> CoreExpr -> CoreExpr
 180 -- Returns something like (let var = scrut in body)
 181 -- but if var is an unboxed-tuple type, it inlines it in a fragile way
 182 -- Special case to handle unboxed tuple patterns; they can't appear nested
 183 -- The idea is that
 184 --      case e of (# p1, p2 #) -> rhs
 185 -- should desugar to
 186 --      case e of (# x1, x2 #) -> ... match p1, p2 ...
 187 -- NOT
 188 --      let x = e in case x of ....
 189 --
 190 -- But there may be a big
 191 --      let fail = ... in case e of ...
 192 -- wrapping the whole case, which complicates matters slightly
 193 -- It all seems a bit fragile.  Test is dsrun013.
 194
 195 scrungleMatch var scrut body
 196   | isUnboxedTupleType (idType var) = scrungle body
 197   | otherwise                       = bindNonRec var scrut body
 198   where
 199     scrungle (Case (Var x) bndr ty alts)
 200                     | x == var = Case scrut bndr ty alts
 201     scrungle (Let binds body)  = Let binds (scrungle body)
 202     scrungle other = panic ("scrungleMatch: tuple pattern:\n" ++ showSDoc (ppr other))
 203
 204 \end{code}
 205
 206 %************************************************************************
 207 %*                                                                      *
 208 \subsection[DsExpr-vars-and-cons]{Variables, constructors, literals}
 209 %*                                                                      *
 210 %************************************************************************
 211
 212 \begin{code}
 213 dsLExpr :: LHsExpr Id -> DsM CoreExpr
 214
 215 dsLExpr (L loc e) = putSrcSpanDs loc $ dsExpr e
 216
 217 dsExpr :: HsExpr Id -> DsM CoreExpr
 218 dsExpr (HsPar e)              = dsLExpr e
 219 dsExpr (ExprWithTySigOut e _) = dsLExpr e
 220 dsExpr (HsVar var)            = return (Var var)
 221 dsExpr (HsIPVar ip)           = return (Var (ipNameName ip))
 222 dsExpr (HsLit lit)            = dsLit lit
 223 dsExpr (HsOverLit lit)        = dsOverLit lit
 224
 225 dsExpr (HsWrap co_fn e)
 226   = do { co_fn' <- dsHsWrapper co_fn
 227        ; e' <- dsExpr e
 228        ; warn_id <- doptDs Opt_WarnIdentities
 229        ; when warn_id $ warnAboutIdentities e' co_fn'
 230        ; return (co_fn' e') }
 231
 232 dsExpr (NegApp expr neg_expr)
 233   = App <$> dsExpr neg_expr <*> dsLExpr expr
 234
 235 dsExpr (HsLam a_Match)
 236   = uncurry mkLams <$> matchWrapper LambdaExpr a_Match
 237
 238 dsExpr (HsApp fun arg)
 239   = mkCoreAppDs <$> dsLExpr fun <*>  dsLExpr arg
 240 \end{code}
 241
 242 Operator sections.  At first it looks as if we can convert
 243 \begin{verbatim}
 244         (expr op)
 245 \end{verbatim}
 246 to
 247 \begin{verbatim}
 248         \x -> op expr x
 249 \end{verbatim}
 250
 251 But no!  expr might be a redex, and we can lose laziness badly this
 252 way.  Consider
 253 \begin{verbatim}
 254         map (expr op) xs
 255 \end{verbatim}
 256 for example.  So we convert instead to
 257 \begin{verbatim}
 258         let y = expr in \x -> op y x
 259 \end{verbatim}
 260 If \tr{expr} is actually just a variable, say, then the simplifier
 261 will sort it out.
 262
 263 \begin{code}
 264 dsExpr (OpApp e1 op _ e2)
 265   = -- for the type of y, we need the type of op's 2nd argument
 266     mkCoreAppsDs <$> dsLExpr op <*> mapM dsLExpr [e1, e2]
 267
 268 dsExpr (SectionL expr op)       -- Desugar (e !) to ((!) e)
 269   = mkCoreAppDs <$> dsLExpr op <*> dsLExpr expr
 270
 271 -- dsLExpr (SectionR op expr)   -- \ x -> op x expr
 272 dsExpr (SectionR op expr) = do
 273     core_op <- dsLExpr op
 274     -- for the type of x, we need the type of op's 2nd argument
 275     let (x_ty:y_ty:_, _) = splitFunTys (exprType core_op)
 276         -- See comment with SectionL
 277     y_core <- dsLExpr expr
 278     x_id <- newSysLocalDs x_ty
 279     y_id <- newSysLocalDs y_ty
 280     return (bindNonRec y_id y_core $
 281             Lam x_id (mkCoreAppsDs core_op [Var x_id, Var y_id]))
 282
 283 dsExpr (ExplicitTuple tup_args boxity)
 284   = do { let go (lam_vars, args) (Missing ty)
 285                     -- For every missing expression, we need
 286                     -- another lambda in the desugaring.
 287                = do { lam_var <- newSysLocalDs ty
 288                     ; return (lam_var : lam_vars, Var lam_var : args) }
 289              go (lam_vars, args) (Present expr)
 290                     -- Expressions that are present don't generate
 291                     -- lambdas, just arguments.
 292                = do { core_expr <- dsLExpr expr
 293                     ; return (lam_vars, core_expr : args) }
 294
 295        ; (lam_vars, args) <- foldM go ([], []) (reverse tup_args)
 296                 -- The reverse is because foldM goes left-to-right
 297
 298        ; return $ mkCoreLams lam_vars $
 299                   mkConApp (tupleCon boxity (length tup_args))
 300                            (map (Type . exprType) args ++ args) }
 301
 302 dsExpr (HsSCC cc expr) = do
 303     mod_name <- getModuleDs
 304     Note (SCC (mkUserCC cc mod_name)) <$> dsLExpr expr
 305
 306 dsExpr (HsCoreAnn fs expr)
 307   = Note (CoreNote $ unpackFS fs) <$> dsLExpr expr
 308
 309 dsExpr (HsCase discrim matches@(MatchGroup _ rhs_ty))
 310   | isEmptyMatchGroup matches   -- A Core 'case' is always non-empty
 311   =                             -- So desugar empty HsCase to error call
 312     mkErrorAppDs pAT_ERROR_ID (funResultTy rhs_ty) (ptext (sLit "case"))
 313
 314   | otherwise
 315   = do { core_discrim <- dsLExpr discrim
 316        ; ([discrim_var], matching_code) <- matchWrapper CaseAlt matches
 317        ; return (scrungleMatch discrim_var core_discrim matching_code) }
 318
 319 -- Pepe: The binds are in scope in the body but NOT in the binding group
 320 --       This is to avoid silliness in breakpoints
 321 dsExpr (HsLet binds body) = do
 322     body' <- dsLExpr body
 323     dsLocalBinds binds body'
 324
 325 -- We need the `ListComp' form to use `deListComp' (rather than the "do" form)
 326 -- because the interpretation of `stmts' depends on what sort of thing it is.
 327 --
 328 dsExpr (HsDo ListComp  stmts res_ty) = dsListComp stmts res_ty
 329 dsExpr (HsDo PArrComp  stmts _)      = dsPArrComp (map unLoc stmts)
 330 dsExpr (HsDo DoExpr    stmts _)      = dsDo stmts
 331 dsExpr (HsDo GhciStmt  stmts _)      = dsDo stmts
 332 dsExpr (HsDo MDoExpr   stmts _)      = dsDo stmts
 333 dsExpr (HsDo MonadComp stmts _)      = dsMonadComp stmts
 334
 335 dsExpr (HsIf mb_fun guard_expr then_expr else_expr)
 336   = do { pred <- dsLExpr guard_expr
 337        ; b1 <- dsLExpr then_expr
 338        ; b2 <- dsLExpr else_expr
 339        ; case mb_fun of
 340            Just fun -> do { core_fun <- dsExpr fun
 341                           ; return (mkCoreApps core_fun [pred,b1,b2]) }
 342            Nothing  -> return $ mkIfThenElse pred b1 b2 }
 343 \end{code}
 344
 345
 346 \noindent
 347 \underline{\bf Various data construction things}
 348 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 349 \begin{code}
 350 dsExpr (ExplicitList elt_ty xs)
 351   = dsExplicitList elt_ty xs
 352
 353 -- We desugar [:x1, ..., xn:] as
 354 --   singletonP x1 +:+ ... +:+ singletonP xn
 355 --
 356 dsExpr (ExplicitPArr ty []) = do
 357     emptyP <- dsLookupDPHId emptyPName
 358     return (Var emptyP `App` Type ty)
 359 dsExpr (ExplicitPArr ty xs) = do
 360     singletonP <- dsLookupDPHId singletonPName
 361     appP       <- dsLookupDPHId appPName
 362     xs'        <- mapM dsLExpr xs
 363     return . foldr1 (binary appP) $ map (unary singletonP) xs'
 364   where
 365     unary  fn x   = mkApps (Var fn) [Type ty, x]
 366     binary fn x y = mkApps (Var fn) [Type ty, x, y]
 367
 368 dsExpr (ArithSeq expr (From from))
 369   = App <$> dsExpr expr <*> dsLExpr from
 370
 371 dsExpr (ArithSeq expr (FromTo from to))
 372   = mkApps <$> dsExpr expr <*> mapM dsLExpr [from, to]
 373
 374 dsExpr (ArithSeq expr (FromThen from thn))
 375   = mkApps <$> dsExpr expr <*> mapM dsLExpr [from, thn]
 376
 377 dsExpr (ArithSeq expr (FromThenTo from thn to))
 378   = mkApps <$> dsExpr expr <*> mapM dsLExpr [from, thn, to]
 379
 380 dsExpr (PArrSeq expr (FromTo from to))
 381   = mkApps <$> dsExpr expr <*> mapM dsLExpr [from, to]
 382
 383 dsExpr (PArrSeq expr (FromThenTo from thn to))
 384   = mkApps <$> dsExpr expr <*> mapM dsLExpr [from, thn, to]
 385
 386 dsExpr (PArrSeq _ _)
 387   = panic "DsExpr.dsExpr: Infinite parallel array!"
 388     -- the parser shouldn't have generated it and the renamer and typechecker
 389     -- shouldn't have let it through
 390 \end{code}
 391
 392 \noindent
 393 \underline{\bf Record construction and update}
 394 %              ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 395 For record construction we do this (assuming T has three arguments)
 396 \begin{verbatim}
 397         T { op2 = e }
 398 ==>
 399         let err = /\a -> recConErr a
 400         T (recConErr t1 "M.lhs/230/op1")
 401           e
 402           (recConErr t1 "M.lhs/230/op3")
 403 \end{verbatim}
 404 @recConErr@ then converts its arugment string into a proper message
 405 before printing it as
 406 \begin{verbatim}
 407         M.lhs, line 230: missing field op1 was evaluated
 408 \end{verbatim}
 409
 410 We also handle @C{}@ as valid construction syntax for an unlabelled
 411 constructor @C@, setting all of @C@'s fields to bottom.
 412
 413 \begin{code}
 414 dsExpr (RecordCon (L _ data_con_id) con_expr rbinds) = do
 415     con_expr' <- dsExpr con_expr
 416     let
 417         (arg_tys, _) = tcSplitFunTys (exprType con_expr')
 418         -- A newtype in the corner should be opaque;
 419         -- hence TcType.tcSplitFunTys
 420
 421         mk_arg (arg_ty, lbl)    -- Selector id has the field label as its name
 422           = case findField (rec_flds rbinds) lbl of
 423               (rhs:rhss) -> ASSERT( null rhss )
 424                             dsLExpr rhs
 425               []         -> mkErrorAppDs rEC_CON_ERROR_ID arg_ty (ppr lbl)
 426         unlabelled_bottom arg_ty = mkErrorAppDs rEC_CON_ERROR_ID arg_ty empty
 427
 428         labels = dataConFieldLabels (idDataCon data_con_id)
 429         -- The data_con_id is guaranteed to be the wrapper id of the constructor
 430
 431     con_args <- if null labels
 432                 then mapM unlabelled_bottom arg_tys
 433                 else mapM mk_arg (zipEqual "dsExpr:RecordCon" arg_tys labels)
 434
 435     return (mkApps con_expr' con_args)
 436 \end{code}
 437
 438 Record update is a little harder. Suppose we have the decl:
 439 \begin{verbatim}
 440         data T = T1 {op1, op2, op3 :: Int}
 441                | T2 {op4, op2 :: Int}
 442                | T3
 443 \end{verbatim}
 444 Then we translate as follows:
 445 \begin{verbatim}
 446         r { op2 = e }
 447 ===>
 448         let op2 = e in
 449         case r of
 450           T1 op1 _ op3 -> T1 op1 op2 op3
 451           T2 op4 _     -> T2 op4 op2
 452           other        -> recUpdError "M.lhs/230"
 453 \end{verbatim}
 454 It's important that we use the constructor Ids for @T1@, @T2@ etc on the
 455 RHSs, and do not generate a Core constructor application directly, because the constructor
 456 might do some argument-evaluation first; and may have to throw away some
 457 dictionaries.
 458
 459 Note [Update for GADTs]
 460 ~~~~~~~~~~~~~~~~~~~~~~~
 461 Consider
 462    data T a b where
 463      T1 { f1 :: a } :: T a Int
 464
 465 Then the wrapper function for T1 has type
 466    $WT1 :: a -> T a Int
 467 But if x::T a b, then
 468    x { f1 = v } :: T a b   (not T a Int!)
 469 So we need to cast (T a Int) to (T a b).  Sigh.
 470
 471 \begin{code}
 472 dsExpr expr@(RecordUpd record_expr (HsRecFields { rec_flds = fields })
 473                        cons_to_upd in_inst_tys out_inst_tys)
 474   | null fields
 475   = dsLExpr record_expr
 476   | otherwise
 477   = ASSERT2( notNull cons_to_upd, ppr expr )
 478
 479     do  { record_expr' <- dsLExpr record_expr
 480         ; field_binds' <- mapM ds_field fields
 481         ; let upd_fld_env :: NameEnv Id -- Maps field name to the LocalId of the field binding
 482               upd_fld_env = mkNameEnv [(f,l) | (f,l,_) <- field_binds']
 483
 484         -- It's important to generate the match with matchWrapper,
 485         -- and the right hand sides with applications of the wrapper Id
 486         -- so that everything works when we are doing fancy unboxing on the
 487         -- constructor aguments.
 488         ; alts <- mapM (mk_alt upd_fld_env) cons_to_upd
 489         ; ([discrim_var], matching_code)
 490                 <- matchWrapper RecUpd (MatchGroup alts in_out_ty)
 491
 492         ; return (add_field_binds field_binds' $
 493                   bindNonRec discrim_var record_expr' matching_code) }
 494   where
 495     ds_field :: HsRecField Id (LHsExpr Id) -> DsM (Name, Id, CoreExpr)
 496       -- Clone the Id in the HsRecField, because its Name is that
 497       -- of the record selector, and we must not make that a lcoal binder
 498       -- else we shadow other uses of the record selector
 499       -- Hence 'lcl_id'.  Cf Trac #2735
 500     ds_field rec_field = do { rhs <- dsLExpr (hsRecFieldArg rec_field)
 501                             ; let fld_id = unLoc (hsRecFieldId rec_field)
 502                             ; lcl_id <- newSysLocalDs (idType fld_id)
 503                             ; return (idName fld_id, lcl_id, rhs) }
 504
 505     add_field_binds [] expr = expr
 506     add_field_binds ((_,b,r):bs) expr = bindNonRec b r (add_field_binds bs expr)
 507
 508         -- Awkwardly, for families, the match goes
 509         -- from instance type to family type
 510     tycon     = dataConTyCon (head cons_to_upd)
 511     in_ty     = mkTyConApp tycon in_inst_tys
 512     in_out_ty = mkFunTy in_ty (mkFamilyTyConApp tycon out_inst_tys)
 513
 514     mk_alt upd_fld_env con
 515       = do { let (univ_tvs, ex_tvs, eq_spec,
 516                   theta, arg_tys, _) = dataConFullSig con
 517                  subst = mkTopTvSubst (univ_tvs `zip` in_inst_tys)
 518
 519                 -- I'm not bothering to clone the ex_tvs
 520            ; eqs_vars   <- mapM newPredVarDs (substTheta subst (eqSpecPreds eq_spec))
 521            ; theta_vars <- mapM newPredVarDs (substTheta subst theta)
 522            ; arg_ids    <- newSysLocalsDs (substTys subst arg_tys)
 523            ; let val_args = zipWithEqual "dsExpr:RecordUpd" mk_val_arg
 524                                          (dataConFieldLabels con) arg_ids
 525                  mk_val_arg field_name pat_arg_id
 526                      = nlHsVar (lookupNameEnv upd_fld_env field_name `orElse` pat_arg_id)
 527                  inst_con = noLoc $ HsWrap wrap (HsVar (dataConWrapId con))
 528                         -- Reconstruct with the WrapId so that unpacking happens
 529                  wrap = mkWpEvVarApps theta_vars          `WpCompose`
 530                         mkWpTyApps    (mkTyVarTys ex_tvs) `WpCompose`
 531                         mkWpTyApps [ty | (tv, ty) <- univ_tvs `zip` out_inst_tys
 532                                        , not (tv `elemVarEnv` wrap_subst) ]
 533                  rhs = foldl (\a b -> nlHsApp a b) inst_con val_args
 534
 535                         -- Tediously wrap the application in a cast
 536                         -- Note [Update for GADTs]
 537                  wrapped_rhs | null eq_spec = rhs
 538                              | otherwise    = mkLHsWrap (WpCast wrap_co) rhs
 539                  wrap_co = mkTyConAppCo tycon [ lookup tv ty
 540                                               | (tv,ty) <- univ_tvs `zip` out_inst_tys]
 541                  lookup univ_tv ty = case lookupVarEnv wrap_subst univ_tv of
 542                                         Just co' -> co'
 543                                         Nothing  -> mkReflCo ty
 544                  wrap_subst = mkVarEnv [ (tv, mkSymCo (mkCoVarCo co_var))
 545                                        | ((tv,_),co_var) <- eq_spec `zip` eqs_vars ]
 546
 547                  pat = noLoc $ ConPatOut { pat_con = noLoc con, pat_tvs = ex_tvs
 548                                          , pat_dicts = eqs_vars ++ theta_vars
 549                                          , pat_binds = emptyTcEvBinds
 550                                          , pat_args = PrefixCon $ map nlVarPat arg_ids
 551                                          , pat_ty = in_ty }
 552            ; return (mkSimpleMatch [pat] wrapped_rhs) }
 553
 554 \end{code}
 555
 556 Here is where we desugar the Template Haskell brackets and escapes
 557
 558 \begin{code}
 559 -- Template Haskell stuff
 560
 561 #ifdef GHCI     /* Only if bootstrapping */
 562 dsExpr (HsBracketOut x ps) = dsBracket x ps
 563 dsExpr (HsSpliceE s)       = pprPanic "dsExpr:splice" (ppr s)
 564 #endif
 565
 566 -- Arrow notation extension
 567 dsExpr (HsProc pat cmd) = dsProcExpr pat cmd
 568 \end{code}
 569
 570 Hpc Support
 571
 572 \begin{code}
 573 dsExpr (HsTick ix vars e) = do
 574   e' <- dsLExpr e
 575   mkTickBox ix vars e'
 576
 577 -- There is a problem here. The then and else branches
 578 -- have no free variables, so they are open to lifting.
 579 -- We need someway of stopping this.
 580 -- This will make no difference to binary coverage
 581 -- (did you go here: YES or NO), but will effect accurate
 582 -- tick counting.
 583
 584 dsExpr (HsBinTick ixT ixF e) = do
 585   e2 <- dsLExpr e
 586   do { ASSERT(exprType e2 `eqType` boolTy)
 587        mkBinaryTickBox ixT ixF e2
 588      }
 589 \end{code}
 590
 591 \begin{code}
 592
 593 -- HsSyn constructs that just shouldn't be here:
 594 dsExpr (ExprWithTySig _ _)  = panic "dsExpr:ExprWithTySig"
 595
 596
 597 findField :: [HsRecField Id arg] -> Name -> [arg]
 598 findField rbinds lbl
 599   = [rhs | HsRecField { hsRecFieldId = id, hsRecFieldArg = rhs } <- rbinds
 600          , lbl == idName (unLoc id) ]
 601 \end{code}
 602
 603 %--------------------------------------------------------------------
 604
 605 Note [Desugaring explicit lists]
 606 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 607 Explicit lists are desugared in a cleverer way to prevent some
 608 fruitless allocations.  Essentially, whenever we see a list literal
 609 [x_1, ..., x_n] we:
 610
 611 1. Find the tail of the list that can be allocated statically (say
 612    [x_k, ..., x_n]) by later stages and ensure we desugar that
 613    normally: this makes sure that we don't cause a code size increase
 614    by having the cons in that expression fused (see later) and hence
 615    being unable to statically allocate any more
 616
 617 2. For the prefix of the list which cannot be allocated statically,
 618    say [x_1, ..., x_(k-1)], we turn it into an expression involving
 619    build so that if we find any foldrs over it it will fuse away
 620    entirely!
 621
 622    So in this example we will desugar to:
 623    build (\c n -> x_1 `c` x_2 `c` .... `c` foldr c n [x_k, ..., x_n]
 624
 625    If fusion fails to occur then build will get inlined and (since we
 626    defined a RULE for foldr (:) []) we will get back exactly the
 627    normal desugaring for an explicit list.
 628
 629 This optimisation can be worth a lot: up to 25% of the total
 630 allocation in some nofib programs. Specifically
 631
 632         Program           Size    Allocs   Runtime  CompTime
 633         rewrite          +0.0%    -26.3%      0.02     -1.8%
 634            ansi          -0.3%    -13.8%      0.00     +0.0%
 635            lift          +0.0%     -8.7%      0.00     -2.3%
 636
 637 Of course, if rules aren't turned on then there is pretty much no
 638 point doing this fancy stuff, and it may even be harmful.
 639
 640 =======>  Note by SLPJ Dec 08.
 641
 642 I'm unconvinced that we should *ever* generate a build for an explicit
 643 list.  See the comments in GHC.Base about the foldr/cons rule, which
 644 points out that (foldr k z [a,b,c]) may generate *much* less code than
 645 (a `k` b `k` c `k` z).
 646
 647 Furthermore generating builds messes up the LHS of RULES.
 648 Example: the foldr/single rule in GHC.Base
 649    foldr k z [x] = ...
 650 We do not want to generate a build invocation on the LHS of this RULE!
 651
 652 We fix this by disabling rules in rule LHSs, and testing that
 653 flag here; see Note [Desugaring RULE left hand sides] in Desugar
 654
 655 To test this I've added a (static) flag -fsimple-list-literals, which
 656 makes all list literals be generated via the simple route.
 657
 658
 659 \begin{code}
 660 dsExplicitList :: PostTcType -> [LHsExpr Id] -> DsM CoreExpr
 661 -- See Note [Desugaring explicit lists]
 662 dsExplicitList elt_ty xs
 663   = do { dflags <- getDOptsDs
 664        ; xs' <- mapM dsLExpr xs
 665        ; let (dynamic_prefix, static_suffix) = spanTail is_static xs'
 666        ; if opt_SimpleListLiterals                      -- -fsimple-list-literals
 667          || not (dopt Opt_EnableRewriteRules dflags)    -- Rewrite rules off
 668                 -- Don't generate a build if there are no rules to eliminate it!
 669                 -- See Note [Desugaring RULE left hand sides] in Desugar
 670          || null dynamic_prefix   -- Avoid build (\c n. foldr c n xs)!
 671          then return $ mkListExpr elt_ty xs'
 672          else mkBuildExpr elt_ty (mkSplitExplicitList dynamic_prefix static_suffix) }
 673   where
 674     is_static :: CoreExpr -> Bool
 675     is_static e = all is_static_var (varSetElems (exprFreeVars e))
 676
 677     is_static_var :: Var -> Bool
 678     is_static_var v
 679       | isId v = isExternalName (idName v)  -- Top-level things are given external names
 680       | otherwise = False                   -- Type variables
 681
 682     mkSplitExplicitList prefix suffix (c, _) (n, n_ty)
 683       = do { let suffix' = mkListExpr elt_ty suffix
 684            ; folded_suffix <- mkFoldrExpr elt_ty n_ty (Var c) (Var n) suffix'
 685            ; return (foldr (App . App (Var c)) folded_suffix prefix) }
 686
 687 spanTail :: (a -> Bool) -> [a] -> ([a], [a])
 688 spanTail f xs = (reverse rejected, reverse satisfying)
 689     where (satisfying, rejected) = span f $ reverse xs
 690 \end{code}
 691
 692 Desugar 'do' and 'mdo' expressions (NOT list comprehensions, they're
 693 handled in DsListComp).  Basically does the translation given in the
 694 Haskell 98 report:
 695
 696 \begin{code}
 697 dsDo :: [LStmt Id] -> DsM CoreExpr
 698 dsDo stmts
 699   = goL stmts
 700   where
 701     goL [] = panic "dsDo"
 702     goL (L loc stmt:lstmts) = putSrcSpanDs loc (go loc stmt lstmts)
 703
 704     go _ (LastStmt body _) stmts
 705       = ASSERT( null stmts ) dsLExpr body
 706         -- The 'return' op isn't used for 'do' expressions
 707
 708     go _ (ExprStmt rhs then_expr _ _) stmts
 709       = do { rhs2 <- dsLExpr rhs
 710            ; warnDiscardedDoBindings rhs (exprType rhs2)
 711            ; then_expr2 <- dsExpr then_expr
 712            ; rest <- goL stmts
 713            ; return (mkApps then_expr2 [rhs2, rest]) }
 714
 715     go _ (LetStmt binds) stmts
 716       = do { rest <- goL stmts
 717            ; dsLocalBinds binds rest }
 718
 719     go _ (BindStmt pat rhs bind_op fail_op) stmts
 720       = do  { body     <- goL stmts
 721             ; rhs'     <- dsLExpr rhs
 722             ; bind_op' <- dsExpr bind_op
 723             ; var   <- selectSimpleMatchVarL pat
 724             ; let bind_ty = exprType bind_op'   -- rhs -> (pat -> res1) -> res2
 725                   res1_ty = funResultTy (funArgTy (funResultTy bind_ty))
 726             ; match <- matchSinglePat (Var var) (StmtCtxt DoExpr) pat
 727                                       res1_ty (cantFailMatchResult body)
 728             ; match_code <- handle_failure pat match fail_op
 729             ; return (mkApps bind_op' [rhs', Lam var match_code]) }
 730
 731     go loc (RecStmt { recS_stmts = rec_stmts, recS_later_ids = later_ids
 732                     , recS_rec_ids = rec_ids, recS_ret_fn = return_op
 733                     , recS_mfix_fn = mfix_op, recS_bind_fn = bind_op
 734                     , recS_rec_rets = rec_rets, recS_ret_ty = body_ty }) stmts
 735       = ASSERT( length rec_ids > 0 )
 736         goL (new_bind_stmt : stmts)
 737       where
 738         new_bind_stmt = L loc $ BindStmt (mkLHsPatTup later_pats)
 739                                          mfix_app bind_op
 740                                          noSyntaxExpr  -- Tuple cannot fail
 741
 742         tup_ids      = rec_ids ++ filterOut (`elem` rec_ids) later_ids
 743         tup_ty       = mkBoxedTupleTy (map idType tup_ids) -- Deals with singleton case
 744         rec_tup_pats = map nlVarPat tup_ids
 745         later_pats   = rec_tup_pats
 746         rets         = map noLoc rec_rets
 747         mfix_app     = nlHsApp (noLoc mfix_op) mfix_arg
 748         mfix_arg     = noLoc $ HsLam (MatchGroup [mkSimpleMatch [mfix_pat] body]
 749                                                  (mkFunTy tup_ty body_ty))
 750         mfix_pat     = noLoc $ LazyPat $ mkLHsPatTup rec_tup_pats
 751         body         = noLoc $ HsDo DoExpr (rec_stmts ++ [ret_stmt]) body_ty
 752         ret_app      = nlHsApp (noLoc return_op) (mkLHsTupleExpr rets)
 753         ret_stmt     = noLoc $ mkLastStmt ret_app
 754                      -- This LastStmt will be desugared with dsDo,
 755                      -- which ignores the return_op in the LastStmt,
 756                      -- so we must apply the return_op explicitly
 757
 758 handle_failure :: LPat Id -> MatchResult -> SyntaxExpr Id -> DsM CoreExpr
 759     -- In a do expression, pattern-match failure just calls
 760     -- the monadic 'fail' rather than throwing an exception
 761 handle_failure pat match fail_op
 762   | matchCanFail match
 763   = do { fail_op' <- dsExpr fail_op
 764        ; fail_msg <- mkStringExpr (mk_fail_msg pat)
 765        ; extractMatchResult match (App fail_op' fail_msg) }
 766   | otherwise
 767   = extractMatchResult match (error "It can't fail")
 768
 769 mk_fail_msg :: Located e -> String
 770 mk_fail_msg pat = "Pattern match failure in do expression at " ++
 771                   showSDoc (ppr (getLoc pat))
 772 \end{code}
 773
 774
 775 %************************************************************************
 776 %*                                                                      *
 777                  Warning about identities
 778 %*                                                                      *
 779 %************************************************************************
 780
 781 Warn about functions that convert between one type and another
 782 when the to- and from- types are the same.  Then it's probably
 783 (albeit not definitely) the identity
 784 \begin{code}
 785 warnAboutIdentities :: CoreExpr -> (CoreExpr -> CoreExpr) -> DsM ()
 786 warnAboutIdentities (Var v) co_fn
 787   | idName v `elem` conversionNames
 788   , let fun_ty = exprType (co_fn (Var v))
 789   , Just (arg_ty, res_ty) <- splitFunTy_maybe fun_ty
 790   , arg_ty `eqType` res_ty  -- So we are converting  ty -> ty
 791   = warnDs (vcat [ ptext (sLit "Call of") <+> ppr v <+> dcolon <+> ppr fun_ty
 792                  , nest 2 $ ptext (sLit "can probably be omitted")
 793                  , parens (ptext (sLit "Use -fno-warn-identities to suppress this messsage)"))
 794            ])
 795 warnAboutIdentities _ _ = return ()
 796
 797 conversionNames :: [Name]
 798 conversionNames
 799   = [ toIntegerName, toRationalName
 800     , fromIntegralName, realToFracName ]
 801  -- We can't easily add fromIntegerName, fromRationalName,
 802  -- becuase they are generated by literals
 803 \end{code}
 804
 805 %************************************************************************
 806 %*                                                                      *
 807 \subsection{Errors and contexts}
 808 %*                                                                      *
 809 %************************************************************************
 810
 811 \begin{code}
 812 -- Warn about certain types of values discarded in monadic bindings (#3263)
 813 warnDiscardedDoBindings :: LHsExpr Id -> Type -> DsM ()
 814 warnDiscardedDoBindings rhs rhs_ty
 815   | Just (m_ty, elt_ty) <- tcSplitAppTy_maybe rhs_ty
 816   = do {  -- Warn about discarding non-() things in 'monadic' binding
 817        ; warn_unused <- doptDs Opt_WarnUnusedDoBind
 818        ; if warn_unused && not (isUnitTy elt_ty)
 819          then warnDs (unusedMonadBind rhs elt_ty)
 820          else
 821          -- Warn about discarding m a things in 'monadic' binding of the same type,
 822          -- but only if we didn't already warn due to Opt_WarnUnusedDoBind
 823     do { warn_wrong <- doptDs Opt_WarnWrongDoBind
 824        ; case tcSplitAppTy_maybe elt_ty of
 825            Just (elt_m_ty, _) | warn_wrong, m_ty `eqType` elt_m_ty
 826                               -> warnDs (wrongMonadBind rhs elt_ty)
 827            _ -> return () } }
 828
 829   | otherwise   -- RHS does have type of form (m ty), which is wierd
 830   = return ()   -- but at lesat this warning is irrelevant
 831
 832 unusedMonadBind :: LHsExpr Id -> Type -> SDoc
 833 unusedMonadBind rhs elt_ty
 834   = ptext (sLit "A do-notation statement discarded a result of type") <+> ppr elt_ty <> dot $$
 835     ptext (sLit "Suppress this warning by saying \"_ <- ") <> ppr rhs <> ptext (sLit "\",") $$
 836     ptext (sLit "or by using the flag -fno-warn-unused-do-bind")
 837
 838 wrongMonadBind :: LHsExpr Id -> Type -> SDoc
 839 wrongMonadBind rhs elt_ty
 840   = ptext (sLit "A do-notation statement discarded a result of type") <+> ppr elt_ty <> dot $$
 841     ptext (sLit "Suppress this warning by saying \"_ <- ") <> ppr rhs <> ptext (sLit "\",") $$
 842     ptext (sLit "or by using the flag -fno-warn-wrong-do-bind")
 843 \end{code}