compiler/deSugar/DsUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utilities for desugaring
   7
   8 This module exports some utility functions of no great interest.
   9
  10 \begin{code}
  11 module DsUtils (
  12         EquationInfo(..),
  13         firstPat, shiftEqns,
  14
  15         mkDsLet, mkDsLets,
  16
  17         MatchResult(..), CanItFail(..),
  18         cantFailMatchResult, alwaysFailMatchResult,
  19         extractMatchResult, combineMatchResults,
  20         adjustMatchResult,  adjustMatchResultDs,
  21         mkCoLetMatchResult, mkGuardedMatchResult,
  22         matchCanFail, mkEvalMatchResult,
  23         mkCoPrimCaseMatchResult, mkCoAlgCaseMatchResult,
  24         wrapBind, wrapBinds,
  25
  26         mkErrorAppDs, mkNilExpr, mkConsExpr, mkListExpr,
  27         mkIntExpr, mkCharExpr,
  28         mkStringExpr, mkStringExprFS, mkIntegerExpr,
  29
  30         mkSelectorBinds, mkTupleExpr, mkTupleSelector,
  31         mkTupleType, mkTupleCase, mkBigCoreTup,
  32         mkCoreTup, mkCoreTupTy, seqVar,
  33
  34         dsSyntaxTable, lookupEvidence,
  35
  36         selectSimpleMatchVarL, selectMatchVars, selectMatchVar,
  37         mkTickBox, mkOptTickBox, mkBinaryTickBox
  38     ) where
  39
  40 #include "HsVersions.h"
  41
  42 import {-# SOURCE #-}   Match ( matchSimply )
  43 import {-# SOURCE #-}   DsExpr( dsExpr )
  44
  45 import HsSyn
  46 import TcHsSyn
  47 import CoreSyn
  48 import Constants
  49 import DsMonad
  50
  51 import CoreUtils
  52 import MkId
  53 import Id
  54 import Var
  55 import Name
  56 import Literal
  57 import TyCon
  58 import DataCon
  59 import Type
  60 import Coercion
  61 import TysPrim
  62 import TysWiredIn
  63 import BasicTypes
  64 import UniqSet
  65 import UniqSupply
  66 import PrelNames
  67 import Outputable
  68 import SrcLoc
  69 import Util
  70 import ListSetOps
  71 import FastString
  72 import Data.Char
  73 import DynFlags
  74
  75 #ifdef DEBUG
  76 import Util
  77 #endif
  78 \end{code}
  79
  80
  81
  82 %************************************************************************
  83 %*                                                                      *
  84                 Rebindable syntax
  85 %*                                                                      *
  86 %************************************************************************
  87
  88 \begin{code}
  89 dsSyntaxTable :: SyntaxTable Id
  90                -> DsM ([CoreBind],      -- Auxiliary bindings
  91                        [(Name,Id)])     -- Maps the standard name to its value
  92
  93 dsSyntaxTable rebound_ids
  94   = mapAndUnzipDs mk_bind rebound_ids   `thenDs` \ (binds_s, prs) ->
  95     return (concat binds_s, prs)
  96   where
  97         -- The cheapo special case can happen when we
  98         -- make an intermediate HsDo when desugaring a RecStmt
  99     mk_bind (std_name, HsVar id) = return ([], (std_name, id))
 100     mk_bind (std_name, expr)
 101          = dsExpr expr                          `thenDs` \ rhs ->
 102            newSysLocalDs (exprType rhs)         `thenDs` \ id ->
 103            return ([NonRec id rhs], (std_name, id))
 104
 105 lookupEvidence :: [(Name, Id)] -> Name -> Id
 106 lookupEvidence prs std_name
 107   = assocDefault (mk_panic std_name) prs std_name
 108   where
 109     mk_panic std_name = pprPanic "dsSyntaxTable" (ptext SLIT("Not found:") <+> ppr std_name)
 110 \end{code}
 111
 112
 113 %************************************************************************
 114 %*                                                                      *
 115 \subsection{Building lets}
 116 %*                                                                      *
 117 %************************************************************************
 118
 119 Use case, not let for unlifted types.  The simplifier will turn some
 120 back again.
 121
 122 \begin{code}
 123 mkDsLet :: CoreBind -> CoreExpr -> CoreExpr
 124 mkDsLet (NonRec bndr rhs) body
 125   | isUnLiftedType (idType bndr)
 126   = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 127 mkDsLet bind body
 128   = Let bind body
 129
 130 mkDsLets :: [CoreBind] -> CoreExpr -> CoreExpr
 131 mkDsLets binds body = foldr mkDsLet body binds
 132 \end{code}
 133
 134
 135 %************************************************************************
 136 %*                                                                      *
 137 \subsection{ Selecting match variables}
 138 %*                                                                      *
 139 %************************************************************************
 140
 141 We're about to match against some patterns.  We want to make some
 142 @Ids@ to use as match variables.  If a pattern has an @Id@ readily at
 143 hand, which should indeed be bound to the pattern as a whole, then use it;
 144 otherwise, make one up.
 145
 146 \begin{code}
 147 selectSimpleMatchVarL :: LPat Id -> DsM Id
 148 selectSimpleMatchVarL pat = selectMatchVar (unLoc pat)
 149
 150 -- (selectMatchVars ps tys) chooses variables of type tys
 151 -- to use for matching ps against.  If the pattern is a variable,
 152 -- we try to use that, to save inventing lots of fresh variables.
 153 --
 154 -- OLD, but interesting note:
 155 --    But even if it is a variable, its type might not match.  Consider
 156 --      data T a where
 157 --        T1 :: Int -> T Int
 158 --        T2 :: a   -> T a
 159 --
 160 --      f :: T a -> a -> Int
 161 --      f (T1 i) (x::Int) = x
 162 --      f (T2 i) (y::a)   = 0
 163 --    Then we must not choose (x::Int) as the matching variable!
 164 -- And nowadays we won't, because the (x::Int) will be wrapped in a CoPat
 165
 166 selectMatchVars :: [Pat Id] -> DsM [Id]
 167 selectMatchVars ps = mapM selectMatchVar ps
 168
 169 selectMatchVar (BangPat pat)   = selectMatchVar (unLoc pat)
 170 selectMatchVar (LazyPat pat)   = selectMatchVar (unLoc pat)
 171 selectMatchVar (ParPat pat)    = selectMatchVar (unLoc pat)
 172 selectMatchVar (VarPat var)    = return var
 173 selectMatchVar (AsPat var pat) = return (unLoc var)
 174 selectMatchVar other_pat       = newSysLocalDs (hsPatType other_pat)
 175                                   -- OK, better make up one...
 176 \end{code}
 177
 178
 179 %************************************************************************
 180 %*                                                                      *
 181 %* type synonym EquationInfo and access functions for its pieces        *
 182 %*                                                                      *
 183 %************************************************************************
 184 \subsection[EquationInfo-synonym]{@EquationInfo@: a useful synonym}
 185
 186 The ``equation info'' used by @match@ is relatively complicated and
 187 worthy of a type synonym and a few handy functions.
 188
 189 \begin{code}
 190 firstPat :: EquationInfo -> Pat Id
 191 firstPat eqn = head (eqn_pats eqn)
 192
 193 shiftEqns :: [EquationInfo] -> [EquationInfo]
 194 -- Drop the first pattern in each equation
 195 shiftEqns eqns = [ eqn { eqn_pats = tail (eqn_pats eqn) } | eqn <- eqns ]
 196 \end{code}
 197
 198 Functions on MatchResults
 199
 200 \begin{code}
 201 matchCanFail :: MatchResult -> Bool
 202 matchCanFail (MatchResult CanFail _)  = True
 203 matchCanFail (MatchResult CantFail _) = False
 204
 205 alwaysFailMatchResult :: MatchResult
 206 alwaysFailMatchResult = MatchResult CanFail (\fail -> returnDs fail)
 207
 208 cantFailMatchResult :: CoreExpr -> MatchResult
 209 cantFailMatchResult expr = MatchResult CantFail (\ ignore -> returnDs expr)
 210
 211 extractMatchResult :: MatchResult -> CoreExpr -> DsM CoreExpr
 212 extractMatchResult (MatchResult CantFail match_fn) fail_expr
 213   = match_fn (error "It can't fail!")
 214
 215 extractMatchResult (MatchResult CanFail match_fn) fail_expr
 216   = mkFailurePair fail_expr             `thenDs` \ (fail_bind, if_it_fails) ->
 217     match_fn if_it_fails                `thenDs` \ body ->
 218     returnDs (mkDsLet fail_bind body)
 219
 220
 221 combineMatchResults :: MatchResult -> MatchResult -> MatchResult
 222 combineMatchResults (MatchResult CanFail      body_fn1)
 223                     (MatchResult can_it_fail2 body_fn2)
 224   = MatchResult can_it_fail2 body_fn
 225   where
 226     body_fn fail = body_fn2 fail                        `thenDs` \ body2 ->
 227                    mkFailurePair body2                  `thenDs` \ (fail_bind, duplicatable_expr) ->
 228                    body_fn1 duplicatable_expr           `thenDs` \ body1 ->
 229                    returnDs (Let fail_bind body1)
 230
 231 combineMatchResults match_result1@(MatchResult CantFail body_fn1) match_result2
 232   = match_result1
 233
 234 adjustMatchResult :: DsWrapper -> MatchResult -> MatchResult
 235 adjustMatchResult encl_fn (MatchResult can_it_fail body_fn)
 236   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 237                                       returnDs (encl_fn body))
 238
 239 adjustMatchResultDs :: (CoreExpr -> DsM CoreExpr) -> MatchResult -> MatchResult
 240 adjustMatchResultDs encl_fn (MatchResult can_it_fail body_fn)
 241   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 242                                       encl_fn body)
 243
 244 wrapBinds :: [(Var,Var)] -> CoreExpr -> CoreExpr
 245 wrapBinds [] e = e
 246 wrapBinds ((new,old):prs) e = wrapBind new old (wrapBinds prs e)
 247
 248 wrapBind :: Var -> Var -> CoreExpr -> CoreExpr
 249 wrapBind new old body
 250   | new==old    = body
 251   | isTyVar new = App (Lam new body) (Type (mkTyVarTy old))
 252   | otherwise   = Let (NonRec new (Var old)) body
 253
 254 seqVar :: Var -> CoreExpr -> CoreExpr
 255 seqVar var body = Case (Var var) var (exprType body)
 256                         [(DEFAULT, [], body)]
 257
 258 mkCoLetMatchResult :: CoreBind -> MatchResult -> MatchResult
 259 mkCoLetMatchResult bind = adjustMatchResult (mkDsLet bind)
 260
 261 mkEvalMatchResult :: Id -> Type -> MatchResult -> MatchResult
 262 mkEvalMatchResult var ty
 263   = adjustMatchResult (\e -> Case (Var var) var ty [(DEFAULT, [], e)])
 264
 265 mkGuardedMatchResult :: CoreExpr -> MatchResult -> MatchResult
 266 mkGuardedMatchResult pred_expr (MatchResult can_it_fail body_fn)
 267   = MatchResult CanFail (\fail -> body_fn fail  `thenDs` \ body ->
 268                                   returnDs (mkIfThenElse pred_expr body fail))
 269
 270 mkCoPrimCaseMatchResult :: Id                           -- Scrutinee
 271                     -> Type                             -- Type of the case
 272                     -> [(Literal, MatchResult)]         -- Alternatives
 273                     -> MatchResult
 274 mkCoPrimCaseMatchResult var ty match_alts
 275   = MatchResult CanFail mk_case
 276   where
 277     mk_case fail
 278       = mappM (mk_alt fail) sorted_alts         `thenDs` \ alts ->
 279         returnDs (Case (Var var) var ty ((DEFAULT, [], fail) : alts))
 280
 281     sorted_alts = sortWith fst match_alts       -- Right order for a Case
 282     mk_alt fail (lit, MatchResult _ body_fn) = body_fn fail     `thenDs` \ body ->
 283                                                returnDs (LitAlt lit, [], body)
 284
 285
 286 mkCoAlgCaseMatchResult :: Id                                    -- Scrutinee
 287                     -> Type                                     -- Type of exp
 288                     -> [(DataCon, [CoreBndr], MatchResult)]     -- Alternatives
 289                     -> MatchResult
 290 mkCoAlgCaseMatchResult var ty match_alts
 291   | isNewTyCon tycon            -- Newtype case; use a let
 292   = ASSERT( null (tail match_alts) && null (tail arg_ids1) )
 293     mkCoLetMatchResult (NonRec arg_id1 newtype_rhs) match_result1
 294
 295   | isPArrFakeAlts match_alts   -- Sugared parallel array; use a literal case
 296   = MatchResult CanFail mk_parrCase
 297
 298   | otherwise                   -- Datatype case; use a case
 299   = MatchResult fail_flag mk_case
 300   where
 301     tycon = dataConTyCon con1
 302         -- [Interesting: becuase of GADTs, we can't rely on the type of
 303         --  the scrutinised Id to be sufficiently refined to have a TyCon in it]
 304
 305         -- Stuff for newtype
 306     (con1, arg_ids1, match_result1) = head match_alts
 307     arg_id1     = head arg_ids1
 308     var_ty      = idType var
 309     (tc, ty_args) = splitNewTyConApp var_ty
 310     newtype_rhs = unwrapNewTypeBody tc ty_args (Var var)
 311
 312         -- Stuff for data types
 313     data_cons      = tyConDataCons tycon
 314     match_results  = [match_result | (_,_,match_result) <- match_alts]
 315
 316     fail_flag | exhaustive_case
 317               = foldr1 orFail [can_it_fail | MatchResult can_it_fail _ <- match_results]
 318               | otherwise
 319               = CanFail
 320
 321     wild_var = mkWildId (idType var)
 322     sorted_alts  = sortWith get_tag match_alts
 323     get_tag (con, _, _) = dataConTag con
 324     mk_case fail = mappM (mk_alt fail) sorted_alts      `thenDs` \ alts ->
 325                    returnDs (Case (Var var) wild_var ty (mk_default fail ++ alts))
 326
 327     mk_alt fail (con, args, MatchResult _ body_fn)
 328         = body_fn fail                          `thenDs` \ body ->
 329           newUniqueSupply                       `thenDs` \ us ->
 330           returnDs (mkReboxingAlt (uniqsFromSupply us) con args body)
 331
 332     mk_default fail | exhaustive_case = []
 333                     | otherwise       = [(DEFAULT, [], fail)]
 334
 335     un_mentioned_constructors
 336         = mkUniqSet data_cons `minusUniqSet` mkUniqSet [ con | (con, _, _) <- match_alts]
 337     exhaustive_case = isEmptyUniqSet un_mentioned_constructors
 338
 339         -- Stuff for parallel arrays
 340         --
 341         --  * the following is to desugar cases over fake constructors for
 342         --   parallel arrays, which are introduced by `tidy1' in the `PArrPat'
 343         --   case
 344         --
 345         -- Concerning `isPArrFakeAlts':
 346         --
 347         --  * it is *not* sufficient to just check the type of the type
 348         --   constructor, as we have to be careful not to confuse the real
 349         --   representation of parallel arrays with the fake constructors;
 350         --   moreover, a list of alternatives must not mix fake and real
 351         --   constructors (this is checked earlier on)
 352         --
 353         -- FIXME: We actually go through the whole list and make sure that
 354         --        either all or none of the constructors are fake parallel
 355         --        array constructors.  This is to spot equations that mix fake
 356         --        constructors with the real representation defined in
 357         --        `PrelPArr'.  It would be nicer to spot this situation
 358         --        earlier and raise a proper error message, but it can really
 359         --        only happen in `PrelPArr' anyway.
 360         --
 361     isPArrFakeAlts [(dcon, _, _)]      = isPArrFakeCon dcon
 362     isPArrFakeAlts ((dcon, _, _):alts) =
 363       case (isPArrFakeCon dcon, isPArrFakeAlts alts) of
 364         (True , True ) -> True
 365         (False, False) -> False
 366         _              ->
 367           panic "DsUtils: You may not mix `[:...:]' with `PArr' patterns"
 368     --
 369     mk_parrCase fail =
 370       dsLookupGlobalId lengthPName                      `thenDs` \lengthP  ->
 371       unboxAlt                                          `thenDs` \alt      ->
 372       returnDs (Case (len lengthP) (mkWildId intTy) ty [alt])
 373       where
 374         elemTy      = case splitTyConApp (idType var) of
 375                         (_, [elemTy]) -> elemTy
 376                         _               -> panic panicMsg
 377         panicMsg    = "DsUtils.mkCoAlgCaseMatchResult: not a parallel array?"
 378         len lengthP = mkApps (Var lengthP) [Type elemTy, Var var]
 379         --
 380         unboxAlt =
 381           newSysLocalDs intPrimTy                       `thenDs` \l        ->
 382           dsLookupGlobalId indexPName                   `thenDs` \indexP   ->
 383           mappM (mkAlt indexP) sorted_alts              `thenDs` \alts     ->
 384           returnDs (DataAlt intDataCon, [l], (Case (Var l) wild ty (dft : alts)))
 385           where
 386             wild = mkWildId intPrimTy
 387             dft  = (DEFAULT, [], fail)
 388         --
 389         -- each alternative matches one array length (corresponding to one
 390         -- fake array constructor), so the match is on a literal; each
 391         -- alternative's body is extended by a local binding for each
 392         -- constructor argument, which are bound to array elements starting
 393         -- with the first
 394         --
 395         mkAlt indexP (con, args, MatchResult _ bodyFun) =
 396           bodyFun fail                                  `thenDs` \body     ->
 397           returnDs (LitAlt lit, [], mkDsLets binds body)
 398           where
 399             lit   = MachInt $ toInteger (dataConSourceArity con)
 400             binds = [NonRec arg (indexExpr i) | (i, arg) <- zip [1..] args]
 401             --
 402             indexExpr i = mkApps (Var indexP) [Type elemTy, Var var, mkIntExpr i]
 403 \end{code}
 404
 405
 406 %************************************************************************
 407 %*                                                                      *
 408 \subsection{Desugarer's versions of some Core functions}
 409 %*                                                                      *
 410 %************************************************************************
 411
 412 \begin{code}
 413 mkErrorAppDs :: Id              -- The error function
 414              -> Type            -- Type to which it should be applied
 415              -> String          -- The error message string to pass
 416              -> DsM CoreExpr
 417
 418 mkErrorAppDs err_id ty msg
 419   = getSrcSpanDs                `thenDs` \ src_loc ->
 420     let
 421         full_msg = showSDoc (hcat [ppr src_loc, text "|", text msg])
 422         core_msg = Lit (mkStringLit full_msg)
 423         -- mkStringLit returns a result of type String#
 424     in
 425     returnDs (mkApps (Var err_id) [Type ty, core_msg])
 426 \end{code}
 427
 428
 429 *************************************************************
 430 %*                                                                      *
 431 \subsection{Making literals}
 432 %*                                                                      *
 433 %************************************************************************
 434
 435 \begin{code}
 436 mkCharExpr     :: Char       -> CoreExpr      -- Returns        C# c :: Int
 437 mkIntExpr      :: Integer    -> CoreExpr      -- Returns        I# i :: Int
 438 mkIntegerExpr  :: Integer    -> DsM CoreExpr  -- Result :: Integer
 439 mkStringExpr   :: String     -> DsM CoreExpr  -- Result :: String
 440 mkStringExprFS :: FastString -> DsM CoreExpr  -- Result :: String
 441
 442 mkIntExpr  i = mkConApp intDataCon  [mkIntLit i]
 443 mkCharExpr c = mkConApp charDataCon [mkLit (MachChar c)]
 444
 445 mkIntegerExpr i
 446   | inIntRange i        -- Small enough, so start from an Int
 447   = dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 448     returnDs (mkSmallIntegerLit integer_dc i)
 449
 450 -- Special case for integral literals with a large magnitude:
 451 -- They are transformed into an expression involving only smaller
 452 -- integral literals. This improves constant folding.
 453
 454   | otherwise           -- Big, so start from a string
 455   = dsLookupGlobalId plusIntegerName            `thenDs` \ plus_id ->
 456     dsLookupGlobalId timesIntegerName           `thenDs` \ times_id ->
 457     dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 458     let
 459         lit i = mkSmallIntegerLit integer_dc i
 460         plus a b  = Var plus_id  `App` a `App` b
 461         times a b = Var times_id `App` a `App` b
 462
 463         -- Transform i into (x1 + (x2 + (x3 + (...) * b) * b) * b) with abs xi <= b
 464         horner :: Integer -> Integer -> CoreExpr
 465         horner b i | abs q <= 1 = if r == 0 || r == i
 466                                   then lit i
 467                                   else lit r `plus` lit (i-r)
 468                    | r == 0     =               horner b q `times` lit b
 469                    | otherwise  = lit r `plus` (horner b q `times` lit b)
 470                    where
 471                      (q,r) = i `quotRem` b
 472
 473     in
 474     returnDs (horner tARGET_MAX_INT i)
 475
 476 mkSmallIntegerLit small_integer_data_con i = mkConApp small_integer_data_con [mkIntLit i]
 477
 478 mkStringExpr str = mkStringExprFS (mkFastString str)
 479
 480 mkStringExprFS str
 481   | nullFS str
 482   = returnDs (mkNilExpr charTy)
 483
 484   | lengthFS str == 1
 485   = let
 486         the_char = mkCharExpr (headFS str)
 487     in
 488     returnDs (mkConsExpr charTy the_char (mkNilExpr charTy))
 489
 490   | all safeChar chars
 491   = dsLookupGlobalId unpackCStringName  `thenDs` \ unpack_id ->
 492     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 493
 494   | otherwise
 495   = dsLookupGlobalId unpackCStringUtf8Name      `thenDs` \ unpack_id ->
 496     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 497
 498   where
 499     chars = unpackFS str
 500     safeChar c = ord c >= 1 && ord c <= 0x7F
 501 \end{code}
 502
 503
 504 %************************************************************************
 505 %*                                                                      *
 506 \subsection[mkSelectorBind]{Make a selector bind}
 507 %*                                                                      *
 508 %************************************************************************
 509
 510 This is used in various places to do with lazy patterns.
 511 For each binder $b$ in the pattern, we create a binding:
 512 \begin{verbatim}
 513     b = case v of pat' -> b'
 514 \end{verbatim}
 515 where @pat'@ is @pat@ with each binder @b@ cloned into @b'@.
 516
 517 ToDo: making these bindings should really depend on whether there's
 518 much work to be done per binding.  If the pattern is complex, it
 519 should be de-mangled once, into a tuple (and then selected from).
 520 Otherwise the demangling can be in-line in the bindings (as here).
 521
 522 Boring!  Boring!  One error message per binder.  The above ToDo is
 523 even more helpful.  Something very similar happens for pattern-bound
 524 expressions.
 525
 526 \begin{code}
 527 mkSelectorBinds :: LPat Id      -- The pattern
 528                 -> CoreExpr     -- Expression to which the pattern is bound
 529                 -> DsM [(Id,CoreExpr)]
 530
 531 mkSelectorBinds (L _ (VarPat v)) val_expr
 532   = returnDs [(v, val_expr)]
 533
 534 mkSelectorBinds pat val_expr
 535   | isSingleton binders || is_simple_lpat pat
 536   =     -- Given   p = e, where p binds x,y
 537         -- we are going to make
 538         --      v = p   (where v is fresh)
 539         --      x = case v of p -> x
 540         --      y = case v of p -> x
 541
 542         -- Make up 'v'
 543         -- NB: give it the type of *pattern* p, not the type of the *rhs* e.
 544         -- This does not matter after desugaring, but there's a subtle
 545         -- issue with implicit parameters. Consider
 546         --      (x,y) = ?i
 547         -- Then, ?i is given type {?i :: Int}, a PredType, which is opaque
 548         -- to the desugarer.  (Why opaque?  Because newtypes have to be.  Why
 549         -- does it get that type?  So that when we abstract over it we get the
 550         -- right top-level type  (?i::Int) => ...)
 551         --
 552         -- So to get the type of 'v', use the pattern not the rhs.  Often more
 553         -- efficient too.
 554     newSysLocalDs (hsLPatType pat)      `thenDs` \ val_var ->
 555
 556         -- For the error message we make one error-app, to avoid duplication.
 557         -- But we need it at different types... so we use coerce for that
 558     mkErrorAppDs iRREFUT_PAT_ERROR_ID
 559                  unitTy (showSDoc (ppr pat))    `thenDs` \ err_expr ->
 560     newSysLocalDs unitTy                        `thenDs` \ err_var ->
 561     mappM (mk_bind val_var err_var) binders     `thenDs` \ binds ->
 562     returnDs ( (val_var, val_expr) :
 563                (err_var, err_expr) :
 564                binds )
 565
 566
 567   | otherwise
 568   = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 569                  tuple_ty (showSDoc (ppr pat))                  `thenDs` \ error_expr ->
 570     matchSimply val_expr PatBindRhs pat local_tuple error_expr  `thenDs` \ tuple_expr ->
 571     newSysLocalDs tuple_ty                                      `thenDs` \ tuple_var ->
 572     let
 573         mk_tup_bind binder
 574           = (binder, mkTupleSelector binders binder tuple_var (Var tuple_var))
 575     in
 576     returnDs ( (tuple_var, tuple_expr) : map mk_tup_bind binders )
 577   where
 578     binders     = collectPatBinders pat
 579     local_tuple = mkTupleExpr binders
 580     tuple_ty    = exprType local_tuple
 581
 582     mk_bind scrut_var err_var bndr_var
 583     -- (mk_bind sv err_var) generates
 584     --          bv = case sv of { pat -> bv; other -> coerce (type-of-bv) err_var }
 585     -- Remember, pat binds bv
 586       = matchSimply (Var scrut_var) PatBindRhs pat
 587                     (Var bndr_var) error_expr                   `thenDs` \ rhs_expr ->
 588         returnDs (bndr_var, rhs_expr)
 589       where
 590         error_expr = mkCoerce co (Var err_var)
 591         co         = mkUnsafeCoercion (exprType (Var err_var)) (idType bndr_var)
 592
 593     is_simple_lpat p = is_simple_pat (unLoc p)
 594
 595     is_simple_pat (TuplePat ps Boxed _)        = all is_triv_lpat ps
 596     is_simple_pat (ConPatOut{ pat_args = ps }) = all is_triv_lpat (hsConArgs ps)
 597     is_simple_pat (VarPat _)                   = True
 598     is_simple_pat (ParPat p)                   = is_simple_lpat p
 599     is_simple_pat other                        = False
 600
 601     is_triv_lpat p = is_triv_pat (unLoc p)
 602
 603     is_triv_pat (VarPat v)  = True
 604     is_triv_pat (WildPat _) = True
 605     is_triv_pat (ParPat p)  = is_triv_lpat p
 606     is_triv_pat other       = False
 607 \end{code}
 608
 609
 610 %************************************************************************
 611 %*                                                                      *
 612                 Tuples
 613 %*                                                                      *
 614 %************************************************************************
 615
 616 @mkTupleExpr@ builds a tuple; the inverse to @mkTupleSelector@.
 617
 618 * If it has only one element, it is the identity function.
 619
 620 * If there are more elements than a big tuple can have, it nests
 621   the tuples.
 622
 623 Nesting policy.  Better a 2-tuple of 10-tuples (3 objects) than
 624 a 10-tuple of 2-tuples (11 objects).  So we want the leaves to be big.
 625
 626 \begin{code}
 627 mkTupleExpr :: [Id] -> CoreExpr
 628 mkTupleExpr ids = mkBigCoreTup (map Var ids)
 629
 630 -- corresponding type
 631 mkTupleType :: [Id] -> Type
 632 mkTupleType ids = mkBigTuple mkCoreTupTy (map idType ids)
 633
 634 mkBigCoreTup :: [CoreExpr] -> CoreExpr
 635 mkBigCoreTup = mkBigTuple mkCoreTup
 636
 637 mkBigTuple :: ([a] -> a) -> [a] -> a
 638 mkBigTuple small_tuple as = mk_big_tuple (chunkify as)
 639   where
 640         -- Each sub-list is short enough to fit in a tuple
 641     mk_big_tuple [as] = small_tuple as
 642     mk_big_tuple as_s = mk_big_tuple (chunkify (map small_tuple as_s))
 643
 644 chunkify :: [a] -> [[a]]
 645 -- The sub-lists of the result all have length <= mAX_TUPLE_SIZE
 646 -- But there may be more than mAX_TUPLE_SIZE sub-lists
 647 chunkify xs
 648   | n_xs <= mAX_TUPLE_SIZE = {- pprTrace "Small" (ppr n_xs) -} [xs]
 649   | otherwise              = {- pprTrace "Big"   (ppr n_xs) -} (split xs)
 650   where
 651     n_xs     = length xs
 652     split [] = []
 653     split xs = take mAX_TUPLE_SIZE xs : split (drop mAX_TUPLE_SIZE xs)
 654 \end{code}
 655
 656
 657 @mkTupleSelector@ builds a selector which scrutises the given
 658 expression and extracts the one name from the list given.
 659 If you want the no-shadowing rule to apply, the caller
 660 is responsible for making sure that none of these names
 661 are in scope.
 662
 663 If there is just one id in the ``tuple'', then the selector is
 664 just the identity.
 665
 666 If it's big, it does nesting
 667         mkTupleSelector [a,b,c,d] b v e
 668           = case e of v {
 669                 (p,q) -> case p of p {
 670                            (a,b) -> b }}
 671 We use 'tpl' vars for the p,q, since shadowing does not matter.
 672
 673 In fact, it's more convenient to generate it innermost first, getting
 674
 675         case (case e of v
 676                 (p,q) -> p) of p
 677           (a,b) -> b
 678
 679 \begin{code}
 680 mkTupleSelector :: [Id]         -- The tuple args
 681                 -> Id           -- The selected one
 682                 -> Id           -- A variable of the same type as the scrutinee
 683                 -> CoreExpr     -- Scrutinee
 684                 -> CoreExpr
 685
 686 mkTupleSelector vars the_var scrut_var scrut
 687   = mk_tup_sel (chunkify vars) the_var
 688   where
 689     mk_tup_sel [vars] the_var = mkCoreSel vars the_var scrut_var scrut
 690     mk_tup_sel vars_s the_var = mkCoreSel group the_var tpl_v $
 691                                 mk_tup_sel (chunkify tpl_vs) tpl_v
 692         where
 693           tpl_tys = [mkCoreTupTy (map idType gp) | gp <- vars_s]
 694           tpl_vs  = mkTemplateLocals tpl_tys
 695           [(tpl_v, group)] = [(tpl,gp) | (tpl,gp) <- zipEqual "mkTupleSelector" tpl_vs vars_s,
 696                                          the_var `elem` gp ]
 697 \end{code}
 698
 699 A generalization of @mkTupleSelector@, allowing the body
 700 of the case to be an arbitrary expression.
 701
 702 If the tuple is big, it is nested:
 703
 704         mkTupleCase uniqs [a,b,c,d] body v e
 705           = case e of v { (p,q) ->
 706             case p of p { (a,b) ->
 707             case q of q { (c,d) ->
 708             body }}}
 709
 710 To avoid shadowing, we use uniqs to invent new variables p,q.
 711
 712 ToDo: eliminate cases where none of the variables are needed.
 713
 714 \begin{code}
 715 mkTupleCase
 716         :: UniqSupply   -- for inventing names of intermediate variables
 717         -> [Id]         -- the tuple args
 718         -> CoreExpr     -- body of the case
 719         -> Id           -- a variable of the same type as the scrutinee
 720         -> CoreExpr     -- scrutinee
 721         -> CoreExpr
 722
 723 mkTupleCase uniqs vars body scrut_var scrut
 724   = mk_tuple_case uniqs (chunkify vars) body
 725   where
 726     mk_tuple_case us [vars] body
 727       = mkSmallTupleCase vars body scrut_var scrut
 728     mk_tuple_case us vars_s body
 729       = let
 730             (us', vars', body') = foldr one_tuple_case (us, [], body) vars_s
 731         in
 732         mk_tuple_case us' (chunkify vars') body'
 733     one_tuple_case chunk_vars (us, vs, body)
 734       = let
 735             (us1, us2) = splitUniqSupply us
 736             scrut_var = mkSysLocal FSLIT("ds") (uniqFromSupply us1)
 737                         (mkCoreTupTy (map idType chunk_vars))
 738             body' = mkSmallTupleCase chunk_vars body scrut_var (Var scrut_var)
 739         in (us2, scrut_var:vs, body')
 740 \end{code}
 741
 742 The same, but with a tuple small enough not to need nesting.
 743
 744 \begin{code}
 745 mkSmallTupleCase
 746         :: [Id]         -- the tuple args
 747         -> CoreExpr     -- body of the case
 748         -> Id           -- a variable of the same type as the scrutinee
 749         -> CoreExpr     -- scrutinee
 750         -> CoreExpr
 751
 752 mkSmallTupleCase [var] body _scrut_var scrut
 753   = bindNonRec var scrut body
 754 mkSmallTupleCase vars body scrut_var scrut
 755 -- One branch no refinement?
 756   = Case scrut scrut_var (exprType body) [(DataAlt (tupleCon Boxed (length vars)), vars, body)]
 757 \end{code}
 758
 759 %************************************************************************
 760 %*                                                                      *
 761 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 762 %*                                                                      *
 763 %************************************************************************
 764
 765 Call the constructor Ids when building explicit lists, so that they
 766 interact well with rules.
 767
 768 \begin{code}
 769 mkNilExpr :: Type -> CoreExpr
 770 mkNilExpr ty = mkConApp nilDataCon [Type ty]
 771
 772 mkConsExpr :: Type -> CoreExpr -> CoreExpr -> CoreExpr
 773 mkConsExpr ty hd tl = mkConApp consDataCon [Type ty, hd, tl]
 774
 775 mkListExpr :: Type -> [CoreExpr] -> CoreExpr
 776 mkListExpr ty xs = foldr (mkConsExpr ty) (mkNilExpr ty) xs
 777
 778
 779 -- The next three functions make tuple types, constructors and selectors,
 780 -- with the rule that a 1-tuple is represented by the thing itselg
 781 mkCoreTupTy :: [Type] -> Type
 782 mkCoreTupTy [ty] = ty
 783 mkCoreTupTy tys  = mkTupleTy Boxed (length tys) tys
 784
 785 mkCoreTup :: [CoreExpr] -> CoreExpr
 786 -- Builds exactly the specified tuple.
 787 -- No fancy business for big tuples
 788 mkCoreTup []  = Var unitDataConId
 789 mkCoreTup [c] = c
 790 mkCoreTup cs  = mkConApp (tupleCon Boxed (length cs))
 791                          (map (Type . exprType) cs ++ cs)
 792
 793 mkCoreSel :: [Id]       -- The tuple args
 794           -> Id         -- The selected one
 795           -> Id         -- A variable of the same type as the scrutinee
 796           -> CoreExpr   -- Scrutinee
 797           -> CoreExpr
 798 -- mkCoreSel [x,y,z] x v e
 799 -- ===>  case e of v { (x,y,z) -> x
 800 mkCoreSel [var] should_be_the_same_var scrut_var scrut
 801   = ASSERT(var == should_be_the_same_var)
 802     scrut
 803
 804 mkCoreSel vars the_var scrut_var scrut
 805   = ASSERT( notNull vars )
 806     Case scrut scrut_var (idType the_var)
 807          [(DataAlt (tupleCon Boxed (length vars)), vars, Var the_var)]
 808 \end{code}
 809
 810
 811 %************************************************************************
 812 %*                                                                      *
 813 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 814 %*                                                                      *
 815 %************************************************************************
 816
 817 Generally, we handle pattern matching failure like this: let-bind a
 818 fail-variable, and use that variable if the thing fails:
 819 \begin{verbatim}
 820         let fail.33 = error "Help"
 821         in
 822         case x of
 823                 p1 -> ...
 824                 p2 -> fail.33
 825                 p3 -> fail.33
 826                 p4 -> ...
 827 \end{verbatim}
 828 Then
 829 \begin{itemize}
 830 \item
 831 If the case can't fail, then there'll be no mention of @fail.33@, and the
 832 simplifier will later discard it.
 833
 834 \item
 835 If it can fail in only one way, then the simplifier will inline it.
 836
 837 \item
 838 Only if it is used more than once will the let-binding remain.
 839 \end{itemize}
 840
 841 There's a problem when the result of the case expression is of
 842 unboxed type.  Then the type of @fail.33@ is unboxed too, and
 843 there is every chance that someone will change the let into a case:
 844 \begin{verbatim}
 845         case error "Help" of
 846           fail.33 -> case ....
 847 \end{verbatim}
 848
 849 which is of course utterly wrong.  Rather than drop the condition that
 850 only boxed types can be let-bound, we just turn the fail into a function
 851 for the primitive case:
 852 \begin{verbatim}
 853         let fail.33 :: Void -> Int#
 854             fail.33 = \_ -> error "Help"
 855         in
 856         case x of
 857                 p1 -> ...
 858                 p2 -> fail.33 void
 859                 p3 -> fail.33 void
 860                 p4 -> ...
 861 \end{verbatim}
 862
 863 Now @fail.33@ is a function, so it can be let-bound.
 864
 865 \begin{code}
 866 mkFailurePair :: CoreExpr       -- Result type of the whole case expression
 867               -> DsM (CoreBind, -- Binds the newly-created fail variable
 868                                 -- to either the expression or \ _ -> expression
 869                       CoreExpr) -- Either the fail variable, or fail variable
 870                                 -- applied to unit tuple
 871 mkFailurePair expr
 872   | isUnLiftedType ty
 873   = newFailLocalDs (unitTy `mkFunTy` ty)        `thenDs` \ fail_fun_var ->
 874     newSysLocalDs unitTy                        `thenDs` \ fail_fun_arg ->
 875     returnDs (NonRec fail_fun_var (Lam fail_fun_arg expr),
 876               App (Var fail_fun_var) (Var unitDataConId))
 877
 878   | otherwise
 879   = newFailLocalDs ty           `thenDs` \ fail_var ->
 880     returnDs (NonRec fail_var expr, Var fail_var)
 881   where
 882     ty = exprType expr
 883 \end{code}
 884
 885 \begin{code}
 886 mkOptTickBox :: Maybe Int -> CoreExpr -> DsM CoreExpr
 887 mkOptTickBox Nothing e   = return e
 888 mkOptTickBox (Just ix) e = mkTickBox ix e
 889
 890 mkTickBox :: Int -> CoreExpr -> DsM CoreExpr
 891 mkTickBox ix e = do
 892        uq <- newUnique
 893        mod <- getModuleDs
 894        let tick = mkTickBoxOpId uq mod ix
 895        uq2 <- newUnique
 896        let occName = mkVarOcc "tick"
 897        let name = mkInternalName uq2 occName noSrcLoc   -- use mkSysLocal?
 898        let var  = Id.mkLocalId name realWorldStatePrimTy
 899        return $ Case (Var tick)
 900                      var
 901                      ty
 902                      [(DEFAULT,[],e)]
 903   where
 904      ty = exprType e
 905
 906 mkBinaryTickBox :: Int -> Int -> CoreExpr -> DsM CoreExpr
 907 mkBinaryTickBox ixT ixF e = do
 908        mod <- getModuleDs
 909        uq <- newUnique
 910        mod <- getModuleDs
 911        let bndr1 = mkSysLocal FSLIT("t1") uq boolTy
 912        falseBox <- mkTickBox ixF $ Var falseDataConId
 913        trueBox  <- mkTickBox ixT $ Var trueDataConId
 914        return $ Case e bndr1 boolTy
 915                        [ (DataAlt falseDataCon, [], falseBox)
 916                        , (DataAlt trueDataCon,  [], trueBox)
 917                        ]
 918 \end{code}