compiler/deSugar/DsUtils.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[DsUtils]{Utilities for desugaring}
   5
   6 This module exports some utility functions of no great interest.
   7
   8 \begin{code}
   9 module DsUtils (
  10         EquationInfo(..),
  11         firstPat, shiftEqns,
  12
  13         mkDsLet, mkDsLets,
  14
  15         MatchResult(..), CanItFail(..),
  16         cantFailMatchResult, alwaysFailMatchResult,
  17         extractMatchResult, combineMatchResults,
  18         adjustMatchResult,  adjustMatchResultDs,
  19         mkCoLetMatchResult, mkGuardedMatchResult,
  20         matchCanFail,
  21         mkCoPrimCaseMatchResult, mkCoAlgCaseMatchResult,
  22         wrapBind, wrapBinds,
  23
  24         mkErrorAppDs, mkNilExpr, mkConsExpr, mkListExpr,
  25         mkIntExpr, mkCharExpr,
  26         mkStringExpr, mkStringExprFS, mkIntegerExpr,
  27
  28         mkSelectorBinds, mkTupleExpr, mkTupleSelector,
  29         mkTupleType, mkTupleCase, mkBigCoreTup,
  30         mkCoreTup, mkCoreTupTy, seqVar,
  31
  32         dsSyntaxTable, lookupEvidence,
  33
  34         selectSimpleMatchVarL, selectMatchVars, selectMatchVar
  35     ) where
  36
  37 #include "HsVersions.h"
  38
  39 import {-# SOURCE #-}   Match ( matchSimply )
  40 import {-# SOURCE #-}   DsExpr( dsExpr )
  41
  42 import HsSyn
  43 import TcHsSyn          ( hsPatType )
  44 import CoreSyn
  45 import Constants        ( mAX_TUPLE_SIZE )
  46 import DsMonad
  47
  48 import CoreUtils        ( exprType, mkIfThenElse, mkCoerce, bindNonRec )
  49 import MkId             ( iRREFUT_PAT_ERROR_ID, mkReboxingAlt, mkNewTypeBody )
  50 import Id               ( idType, Id, mkWildId, mkTemplateLocals, mkSysLocal )
  51 import Var              ( Var )
  52 import Name             ( Name )
  53 import Literal          ( Literal(..), mkStringLit, inIntRange, tARGET_MAX_INT )
  54 import TyCon            ( isNewTyCon, tyConDataCons )
  55 import DataCon          ( DataCon, dataConSourceArity, dataConTyCon, dataConTag )
  56 import Type             ( mkFunTy, isUnLiftedType, Type, splitTyConApp, mkTyVarTy )
  57 import TcType           ( tcEqType )
  58 import TysPrim          ( intPrimTy )
  59 import TysWiredIn       ( nilDataCon, consDataCon,
  60                           tupleCon, mkTupleTy,
  61                           unitDataConId, unitTy,
  62                           charTy, charDataCon,
  63                           intTy, intDataCon,
  64                           isPArrFakeCon )
  65 import BasicTypes       ( Boxity(..) )
  66 import UniqSet          ( mkUniqSet, minusUniqSet, isEmptyUniqSet )
  67 import UniqSupply       ( splitUniqSupply, uniqFromSupply, uniqsFromSupply )
  68 import PrelNames        ( unpackCStringName, unpackCStringUtf8Name,
  69                           plusIntegerName, timesIntegerName, smallIntegerDataConName,
  70                           lengthPName, indexPName )
  71 import Outputable
  72 import SrcLoc           ( Located(..), unLoc )
  73 import Util             ( isSingleton, zipEqual, sortWith )
  74 import ListSetOps       ( assocDefault )
  75 import FastString
  76 import Data.Char        ( ord )
  77
  78 #ifdef DEBUG
  79 import Util             ( notNull )     -- Used in an assertion
  80 #endif
  81 \end{code}
  82
  83
  84
  85 %************************************************************************
  86 %*                                                                      *
  87                 Rebindable syntax
  88 %*                                                                      *
  89 %************************************************************************
  90
  91 \begin{code}
  92 dsSyntaxTable :: SyntaxTable Id
  93                -> DsM ([CoreBind],      -- Auxiliary bindings
  94                        [(Name,Id)])     -- Maps the standard name to its value
  95
  96 dsSyntaxTable rebound_ids
  97   = mapAndUnzipDs mk_bind rebound_ids   `thenDs` \ (binds_s, prs) ->
  98     return (concat binds_s, prs)
  99   where
 100         -- The cheapo special case can happen when we
 101         -- make an intermediate HsDo when desugaring a RecStmt
 102     mk_bind (std_name, HsVar id) = return ([], (std_name, id))
 103     mk_bind (std_name, expr)
 104          = dsExpr expr                          `thenDs` \ rhs ->
 105            newSysLocalDs (exprType rhs)         `thenDs` \ id ->
 106            return ([NonRec id rhs], (std_name, id))
 107
 108 lookupEvidence :: [(Name, Id)] -> Name -> Id
 109 lookupEvidence prs std_name
 110   = assocDefault (mk_panic std_name) prs std_name
 111   where
 112     mk_panic std_name = pprPanic "dsSyntaxTable" (ptext SLIT("Not found:") <+> ppr std_name)
 113 \end{code}
 114
 115
 116 %************************************************************************
 117 %*                                                                      *
 118 \subsection{Building lets}
 119 %*                                                                      *
 120 %************************************************************************
 121
 122 Use case, not let for unlifted types.  The simplifier will turn some
 123 back again.
 124
 125 \begin{code}
 126 mkDsLet :: CoreBind -> CoreExpr -> CoreExpr
 127 mkDsLet (NonRec bndr rhs) body
 128   | isUnLiftedType (idType bndr)
 129   = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 130 mkDsLet bind body
 131   = Let bind body
 132
 133 mkDsLets :: [CoreBind] -> CoreExpr -> CoreExpr
 134 mkDsLets binds body = foldr mkDsLet body binds
 135 \end{code}
 136
 137
 138 %************************************************************************
 139 %*                                                                      *
 140 \subsection{ Selecting match variables}
 141 %*                                                                      *
 142 %************************************************************************
 143
 144 We're about to match against some patterns.  We want to make some
 145 @Ids@ to use as match variables.  If a pattern has an @Id@ readily at
 146 hand, which should indeed be bound to the pattern as a whole, then use it;
 147 otherwise, make one up.
 148
 149 \begin{code}
 150 selectSimpleMatchVarL :: LPat Id -> DsM Id
 151 selectSimpleMatchVarL pat = selectMatchVar (unLoc pat) (hsPatType pat)
 152
 153 -- (selectMatchVars ps tys) chooses variables of type tys
 154 -- to use for matching ps against.  If the pattern is a variable,
 155 -- we try to use that, to save inventing lots of fresh variables.
 156 -- But even if it is a variable, its type might not match.  Consider
 157 --      data T a where
 158 --        T1 :: Int -> T Int
 159 --        T2 :: a   -> T a
 160 --
 161 --      f :: T a -> a -> Int
 162 --      f (T1 i) (x::Int) = x
 163 --      f (T2 i) (y::a)   = 0
 164 -- Then we must not choose (x::Int) as the matching variable!
 165
 166 selectMatchVars :: [Pat Id] -> [Type] -> DsM [Id]
 167 selectMatchVars []     []       = return []
 168 selectMatchVars (p:ps) (ty:tys) = do { v  <- selectMatchVar  p  ty
 169                                      ; vs <- selectMatchVars ps tys
 170                                      ; return (v:vs) }
 171
 172 selectMatchVar (BangPat pat)   pat_ty  = selectMatchVar (unLoc pat) pat_ty
 173 selectMatchVar (LazyPat pat)   pat_ty  = selectMatchVar (unLoc pat) pat_ty
 174 selectMatchVar (VarPat var)    pat_ty  = try_for var         pat_ty
 175 selectMatchVar (AsPat var pat) pat_ty  = try_for (unLoc var) pat_ty
 176 selectMatchVar other_pat       pat_ty  = newSysLocalDs pat_ty   -- OK, better make up one...
 177
 178 try_for var pat_ty
 179   | idType var `tcEqType` pat_ty = returnDs var
 180   | otherwise                    = newSysLocalDs pat_ty
 181 \end{code}
 182
 183
 184 %************************************************************************
 185 %*                                                                      *
 186 %* type synonym EquationInfo and access functions for its pieces        *
 187 %*                                                                      *
 188 %************************************************************************
 189 \subsection[EquationInfo-synonym]{@EquationInfo@: a useful synonym}
 190
 191 The ``equation info'' used by @match@ is relatively complicated and
 192 worthy of a type synonym and a few handy functions.
 193
 194 \begin{code}
 195 firstPat :: EquationInfo -> Pat Id
 196 firstPat eqn = head (eqn_pats eqn)
 197
 198 shiftEqns :: [EquationInfo] -> [EquationInfo]
 199 -- Drop the first pattern in each equation
 200 shiftEqns eqns = [ eqn { eqn_pats = tail (eqn_pats eqn) } | eqn <- eqns ]
 201 \end{code}
 202
 203 Functions on MatchResults
 204
 205 \begin{code}
 206 matchCanFail :: MatchResult -> Bool
 207 matchCanFail (MatchResult CanFail _)  = True
 208 matchCanFail (MatchResult CantFail _) = False
 209
 210 alwaysFailMatchResult :: MatchResult
 211 alwaysFailMatchResult = MatchResult CanFail (\fail -> returnDs fail)
 212
 213 cantFailMatchResult :: CoreExpr -> MatchResult
 214 cantFailMatchResult expr = MatchResult CantFail (\ ignore -> returnDs expr)
 215
 216 extractMatchResult :: MatchResult -> CoreExpr -> DsM CoreExpr
 217 extractMatchResult (MatchResult CantFail match_fn) fail_expr
 218   = match_fn (error "It can't fail!")
 219
 220 extractMatchResult (MatchResult CanFail match_fn) fail_expr
 221   = mkFailurePair fail_expr             `thenDs` \ (fail_bind, if_it_fails) ->
 222     match_fn if_it_fails                `thenDs` \ body ->
 223     returnDs (mkDsLet fail_bind body)
 224
 225
 226 combineMatchResults :: MatchResult -> MatchResult -> MatchResult
 227 combineMatchResults (MatchResult CanFail      body_fn1)
 228                     (MatchResult can_it_fail2 body_fn2)
 229   = MatchResult can_it_fail2 body_fn
 230   where
 231     body_fn fail = body_fn2 fail                        `thenDs` \ body2 ->
 232                    mkFailurePair body2                  `thenDs` \ (fail_bind, duplicatable_expr) ->
 233                    body_fn1 duplicatable_expr           `thenDs` \ body1 ->
 234                    returnDs (Let fail_bind body1)
 235
 236 combineMatchResults match_result1@(MatchResult CantFail body_fn1) match_result2
 237   = match_result1
 238
 239 adjustMatchResult :: (CoreExpr -> CoreExpr) -> MatchResult -> MatchResult
 240 adjustMatchResult encl_fn (MatchResult can_it_fail body_fn)
 241   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 242                                       returnDs (encl_fn body))
 243
 244 adjustMatchResultDs :: (CoreExpr -> DsM CoreExpr) -> MatchResult -> MatchResult
 245 adjustMatchResultDs encl_fn (MatchResult can_it_fail body_fn)
 246   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 247                                       encl_fn body)
 248
 249 wrapBinds :: [(Var,Var)] -> CoreExpr -> CoreExpr
 250 wrapBinds [] e = e
 251 wrapBinds ((new,old):prs) e = wrapBind new old (wrapBinds prs e)
 252
 253 wrapBind :: Var -> Var -> CoreExpr -> CoreExpr
 254 wrapBind new old body
 255   | new==old    = body
 256   | isTyVar new = App (Lam new body) (Type (mkTyVarTy old))
 257   | otherwise   = Let (NonRec new (Var old)) body
 258
 259 seqVar :: Var -> CoreExpr -> CoreExpr
 260 seqVar var body = Case (Var var) var (exprType body)
 261                         [(DEFAULT, [], body)]
 262
 263 mkCoLetMatchResult :: CoreBind -> MatchResult -> MatchResult
 264 mkCoLetMatchResult bind match_result
 265   = adjustMatchResult (mkDsLet bind) match_result
 266
 267 mkGuardedMatchResult :: CoreExpr -> MatchResult -> MatchResult
 268 mkGuardedMatchResult pred_expr (MatchResult can_it_fail body_fn)
 269   = MatchResult CanFail (\fail -> body_fn fail  `thenDs` \ body ->
 270                                   returnDs (mkIfThenElse pred_expr body fail))
 271
 272 mkCoPrimCaseMatchResult :: Id                           -- Scrutinee
 273                     -> Type                             -- Type of the case
 274                     -> [(Literal, MatchResult)]         -- Alternatives
 275                     -> MatchResult
 276 mkCoPrimCaseMatchResult var ty match_alts
 277   = MatchResult CanFail mk_case
 278   where
 279     mk_case fail
 280       = mappM (mk_alt fail) sorted_alts         `thenDs` \ alts ->
 281         returnDs (Case (Var var) var ty ((DEFAULT, [], fail) : alts))
 282
 283     sorted_alts = sortWith fst match_alts       -- Right order for a Case
 284     mk_alt fail (lit, MatchResult _ body_fn) = body_fn fail     `thenDs` \ body ->
 285                                                returnDs (LitAlt lit, [], body)
 286
 287
 288 mkCoAlgCaseMatchResult :: Id                                    -- Scrutinee
 289                     -> Type                                     -- Type of exp
 290                     -> [(DataCon, [CoreBndr], MatchResult)]     -- Alternatives
 291                     -> MatchResult
 292 mkCoAlgCaseMatchResult var ty match_alts
 293   | isNewTyCon tycon            -- Newtype case; use a let
 294   = ASSERT( null (tail match_alts) && null (tail arg_ids1) )
 295     mkCoLetMatchResult (NonRec arg_id1 newtype_rhs) match_result1
 296
 297   | isPArrFakeAlts match_alts   -- Sugared parallel array; use a literal case
 298   = MatchResult CanFail mk_parrCase
 299
 300   | otherwise                   -- Datatype case; use a case
 301   = MatchResult fail_flag mk_case
 302   where
 303     tycon = dataConTyCon con1
 304         -- [Interesting: becuase of GADTs, we can't rely on the type of
 305         --  the scrutinised Id to be sufficiently refined to have a TyCon in it]
 306
 307         -- Stuff for newtype
 308     (con1, arg_ids1, match_result1) = head match_alts
 309     arg_id1     = head arg_ids1
 310     newtype_rhs = mkNewTypeBody tycon (idType arg_id1) (Var var)
 311
 312         -- Stuff for data types
 313     data_cons      = tyConDataCons tycon
 314     match_results  = [match_result | (_,_,match_result) <- match_alts]
 315
 316     fail_flag | exhaustive_case
 317               = foldr1 orFail [can_it_fail | MatchResult can_it_fail _ <- match_results]
 318               | otherwise
 319               = CanFail
 320
 321     wild_var = mkWildId (idType var)
 322     sorted_alts  = sortWith get_tag match_alts
 323     get_tag (con, _, _) = dataConTag con
 324     mk_case fail = mappM (mk_alt fail) sorted_alts      `thenDs` \ alts ->
 325                    returnDs (Case (Var var) wild_var ty (mk_default fail ++ alts))
 326
 327     mk_alt fail (con, args, MatchResult _ body_fn)
 328         = body_fn fail                          `thenDs` \ body ->
 329           newUniqueSupply                       `thenDs` \ us ->
 330           returnDs (mkReboxingAlt (uniqsFromSupply us) con args body)
 331
 332     mk_default fail | exhaustive_case = []
 333                     | otherwise       = [(DEFAULT, [], fail)]
 334
 335     un_mentioned_constructors
 336         = mkUniqSet data_cons `minusUniqSet` mkUniqSet [ con | (con, _, _) <- match_alts]
 337     exhaustive_case = isEmptyUniqSet un_mentioned_constructors
 338
 339         -- Stuff for parallel arrays
 340         --
 341         --  * the following is to desugar cases over fake constructors for
 342         --   parallel arrays, which are introduced by `tidy1' in the `PArrPat'
 343         --   case
 344         --
 345         -- Concerning `isPArrFakeAlts':
 346         --
 347         --  * it is *not* sufficient to just check the type of the type
 348         --   constructor, as we have to be careful not to confuse the real
 349         --   representation of parallel arrays with the fake constructors;
 350         --   moreover, a list of alternatives must not mix fake and real
 351         --   constructors (this is checked earlier on)
 352         --
 353         -- FIXME: We actually go through the whole list and make sure that
 354         --        either all or none of the constructors are fake parallel
 355         --        array constructors.  This is to spot equations that mix fake
 356         --        constructors with the real representation defined in
 357         --        `PrelPArr'.  It would be nicer to spot this situation
 358         --        earlier and raise a proper error message, but it can really
 359         --        only happen in `PrelPArr' anyway.
 360         --
 361     isPArrFakeAlts [(dcon, _, _)]      = isPArrFakeCon dcon
 362     isPArrFakeAlts ((dcon, _, _):alts) =
 363       case (isPArrFakeCon dcon, isPArrFakeAlts alts) of
 364         (True , True ) -> True
 365         (False, False) -> False
 366         _              ->
 367           panic "DsUtils: You may not mix `[:...:]' with `PArr' patterns"
 368     --
 369     mk_parrCase fail =
 370       dsLookupGlobalId lengthPName                      `thenDs` \lengthP  ->
 371       unboxAlt                                          `thenDs` \alt      ->
 372       returnDs (Case (len lengthP) (mkWildId intTy) ty [alt])
 373       where
 374         elemTy      = case splitTyConApp (idType var) of
 375                         (_, [elemTy]) -> elemTy
 376                         _               -> panic panicMsg
 377         panicMsg    = "DsUtils.mkCoAlgCaseMatchResult: not a parallel array?"
 378         len lengthP = mkApps (Var lengthP) [Type elemTy, Var var]
 379         --
 380         unboxAlt =
 381           newSysLocalDs intPrimTy                       `thenDs` \l        ->
 382           dsLookupGlobalId indexPName                   `thenDs` \indexP   ->
 383           mappM (mkAlt indexP) sorted_alts              `thenDs` \alts     ->
 384           returnDs (DataAlt intDataCon, [l], (Case (Var l) wild ty (dft : alts)))
 385           where
 386             wild = mkWildId intPrimTy
 387             dft  = (DEFAULT, [], fail)
 388         --
 389         -- each alternative matches one array length (corresponding to one
 390         -- fake array constructor), so the match is on a literal; each
 391         -- alternative's body is extended by a local binding for each
 392         -- constructor argument, which are bound to array elements starting
 393         -- with the first
 394         --
 395         mkAlt indexP (con, args, MatchResult _ bodyFun) =
 396           bodyFun fail                                  `thenDs` \body     ->
 397           returnDs (LitAlt lit, [], mkDsLets binds body)
 398           where
 399             lit   = MachInt $ toInteger (dataConSourceArity con)
 400             binds = [NonRec arg (indexExpr i) | (i, arg) <- zip [1..] args]
 401             --
 402             indexExpr i = mkApps (Var indexP) [Type elemTy, Var var, mkIntExpr i]
 403 \end{code}
 404
 405
 406 %************************************************************************
 407 %*                                                                      *
 408 \subsection{Desugarer's versions of some Core functions}
 409 %*                                                                      *
 410 %************************************************************************
 411
 412 \begin{code}
 413 mkErrorAppDs :: Id              -- The error function
 414              -> Type            -- Type to which it should be applied
 415              -> String          -- The error message string to pass
 416              -> DsM CoreExpr
 417
 418 mkErrorAppDs err_id ty msg
 419   = getSrcSpanDs                `thenDs` \ src_loc ->
 420     let
 421         full_msg = showSDoc (hcat [ppr src_loc, text "|", text msg])
 422         core_msg = Lit (mkStringLit full_msg)
 423         -- mkStringLit returns a result of type String#
 424     in
 425     returnDs (mkApps (Var err_id) [Type ty, core_msg])
 426 \end{code}
 427
 428
 429 *************************************************************
 430 %*                                                                      *
 431 \subsection{Making literals}
 432 %*                                                                      *
 433 %************************************************************************
 434
 435 \begin{code}
 436 mkCharExpr     :: Char       -> CoreExpr      -- Returns        C# c :: Int
 437 mkIntExpr      :: Integer    -> CoreExpr      -- Returns        I# i :: Int
 438 mkIntegerExpr  :: Integer    -> DsM CoreExpr  -- Result :: Integer
 439 mkStringExpr   :: String     -> DsM CoreExpr  -- Result :: String
 440 mkStringExprFS :: FastString -> DsM CoreExpr  -- Result :: String
 441
 442 mkIntExpr  i = mkConApp intDataCon  [mkIntLit i]
 443 mkCharExpr c = mkConApp charDataCon [mkLit (MachChar c)]
 444
 445 mkIntegerExpr i
 446   | inIntRange i        -- Small enough, so start from an Int
 447   = dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 448     returnDs (mkSmallIntegerLit integer_dc i)
 449
 450 -- Special case for integral literals with a large magnitude:
 451 -- They are transformed into an expression involving only smaller
 452 -- integral literals. This improves constant folding.
 453
 454   | otherwise           -- Big, so start from a string
 455   = dsLookupGlobalId plusIntegerName            `thenDs` \ plus_id ->
 456     dsLookupGlobalId timesIntegerName           `thenDs` \ times_id ->
 457     dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 458     let
 459         lit i = mkSmallIntegerLit integer_dc i
 460         plus a b  = Var plus_id  `App` a `App` b
 461         times a b = Var times_id `App` a `App` b
 462
 463         -- Transform i into (x1 + (x2 + (x3 + (...) * b) * b) * b) with abs xi <= b
 464         horner :: Integer -> Integer -> CoreExpr
 465         horner b i | abs q <= 1 = if r == 0 || r == i
 466                                   then lit i
 467                                   else lit r `plus` lit (i-r)
 468                    | r == 0     =               horner b q `times` lit b
 469                    | otherwise  = lit r `plus` (horner b q `times` lit b)
 470                    where
 471                      (q,r) = i `quotRem` b
 472
 473     in
 474     returnDs (horner tARGET_MAX_INT i)
 475
 476 mkSmallIntegerLit small_integer_data_con i = mkConApp small_integer_data_con [mkIntLit i]
 477
 478 mkStringExpr str = mkStringExprFS (mkFastString str)
 479
 480 mkStringExprFS str
 481   | nullFS str
 482   = returnDs (mkNilExpr charTy)
 483
 484   | lengthFS str == 1
 485   = let
 486         the_char = mkCharExpr (headFS str)
 487     in
 488     returnDs (mkConsExpr charTy the_char (mkNilExpr charTy))
 489
 490   | all safeChar chars
 491   = dsLookupGlobalId unpackCStringName  `thenDs` \ unpack_id ->
 492     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 493
 494   | otherwise
 495   = dsLookupGlobalId unpackCStringUtf8Name      `thenDs` \ unpack_id ->
 496     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 497
 498   where
 499     chars = unpackFS str
 500     safeChar c = ord c >= 1 && ord c <= 0x7F
 501 \end{code}
 502
 503
 504 %************************************************************************
 505 %*                                                                      *
 506 \subsection[mkSelectorBind]{Make a selector bind}
 507 %*                                                                      *
 508 %************************************************************************
 509
 510 This is used in various places to do with lazy patterns.
 511 For each binder $b$ in the pattern, we create a binding:
 512 \begin{verbatim}
 513     b = case v of pat' -> b'
 514 \end{verbatim}
 515 where @pat'@ is @pat@ with each binder @b@ cloned into @b'@.
 516
 517 ToDo: making these bindings should really depend on whether there's
 518 much work to be done per binding.  If the pattern is complex, it
 519 should be de-mangled once, into a tuple (and then selected from).
 520 Otherwise the demangling can be in-line in the bindings (as here).
 521
 522 Boring!  Boring!  One error message per binder.  The above ToDo is
 523 even more helpful.  Something very similar happens for pattern-bound
 524 expressions.
 525
 526 \begin{code}
 527 mkSelectorBinds :: LPat Id      -- The pattern
 528                 -> CoreExpr     -- Expression to which the pattern is bound
 529                 -> DsM [(Id,CoreExpr)]
 530
 531 mkSelectorBinds (L _ (VarPat v)) val_expr
 532   = returnDs [(v, val_expr)]
 533
 534 mkSelectorBinds pat val_expr
 535   | isSingleton binders || is_simple_lpat pat
 536   =     -- Given   p = e, where p binds x,y
 537         -- we are going to make
 538         --      v = p   (where v is fresh)
 539         --      x = case v of p -> x
 540         --      y = case v of p -> x
 541
 542         -- Make up 'v'
 543         -- NB: give it the type of *pattern* p, not the type of the *rhs* e.
 544         -- This does not matter after desugaring, but there's a subtle
 545         -- issue with implicit parameters. Consider
 546         --      (x,y) = ?i
 547         -- Then, ?i is given type {?i :: Int}, a PredType, which is opaque
 548         -- to the desugarer.  (Why opaque?  Because newtypes have to be.  Why
 549         -- does it get that type?  So that when we abstract over it we get the
 550         -- right top-level type  (?i::Int) => ...)
 551         --
 552         -- So to get the type of 'v', use the pattern not the rhs.  Often more
 553         -- efficient too.
 554     newSysLocalDs (hsPatType pat)       `thenDs` \ val_var ->
 555
 556         -- For the error message we make one error-app, to avoid duplication.
 557         -- But we need it at different types... so we use coerce for that
 558     mkErrorAppDs iRREFUT_PAT_ERROR_ID
 559                  unitTy (showSDoc (ppr pat))    `thenDs` \ err_expr ->
 560     newSysLocalDs unitTy                        `thenDs` \ err_var ->
 561     mappM (mk_bind val_var err_var) binders     `thenDs` \ binds ->
 562     returnDs ( (val_var, val_expr) :
 563                (err_var, err_expr) :
 564                binds )
 565
 566
 567   | otherwise
 568   = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 569                  tuple_ty (showSDoc (ppr pat))                  `thenDs` \ error_expr ->
 570     matchSimply val_expr PatBindRhs pat local_tuple error_expr  `thenDs` \ tuple_expr ->
 571     newSysLocalDs tuple_ty                                      `thenDs` \ tuple_var ->
 572     let
 573         mk_tup_bind binder
 574           = (binder, mkTupleSelector binders binder tuple_var (Var tuple_var))
 575     in
 576     returnDs ( (tuple_var, tuple_expr) : map mk_tup_bind binders )
 577   where
 578     binders     = collectPatBinders pat
 579     local_tuple = mkTupleExpr binders
 580     tuple_ty    = exprType local_tuple
 581
 582     mk_bind scrut_var err_var bndr_var
 583     -- (mk_bind sv err_var) generates
 584     --          bv = case sv of { pat -> bv; other -> coerce (type-of-bv) err_var }
 585     -- Remember, pat binds bv
 586       = matchSimply (Var scrut_var) PatBindRhs pat
 587                     (Var bndr_var) error_expr                   `thenDs` \ rhs_expr ->
 588         returnDs (bndr_var, rhs_expr)
 589       where
 590         error_expr = mkCoerce (idType bndr_var) (Var err_var)
 591
 592     is_simple_lpat p = is_simple_pat (unLoc p)
 593
 594     is_simple_pat (TuplePat ps Boxed _)    = all is_triv_lpat ps
 595     is_simple_pat (ConPatOut _ _ _ _ ps _) = all is_triv_lpat (hsConArgs ps)
 596     is_simple_pat (VarPat _)               = True
 597     is_simple_pat (ParPat p)               = is_simple_lpat p
 598     is_simple_pat other                    = False
 599
 600     is_triv_lpat p = is_triv_pat (unLoc p)
 601
 602     is_triv_pat (VarPat v)  = True
 603     is_triv_pat (WildPat _) = True
 604     is_triv_pat (ParPat p)  = is_triv_lpat p
 605     is_triv_pat other       = False
 606 \end{code}
 607
 608
 609 %************************************************************************
 610 %*                                                                      *
 611                 Tuples
 612 %*                                                                      *
 613 %************************************************************************
 614
 615 @mkTupleExpr@ builds a tuple; the inverse to @mkTupleSelector@.
 616
 617 * If it has only one element, it is the identity function.
 618
 619 * If there are more elements than a big tuple can have, it nests
 620   the tuples.
 621
 622 Nesting policy.  Better a 2-tuple of 10-tuples (3 objects) than
 623 a 10-tuple of 2-tuples (11 objects).  So we want the leaves to be big.
 624
 625 \begin{code}
 626 mkTupleExpr :: [Id] -> CoreExpr
 627 mkTupleExpr ids = mkBigCoreTup (map Var ids)
 628
 629 -- corresponding type
 630 mkTupleType :: [Id] -> Type
 631 mkTupleType ids = mkBigTuple mkCoreTupTy (map idType ids)
 632
 633 mkBigCoreTup :: [CoreExpr] -> CoreExpr
 634 mkBigCoreTup = mkBigTuple mkCoreTup
 635
 636 mkBigTuple :: ([a] -> a) -> [a] -> a
 637 mkBigTuple small_tuple as = mk_big_tuple (chunkify as)
 638   where
 639         -- Each sub-list is short enough to fit in a tuple
 640     mk_big_tuple [as] = small_tuple as
 641     mk_big_tuple as_s = mk_big_tuple (chunkify (map small_tuple as_s))
 642
 643 chunkify :: [a] -> [[a]]
 644 -- The sub-lists of the result all have length <= mAX_TUPLE_SIZE
 645 -- But there may be more than mAX_TUPLE_SIZE sub-lists
 646 chunkify xs
 647   | n_xs <= mAX_TUPLE_SIZE = {- pprTrace "Small" (ppr n_xs) -} [xs]
 648   | otherwise              = {- pprTrace "Big"   (ppr n_xs) -} (split xs)
 649   where
 650     n_xs     = length xs
 651     split [] = []
 652     split xs = take mAX_TUPLE_SIZE xs : split (drop mAX_TUPLE_SIZE xs)
 653 \end{code}
 654
 655
 656 @mkTupleSelector@ builds a selector which scrutises the given
 657 expression and extracts the one name from the list given.
 658 If you want the no-shadowing rule to apply, the caller
 659 is responsible for making sure that none of these names
 660 are in scope.
 661
 662 If there is just one id in the ``tuple'', then the selector is
 663 just the identity.
 664
 665 If it's big, it does nesting
 666         mkTupleSelector [a,b,c,d] b v e
 667           = case e of v {
 668                 (p,q) -> case p of p {
 669                            (a,b) -> b }}
 670 We use 'tpl' vars for the p,q, since shadowing does not matter.
 671
 672 In fact, it's more convenient to generate it innermost first, getting
 673
 674         case (case e of v
 675                 (p,q) -> p) of p
 676           (a,b) -> b
 677
 678 \begin{code}
 679 mkTupleSelector :: [Id]         -- The tuple args
 680                 -> Id           -- The selected one
 681                 -> Id           -- A variable of the same type as the scrutinee
 682                 -> CoreExpr     -- Scrutinee
 683                 -> CoreExpr
 684
 685 mkTupleSelector vars the_var scrut_var scrut
 686   = mk_tup_sel (chunkify vars) the_var
 687   where
 688     mk_tup_sel [vars] the_var = mkCoreSel vars the_var scrut_var scrut
 689     mk_tup_sel vars_s the_var = mkCoreSel group the_var tpl_v $
 690                                 mk_tup_sel (chunkify tpl_vs) tpl_v
 691         where
 692           tpl_tys = [mkCoreTupTy (map idType gp) | gp <- vars_s]
 693           tpl_vs  = mkTemplateLocals tpl_tys
 694           [(tpl_v, group)] = [(tpl,gp) | (tpl,gp) <- zipEqual "mkTupleSelector" tpl_vs vars_s,
 695                                          the_var `elem` gp ]
 696 \end{code}
 697
 698 A generalization of @mkTupleSelector@, allowing the body
 699 of the case to be an arbitrary expression.
 700
 701 If the tuple is big, it is nested:
 702
 703         mkTupleCase uniqs [a,b,c,d] body v e
 704           = case e of v { (p,q) ->
 705             case p of p { (a,b) ->
 706             case q of q { (c,d) ->
 707             body }}}
 708
 709 To avoid shadowing, we use uniqs to invent new variables p,q.
 710
 711 ToDo: eliminate cases where none of the variables are needed.
 712
 713 \begin{code}
 714 mkTupleCase
 715         :: UniqSupply   -- for inventing names of intermediate variables
 716         -> [Id]         -- the tuple args
 717         -> CoreExpr     -- body of the case
 718         -> Id           -- a variable of the same type as the scrutinee
 719         -> CoreExpr     -- scrutinee
 720         -> CoreExpr
 721
 722 mkTupleCase uniqs vars body scrut_var scrut
 723   = mk_tuple_case uniqs (chunkify vars) body
 724   where
 725     mk_tuple_case us [vars] body
 726       = mkSmallTupleCase vars body scrut_var scrut
 727     mk_tuple_case us vars_s body
 728       = let
 729             (us', vars', body') = foldr one_tuple_case (us, [], body) vars_s
 730         in
 731         mk_tuple_case us' (chunkify vars') body'
 732     one_tuple_case chunk_vars (us, vs, body)
 733       = let
 734             (us1, us2) = splitUniqSupply us
 735             scrut_var = mkSysLocal FSLIT("ds") (uniqFromSupply us1)
 736                         (mkCoreTupTy (map idType chunk_vars))
 737             body' = mkSmallTupleCase chunk_vars body scrut_var (Var scrut_var)
 738         in (us2, scrut_var:vs, body')
 739 \end{code}
 740
 741 The same, but with a tuple small enough not to need nesting.
 742
 743 \begin{code}
 744 mkSmallTupleCase
 745         :: [Id]         -- the tuple args
 746         -> CoreExpr     -- body of the case
 747         -> Id           -- a variable of the same type as the scrutinee
 748         -> CoreExpr     -- scrutinee
 749         -> CoreExpr
 750
 751 mkSmallTupleCase [var] body _scrut_var scrut
 752   = bindNonRec var scrut body
 753 mkSmallTupleCase vars body scrut_var scrut
 754 -- One branch no refinement?
 755   = Case scrut scrut_var (exprType body) [(DataAlt (tupleCon Boxed (length vars)), vars, body)]
 756 \end{code}
 757
 758 %************************************************************************
 759 %*                                                                      *
 760 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 761 %*                                                                      *
 762 %************************************************************************
 763
 764 Call the constructor Ids when building explicit lists, so that they
 765 interact well with rules.
 766
 767 \begin{code}
 768 mkNilExpr :: Type -> CoreExpr
 769 mkNilExpr ty = mkConApp nilDataCon [Type ty]
 770
 771 mkConsExpr :: Type -> CoreExpr -> CoreExpr -> CoreExpr
 772 mkConsExpr ty hd tl = mkConApp consDataCon [Type ty, hd, tl]
 773
 774 mkListExpr :: Type -> [CoreExpr] -> CoreExpr
 775 mkListExpr ty xs = foldr (mkConsExpr ty) (mkNilExpr ty) xs
 776
 777
 778 -- The next three functions make tuple types, constructors and selectors,
 779 -- with the rule that a 1-tuple is represented by the thing itselg
 780 mkCoreTupTy :: [Type] -> Type
 781 mkCoreTupTy [ty] = ty
 782 mkCoreTupTy tys  = mkTupleTy Boxed (length tys) tys
 783
 784 mkCoreTup :: [CoreExpr] -> CoreExpr
 785 -- Builds exactly the specified tuple.
 786 -- No fancy business for big tuples
 787 mkCoreTup []  = Var unitDataConId
 788 mkCoreTup [c] = c
 789 mkCoreTup cs  = mkConApp (tupleCon Boxed (length cs))
 790                          (map (Type . exprType) cs ++ cs)
 791
 792 mkCoreSel :: [Id]       -- The tuple args
 793           -> Id         -- The selected one
 794           -> Id         -- A variable of the same type as the scrutinee
 795           -> CoreExpr   -- Scrutinee
 796           -> CoreExpr
 797 -- mkCoreSel [x,y,z] x v e
 798 -- ===>  case e of v { (x,y,z) -> x
 799 mkCoreSel [var] should_be_the_same_var scrut_var scrut
 800   = ASSERT(var == should_be_the_same_var)
 801     scrut
 802
 803 mkCoreSel vars the_var scrut_var scrut
 804   = ASSERT( notNull vars )
 805     Case scrut scrut_var (idType the_var)
 806          [(DataAlt (tupleCon Boxed (length vars)), vars, Var the_var)]
 807 \end{code}
 808
 809
 810 %************************************************************************
 811 %*                                                                      *
 812 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 813 %*                                                                      *
 814 %************************************************************************
 815
 816 Generally, we handle pattern matching failure like this: let-bind a
 817 fail-variable, and use that variable if the thing fails:
 818 \begin{verbatim}
 819         let fail.33 = error "Help"
 820         in
 821         case x of
 822                 p1 -> ...
 823                 p2 -> fail.33
 824                 p3 -> fail.33
 825                 p4 -> ...
 826 \end{verbatim}
 827 Then
 828 \begin{itemize}
 829 \item
 830 If the case can't fail, then there'll be no mention of @fail.33@, and the
 831 simplifier will later discard it.
 832
 833 \item
 834 If it can fail in only one way, then the simplifier will inline it.
 835
 836 \item
 837 Only if it is used more than once will the let-binding remain.
 838 \end{itemize}
 839
 840 There's a problem when the result of the case expression is of
 841 unboxed type.  Then the type of @fail.33@ is unboxed too, and
 842 there is every chance that someone will change the let into a case:
 843 \begin{verbatim}
 844         case error "Help" of
 845           fail.33 -> case ....
 846 \end{verbatim}
 847
 848 which is of course utterly wrong.  Rather than drop the condition that
 849 only boxed types can be let-bound, we just turn the fail into a function
 850 for the primitive case:
 851 \begin{verbatim}
 852         let fail.33 :: Void -> Int#
 853             fail.33 = \_ -> error "Help"
 854         in
 855         case x of
 856                 p1 -> ...
 857                 p2 -> fail.33 void
 858                 p3 -> fail.33 void
 859                 p4 -> ...
 860 \end{verbatim}
 861
 862 Now @fail.33@ is a function, so it can be let-bound.
 863
 864 \begin{code}
 865 mkFailurePair :: CoreExpr       -- Result type of the whole case expression
 866               -> DsM (CoreBind, -- Binds the newly-created fail variable
 867                                 -- to either the expression or \ _ -> expression
 868                       CoreExpr) -- Either the fail variable, or fail variable
 869                                 -- applied to unit tuple
 870 mkFailurePair expr
 871   | isUnLiftedType ty
 872   = newFailLocalDs (unitTy `mkFunTy` ty)        `thenDs` \ fail_fun_var ->
 873     newSysLocalDs unitTy                        `thenDs` \ fail_fun_arg ->
 874     returnDs (NonRec fail_fun_var (Lam fail_fun_arg expr),
 875               App (Var fail_fun_var) (Var unitDataConId))
 876
 877   | otherwise
 878   = newFailLocalDs ty           `thenDs` \ fail_var ->
 879     returnDs (NonRec fail_var expr, Var fail_var)
 880   where
 881     ty = exprType expr
 882 \end{code}
 883
 884