compiler/deSugar/DsUtils.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Utilities for desugaring
   7
   8 This module exports some utility functions of no great interest.
   9
  10 \begin{code}
  11 module DsUtils (
  12         EquationInfo(..),
  13         firstPat, shiftEqns,
  14
  15         mkDsLet, mkDsLets,
  16
  17         MatchResult(..), CanItFail(..),
  18         cantFailMatchResult, alwaysFailMatchResult,
  19         extractMatchResult, combineMatchResults,
  20         adjustMatchResult,  adjustMatchResultDs,
  21         mkCoLetMatchResult, mkGuardedMatchResult,
  22         matchCanFail, mkEvalMatchResult,
  23         mkCoPrimCaseMatchResult, mkCoAlgCaseMatchResult,
  24         wrapBind, wrapBinds,
  25
  26         mkErrorAppDs, mkNilExpr, mkConsExpr, mkListExpr,
  27         mkIntExpr, mkCharExpr,
  28         mkStringExpr, mkStringExprFS, mkIntegerExpr,
  29
  30         mkSelectorBinds, mkTupleExpr, mkTupleSelector,
  31         mkTupleType, mkTupleCase, mkBigCoreTup,
  32         mkCoreTup, mkCoreTupTy, seqVar,
  33
  34         dsSyntaxTable, lookupEvidence,
  35
  36         selectSimpleMatchVarL, selectMatchVars, selectMatchVar,
  37         mkTickBox, mkOptTickBox, mkBinaryTickBox
  38     ) where
  39
  40 #include "HsVersions.h"
  41
  42 import {-# SOURCE #-}   Match ( matchSimply )
  43 import {-# SOURCE #-}   DsExpr( dsExpr )
  44
  45 import HsSyn
  46 import TcHsSyn
  47 import CoreSyn
  48 import Constants
  49 import DsMonad
  50
  51 import CoreUtils
  52 import MkId
  53 import Id
  54 import Var
  55 import Name
  56 import Literal
  57 import TyCon
  58 import DataCon
  59 import Type
  60 import Coercion
  61 import TysPrim
  62 import TysWiredIn
  63 import BasicTypes
  64 import UniqSet
  65 import UniqSupply
  66 import PrelNames
  67 import Outputable
  68 import SrcLoc
  69 import Util
  70 import ListSetOps
  71 import FastString
  72 import Data.Char
  73
  74 #ifdef DEBUG
  75 import Util
  76 #endif
  77 \end{code}
  78
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83                 Rebindable syntax
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 dsSyntaxTable :: SyntaxTable Id
  89                -> DsM ([CoreBind],      -- Auxiliary bindings
  90                        [(Name,Id)])     -- Maps the standard name to its value
  91
  92 dsSyntaxTable rebound_ids
  93   = mapAndUnzipDs mk_bind rebound_ids   `thenDs` \ (binds_s, prs) ->
  94     return (concat binds_s, prs)
  95   where
  96         -- The cheapo special case can happen when we
  97         -- make an intermediate HsDo when desugaring a RecStmt
  98     mk_bind (std_name, HsVar id) = return ([], (std_name, id))
  99     mk_bind (std_name, expr)
 100          = dsExpr expr                          `thenDs` \ rhs ->
 101            newSysLocalDs (exprType rhs)         `thenDs` \ id ->
 102            return ([NonRec id rhs], (std_name, id))
 103
 104 lookupEvidence :: [(Name, Id)] -> Name -> Id
 105 lookupEvidence prs std_name
 106   = assocDefault (mk_panic std_name) prs std_name
 107   where
 108     mk_panic std_name = pprPanic "dsSyntaxTable" (ptext SLIT("Not found:") <+> ppr std_name)
 109 \end{code}
 110
 111
 112 %************************************************************************
 113 %*                                                                      *
 114 \subsection{Building lets}
 115 %*                                                                      *
 116 %************************************************************************
 117
 118 Use case, not let for unlifted types.  The simplifier will turn some
 119 back again.
 120
 121 \begin{code}
 122 mkDsLet :: CoreBind -> CoreExpr -> CoreExpr
 123 mkDsLet (NonRec bndr rhs) body
 124   | isUnLiftedType (idType bndr)
 125   = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 126 mkDsLet bind body
 127   = Let bind body
 128
 129 mkDsLets :: [CoreBind] -> CoreExpr -> CoreExpr
 130 mkDsLets binds body = foldr mkDsLet body binds
 131 \end{code}
 132
 133
 134 %************************************************************************
 135 %*                                                                      *
 136 \subsection{ Selecting match variables}
 137 %*                                                                      *
 138 %************************************************************************
 139
 140 We're about to match against some patterns.  We want to make some
 141 @Ids@ to use as match variables.  If a pattern has an @Id@ readily at
 142 hand, which should indeed be bound to the pattern as a whole, then use it;
 143 otherwise, make one up.
 144
 145 \begin{code}
 146 selectSimpleMatchVarL :: LPat Id -> DsM Id
 147 selectSimpleMatchVarL pat = selectMatchVar (unLoc pat)
 148
 149 -- (selectMatchVars ps tys) chooses variables of type tys
 150 -- to use for matching ps against.  If the pattern is a variable,
 151 -- we try to use that, to save inventing lots of fresh variables.
 152 --
 153 -- OLD, but interesting note:
 154 --    But even if it is a variable, its type might not match.  Consider
 155 --      data T a where
 156 --        T1 :: Int -> T Int
 157 --        T2 :: a   -> T a
 158 --
 159 --      f :: T a -> a -> Int
 160 --      f (T1 i) (x::Int) = x
 161 --      f (T2 i) (y::a)   = 0
 162 --    Then we must not choose (x::Int) as the matching variable!
 163 -- And nowadays we won't, because the (x::Int) will be wrapped in a CoPat
 164
 165 selectMatchVars :: [Pat Id] -> DsM [Id]
 166 selectMatchVars ps = mapM selectMatchVar ps
 167
 168 selectMatchVar (BangPat pat)   = selectMatchVar (unLoc pat)
 169 selectMatchVar (LazyPat pat)   = selectMatchVar (unLoc pat)
 170 selectMatchVar (ParPat pat)    = selectMatchVar (unLoc pat)
 171 selectMatchVar (VarPat var)    = return var
 172 selectMatchVar (AsPat var pat) = return (unLoc var)
 173 selectMatchVar other_pat       = newSysLocalDs (hsPatType other_pat)
 174                                   -- OK, better make up one...
 175 \end{code}
 176
 177
 178 %************************************************************************
 179 %*                                                                      *
 180 %* type synonym EquationInfo and access functions for its pieces        *
 181 %*                                                                      *
 182 %************************************************************************
 183 \subsection[EquationInfo-synonym]{@EquationInfo@: a useful synonym}
 184
 185 The ``equation info'' used by @match@ is relatively complicated and
 186 worthy of a type synonym and a few handy functions.
 187
 188 \begin{code}
 189 firstPat :: EquationInfo -> Pat Id
 190 firstPat eqn = head (eqn_pats eqn)
 191
 192 shiftEqns :: [EquationInfo] -> [EquationInfo]
 193 -- Drop the first pattern in each equation
 194 shiftEqns eqns = [ eqn { eqn_pats = tail (eqn_pats eqn) } | eqn <- eqns ]
 195 \end{code}
 196
 197 Functions on MatchResults
 198
 199 \begin{code}
 200 matchCanFail :: MatchResult -> Bool
 201 matchCanFail (MatchResult CanFail _)  = True
 202 matchCanFail (MatchResult CantFail _) = False
 203
 204 alwaysFailMatchResult :: MatchResult
 205 alwaysFailMatchResult = MatchResult CanFail (\fail -> returnDs fail)
 206
 207 cantFailMatchResult :: CoreExpr -> MatchResult
 208 cantFailMatchResult expr = MatchResult CantFail (\ ignore -> returnDs expr)
 209
 210 extractMatchResult :: MatchResult -> CoreExpr -> DsM CoreExpr
 211 extractMatchResult (MatchResult CantFail match_fn) fail_expr
 212   = match_fn (error "It can't fail!")
 213
 214 extractMatchResult (MatchResult CanFail match_fn) fail_expr
 215   = mkFailurePair fail_expr             `thenDs` \ (fail_bind, if_it_fails) ->
 216     match_fn if_it_fails                `thenDs` \ body ->
 217     returnDs (mkDsLet fail_bind body)
 218
 219
 220 combineMatchResults :: MatchResult -> MatchResult -> MatchResult
 221 combineMatchResults (MatchResult CanFail      body_fn1)
 222                     (MatchResult can_it_fail2 body_fn2)
 223   = MatchResult can_it_fail2 body_fn
 224   where
 225     body_fn fail = body_fn2 fail                        `thenDs` \ body2 ->
 226                    mkFailurePair body2                  `thenDs` \ (fail_bind, duplicatable_expr) ->
 227                    body_fn1 duplicatable_expr           `thenDs` \ body1 ->
 228                    returnDs (Let fail_bind body1)
 229
 230 combineMatchResults match_result1@(MatchResult CantFail body_fn1) match_result2
 231   = match_result1
 232
 233 adjustMatchResult :: DsWrapper -> MatchResult -> MatchResult
 234 adjustMatchResult encl_fn (MatchResult can_it_fail body_fn)
 235   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 236                                       returnDs (encl_fn body))
 237
 238 adjustMatchResultDs :: (CoreExpr -> DsM CoreExpr) -> MatchResult -> MatchResult
 239 adjustMatchResultDs encl_fn (MatchResult can_it_fail body_fn)
 240   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 241                                       encl_fn body)
 242
 243 wrapBinds :: [(Var,Var)] -> CoreExpr -> CoreExpr
 244 wrapBinds [] e = e
 245 wrapBinds ((new,old):prs) e = wrapBind new old (wrapBinds prs e)
 246
 247 wrapBind :: Var -> Var -> CoreExpr -> CoreExpr
 248 wrapBind new old body
 249   | new==old    = body
 250   | isTyVar new = App (Lam new body) (Type (mkTyVarTy old))
 251   | otherwise   = Let (NonRec new (Var old)) body
 252
 253 seqVar :: Var -> CoreExpr -> CoreExpr
 254 seqVar var body = Case (Var var) var (exprType body)
 255                         [(DEFAULT, [], body)]
 256
 257 mkCoLetMatchResult :: CoreBind -> MatchResult -> MatchResult
 258 mkCoLetMatchResult bind = adjustMatchResult (mkDsLet bind)
 259
 260 mkEvalMatchResult :: Id -> Type -> MatchResult -> MatchResult
 261 mkEvalMatchResult var ty
 262   = adjustMatchResult (\e -> Case (Var var) var ty [(DEFAULT, [], e)])
 263
 264 mkGuardedMatchResult :: CoreExpr -> MatchResult -> MatchResult
 265 mkGuardedMatchResult pred_expr (MatchResult can_it_fail body_fn)
 266   = MatchResult CanFail (\fail -> body_fn fail  `thenDs` \ body ->
 267                                   returnDs (mkIfThenElse pred_expr body fail))
 268
 269 mkCoPrimCaseMatchResult :: Id                           -- Scrutinee
 270                     -> Type                             -- Type of the case
 271                     -> [(Literal, MatchResult)]         -- Alternatives
 272                     -> MatchResult
 273 mkCoPrimCaseMatchResult var ty match_alts
 274   = MatchResult CanFail mk_case
 275   where
 276     mk_case fail
 277       = mappM (mk_alt fail) sorted_alts         `thenDs` \ alts ->
 278         returnDs (Case (Var var) var ty ((DEFAULT, [], fail) : alts))
 279
 280     sorted_alts = sortWith fst match_alts       -- Right order for a Case
 281     mk_alt fail (lit, MatchResult _ body_fn) = body_fn fail     `thenDs` \ body ->
 282                                                returnDs (LitAlt lit, [], body)
 283
 284
 285 mkCoAlgCaseMatchResult :: Id                                    -- Scrutinee
 286                     -> Type                                     -- Type of exp
 287                     -> [(DataCon, [CoreBndr], MatchResult)]     -- Alternatives
 288                     -> MatchResult
 289 mkCoAlgCaseMatchResult var ty match_alts
 290   | isNewTyCon tycon            -- Newtype case; use a let
 291   = ASSERT( null (tail match_alts) && null (tail arg_ids1) )
 292     mkCoLetMatchResult (NonRec arg_id1 newtype_rhs) match_result1
 293
 294   | isPArrFakeAlts match_alts   -- Sugared parallel array; use a literal case
 295   = MatchResult CanFail mk_parrCase
 296
 297   | otherwise                   -- Datatype case; use a case
 298   = MatchResult fail_flag mk_case
 299   where
 300     tycon = dataConTyCon con1
 301         -- [Interesting: becuase of GADTs, we can't rely on the type of
 302         --  the scrutinised Id to be sufficiently refined to have a TyCon in it]
 303
 304         -- Stuff for newtype
 305     (con1, arg_ids1, match_result1) = head match_alts
 306     arg_id1     = head arg_ids1
 307     var_ty      = idType var
 308     (tc, ty_args) = splitNewTyConApp var_ty
 309     newtype_rhs = unwrapNewTypeBody tc ty_args (Var var)
 310
 311         -- Stuff for data types
 312     data_cons      = tyConDataCons tycon
 313     match_results  = [match_result | (_,_,match_result) <- match_alts]
 314
 315     fail_flag | exhaustive_case
 316               = foldr1 orFail [can_it_fail | MatchResult can_it_fail _ <- match_results]
 317               | otherwise
 318               = CanFail
 319
 320     wild_var = mkWildId (idType var)
 321     sorted_alts  = sortWith get_tag match_alts
 322     get_tag (con, _, _) = dataConTag con
 323     mk_case fail = mappM (mk_alt fail) sorted_alts      `thenDs` \ alts ->
 324                    returnDs (Case (Var var) wild_var ty (mk_default fail ++ alts))
 325
 326     mk_alt fail (con, args, MatchResult _ body_fn)
 327         = body_fn fail                          `thenDs` \ body ->
 328           newUniqueSupply                       `thenDs` \ us ->
 329           returnDs (mkReboxingAlt (uniqsFromSupply us) con args body)
 330
 331     mk_default fail | exhaustive_case = []
 332                     | otherwise       = [(DEFAULT, [], fail)]
 333
 334     un_mentioned_constructors
 335         = mkUniqSet data_cons `minusUniqSet` mkUniqSet [ con | (con, _, _) <- match_alts]
 336     exhaustive_case = isEmptyUniqSet un_mentioned_constructors
 337
 338         -- Stuff for parallel arrays
 339         --
 340         --  * the following is to desugar cases over fake constructors for
 341         --   parallel arrays, which are introduced by `tidy1' in the `PArrPat'
 342         --   case
 343         --
 344         -- Concerning `isPArrFakeAlts':
 345         --
 346         --  * it is *not* sufficient to just check the type of the type
 347         --   constructor, as we have to be careful not to confuse the real
 348         --   representation of parallel arrays with the fake constructors;
 349         --   moreover, a list of alternatives must not mix fake and real
 350         --   constructors (this is checked earlier on)
 351         --
 352         -- FIXME: We actually go through the whole list and make sure that
 353         --        either all or none of the constructors are fake parallel
 354         --        array constructors.  This is to spot equations that mix fake
 355         --        constructors with the real representation defined in
 356         --        `PrelPArr'.  It would be nicer to spot this situation
 357         --        earlier and raise a proper error message, but it can really
 358         --        only happen in `PrelPArr' anyway.
 359         --
 360     isPArrFakeAlts [(dcon, _, _)]      = isPArrFakeCon dcon
 361     isPArrFakeAlts ((dcon, _, _):alts) =
 362       case (isPArrFakeCon dcon, isPArrFakeAlts alts) of
 363         (True , True ) -> True
 364         (False, False) -> False
 365         _              ->
 366           panic "DsUtils: You may not mix `[:...:]' with `PArr' patterns"
 367     --
 368     mk_parrCase fail =
 369       dsLookupGlobalId lengthPName                      `thenDs` \lengthP  ->
 370       unboxAlt                                          `thenDs` \alt      ->
 371       returnDs (Case (len lengthP) (mkWildId intTy) ty [alt])
 372       where
 373         elemTy      = case splitTyConApp (idType var) of
 374                         (_, [elemTy]) -> elemTy
 375                         _               -> panic panicMsg
 376         panicMsg    = "DsUtils.mkCoAlgCaseMatchResult: not a parallel array?"
 377         len lengthP = mkApps (Var lengthP) [Type elemTy, Var var]
 378         --
 379         unboxAlt =
 380           newSysLocalDs intPrimTy                       `thenDs` \l        ->
 381           dsLookupGlobalId indexPName                   `thenDs` \indexP   ->
 382           mappM (mkAlt indexP) sorted_alts              `thenDs` \alts     ->
 383           returnDs (DataAlt intDataCon, [l], (Case (Var l) wild ty (dft : alts)))
 384           where
 385             wild = mkWildId intPrimTy
 386             dft  = (DEFAULT, [], fail)
 387         --
 388         -- each alternative matches one array length (corresponding to one
 389         -- fake array constructor), so the match is on a literal; each
 390         -- alternative's body is extended by a local binding for each
 391         -- constructor argument, which are bound to array elements starting
 392         -- with the first
 393         --
 394         mkAlt indexP (con, args, MatchResult _ bodyFun) =
 395           bodyFun fail                                  `thenDs` \body     ->
 396           returnDs (LitAlt lit, [], mkDsLets binds body)
 397           where
 398             lit   = MachInt $ toInteger (dataConSourceArity con)
 399             binds = [NonRec arg (indexExpr i) | (i, arg) <- zip [1..] args]
 400             --
 401             indexExpr i = mkApps (Var indexP) [Type elemTy, Var var, mkIntExpr i]
 402 \end{code}
 403
 404
 405 %************************************************************************
 406 %*                                                                      *
 407 \subsection{Desugarer's versions of some Core functions}
 408 %*                                                                      *
 409 %************************************************************************
 410
 411 \begin{code}
 412 mkErrorAppDs :: Id              -- The error function
 413              -> Type            -- Type to which it should be applied
 414              -> String          -- The error message string to pass
 415              -> DsM CoreExpr
 416
 417 mkErrorAppDs err_id ty msg
 418   = getSrcSpanDs                `thenDs` \ src_loc ->
 419     let
 420         full_msg = showSDoc (hcat [ppr src_loc, text "|", text msg])
 421         core_msg = Lit (mkStringLit full_msg)
 422         -- mkStringLit returns a result of type String#
 423     in
 424     returnDs (mkApps (Var err_id) [Type ty, core_msg])
 425 \end{code}
 426
 427
 428 *************************************************************
 429 %*                                                                      *
 430 \subsection{Making literals}
 431 %*                                                                      *
 432 %************************************************************************
 433
 434 \begin{code}
 435 mkCharExpr     :: Char       -> CoreExpr      -- Returns        C# c :: Int
 436 mkIntExpr      :: Integer    -> CoreExpr      -- Returns        I# i :: Int
 437 mkIntegerExpr  :: Integer    -> DsM CoreExpr  -- Result :: Integer
 438 mkStringExpr   :: String     -> DsM CoreExpr  -- Result :: String
 439 mkStringExprFS :: FastString -> DsM CoreExpr  -- Result :: String
 440
 441 mkIntExpr  i = mkConApp intDataCon  [mkIntLit i]
 442 mkCharExpr c = mkConApp charDataCon [mkLit (MachChar c)]
 443
 444 mkIntegerExpr i
 445   | inIntRange i        -- Small enough, so start from an Int
 446   = dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 447     returnDs (mkSmallIntegerLit integer_dc i)
 448
 449 -- Special case for integral literals with a large magnitude:
 450 -- They are transformed into an expression involving only smaller
 451 -- integral literals. This improves constant folding.
 452
 453   | otherwise           -- Big, so start from a string
 454   = dsLookupGlobalId plusIntegerName            `thenDs` \ plus_id ->
 455     dsLookupGlobalId timesIntegerName           `thenDs` \ times_id ->
 456     dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 457     let
 458         lit i = mkSmallIntegerLit integer_dc i
 459         plus a b  = Var plus_id  `App` a `App` b
 460         times a b = Var times_id `App` a `App` b
 461
 462         -- Transform i into (x1 + (x2 + (x3 + (...) * b) * b) * b) with abs xi <= b
 463         horner :: Integer -> Integer -> CoreExpr
 464         horner b i | abs q <= 1 = if r == 0 || r == i
 465                                   then lit i
 466                                   else lit r `plus` lit (i-r)
 467                    | r == 0     =               horner b q `times` lit b
 468                    | otherwise  = lit r `plus` (horner b q `times` lit b)
 469                    where
 470                      (q,r) = i `quotRem` b
 471
 472     in
 473     returnDs (horner tARGET_MAX_INT i)
 474
 475 mkSmallIntegerLit small_integer_data_con i = mkConApp small_integer_data_con [mkIntLit i]
 476
 477 mkStringExpr str = mkStringExprFS (mkFastString str)
 478
 479 mkStringExprFS str
 480   | nullFS str
 481   = returnDs (mkNilExpr charTy)
 482
 483   | lengthFS str == 1
 484   = let
 485         the_char = mkCharExpr (headFS str)
 486     in
 487     returnDs (mkConsExpr charTy the_char (mkNilExpr charTy))
 488
 489   | all safeChar chars
 490   = dsLookupGlobalId unpackCStringName  `thenDs` \ unpack_id ->
 491     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 492
 493   | otherwise
 494   = dsLookupGlobalId unpackCStringUtf8Name      `thenDs` \ unpack_id ->
 495     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 496
 497   where
 498     chars = unpackFS str
 499     safeChar c = ord c >= 1 && ord c <= 0x7F
 500 \end{code}
 501
 502
 503 %************************************************************************
 504 %*                                                                      *
 505 \subsection[mkSelectorBind]{Make a selector bind}
 506 %*                                                                      *
 507 %************************************************************************
 508
 509 This is used in various places to do with lazy patterns.
 510 For each binder $b$ in the pattern, we create a binding:
 511 \begin{verbatim}
 512     b = case v of pat' -> b'
 513 \end{verbatim}
 514 where @pat'@ is @pat@ with each binder @b@ cloned into @b'@.
 515
 516 ToDo: making these bindings should really depend on whether there's
 517 much work to be done per binding.  If the pattern is complex, it
 518 should be de-mangled once, into a tuple (and then selected from).
 519 Otherwise the demangling can be in-line in the bindings (as here).
 520
 521 Boring!  Boring!  One error message per binder.  The above ToDo is
 522 even more helpful.  Something very similar happens for pattern-bound
 523 expressions.
 524
 525 \begin{code}
 526 mkSelectorBinds :: LPat Id      -- The pattern
 527                 -> CoreExpr     -- Expression to which the pattern is bound
 528                 -> DsM [(Id,CoreExpr)]
 529
 530 mkSelectorBinds (L _ (VarPat v)) val_expr
 531   = returnDs [(v, val_expr)]
 532
 533 mkSelectorBinds pat val_expr
 534   | isSingleton binders || is_simple_lpat pat
 535   =     -- Given   p = e, where p binds x,y
 536         -- we are going to make
 537         --      v = p   (where v is fresh)
 538         --      x = case v of p -> x
 539         --      y = case v of p -> x
 540
 541         -- Make up 'v'
 542         -- NB: give it the type of *pattern* p, not the type of the *rhs* e.
 543         -- This does not matter after desugaring, but there's a subtle
 544         -- issue with implicit parameters. Consider
 545         --      (x,y) = ?i
 546         -- Then, ?i is given type {?i :: Int}, a PredType, which is opaque
 547         -- to the desugarer.  (Why opaque?  Because newtypes have to be.  Why
 548         -- does it get that type?  So that when we abstract over it we get the
 549         -- right top-level type  (?i::Int) => ...)
 550         --
 551         -- So to get the type of 'v', use the pattern not the rhs.  Often more
 552         -- efficient too.
 553     newSysLocalDs (hsLPatType pat)      `thenDs` \ val_var ->
 554
 555         -- For the error message we make one error-app, to avoid duplication.
 556         -- But we need it at different types... so we use coerce for that
 557     mkErrorAppDs iRREFUT_PAT_ERROR_ID
 558                  unitTy (showSDoc (ppr pat))    `thenDs` \ err_expr ->
 559     newSysLocalDs unitTy                        `thenDs` \ err_var ->
 560     mappM (mk_bind val_var err_var) binders     `thenDs` \ binds ->
 561     returnDs ( (val_var, val_expr) :
 562                (err_var, err_expr) :
 563                binds )
 564
 565
 566   | otherwise
 567   = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 568                  tuple_ty (showSDoc (ppr pat))                  `thenDs` \ error_expr ->
 569     matchSimply val_expr PatBindRhs pat local_tuple error_expr  `thenDs` \ tuple_expr ->
 570     newSysLocalDs tuple_ty                                      `thenDs` \ tuple_var ->
 571     let
 572         mk_tup_bind binder
 573           = (binder, mkTupleSelector binders binder tuple_var (Var tuple_var))
 574     in
 575     returnDs ( (tuple_var, tuple_expr) : map mk_tup_bind binders )
 576   where
 577     binders     = collectPatBinders pat
 578     local_tuple = mkTupleExpr binders
 579     tuple_ty    = exprType local_tuple
 580
 581     mk_bind scrut_var err_var bndr_var
 582     -- (mk_bind sv err_var) generates
 583     --          bv = case sv of { pat -> bv; other -> coerce (type-of-bv) err_var }
 584     -- Remember, pat binds bv
 585       = matchSimply (Var scrut_var) PatBindRhs pat
 586                     (Var bndr_var) error_expr                   `thenDs` \ rhs_expr ->
 587         returnDs (bndr_var, rhs_expr)
 588       where
 589         error_expr = mkCoerce co (Var err_var)
 590         co         = mkUnsafeCoercion (exprType (Var err_var)) (idType bndr_var)
 591
 592     is_simple_lpat p = is_simple_pat (unLoc p)
 593
 594     is_simple_pat (TuplePat ps Boxed _)        = all is_triv_lpat ps
 595     is_simple_pat (ConPatOut{ pat_args = ps }) = all is_triv_lpat (hsConArgs ps)
 596     is_simple_pat (VarPat _)                   = True
 597     is_simple_pat (ParPat p)                   = is_simple_lpat p
 598     is_simple_pat other                        = False
 599
 600     is_triv_lpat p = is_triv_pat (unLoc p)
 601
 602     is_triv_pat (VarPat v)  = True
 603     is_triv_pat (WildPat _) = True
 604     is_triv_pat (ParPat p)  = is_triv_lpat p
 605     is_triv_pat other       = False
 606 \end{code}
 607
 608
 609 %************************************************************************
 610 %*                                                                      *
 611                 Tuples
 612 %*                                                                      *
 613 %************************************************************************
 614
 615 @mkTupleExpr@ builds a tuple; the inverse to @mkTupleSelector@.
 616
 617 * If it has only one element, it is the identity function.
 618
 619 * If there are more elements than a big tuple can have, it nests
 620   the tuples.
 621
 622 Nesting policy.  Better a 2-tuple of 10-tuples (3 objects) than
 623 a 10-tuple of 2-tuples (11 objects).  So we want the leaves to be big.
 624
 625 \begin{code}
 626 mkTupleExpr :: [Id] -> CoreExpr
 627 mkTupleExpr ids = mkBigCoreTup (map Var ids)
 628
 629 -- corresponding type
 630 mkTupleType :: [Id] -> Type
 631 mkTupleType ids = mkBigTuple mkCoreTupTy (map idType ids)
 632
 633 mkBigCoreTup :: [CoreExpr] -> CoreExpr
 634 mkBigCoreTup = mkBigTuple mkCoreTup
 635
 636 mkBigTuple :: ([a] -> a) -> [a] -> a
 637 mkBigTuple small_tuple as = mk_big_tuple (chunkify as)
 638   where
 639         -- Each sub-list is short enough to fit in a tuple
 640     mk_big_tuple [as] = small_tuple as
 641     mk_big_tuple as_s = mk_big_tuple (chunkify (map small_tuple as_s))
 642
 643 chunkify :: [a] -> [[a]]
 644 -- The sub-lists of the result all have length <= mAX_TUPLE_SIZE
 645 -- But there may be more than mAX_TUPLE_SIZE sub-lists
 646 chunkify xs
 647   | n_xs <= mAX_TUPLE_SIZE = {- pprTrace "Small" (ppr n_xs) -} [xs]
 648   | otherwise              = {- pprTrace "Big"   (ppr n_xs) -} (split xs)
 649   where
 650     n_xs     = length xs
 651     split [] = []
 652     split xs = take mAX_TUPLE_SIZE xs : split (drop mAX_TUPLE_SIZE xs)
 653 \end{code}
 654
 655
 656 @mkTupleSelector@ builds a selector which scrutises the given
 657 expression and extracts the one name from the list given.
 658 If you want the no-shadowing rule to apply, the caller
 659 is responsible for making sure that none of these names
 660 are in scope.
 661
 662 If there is just one id in the ``tuple'', then the selector is
 663 just the identity.
 664
 665 If it's big, it does nesting
 666         mkTupleSelector [a,b,c,d] b v e
 667           = case e of v {
 668                 (p,q) -> case p of p {
 669                            (a,b) -> b }}
 670 We use 'tpl' vars for the p,q, since shadowing does not matter.
 671
 672 In fact, it's more convenient to generate it innermost first, getting
 673
 674         case (case e of v
 675                 (p,q) -> p) of p
 676           (a,b) -> b
 677
 678 \begin{code}
 679 mkTupleSelector :: [Id]         -- The tuple args
 680                 -> Id           -- The selected one
 681                 -> Id           -- A variable of the same type as the scrutinee
 682                 -> CoreExpr     -- Scrutinee
 683                 -> CoreExpr
 684
 685 mkTupleSelector vars the_var scrut_var scrut
 686   = mk_tup_sel (chunkify vars) the_var
 687   where
 688     mk_tup_sel [vars] the_var = mkCoreSel vars the_var scrut_var scrut
 689     mk_tup_sel vars_s the_var = mkCoreSel group the_var tpl_v $
 690                                 mk_tup_sel (chunkify tpl_vs) tpl_v
 691         where
 692           tpl_tys = [mkCoreTupTy (map idType gp) | gp <- vars_s]
 693           tpl_vs  = mkTemplateLocals tpl_tys
 694           [(tpl_v, group)] = [(tpl,gp) | (tpl,gp) <- zipEqual "mkTupleSelector" tpl_vs vars_s,
 695                                          the_var `elem` gp ]
 696 \end{code}
 697
 698 A generalization of @mkTupleSelector@, allowing the body
 699 of the case to be an arbitrary expression.
 700
 701 If the tuple is big, it is nested:
 702
 703         mkTupleCase uniqs [a,b,c,d] body v e
 704           = case e of v { (p,q) ->
 705             case p of p { (a,b) ->
 706             case q of q { (c,d) ->
 707             body }}}
 708
 709 To avoid shadowing, we use uniqs to invent new variables p,q.
 710
 711 ToDo: eliminate cases where none of the variables are needed.
 712
 713 \begin{code}
 714 mkTupleCase
 715         :: UniqSupply   -- for inventing names of intermediate variables
 716         -> [Id]         -- the tuple args
 717         -> CoreExpr     -- body of the case
 718         -> Id           -- a variable of the same type as the scrutinee
 719         -> CoreExpr     -- scrutinee
 720         -> CoreExpr
 721
 722 mkTupleCase uniqs vars body scrut_var scrut
 723   = mk_tuple_case uniqs (chunkify vars) body
 724   where
 725     mk_tuple_case us [vars] body
 726       = mkSmallTupleCase vars body scrut_var scrut
 727     mk_tuple_case us vars_s body
 728       = let
 729             (us', vars', body') = foldr one_tuple_case (us, [], body) vars_s
 730         in
 731         mk_tuple_case us' (chunkify vars') body'
 732     one_tuple_case chunk_vars (us, vs, body)
 733       = let
 734             (us1, us2) = splitUniqSupply us
 735             scrut_var = mkSysLocal FSLIT("ds") (uniqFromSupply us1)
 736                         (mkCoreTupTy (map idType chunk_vars))
 737             body' = mkSmallTupleCase chunk_vars body scrut_var (Var scrut_var)
 738         in (us2, scrut_var:vs, body')
 739 \end{code}
 740
 741 The same, but with a tuple small enough not to need nesting.
 742
 743 \begin{code}
 744 mkSmallTupleCase
 745         :: [Id]         -- the tuple args
 746         -> CoreExpr     -- body of the case
 747         -> Id           -- a variable of the same type as the scrutinee
 748         -> CoreExpr     -- scrutinee
 749         -> CoreExpr
 750
 751 mkSmallTupleCase [var] body _scrut_var scrut
 752   = bindNonRec var scrut body
 753 mkSmallTupleCase vars body scrut_var scrut
 754 -- One branch no refinement?
 755   = Case scrut scrut_var (exprType body) [(DataAlt (tupleCon Boxed (length vars)), vars, body)]
 756 \end{code}
 757
 758 %************************************************************************
 759 %*                                                                      *
 760 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 761 %*                                                                      *
 762 %************************************************************************
 763
 764 Call the constructor Ids when building explicit lists, so that they
 765 interact well with rules.
 766
 767 \begin{code}
 768 mkNilExpr :: Type -> CoreExpr
 769 mkNilExpr ty = mkConApp nilDataCon [Type ty]
 770
 771 mkConsExpr :: Type -> CoreExpr -> CoreExpr -> CoreExpr
 772 mkConsExpr ty hd tl = mkConApp consDataCon [Type ty, hd, tl]
 773
 774 mkListExpr :: Type -> [CoreExpr] -> CoreExpr
 775 mkListExpr ty xs = foldr (mkConsExpr ty) (mkNilExpr ty) xs
 776
 777
 778 -- The next three functions make tuple types, constructors and selectors,
 779 -- with the rule that a 1-tuple is represented by the thing itselg
 780 mkCoreTupTy :: [Type] -> Type
 781 mkCoreTupTy [ty] = ty
 782 mkCoreTupTy tys  = mkTupleTy Boxed (length tys) tys
 783
 784 mkCoreTup :: [CoreExpr] -> CoreExpr
 785 -- Builds exactly the specified tuple.
 786 -- No fancy business for big tuples
 787 mkCoreTup []  = Var unitDataConId
 788 mkCoreTup [c] = c
 789 mkCoreTup cs  = mkConApp (tupleCon Boxed (length cs))
 790                          (map (Type . exprType) cs ++ cs)
 791
 792 mkCoreSel :: [Id]       -- The tuple args
 793           -> Id         -- The selected one
 794           -> Id         -- A variable of the same type as the scrutinee
 795           -> CoreExpr   -- Scrutinee
 796           -> CoreExpr
 797 -- mkCoreSel [x,y,z] x v e
 798 -- ===>  case e of v { (x,y,z) -> x
 799 mkCoreSel [var] should_be_the_same_var scrut_var scrut
 800   = ASSERT(var == should_be_the_same_var)
 801     scrut
 802
 803 mkCoreSel vars the_var scrut_var scrut
 804   = ASSERT( notNull vars )
 805     Case scrut scrut_var (idType the_var)
 806          [(DataAlt (tupleCon Boxed (length vars)), vars, Var the_var)]
 807 \end{code}
 808
 809
 810 %************************************************************************
 811 %*                                                                      *
 812 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 813 %*                                                                      *
 814 %************************************************************************
 815
 816 Generally, we handle pattern matching failure like this: let-bind a
 817 fail-variable, and use that variable if the thing fails:
 818 \begin{verbatim}
 819         let fail.33 = error "Help"
 820         in
 821         case x of
 822                 p1 -> ...
 823                 p2 -> fail.33
 824                 p3 -> fail.33
 825                 p4 -> ...
 826 \end{verbatim}
 827 Then
 828 \begin{itemize}
 829 \item
 830 If the case can't fail, then there'll be no mention of @fail.33@, and the
 831 simplifier will later discard it.
 832
 833 \item
 834 If it can fail in only one way, then the simplifier will inline it.
 835
 836 \item
 837 Only if it is used more than once will the let-binding remain.
 838 \end{itemize}
 839
 840 There's a problem when the result of the case expression is of
 841 unboxed type.  Then the type of @fail.33@ is unboxed too, and
 842 there is every chance that someone will change the let into a case:
 843 \begin{verbatim}
 844         case error "Help" of
 845           fail.33 -> case ....
 846 \end{verbatim}
 847
 848 which is of course utterly wrong.  Rather than drop the condition that
 849 only boxed types can be let-bound, we just turn the fail into a function
 850 for the primitive case:
 851 \begin{verbatim}
 852         let fail.33 :: Void -> Int#
 853             fail.33 = \_ -> error "Help"
 854         in
 855         case x of
 856                 p1 -> ...
 857                 p2 -> fail.33 void
 858                 p3 -> fail.33 void
 859                 p4 -> ...
 860 \end{verbatim}
 861
 862 Now @fail.33@ is a function, so it can be let-bound.
 863
 864 \begin{code}
 865 mkFailurePair :: CoreExpr       -- Result type of the whole case expression
 866               -> DsM (CoreBind, -- Binds the newly-created fail variable
 867                                 -- to either the expression or \ _ -> expression
 868                       CoreExpr) -- Either the fail variable, or fail variable
 869                                 -- applied to unit tuple
 870 mkFailurePair expr
 871   | isUnLiftedType ty
 872   = newFailLocalDs (unitTy `mkFunTy` ty)        `thenDs` \ fail_fun_var ->
 873     newSysLocalDs unitTy                        `thenDs` \ fail_fun_arg ->
 874     returnDs (NonRec fail_fun_var (Lam fail_fun_arg expr),
 875               App (Var fail_fun_var) (Var unitDataConId))
 876
 877   | otherwise
 878   = newFailLocalDs ty           `thenDs` \ fail_var ->
 879     returnDs (NonRec fail_var expr, Var fail_var)
 880   where
 881     ty = exprType expr
 882 \end{code}
 883
 884 \begin{code}
 885 mkOptTickBox :: Maybe Int -> CoreExpr -> DsM CoreExpr
 886 mkOptTickBox Nothing e   = return e
 887 mkOptTickBox (Just ix) e = mkTickBox ix e
 888
 889 mkTickBox :: Int -> CoreExpr -> DsM CoreExpr
 890 mkTickBox ix e = do
 891        mod <- getModuleDs
 892        return $ Note (TickBox mod ix) e
 893
 894 mkBinaryTickBox :: Int -> Int -> CoreExpr -> DsM CoreExpr
 895 mkBinaryTickBox ixT ixF e = do
 896        mod <- getModuleDs
 897        return $ Note (BinaryTickBox mod ixT ixF) e
 898 \end{code}