compiler/deSugar/DsUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utilities for desugaring
   7
   8 This module exports some utility functions of no great interest.
   9
  10 \begin{code}
  11 module DsUtils (
  12         EquationInfo(..),
  13         firstPat, shiftEqns,
  14
  15         mkDsLet, mkDsLets, mkDsApp, mkDsApps,
  16
  17         MatchResult(..), CanItFail(..),
  18         cantFailMatchResult, alwaysFailMatchResult,
  19         extractMatchResult, combineMatchResults,
  20         adjustMatchResult,  adjustMatchResultDs,
  21         mkCoLetMatchResult, mkGuardedMatchResult,
  22         matchCanFail, mkEvalMatchResult,
  23         mkCoPrimCaseMatchResult, mkCoAlgCaseMatchResult,
  24         wrapBind, wrapBinds,
  25
  26         mkErrorAppDs, mkNilExpr, mkConsExpr, mkListExpr,
  27         mkIntExpr, mkCharExpr,
  28         mkStringExpr, mkStringExprFS, mkIntegerExpr,
  29
  30         mkSelectorBinds, mkTupleExpr, mkTupleSelector,
  31         mkTupleType, mkTupleCase, mkBigCoreTup,
  32         mkCoreTup, mkCoreTupTy, seqVar,
  33
  34         dsSyntaxTable, lookupEvidence,
  35
  36         selectSimpleMatchVarL, selectMatchVars, selectMatchVar,
  37         mkTickBox, mkOptTickBox, mkBinaryTickBox
  38     ) where
  39
  40 #include "HsVersions.h"
  41
  42 import {-# SOURCE #-}   Match ( matchSimply )
  43 import {-# SOURCE #-}   DsExpr( dsExpr )
  44
  45 import HsSyn
  46 import TcHsSyn
  47 import CoreSyn
  48 import Constants
  49 import DsMonad
  50
  51 import CoreUtils
  52 import MkId
  53 import Id
  54 import Var
  55 import Name
  56 import Literal
  57 import TyCon
  58 import DataCon
  59 import Type
  60 import Coercion
  61 import TysPrim
  62 import TysWiredIn
  63 import BasicTypes
  64 import UniqSet
  65 import UniqSupply
  66 import PrelNames
  67 import Outputable
  68 import SrcLoc
  69 import Util
  70 import ListSetOps
  71 import FastString
  72 import StaticFlags
  73
  74 import Data.Char
  75
  76 infixl 4 `mkDsApp`, `mkDsApps`
  77 \end{code}
  78
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83                 Rebindable syntax
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 dsSyntaxTable :: SyntaxTable Id
  89                -> DsM ([CoreBind],      -- Auxiliary bindings
  90                        [(Name,Id)])     -- Maps the standard name to its value
  91
  92 dsSyntaxTable rebound_ids
  93   = mapAndUnzipDs mk_bind rebound_ids   `thenDs` \ (binds_s, prs) ->
  94     return (concat binds_s, prs)
  95   where
  96         -- The cheapo special case can happen when we
  97         -- make an intermediate HsDo when desugaring a RecStmt
  98     mk_bind (std_name, HsVar id) = return ([], (std_name, id))
  99     mk_bind (std_name, expr)
 100          = dsExpr expr                          `thenDs` \ rhs ->
 101            newSysLocalDs (exprType rhs)         `thenDs` \ id ->
 102            return ([NonRec id rhs], (std_name, id))
 103
 104 lookupEvidence :: [(Name, Id)] -> Name -> Id
 105 lookupEvidence prs std_name
 106   = assocDefault (mk_panic std_name) prs std_name
 107   where
 108     mk_panic std_name = pprPanic "dsSyntaxTable" (ptext SLIT("Not found:") <+> ppr std_name)
 109 \end{code}
 110
 111
 112 %************************************************************************
 113 %*                                                                      *
 114 \subsection{Building lets}
 115 %*                                                                      *
 116 %************************************************************************
 117
 118 Use case, not let for unlifted types.  The simplifier will turn some
 119 back again.
 120
 121 \begin{code}
 122 mkDsLet :: CoreBind -> CoreExpr -> CoreExpr
 123 mkDsLet (NonRec bndr rhs) body  -- See Note [CoreSyn let/app invariant]
 124   | isUnLiftedType (idType bndr) && not (exprOkForSpeculation rhs)
 125   = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 126 mkDsLet bind body
 127   = Let bind body
 128
 129 mkDsLets :: [CoreBind] -> CoreExpr -> CoreExpr
 130 mkDsLets binds body = foldr mkDsLet body binds
 131
 132 -----------
 133 mkDsApp :: CoreExpr -> CoreExpr -> CoreExpr
 134 -- Check the invariant that the arg of an App is ok-for-speculation if unlifted
 135 -- See CoreSyn Note [CoreSyn let/app invariant]
 136 mkDsApp fun (Type ty) = App fun (Type ty)
 137 mkDsApp fun arg       = mk_val_app fun arg arg_ty res_ty
 138                       where
 139                         (arg_ty, res_ty) = splitFunTy (exprType fun)
 140
 141 -----------
 142 mkDsApps :: CoreExpr -> [CoreExpr] -> CoreExpr
 143 -- Slightly more efficient version of (foldl mkDsApp)
 144 mkDsApps fun args
 145   = go fun (exprType fun) args
 146   where
 147     go fun fun_ty []               = fun
 148     go fun fun_ty (Type ty : args) = go (App fun (Type ty)) (applyTy fun_ty ty) args
 149     go fun fun_ty (arg     : args) = go (mk_val_app fun arg arg_ty res_ty) res_ty args
 150                                    where
 151                                      (arg_ty, res_ty) = splitFunTy fun_ty
 152 -----------
 153 mk_val_app fun arg arg_ty res_ty        -- See Note [CoreSyn let/app invariant]
 154   | not (isUnLiftedType arg_ty) || exprOkForSpeculation arg
 155   = App fun arg         -- The vastly common case
 156
 157 mk_val_app (Var f `App` Type ty1 `App` Type ty2 `App` arg1) arg2 _ res_ty
 158   | f == seqId          -- Note [Desugaring seq]
 159   = Case arg1 (mkWildId ty1) res_ty [(DEFAULT,[],arg2)]
 160
 161 mk_val_app fun arg arg_ty res_ty
 162   = Case arg (mkWildId arg_ty) res_ty [(DEFAULT,[],App fun (Var arg_id))]
 163   where
 164     arg_id = mkWildId arg_ty    -- Lots of shadowing, but it doesn't matter,
 165                                 -- because 'fun ' should not have a free wild-id
 166 \end{code}
 167
 168 Note [Desugaring seq]  cf Trac #1031
 169 ~~~~~~~~~~~~~~~~~~~~~
 170    f x y = x `seq` (y `seq` (# x,y #))
 171
 172 The [CoreSyn let/app invariant] means that, other things being equal, because
 173 the argument to the outer 'seq' has an unlifted type, we'll use call-by-value thus:
 174
 175    f x y = case (y `seq` (# x,y #)) of v -> x `seq` v
 176
 177 But that is bad for two reasons:
 178   (a) we now evaluate y before x, and
 179   (b) we can't bind v to an unboxed pair
 180
 181 Seq is very, very special!  So we recognise it right here, and desugar to
 182         case x of _ -> case y of _ -> (# x,y #)
 183
 184 The special case would be valid for all calls to 'seq', but it's only *necessary*
 185 for ones whose second argument has an unlifted type. So we only catch the latter
 186 case here, to avoid unnecessary tests.
 187
 188
 189 %************************************************************************
 190 %*                                                                      *
 191 \subsection{ Selecting match variables}
 192 %*                                                                      *
 193 %************************************************************************
 194
 195 We're about to match against some patterns.  We want to make some
 196 @Ids@ to use as match variables.  If a pattern has an @Id@ readily at
 197 hand, which should indeed be bound to the pattern as a whole, then use it;
 198 otherwise, make one up.
 199
 200 \begin{code}
 201 selectSimpleMatchVarL :: LPat Id -> DsM Id
 202 selectSimpleMatchVarL pat = selectMatchVar (unLoc pat)
 203
 204 -- (selectMatchVars ps tys) chooses variables of type tys
 205 -- to use for matching ps against.  If the pattern is a variable,
 206 -- we try to use that, to save inventing lots of fresh variables.
 207 --
 208 -- OLD, but interesting note:
 209 --    But even if it is a variable, its type might not match.  Consider
 210 --      data T a where
 211 --        T1 :: Int -> T Int
 212 --        T2 :: a   -> T a
 213 --
 214 --      f :: T a -> a -> Int
 215 --      f (T1 i) (x::Int) = x
 216 --      f (T2 i) (y::a)   = 0
 217 --    Then we must not choose (x::Int) as the matching variable!
 218 -- And nowadays we won't, because the (x::Int) will be wrapped in a CoPat
 219
 220 selectMatchVars :: [Pat Id] -> DsM [Id]
 221 selectMatchVars ps = mapM selectMatchVar ps
 222
 223 selectMatchVar (BangPat pat)   = selectMatchVar (unLoc pat)
 224 selectMatchVar (LazyPat pat)   = selectMatchVar (unLoc pat)
 225 selectMatchVar (ParPat pat)    = selectMatchVar (unLoc pat)
 226 selectMatchVar (VarPat var)    = return var
 227 selectMatchVar (AsPat var pat) = return (unLoc var)
 228 selectMatchVar other_pat       = newSysLocalDs (hsPatType other_pat)
 229                                   -- OK, better make up one...
 230 \end{code}
 231
 232
 233 %************************************************************************
 234 %*                                                                      *
 235 %* type synonym EquationInfo and access functions for its pieces        *
 236 %*                                                                      *
 237 %************************************************************************
 238 \subsection[EquationInfo-synonym]{@EquationInfo@: a useful synonym}
 239
 240 The ``equation info'' used by @match@ is relatively complicated and
 241 worthy of a type synonym and a few handy functions.
 242
 243 \begin{code}
 244 firstPat :: EquationInfo -> Pat Id
 245 firstPat eqn = ASSERT( notNull (eqn_pats eqn) ) head (eqn_pats eqn)
 246
 247 shiftEqns :: [EquationInfo] -> [EquationInfo]
 248 -- Drop the first pattern in each equation
 249 shiftEqns eqns = [ eqn { eqn_pats = tail (eqn_pats eqn) } | eqn <- eqns ]
 250 \end{code}
 251
 252 Functions on MatchResults
 253
 254 \begin{code}
 255 matchCanFail :: MatchResult -> Bool
 256 matchCanFail (MatchResult CanFail _)  = True
 257 matchCanFail (MatchResult CantFail _) = False
 258
 259 alwaysFailMatchResult :: MatchResult
 260 alwaysFailMatchResult = MatchResult CanFail (\fail -> returnDs fail)
 261
 262 cantFailMatchResult :: CoreExpr -> MatchResult
 263 cantFailMatchResult expr = MatchResult CantFail (\ ignore -> returnDs expr)
 264
 265 extractMatchResult :: MatchResult -> CoreExpr -> DsM CoreExpr
 266 extractMatchResult (MatchResult CantFail match_fn) fail_expr
 267   = match_fn (error "It can't fail!")
 268
 269 extractMatchResult (MatchResult CanFail match_fn) fail_expr
 270   = mkFailurePair fail_expr             `thenDs` \ (fail_bind, if_it_fails) ->
 271     match_fn if_it_fails                `thenDs` \ body ->
 272     returnDs (mkDsLet fail_bind body)
 273
 274
 275 combineMatchResults :: MatchResult -> MatchResult -> MatchResult
 276 combineMatchResults (MatchResult CanFail      body_fn1)
 277                     (MatchResult can_it_fail2 body_fn2)
 278   = MatchResult can_it_fail2 body_fn
 279   where
 280     body_fn fail = body_fn2 fail                        `thenDs` \ body2 ->
 281                    mkFailurePair body2                  `thenDs` \ (fail_bind, duplicatable_expr) ->
 282                    body_fn1 duplicatable_expr           `thenDs` \ body1 ->
 283                    returnDs (Let fail_bind body1)
 284
 285 combineMatchResults match_result1@(MatchResult CantFail body_fn1) match_result2
 286   = match_result1
 287
 288 adjustMatchResult :: DsWrapper -> MatchResult -> MatchResult
 289 adjustMatchResult encl_fn (MatchResult can_it_fail body_fn)
 290   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 291                                       returnDs (encl_fn body))
 292
 293 adjustMatchResultDs :: (CoreExpr -> DsM CoreExpr) -> MatchResult -> MatchResult
 294 adjustMatchResultDs encl_fn (MatchResult can_it_fail body_fn)
 295   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 296                                       encl_fn body)
 297
 298 wrapBinds :: [(Var,Var)] -> CoreExpr -> CoreExpr
 299 wrapBinds [] e = e
 300 wrapBinds ((new,old):prs) e = wrapBind new old (wrapBinds prs e)
 301
 302 wrapBind :: Var -> Var -> CoreExpr -> CoreExpr
 303 wrapBind new old body
 304   | new==old    = body
 305   | isTyVar new = App (Lam new body) (Type (mkTyVarTy old))
 306   | otherwise   = Let (NonRec new (Var old)) body
 307
 308 seqVar :: Var -> CoreExpr -> CoreExpr
 309 seqVar var body = Case (Var var) var (exprType body)
 310                         [(DEFAULT, [], body)]
 311
 312 mkCoLetMatchResult :: CoreBind -> MatchResult -> MatchResult
 313 mkCoLetMatchResult bind = adjustMatchResult (mkDsLet bind)
 314
 315 mkEvalMatchResult :: Id -> Type -> MatchResult -> MatchResult
 316 mkEvalMatchResult var ty
 317   = adjustMatchResult (\e -> Case (Var var) var ty [(DEFAULT, [], e)])
 318
 319 mkGuardedMatchResult :: CoreExpr -> MatchResult -> MatchResult
 320 mkGuardedMatchResult pred_expr (MatchResult can_it_fail body_fn)
 321   = MatchResult CanFail (\fail -> body_fn fail  `thenDs` \ body ->
 322                                   returnDs (mkIfThenElse pred_expr body fail))
 323
 324 mkCoPrimCaseMatchResult :: Id                           -- Scrutinee
 325                     -> Type                             -- Type of the case
 326                     -> [(Literal, MatchResult)]         -- Alternatives
 327                     -> MatchResult
 328 mkCoPrimCaseMatchResult var ty match_alts
 329   = MatchResult CanFail mk_case
 330   where
 331     mk_case fail
 332       = mappM (mk_alt fail) sorted_alts         `thenDs` \ alts ->
 333         returnDs (Case (Var var) var ty ((DEFAULT, [], fail) : alts))
 334
 335     sorted_alts = sortWith fst match_alts       -- Right order for a Case
 336     mk_alt fail (lit, MatchResult _ body_fn) = body_fn fail     `thenDs` \ body ->
 337                                                returnDs (LitAlt lit, [], body)
 338
 339
 340 mkCoAlgCaseMatchResult :: Id                                    -- Scrutinee
 341                     -> Type                                     -- Type of exp
 342                     -> [(DataCon, [CoreBndr], MatchResult)]     -- Alternatives
 343                     -> MatchResult
 344 mkCoAlgCaseMatchResult var ty match_alts
 345   | isNewTyCon tycon            -- Newtype case; use a let
 346   = ASSERT( null (tail match_alts) && null (tail arg_ids1) )
 347     mkCoLetMatchResult (NonRec arg_id1 newtype_rhs) match_result1
 348
 349   | isPArrFakeAlts match_alts   -- Sugared parallel array; use a literal case
 350   = MatchResult CanFail mk_parrCase
 351
 352   | otherwise                   -- Datatype case; use a case
 353   = MatchResult fail_flag mk_case
 354   where
 355     tycon = dataConTyCon con1
 356         -- [Interesting: becuase of GADTs, we can't rely on the type of
 357         --  the scrutinised Id to be sufficiently refined to have a TyCon in it]
 358
 359         -- Stuff for newtype
 360     (con1, arg_ids1, match_result1) = ASSERT( notNull match_alts ) head match_alts
 361     arg_id1     = ASSERT( notNull arg_ids1 ) head arg_ids1
 362     var_ty      = idType var
 363     (tc, ty_args) = splitNewTyConApp var_ty
 364     newtype_rhs = unwrapNewTypeBody tc ty_args (Var var)
 365
 366         -- Stuff for data types
 367     data_cons      = tyConDataCons tycon
 368     match_results  = [match_result | (_,_,match_result) <- match_alts]
 369
 370     fail_flag | exhaustive_case
 371               = foldr1 orFail [can_it_fail | MatchResult can_it_fail _ <- match_results]
 372               | otherwise
 373               = CanFail
 374
 375     wild_var = mkWildId (idType var)
 376     sorted_alts  = sortWith get_tag match_alts
 377     get_tag (con, _, _) = dataConTag con
 378     mk_case fail = mappM (mk_alt fail) sorted_alts      `thenDs` \ alts ->
 379                    returnDs (Case (Var var) wild_var ty (mk_default fail ++ alts))
 380
 381     mk_alt fail (con, args, MatchResult _ body_fn)
 382         = body_fn fail                          `thenDs` \ body ->
 383           newUniqueSupply                       `thenDs` \ us ->
 384           returnDs (mkReboxingAlt (uniqsFromSupply us) con args body)
 385
 386     mk_default fail | exhaustive_case = []
 387                     | otherwise       = [(DEFAULT, [], fail)]
 388
 389     un_mentioned_constructors
 390         = mkUniqSet data_cons `minusUniqSet` mkUniqSet [ con | (con, _, _) <- match_alts]
 391     exhaustive_case = isEmptyUniqSet un_mentioned_constructors
 392
 393         -- Stuff for parallel arrays
 394         --
 395         --  * the following is to desugar cases over fake constructors for
 396         --   parallel arrays, which are introduced by `tidy1' in the `PArrPat'
 397         --   case
 398         --
 399         -- Concerning `isPArrFakeAlts':
 400         --
 401         --  * it is *not* sufficient to just check the type of the type
 402         --   constructor, as we have to be careful not to confuse the real
 403         --   representation of parallel arrays with the fake constructors;
 404         --   moreover, a list of alternatives must not mix fake and real
 405         --   constructors (this is checked earlier on)
 406         --
 407         -- FIXME: We actually go through the whole list and make sure that
 408         --        either all or none of the constructors are fake parallel
 409         --        array constructors.  This is to spot equations that mix fake
 410         --        constructors with the real representation defined in
 411         --        `PrelPArr'.  It would be nicer to spot this situation
 412         --        earlier and raise a proper error message, but it can really
 413         --        only happen in `PrelPArr' anyway.
 414         --
 415     isPArrFakeAlts [(dcon, _, _)]      = isPArrFakeCon dcon
 416     isPArrFakeAlts ((dcon, _, _):alts) =
 417       case (isPArrFakeCon dcon, isPArrFakeAlts alts) of
 418         (True , True ) -> True
 419         (False, False) -> False
 420         _              ->
 421           panic "DsUtils: You may not mix `[:...:]' with `PArr' patterns"
 422     --
 423     mk_parrCase fail =
 424       dsLookupGlobalId lengthPName                      `thenDs` \lengthP  ->
 425       unboxAlt                                          `thenDs` \alt      ->
 426       returnDs (Case (len lengthP) (mkWildId intTy) ty [alt])
 427       where
 428         elemTy      = case splitTyConApp (idType var) of
 429                         (_, [elemTy]) -> elemTy
 430                         _               -> panic panicMsg
 431         panicMsg    = "DsUtils.mkCoAlgCaseMatchResult: not a parallel array?"
 432         len lengthP = mkApps (Var lengthP) [Type elemTy, Var var]
 433         --
 434         unboxAlt =
 435           newSysLocalDs intPrimTy                       `thenDs` \l        ->
 436           dsLookupGlobalId indexPName                   `thenDs` \indexP   ->
 437           mappM (mkAlt indexP) sorted_alts              `thenDs` \alts     ->
 438           returnDs (DataAlt intDataCon, [l], (Case (Var l) wild ty (dft : alts)))
 439           where
 440             wild = mkWildId intPrimTy
 441             dft  = (DEFAULT, [], fail)
 442         --
 443         -- each alternative matches one array length (corresponding to one
 444         -- fake array constructor), so the match is on a literal; each
 445         -- alternative's body is extended by a local binding for each
 446         -- constructor argument, which are bound to array elements starting
 447         -- with the first
 448         --
 449         mkAlt indexP (con, args, MatchResult _ bodyFun) =
 450           bodyFun fail                                  `thenDs` \body     ->
 451           returnDs (LitAlt lit, [], mkDsLets binds body)
 452           where
 453             lit   = MachInt $ toInteger (dataConSourceArity con)
 454             binds = [NonRec arg (indexExpr i) | (i, arg) <- zip [1..] args]
 455             --
 456             indexExpr i = mkApps (Var indexP) [Type elemTy, Var var, mkIntExpr i]
 457 \end{code}
 458
 459
 460 %************************************************************************
 461 %*                                                                      *
 462 \subsection{Desugarer's versions of some Core functions}
 463 %*                                                                      *
 464 %************************************************************************
 465
 466 \begin{code}
 467 mkErrorAppDs :: Id              -- The error function
 468              -> Type            -- Type to which it should be applied
 469              -> String          -- The error message string to pass
 470              -> DsM CoreExpr
 471
 472 mkErrorAppDs err_id ty msg
 473   = getSrcSpanDs                `thenDs` \ src_loc ->
 474     let
 475         full_msg = showSDoc (hcat [ppr src_loc, text "|", text msg])
 476         core_msg = Lit (mkStringLit full_msg)
 477         -- mkStringLit returns a result of type String#
 478     in
 479     returnDs (mkApps (Var err_id) [Type ty, core_msg])
 480 \end{code}
 481
 482
 483 *************************************************************
 484 %*                                                                      *
 485 \subsection{Making literals}
 486 %*                                                                      *
 487 %************************************************************************
 488
 489 \begin{code}
 490 mkCharExpr     :: Char       -> CoreExpr      -- Returns        C# c :: Int
 491 mkIntExpr      :: Integer    -> CoreExpr      -- Returns        I# i :: Int
 492 mkIntegerExpr  :: Integer    -> DsM CoreExpr  -- Result :: Integer
 493 mkStringExpr   :: String     -> DsM CoreExpr  -- Result :: String
 494 mkStringExprFS :: FastString -> DsM CoreExpr  -- Result :: String
 495
 496 mkIntExpr  i = mkConApp intDataCon  [mkIntLit i]
 497 mkCharExpr c = mkConApp charDataCon [mkLit (MachChar c)]
 498
 499 mkIntegerExpr i
 500   | inIntRange i        -- Small enough, so start from an Int
 501   = dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 502     returnDs (mkSmallIntegerLit integer_dc i)
 503
 504 -- Special case for integral literals with a large magnitude:
 505 -- They are transformed into an expression involving only smaller
 506 -- integral literals. This improves constant folding.
 507
 508   | otherwise           -- Big, so start from a string
 509   = dsLookupGlobalId plusIntegerName            `thenDs` \ plus_id ->
 510     dsLookupGlobalId timesIntegerName           `thenDs` \ times_id ->
 511     dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 512     let
 513         lit i = mkSmallIntegerLit integer_dc i
 514         plus a b  = Var plus_id  `App` a `App` b
 515         times a b = Var times_id `App` a `App` b
 516
 517         -- Transform i into (x1 + (x2 + (x3 + (...) * b) * b) * b) with abs xi <= b
 518         horner :: Integer -> Integer -> CoreExpr
 519         horner b i | abs q <= 1 = if r == 0 || r == i
 520                                   then lit i
 521                                   else lit r `plus` lit (i-r)
 522                    | r == 0     =               horner b q `times` lit b
 523                    | otherwise  = lit r `plus` (horner b q `times` lit b)
 524                    where
 525                      (q,r) = i `quotRem` b
 526
 527     in
 528     returnDs (horner tARGET_MAX_INT i)
 529
 530 mkSmallIntegerLit small_integer_data_con i = mkConApp small_integer_data_con [mkIntLit i]
 531
 532 mkStringExpr str = mkStringExprFS (mkFastString str)
 533
 534 mkStringExprFS str
 535   | nullFS str
 536   = returnDs (mkNilExpr charTy)
 537
 538   | lengthFS str == 1
 539   = let
 540         the_char = mkCharExpr (headFS str)
 541     in
 542     returnDs (mkConsExpr charTy the_char (mkNilExpr charTy))
 543
 544   | all safeChar chars
 545   = dsLookupGlobalId unpackCStringName  `thenDs` \ unpack_id ->
 546     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 547
 548   | otherwise
 549   = dsLookupGlobalId unpackCStringUtf8Name      `thenDs` \ unpack_id ->
 550     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 551
 552   where
 553     chars = unpackFS str
 554     safeChar c = ord c >= 1 && ord c <= 0x7F
 555 \end{code}
 556
 557
 558 %************************************************************************
 559 %*                                                                      *
 560 \subsection[mkSelectorBind]{Make a selector bind}
 561 %*                                                                      *
 562 %************************************************************************
 563
 564 This is used in various places to do with lazy patterns.
 565 For each binder $b$ in the pattern, we create a binding:
 566 \begin{verbatim}
 567     b = case v of pat' -> b'
 568 \end{verbatim}
 569 where @pat'@ is @pat@ with each binder @b@ cloned into @b'@.
 570
 571 ToDo: making these bindings should really depend on whether there's
 572 much work to be done per binding.  If the pattern is complex, it
 573 should be de-mangled once, into a tuple (and then selected from).
 574 Otherwise the demangling can be in-line in the bindings (as here).
 575
 576 Boring!  Boring!  One error message per binder.  The above ToDo is
 577 even more helpful.  Something very similar happens for pattern-bound
 578 expressions.
 579
 580 \begin{code}
 581 mkSelectorBinds :: LPat Id      -- The pattern
 582                 -> CoreExpr     -- Expression to which the pattern is bound
 583                 -> DsM [(Id,CoreExpr)]
 584
 585 mkSelectorBinds (L _ (VarPat v)) val_expr
 586   = returnDs [(v, val_expr)]
 587
 588 mkSelectorBinds pat val_expr
 589   | isSingleton binders || is_simple_lpat pat
 590   =     -- Given   p = e, where p binds x,y
 591         -- we are going to make
 592         --      v = p   (where v is fresh)
 593         --      x = case v of p -> x
 594         --      y = case v of p -> x
 595
 596         -- Make up 'v'
 597         -- NB: give it the type of *pattern* p, not the type of the *rhs* e.
 598         -- This does not matter after desugaring, but there's a subtle
 599         -- issue with implicit parameters. Consider
 600         --      (x,y) = ?i
 601         -- Then, ?i is given type {?i :: Int}, a PredType, which is opaque
 602         -- to the desugarer.  (Why opaque?  Because newtypes have to be.  Why
 603         -- does it get that type?  So that when we abstract over it we get the
 604         -- right top-level type  (?i::Int) => ...)
 605         --
 606         -- So to get the type of 'v', use the pattern not the rhs.  Often more
 607         -- efficient too.
 608     newSysLocalDs (hsLPatType pat)      `thenDs` \ val_var ->
 609
 610         -- For the error message we make one error-app, to avoid duplication.
 611         -- But we need it at different types... so we use coerce for that
 612     mkErrorAppDs iRREFUT_PAT_ERROR_ID
 613                  unitTy (showSDoc (ppr pat))    `thenDs` \ err_expr ->
 614     newSysLocalDs unitTy                        `thenDs` \ err_var ->
 615     mappM (mk_bind val_var err_var) binders     `thenDs` \ binds ->
 616     returnDs ( (val_var, val_expr) :
 617                (err_var, err_expr) :
 618                binds )
 619
 620
 621   | otherwise
 622   = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 623                  tuple_ty (showSDoc (ppr pat))                  `thenDs` \ error_expr ->
 624     matchSimply val_expr PatBindRhs pat local_tuple error_expr  `thenDs` \ tuple_expr ->
 625     newSysLocalDs tuple_ty                                      `thenDs` \ tuple_var ->
 626     let
 627         mk_tup_bind binder
 628           = (binder, mkTupleSelector binders binder tuple_var (Var tuple_var))
 629     in
 630     returnDs ( (tuple_var, tuple_expr) : map mk_tup_bind binders )
 631   where
 632     binders     = collectPatBinders pat
 633     local_tuple = mkTupleExpr binders
 634     tuple_ty    = exprType local_tuple
 635
 636     mk_bind scrut_var err_var bndr_var
 637     -- (mk_bind sv err_var) generates
 638     --          bv = case sv of { pat -> bv; other -> coerce (type-of-bv) err_var }
 639     -- Remember, pat binds bv
 640       = matchSimply (Var scrut_var) PatBindRhs pat
 641                     (Var bndr_var) error_expr                   `thenDs` \ rhs_expr ->
 642         returnDs (bndr_var, rhs_expr)
 643       where
 644         error_expr = mkCoerce co (Var err_var)
 645         co         = mkUnsafeCoercion (exprType (Var err_var)) (idType bndr_var)
 646
 647     is_simple_lpat p = is_simple_pat (unLoc p)
 648
 649     is_simple_pat (TuplePat ps Boxed _)        = all is_triv_lpat ps
 650     is_simple_pat (ConPatOut{ pat_args = ps }) = all is_triv_lpat (hsConPatArgs ps)
 651     is_simple_pat (VarPat _)                   = True
 652     is_simple_pat (ParPat p)                   = is_simple_lpat p
 653     is_simple_pat other                        = False
 654
 655     is_triv_lpat p = is_triv_pat (unLoc p)
 656
 657     is_triv_pat (VarPat v)  = True
 658     is_triv_pat (WildPat _) = True
 659     is_triv_pat (ParPat p)  = is_triv_lpat p
 660     is_triv_pat other       = False
 661 \end{code}
 662
 663
 664 %************************************************************************
 665 %*                                                                      *
 666                 Tuples
 667 %*                                                                      *
 668 %************************************************************************
 669
 670 @mkTupleExpr@ builds a tuple; the inverse to @mkTupleSelector@.
 671
 672 * If it has only one element, it is the identity function.
 673
 674 * If there are more elements than a big tuple can have, it nests
 675   the tuples.
 676
 677 Nesting policy.  Better a 2-tuple of 10-tuples (3 objects) than
 678 a 10-tuple of 2-tuples (11 objects).  So we want the leaves to be big.
 679
 680 \begin{code}
 681 mkTupleExpr :: [Id] -> CoreExpr
 682 mkTupleExpr ids = mkBigCoreTup (map Var ids)
 683
 684 -- corresponding type
 685 mkTupleType :: [Id] -> Type
 686 mkTupleType ids = mkBigTuple mkCoreTupTy (map idType ids)
 687
 688 mkBigCoreTup :: [CoreExpr] -> CoreExpr
 689 mkBigCoreTup = mkBigTuple mkCoreTup
 690
 691 mkBigTuple :: ([a] -> a) -> [a] -> a
 692 mkBigTuple small_tuple as = mk_big_tuple (chunkify as)
 693   where
 694         -- Each sub-list is short enough to fit in a tuple
 695     mk_big_tuple [as] = small_tuple as
 696     mk_big_tuple as_s = mk_big_tuple (chunkify (map small_tuple as_s))
 697
 698 chunkify :: [a] -> [[a]]
 699 -- The sub-lists of the result all have length <= mAX_TUPLE_SIZE
 700 -- But there may be more than mAX_TUPLE_SIZE sub-lists
 701 chunkify xs
 702   | n_xs <= mAX_TUPLE_SIZE = {- pprTrace "Small" (ppr n_xs) -} [xs]
 703   | otherwise              = {- pprTrace "Big"   (ppr n_xs) -} (split xs)
 704   where
 705     n_xs     = length xs
 706     split [] = []
 707     split xs = take mAX_TUPLE_SIZE xs : split (drop mAX_TUPLE_SIZE xs)
 708 \end{code}
 709
 710
 711 @mkTupleSelector@ builds a selector which scrutises the given
 712 expression and extracts the one name from the list given.
 713 If you want the no-shadowing rule to apply, the caller
 714 is responsible for making sure that none of these names
 715 are in scope.
 716
 717 If there is just one id in the ``tuple'', then the selector is
 718 just the identity.
 719
 720 If it's big, it does nesting
 721         mkTupleSelector [a,b,c,d] b v e
 722           = case e of v {
 723                 (p,q) -> case p of p {
 724                            (a,b) -> b }}
 725 We use 'tpl' vars for the p,q, since shadowing does not matter.
 726
 727 In fact, it's more convenient to generate it innermost first, getting
 728
 729         case (case e of v
 730                 (p,q) -> p) of p
 731           (a,b) -> b
 732
 733 \begin{code}
 734 mkTupleSelector :: [Id]         -- The tuple args
 735                 -> Id           -- The selected one
 736                 -> Id           -- A variable of the same type as the scrutinee
 737                 -> CoreExpr     -- Scrutinee
 738                 -> CoreExpr
 739
 740 mkTupleSelector vars the_var scrut_var scrut
 741   = mk_tup_sel (chunkify vars) the_var
 742   where
 743     mk_tup_sel [vars] the_var = mkCoreSel vars the_var scrut_var scrut
 744     mk_tup_sel vars_s the_var = mkCoreSel group the_var tpl_v $
 745                                 mk_tup_sel (chunkify tpl_vs) tpl_v
 746         where
 747           tpl_tys = [mkCoreTupTy (map idType gp) | gp <- vars_s]
 748           tpl_vs  = mkTemplateLocals tpl_tys
 749           [(tpl_v, group)] = [(tpl,gp) | (tpl,gp) <- zipEqual "mkTupleSelector" tpl_vs vars_s,
 750                                          the_var `elem` gp ]
 751 \end{code}
 752
 753 A generalization of @mkTupleSelector@, allowing the body
 754 of the case to be an arbitrary expression.
 755
 756 If the tuple is big, it is nested:
 757
 758         mkTupleCase uniqs [a,b,c,d] body v e
 759           = case e of v { (p,q) ->
 760             case p of p { (a,b) ->
 761             case q of q { (c,d) ->
 762             body }}}
 763
 764 To avoid shadowing, we use uniqs to invent new variables p,q.
 765
 766 ToDo: eliminate cases where none of the variables are needed.
 767
 768 \begin{code}
 769 mkTupleCase
 770         :: UniqSupply   -- for inventing names of intermediate variables
 771         -> [Id]         -- the tuple args
 772         -> CoreExpr     -- body of the case
 773         -> Id           -- a variable of the same type as the scrutinee
 774         -> CoreExpr     -- scrutinee
 775         -> CoreExpr
 776
 777 mkTupleCase uniqs vars body scrut_var scrut
 778   = mk_tuple_case uniqs (chunkify vars) body
 779   where
 780     mk_tuple_case us [vars] body
 781       = mkSmallTupleCase vars body scrut_var scrut
 782     mk_tuple_case us vars_s body
 783       = let
 784             (us', vars', body') = foldr one_tuple_case (us, [], body) vars_s
 785         in
 786         mk_tuple_case us' (chunkify vars') body'
 787     one_tuple_case chunk_vars (us, vs, body)
 788       = let
 789             (us1, us2) = splitUniqSupply us
 790             scrut_var = mkSysLocal FSLIT("ds") (uniqFromSupply us1)
 791                         (mkCoreTupTy (map idType chunk_vars))
 792             body' = mkSmallTupleCase chunk_vars body scrut_var (Var scrut_var)
 793         in (us2, scrut_var:vs, body')
 794 \end{code}
 795
 796 The same, but with a tuple small enough not to need nesting.
 797
 798 \begin{code}
 799 mkSmallTupleCase
 800         :: [Id]         -- the tuple args
 801         -> CoreExpr     -- body of the case
 802         -> Id           -- a variable of the same type as the scrutinee
 803         -> CoreExpr     -- scrutinee
 804         -> CoreExpr
 805
 806 mkSmallTupleCase [var] body _scrut_var scrut
 807   = bindNonRec var scrut body
 808 mkSmallTupleCase vars body scrut_var scrut
 809 -- One branch no refinement?
 810   = Case scrut scrut_var (exprType body) [(DataAlt (tupleCon Boxed (length vars)), vars, body)]
 811 \end{code}
 812
 813 %************************************************************************
 814 %*                                                                      *
 815 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 816 %*                                                                      *
 817 %************************************************************************
 818
 819 Call the constructor Ids when building explicit lists, so that they
 820 interact well with rules.
 821
 822 \begin{code}
 823 mkNilExpr :: Type -> CoreExpr
 824 mkNilExpr ty = mkConApp nilDataCon [Type ty]
 825
 826 mkConsExpr :: Type -> CoreExpr -> CoreExpr -> CoreExpr
 827 mkConsExpr ty hd tl = mkConApp consDataCon [Type ty, hd, tl]
 828
 829 mkListExpr :: Type -> [CoreExpr] -> CoreExpr
 830 mkListExpr ty xs = foldr (mkConsExpr ty) (mkNilExpr ty) xs
 831
 832
 833 -- The next three functions make tuple types, constructors and selectors,
 834 -- with the rule that a 1-tuple is represented by the thing itselg
 835 mkCoreTupTy :: [Type] -> Type
 836 mkCoreTupTy [ty] = ty
 837 mkCoreTupTy tys  = mkTupleTy Boxed (length tys) tys
 838
 839 mkCoreTup :: [CoreExpr] -> CoreExpr
 840 -- Builds exactly the specified tuple.
 841 -- No fancy business for big tuples
 842 mkCoreTup []  = Var unitDataConId
 843 mkCoreTup [c] = c
 844 mkCoreTup cs  = mkConApp (tupleCon Boxed (length cs))
 845                          (map (Type . exprType) cs ++ cs)
 846
 847 mkCoreSel :: [Id]       -- The tuple args
 848           -> Id         -- The selected one
 849           -> Id         -- A variable of the same type as the scrutinee
 850           -> CoreExpr   -- Scrutinee
 851           -> CoreExpr
 852 -- mkCoreSel [x,y,z] x v e
 853 -- ===>  case e of v { (x,y,z) -> x
 854 mkCoreSel [var] should_be_the_same_var scrut_var scrut
 855   = ASSERT(var == should_be_the_same_var)
 856     scrut
 857
 858 mkCoreSel vars the_var scrut_var scrut
 859   = ASSERT( notNull vars )
 860     Case scrut scrut_var (idType the_var)
 861          [(DataAlt (tupleCon Boxed (length vars)), vars, Var the_var)]
 862 \end{code}
 863
 864 %************************************************************************
 865 %*                                                                      *
 866 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 867 %*                                                                      *
 868 %************************************************************************
 869
 870 Generally, we handle pattern matching failure like this: let-bind a
 871 fail-variable, and use that variable if the thing fails:
 872 \begin{verbatim}
 873         let fail.33 = error "Help"
 874         in
 875         case x of
 876                 p1 -> ...
 877                 p2 -> fail.33
 878                 p3 -> fail.33
 879                 p4 -> ...
 880 \end{verbatim}
 881 Then
 882 \begin{itemize}
 883 \item
 884 If the case can't fail, then there'll be no mention of @fail.33@, and the
 885 simplifier will later discard it.
 886
 887 \item
 888 If it can fail in only one way, then the simplifier will inline it.
 889
 890 \item
 891 Only if it is used more than once will the let-binding remain.
 892 \end{itemize}
 893
 894 There's a problem when the result of the case expression is of
 895 unboxed type.  Then the type of @fail.33@ is unboxed too, and
 896 there is every chance that someone will change the let into a case:
 897 \begin{verbatim}
 898         case error "Help" of
 899           fail.33 -> case ....
 900 \end{verbatim}
 901
 902 which is of course utterly wrong.  Rather than drop the condition that
 903 only boxed types can be let-bound, we just turn the fail into a function
 904 for the primitive case:
 905 \begin{verbatim}
 906         let fail.33 :: Void -> Int#
 907             fail.33 = \_ -> error "Help"
 908         in
 909         case x of
 910                 p1 -> ...
 911                 p2 -> fail.33 void
 912                 p3 -> fail.33 void
 913                 p4 -> ...
 914 \end{verbatim}
 915
 916 Now @fail.33@ is a function, so it can be let-bound.
 917
 918 \begin{code}
 919 mkFailurePair :: CoreExpr       -- Result type of the whole case expression
 920               -> DsM (CoreBind, -- Binds the newly-created fail variable
 921                                 -- to either the expression or \ _ -> expression
 922                       CoreExpr) -- Either the fail variable, or fail variable
 923                                 -- applied to unit tuple
 924 mkFailurePair expr
 925   | isUnLiftedType ty
 926   = newFailLocalDs (unitTy `mkFunTy` ty)        `thenDs` \ fail_fun_var ->
 927     newSysLocalDs unitTy                        `thenDs` \ fail_fun_arg ->
 928     returnDs (NonRec fail_fun_var (Lam fail_fun_arg expr),
 929               App (Var fail_fun_var) (Var unitDataConId))
 930
 931   | otherwise
 932   = newFailLocalDs ty           `thenDs` \ fail_var ->
 933     returnDs (NonRec fail_var expr, Var fail_var)
 934   where
 935     ty = exprType expr
 936 \end{code}
 937
 938 \begin{code}
 939 mkOptTickBox :: Maybe (Int,[Id]) -> CoreExpr -> DsM CoreExpr
 940 mkOptTickBox Nothing e   = return e
 941 mkOptTickBox (Just (ix,ids)) e = mkTickBox ix ids e
 942
 943 mkTickBox :: Int -> [Id] -> CoreExpr -> DsM CoreExpr
 944 mkTickBox ix vars e = do
 945        uq <- newUnique
 946        mod <- getModuleDs
 947        let tick | opt_Hpc   = mkTickBoxOpId uq mod ix
 948                 | otherwise = mkBreakPointOpId uq mod ix
 949        uq2 <- newUnique
 950        let occName = mkVarOcc "tick"
 951        let name = mkInternalName uq2 occName noSrcSpan   -- use mkSysLocal?
 952        let var  = Id.mkLocalId name realWorldStatePrimTy
 953        scrut <-
 954           if opt_Hpc
 955             then return (Var tick)
 956             else do
 957               let tickVar = Var tick
 958               let tickType = mkFunTys (map idType vars) realWorldStatePrimTy
 959               let scrutApTy = App tickVar (Type tickType)
 960               return (mkApps scrutApTy (map Var vars) :: Expr Id)
 961        return $ Case scrut var ty [(DEFAULT,[],e)]
 962   where
 963      ty = exprType e
 964
 965 mkBinaryTickBox :: Int -> Int -> CoreExpr -> DsM CoreExpr
 966 mkBinaryTickBox ixT ixF e = do
 967        mod <- getModuleDs
 968        uq <- newUnique
 969        mod <- getModuleDs
 970        let bndr1 = mkSysLocal FSLIT("t1") uq boolTy
 971        falseBox <- mkTickBox ixF [] $ Var falseDataConId
 972        trueBox  <- mkTickBox ixT [] $ Var trueDataConId
 973        return $ Case e bndr1 boolTy
 974                        [ (DataAlt falseDataCon, [], falseBox)
 975                        , (DataAlt trueDataCon,  [], trueBox)
 976                        ]
 977 \end{code}