compiler/deSugar/Match.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 The @match@ function
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 module Match ( match, matchEquations, matchWrapper, matchSimply, matchSinglePat ) where
  17
  18 #include "HsVersions.h"
  19
  20 import {-#SOURCE#-} DsExpr (dsLExpr)
  21
  22 import DynFlags
  23 import HsSyn
  24 import TcHsSyn
  25 import Check
  26 import CoreSyn
  27 import Literal
  28 import CoreUtils
  29 import MkCore
  30 import DsMonad
  31 import DsBinds
  32 import DsGRHSs
  33 import DsUtils
  34 import Id
  35 import DataCon
  36 import MatchCon
  37 import MatchLit
  38 import PrelInfo
  39 import Type
  40 import TysWiredIn
  41 import ListSetOps
  42 import SrcLoc
  43 import Maybes
  44 import Util
  45 import Name
  46 import FiniteMap
  47 import Outputable
  48 import FastString
  49 \end{code}
  50
  51 This function is a wrapper of @match@, it must be called from all the parts where
  52 it was called match, but only substitutes the firs call, ....
  53 if the associated flags are declared, warnings will be issued.
  54 It can not be called matchWrapper because this name already exists :-(
  55
  56 JJCQ 30-Nov-1997
  57
  58 \begin{code}
  59 matchCheck ::  DsMatchContext
  60             -> [Id]             -- Vars rep'ing the exprs we're matching with
  61             -> Type             -- Type of the case expression
  62             -> [EquationInfo]   -- Info about patterns, etc. (type synonym below)
  63             -> DsM MatchResult  -- Desugared result!
  64
  65 matchCheck ctx vars ty qs = do
  66     dflags <- getDOptsDs
  67     matchCheck_really dflags ctx vars ty qs
  68
  69 matchCheck_really :: DynFlags
  70                   -> DsMatchContext
  71                   -> [Id]
  72                   -> Type
  73                   -> [EquationInfo]
  74                   -> DsM MatchResult
  75 matchCheck_really dflags ctx vars ty qs
  76   | incomplete && shadow  = do
  77       dsShadowWarn ctx eqns_shadow
  78       dsIncompleteWarn ctx pats
  79       match vars ty qs
  80   | incomplete            = do
  81       dsIncompleteWarn ctx pats
  82       match vars ty qs
  83   | shadow                = do
  84       dsShadowWarn ctx eqns_shadow
  85       match vars ty qs
  86   | otherwise             =
  87       match vars ty qs
  88   where (pats, eqns_shadow) = check qs
  89         incomplete    = want_incomplete && (notNull pats)
  90         want_incomplete = case ctx of
  91                               DsMatchContext RecUpd _ ->
  92                                   dopt Opt_WarnIncompletePatternsRecUpd dflags
  93                               _ ->
  94                                   dopt Opt_WarnIncompletePatterns       dflags
  95         shadow        = dopt Opt_WarnOverlappingPatterns dflags
  96                         && not (null eqns_shadow)
  97 \end{code}
  98
  99 This variable shows the maximum number of lines of output generated for warnings.
 100 It will limit the number of patterns/equations displayed to@ maximum_output@.
 101
 102 (ToDo: add command-line option?)
 103
 104 \begin{code}
 105 maximum_output :: Int
 106 maximum_output = 4
 107 \end{code}
 108
 109 The next two functions create the warning message.
 110
 111 \begin{code}
 112 dsShadowWarn :: DsMatchContext -> [EquationInfo] -> DsM ()
 113 dsShadowWarn ctx@(DsMatchContext kind loc) qs
 114   = putSrcSpanDs loc (warnDs warn)
 115   where
 116     warn | qs `lengthExceeds` maximum_output
 117          = pp_context ctx (ptext (sLit "are overlapped"))
 118                       (\ f -> vcat (map (ppr_eqn f kind) (take maximum_output qs)) $$
 119                       ptext (sLit "..."))
 120          | otherwise
 121          = pp_context ctx (ptext (sLit "are overlapped"))
 122                       (\ f -> vcat $ map (ppr_eqn f kind) qs)
 123
 124
 125 dsIncompleteWarn :: DsMatchContext -> [ExhaustivePat] -> DsM ()
 126 dsIncompleteWarn ctx@(DsMatchContext kind loc) pats
 127   = putSrcSpanDs loc (warnDs warn)
 128         where
 129           warn = pp_context ctx (ptext (sLit "are non-exhaustive"))
 130                             (\_ -> hang (ptext (sLit "Patterns not matched:"))
 131                                    4 ((vcat $ map (ppr_incomplete_pats kind)
 132                                                   (take maximum_output pats))
 133                                       $$ dots))
 134
 135           dots | pats `lengthExceeds` maximum_output = ptext (sLit "...")
 136                | otherwise                           = empty
 137
 138 pp_context :: DsMatchContext -> SDoc -> ((SDoc -> SDoc) -> SDoc) -> SDoc
 139 pp_context (DsMatchContext kind _loc) msg rest_of_msg_fun
 140   = vcat [ptext (sLit "Pattern match(es)") <+> msg,
 141           sep [ptext (sLit "In") <+> ppr_match <> char ':', nest 4 (rest_of_msg_fun pref)]]
 142   where
 143     (ppr_match, pref)
 144         = case kind of
 145              FunRhs fun _ -> (pprMatchContext kind, \ pp -> ppr fun <+> pp)
 146              _            -> (pprMatchContext kind, \ pp -> pp)
 147
 148 ppr_pats :: Outputable a => [a] -> SDoc
 149 ppr_pats pats = sep (map ppr pats)
 150
 151 ppr_shadow_pats :: HsMatchContext Name -> [Pat Id] -> SDoc
 152 ppr_shadow_pats kind pats
 153   = sep [ppr_pats pats, matchSeparator kind, ptext (sLit "...")]
 154
 155 ppr_incomplete_pats :: HsMatchContext Name -> ExhaustivePat -> SDoc
 156 ppr_incomplete_pats _ (pats,[]) = ppr_pats pats
 157 ppr_incomplete_pats _ (pats,constraints) =
 158                          sep [ppr_pats pats, ptext (sLit "with"),
 159                               sep (map ppr_constraint constraints)]
 160
 161 ppr_constraint :: (Name,[HsLit]) -> SDoc
 162 ppr_constraint (var,pats) = sep [ppr var, ptext (sLit "`notElem`"), ppr pats]
 163
 164 ppr_eqn :: (SDoc -> SDoc) -> HsMatchContext Name -> EquationInfo -> SDoc
 165 ppr_eqn prefixF kind eqn = prefixF (ppr_shadow_pats kind (eqn_pats eqn))
 166 \end{code}
 167
 168
 169 %************************************************************************
 170 %*                                                                      *
 171                 The main matching function
 172 %*                                                                      *
 173 %************************************************************************
 174
 175 The function @match@ is basically the same as in the Wadler chapter,
 176 except it is monadised, to carry around the name supply, info about
 177 annotations, etc.
 178
 179 Notes on @match@'s arguments, assuming $m$ equations and $n$ patterns:
 180 \begin{enumerate}
 181 \item
 182 A list of $n$ variable names, those variables presumably bound to the
 183 $n$ expressions being matched against the $n$ patterns.  Using the
 184 list of $n$ expressions as the first argument showed no benefit and
 185 some inelegance.
 186
 187 \item
 188 The second argument, a list giving the ``equation info'' for each of
 189 the $m$ equations:
 190 \begin{itemize}
 191 \item
 192 the $n$ patterns for that equation, and
 193 \item
 194 a list of Core bindings [@(Id, CoreExpr)@ pairs] to be ``stuck on
 195 the front'' of the matching code, as in:
 196 \begin{verbatim}
 197 let <binds>
 198 in  <matching-code>
 199 \end{verbatim}
 200 \item
 201 and finally: (ToDo: fill in)
 202
 203 The right way to think about the ``after-match function'' is that it
 204 is an embryonic @CoreExpr@ with a ``hole'' at the end for the
 205 final ``else expression''.
 206 \end{itemize}
 207
 208 There is a type synonym, @EquationInfo@, defined in module @DsUtils@.
 209
 210 An experiment with re-ordering this information about equations (in
 211 particular, having the patterns available in column-major order)
 212 showed no benefit.
 213
 214 \item
 215 A default expression---what to evaluate if the overall pattern-match
 216 fails.  This expression will (almost?) always be
 217 a measly expression @Var@, unless we know it will only be used once
 218 (as we do in @glue_success_exprs@).
 219
 220 Leaving out this third argument to @match@ (and slamming in lots of
 221 @Var "fail"@s) is a positively {\em bad} idea, because it makes it
 222 impossible to share the default expressions.  (Also, it stands no
 223 chance of working in our post-upheaval world of @Locals@.)
 224 \end{enumerate}
 225
 226 Note: @match@ is often called via @matchWrapper@ (end of this module),
 227 a function that does much of the house-keeping that goes with a call
 228 to @match@.
 229
 230 It is also worth mentioning the {\em typical} way a block of equations
 231 is desugared with @match@.  At each stage, it is the first column of
 232 patterns that is examined.  The steps carried out are roughly:
 233 \begin{enumerate}
 234 \item
 235 Tidy the patterns in column~1 with @tidyEqnInfo@ (this may add
 236 bindings to the second component of the equation-info):
 237 \begin{itemize}
 238 \item
 239 Remove the `as' patterns from column~1.
 240 \item
 241 Make all constructor patterns in column~1 into @ConPats@, notably
 242 @ListPats@ and @TuplePats@.
 243 \item
 244 Handle any irrefutable (or ``twiddle'') @LazyPats@.
 245 \end{itemize}
 246 \item
 247 Now {\em unmix} the equations into {\em blocks} [w\/ local function
 248 @unmix_eqns@], in which the equations in a block all have variable
 249 patterns in column~1, or they all have constructor patterns in ...
 250 (see ``the mixture rule'' in SLPJ).
 251 \item
 252 Call @matchEqnBlock@ on each block of equations; it will do the
 253 appropriate thing for each kind of column-1 pattern, usually ending up
 254 in a recursive call to @match@.
 255 \end{enumerate}
 256
 257 We are a little more paranoid about the ``empty rule'' (SLPJ, p.~87)
 258 than the Wadler-chapter code for @match@ (p.~93, first @match@ clause).
 259 And gluing the ``success expressions'' together isn't quite so pretty.
 260
 261 This (more interesting) clause of @match@ uses @tidy_and_unmix_eqns@
 262 (a)~to get `as'- and `twiddle'-patterns out of the way (tidying), and
 263 (b)~to do ``the mixture rule'' (SLPJ, p.~88) [which really {\em
 264 un}mixes the equations], producing a list of equation-info
 265 blocks, each block having as its first column of patterns either all
 266 constructors, or all variables (or similar beasts), etc.
 267
 268 @match_unmixed_eqn_blks@ simply takes the place of the @foldr@ in the
 269 Wadler-chapter @match@ (p.~93, last clause), and @match_unmixed_blk@
 270 corresponds roughly to @matchVarCon@.
 271
 272 \begin{code}
 273 match :: [Id]             -- Variables rep\'ing the exprs we\'re matching with
 274       -> Type             -- Type of the case expression
 275       -> [EquationInfo]   -- Info about patterns, etc. (type synonym below)
 276       -> DsM MatchResult  -- Desugared result!
 277
 278 match [] ty eqns
 279   = ASSERT2( not (null eqns), ppr ty )
 280     return (foldr1 combineMatchResults match_results)
 281   where
 282     match_results = [ ASSERT( null (eqn_pats eqn) )
 283                       eqn_rhs eqn
 284                     | eqn <- eqns ]
 285
 286 match vars@(v:_) ty eqns
 287   = ASSERT( not (null eqns ) )
 288     do  {       -- Tidy the first pattern, generating
 289                 -- auxiliary bindings if necessary
 290           (aux_binds, tidy_eqns) <- mapAndUnzipM (tidyEqnInfo v) eqns
 291
 292                 -- Group the equations and match each group in turn
 293        ; let grouped = groupEquations tidy_eqns
 294
 295          -- print the view patterns that are commoned up to help debug
 296        ; ifOptM Opt_D_dump_view_pattern_commoning (debug grouped)
 297
 298         ; match_results <- mapM match_group grouped
 299         ; return (adjustMatchResult (foldr1 (.) aux_binds) $
 300                   foldr1 combineMatchResults match_results) }
 301   where
 302     dropGroup :: [(PatGroup,EquationInfo)] -> [EquationInfo]
 303     dropGroup = map snd
 304
 305     match_group :: [(PatGroup,EquationInfo)] -> DsM MatchResult
 306     match_group eqns@((group,_) : _)
 307         = case group of
 308             PgCon _    -> matchConFamily  vars ty (subGroup [(c,e) | (PgCon c, e) <- eqns])
 309             PgLit _    -> matchLiterals   vars ty (subGroup [(l,e) | (PgLit l, e) <- eqns])
 310
 311             PgAny      -> matchVariables  vars ty (dropGroup eqns)
 312             PgN _      -> matchNPats      vars ty (dropGroup eqns)
 313             PgNpK _    -> matchNPlusKPats vars ty (dropGroup eqns)
 314             PgBang     -> matchBangs      vars ty (dropGroup eqns)
 315             PgCo _     -> matchCoercion   vars ty (dropGroup eqns)
 316             PgView _ _ -> matchView       vars ty (dropGroup eqns)
 317
 318     -- FIXME: we should also warn about view patterns that should be
 319     -- commoned up but are not
 320
 321     -- print some stuff to see what's getting grouped
 322     -- use -dppr-debug to see the resolution of overloaded lits
 323     debug eqns =
 324         let gs = map (\group -> foldr (\ (p,_) -> \acc ->
 325                                            case p of PgView e _ -> e:acc
 326                                                      _ -> acc) [] group) eqns
 327             maybeWarn [] = return ()
 328             maybeWarn l = warnDs (vcat l)
 329         in
 330           maybeWarn $ (map (\g -> text "Putting these view expressions into the same case:" <+> (ppr g))
 331                        (filter (not . null) gs))
 332
 333 matchVariables :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 334 -- Real true variables, just like in matchVar, SLPJ p 94
 335 -- No binding to do: they'll all be wildcards by now (done in tidy)
 336 matchVariables (_:vars) ty eqns = match vars ty (shiftEqns eqns)
 337
 338 matchBangs :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 339 matchBangs (var:vars) ty eqns
 340   = do  { match_result <- match (var:vars) ty (map decomposeFirst_Bang eqns)
 341         ; return (mkEvalMatchResult var ty match_result) }
 342
 343 matchCoercion :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 344 -- Apply the coercion to the match variable and then match that
 345 matchCoercion (var:vars) ty (eqns@(eqn1:_))
 346   = do  { let CoPat co pat _ = firstPat eqn1
 347         ; var' <- newUniqueId (idName var) (hsPatType pat)
 348         ; match_result <- match (var':vars) ty (map decomposeFirst_Coercion eqns)
 349         ; rhs <- dsCoercion co (return (Var var))
 350         ; return (mkCoLetMatchResult (NonRec var' rhs) match_result) }
 351
 352 matchView :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 353 -- Apply the view function to the match variable and then match that
 354 matchView (var:vars) ty (eqns@(eqn1:_))
 355   = do  { -- we could pass in the expr from the PgView,
 356          -- but this needs to extract the pat anyway
 357          -- to figure out the type of the fresh variable
 358          let ViewPat viewExpr (L _ pat) _ = firstPat eqn1
 359          -- do the rest of the compilation
 360         ; var' <- newUniqueId (idName var) (hsPatType pat)
 361         ; match_result <- match (var':vars) ty (map decomposeFirst_View eqns)
 362          -- compile the view expressions
 363        ; viewExpr' <- dsLExpr viewExpr
 364         ; return (mkViewMatchResult var' viewExpr' var match_result) }
 365
 366 -- decompose the first pattern and leave the rest alone
 367 decomposeFirstPat :: (Pat Id -> Pat Id) -> EquationInfo -> EquationInfo
 368 decomposeFirstPat extractpat (eqn@(EqnInfo { eqn_pats = pat : pats }))
 369         = eqn { eqn_pats = extractpat pat : pats}
 370
 371 decomposeFirst_Coercion, decomposeFirst_Bang, decomposeFirst_View :: EquationInfo -> EquationInfo
 372
 373 decomposeFirst_Coercion = decomposeFirstPat (\ (CoPat _ pat _) -> pat)
 374 decomposeFirst_Bang     = decomposeFirstPat (\ (BangPat pat  ) -> unLoc pat)
 375 decomposeFirst_View     = decomposeFirstPat (\ (ViewPat _ pat _) -> unLoc pat)
 376
 377 \end{code}
 378
 379 %************************************************************************
 380 %*                                                                      *
 381                 Tidying patterns
 382 %*                                                                      *
 383 %************************************************************************
 384
 385 Tidy up the leftmost pattern in an @EquationInfo@, given the variable @v@
 386 which will be scrutinised.  This means:
 387 \begin{itemize}
 388 \item
 389 Replace variable patterns @x@ (@x /= v@) with the pattern @_@,
 390 together with the binding @x = v@.
 391 \item
 392 Replace the `as' pattern @x@@p@ with the pattern p and a binding @x = v@.
 393 \item
 394 Removing lazy (irrefutable) patterns (you don't want to know...).
 395 \item
 396 Converting explicit tuple-, list-, and parallel-array-pats into ordinary
 397 @ConPats@.
 398 \item
 399 Convert the literal pat "" to [].
 400 \end{itemize}
 401
 402 The result of this tidying is that the column of patterns will include
 403 {\em only}:
 404 \begin{description}
 405 \item[@WildPats@:]
 406 The @VarPat@ information isn't needed any more after this.
 407
 408 \item[@ConPats@:]
 409 @ListPats@, @TuplePats@, etc., are all converted into @ConPats@.
 410
 411 \item[@LitPats@ and @NPats@:]
 412 @LitPats@/@NPats@ of ``known friendly types'' (Int, Char,
 413 Float,  Double, at least) are converted to unboxed form; e.g.,
 414 \tr{(NPat (HsInt i) _ _)} is converted to:
 415 \begin{verbatim}
 416 (ConPat I# _ _ [LitPat (HsIntPrim i)])
 417 \end{verbatim}
 418 \end{description}
 419
 420 \begin{code}
 421 tidyEqnInfo :: Id -> EquationInfo
 422             -> DsM (DsWrapper, EquationInfo)
 423         -- DsM'd because of internal call to dsLHsBinds
 424         --      and mkSelectorBinds.
 425         -- "tidy1" does the interesting stuff, looking at
 426         -- one pattern and fiddling the list of bindings.
 427         --
 428         -- POST CONDITION: head pattern in the EqnInfo is
 429         --      WildPat
 430         --      ConPat
 431         --      NPat
 432         --      LitPat
 433         --      NPlusKPat
 434         -- but no other
 435
 436 tidyEqnInfo v eqn@(EqnInfo { eqn_pats = pat : pats }) = do
 437     (wrap, pat') <- tidy1 v pat
 438     return (wrap, eqn { eqn_pats = do pat' : pats })
 439
 440 tidy1 :: Id                     -- The Id being scrutinised
 441       -> Pat Id                 -- The pattern against which it is to be matched
 442       -> DsM (DsWrapper,        -- Extra bindings to do before the match
 443               Pat Id)           -- Equivalent pattern
 444
 445 -------------------------------------------------------
 446 --      (pat', mr') = tidy1 v pat mr
 447 -- tidies the *outer level only* of pat, giving pat'
 448 -- It eliminates many pattern forms (as-patterns, variable patterns,
 449 -- list patterns, etc) yielding one of:
 450 --      WildPat
 451 --      ConPatOut
 452 --      LitPat
 453 --      NPat
 454 --      NPlusKPat
 455
 456 tidy1 v (ParPat pat)      = tidy1 v (unLoc pat)
 457 tidy1 v (SigPatOut pat _) = tidy1 v (unLoc pat)
 458 tidy1 _ (WildPat ty)      = return (idDsWrapper, WildPat ty)
 459
 460         -- case v of { x -> mr[] }
 461         -- = case v of { _ -> let x=v in mr[] }
 462 tidy1 v (VarPat var)
 463   = return (wrapBind var v, WildPat (idType var))
 464
 465 tidy1 v (VarPatOut var binds)
 466   = do  { prs <- dsLHsBinds binds
 467         ; return (wrapBind var v . mkCoreLet (Rec prs),
 468                   WildPat (idType var)) }
 469
 470         -- case v of { x@p -> mr[] }
 471         -- = case v of { p -> let x=v in mr[] }
 472 tidy1 v (AsPat (L _ var) pat)
 473   = do  { (wrap, pat') <- tidy1 v (unLoc pat)
 474         ; return (wrapBind var v . wrap, pat') }
 475
 476 {- now, here we handle lazy patterns:
 477     tidy1 v ~p bs = (v, v1 = case v of p -> v1 :
 478                         v2 = case v of p -> v2 : ... : bs )
 479
 480     where the v_i's are the binders in the pattern.
 481
 482     ToDo: in "v_i = ... -> v_i", are the v_i's really the same thing?
 483
 484     The case expr for v_i is just: match [v] [(p, [], \ x -> Var v_i)] any_expr
 485 -}
 486
 487 tidy1 v (LazyPat pat)
 488   = do  { sel_prs <- mkSelectorBinds pat (Var v)
 489         ; let sel_binds =  [NonRec b rhs | (b,rhs) <- sel_prs]
 490         ; return (mkCoreLets sel_binds, WildPat (idType v)) }
 491
 492 tidy1 _ (ListPat pats ty)
 493   = return (idDsWrapper, unLoc list_ConPat)
 494   where
 495     list_ty     = mkListTy ty
 496     list_ConPat = foldr (\ x y -> mkPrefixConPat consDataCon [x, y] list_ty)
 497                         (mkNilPat list_ty)
 498                         pats
 499
 500 -- Introduce fake parallel array constructors to be able to handle parallel
 501 -- arrays with the existing machinery for constructor pattern
 502 tidy1 _ (PArrPat pats ty)
 503   = return (idDsWrapper, unLoc parrConPat)
 504   where
 505     arity      = length pats
 506     parrConPat = mkPrefixConPat (parrFakeCon arity) pats (mkPArrTy ty)
 507
 508 tidy1 _ (TuplePat pats boxity ty)
 509   = return (idDsWrapper, unLoc tuple_ConPat)
 510   where
 511     arity = length pats
 512     tuple_ConPat = mkPrefixConPat (tupleCon boxity arity) pats ty
 513
 514 -- LitPats: we *might* be able to replace these w/ a simpler form
 515 tidy1 _ (LitPat lit)
 516   = return (idDsWrapper, tidyLitPat lit)
 517
 518 -- NPats: we *might* be able to replace these w/ a simpler form
 519 tidy1 _ (NPat lit mb_neg eq)
 520   = return (idDsWrapper, tidyNPat lit mb_neg eq)
 521
 522 -- BangPatterns: Pattern matching is already strict in constructors,
 523 -- tuples etc, so the last case strips off the bang for thoses patterns.
 524 tidy1 v (BangPat (L _ (LazyPat p)))       = tidy1 v (BangPat p)
 525 tidy1 v (BangPat (L _ (ParPat p)))        = tidy1 v (BangPat p)
 526 tidy1 _ p@(BangPat (L _(VarPat _)))       = return (idDsWrapper, p)
 527 tidy1 _ p@(BangPat (L _(VarPatOut _ _)))  = return (idDsWrapper, p)
 528 tidy1 _ p@(BangPat (L _ (WildPat _)))     = return (idDsWrapper, p)
 529 tidy1 _ p@(BangPat (L _ (CoPat _ _ _)))   = return (idDsWrapper, p)
 530 tidy1 _ p@(BangPat (L _ (SigPatIn _ _)))  = return (idDsWrapper, p)
 531 tidy1 _ p@(BangPat (L _ (SigPatOut _ _))) = return (idDsWrapper, p)
 532 tidy1 v (BangPat (L _ (AsPat (L _ var) pat)))
 533   = do  { (wrap, pat') <- tidy1 v (BangPat pat)
 534         ; return (wrapBind var v . wrap, pat') }
 535 tidy1 v (BangPat (L _ p))                   = tidy1 v p
 536
 537 -- Everything else goes through unchanged...
 538
 539 tidy1 _ non_interesting_pat
 540   = return (idDsWrapper, non_interesting_pat)
 541 \end{code}
 542
 543 \noindent
 544 {\bf Previous @matchTwiddled@ stuff:}
 545
 546 Now we get to the only interesting part; note: there are choices for
 547 translation [from Simon's notes]; translation~1:
 548 \begin{verbatim}
 549 deTwiddle [s,t] e
 550 \end{verbatim}
 551 returns
 552 \begin{verbatim}
 553 [ w = e,
 554   s = case w of [s,t] -> s
 555   t = case w of [s,t] -> t
 556 ]
 557 \end{verbatim}
 558
 559 Here \tr{w} is a fresh variable, and the \tr{w}-binding prevents multiple
 560 evaluation of \tr{e}.  An alternative translation (No.~2):
 561 \begin{verbatim}
 562 [ w = case e of [s,t] -> (s,t)
 563   s = case w of (s,t) -> s
 564   t = case w of (s,t) -> t
 565 ]
 566 \end{verbatim}
 567
 568 %************************************************************************
 569 %*                                                                      *
 570 \subsubsection[improved-unmixing]{UNIMPLEMENTED idea for improved unmixing}
 571 %*                                                                      *
 572 %************************************************************************
 573
 574 We might be able to optimise unmixing when confronted by
 575 only-one-constructor-possible, of which tuples are the most notable
 576 examples.  Consider:
 577 \begin{verbatim}
 578 f (a,b,c) ... = ...
 579 f d ... (e:f) = ...
 580 f (g,h,i) ... = ...
 581 f j ...       = ...
 582 \end{verbatim}
 583 This definition would normally be unmixed into four equation blocks,
 584 one per equation.  But it could be unmixed into just one equation
 585 block, because if the one equation matches (on the first column),
 586 the others certainly will.
 587
 588 You have to be careful, though; the example
 589 \begin{verbatim}
 590 f j ...       = ...
 591 -------------------
 592 f (a,b,c) ... = ...
 593 f d ... (e:f) = ...
 594 f (g,h,i) ... = ...
 595 \end{verbatim}
 596 {\em must} be broken into two blocks at the line shown; otherwise, you
 597 are forcing unnecessary evaluation.  In any case, the top-left pattern
 598 always gives the cue.  You could then unmix blocks into groups of...
 599 \begin{description}
 600 \item[all variables:]
 601 As it is now.
 602 \item[constructors or variables (mixed):]
 603 Need to make sure the right names get bound for the variable patterns.
 604 \item[literals or variables (mixed):]
 605 Presumably just a variant on the constructor case (as it is now).
 606 \end{description}
 607
 608 %************************************************************************
 609 %*                                                                      *
 610 %*  matchWrapper: a convenient way to call @match@                      *
 611 %*                                                                      *
 612 %************************************************************************
 613 \subsection[matchWrapper]{@matchWrapper@: a convenient interface to @match@}
 614
 615 Calls to @match@ often involve similar (non-trivial) work; that work
 616 is collected here, in @matchWrapper@.  This function takes as
 617 arguments:
 618 \begin{itemize}
 619 \item
 620 Typchecked @Matches@ (of a function definition, or a case or lambda
 621 expression)---the main input;
 622 \item
 623 An error message to be inserted into any (runtime) pattern-matching
 624 failure messages.
 625 \end{itemize}
 626
 627 As results, @matchWrapper@ produces:
 628 \begin{itemize}
 629 \item
 630 A list of variables (@Locals@) that the caller must ``promise'' to
 631 bind to appropriate values; and
 632 \item
 633 a @CoreExpr@, the desugared output (main result).
 634 \end{itemize}
 635
 636 The main actions of @matchWrapper@ include:
 637 \begin{enumerate}
 638 \item
 639 Flatten the @[TypecheckedMatch]@ into a suitable list of
 640 @EquationInfo@s.
 641 \item
 642 Create as many new variables as there are patterns in a pattern-list
 643 (in any one of the @EquationInfo@s).
 644 \item
 645 Create a suitable ``if it fails'' expression---a call to @error@ using
 646 the error-string input; the {\em type} of this fail value can be found
 647 by examining one of the RHS expressions in one of the @EquationInfo@s.
 648 \item
 649 Call @match@ with all of this information!
 650 \end{enumerate}
 651
 652 \begin{code}
 653 matchWrapper :: HsMatchContext Name     -- For shadowing warning messages
 654              -> MatchGroup Id           -- Matches being desugared
 655              -> DsM ([Id], CoreExpr)    -- Results
 656 \end{code}
 657
 658  There is one small problem with the Lambda Patterns, when somebody
 659  writes something similar to:
 660 \begin{verbatim}
 661     (\ (x:xs) -> ...)
 662 \end{verbatim}
 663  he/she don't want a warning about incomplete patterns, that is done with
 664  the flag @opt_WarnSimplePatterns@.
 665  This problem also appears in the:
 666 \begin{itemize}
 667 \item @do@ patterns, but if the @do@ can fail
 668       it creates another equation if the match can fail
 669       (see @DsExpr.doDo@ function)
 670 \item @let@ patterns, are treated by @matchSimply@
 671    List Comprension Patterns, are treated by @matchSimply@ also
 672 \end{itemize}
 673
 674 We can't call @matchSimply@ with Lambda patterns,
 675 due to the fact that lambda patterns can have more than
 676 one pattern, and match simply only accepts one pattern.
 677
 678 JJQC 30-Nov-1997
 679
 680 \begin{code}
 681 matchWrapper ctxt (MatchGroup matches match_ty)
 682   = ASSERT( notNull matches )
 683     do  { eqns_info   <- mapM mk_eqn_info matches
 684         ; new_vars    <- selectMatchVars arg_pats
 685         ; result_expr <- matchEquations ctxt new_vars eqns_info rhs_ty
 686         ; return (new_vars, result_expr) }
 687   where
 688     arg_pats    = map unLoc (hsLMatchPats (head matches))
 689     n_pats      = length arg_pats
 690     (_, rhs_ty) = splitFunTysN n_pats match_ty
 691
 692     mk_eqn_info (L _ (Match pats _ grhss))
 693       = do { let upats = map unLoc pats
 694            ; match_result <- dsGRHSs ctxt upats grhss rhs_ty
 695            ; return (EqnInfo { eqn_pats = upats, eqn_rhs  = match_result}) }
 696
 697
 698 matchEquations  :: HsMatchContext Name
 699                 -> [Id] -> [EquationInfo] -> Type
 700                 -> DsM CoreExpr
 701 matchEquations ctxt vars eqns_info rhs_ty
 702   = do  { dflags <- getDOptsDs
 703         ; locn   <- getSrcSpanDs
 704         ; let   ds_ctxt      = DsMatchContext ctxt locn
 705                 error_doc = matchContextErrString ctxt
 706
 707         ; match_result <- match_fun dflags ds_ctxt vars rhs_ty eqns_info
 708
 709         ; fail_expr <- mkErrorAppDs pAT_ERROR_ID rhs_ty error_doc
 710         ; extractMatchResult match_result fail_expr }
 711   where
 712     match_fun dflags ds_ctxt
 713        = case ctxt of
 714            LambdaExpr | dopt Opt_WarnSimplePatterns dflags -> matchCheck ds_ctxt
 715                       | otherwise                          -> match
 716            _                                               -> matchCheck ds_ctxt
 717 \end{code}
 718
 719 %************************************************************************
 720 %*                                                                      *
 721 \subsection[matchSimply]{@matchSimply@: match a single expression against a single pattern}
 722 %*                                                                      *
 723 %************************************************************************
 724
 725 @mkSimpleMatch@ is a wrapper for @match@ which deals with the
 726 situation where we want to match a single expression against a single
 727 pattern. It returns an expression.
 728
 729 \begin{code}
 730 matchSimply :: CoreExpr                 -- Scrutinee
 731             -> HsMatchContext Name      -- Match kind
 732             -> LPat Id                  -- Pattern it should match
 733             -> CoreExpr                 -- Return this if it matches
 734             -> CoreExpr                 -- Return this if it doesn't
 735             -> DsM CoreExpr
 736
 737 matchSimply scrut hs_ctx pat result_expr fail_expr = do
 738     let
 739       match_result = cantFailMatchResult result_expr
 740       rhs_ty       = exprType fail_expr
 741         -- Use exprType of fail_expr, because won't refine in the case of failure!
 742     match_result' <- matchSinglePat scrut hs_ctx pat rhs_ty match_result
 743     extractMatchResult match_result' fail_expr
 744
 745
 746 matchSinglePat :: CoreExpr -> HsMatchContext Name -> LPat Id
 747                -> Type -> MatchResult -> DsM MatchResult
 748 matchSinglePat (Var var) hs_ctx (L _ pat) ty match_result = do
 749     dflags <- getDOptsDs
 750     locn <- getSrcSpanDs
 751     let
 752         match_fn dflags
 753            | dopt Opt_WarnSimplePatterns dflags = matchCheck ds_ctx
 754            | otherwise                          = match
 755            where
 756              ds_ctx = DsMatchContext hs_ctx locn
 757     match_fn dflags [var] ty [EqnInfo { eqn_pats = [pat], eqn_rhs  = match_result }]
 758
 759 matchSinglePat scrut hs_ctx pat ty match_result = do
 760     var <- selectSimpleMatchVarL pat
 761     match_result' <- matchSinglePat (Var var) hs_ctx pat ty match_result
 762     return (adjustMatchResult (bindNonRec var scrut) match_result')
 763 \end{code}
 764
 765
 766 %************************************************************************
 767 %*                                                                      *
 768                 Pattern classification
 769 %*                                                                      *
 770 %************************************************************************
 771
 772 \begin{code}
 773 data PatGroup
 774   = PgAny               -- Immediate match: variables, wildcards,
 775                         --                  lazy patterns
 776   | PgCon DataCon       -- Constructor patterns (incl list, tuple)
 777   | PgLit Literal       -- Literal patterns
 778   | PgN   Literal       -- Overloaded literals
 779   | PgNpK Literal       -- n+k patterns
 780   | PgBang              -- Bang patterns
 781   | PgCo Type           -- Coercion patterns; the type is the type
 782                         --      of the pattern *inside*
 783   | PgView (LHsExpr Id) -- view pattern (e -> p):
 784                         -- the LHsExpr is the expression e
 785            Type         -- the Type is the type of p (equivalently, the result type of e)
 786
 787 groupEquations :: [EquationInfo] -> [[(PatGroup, EquationInfo)]]
 788 -- If the result is of form [g1, g2, g3],
 789 -- (a) all the (pg,eq) pairs in g1 have the same pg
 790 -- (b) none of the gi are empty
 791 -- The ordering of equations is unchanged
 792 groupEquations eqns
 793   = runs same_gp [(patGroup (firstPat eqn), eqn) | eqn <- eqns]
 794   where
 795     same_gp :: (PatGroup,EquationInfo) -> (PatGroup,EquationInfo) -> Bool
 796     (pg1,_) `same_gp` (pg2,_) = pg1 `sameGroup` pg2
 797
 798 subGroup :: Ord a => [(a, EquationInfo)] -> [[EquationInfo]]
 799 -- Input is a particular group.  The result sub-groups the
 800 -- equations by with particular constructor, literal etc they match.
 801 -- Each sub-list in the result has the same PatGroup
 802 -- See Note [Take care with pattern order]
 803 subGroup group
 804     = map reverse $ eltsFM $ foldl accumulate emptyFM group
 805   where
 806     accumulate pg_map (pg, eqn)
 807       = case lookupFM pg_map pg of
 808           Just eqns -> addToFM pg_map pg (eqn:eqns)
 809           Nothing   -> addToFM pg_map pg [eqn]
 810
 811     -- pg_map :: FiniteMap a [EquationInfo]
 812     -- Equations seen so far in reverse order of appearance
 813 \end{code}
 814
 815 Note [Take care with pattern order]
 816 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 817 In the subGroup function we must be very careful about pattern re-ordering,
 818 Consider the patterns [ (True, Nothing), (False, x), (True, y) ]
 819 Then in bringing together the patterns for True, we must not
 820 swap the Nothing and y!
 821
 822
 823 \begin{code}
 824 sameGroup :: PatGroup -> PatGroup -> Bool
 825 -- Same group means that a single case expression
 826 -- or test will suffice to match both, *and* the order
 827 -- of testing within the group is insignificant.
 828 sameGroup PgAny      PgAny      = True
 829 sameGroup PgBang     PgBang     = True
 830 sameGroup (PgCon _)  (PgCon _)  = True          -- One case expression
 831 sameGroup (PgLit _)  (PgLit _)  = True          -- One case expression
 832 sameGroup (PgN l1)   (PgN l2)   = l1==l2        -- Order is significant
 833 sameGroup (PgNpK l1) (PgNpK l2) = l1==l2        -- See Note [Grouping overloaded literal patterns]
 834 sameGroup (PgCo t1)  (PgCo t2)  = t1 `coreEqType` t2
 835         -- CoPats are in the same goup only if the type of the
 836         -- enclosed pattern is the same. The patterns outside the CoPat
 837         -- always have the same type, so this boils down to saying that
 838         -- the two coercions are identical.
 839 sameGroup (PgView e1 t1) (PgView e2 t2) = viewLExprEq (e1,t1) (e2,t2)
 840        -- ViewPats are in the same gorup iff the expressions
 841        -- are "equal"---conservatively, we use syntactic equality
 842 sameGroup _          _          = False
 843
 844 -- An approximation of syntactic equality used for determining when view
 845 -- exprs are in the same group.
 846 -- This function can always safely return false;
 847 -- but doing so will result in the application of the view function being repeated.
 848 --
 849 -- Currently: compare applications of literals and variables
 850 --            and anything else that we can do without involving other
 851 --            HsSyn types in the recursion
 852 --
 853 -- NB we can't assume that the two view expressions have the same type.  Consider
 854 --   f (e1 -> True) = ...
 855 --   f (e2 -> "hi") = ...
 856 viewLExprEq :: (LHsExpr Id,Type) -> (LHsExpr Id,Type) -> Bool
 857 viewLExprEq (e1,_) (e2,_) =
 858     let
 859         -- short name for recursive call on unLoc
 860         lexp e e' = exp (unLoc e) (unLoc e')
 861
 862         eq_list :: (a->a->Bool) -> [a] -> [a] -> Bool
 863         eq_list _  []     []     = True
 864         eq_list _  []     (_:_)  = False
 865         eq_list _  (_:_)  []     = False
 866         eq_list eq (x:xs) (y:ys) = eq x y && eq_list eq xs ys
 867
 868         -- conservative, in that it demands that wrappers be
 869         -- syntactically identical and doesn't look under binders
 870         --
 871         -- coarser notions of equality are possible
 872         -- (e.g., reassociating compositions,
 873         --        equating different ways of writing a coercion)
 874         wrap WpHole WpHole = True
 875         wrap (WpCompose w1 w2) (WpCompose w1' w2') = wrap w1 w1' && wrap w2 w2'
 876         wrap (WpCast c)  (WpCast c')  = tcEqType c c'
 877         wrap (WpApp d)   (WpApp d')   = d == d'
 878         wrap (WpTyApp t) (WpTyApp t') = tcEqType t t'
 879         -- Enhancement: could implement equality for more wrappers
 880         --   if it seems useful (lams and lets)
 881         wrap _ _ = False
 882
 883         -- real comparison is on HsExpr's
 884         -- strip parens
 885         exp (HsPar (L _ e)) e'   = exp e e'
 886         exp e (HsPar (L _ e'))   = exp e e'
 887         -- because the expressions do not necessarily have the same type,
 888         -- we have to compare the wrappers
 889         exp (HsWrap h e) (HsWrap h' e') = wrap h h' && exp e e'
 890         exp (HsVar i) (HsVar i') =  i == i'
 891         -- the instance for IPName derives using the id, so this works if the
 892         -- above does
 893         exp (HsIPVar i) (HsIPVar i') = i == i'
 894         exp (HsOverLit l) (HsOverLit l') =
 895             -- Overloaded lits are equal if they have the same type
 896             -- and the data is the same.
 897             -- this is coarser than comparing the SyntaxExpr's in l and l',
 898             -- which resolve the overloading (e.g., fromInteger 1),
 899             -- because these expressions get written as a bunch of different variables
 900             -- (presumably to improve sharing)
 901             tcEqType (overLitType l) (overLitType l') && l == l'
 902         exp (HsApp e1 e2) (HsApp e1' e2') = lexp e1 e1' && lexp e2 e2'
 903         -- the fixities have been straightened out by now, so it's safe
 904         -- to ignore them?
 905         exp (OpApp l o _ ri) (OpApp l' o' _ ri') =
 906             lexp l l' && lexp o o' && lexp ri ri'
 907         exp (NegApp e n) (NegApp e' n') = lexp e e' && exp n n'
 908         exp (SectionL e1 e2) (SectionL e1' e2') =
 909             lexp e1 e1' && lexp e2 e2'
 910         exp (SectionR e1 e2) (SectionR e1' e2') =
 911             lexp e1 e1' && lexp e2 e2'
 912         exp (ExplicitTuple es1 _) (ExplicitTuple es2 _) =
 913             eq_list tup_arg es1 es2
 914         exp (HsIf e e1 e2) (HsIf e' e1' e2') =
 915             lexp e e' && lexp e1 e1' && lexp e2 e2'
 916
 917         -- Enhancement: could implement equality for more expressions
 918         --   if it seems useful
 919         -- But no need for HsLit, ExplicitList, ExplicitTuple,
 920         -- because they cannot be functions
 921         exp _ _  = False
 922
 923         tup_arg (Present e1) (Present e2) = lexp e1 e2
 924         tup_arg (Missing t1) (Missing t2) = tcEqType t1 t2
 925         tup_arg _ _ = False
 926     in
 927       lexp e1 e2
 928
 929 patGroup :: Pat Id -> PatGroup
 930 patGroup (WildPat {})                 = PgAny
 931 patGroup (BangPat {})                 = PgBang
 932 patGroup (ConPatOut { pat_con = dc }) = PgCon (unLoc dc)
 933 patGroup (LitPat lit)                 = PgLit (hsLitKey lit)
 934 patGroup (NPat olit mb_neg _)         = PgN   (hsOverLitKey olit (isJust mb_neg))
 935 patGroup (NPlusKPat _ olit _ _)       = PgNpK (hsOverLitKey olit False)
 936 patGroup (CoPat _ p _)                = PgCo  (hsPatType p)     -- Type of innelexp pattern
 937 patGroup (ViewPat expr p _)               = PgView expr (hsPatType (unLoc p))
 938 patGroup pat = pprPanic "patGroup" (ppr pat)
 939 \end{code}
 940
 941 Note [Grouping overloaded literal patterns]
 942 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 943 WATCH OUT!  Consider
 944
 945         f (n+1) = ...
 946         f (n+2) = ...
 947         f (n+1) = ...
 948
 949 We can't group the first and third together, because the second may match
 950 the same thing as the first.  Same goes for *overloaded* literal patterns
 951         f 1 True = ...
 952         f 2 False = ...
 953         f 1 False = ...
 954 If the first arg matches '1' but the second does not match 'True', we
 955 cannot jump to the third equation!  Because the same argument might
 956 match '2'!
 957 Hence we don't regard 1 and 2, or (n+1) and (n+2), as part of the same group.