compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12 import TcRnMonad        -- temp
  13
  14 import CoreSyn
  15
  16 import DsCCall          ( dsCCall, mkFCall, boxResult, unboxArg, resultWrapper )
  17 import DsMonad
  18
  19 import HsSyn            ( ForeignDecl(..), ForeignExport(..), LForeignDecl,
  20                           ForeignImport(..), CImportSpec(..) )
  21 import DataCon          ( splitProductType_maybe )
  22 #ifdef DEBUG
  23 import DataCon          ( dataConSourceArity )
  24 import Type             ( isUnLiftedType )
  25 #endif
  26 import MachOp           ( machRepByteWidth, MachRep(..) )
  27 import SMRep            ( argMachRep, typeCgRep )
  28 import CoreUtils        ( exprType, mkInlineMe )
  29 import Id               ( Id, idType, idName, mkSysLocal, setInlinePragma )
  30 import Literal          ( Literal(..), mkStringLit )
  31 import Module           ( moduleNameFS, moduleName )
  32 import Name             ( getOccString, NamedThing(..) )
  33 import Type             ( repType, coreEqType )
  34 import TcType           ( Type, mkFunTys, mkForAllTys, mkTyConApp,
  35                           mkFunTy, tcSplitTyConApp_maybe, tcSplitIOType_maybe,
  36                           tcSplitForAllTys, tcSplitFunTys, tcTyConAppArgs,
  37                           isBoolTy
  38                         )
  39
  40 import BasicTypes       ( Boxity(..) )
  41 import HscTypes         ( ForeignStubs(..) )
  42 import ForeignCall      ( ForeignCall(..), CCallSpec(..),
  43                           Safety(..),
  44                           CExportSpec(..), CLabelString,
  45                           CCallConv(..), ccallConvToInt,
  46                           ccallConvAttribute
  47                         )
  48 import TysWiredIn       ( unitTy, tupleTyCon )
  49 import TysPrim          ( addrPrimTy, mkStablePtrPrimTy, alphaTy, intPrimTy )
  50 import PrelNames        ( stablePtrTyConName, newStablePtrName, bindIOName,
  51                           checkDotnetResName )
  52 import BasicTypes       ( Activation( NeverActive ) )
  53 import SrcLoc           ( Located(..), unLoc )
  54 import Outputable
  55 import Maybe            ( fromJust, isNothing )
  56 import FastString
  57 \end{code}
  58
  59 Desugaring of @foreign@ declarations is naturally split up into
  60 parts, an @import@ and an @export@  part. A @foreign import@
  61 declaration
  62 \begin{verbatim}
  63   foreign import cc nm f :: prim_args -> IO prim_res
  64 \end{verbatim}
  65 is the same as
  66 \begin{verbatim}
  67   f :: prim_args -> IO prim_res
  68   f a1 ... an = _ccall_ nm cc a1 ... an
  69 \end{verbatim}
  70 so we reuse the desugaring code in @DsCCall@ to deal with these.
  71
  72 \begin{code}
  73 type Binding = (Id, CoreExpr)   -- No rec/nonrec structure;
  74                                 -- the occurrence analyser will sort it all out
  75
  76 dsForeigns :: [LForeignDecl Id]
  77            -> DsM (ForeignStubs, [Binding])
  78 dsForeigns []
  79   = returnDs (NoStubs, [])
  80 dsForeigns fos
  81   = foldlDs combine (ForeignStubs empty empty [] [], []) fos
  82  where
  83   combine stubs (L loc decl) = putSrcSpanDs loc (combine1 stubs decl)
  84
  85   combine1 (ForeignStubs acc_h acc_c acc_hdrs acc_feb, acc_f)
  86            (ForeignImport id _ spec depr)
  87     = traceIf (text "fi start" <+> ppr id)      `thenDs` \ _ ->
  88       dsFImport (unLoc id) spec                 `thenDs` \ (bs, h, c, mbhd) ->
  89       warnDepr depr                             `thenDs` \ _                ->
  90       traceIf (text "fi end" <+> ppr id)        `thenDs` \ _ ->
  91       returnDs (ForeignStubs (h $$ acc_h)
  92                              (c $$ acc_c)
  93                              (addH mbhd acc_hdrs)
  94                              acc_feb,
  95                 bs ++ acc_f)
  96
  97   combine1 (ForeignStubs acc_h acc_c acc_hdrs acc_feb, acc_f)
  98            (ForeignExport (L _ id) _ (CExport (CExportStatic ext_nm cconv)) depr)
  99     = dsFExport id (idType id)
 100                 ext_nm cconv False                 `thenDs` \(h, c, _, _) ->
 101       warnDepr depr                                `thenDs` \_              ->
 102       returnDs (ForeignStubs (h $$ acc_h) (c $$ acc_c) acc_hdrs (id:acc_feb),
 103                 acc_f)
 104
 105   addH Nothing  ls = ls
 106   addH (Just e) ls
 107    | e `elem` ls = ls
 108    | otherwise   = e:ls
 109
 110   warnDepr False = returnDs ()
 111   warnDepr True  = dsWarn msg
 112      where
 113        msg = ptext SLIT("foreign declaration uses deprecated non-standard syntax")
 114 \end{code}
 115
 116
 117 %************************************************************************
 118 %*                                                                      *
 119 \subsection{Foreign import}
 120 %*                                                                      *
 121 %************************************************************************
 122
 123 Desugaring foreign imports is just the matter of creating a binding
 124 that on its RHS unboxes its arguments, performs the external call
 125 (using the @CCallOp@ primop), before boxing the result up and returning it.
 126
 127 However, we create a worker/wrapper pair, thus:
 128
 129         foreign import f :: Int -> IO Int
 130 ==>
 131         f x = IO ( \s -> case x of { I# x# ->
 132                          case fw s x# of { (# s1, y# #) ->
 133                          (# s1, I# y# #)}})
 134
 135         fw s x# = ccall f s x#
 136
 137 The strictness/CPR analyser won't do this automatically because it doesn't look
 138 inside returned tuples; but inlining this wrapper is a Really Good Idea
 139 because it exposes the boxing to the call site.
 140
 141 \begin{code}
 142 dsFImport :: Id
 143           -> ForeignImport
 144           -> DsM ([Binding], SDoc, SDoc, Maybe FastString)
 145 dsFImport id (CImport cconv safety header lib spec)
 146   = dsCImport id spec cconv safety no_hdrs        `thenDs` \(ids, h, c) ->
 147     returnDs (ids, h, c, if no_hdrs then Nothing else Just header)
 148   where
 149     no_hdrs = nullFS header
 150
 151   -- FIXME: the `lib' field is needed for .NET ILX generation when invoking
 152   --        routines that are external to the .NET runtime, but GHC doesn't
 153   --        support such calls yet; if `nullFastString lib', the value was not given
 154 dsFImport id (DNImport spec)
 155   = dsFCall id (DNCall spec) True {- No headers -} `thenDs` \(ids, h, c) ->
 156     returnDs (ids, h, c, Nothing)
 157
 158 dsCImport :: Id
 159           -> CImportSpec
 160           -> CCallConv
 161           -> Safety
 162           -> Bool       -- True <=> no headers in the f.i decl
 163           -> DsM ([Binding], SDoc, SDoc)
 164 dsCImport id (CLabel cid) _ _ no_hdrs
 165  = resultWrapper (idType id) `thenDs` \ (resTy, foRhs) ->
 166    ASSERT(fromJust resTy `coreEqType` addrPrimTy)    -- typechecker ensures this
 167     let rhs = foRhs (mkLit (MachLabel cid Nothing)) in
 168     returnDs ([(setImpInline no_hdrs id, rhs)], empty, empty)
 169 dsCImport id (CFunction target) cconv safety no_hdrs
 170   = dsFCall id (CCall (CCallSpec target cconv safety)) no_hdrs
 171 dsCImport id CWrapper cconv _ _
 172   = dsFExportDynamic id cconv
 173
 174 setImpInline :: Bool    -- True <=> No #include headers
 175                         -- in the foreign import declaration
 176              -> Id -> Id
 177 -- If there is a #include header in the foreign import
 178 -- we make the worker non-inlinable, because we currently
 179 -- don't keep the #include stuff in the CCallId, and hence
 180 -- it won't be visible in the importing module, which can be
 181 -- fatal.
 182 -- (The #include stuff is just collected from the foreign import
 183 --  decls in a module.)
 184 -- If you want to do cross-module inlining of the c-calls themselves,
 185 -- put the #include stuff in the package spec, not the foreign
 186 -- import decl.
 187 setImpInline True  id = id
 188 setImpInline False id = id `setInlinePragma` NeverActive
 189 \end{code}
 190
 191
 192 %************************************************************************
 193 %*                                                                      *
 194 \subsection{Foreign calls}
 195 %*                                                                      *
 196 %************************************************************************
 197
 198 \begin{code}
 199 dsFCall fn_id fcall no_hdrs
 200   = let
 201         ty                   = idType fn_id
 202         (tvs, fun_ty)        = tcSplitForAllTys ty
 203         (arg_tys, io_res_ty) = tcSplitFunTys fun_ty
 204                 -- Must use tcSplit* functions because we want to
 205                 -- see that (IO t) in the corner
 206     in
 207     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 208     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 209
 210     let
 211         work_arg_ids  = [v | Var v <- val_args] -- All guaranteed to be vars
 212
 213         forDotnet =
 214          case fcall of
 215            DNCall{} -> True
 216            _        -> False
 217
 218         topConDs
 219           | forDotnet =
 220              dsLookupGlobalId checkDotnetResName `thenDs` \ check_id ->
 221              return (Just check_id)
 222           | otherwise = return Nothing
 223
 224         augmentResultDs
 225           | forDotnet =
 226                 newSysLocalDs addrPrimTy `thenDs` \ err_res ->
 227                 returnDs (\ (mb_res_ty, resWrap) ->
 228                               case mb_res_ty of
 229                                 Nothing -> (Just (mkTyConApp (tupleTyCon Unboxed 1)
 230                                                              [ addrPrimTy ]),
 231                                                  resWrap)
 232                                 Just x  -> (Just (mkTyConApp (tupleTyCon Unboxed 2)
 233                                                              [ x, addrPrimTy ]),
 234                                                  resWrap))
 235           | otherwise = returnDs id
 236     in
 237     augmentResultDs                                  `thenDs` \ augment ->
 238     topConDs                                         `thenDs` \ topCon ->
 239     boxResult augment topCon io_res_ty `thenDs` \ (ccall_result_ty, res_wrapper) ->
 240
 241     newUnique                                   `thenDs` \ ccall_uniq ->
 242     newUnique                                   `thenDs` \ work_uniq ->
 243     let
 244         -- Build the worker
 245         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 246         the_ccall_app = mkFCall ccall_uniq fcall val_args ccall_result_ty
 247         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 248         work_id       = setImpInline no_hdrs $  -- See comments with setImpInline
 249                         mkSysLocal FSLIT("$wccall") work_uniq worker_ty
 250
 251         -- Build the wrapper
 252         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 253         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 254         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 255     in
 256     returnDs ([(work_id, work_rhs), (fn_id, wrap_rhs)], empty, empty)
 257 \end{code}
 258
 259
 260 %************************************************************************
 261 %*                                                                      *
 262 \subsection{Foreign export}
 263 %*                                                                      *
 264 %************************************************************************
 265
 266 The function that does most of the work for `@foreign export@' declarations.
 267 (see below for the boilerplate code a `@foreign export@' declaration expands
 268  into.)
 269
 270 For each `@foreign export foo@' in a module M we generate:
 271 \begin{itemize}
 272 \item a C function `@foo@', which calls
 273 \item a Haskell stub `@M.$ffoo@', which calls
 274 \end{itemize}
 275 the user-written Haskell function `@M.foo@'.
 276
 277 \begin{code}
 278 dsFExport :: Id                 -- Either the exported Id,
 279                                 -- or the foreign-export-dynamic constructor
 280           -> Type               -- The type of the thing callable from C
 281           -> CLabelString       -- The name to export to C land
 282           -> CCallConv
 283           -> Bool               -- True => foreign export dynamic
 284                                 --         so invoke IO action that's hanging off
 285                                 --         the first argument's stable pointer
 286           -> DsM ( SDoc         -- contents of Module_stub.h
 287                  , SDoc         -- contents of Module_stub.c
 288                  , [MachRep]    -- primitive arguments expected by stub function
 289                  , Int          -- size of args to stub function
 290                  )
 291
 292 dsFExport fn_id ty ext_name cconv isDyn
 293    =
 294      let
 295         (_tvs,sans_foralls)             = tcSplitForAllTys ty
 296         (fe_arg_tys', orig_res_ty)      = tcSplitFunTys sans_foralls
 297         -- We must use tcSplits here, because we want to see
 298         -- the (IO t) in the corner of the type!
 299         fe_arg_tys | isDyn     = tail fe_arg_tys'
 300                    | otherwise = fe_arg_tys'
 301      in
 302         -- Look at the result type of the exported function, orig_res_ty
 303         -- If it's IO t, return         (t, True)
 304         -- If it's plain t, return      (t, False)
 305      (case tcSplitIOType_maybe orig_res_ty of
 306         Just (ioTyCon, res_ty) -> returnDs (res_ty, True)
 307                 -- The function already returns IO t
 308         Nothing                -> returnDs (orig_res_ty, False)
 309                 -- The function returns t
 310      )                                  `thenDs` \ (res_ty,             -- t
 311                                                     is_IO_res_ty) ->    -- Bool
 312      returnDs $
 313        mkFExportCBits ext_name
 314                       (if isDyn then Nothing else Just fn_id)
 315                       fe_arg_tys res_ty is_IO_res_ty cconv
 316 \end{code}
 317
 318 @foreign import "wrapper"@ (previously "foreign export dynamic") lets
 319 you dress up Haskell IO actions of some fixed type behind an
 320 externally callable interface (i.e., as a C function pointer). Useful
 321 for callbacks and stuff.
 322
 323 \begin{verbatim}
 324 type Fun = Bool -> Int -> IO Int
 325 foreign import "wrapper" f :: Fun -> IO (FunPtr Fun)
 326
 327 -- Haskell-visible constructor, which is generated from the above:
 328 -- SUP: No check for NULL from createAdjustor anymore???
 329
 330 f :: Fun -> IO (FunPtr Fun)
 331 f cback =
 332    bindIO (newStablePtr cback)
 333           (\StablePtr sp# -> IO (\s1# ->
 334               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 335                  (# s2#, a# #) -> (# s2#, A# a# #)))
 336
 337 foreign import "&f_helper" f_helper :: FunPtr (StablePtr Fun -> Fun)
 338
 339 -- and the helper in C:
 340
 341 f_helper(StablePtr s, HsBool b, HsInt i)
 342 {
 343         rts_evalIO(rts_apply(rts_apply(deRefStablePtr(s),
 344                                        rts_mkBool(b)), rts_mkInt(i)));
 345 }
 346 \end{verbatim}
 347
 348 \begin{code}
 349 dsFExportDynamic :: Id
 350                  -> CCallConv
 351                  -> DsM ([Binding], SDoc, SDoc)
 352 dsFExportDynamic id cconv
 353   =  newSysLocalDs ty                            `thenDs` \ fe_id ->
 354      getModuleDs                                `thenDs` \ mod ->
 355      let
 356         -- hack: need to get at the name of the C stub we're about to generate.
 357        fe_nm       = mkFastString (unpackFS (zEncodeFS (moduleNameFS (moduleName mod))) ++ "_" ++ toCName fe_id)
 358      in
 359      newSysLocalDs arg_ty                       `thenDs` \ cback ->
 360      dsLookupGlobalId newStablePtrName          `thenDs` \ newStablePtrId ->
 361      dsLookupTyCon stablePtrTyConName           `thenDs` \ stable_ptr_tycon ->
 362      let
 363         mk_stbl_ptr_app = mkApps (Var newStablePtrId) [ Type arg_ty, Var cback ]
 364         stable_ptr_ty   = mkTyConApp stable_ptr_tycon [arg_ty]
 365         export_ty       = mkFunTy stable_ptr_ty arg_ty
 366      in
 367      dsLookupGlobalId bindIOName                `thenDs` \ bindIOId ->
 368      newSysLocalDs stable_ptr_ty                `thenDs` \ stbl_value ->
 369      dsFExport id export_ty fe_nm cconv True
 370                 `thenDs` \ (h_code, c_code, arg_reps, args_size) ->
 371      let
 372       stbl_app cont ret_ty = mkApps (Var bindIOId)
 373                                     [ Type stable_ptr_ty
 374                                     , Type ret_ty
 375                                     , mk_stbl_ptr_app
 376                                     , cont
 377                                     ]
 378        {-
 379         The arguments to the external function which will
 380         create a little bit of (template) code on the fly
 381         for allowing the (stable pointed) Haskell closure
 382         to be entered using an external calling convention
 383         (stdcall, ccall).
 384        -}
 385       adj_args      = [ mkIntLitInt (ccallConvToInt cconv)
 386                       , Var stbl_value
 387                       , mkLit (MachLabel fe_nm mb_sz_args)
 388                       , mkLit (mkStringLit arg_type_info)
 389                       ]
 390         -- name of external entry point providing these services.
 391         -- (probably in the RTS.)
 392       adjustor   = FSLIT("createAdjustor")
 393
 394       arg_type_info = map repCharCode arg_reps
 395       repCharCode F32 = 'f'
 396       repCharCode F64 = 'd'
 397       repCharCode I64 = 'l'
 398       repCharCode _   = 'i'
 399
 400         -- Determine the number of bytes of arguments to the stub function,
 401         -- so that we can attach the '@N' suffix to its label if it is a
 402         -- stdcall on Windows.
 403       mb_sz_args = case cconv of
 404                       StdCallConv -> Just args_size
 405                       _           -> Nothing
 406
 407      in
 408      dsCCall adjustor adj_args PlayRisky io_res_ty      `thenDs` \ ccall_adj ->
 409         -- PlayRisky: the adjustor doesn't allocate in the Haskell heap or do a callback
 410      let ccall_adj_ty = exprType ccall_adj
 411          ccall_io_adj = mkLams [stbl_value]                  $
 412                         Note (Coerce io_res_ty ccall_adj_ty)
 413                              ccall_adj
 414          io_app = mkLams tvs     $
 415                   mkLams [cback] $
 416                   stbl_app ccall_io_adj res_ty
 417          fed = (id `setInlinePragma` NeverActive, io_app)
 418                 -- Never inline the f.e.d. function, because the litlit
 419                 -- might not be in scope in other modules.
 420      in
 421      returnDs ([fed], h_code, c_code)
 422
 423  where
 424   ty                    = idType id
 425   (tvs,sans_foralls)    = tcSplitForAllTys ty
 426   ([arg_ty], io_res_ty) = tcSplitFunTys sans_foralls
 427   [res_ty]              = tcTyConAppArgs io_res_ty
 428         -- Must use tcSplit* to see the (IO t), which is a newtype
 429
 430 toCName :: Id -> String
 431 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 432 \end{code}
 433
 434 %*
 435 %
 436 \subsection{Generating @foreign export@ stubs}
 437 %
 438 %*
 439
 440 For each @foreign export@ function, a C stub function is generated.
 441 The C stub constructs the application of the exported Haskell function
 442 using the hugs/ghc rts invocation API.
 443
 444 \begin{code}
 445 mkFExportCBits :: FastString
 446                -> Maybe Id      -- Just==static, Nothing==dynamic
 447                -> [Type]
 448                -> Type
 449                -> Bool          -- True <=> returns an IO type
 450                -> CCallConv
 451                -> (SDoc,
 452                    SDoc,
 453                    [MachRep],   -- the argument reps
 454                    Int          -- total size of arguments
 455                   )
 456 mkFExportCBits c_nm maybe_target arg_htys res_hty is_IO_res_ty cc
 457  = (header_bits, c_bits,
 458     [rep | (_,_,_,rep) <- arg_info],  -- just the real args
 459     sum [ machRepByteWidth rep | (_,_,_,rep) <- aug_arg_info] -- all the args
 460     )
 461  where
 462   -- list the arguments to the C function
 463   arg_info :: [(SDoc,           -- arg name
 464                 SDoc,           -- C type
 465                 Type,           -- Haskell type
 466                 MachRep)]       -- the MachRep
 467   arg_info  = [ (text ('a':show n), showStgType ty, ty,
 468                  typeMachRep (getPrimTyOf ty))
 469               | (ty,n) <- zip arg_htys [1..] ]
 470
 471   -- add some auxiliary args; the stable ptr in the wrapper case, and
 472   -- a slot for the dummy return address in the wrapper + ccall case
 473   aug_arg_info
 474     | isNothing maybe_target = stable_ptr_arg : insertRetAddr cc arg_info
 475     | otherwise              = arg_info
 476
 477   stable_ptr_arg =
 478         (text "the_stableptr", text "StgStablePtr", undefined,
 479          typeMachRep (mkStablePtrPrimTy alphaTy))
 480
 481   -- stuff to do with the return type of the C function
 482   res_hty_is_unit = res_hty `coreEqType` unitTy -- Look through any newtypes
 483
 484   cResType | res_hty_is_unit = text "void"
 485            | otherwise       = showStgType res_hty
 486
 487   -- Now we can cook up the prototype for the exported function.
 488   pprCconv = case cc of
 489                 CCallConv   -> empty
 490                 StdCallConv -> text (ccallConvAttribute cc)
 491
 492   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 493
 494   fun_proto = cResType <+> pprCconv <+> ftext c_nm <>
 495               parens (hsep (punctuate comma (map (\(nm,ty,_,_) -> ty <+> nm)
 496                                                  aug_arg_info)))
 497
 498   -- the target which will form the root of what we ask rts_evalIO to run
 499   the_cfun
 500      = case maybe_target of
 501           Nothing    -> text "(StgClosure*)deRefStablePtr(the_stableptr)"
 502           Just hs_fn -> char '&' <> ppr hs_fn <> text "_closure"
 503
 504   cap = text "cap" <> comma
 505
 506   -- the expression we give to rts_evalIO
 507   expr_to_run
 508      = foldl appArg the_cfun arg_info -- NOT aug_arg_info
 509        where
 510           appArg acc (arg_cname, _, arg_hty, _)
 511              = text "rts_apply"
 512                <> parens (cap <> acc <> comma <> mkHObj arg_hty <> parens (cap <> arg_cname))
 513
 514   -- various other bits for inside the fn
 515   declareResult = text "HaskellObj ret;"
 516   declareCResult | res_hty_is_unit = empty
 517                  | otherwise       = cResType <+> text "cret;"
 518
 519   assignCResult | res_hty_is_unit = empty
 520                 | otherwise       =
 521                         text "cret=" <> unpackHObj res_hty <> parens (text "ret") <> semi
 522
 523   -- an extern decl for the fn being called
 524   extern_decl
 525      = case maybe_target of
 526           Nothing -> empty
 527           Just hs_fn -> text "extern StgClosure " <> ppr hs_fn <> text "_closure" <> semi
 528
 529
 530    -- Initialise foreign exports by registering a stable pointer from an
 531    -- __attribute__((constructor)) function.
 532    -- The alternative is to do this from stginit functions generated in
 533    -- codeGen/CodeGen.lhs; however, stginit functions have a negative impact
 534    -- on binary sizes and link times because the static linker will think that
 535    -- all modules that are imported directly or indirectly are actually used by
 536    -- the program.
 537    -- (this is bad for big umbrella modules like Graphics.Rendering.OpenGL)
 538
 539   initialiser
 540      = case maybe_target of
 541           Nothing -> empty
 542           Just hs_fn ->
 543             vcat
 544              [ text "static void stginit_export_" <> ppr hs_fn
 545                   <> text "() __attribute__((constructor));"
 546              , text "static void stginit_export_" <> ppr hs_fn <> text "()"
 547              , braces (text "getStablePtr"
 548                 <> parens (text "(StgPtr) &" <> ppr hs_fn <> text "_closure")
 549                 <> semi)
 550              ]
 551
 552   -- finally, the whole darn thing
 553   c_bits =
 554     space $$
 555     extern_decl $$
 556     fun_proto  $$
 557     vcat
 558      [ lbrace
 559      ,   text "Capability *cap;"
 560      ,   declareResult
 561      ,   declareCResult
 562      ,   text "cap = rts_lock();"
 563           -- create the application + perform it.
 564      ,   text "cap=rts_evalIO" <> parens (
 565                 cap <>
 566                 text "rts_apply" <> parens (
 567                     cap <>
 568                     text "(HaskellObj)"
 569                  <> text (if is_IO_res_ty
 570                                 then "runIO_closure"
 571                                 else "runNonIO_closure")
 572                  <> comma
 573                  <> expr_to_run
 574                 ) <+> comma
 575                <> text "&ret"
 576              ) <> semi
 577      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ftext c_nm)
 578                                                 <> comma <> text "cap") <> semi
 579      ,   assignCResult
 580      ,   text "rts_unlock(cap);"
 581      ,   if res_hty_is_unit then empty
 582             else text "return cret;"
 583      , rbrace
 584      ] $$
 585     initialiser
 586
 587 -- NB. the calculation here isn't strictly speaking correct.
 588 -- We have a primitive Haskell type (eg. Int#, Double#), and
 589 -- we want to know the size, when passed on the C stack, of
 590 -- the associated C type (eg. HsInt, HsDouble).  We don't have
 591 -- this information to hand, but we know what GHC's conventions
 592 -- are for passing around the primitive Haskell types, so we
 593 -- use that instead.  I hope the two coincide --SDM
 594 typeMachRep ty = argMachRep (typeCgRep ty)
 595
 596 mkHObj :: Type -> SDoc
 597 mkHObj t = text "rts_mk" <> text (showFFIType t)
 598
 599 unpackHObj :: Type -> SDoc
 600 unpackHObj t = text "rts_get" <> text (showFFIType t)
 601
 602 showStgType :: Type -> SDoc
 603 showStgType t = text "Hs" <> text (showFFIType t)
 604
 605 showFFIType :: Type -> String
 606 showFFIType t = getOccString (getName tc)
 607  where
 608   tc = case tcSplitTyConApp_maybe (repType t) of
 609             Just (tc,_) -> tc
 610             Nothing     -> pprPanic "showFFIType" (ppr t)
 611
 612 #if !defined(x86_64_TARGET_ARCH)
 613 insertRetAddr CCallConv args = ret_addr_arg : args
 614 insertRetAddr _ args = args
 615 #else
 616 -- On x86_64 we insert the return address after the 6th
 617 -- integer argument, because this is the point at which we
 618 -- need to flush a register argument to the stack (See rts/Adjustor.c for
 619 -- details).
 620 insertRetAddr CCallConv args = go 0 args
 621   where  go 6 args = ret_addr_arg : args
 622          go n (arg@(_,_,_,rep):args)
 623           | I64 <- rep = arg : go (n+1) args
 624           | otherwise  = arg : go n     args
 625          go n [] = []
 626 insertRetAddr _ args = args
 627 #endif
 628
 629 ret_addr_arg = (text "original_return_addr", text "void*", undefined,
 630                 typeMachRep addrPrimTy)
 631
 632 -- This function returns the primitive type associated with the boxed
 633 -- type argument to a foreign export (eg. Int ==> Int#).
 634 getPrimTyOf :: Type -> Type
 635 getPrimTyOf ty
 636   | isBoolTy rep_ty = intPrimTy
 637   -- Except for Bool, the types we are interested in have a single constructor
 638   -- with a single primitive-typed argument (see TcType.legalFEArgTyCon).
 639   | otherwise =
 640   case splitProductType_maybe rep_ty of
 641      Just (_, _, data_con, [prim_ty]) ->
 642         ASSERT(dataConSourceArity data_con == 1)
 643         ASSERT2(isUnLiftedType prim_ty, ppr prim_ty)
 644         prim_ty
 645      _other -> pprPanic "DsForeign.getPrimTyOf" (ppr ty)
 646   where
 647         rep_ty = repType ty
 648 \end{code}