compiler/deSugar/DsUtils.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[DsUtils]{Utilities for desugaring}
   5
   6 This module exports some utility functions of no great interest.
   7
   8 \begin{code}
   9 module DsUtils (
  10         EquationInfo(..),
  11         firstPat, shiftEqns,
  12
  13         mkDsLet, mkDsLets,
  14
  15         MatchResult(..), CanItFail(..),
  16         cantFailMatchResult, alwaysFailMatchResult,
  17         extractMatchResult, combineMatchResults,
  18         adjustMatchResult,  adjustMatchResultDs,
  19         mkCoLetMatchResult, mkGuardedMatchResult,
  20         matchCanFail, mkEvalMatchResult,
  21         mkCoPrimCaseMatchResult, mkCoAlgCaseMatchResult,
  22         wrapBind, wrapBinds,
  23
  24         mkErrorAppDs, mkNilExpr, mkConsExpr, mkListExpr,
  25         mkIntExpr, mkCharExpr,
  26         mkStringExpr, mkStringExprFS, mkIntegerExpr,
  27
  28         mkSelectorBinds, mkTupleExpr, mkTupleSelector,
  29         mkTupleType, mkTupleCase, mkBigCoreTup,
  30         mkCoreTup, mkCoreTupTy, seqVar,
  31
  32         dsSyntaxTable, lookupEvidence,
  33
  34         selectSimpleMatchVarL, selectMatchVars, selectMatchVar
  35     ) where
  36
  37 #include "HsVersions.h"
  38
  39 import {-# SOURCE #-}   Match ( matchSimply )
  40 import {-# SOURCE #-}   DsExpr( dsExpr )
  41
  42 import HsSyn
  43 import TcHsSyn          ( hsLPatType, hsPatType )
  44 import CoreSyn
  45 import Constants        ( mAX_TUPLE_SIZE )
  46 import DsMonad
  47
  48 import CoreUtils        ( exprType, mkIfThenElse, mkCoerce, bindNonRec )
  49 import MkId             ( iRREFUT_PAT_ERROR_ID, mkReboxingAlt, unwrapNewTypeBody )
  50 import Id               ( idType, Id, mkWildId, mkTemplateLocals, mkSysLocal )
  51 import Var              ( Var )
  52 import Name             ( Name )
  53 import Literal          ( Literal(..), mkStringLit, inIntRange, tARGET_MAX_INT )
  54 import TyCon            ( isNewTyCon, tyConDataCons )
  55 import DataCon          ( DataCon, dataConSourceArity, dataConTyCon, dataConTag )
  56 import Type             ( mkFunTy, isUnLiftedType, Type, splitTyConApp, mkTyVarTy,
  57                           splitNewTyConApp )
  58 import Coercion         ( mkUnsafeCoercion )
  59 import TysPrim          ( intPrimTy )
  60 import TysWiredIn       ( nilDataCon, consDataCon,
  61                           tupleCon, mkTupleTy,
  62                           unitDataConId, unitTy,
  63                           charTy, charDataCon,
  64                           intTy, intDataCon,
  65                           isPArrFakeCon )
  66 import BasicTypes       ( Boxity(..) )
  67 import UniqSet          ( mkUniqSet, minusUniqSet, isEmptyUniqSet )
  68 import UniqSupply       ( splitUniqSupply, uniqFromSupply, uniqsFromSupply )
  69 import PrelNames        ( unpackCStringName, unpackCStringUtf8Name,
  70                           plusIntegerName, timesIntegerName, smallIntegerDataConName,
  71                           lengthPName, indexPName )
  72 import Outputable
  73 import SrcLoc           ( Located(..), unLoc )
  74 import Util             ( isSingleton, zipEqual, sortWith )
  75 import ListSetOps       ( assocDefault )
  76 import FastString
  77 import Data.Char        ( ord )
  78
  79 #ifdef DEBUG
  80 import Util             ( notNull )     -- Used in an assertion
  81 #endif
  82 \end{code}
  83
  84
  85
  86 %************************************************************************
  87 %*                                                                      *
  88                 Rebindable syntax
  89 %*                                                                      *
  90 %************************************************************************
  91
  92 \begin{code}
  93 dsSyntaxTable :: SyntaxTable Id
  94                -> DsM ([CoreBind],      -- Auxiliary bindings
  95                        [(Name,Id)])     -- Maps the standard name to its value
  96
  97 dsSyntaxTable rebound_ids
  98   = mapAndUnzipDs mk_bind rebound_ids   `thenDs` \ (binds_s, prs) ->
  99     return (concat binds_s, prs)
 100   where
 101         -- The cheapo special case can happen when we
 102         -- make an intermediate HsDo when desugaring a RecStmt
 103     mk_bind (std_name, HsVar id) = return ([], (std_name, id))
 104     mk_bind (std_name, expr)
 105          = dsExpr expr                          `thenDs` \ rhs ->
 106            newSysLocalDs (exprType rhs)         `thenDs` \ id ->
 107            return ([NonRec id rhs], (std_name, id))
 108
 109 lookupEvidence :: [(Name, Id)] -> Name -> Id
 110 lookupEvidence prs std_name
 111   = assocDefault (mk_panic std_name) prs std_name
 112   where
 113     mk_panic std_name = pprPanic "dsSyntaxTable" (ptext SLIT("Not found:") <+> ppr std_name)
 114 \end{code}
 115
 116
 117 %************************************************************************
 118 %*                                                                      *
 119 \subsection{Building lets}
 120 %*                                                                      *
 121 %************************************************************************
 122
 123 Use case, not let for unlifted types.  The simplifier will turn some
 124 back again.
 125
 126 \begin{code}
 127 mkDsLet :: CoreBind -> CoreExpr -> CoreExpr
 128 mkDsLet (NonRec bndr rhs) body
 129   | isUnLiftedType (idType bndr)
 130   = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 131 mkDsLet bind body
 132   = Let bind body
 133
 134 mkDsLets :: [CoreBind] -> CoreExpr -> CoreExpr
 135 mkDsLets binds body = foldr mkDsLet body binds
 136 \end{code}
 137
 138
 139 %************************************************************************
 140 %*                                                                      *
 141 \subsection{ Selecting match variables}
 142 %*                                                                      *
 143 %************************************************************************
 144
 145 We're about to match against some patterns.  We want to make some
 146 @Ids@ to use as match variables.  If a pattern has an @Id@ readily at
 147 hand, which should indeed be bound to the pattern as a whole, then use it;
 148 otherwise, make one up.
 149
 150 \begin{code}
 151 selectSimpleMatchVarL :: LPat Id -> DsM Id
 152 selectSimpleMatchVarL pat = selectMatchVar (unLoc pat)
 153
 154 -- (selectMatchVars ps tys) chooses variables of type tys
 155 -- to use for matching ps against.  If the pattern is a variable,
 156 -- we try to use that, to save inventing lots of fresh variables.
 157 --
 158 -- OLD, but interesting note:
 159 --    But even if it is a variable, its type might not match.  Consider
 160 --      data T a where
 161 --        T1 :: Int -> T Int
 162 --        T2 :: a   -> T a
 163 --
 164 --      f :: T a -> a -> Int
 165 --      f (T1 i) (x::Int) = x
 166 --      f (T2 i) (y::a)   = 0
 167 --    Then we must not choose (x::Int) as the matching variable!
 168 -- And nowadays we won't, because the (x::Int) will be wrapped in a CoPat
 169
 170 selectMatchVars :: [Pat Id] -> DsM [Id]
 171 selectMatchVars ps = mapM selectMatchVar ps
 172
 173 selectMatchVar (BangPat pat)   = selectMatchVar (unLoc pat)
 174 selectMatchVar (LazyPat pat)   = selectMatchVar (unLoc pat)
 175 selectMatchVar (ParPat pat)    = selectMatchVar (unLoc pat)
 176 selectMatchVar (VarPat var)    = return var
 177 selectMatchVar (AsPat var pat) = return (unLoc var)
 178 selectMatchVar other_pat       = newSysLocalDs (hsPatType other_pat)
 179                                   -- OK, better make up one...
 180 \end{code}
 181
 182
 183 %************************************************************************
 184 %*                                                                      *
 185 %* type synonym EquationInfo and access functions for its pieces        *
 186 %*                                                                      *
 187 %************************************************************************
 188 \subsection[EquationInfo-synonym]{@EquationInfo@: a useful synonym}
 189
 190 The ``equation info'' used by @match@ is relatively complicated and
 191 worthy of a type synonym and a few handy functions.
 192
 193 \begin{code}
 194 firstPat :: EquationInfo -> Pat Id
 195 firstPat eqn = head (eqn_pats eqn)
 196
 197 shiftEqns :: [EquationInfo] -> [EquationInfo]
 198 -- Drop the first pattern in each equation
 199 shiftEqns eqns = [ eqn { eqn_pats = tail (eqn_pats eqn) } | eqn <- eqns ]
 200 \end{code}
 201
 202 Functions on MatchResults
 203
 204 \begin{code}
 205 matchCanFail :: MatchResult -> Bool
 206 matchCanFail (MatchResult CanFail _)  = True
 207 matchCanFail (MatchResult CantFail _) = False
 208
 209 alwaysFailMatchResult :: MatchResult
 210 alwaysFailMatchResult = MatchResult CanFail (\fail -> returnDs fail)
 211
 212 cantFailMatchResult :: CoreExpr -> MatchResult
 213 cantFailMatchResult expr = MatchResult CantFail (\ ignore -> returnDs expr)
 214
 215 extractMatchResult :: MatchResult -> CoreExpr -> DsM CoreExpr
 216 extractMatchResult (MatchResult CantFail match_fn) fail_expr
 217   = match_fn (error "It can't fail!")
 218
 219 extractMatchResult (MatchResult CanFail match_fn) fail_expr
 220   = mkFailurePair fail_expr             `thenDs` \ (fail_bind, if_it_fails) ->
 221     match_fn if_it_fails                `thenDs` \ body ->
 222     returnDs (mkDsLet fail_bind body)
 223
 224
 225 combineMatchResults :: MatchResult -> MatchResult -> MatchResult
 226 combineMatchResults (MatchResult CanFail      body_fn1)
 227                     (MatchResult can_it_fail2 body_fn2)
 228   = MatchResult can_it_fail2 body_fn
 229   where
 230     body_fn fail = body_fn2 fail                        `thenDs` \ body2 ->
 231                    mkFailurePair body2                  `thenDs` \ (fail_bind, duplicatable_expr) ->
 232                    body_fn1 duplicatable_expr           `thenDs` \ body1 ->
 233                    returnDs (Let fail_bind body1)
 234
 235 combineMatchResults match_result1@(MatchResult CantFail body_fn1) match_result2
 236   = match_result1
 237
 238 adjustMatchResult :: DsWrapper -> MatchResult -> MatchResult
 239 adjustMatchResult encl_fn (MatchResult can_it_fail body_fn)
 240   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 241                                       returnDs (encl_fn body))
 242
 243 adjustMatchResultDs :: (CoreExpr -> DsM CoreExpr) -> MatchResult -> MatchResult
 244 adjustMatchResultDs encl_fn (MatchResult can_it_fail body_fn)
 245   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 246                                       encl_fn body)
 247
 248 wrapBinds :: [(Var,Var)] -> CoreExpr -> CoreExpr
 249 wrapBinds [] e = e
 250 wrapBinds ((new,old):prs) e = wrapBind new old (wrapBinds prs e)
 251
 252 wrapBind :: Var -> Var -> CoreExpr -> CoreExpr
 253 wrapBind new old body
 254   | new==old    = body
 255   | isTyVar new = App (Lam new body) (Type (mkTyVarTy old))
 256   | otherwise   = Let (NonRec new (Var old)) body
 257
 258 seqVar :: Var -> CoreExpr -> CoreExpr
 259 seqVar var body = Case (Var var) var (exprType body)
 260                         [(DEFAULT, [], body)]
 261
 262 mkCoLetMatchResult :: CoreBind -> MatchResult -> MatchResult
 263 mkCoLetMatchResult bind = adjustMatchResult (mkDsLet bind)
 264
 265 mkEvalMatchResult :: Id -> Type -> MatchResult -> MatchResult
 266 mkEvalMatchResult var ty
 267   = adjustMatchResult (\e -> Case (Var var) var ty [(DEFAULT, [], e)])
 268
 269 mkGuardedMatchResult :: CoreExpr -> MatchResult -> MatchResult
 270 mkGuardedMatchResult pred_expr (MatchResult can_it_fail body_fn)
 271   = MatchResult CanFail (\fail -> body_fn fail  `thenDs` \ body ->
 272                                   returnDs (mkIfThenElse pred_expr body fail))
 273
 274 mkCoPrimCaseMatchResult :: Id                           -- Scrutinee
 275                     -> Type                             -- Type of the case
 276                     -> [(Literal, MatchResult)]         -- Alternatives
 277                     -> MatchResult
 278 mkCoPrimCaseMatchResult var ty match_alts
 279   = MatchResult CanFail mk_case
 280   where
 281     mk_case fail
 282       = mappM (mk_alt fail) sorted_alts         `thenDs` \ alts ->
 283         returnDs (Case (Var var) var ty ((DEFAULT, [], fail) : alts))
 284
 285     sorted_alts = sortWith fst match_alts       -- Right order for a Case
 286     mk_alt fail (lit, MatchResult _ body_fn) = body_fn fail     `thenDs` \ body ->
 287                                                returnDs (LitAlt lit, [], body)
 288
 289
 290 mkCoAlgCaseMatchResult :: Id                                    -- Scrutinee
 291                     -> Type                                     -- Type of exp
 292                     -> [(DataCon, [CoreBndr], MatchResult)]     -- Alternatives
 293                     -> MatchResult
 294 mkCoAlgCaseMatchResult var ty match_alts
 295   | isNewTyCon tycon            -- Newtype case; use a let
 296   = ASSERT( null (tail match_alts) && null (tail arg_ids1) )
 297     mkCoLetMatchResult (NonRec arg_id1 newtype_rhs) match_result1
 298
 299   | isPArrFakeAlts match_alts   -- Sugared parallel array; use a literal case
 300   = MatchResult CanFail mk_parrCase
 301
 302   | otherwise                   -- Datatype case; use a case
 303   = MatchResult fail_flag mk_case
 304   where
 305     tycon = dataConTyCon con1
 306         -- [Interesting: becuase of GADTs, we can't rely on the type of
 307         --  the scrutinised Id to be sufficiently refined to have a TyCon in it]
 308
 309         -- Stuff for newtype
 310     (con1, arg_ids1, match_result1) = head match_alts
 311     arg_id1     = head arg_ids1
 312     var_ty      = idType var
 313     (tc, ty_args) = splitNewTyConApp var_ty
 314     newtype_rhs = unwrapNewTypeBody tc ty_args (Var var)
 315
 316         -- Stuff for data types
 317     data_cons      = tyConDataCons tycon
 318     match_results  = [match_result | (_,_,match_result) <- match_alts]
 319
 320     fail_flag | exhaustive_case
 321               = foldr1 orFail [can_it_fail | MatchResult can_it_fail _ <- match_results]
 322               | otherwise
 323               = CanFail
 324
 325     wild_var = mkWildId (idType var)
 326     sorted_alts  = sortWith get_tag match_alts
 327     get_tag (con, _, _) = dataConTag con
 328     mk_case fail = mappM (mk_alt fail) sorted_alts      `thenDs` \ alts ->
 329                    returnDs (Case (Var var) wild_var ty (mk_default fail ++ alts))
 330
 331     mk_alt fail (con, args, MatchResult _ body_fn)
 332         = body_fn fail                          `thenDs` \ body ->
 333           newUniqueSupply                       `thenDs` \ us ->
 334           returnDs (mkReboxingAlt (uniqsFromSupply us) con args body)
 335
 336     mk_default fail | exhaustive_case = []
 337                     | otherwise       = [(DEFAULT, [], fail)]
 338
 339     un_mentioned_constructors
 340         = mkUniqSet data_cons `minusUniqSet` mkUniqSet [ con | (con, _, _) <- match_alts]
 341     exhaustive_case = isEmptyUniqSet un_mentioned_constructors
 342
 343         -- Stuff for parallel arrays
 344         --
 345         --  * the following is to desugar cases over fake constructors for
 346         --   parallel arrays, which are introduced by `tidy1' in the `PArrPat'
 347         --   case
 348         --
 349         -- Concerning `isPArrFakeAlts':
 350         --
 351         --  * it is *not* sufficient to just check the type of the type
 352         --   constructor, as we have to be careful not to confuse the real
 353         --   representation of parallel arrays with the fake constructors;
 354         --   moreover, a list of alternatives must not mix fake and real
 355         --   constructors (this is checked earlier on)
 356         --
 357         -- FIXME: We actually go through the whole list and make sure that
 358         --        either all or none of the constructors are fake parallel
 359         --        array constructors.  This is to spot equations that mix fake
 360         --        constructors with the real representation defined in
 361         --        `PrelPArr'.  It would be nicer to spot this situation
 362         --        earlier and raise a proper error message, but it can really
 363         --        only happen in `PrelPArr' anyway.
 364         --
 365     isPArrFakeAlts [(dcon, _, _)]      = isPArrFakeCon dcon
 366     isPArrFakeAlts ((dcon, _, _):alts) =
 367       case (isPArrFakeCon dcon, isPArrFakeAlts alts) of
 368         (True , True ) -> True
 369         (False, False) -> False
 370         _              ->
 371           panic "DsUtils: You may not mix `[:...:]' with `PArr' patterns"
 372     --
 373     mk_parrCase fail =
 374       dsLookupGlobalId lengthPName                      `thenDs` \lengthP  ->
 375       unboxAlt                                          `thenDs` \alt      ->
 376       returnDs (Case (len lengthP) (mkWildId intTy) ty [alt])
 377       where
 378         elemTy      = case splitTyConApp (idType var) of
 379                         (_, [elemTy]) -> elemTy
 380                         _               -> panic panicMsg
 381         panicMsg    = "DsUtils.mkCoAlgCaseMatchResult: not a parallel array?"
 382         len lengthP = mkApps (Var lengthP) [Type elemTy, Var var]
 383         --
 384         unboxAlt =
 385           newSysLocalDs intPrimTy                       `thenDs` \l        ->
 386           dsLookupGlobalId indexPName                   `thenDs` \indexP   ->
 387           mappM (mkAlt indexP) sorted_alts              `thenDs` \alts     ->
 388           returnDs (DataAlt intDataCon, [l], (Case (Var l) wild ty (dft : alts)))
 389           where
 390             wild = mkWildId intPrimTy
 391             dft  = (DEFAULT, [], fail)
 392         --
 393         -- each alternative matches one array length (corresponding to one
 394         -- fake array constructor), so the match is on a literal; each
 395         -- alternative's body is extended by a local binding for each
 396         -- constructor argument, which are bound to array elements starting
 397         -- with the first
 398         --
 399         mkAlt indexP (con, args, MatchResult _ bodyFun) =
 400           bodyFun fail                                  `thenDs` \body     ->
 401           returnDs (LitAlt lit, [], mkDsLets binds body)
 402           where
 403             lit   = MachInt $ toInteger (dataConSourceArity con)
 404             binds = [NonRec arg (indexExpr i) | (i, arg) <- zip [1..] args]
 405             --
 406             indexExpr i = mkApps (Var indexP) [Type elemTy, Var var, mkIntExpr i]
 407 \end{code}
 408
 409
 410 %************************************************************************
 411 %*                                                                      *
 412 \subsection{Desugarer's versions of some Core functions}
 413 %*                                                                      *
 414 %************************************************************************
 415
 416 \begin{code}
 417 mkErrorAppDs :: Id              -- The error function
 418              -> Type            -- Type to which it should be applied
 419              -> String          -- The error message string to pass
 420              -> DsM CoreExpr
 421
 422 mkErrorAppDs err_id ty msg
 423   = getSrcSpanDs                `thenDs` \ src_loc ->
 424     let
 425         full_msg = showSDoc (hcat [ppr src_loc, text "|", text msg])
 426         core_msg = Lit (mkStringLit full_msg)
 427         -- mkStringLit returns a result of type String#
 428     in
 429     returnDs (mkApps (Var err_id) [Type ty, core_msg])
 430 \end{code}
 431
 432
 433 *************************************************************
 434 %*                                                                      *
 435 \subsection{Making literals}
 436 %*                                                                      *
 437 %************************************************************************
 438
 439 \begin{code}
 440 mkCharExpr     :: Char       -> CoreExpr      -- Returns        C# c :: Int
 441 mkIntExpr      :: Integer    -> CoreExpr      -- Returns        I# i :: Int
 442 mkIntegerExpr  :: Integer    -> DsM CoreExpr  -- Result :: Integer
 443 mkStringExpr   :: String     -> DsM CoreExpr  -- Result :: String
 444 mkStringExprFS :: FastString -> DsM CoreExpr  -- Result :: String
 445
 446 mkIntExpr  i = mkConApp intDataCon  [mkIntLit i]
 447 mkCharExpr c = mkConApp charDataCon [mkLit (MachChar c)]
 448
 449 mkIntegerExpr i
 450   | inIntRange i        -- Small enough, so start from an Int
 451   = dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 452     returnDs (mkSmallIntegerLit integer_dc i)
 453
 454 -- Special case for integral literals with a large magnitude:
 455 -- They are transformed into an expression involving only smaller
 456 -- integral literals. This improves constant folding.
 457
 458   | otherwise           -- Big, so start from a string
 459   = dsLookupGlobalId plusIntegerName            `thenDs` \ plus_id ->
 460     dsLookupGlobalId timesIntegerName           `thenDs` \ times_id ->
 461     dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 462     let
 463         lit i = mkSmallIntegerLit integer_dc i
 464         plus a b  = Var plus_id  `App` a `App` b
 465         times a b = Var times_id `App` a `App` b
 466
 467         -- Transform i into (x1 + (x2 + (x3 + (...) * b) * b) * b) with abs xi <= b
 468         horner :: Integer -> Integer -> CoreExpr
 469         horner b i | abs q <= 1 = if r == 0 || r == i
 470                                   then lit i
 471                                   else lit r `plus` lit (i-r)
 472                    | r == 0     =               horner b q `times` lit b
 473                    | otherwise  = lit r `plus` (horner b q `times` lit b)
 474                    where
 475                      (q,r) = i `quotRem` b
 476
 477     in
 478     returnDs (horner tARGET_MAX_INT i)
 479
 480 mkSmallIntegerLit small_integer_data_con i = mkConApp small_integer_data_con [mkIntLit i]
 481
 482 mkStringExpr str = mkStringExprFS (mkFastString str)
 483
 484 mkStringExprFS str
 485   | nullFS str
 486   = returnDs (mkNilExpr charTy)
 487
 488   | lengthFS str == 1
 489   = let
 490         the_char = mkCharExpr (headFS str)
 491     in
 492     returnDs (mkConsExpr charTy the_char (mkNilExpr charTy))
 493
 494   | all safeChar chars
 495   = dsLookupGlobalId unpackCStringName  `thenDs` \ unpack_id ->
 496     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 497
 498   | otherwise
 499   = dsLookupGlobalId unpackCStringUtf8Name      `thenDs` \ unpack_id ->
 500     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 501
 502   where
 503     chars = unpackFS str
 504     safeChar c = ord c >= 1 && ord c <= 0x7F
 505 \end{code}
 506
 507
 508 %************************************************************************
 509 %*                                                                      *
 510 \subsection[mkSelectorBind]{Make a selector bind}
 511 %*                                                                      *
 512 %************************************************************************
 513
 514 This is used in various places to do with lazy patterns.
 515 For each binder $b$ in the pattern, we create a binding:
 516 \begin{verbatim}
 517     b = case v of pat' -> b'
 518 \end{verbatim}
 519 where @pat'@ is @pat@ with each binder @b@ cloned into @b'@.
 520
 521 ToDo: making these bindings should really depend on whether there's
 522 much work to be done per binding.  If the pattern is complex, it
 523 should be de-mangled once, into a tuple (and then selected from).
 524 Otherwise the demangling can be in-line in the bindings (as here).
 525
 526 Boring!  Boring!  One error message per binder.  The above ToDo is
 527 even more helpful.  Something very similar happens for pattern-bound
 528 expressions.
 529
 530 \begin{code}
 531 mkSelectorBinds :: LPat Id      -- The pattern
 532                 -> CoreExpr     -- Expression to which the pattern is bound
 533                 -> DsM [(Id,CoreExpr)]
 534
 535 mkSelectorBinds (L _ (VarPat v)) val_expr
 536   = returnDs [(v, val_expr)]
 537
 538 mkSelectorBinds pat val_expr
 539   | isSingleton binders || is_simple_lpat pat
 540   =     -- Given   p = e, where p binds x,y
 541         -- we are going to make
 542         --      v = p   (where v is fresh)
 543         --      x = case v of p -> x
 544         --      y = case v of p -> x
 545
 546         -- Make up 'v'
 547         -- NB: give it the type of *pattern* p, not the type of the *rhs* e.
 548         -- This does not matter after desugaring, but there's a subtle
 549         -- issue with implicit parameters. Consider
 550         --      (x,y) = ?i
 551         -- Then, ?i is given type {?i :: Int}, a PredType, which is opaque
 552         -- to the desugarer.  (Why opaque?  Because newtypes have to be.  Why
 553         -- does it get that type?  So that when we abstract over it we get the
 554         -- right top-level type  (?i::Int) => ...)
 555         --
 556         -- So to get the type of 'v', use the pattern not the rhs.  Often more
 557         -- efficient too.
 558     newSysLocalDs (hsLPatType pat)      `thenDs` \ val_var ->
 559
 560         -- For the error message we make one error-app, to avoid duplication.
 561         -- But we need it at different types... so we use coerce for that
 562     mkErrorAppDs iRREFUT_PAT_ERROR_ID
 563                  unitTy (showSDoc (ppr pat))    `thenDs` \ err_expr ->
 564     newSysLocalDs unitTy                        `thenDs` \ err_var ->
 565     mappM (mk_bind val_var err_var) binders     `thenDs` \ binds ->
 566     returnDs ( (val_var, val_expr) :
 567                (err_var, err_expr) :
 568                binds )
 569
 570
 571   | otherwise
 572   = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 573                  tuple_ty (showSDoc (ppr pat))                  `thenDs` \ error_expr ->
 574     matchSimply val_expr PatBindRhs pat local_tuple error_expr  `thenDs` \ tuple_expr ->
 575     newSysLocalDs tuple_ty                                      `thenDs` \ tuple_var ->
 576     let
 577         mk_tup_bind binder
 578           = (binder, mkTupleSelector binders binder tuple_var (Var tuple_var))
 579     in
 580     returnDs ( (tuple_var, tuple_expr) : map mk_tup_bind binders )
 581   where
 582     binders     = collectPatBinders pat
 583     local_tuple = mkTupleExpr binders
 584     tuple_ty    = exprType local_tuple
 585
 586     mk_bind scrut_var err_var bndr_var
 587     -- (mk_bind sv err_var) generates
 588     --          bv = case sv of { pat -> bv; other -> coerce (type-of-bv) err_var }
 589     -- Remember, pat binds bv
 590       = matchSimply (Var scrut_var) PatBindRhs pat
 591                     (Var bndr_var) error_expr                   `thenDs` \ rhs_expr ->
 592         returnDs (bndr_var, rhs_expr)
 593       where
 594         error_expr = mkCoerce co (Var err_var)
 595         co         = mkUnsafeCoercion (exprType (Var err_var)) (idType bndr_var)
 596
 597     is_simple_lpat p = is_simple_pat (unLoc p)
 598
 599     is_simple_pat (TuplePat ps Boxed _)        = all is_triv_lpat ps
 600     is_simple_pat (ConPatOut{ pat_args = ps }) = all is_triv_lpat (hsConArgs ps)
 601     is_simple_pat (VarPat _)                   = True
 602     is_simple_pat (ParPat p)                   = is_simple_lpat p
 603     is_simple_pat other                        = False
 604
 605     is_triv_lpat p = is_triv_pat (unLoc p)
 606
 607     is_triv_pat (VarPat v)  = True
 608     is_triv_pat (WildPat _) = True
 609     is_triv_pat (ParPat p)  = is_triv_lpat p
 610     is_triv_pat other       = False
 611 \end{code}
 612
 613
 614 %************************************************************************
 615 %*                                                                      *
 616                 Tuples
 617 %*                                                                      *
 618 %************************************************************************
 619
 620 @mkTupleExpr@ builds a tuple; the inverse to @mkTupleSelector@.
 621
 622 * If it has only one element, it is the identity function.
 623
 624 * If there are more elements than a big tuple can have, it nests
 625   the tuples.
 626
 627 Nesting policy.  Better a 2-tuple of 10-tuples (3 objects) than
 628 a 10-tuple of 2-tuples (11 objects).  So we want the leaves to be big.
 629
 630 \begin{code}
 631 mkTupleExpr :: [Id] -> CoreExpr
 632 mkTupleExpr ids = mkBigCoreTup (map Var ids)
 633
 634 -- corresponding type
 635 mkTupleType :: [Id] -> Type
 636 mkTupleType ids = mkBigTuple mkCoreTupTy (map idType ids)
 637
 638 mkBigCoreTup :: [CoreExpr] -> CoreExpr
 639 mkBigCoreTup = mkBigTuple mkCoreTup
 640
 641 mkBigTuple :: ([a] -> a) -> [a] -> a
 642 mkBigTuple small_tuple as = mk_big_tuple (chunkify as)
 643   where
 644         -- Each sub-list is short enough to fit in a tuple
 645     mk_big_tuple [as] = small_tuple as
 646     mk_big_tuple as_s = mk_big_tuple (chunkify (map small_tuple as_s))
 647
 648 chunkify :: [a] -> [[a]]
 649 -- The sub-lists of the result all have length <= mAX_TUPLE_SIZE
 650 -- But there may be more than mAX_TUPLE_SIZE sub-lists
 651 chunkify xs
 652   | n_xs <= mAX_TUPLE_SIZE = {- pprTrace "Small" (ppr n_xs) -} [xs]
 653   | otherwise              = {- pprTrace "Big"   (ppr n_xs) -} (split xs)
 654   where
 655     n_xs     = length xs
 656     split [] = []
 657     split xs = take mAX_TUPLE_SIZE xs : split (drop mAX_TUPLE_SIZE xs)
 658 \end{code}
 659
 660
 661 @mkTupleSelector@ builds a selector which scrutises the given
 662 expression and extracts the one name from the list given.
 663 If you want the no-shadowing rule to apply, the caller
 664 is responsible for making sure that none of these names
 665 are in scope.
 666
 667 If there is just one id in the ``tuple'', then the selector is
 668 just the identity.
 669
 670 If it's big, it does nesting
 671         mkTupleSelector [a,b,c,d] b v e
 672           = case e of v {
 673                 (p,q) -> case p of p {
 674                            (a,b) -> b }}
 675 We use 'tpl' vars for the p,q, since shadowing does not matter.
 676
 677 In fact, it's more convenient to generate it innermost first, getting
 678
 679         case (case e of v
 680                 (p,q) -> p) of p
 681           (a,b) -> b
 682
 683 \begin{code}
 684 mkTupleSelector :: [Id]         -- The tuple args
 685                 -> Id           -- The selected one
 686                 -> Id           -- A variable of the same type as the scrutinee
 687                 -> CoreExpr     -- Scrutinee
 688                 -> CoreExpr
 689
 690 mkTupleSelector vars the_var scrut_var scrut
 691   = mk_tup_sel (chunkify vars) the_var
 692   where
 693     mk_tup_sel [vars] the_var = mkCoreSel vars the_var scrut_var scrut
 694     mk_tup_sel vars_s the_var = mkCoreSel group the_var tpl_v $
 695                                 mk_tup_sel (chunkify tpl_vs) tpl_v
 696         where
 697           tpl_tys = [mkCoreTupTy (map idType gp) | gp <- vars_s]
 698           tpl_vs  = mkTemplateLocals tpl_tys
 699           [(tpl_v, group)] = [(tpl,gp) | (tpl,gp) <- zipEqual "mkTupleSelector" tpl_vs vars_s,
 700                                          the_var `elem` gp ]
 701 \end{code}
 702
 703 A generalization of @mkTupleSelector@, allowing the body
 704 of the case to be an arbitrary expression.
 705
 706 If the tuple is big, it is nested:
 707
 708         mkTupleCase uniqs [a,b,c,d] body v e
 709           = case e of v { (p,q) ->
 710             case p of p { (a,b) ->
 711             case q of q { (c,d) ->
 712             body }}}
 713
 714 To avoid shadowing, we use uniqs to invent new variables p,q.
 715
 716 ToDo: eliminate cases where none of the variables are needed.
 717
 718 \begin{code}
 719 mkTupleCase
 720         :: UniqSupply   -- for inventing names of intermediate variables
 721         -> [Id]         -- the tuple args
 722         -> CoreExpr     -- body of the case
 723         -> Id           -- a variable of the same type as the scrutinee
 724         -> CoreExpr     -- scrutinee
 725         -> CoreExpr
 726
 727 mkTupleCase uniqs vars body scrut_var scrut
 728   = mk_tuple_case uniqs (chunkify vars) body
 729   where
 730     mk_tuple_case us [vars] body
 731       = mkSmallTupleCase vars body scrut_var scrut
 732     mk_tuple_case us vars_s body
 733       = let
 734             (us', vars', body') = foldr one_tuple_case (us, [], body) vars_s
 735         in
 736         mk_tuple_case us' (chunkify vars') body'
 737     one_tuple_case chunk_vars (us, vs, body)
 738       = let
 739             (us1, us2) = splitUniqSupply us
 740             scrut_var = mkSysLocal FSLIT("ds") (uniqFromSupply us1)
 741                         (mkCoreTupTy (map idType chunk_vars))
 742             body' = mkSmallTupleCase chunk_vars body scrut_var (Var scrut_var)
 743         in (us2, scrut_var:vs, body')
 744 \end{code}
 745
 746 The same, but with a tuple small enough not to need nesting.
 747
 748 \begin{code}
 749 mkSmallTupleCase
 750         :: [Id]         -- the tuple args
 751         -> CoreExpr     -- body of the case
 752         -> Id           -- a variable of the same type as the scrutinee
 753         -> CoreExpr     -- scrutinee
 754         -> CoreExpr
 755
 756 mkSmallTupleCase [var] body _scrut_var scrut
 757   = bindNonRec var scrut body
 758 mkSmallTupleCase vars body scrut_var scrut
 759 -- One branch no refinement?
 760   = Case scrut scrut_var (exprType body) [(DataAlt (tupleCon Boxed (length vars)), vars, body)]
 761 \end{code}
 762
 763 %************************************************************************
 764 %*                                                                      *
 765 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 766 %*                                                                      *
 767 %************************************************************************
 768
 769 Call the constructor Ids when building explicit lists, so that they
 770 interact well with rules.
 771
 772 \begin{code}
 773 mkNilExpr :: Type -> CoreExpr
 774 mkNilExpr ty = mkConApp nilDataCon [Type ty]
 775
 776 mkConsExpr :: Type -> CoreExpr -> CoreExpr -> CoreExpr
 777 mkConsExpr ty hd tl = mkConApp consDataCon [Type ty, hd, tl]
 778
 779 mkListExpr :: Type -> [CoreExpr] -> CoreExpr
 780 mkListExpr ty xs = foldr (mkConsExpr ty) (mkNilExpr ty) xs
 781
 782
 783 -- The next three functions make tuple types, constructors and selectors,
 784 -- with the rule that a 1-tuple is represented by the thing itselg
 785 mkCoreTupTy :: [Type] -> Type
 786 mkCoreTupTy [ty] = ty
 787 mkCoreTupTy tys  = mkTupleTy Boxed (length tys) tys
 788
 789 mkCoreTup :: [CoreExpr] -> CoreExpr
 790 -- Builds exactly the specified tuple.
 791 -- No fancy business for big tuples
 792 mkCoreTup []  = Var unitDataConId
 793 mkCoreTup [c] = c
 794 mkCoreTup cs  = mkConApp (tupleCon Boxed (length cs))
 795                          (map (Type . exprType) cs ++ cs)
 796
 797 mkCoreSel :: [Id]       -- The tuple args
 798           -> Id         -- The selected one
 799           -> Id         -- A variable of the same type as the scrutinee
 800           -> CoreExpr   -- Scrutinee
 801           -> CoreExpr
 802 -- mkCoreSel [x,y,z] x v e
 803 -- ===>  case e of v { (x,y,z) -> x
 804 mkCoreSel [var] should_be_the_same_var scrut_var scrut
 805   = ASSERT(var == should_be_the_same_var)
 806     scrut
 807
 808 mkCoreSel vars the_var scrut_var scrut
 809   = ASSERT( notNull vars )
 810     Case scrut scrut_var (idType the_var)
 811          [(DataAlt (tupleCon Boxed (length vars)), vars, Var the_var)]
 812 \end{code}
 813
 814
 815 %************************************************************************
 816 %*                                                                      *
 817 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 818 %*                                                                      *
 819 %************************************************************************
 820
 821 Generally, we handle pattern matching failure like this: let-bind a
 822 fail-variable, and use that variable if the thing fails:
 823 \begin{verbatim}
 824         let fail.33 = error "Help"
 825         in
 826         case x of
 827                 p1 -> ...
 828                 p2 -> fail.33
 829                 p3 -> fail.33
 830                 p4 -> ...
 831 \end{verbatim}
 832 Then
 833 \begin{itemize}
 834 \item
 835 If the case can't fail, then there'll be no mention of @fail.33@, and the
 836 simplifier will later discard it.
 837
 838 \item
 839 If it can fail in only one way, then the simplifier will inline it.
 840
 841 \item
 842 Only if it is used more than once will the let-binding remain.
 843 \end{itemize}
 844
 845 There's a problem when the result of the case expression is of
 846 unboxed type.  Then the type of @fail.33@ is unboxed too, and
 847 there is every chance that someone will change the let into a case:
 848 \begin{verbatim}
 849         case error "Help" of
 850           fail.33 -> case ....
 851 \end{verbatim}
 852
 853 which is of course utterly wrong.  Rather than drop the condition that
 854 only boxed types can be let-bound, we just turn the fail into a function
 855 for the primitive case:
 856 \begin{verbatim}
 857         let fail.33 :: Void -> Int#
 858             fail.33 = \_ -> error "Help"
 859         in
 860         case x of
 861                 p1 -> ...
 862                 p2 -> fail.33 void
 863                 p3 -> fail.33 void
 864                 p4 -> ...
 865 \end{verbatim}
 866
 867 Now @fail.33@ is a function, so it can be let-bound.
 868
 869 \begin{code}
 870 mkFailurePair :: CoreExpr       -- Result type of the whole case expression
 871               -> DsM (CoreBind, -- Binds the newly-created fail variable
 872                                 -- to either the expression or \ _ -> expression
 873                       CoreExpr) -- Either the fail variable, or fail variable
 874                                 -- applied to unit tuple
 875 mkFailurePair expr
 876   | isUnLiftedType ty
 877   = newFailLocalDs (unitTy `mkFunTy` ty)        `thenDs` \ fail_fun_var ->
 878     newSysLocalDs unitTy                        `thenDs` \ fail_fun_arg ->
 879     returnDs (NonRec fail_fun_var (Lam fail_fun_arg expr),
 880               App (Var fail_fun_var) (Var unitDataConId))
 881
 882   | otherwise
 883   = newFailLocalDs ty           `thenDs` \ fail_var ->
 884     returnDs (NonRec fail_var expr, Var fail_var)
 885   where
 886     ty = exprType expr
 887 \end{code}
 888
 889