compiler/deSugar/DsUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utilities for desugaring
   7
   8 This module exports some utility functions of no great interest.
   9
  10 \begin{code}
  11
  12 module DsUtils (
  13         EquationInfo(..),
  14         firstPat, shiftEqns,
  15
  16         mkDsLet, mkDsLets, mkDsApp, mkDsApps,
  17
  18         MatchResult(..), CanItFail(..),
  19         cantFailMatchResult, alwaysFailMatchResult,
  20         extractMatchResult, combineMatchResults,
  21         adjustMatchResult,  adjustMatchResultDs,
  22         mkCoLetMatchResult, mkViewMatchResult, mkGuardedMatchResult,
  23         matchCanFail, mkEvalMatchResult,
  24         mkCoPrimCaseMatchResult, mkCoAlgCaseMatchResult,
  25         wrapBind, wrapBinds,
  26
  27         mkErrorAppDs, mkNilExpr, mkConsExpr, mkListExpr,
  28         mkIntExpr, mkCharExpr,
  29         mkStringExpr, mkStringExprFS, mkIntegerExpr,
  30         mkBuildExpr, mkFoldrExpr,
  31
  32     seqVar,
  33
  34     -- Core tuples
  35     mkCoreVarTup, mkCoreTup, mkCoreVarTupTy, mkCoreTupTy,
  36     mkBigCoreVarTup, mkBigCoreTup, mkBigCoreVarTupTy, mkBigCoreTupTy,
  37
  38     -- LHs tuples
  39     mkLHsVarTup, mkLHsTup, mkLHsVarPatTup, mkLHsPatTup,
  40     mkBigLHsVarTup, mkBigLHsTup, mkBigLHsVarPatTup, mkBigLHsPatTup,
  41
  42     -- Tuple bindings
  43         mkSelectorBinds, mkTupleSelector,
  44         mkSmallTupleCase, mkTupleCase,
  45
  46         dsSyntaxTable, lookupEvidence,
  47
  48         selectSimpleMatchVarL, selectMatchVars, selectMatchVar,
  49         mkTickBox, mkOptTickBox, mkBinaryTickBox
  50     ) where
  51
  52 #include "HsVersions.h"
  53
  54 import {-# SOURCE #-}   Match ( matchSimply )
  55 import {-# SOURCE #-}   DsExpr( dsExpr )
  56
  57 import HsSyn
  58 import TcHsSyn
  59 import CoreSyn
  60 import Constants
  61 import DsMonad
  62
  63 import CoreUtils
  64 import MkId
  65 import Id
  66 import Var
  67 import Name
  68 import Literal
  69 import TyCon
  70 import DataCon
  71 import Type
  72 import Coercion
  73 import TysPrim
  74 import TysWiredIn
  75 import BasicTypes
  76 import UniqSet
  77 import UniqSupply
  78 import PrelNames
  79 import Outputable
  80 import SrcLoc
  81 import Util
  82 import ListSetOps
  83 import FastString
  84 import StaticFlags
  85
  86 import Data.Char
  87
  88 infixl 4 `mkDsApp`, `mkDsApps`
  89 \end{code}
  90
  91
  92
  93 %************************************************************************
  94 %*                                                                      *
  95                 Rebindable syntax
  96 %*                                                                      *
  97 %************************************************************************
  98
  99 \begin{code}
 100 dsSyntaxTable :: SyntaxTable Id
 101                -> DsM ([CoreBind],      -- Auxiliary bindings
 102                        [(Name,Id)])     -- Maps the standard name to its value
 103
 104 dsSyntaxTable rebound_ids = do
 105     (binds_s, prs) <- mapAndUnzipM mk_bind rebound_ids
 106     return (concat binds_s, prs)
 107   where
 108         -- The cheapo special case can happen when we
 109         -- make an intermediate HsDo when desugaring a RecStmt
 110     mk_bind (std_name, HsVar id) = return ([], (std_name, id))
 111     mk_bind (std_name, expr) = do
 112            rhs <- dsExpr expr
 113            id <- newSysLocalDs (exprType rhs)
 114            return ([NonRec id rhs], (std_name, id))
 115
 116 lookupEvidence :: [(Name, Id)] -> Name -> Id
 117 lookupEvidence prs std_name
 118   = assocDefault (mk_panic std_name) prs std_name
 119   where
 120     mk_panic std_name = pprPanic "dsSyntaxTable" (ptext (sLit "Not found:") <+> ppr std_name)
 121 \end{code}
 122
 123
 124 %************************************************************************
 125 %*                                                                      *
 126 \subsection{Building lets}
 127 %*                                                                      *
 128 %************************************************************************
 129
 130 Use case, not let for unlifted types.  The simplifier will turn some
 131 back again.
 132
 133 \begin{code}
 134 mkDsLet :: CoreBind -> CoreExpr -> CoreExpr
 135 mkDsLet (NonRec bndr rhs) body  -- See Note [CoreSyn let/app invariant]
 136   | isUnLiftedType (idType bndr) && not (exprOkForSpeculation rhs)
 137   = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 138 mkDsLet bind body
 139   = Let bind body
 140
 141 mkDsLets :: [CoreBind] -> CoreExpr -> CoreExpr
 142 mkDsLets binds body = foldr mkDsLet body binds
 143
 144 -----------
 145 mkDsApp :: CoreExpr -> CoreExpr -> CoreExpr
 146 -- Check the invariant that the arg of an App is ok-for-speculation if unlifted
 147 -- See CoreSyn Note [CoreSyn let/app invariant]
 148 mkDsApp fun (Type ty) = App fun (Type ty)
 149 mkDsApp fun arg       = mk_val_app fun arg arg_ty res_ty
 150                       where
 151                         (arg_ty, res_ty) = splitFunTy (exprType fun)
 152
 153 -----------
 154 mkDsApps :: CoreExpr -> [CoreExpr] -> CoreExpr
 155 -- Slightly more efficient version of (foldl mkDsApp)
 156 mkDsApps fun args
 157   = go fun (exprType fun) args
 158   where
 159     go fun _      []               = fun
 160     go fun fun_ty (Type ty : args) = go (App fun (Type ty)) (applyTy fun_ty ty) args
 161     go fun fun_ty (arg     : args) = go (mk_val_app fun arg arg_ty res_ty) res_ty args
 162                                    where
 163                                      (arg_ty, res_ty) = splitFunTy fun_ty
 164 -----------
 165 mk_val_app :: CoreExpr -> CoreExpr -> Type -> Type -> CoreExpr
 166 mk_val_app fun arg arg_ty _     -- See Note [CoreSyn let/app invariant]
 167   | not (isUnLiftedType arg_ty) || exprOkForSpeculation arg
 168   = App fun arg         -- The vastly common case
 169
 170 mk_val_app (Var f `App` Type ty1 `App` Type _ `App` arg1) arg2 _ res_ty
 171   | f == seqId          -- Note [Desugaring seq]
 172   = Case arg1 (mkWildId ty1) res_ty [(DEFAULT,[],arg2)]
 173
 174 mk_val_app fun arg arg_ty res_ty
 175   = Case arg (mkWildId arg_ty) res_ty [(DEFAULT,[],App fun (Var arg_id))]
 176   where
 177     arg_id = mkWildId arg_ty    -- Lots of shadowing, but it doesn't matter,
 178                                 -- because 'fun ' should not have a free wild-id
 179 \end{code}
 180
 181 Note [Desugaring seq]  cf Trac #1031
 182 ~~~~~~~~~~~~~~~~~~~~~
 183    f x y = x `seq` (y `seq` (# x,y #))
 184
 185 The [CoreSyn let/app invariant] means that, other things being equal, because
 186 the argument to the outer 'seq' has an unlifted type, we'll use call-by-value thus:
 187
 188    f x y = case (y `seq` (# x,y #)) of v -> x `seq` v
 189
 190 But that is bad for two reasons:
 191   (a) we now evaluate y before x, and
 192   (b) we can't bind v to an unboxed pair
 193
 194 Seq is very, very special!  So we recognise it right here, and desugar to
 195         case x of _ -> case y of _ -> (# x,y #)
 196
 197 The special case would be valid for all calls to 'seq', but it's only *necessary*
 198 for ones whose second argument has an unlifted type. So we only catch the latter
 199 case here, to avoid unnecessary tests.
 200
 201
 202 %************************************************************************
 203 %*                                                                      *
 204 \subsection{ Selecting match variables}
 205 %*                                                                      *
 206 %************************************************************************
 207
 208 We're about to match against some patterns.  We want to make some
 209 @Ids@ to use as match variables.  If a pattern has an @Id@ readily at
 210 hand, which should indeed be bound to the pattern as a whole, then use it;
 211 otherwise, make one up.
 212
 213 \begin{code}
 214 selectSimpleMatchVarL :: LPat Id -> DsM Id
 215 selectSimpleMatchVarL pat = selectMatchVar (unLoc pat)
 216
 217 -- (selectMatchVars ps tys) chooses variables of type tys
 218 -- to use for matching ps against.  If the pattern is a variable,
 219 -- we try to use that, to save inventing lots of fresh variables.
 220 --
 221 -- OLD, but interesting note:
 222 --    But even if it is a variable, its type might not match.  Consider
 223 --      data T a where
 224 --        T1 :: Int -> T Int
 225 --        T2 :: a   -> T a
 226 --
 227 --      f :: T a -> a -> Int
 228 --      f (T1 i) (x::Int) = x
 229 --      f (T2 i) (y::a)   = 0
 230 --    Then we must not choose (x::Int) as the matching variable!
 231 -- And nowadays we won't, because the (x::Int) will be wrapped in a CoPat
 232
 233 selectMatchVars :: [Pat Id] -> DsM [Id]
 234 selectMatchVars ps = mapM selectMatchVar ps
 235
 236 selectMatchVar :: Pat Id -> DsM Id
 237 selectMatchVar (BangPat pat)   = selectMatchVar (unLoc pat)
 238 selectMatchVar (LazyPat pat)   = selectMatchVar (unLoc pat)
 239 selectMatchVar (ParPat pat)    = selectMatchVar (unLoc pat)
 240 selectMatchVar (VarPat var)    = return var
 241 selectMatchVar (AsPat var _) = return (unLoc var)
 242 selectMatchVar other_pat       = newSysLocalDs (hsPatType other_pat)
 243                                   -- OK, better make up one...
 244 \end{code}
 245
 246
 247 %************************************************************************
 248 %*                                                                      *
 249 %* type synonym EquationInfo and access functions for its pieces        *
 250 %*                                                                      *
 251 %************************************************************************
 252 \subsection[EquationInfo-synonym]{@EquationInfo@: a useful synonym}
 253
 254 The ``equation info'' used by @match@ is relatively complicated and
 255 worthy of a type synonym and a few handy functions.
 256
 257 \begin{code}
 258 firstPat :: EquationInfo -> Pat Id
 259 firstPat eqn = ASSERT( notNull (eqn_pats eqn) ) head (eqn_pats eqn)
 260
 261 shiftEqns :: [EquationInfo] -> [EquationInfo]
 262 -- Drop the first pattern in each equation
 263 shiftEqns eqns = [ eqn { eqn_pats = tail (eqn_pats eqn) } | eqn <- eqns ]
 264 \end{code}
 265
 266 Functions on MatchResults
 267
 268 \begin{code}
 269 matchCanFail :: MatchResult -> Bool
 270 matchCanFail (MatchResult CanFail _)  = True
 271 matchCanFail (MatchResult CantFail _) = False
 272
 273 alwaysFailMatchResult :: MatchResult
 274 alwaysFailMatchResult = MatchResult CanFail (\fail -> return fail)
 275
 276 cantFailMatchResult :: CoreExpr -> MatchResult
 277 cantFailMatchResult expr = MatchResult CantFail (\_ -> return expr)
 278
 279 extractMatchResult :: MatchResult -> CoreExpr -> DsM CoreExpr
 280 extractMatchResult (MatchResult CantFail match_fn) _
 281   = match_fn (error "It can't fail!")
 282
 283 extractMatchResult (MatchResult CanFail match_fn) fail_expr = do
 284     (fail_bind, if_it_fails) <- mkFailurePair fail_expr
 285     body <- match_fn if_it_fails
 286     return (mkDsLet fail_bind body)
 287
 288
 289 combineMatchResults :: MatchResult -> MatchResult -> MatchResult
 290 combineMatchResults (MatchResult CanFail      body_fn1)
 291                     (MatchResult can_it_fail2 body_fn2)
 292   = MatchResult can_it_fail2 body_fn
 293   where
 294     body_fn fail = do body2 <- body_fn2 fail
 295                       (fail_bind, duplicatable_expr) <- mkFailurePair body2
 296                       body1 <- body_fn1 duplicatable_expr
 297                       return (Let fail_bind body1)
 298
 299 combineMatchResults match_result1@(MatchResult CantFail _) _
 300   = match_result1
 301
 302 adjustMatchResult :: DsWrapper -> MatchResult -> MatchResult
 303 adjustMatchResult encl_fn (MatchResult can_it_fail body_fn)
 304   = MatchResult can_it_fail (\fail -> encl_fn <$> body_fn fail)
 305
 306 adjustMatchResultDs :: (CoreExpr -> DsM CoreExpr) -> MatchResult -> MatchResult
 307 adjustMatchResultDs encl_fn (MatchResult can_it_fail body_fn)
 308   = MatchResult can_it_fail (\fail -> encl_fn =<< body_fn fail)
 309
 310 wrapBinds :: [(Var,Var)] -> CoreExpr -> CoreExpr
 311 wrapBinds [] e = e
 312 wrapBinds ((new,old):prs) e = wrapBind new old (wrapBinds prs e)
 313
 314 wrapBind :: Var -> Var -> CoreExpr -> CoreExpr
 315 wrapBind new old body
 316   | new==old    = body
 317   | isTyVar new = App (Lam new body) (Type (mkTyVarTy old))
 318   | otherwise   = Let (NonRec new (Var old)) body
 319
 320 seqVar :: Var -> CoreExpr -> CoreExpr
 321 seqVar var body = Case (Var var) var (exprType body)
 322                         [(DEFAULT, [], body)]
 323
 324 mkCoLetMatchResult :: CoreBind -> MatchResult -> MatchResult
 325 mkCoLetMatchResult bind = adjustMatchResult (mkDsLet bind)
 326
 327 -- (mkViewMatchResult var' viewExpr var mr) makes the expression
 328 -- let var' = viewExpr var in mr
 329 mkViewMatchResult :: Id -> CoreExpr -> Id -> MatchResult -> MatchResult
 330 mkViewMatchResult var' viewExpr var =
 331     adjustMatchResult (mkDsLet (NonRec var' (mkDsApp viewExpr (Var var))))
 332
 333 mkEvalMatchResult :: Id -> Type -> MatchResult -> MatchResult
 334 mkEvalMatchResult var ty
 335   = adjustMatchResult (\e -> Case (Var var) var ty [(DEFAULT, [], e)])
 336
 337 mkGuardedMatchResult :: CoreExpr -> MatchResult -> MatchResult
 338 mkGuardedMatchResult pred_expr (MatchResult _ body_fn)
 339   = MatchResult CanFail (\fail -> do body <- body_fn fail
 340                                      return (mkIfThenElse pred_expr body fail))
 341
 342 mkCoPrimCaseMatchResult :: Id                           -- Scrutinee
 343                     -> Type                             -- Type of the case
 344                     -> [(Literal, MatchResult)]         -- Alternatives
 345                     -> MatchResult
 346 mkCoPrimCaseMatchResult var ty match_alts
 347   = MatchResult CanFail mk_case
 348   where
 349     mk_case fail = do
 350         alts <- mapM (mk_alt fail) sorted_alts
 351         return (Case (Var var) var ty ((DEFAULT, [], fail) : alts))
 352
 353     sorted_alts = sortWith fst match_alts       -- Right order for a Case
 354     mk_alt fail (lit, MatchResult _ body_fn) = do body <- body_fn fail
 355                                                   return (LitAlt lit, [], body)
 356
 357
 358 mkCoAlgCaseMatchResult :: Id                                    -- Scrutinee
 359                     -> Type                                     -- Type of exp
 360                     -> [(DataCon, [CoreBndr], MatchResult)]     -- Alternatives
 361                     -> MatchResult
 362 mkCoAlgCaseMatchResult var ty match_alts
 363   | isNewTyCon tycon            -- Newtype case; use a let
 364   = ASSERT( null (tail match_alts) && null (tail arg_ids1) )
 365     mkCoLetMatchResult (NonRec arg_id1 newtype_rhs) match_result1
 366
 367   | isPArrFakeAlts match_alts   -- Sugared parallel array; use a literal case
 368   = MatchResult CanFail mk_parrCase
 369
 370   | otherwise                   -- Datatype case; use a case
 371   = MatchResult fail_flag mk_case
 372   where
 373     tycon = dataConTyCon con1
 374         -- [Interesting: becuase of GADTs, we can't rely on the type of
 375         --  the scrutinised Id to be sufficiently refined to have a TyCon in it]
 376
 377         -- Stuff for newtype
 378     (con1, arg_ids1, match_result1) = ASSERT( notNull match_alts ) head match_alts
 379     arg_id1     = ASSERT( notNull arg_ids1 ) head arg_ids1
 380     var_ty      = idType var
 381     (tc, ty_args) = splitNewTyConApp var_ty
 382     newtype_rhs = unwrapNewTypeBody tc ty_args (Var var)
 383
 384         -- Stuff for data types
 385     data_cons      = tyConDataCons tycon
 386     match_results  = [match_result | (_,_,match_result) <- match_alts]
 387
 388     fail_flag | exhaustive_case
 389               = foldr1 orFail [can_it_fail | MatchResult can_it_fail _ <- match_results]
 390               | otherwise
 391               = CanFail
 392
 393     wild_var = mkWildId (idType var)
 394     sorted_alts  = sortWith get_tag match_alts
 395     get_tag (con, _, _) = dataConTag con
 396     mk_case fail = do alts <- mapM (mk_alt fail) sorted_alts
 397                       return (Case (Var var) wild_var ty (mk_default fail ++ alts))
 398
 399     mk_alt fail (con, args, MatchResult _ body_fn) = do
 400           body <- body_fn fail
 401           us <- newUniqueSupply
 402           return (mkReboxingAlt (uniqsFromSupply us) con args body)
 403
 404     mk_default fail | exhaustive_case = []
 405                     | otherwise       = [(DEFAULT, [], fail)]
 406
 407     un_mentioned_constructors
 408         = mkUniqSet data_cons `minusUniqSet` mkUniqSet [ con | (con, _, _) <- match_alts]
 409     exhaustive_case = isEmptyUniqSet un_mentioned_constructors
 410
 411         -- Stuff for parallel arrays
 412         --
 413         --  * the following is to desugar cases over fake constructors for
 414         --   parallel arrays, which are introduced by `tidy1' in the `PArrPat'
 415         --   case
 416         --
 417         -- Concerning `isPArrFakeAlts':
 418         --
 419         --  * it is *not* sufficient to just check the type of the type
 420         --   constructor, as we have to be careful not to confuse the real
 421         --   representation of parallel arrays with the fake constructors;
 422         --   moreover, a list of alternatives must not mix fake and real
 423         --   constructors (this is checked earlier on)
 424         --
 425         -- FIXME: We actually go through the whole list and make sure that
 426         --        either all or none of the constructors are fake parallel
 427         --        array constructors.  This is to spot equations that mix fake
 428         --        constructors with the real representation defined in
 429         --        `PrelPArr'.  It would be nicer to spot this situation
 430         --        earlier and raise a proper error message, but it can really
 431         --        only happen in `PrelPArr' anyway.
 432         --
 433     isPArrFakeAlts [(dcon, _, _)]      = isPArrFakeCon dcon
 434     isPArrFakeAlts ((dcon, _, _):alts) =
 435       case (isPArrFakeCon dcon, isPArrFakeAlts alts) of
 436         (True , True ) -> True
 437         (False, False) -> False
 438         _              -> panic "DsUtils: you may not mix `[:...:]' with `PArr' patterns"
 439     isPArrFakeAlts [] = panic "DsUtils: unexpectedly found an empty list of PArr fake alternatives"
 440     --
 441     mk_parrCase fail = do
 442       lengthP <- dsLookupGlobalId lengthPName
 443       alt <- unboxAlt
 444       return (Case (len lengthP) (mkWildId intTy) ty [alt])
 445       where
 446         elemTy      = case splitTyConApp (idType var) of
 447                         (_, [elemTy]) -> elemTy
 448                         _               -> panic panicMsg
 449         panicMsg    = "DsUtils.mkCoAlgCaseMatchResult: not a parallel array?"
 450         len lengthP = mkApps (Var lengthP) [Type elemTy, Var var]
 451         --
 452         unboxAlt = do
 453           l      <- newSysLocalDs intPrimTy
 454           indexP <- dsLookupGlobalId indexPName
 455           alts   <- mapM (mkAlt indexP) sorted_alts
 456           return (DataAlt intDataCon, [l], (Case (Var l) wild ty (dft : alts)))
 457           where
 458             wild = mkWildId intPrimTy
 459             dft  = (DEFAULT, [], fail)
 460         --
 461         -- each alternative matches one array length (corresponding to one
 462         -- fake array constructor), so the match is on a literal; each
 463         -- alternative's body is extended by a local binding for each
 464         -- constructor argument, which are bound to array elements starting
 465         -- with the first
 466         --
 467         mkAlt indexP (con, args, MatchResult _ bodyFun) = do
 468           body <- bodyFun fail
 469           return (LitAlt lit, [], mkDsLets binds body)
 470           where
 471             lit   = MachInt $ toInteger (dataConSourceArity con)
 472             binds = [NonRec arg (indexExpr i) | (i, arg) <- zip [1..] args]
 473             --
 474             indexExpr i = mkApps (Var indexP) [Type elemTy, Var var, mkIntExpr i]
 475 \end{code}
 476
 477
 478 %************************************************************************
 479 %*                                                                      *
 480 \subsection{Desugarer's versions of some Core functions}
 481 %*                                                                      *
 482 %************************************************************************
 483
 484 \begin{code}
 485 mkErrorAppDs :: Id              -- The error function
 486              -> Type            -- Type to which it should be applied
 487              -> String          -- The error message string to pass
 488              -> DsM CoreExpr
 489
 490 mkErrorAppDs err_id ty msg = do
 491     src_loc <- getSrcSpanDs
 492     let
 493         full_msg = showSDoc (hcat [ppr src_loc, text "|", text msg])
 494         core_msg = Lit (mkStringLit full_msg)
 495         -- mkStringLit returns a result of type String#
 496     return (mkApps (Var err_id) [Type ty, core_msg])
 497 \end{code}
 498
 499
 500 *************************************************************
 501 %*                                                                      *
 502 \subsection{Making literals}
 503 %*                                                                      *
 504 %************************************************************************
 505
 506 \begin{code}
 507 mkCharExpr     :: Char       -> CoreExpr      -- Returns        C# c :: Int
 508 mkIntExpr      :: Integer    -> CoreExpr      -- Returns        I# i :: Int
 509 mkIntegerExpr  :: Integer    -> DsM CoreExpr  -- Result :: Integer
 510 mkStringExpr   :: String     -> DsM CoreExpr  -- Result :: String
 511 mkStringExprFS :: FastString -> DsM CoreExpr  -- Result :: String
 512
 513 mkIntExpr  i = mkConApp intDataCon  [mkIntLit i]
 514 mkCharExpr c = mkConApp charDataCon [mkLit (MachChar c)]
 515
 516 mkIntegerExpr i
 517   | inIntRange i        -- Small enough, so start from an Int
 518     = do integer_id <- dsLookupGlobalId smallIntegerName
 519          return (mkSmallIntegerLit integer_id i)
 520
 521 -- Special case for integral literals with a large magnitude:
 522 -- They are transformed into an expression involving only smaller
 523 -- integral literals. This improves constant folding.
 524
 525   | otherwise = do       -- Big, so start from a string
 526       plus_id <- dsLookupGlobalId plusIntegerName
 527       times_id <- dsLookupGlobalId timesIntegerName
 528       integer_id <- dsLookupGlobalId smallIntegerName
 529       let
 530            lit i = mkSmallIntegerLit integer_id i
 531            plus a b  = Var plus_id  `App` a `App` b
 532            times a b = Var times_id `App` a `App` b
 533
 534            -- Transform i into (x1 + (x2 + (x3 + (...) * b) * b) * b) with abs xi <= b
 535            horner :: Integer -> Integer -> CoreExpr
 536            horner b i | abs q <= 1 = if r == 0 || r == i
 537                                      then lit i
 538                                      else lit r `plus` lit (i-r)
 539                       | r == 0     =               horner b q `times` lit b
 540                       | otherwise  = lit r `plus` (horner b q `times` lit b)
 541                       where
 542                         (q,r) = i `quotRem` b
 543
 544       return (horner tARGET_MAX_INT i)
 545
 546 mkSmallIntegerLit :: Id -> Integer -> CoreExpr
 547 mkSmallIntegerLit small_integer i = mkApps (Var small_integer) [mkIntLit i]
 548
 549 mkStringExpr str = mkStringExprFS (mkFastString str)
 550
 551 mkStringExprFS str
 552   | nullFS str
 553   = return (mkNilExpr charTy)
 554
 555   | lengthFS str == 1
 556   = do let the_char = mkCharExpr (headFS str)
 557        return (mkConsExpr charTy the_char (mkNilExpr charTy))
 558
 559   | all safeChar chars
 560   = do unpack_id <- dsLookupGlobalId unpackCStringName
 561        return (App (Var unpack_id) (Lit (MachStr str)))
 562
 563   | otherwise
 564   = do unpack_id <- dsLookupGlobalId unpackCStringUtf8Name
 565        return (App (Var unpack_id) (Lit (MachStr str)))
 566
 567   where
 568     chars = unpackFS str
 569     safeChar c = ord c >= 1 && ord c <= 0x7F
 570 \end{code}
 571
 572
 573 %************************************************************************
 574 %*                                                                      *
 575 \subsection[mkSelectorBind]{Make a selector bind}
 576 %*                                                                      *
 577 %************************************************************************
 578
 579 This is used in various places to do with lazy patterns.
 580 For each binder $b$ in the pattern, we create a binding:
 581 \begin{verbatim}
 582     b = case v of pat' -> b'
 583 \end{verbatim}
 584 where @pat'@ is @pat@ with each binder @b@ cloned into @b'@.
 585
 586 ToDo: making these bindings should really depend on whether there's
 587 much work to be done per binding.  If the pattern is complex, it
 588 should be de-mangled once, into a tuple (and then selected from).
 589 Otherwise the demangling can be in-line in the bindings (as here).
 590
 591 Boring!  Boring!  One error message per binder.  The above ToDo is
 592 even more helpful.  Something very similar happens for pattern-bound
 593 expressions.
 594
 595 \begin{code}
 596 mkSelectorBinds :: LPat Id      -- The pattern
 597                 -> CoreExpr     -- Expression to which the pattern is bound
 598                 -> DsM [(Id,CoreExpr)]
 599
 600 mkSelectorBinds (L _ (VarPat v)) val_expr
 601   = return [(v, val_expr)]
 602
 603 mkSelectorBinds pat val_expr
 604   | isSingleton binders || is_simple_lpat pat = do
 605         -- Given   p = e, where p binds x,y
 606         -- we are going to make
 607         --      v = p   (where v is fresh)
 608         --      x = case v of p -> x
 609         --      y = case v of p -> x
 610
 611         -- Make up 'v'
 612         -- NB: give it the type of *pattern* p, not the type of the *rhs* e.
 613         -- This does not matter after desugaring, but there's a subtle
 614         -- issue with implicit parameters. Consider
 615         --      (x,y) = ?i
 616         -- Then, ?i is given type {?i :: Int}, a PredType, which is opaque
 617         -- to the desugarer.  (Why opaque?  Because newtypes have to be.  Why
 618         -- does it get that type?  So that when we abstract over it we get the
 619         -- right top-level type  (?i::Int) => ...)
 620         --
 621         -- So to get the type of 'v', use the pattern not the rhs.  Often more
 622         -- efficient too.
 623       val_var <- newSysLocalDs (hsLPatType pat)
 624
 625         -- For the error message we make one error-app, to avoid duplication.
 626         -- But we need it at different types... so we use coerce for that
 627       err_expr <- mkErrorAppDs iRREFUT_PAT_ERROR_ID  unitTy (showSDoc (ppr pat))
 628       err_var <- newSysLocalDs unitTy
 629       binds <- mapM (mk_bind val_var err_var) binders
 630       return ( (val_var, val_expr) :
 631                (err_var, err_expr) :
 632                binds )
 633
 634
 635   | otherwise = do
 636       error_expr <- mkErrorAppDs iRREFUT_PAT_ERROR_ID   tuple_ty (showSDoc (ppr pat))
 637       tuple_expr <- matchSimply val_expr PatBindRhs pat local_tuple error_expr
 638       tuple_var <- newSysLocalDs tuple_ty
 639       let
 640           mk_tup_bind binder
 641             = (binder, mkTupleSelector binders binder tuple_var (Var tuple_var))
 642       return ( (tuple_var, tuple_expr) : map mk_tup_bind binders )
 643   where
 644     binders     = collectPatBinders pat
 645     local_tuple = mkBigCoreVarTup binders
 646     tuple_ty    = exprType local_tuple
 647
 648     mk_bind scrut_var err_var bndr_var = do
 649     -- (mk_bind sv err_var) generates
 650     --          bv = case sv of { pat -> bv; other -> coerce (type-of-bv) err_var }
 651     -- Remember, pat binds bv
 652         rhs_expr <- matchSimply (Var scrut_var) PatBindRhs pat
 653                                 (Var bndr_var) error_expr
 654         return (bndr_var, rhs_expr)
 655       where
 656         error_expr = mkCoerce co (Var err_var)
 657         co         = mkUnsafeCoercion (exprType (Var err_var)) (idType bndr_var)
 658
 659     is_simple_lpat p = is_simple_pat (unLoc p)
 660
 661     is_simple_pat (TuplePat ps Boxed _)        = all is_triv_lpat ps
 662     is_simple_pat (ConPatOut{ pat_args = ps }) = all is_triv_lpat (hsConPatArgs ps)
 663     is_simple_pat (VarPat _)                   = True
 664     is_simple_pat (ParPat p)                   = is_simple_lpat p
 665     is_simple_pat _                                    = False
 666
 667     is_triv_lpat p = is_triv_pat (unLoc p)
 668
 669     is_triv_pat (VarPat _)  = True
 670     is_triv_pat (WildPat _) = True
 671     is_triv_pat (ParPat p)  = is_triv_lpat p
 672     is_triv_pat _           = False
 673 \end{code}
 674
 675
 676 %************************************************************************
 677 %*                                                                      *
 678                 Big Tuples
 679 %*                                                                      *
 680 %************************************************************************
 681
 682 Nesting policy.  Better a 2-tuple of 10-tuples (3 objects) than
 683 a 10-tuple of 2-tuples (11 objects).  So we want the leaves to be big.
 684
 685 \begin{code}
 686
 687 mkBigTuple :: ([a] -> a) -> [a] -> a
 688 mkBigTuple small_tuple as = mk_big_tuple (chunkify as)
 689   where
 690         -- Each sub-list is short enough to fit in a tuple
 691     mk_big_tuple [as] = small_tuple as
 692     mk_big_tuple as_s = mk_big_tuple (chunkify (map small_tuple as_s))
 693
 694 chunkify :: [a] -> [[a]]
 695 -- The sub-lists of the result all have length <= mAX_TUPLE_SIZE
 696 -- But there may be more than mAX_TUPLE_SIZE sub-lists
 697 chunkify xs
 698   | n_xs <= mAX_TUPLE_SIZE = {- pprTrace "Small" (ppr n_xs) -} [xs]
 699   | otherwise                  = {- pprTrace "Big"   (ppr n_xs) -} (split xs)
 700   where
 701     n_xs     = length xs
 702     split [] = []
 703     split xs = take mAX_TUPLE_SIZE xs : split (drop mAX_TUPLE_SIZE xs)
 704
 705 \end{code}
 706
 707 Creating tuples and their types for Core expressions
 708
 709 @mkBigCoreVarTup@ builds a tuple; the inverse to @mkTupleSelector@.
 710
 711 * If it has only one element, it is the identity function.
 712
 713 * If there are more elements than a big tuple can have, it nests
 714   the tuples.
 715
 716 \begin{code}
 717
 718 -- Small tuples: build exactly the specified tuple
 719 mkCoreVarTup :: [Id] -> CoreExpr
 720 mkCoreVarTup ids = mkCoreTup (map Var ids)
 721
 722 mkCoreVarTupTy :: [Id] -> Type
 723 mkCoreVarTupTy ids = mkCoreTupTy (map idType ids)
 724
 725
 726 mkCoreTup :: [CoreExpr] -> CoreExpr
 727 mkCoreTup []  = Var unitDataConId
 728 mkCoreTup [c] = c
 729 mkCoreTup cs  = mkConApp (tupleCon Boxed (length cs))
 730                          (map (Type . exprType) cs ++ cs)
 731
 732 mkCoreTupTy :: [Type] -> Type
 733 mkCoreTupTy [ty] = ty
 734 mkCoreTupTy tys  = mkTupleTy Boxed (length tys) tys
 735
 736
 737
 738 -- Big tuples
 739 mkBigCoreVarTup :: [Id] -> CoreExpr
 740 mkBigCoreVarTup ids = mkBigCoreTup (map Var ids)
 741
 742 mkBigCoreVarTupTy :: [Id] -> Type
 743 mkBigCoreVarTupTy ids = mkBigCoreTupTy (map idType ids)
 744
 745
 746 mkBigCoreTup :: [CoreExpr] -> CoreExpr
 747 mkBigCoreTup = mkBigTuple mkCoreTup
 748
 749 mkBigCoreTupTy :: [Type] -> Type
 750 mkBigCoreTupTy = mkBigTuple mkCoreTupTy
 751
 752 \end{code}
 753
 754 Creating tuples and their types for full Haskell expressions
 755
 756 \begin{code}
 757
 758 -- Smart constructors for source tuple expressions
 759 mkLHsVarTup :: [Id] -> LHsExpr Id
 760 mkLHsVarTup ids  = mkLHsTup (map nlHsVar ids)
 761
 762 mkLHsTup :: [LHsExpr Id] -> LHsExpr Id
 763 mkLHsTup []     = nlHsVar unitDataConId
 764 mkLHsTup [lexp] = lexp
 765 mkLHsTup lexps  = noLoc $ ExplicitTuple lexps Boxed
 766
 767
 768 -- Smart constructors for source tuple patterns
 769 mkLHsVarPatTup :: [Id] -> LPat Id
 770 mkLHsVarPatTup bs  = mkLHsPatTup (map nlVarPat bs)
 771
 772 mkLHsPatTup :: [LPat Id] -> LPat Id
 773 mkLHsPatTup [lpat] = lpat
 774 mkLHsPatTup lpats  = noLoc $ mkVanillaTuplePat lpats Boxed -- Handles the case where lpats = [] gracefully
 775
 776
 777 -- The Big equivalents for the source tuple expressions
 778 mkBigLHsVarTup :: [Id] -> LHsExpr Id
 779 mkBigLHsVarTup ids = mkBigLHsTup (map nlHsVar ids)
 780
 781 mkBigLHsTup :: [LHsExpr Id] -> LHsExpr Id
 782 mkBigLHsTup = mkBigTuple mkLHsTup
 783
 784
 785 -- The Big equivalents for the source tuple patterns
 786 mkBigLHsVarPatTup :: [Id] -> LPat Id
 787 mkBigLHsVarPatTup bs = mkBigLHsPatTup (map nlVarPat bs)
 788
 789 mkBigLHsPatTup :: [LPat Id] -> LPat Id
 790 mkBigLHsPatTup = mkBigTuple mkLHsPatTup
 791
 792 \end{code}
 793
 794
 795 @mkTupleSelector@ builds a selector which scrutises the given
 796 expression and extracts the one name from the list given.
 797 If you want the no-shadowing rule to apply, the caller
 798 is responsible for making sure that none of these names
 799 are in scope.
 800
 801 If there is just one id in the ``tuple'', then the selector is
 802 just the identity.
 803
 804 If it's big, it does nesting
 805         mkTupleSelector [a,b,c,d] b v e
 806           = case e of v {
 807                 (p,q) -> case p of p {
 808                            (a,b) -> b }}
 809 We use 'tpl' vars for the p,q, since shadowing does not matter.
 810
 811 In fact, it's more convenient to generate it innermost first, getting
 812
 813         case (case e of v
 814                 (p,q) -> p) of p
 815           (a,b) -> b
 816
 817 \begin{code}
 818 mkTupleSelector :: [Id]         -- The tuple args
 819                 -> Id           -- The selected one
 820                 -> Id           -- A variable of the same type as the scrutinee
 821                 -> CoreExpr     -- Scrutinee
 822                 -> CoreExpr
 823
 824 mkTupleSelector vars the_var scrut_var scrut
 825   = mk_tup_sel (chunkify vars) the_var
 826   where
 827     mk_tup_sel [vars] the_var = mkCoreSel vars the_var scrut_var scrut
 828     mk_tup_sel vars_s the_var = mkCoreSel group the_var tpl_v $
 829                                 mk_tup_sel (chunkify tpl_vs) tpl_v
 830         where
 831           tpl_tys = [mkCoreTupTy (map idType gp) | gp <- vars_s]
 832           tpl_vs  = mkTemplateLocals tpl_tys
 833           [(tpl_v, group)] = [(tpl,gp) | (tpl,gp) <- zipEqual "mkTupleSelector" tpl_vs vars_s,
 834                                          the_var `elem` gp ]
 835 \end{code}
 836
 837 A generalization of @mkTupleSelector@, allowing the body
 838 of the case to be an arbitrary expression.
 839
 840 If the tuple is big, it is nested:
 841
 842         mkTupleCase uniqs [a,b,c,d] body v e
 843           = case e of v { (p,q) ->
 844             case p of p { (a,b) ->
 845             case q of q { (c,d) ->
 846             body }}}
 847
 848 To avoid shadowing, we use uniqs to invent new variables p,q.
 849
 850 ToDo: eliminate cases where none of the variables are needed.
 851
 852 \begin{code}
 853 mkTupleCase
 854         :: UniqSupply   -- for inventing names of intermediate variables
 855         -> [Id]         -- the tuple args
 856         -> CoreExpr     -- body of the case
 857         -> Id           -- a variable of the same type as the scrutinee
 858         -> CoreExpr     -- scrutinee
 859         -> CoreExpr
 860
 861 mkTupleCase uniqs vars body scrut_var scrut
 862   = mk_tuple_case uniqs (chunkify vars) body
 863   where
 864     -- This is the case where don't need any nesting
 865     mk_tuple_case _ [vars] body
 866       = mkSmallTupleCase vars body scrut_var scrut
 867
 868     -- This is the case where we must make nest tuples at least once
 869     mk_tuple_case us vars_s body
 870       = let (us', vars', body') = foldr one_tuple_case (us, [], body) vars_s
 871             in mk_tuple_case us' (chunkify vars') body'
 872
 873     one_tuple_case chunk_vars (us, vs, body)
 874       = let (us1, us2) = splitUniqSupply us
 875             scrut_var = mkSysLocal (fsLit "ds") (uniqFromSupply us1)
 876               (mkCoreTupTy (map idType chunk_vars))
 877             body' = mkSmallTupleCase chunk_vars body scrut_var (Var scrut_var)
 878         in (us2, scrut_var:vs, body')
 879 \end{code}
 880
 881 The same, but with a tuple small enough not to need nesting.
 882
 883 \begin{code}
 884 mkSmallTupleCase
 885         :: [Id]         -- the tuple args
 886         -> CoreExpr     -- body of the case
 887         -> Id           -- a variable of the same type as the scrutinee
 888         -> CoreExpr     -- scrutinee
 889         -> CoreExpr
 890
 891 mkSmallTupleCase [var] body _scrut_var scrut
 892   = bindNonRec var scrut body
 893 mkSmallTupleCase vars body scrut_var scrut
 894 -- One branch no refinement?
 895   = Case scrut scrut_var (exprType body) [(DataAlt (tupleCon Boxed (length vars)), vars, body)]
 896 \end{code}
 897
 898 %************************************************************************
 899 %*                                                                      *
 900 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 901 %*                                                                      *
 902 %************************************************************************
 903
 904 Call the constructor Ids when building explicit lists, so that they
 905 interact well with rules.
 906
 907 \begin{code}
 908 mkNilExpr :: Type -> CoreExpr
 909 mkNilExpr ty = mkConApp nilDataCon [Type ty]
 910
 911 mkConsExpr :: Type -> CoreExpr -> CoreExpr -> CoreExpr
 912 mkConsExpr ty hd tl = mkConApp consDataCon [Type ty, hd, tl]
 913
 914 mkListExpr :: Type -> [CoreExpr] -> CoreExpr
 915 mkListExpr ty xs = foldr (mkConsExpr ty) (mkNilExpr ty) xs
 916
 917 mkFoldrExpr :: PostTcType -> PostTcType -> CoreExpr -> CoreExpr -> CoreExpr -> DsM CoreExpr
 918 mkFoldrExpr elt_ty result_ty c n list = do
 919     foldr_id <- dsLookupGlobalId foldrName
 920     return (Var foldr_id `App` Type elt_ty
 921            `App` Type result_ty
 922            `App` c
 923            `App` n
 924            `App` list)
 925
 926 mkBuildExpr :: Type -> ((Id, Type) -> (Id, Type) -> DsM CoreExpr) -> DsM CoreExpr
 927 mkBuildExpr elt_ty mk_build_inside = do
 928     [n_tyvar] <- newTyVarsDs [alphaTyVar]
 929     let n_ty = mkTyVarTy n_tyvar
 930         c_ty = mkFunTys [elt_ty, n_ty] n_ty
 931     [c, n] <- newSysLocalsDs [c_ty, n_ty]
 932
 933     build_inside <- mk_build_inside (c, c_ty) (n, n_ty)
 934
 935     build_id <- dsLookupGlobalId buildName
 936     return $ Var build_id `App` Type elt_ty `App` mkLams [n_tyvar, c, n] build_inside
 937
 938 mkCoreSel :: [Id]       -- The tuple args
 939           -> Id         -- The selected one
 940           -> Id         -- A variable of the same type as the scrutinee
 941           -> CoreExpr   -- Scrutinee
 942           -> CoreExpr
 943
 944 -- mkCoreSel [x] x v e
 945 -- ===>  e
 946 mkCoreSel [var] should_be_the_same_var _ scrut
 947   = ASSERT(var == should_be_the_same_var)
 948     scrut
 949
 950 -- mkCoreSel [x,y,z] x v e
 951 -- ===>  case e of v { (x,y,z) -> x
 952 mkCoreSel vars the_var scrut_var scrut
 953   = ASSERT( notNull vars )
 954     Case scrut scrut_var (idType the_var)
 955          [(DataAlt (tupleCon Boxed (length vars)), vars, Var the_var)]
 956 \end{code}
 957
 958 %************************************************************************
 959 %*                                                                      *
 960 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 961 %*                                                                      *
 962 %************************************************************************
 963
 964 Generally, we handle pattern matching failure like this: let-bind a
 965 fail-variable, and use that variable if the thing fails:
 966 \begin{verbatim}
 967         let fail.33 = error "Help"
 968         in
 969         case x of
 970                 p1 -> ...
 971                 p2 -> fail.33
 972                 p3 -> fail.33
 973                 p4 -> ...
 974 \end{verbatim}
 975 Then
 976 \begin{itemize}
 977 \item
 978 If the case can't fail, then there'll be no mention of @fail.33@, and the
 979 simplifier will later discard it.
 980
 981 \item
 982 If it can fail in only one way, then the simplifier will inline it.
 983
 984 \item
 985 Only if it is used more than once will the let-binding remain.
 986 \end{itemize}
 987
 988 There's a problem when the result of the case expression is of
 989 unboxed type.  Then the type of @fail.33@ is unboxed too, and
 990 there is every chance that someone will change the let into a case:
 991 \begin{verbatim}
 992         case error "Help" of
 993           fail.33 -> case ....
 994 \end{verbatim}
 995
 996 which is of course utterly wrong.  Rather than drop the condition that
 997 only boxed types can be let-bound, we just turn the fail into a function
 998 for the primitive case:
 999 \begin{verbatim}
1000         let fail.33 :: Void -> Int#
1001             fail.33 = \_ -> error "Help"
1002         in
1003         case x of
1004                 p1 -> ...
1005                 p2 -> fail.33 void
1006                 p3 -> fail.33 void
1007                 p4 -> ...
1008 \end{verbatim}
1009
1010 Now @fail.33@ is a function, so it can be let-bound.
1011
1012 \begin{code}
1013 mkFailurePair :: CoreExpr       -- Result type of the whole case expression
1014               -> DsM (CoreBind, -- Binds the newly-created fail variable
1015                                 -- to either the expression or \ _ -> expression
1016                       CoreExpr) -- Either the fail variable, or fail variable
1017                                 -- applied to unit tuple
1018 mkFailurePair expr
1019   | isUnLiftedType ty = do
1020      fail_fun_var <- newFailLocalDs (unitTy `mkFunTy` ty)
1021      fail_fun_arg <- newSysLocalDs unitTy
1022      return (NonRec fail_fun_var (Lam fail_fun_arg expr),
1023              App (Var fail_fun_var) (Var unitDataConId))
1024
1025   | otherwise = do
1026      fail_var <- newFailLocalDs ty
1027      return (NonRec fail_var expr, Var fail_var)
1028   where
1029     ty = exprType expr
1030 \end{code}
1031
1032 \begin{code}
1033 mkOptTickBox :: Maybe (Int,[Id]) -> CoreExpr -> DsM CoreExpr
1034 mkOptTickBox Nothing e   = return e
1035 mkOptTickBox (Just (ix,ids)) e = mkTickBox ix ids e
1036
1037 mkTickBox :: Int -> [Id] -> CoreExpr -> DsM CoreExpr
1038 mkTickBox ix vars e = do
1039        uq <- newUnique
1040        mod <- getModuleDs
1041        let tick | opt_Hpc   = mkTickBoxOpId uq mod ix
1042                 | otherwise = mkBreakPointOpId uq mod ix
1043        uq2 <- newUnique
1044        let occName = mkVarOcc "tick"
1045        let name = mkInternalName uq2 occName noSrcSpan   -- use mkSysLocal?
1046        let var  = Id.mkLocalId name realWorldStatePrimTy
1047        scrut <-
1048           if opt_Hpc
1049             then return (Var tick)
1050             else do
1051               let tickVar = Var tick
1052               let tickType = mkFunTys (map idType vars) realWorldStatePrimTy
1053               let scrutApTy = App tickVar (Type tickType)
1054               return (mkApps scrutApTy (map Var vars) :: Expr Id)
1055        return $ Case scrut var ty [(DEFAULT,[],e)]
1056   where
1057      ty = exprType e
1058
1059 mkBinaryTickBox :: Int -> Int -> CoreExpr -> DsM CoreExpr
1060 mkBinaryTickBox ixT ixF e = do
1061        uq <- newUnique
1062        let bndr1 = mkSysLocal (fsLit "t1") uq boolTy
1063        falseBox <- mkTickBox ixF [] $ Var falseDataConId
1064        trueBox  <- mkTickBox ixT [] $ Var trueDataConId
1065        return $ Case e bndr1 boolTy
1066                        [ (DataAlt falseDataCon, [], falseBox)
1067                        , (DataAlt trueDataCon,  [], trueBox)
1068                        ]
1069 \end{code}