compiler/deSugar/Match.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 The @match@ function
   7
   8 \begin{code}
   9 {-# OPTIONS -fno-warn-incomplete-patterns #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 module Match ( match, matchEquations, matchWrapper, matchSimply, matchSinglePat ) where
  17
  18 #include "HsVersions.h"
  19
  20 import {-#SOURCE#-} DsExpr (dsLExpr)
  21
  22 import DynFlags
  23 import HsSyn
  24 import TcHsSyn
  25 import Check
  26 import CoreSyn
  27 import Literal
  28 import CoreUtils
  29 import MkCore
  30 import DsMonad
  31 import DsBinds
  32 import DsGRHSs
  33 import DsUtils
  34 import Id
  35 import DataCon
  36 import MatchCon
  37 import MatchLit
  38 import PrelInfo
  39 import Type
  40 import TysWiredIn
  41 import ListSetOps
  42 import SrcLoc
  43 import Maybes
  44 import Util
  45 import Name
  46 import FiniteMap
  47 import Outputable
  48 import FastString
  49 \end{code}
  50
  51 This function is a wrapper of @match@, it must be called from all the parts where
  52 it was called match, but only substitutes the firs call, ....
  53 if the associated flags are declared, warnings will be issued.
  54 It can not be called matchWrapper because this name already exists :-(
  55
  56 JJCQ 30-Nov-1997
  57
  58 \begin{code}
  59 matchCheck ::  DsMatchContext
  60             -> [Id]             -- Vars rep'ing the exprs we're matching with
  61             -> Type             -- Type of the case expression
  62             -> [EquationInfo]   -- Info about patterns, etc. (type synonym below)
  63             -> DsM MatchResult  -- Desugared result!
  64
  65 matchCheck ctx vars ty qs = do
  66     dflags <- getDOptsDs
  67     matchCheck_really dflags ctx vars ty qs
  68
  69 matchCheck_really :: DynFlags
  70                   -> DsMatchContext
  71                   -> [Id]
  72                   -> Type
  73                   -> [EquationInfo]
  74                   -> DsM MatchResult
  75 matchCheck_really dflags ctx vars ty qs
  76   | incomplete && shadow  = do
  77       dsShadowWarn ctx eqns_shadow
  78       dsIncompleteWarn ctx pats
  79       match vars ty qs
  80   | incomplete            = do
  81       dsIncompleteWarn ctx pats
  82       match vars ty qs
  83   | shadow                = do
  84       dsShadowWarn ctx eqns_shadow
  85       match vars ty qs
  86   | otherwise             =
  87       match vars ty qs
  88   where (pats, eqns_shadow) = check qs
  89         incomplete    = want_incomplete && (notNull pats)
  90         want_incomplete = case ctx of
  91                               DsMatchContext RecUpd _ ->
  92                                   dopt Opt_WarnIncompletePatternsRecUpd dflags
  93                               _ ->
  94                                   dopt Opt_WarnIncompletePatterns       dflags
  95         shadow        = dopt Opt_WarnOverlappingPatterns dflags
  96                         && not (null eqns_shadow)
  97 \end{code}
  98
  99 This variable shows the maximum number of lines of output generated for warnings.
 100 It will limit the number of patterns/equations displayed to@ maximum_output@.
 101
 102 (ToDo: add command-line option?)
 103
 104 \begin{code}
 105 maximum_output :: Int
 106 maximum_output = 4
 107 \end{code}
 108
 109 The next two functions create the warning message.
 110
 111 \begin{code}
 112 dsShadowWarn :: DsMatchContext -> [EquationInfo] -> DsM ()
 113 dsShadowWarn ctx@(DsMatchContext kind loc) qs
 114   = putSrcSpanDs loc (warnDs warn)
 115   where
 116     warn | qs `lengthExceeds` maximum_output
 117          = pp_context ctx (ptext (sLit "are overlapped"))
 118                       (\ f -> vcat (map (ppr_eqn f kind) (take maximum_output qs)) $$
 119                       ptext (sLit "..."))
 120          | otherwise
 121          = pp_context ctx (ptext (sLit "are overlapped"))
 122                       (\ f -> vcat $ map (ppr_eqn f kind) qs)
 123
 124
 125 dsIncompleteWarn :: DsMatchContext -> [ExhaustivePat] -> DsM ()
 126 dsIncompleteWarn ctx@(DsMatchContext kind loc) pats
 127   = putSrcSpanDs loc (warnDs warn)
 128         where
 129           warn = pp_context ctx (ptext (sLit "are non-exhaustive"))
 130                             (\_ -> hang (ptext (sLit "Patterns not matched:"))
 131                                    4 ((vcat $ map (ppr_incomplete_pats kind)
 132                                                   (take maximum_output pats))
 133                                       $$ dots))
 134
 135           dots | pats `lengthExceeds` maximum_output = ptext (sLit "...")
 136                | otherwise                           = empty
 137
 138 pp_context :: DsMatchContext -> SDoc -> ((SDoc -> SDoc) -> SDoc) -> SDoc
 139 pp_context (DsMatchContext kind _loc) msg rest_of_msg_fun
 140   = vcat [ptext (sLit "Pattern match(es)") <+> msg,
 141           sep [ptext (sLit "In") <+> ppr_match <> char ':', nest 4 (rest_of_msg_fun pref)]]
 142   where
 143     (ppr_match, pref)
 144         = case kind of
 145              FunRhs fun _ -> (pprMatchContext kind, \ pp -> ppr fun <+> pp)
 146              _            -> (pprMatchContext kind, \ pp -> pp)
 147
 148 ppr_pats :: Outputable a => [a] -> SDoc
 149 ppr_pats pats = sep (map ppr pats)
 150
 151 ppr_shadow_pats :: HsMatchContext Name -> [Pat Id] -> SDoc
 152 ppr_shadow_pats kind pats
 153   = sep [ppr_pats pats, matchSeparator kind, ptext (sLit "...")]
 154
 155 ppr_incomplete_pats :: HsMatchContext Name -> ExhaustivePat -> SDoc
 156 ppr_incomplete_pats _ (pats,[]) = ppr_pats pats
 157 ppr_incomplete_pats _ (pats,constraints) =
 158                          sep [ppr_pats pats, ptext (sLit "with"),
 159                               sep (map ppr_constraint constraints)]
 160
 161 ppr_constraint :: (Name,[HsLit]) -> SDoc
 162 ppr_constraint (var,pats) = sep [ppr var, ptext (sLit "`notElem`"), ppr pats]
 163
 164 ppr_eqn :: (SDoc -> SDoc) -> HsMatchContext Name -> EquationInfo -> SDoc
 165 ppr_eqn prefixF kind eqn = prefixF (ppr_shadow_pats kind (eqn_pats eqn))
 166 \end{code}
 167
 168
 169 %************************************************************************
 170 %*                                                                      *
 171                 The main matching function
 172 %*                                                                      *
 173 %************************************************************************
 174
 175 The function @match@ is basically the same as in the Wadler chapter,
 176 except it is monadised, to carry around the name supply, info about
 177 annotations, etc.
 178
 179 Notes on @match@'s arguments, assuming $m$ equations and $n$ patterns:
 180 \begin{enumerate}
 181 \item
 182 A list of $n$ variable names, those variables presumably bound to the
 183 $n$ expressions being matched against the $n$ patterns.  Using the
 184 list of $n$ expressions as the first argument showed no benefit and
 185 some inelegance.
 186
 187 \item
 188 The second argument, a list giving the ``equation info'' for each of
 189 the $m$ equations:
 190 \begin{itemize}
 191 \item
 192 the $n$ patterns for that equation, and
 193 \item
 194 a list of Core bindings [@(Id, CoreExpr)@ pairs] to be ``stuck on
 195 the front'' of the matching code, as in:
 196 \begin{verbatim}
 197 let <binds>
 198 in  <matching-code>
 199 \end{verbatim}
 200 \item
 201 and finally: (ToDo: fill in)
 202
 203 The right way to think about the ``after-match function'' is that it
 204 is an embryonic @CoreExpr@ with a ``hole'' at the end for the
 205 final ``else expression''.
 206 \end{itemize}
 207
 208 There is a type synonym, @EquationInfo@, defined in module @DsUtils@.
 209
 210 An experiment with re-ordering this information about equations (in
 211 particular, having the patterns available in column-major order)
 212 showed no benefit.
 213
 214 \item
 215 A default expression---what to evaluate if the overall pattern-match
 216 fails.  This expression will (almost?) always be
 217 a measly expression @Var@, unless we know it will only be used once
 218 (as we do in @glue_success_exprs@).
 219
 220 Leaving out this third argument to @match@ (and slamming in lots of
 221 @Var "fail"@s) is a positively {\em bad} idea, because it makes it
 222 impossible to share the default expressions.  (Also, it stands no
 223 chance of working in our post-upheaval world of @Locals@.)
 224 \end{enumerate}
 225
 226 Note: @match@ is often called via @matchWrapper@ (end of this module),
 227 a function that does much of the house-keeping that goes with a call
 228 to @match@.
 229
 230 It is also worth mentioning the {\em typical} way a block of equations
 231 is desugared with @match@.  At each stage, it is the first column of
 232 patterns that is examined.  The steps carried out are roughly:
 233 \begin{enumerate}
 234 \item
 235 Tidy the patterns in column~1 with @tidyEqnInfo@ (this may add
 236 bindings to the second component of the equation-info):
 237 \begin{itemize}
 238 \item
 239 Remove the `as' patterns from column~1.
 240 \item
 241 Make all constructor patterns in column~1 into @ConPats@, notably
 242 @ListPats@ and @TuplePats@.
 243 \item
 244 Handle any irrefutable (or ``twiddle'') @LazyPats@.
 245 \end{itemize}
 246 \item
 247 Now {\em unmix} the equations into {\em blocks} [w\/ local function
 248 @unmix_eqns@], in which the equations in a block all have variable
 249 patterns in column~1, or they all have constructor patterns in ...
 250 (see ``the mixture rule'' in SLPJ).
 251 \item
 252 Call @matchEqnBlock@ on each block of equations; it will do the
 253 appropriate thing for each kind of column-1 pattern, usually ending up
 254 in a recursive call to @match@.
 255 \end{enumerate}
 256
 257 We are a little more paranoid about the ``empty rule'' (SLPJ, p.~87)
 258 than the Wadler-chapter code for @match@ (p.~93, first @match@ clause).
 259 And gluing the ``success expressions'' together isn't quite so pretty.
 260
 261 This (more interesting) clause of @match@ uses @tidy_and_unmix_eqns@
 262 (a)~to get `as'- and `twiddle'-patterns out of the way (tidying), and
 263 (b)~to do ``the mixture rule'' (SLPJ, p.~88) [which really {\em
 264 un}mixes the equations], producing a list of equation-info
 265 blocks, each block having as its first column of patterns either all
 266 constructors, or all variables (or similar beasts), etc.
 267
 268 @match_unmixed_eqn_blks@ simply takes the place of the @foldr@ in the
 269 Wadler-chapter @match@ (p.~93, last clause), and @match_unmixed_blk@
 270 corresponds roughly to @matchVarCon@.
 271
 272 \begin{code}
 273 match :: [Id]             -- Variables rep\'ing the exprs we\'re matching with
 274       -> Type             -- Type of the case expression
 275       -> [EquationInfo]   -- Info about patterns, etc. (type synonym below)
 276       -> DsM MatchResult  -- Desugared result!
 277
 278 match [] ty eqns
 279   = ASSERT2( not (null eqns), ppr ty )
 280     return (foldr1 combineMatchResults match_results)
 281   where
 282     match_results = [ ASSERT( null (eqn_pats eqn) )
 283                       eqn_rhs eqn
 284                     | eqn <- eqns ]
 285
 286 match vars@(v:_) ty eqns
 287   = ASSERT( not (null eqns ) )
 288     do  {       -- Tidy the first pattern, generating
 289                 -- auxiliary bindings if necessary
 290           (aux_binds, tidy_eqns) <- mapAndUnzipM (tidyEqnInfo v) eqns
 291
 292                 -- Group the equations and match each group in turn
 293        ; let grouped = groupEquations tidy_eqns
 294
 295          -- print the view patterns that are commoned up to help debug
 296        ; ifOptM Opt_D_dump_view_pattern_commoning (debug grouped)
 297
 298         ; match_results <- mapM match_group grouped
 299         ; return (adjustMatchResult (foldr1 (.) aux_binds) $
 300                   foldr1 combineMatchResults match_results) }
 301   where
 302     dropGroup :: [(PatGroup,EquationInfo)] -> [EquationInfo]
 303     dropGroup = map snd
 304
 305     match_group :: [(PatGroup,EquationInfo)] -> DsM MatchResult
 306     match_group eqns@((group,_) : _)
 307         = case group of
 308             PgCon _    -> matchConFamily  vars ty (subGroup [(c,e) | (PgCon c, e) <- eqns])
 309             PgLit _    -> matchLiterals   vars ty (subGroup [(l,e) | (PgLit l, e) <- eqns])
 310
 311             PgAny      -> matchVariables  vars ty (dropGroup eqns)
 312             PgN _      -> matchNPats      vars ty (dropGroup eqns)
 313             PgNpK _    -> matchNPlusKPats vars ty (dropGroup eqns)
 314             PgBang     -> matchBangs      vars ty (dropGroup eqns)
 315             PgCo _     -> matchCoercion   vars ty (dropGroup eqns)
 316             PgView _ _ -> matchView       vars ty (dropGroup eqns)
 317
 318     -- FIXME: we should also warn about view patterns that should be
 319     -- commoned up but are not
 320
 321     -- print some stuff to see what's getting grouped
 322     -- use -dppr-debug to see the resolution of overloaded lits
 323     debug eqns =
 324         let gs = map (\group -> foldr (\ (p,_) -> \acc ->
 325                                            case p of PgView e _ -> e:acc
 326                                                      _ -> acc) [] group) eqns
 327             maybeWarn [] = return ()
 328             maybeWarn l = warnDs (vcat l)
 329         in
 330           maybeWarn $ (map (\g -> text "Putting these view expressions into the same case:" <+> (ppr g))
 331                        (filter (not . null) gs))
 332
 333 matchVariables :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 334 -- Real true variables, just like in matchVar, SLPJ p 94
 335 -- No binding to do: they'll all be wildcards by now (done in tidy)
 336 matchVariables (_:vars) ty eqns = match vars ty (shiftEqns eqns)
 337
 338 matchBangs :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 339 matchBangs (var:vars) ty eqns
 340   = do  { match_result <- match (var:vars) ty (map decomposeFirst_Bang eqns)
 341         ; return (mkEvalMatchResult var ty match_result) }
 342
 343 matchCoercion :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 344 -- Apply the coercion to the match variable and then match that
 345 matchCoercion (var:vars) ty (eqns@(eqn1:_))
 346   = do  { let CoPat co pat _ = firstPat eqn1
 347         ; var' <- newUniqueId (idName var) (hsPatType pat)
 348         ; match_result <- match (var':vars) ty (map decomposeFirst_Coercion eqns)
 349         ; rhs <- dsCoercion co (return (Var var))
 350         ; return (mkCoLetMatchResult (NonRec var' rhs) match_result) }
 351
 352 matchView :: [Id] -> Type -> [EquationInfo] -> DsM MatchResult
 353 -- Apply the view function to the match variable and then match that
 354 matchView (var:vars) ty (eqns@(eqn1:_))
 355   = do  { -- we could pass in the expr from the PgView,
 356          -- but this needs to extract the pat anyway
 357          -- to figure out the type of the fresh variable
 358          let ViewPat viewExpr (L _ pat) _ = firstPat eqn1
 359          -- do the rest of the compilation
 360         ; var' <- newUniqueId (idName var) (hsPatType pat)
 361         ; match_result <- match (var':vars) ty (map decomposeFirst_View eqns)
 362          -- compile the view expressions
 363        ; viewExpr' <- dsLExpr viewExpr
 364         ; return (mkViewMatchResult var' viewExpr' var match_result) }
 365
 366 -- decompose the first pattern and leave the rest alone
 367 decomposeFirstPat :: (Pat Id -> Pat Id) -> EquationInfo -> EquationInfo
 368 decomposeFirstPat extractpat (eqn@(EqnInfo { eqn_pats = pat : pats }))
 369         = eqn { eqn_pats = extractpat pat : pats}
 370
 371 decomposeFirst_Coercion, decomposeFirst_Bang, decomposeFirst_View :: EquationInfo -> EquationInfo
 372
 373 decomposeFirst_Coercion = decomposeFirstPat (\ (CoPat _ pat _) -> pat)
 374 decomposeFirst_Bang     = decomposeFirstPat (\ (BangPat pat  ) -> unLoc pat)
 375 decomposeFirst_View     = decomposeFirstPat (\ (ViewPat _ pat _) -> unLoc pat)
 376
 377 \end{code}
 378
 379 %************************************************************************
 380 %*                                                                      *
 381                 Tidying patterns
 382 %*                                                                      *
 383 %************************************************************************
 384
 385 Tidy up the leftmost pattern in an @EquationInfo@, given the variable @v@
 386 which will be scrutinised.  This means:
 387 \begin{itemize}
 388 \item
 389 Replace variable patterns @x@ (@x /= v@) with the pattern @_@,
 390 together with the binding @x = v@.
 391 \item
 392 Replace the `as' pattern @x@@p@ with the pattern p and a binding @x = v@.
 393 \item
 394 Removing lazy (irrefutable) patterns (you don't want to know...).
 395 \item
 396 Converting explicit tuple-, list-, and parallel-array-pats into ordinary
 397 @ConPats@.
 398 \item
 399 Convert the literal pat "" to [].
 400 \end{itemize}
 401
 402 The result of this tidying is that the column of patterns will include
 403 {\em only}:
 404 \begin{description}
 405 \item[@WildPats@:]
 406 The @VarPat@ information isn't needed any more after this.
 407
 408 \item[@ConPats@:]
 409 @ListPats@, @TuplePats@, etc., are all converted into @ConPats@.
 410
 411 \item[@LitPats@ and @NPats@:]
 412 @LitPats@/@NPats@ of ``known friendly types'' (Int, Char,
 413 Float,  Double, at least) are converted to unboxed form; e.g.,
 414 \tr{(NPat (HsInt i) _ _)} is converted to:
 415 \begin{verbatim}
 416 (ConPat I# _ _ [LitPat (HsIntPrim i)])
 417 \end{verbatim}
 418 \end{description}
 419
 420 \begin{code}
 421 tidyEqnInfo :: Id -> EquationInfo
 422             -> DsM (DsWrapper, EquationInfo)
 423         -- DsM'd because of internal call to dsLHsBinds
 424         --      and mkSelectorBinds.
 425         -- "tidy1" does the interesting stuff, looking at
 426         -- one pattern and fiddling the list of bindings.
 427         --
 428         -- POST CONDITION: head pattern in the EqnInfo is
 429         --      WildPat
 430         --      ConPat
 431         --      NPat
 432         --      LitPat
 433         --      NPlusKPat
 434         -- but no other
 435
 436 tidyEqnInfo v eqn@(EqnInfo { eqn_pats = pat : pats }) = do
 437     (wrap, pat') <- tidy1 v pat
 438     return (wrap, eqn { eqn_pats = do pat' : pats })
 439
 440 tidy1 :: Id                     -- The Id being scrutinised
 441       -> Pat Id                 -- The pattern against which it is to be matched
 442       -> DsM (DsWrapper,        -- Extra bindings to do before the match
 443               Pat Id)           -- Equivalent pattern
 444
 445 -------------------------------------------------------
 446 --      (pat', mr') = tidy1 v pat mr
 447 -- tidies the *outer level only* of pat, giving pat'
 448 -- It eliminates many pattern forms (as-patterns, variable patterns,
 449 -- list patterns, etc) yielding one of:
 450 --      WildPat
 451 --      ConPatOut
 452 --      LitPat
 453 --      NPat
 454 --      NPlusKPat
 455
 456 tidy1 v (ParPat pat)      = tidy1 v (unLoc pat)
 457 tidy1 v (SigPatOut pat _) = tidy1 v (unLoc pat)
 458 tidy1 _ (WildPat ty)      = return (idDsWrapper, WildPat ty)
 459
 460         -- case v of { x -> mr[] }
 461         -- = case v of { _ -> let x=v in mr[] }
 462 tidy1 v (VarPat var)
 463   = return (wrapBind var v, WildPat (idType var))
 464
 465 tidy1 v (VarPatOut var binds)
 466   = do  { prs <- dsLHsBinds binds
 467         ; return (wrapBind var v . mkCoreLet (Rec prs),
 468                   WildPat (idType var)) }
 469
 470         -- case v of { x@p -> mr[] }
 471         -- = case v of { p -> let x=v in mr[] }
 472 tidy1 v (AsPat (L _ var) pat)
 473   = do  { (wrap, pat') <- tidy1 v (unLoc pat)
 474         ; return (wrapBind var v . wrap, pat') }
 475
 476 {- now, here we handle lazy patterns:
 477     tidy1 v ~p bs = (v, v1 = case v of p -> v1 :
 478                         v2 = case v of p -> v2 : ... : bs )
 479
 480     where the v_i's are the binders in the pattern.
 481
 482     ToDo: in "v_i = ... -> v_i", are the v_i's really the same thing?
 483
 484     The case expr for v_i is just: match [v] [(p, [], \ x -> Var v_i)] any_expr
 485 -}
 486
 487 tidy1 v (LazyPat pat)
 488   = do  { sel_prs <- mkSelectorBinds pat (Var v)
 489         ; let sel_binds =  [NonRec b rhs | (b,rhs) <- sel_prs]
 490         ; return (mkCoreLets sel_binds, WildPat (idType v)) }
 491
 492 tidy1 _ (ListPat pats ty)
 493   = return (idDsWrapper, unLoc list_ConPat)
 494   where
 495     list_ty     = mkListTy ty
 496     list_ConPat = foldr (\ x y -> mkPrefixConPat consDataCon [x, y] list_ty)
 497                         (mkNilPat list_ty)
 498                         pats
 499
 500 -- Introduce fake parallel array constructors to be able to handle parallel
 501 -- arrays with the existing machinery for constructor pattern
 502 tidy1 _ (PArrPat pats ty)
 503   = return (idDsWrapper, unLoc parrConPat)
 504   where
 505     arity      = length pats
 506     parrConPat = mkPrefixConPat (parrFakeCon arity) pats (mkPArrTy ty)
 507
 508 tidy1 _ (TuplePat pats boxity ty)
 509   = return (idDsWrapper, unLoc tuple_ConPat)
 510   where
 511     arity = length pats
 512     tuple_ConPat = mkPrefixConPat (tupleCon boxity arity) pats ty
 513
 514 -- LitPats: we *might* be able to replace these w/ a simpler form
 515 tidy1 _ (LitPat lit)
 516   = return (idDsWrapper, tidyLitPat lit)
 517
 518 -- NPats: we *might* be able to replace these w/ a simpler form
 519 tidy1 _ (NPat lit mb_neg eq)
 520   = return (idDsWrapper, tidyNPat lit mb_neg eq)
 521
 522 -- Everything else goes through unchanged...
 523
 524 tidy1 _ non_interesting_pat
 525   = return (idDsWrapper, non_interesting_pat)
 526 \end{code}
 527
 528 \noindent
 529 {\bf Previous @matchTwiddled@ stuff:}
 530
 531 Now we get to the only interesting part; note: there are choices for
 532 translation [from Simon's notes]; translation~1:
 533 \begin{verbatim}
 534 deTwiddle [s,t] e
 535 \end{verbatim}
 536 returns
 537 \begin{verbatim}
 538 [ w = e,
 539   s = case w of [s,t] -> s
 540   t = case w of [s,t] -> t
 541 ]
 542 \end{verbatim}
 543
 544 Here \tr{w} is a fresh variable, and the \tr{w}-binding prevents multiple
 545 evaluation of \tr{e}.  An alternative translation (No.~2):
 546 \begin{verbatim}
 547 [ w = case e of [s,t] -> (s,t)
 548   s = case w of (s,t) -> s
 549   t = case w of (s,t) -> t
 550 ]
 551 \end{verbatim}
 552
 553 %************************************************************************
 554 %*                                                                      *
 555 \subsubsection[improved-unmixing]{UNIMPLEMENTED idea for improved unmixing}
 556 %*                                                                      *
 557 %************************************************************************
 558
 559 We might be able to optimise unmixing when confronted by
 560 only-one-constructor-possible, of which tuples are the most notable
 561 examples.  Consider:
 562 \begin{verbatim}
 563 f (a,b,c) ... = ...
 564 f d ... (e:f) = ...
 565 f (g,h,i) ... = ...
 566 f j ...       = ...
 567 \end{verbatim}
 568 This definition would normally be unmixed into four equation blocks,
 569 one per equation.  But it could be unmixed into just one equation
 570 block, because if the one equation matches (on the first column),
 571 the others certainly will.
 572
 573 You have to be careful, though; the example
 574 \begin{verbatim}
 575 f j ...       = ...
 576 -------------------
 577 f (a,b,c) ... = ...
 578 f d ... (e:f) = ...
 579 f (g,h,i) ... = ...
 580 \end{verbatim}
 581 {\em must} be broken into two blocks at the line shown; otherwise, you
 582 are forcing unnecessary evaluation.  In any case, the top-left pattern
 583 always gives the cue.  You could then unmix blocks into groups of...
 584 \begin{description}
 585 \item[all variables:]
 586 As it is now.
 587 \item[constructors or variables (mixed):]
 588 Need to make sure the right names get bound for the variable patterns.
 589 \item[literals or variables (mixed):]
 590 Presumably just a variant on the constructor case (as it is now).
 591 \end{description}
 592
 593 %************************************************************************
 594 %*                                                                      *
 595 %*  matchWrapper: a convenient way to call @match@                      *
 596 %*                                                                      *
 597 %************************************************************************
 598 \subsection[matchWrapper]{@matchWrapper@: a convenient interface to @match@}
 599
 600 Calls to @match@ often involve similar (non-trivial) work; that work
 601 is collected here, in @matchWrapper@.  This function takes as
 602 arguments:
 603 \begin{itemize}
 604 \item
 605 Typchecked @Matches@ (of a function definition, or a case or lambda
 606 expression)---the main input;
 607 \item
 608 An error message to be inserted into any (runtime) pattern-matching
 609 failure messages.
 610 \end{itemize}
 611
 612 As results, @matchWrapper@ produces:
 613 \begin{itemize}
 614 \item
 615 A list of variables (@Locals@) that the caller must ``promise'' to
 616 bind to appropriate values; and
 617 \item
 618 a @CoreExpr@, the desugared output (main result).
 619 \end{itemize}
 620
 621 The main actions of @matchWrapper@ include:
 622 \begin{enumerate}
 623 \item
 624 Flatten the @[TypecheckedMatch]@ into a suitable list of
 625 @EquationInfo@s.
 626 \item
 627 Create as many new variables as there are patterns in a pattern-list
 628 (in any one of the @EquationInfo@s).
 629 \item
 630 Create a suitable ``if it fails'' expression---a call to @error@ using
 631 the error-string input; the {\em type} of this fail value can be found
 632 by examining one of the RHS expressions in one of the @EquationInfo@s.
 633 \item
 634 Call @match@ with all of this information!
 635 \end{enumerate}
 636
 637 \begin{code}
 638 matchWrapper :: HsMatchContext Name     -- For shadowing warning messages
 639              -> MatchGroup Id           -- Matches being desugared
 640              -> DsM ([Id], CoreExpr)    -- Results
 641 \end{code}
 642
 643  There is one small problem with the Lambda Patterns, when somebody
 644  writes something similar to:
 645 \begin{verbatim}
 646     (\ (x:xs) -> ...)
 647 \end{verbatim}
 648  he/she don't want a warning about incomplete patterns, that is done with
 649  the flag @opt_WarnSimplePatterns@.
 650  This problem also appears in the:
 651 \begin{itemize}
 652 \item @do@ patterns, but if the @do@ can fail
 653       it creates another equation if the match can fail
 654       (see @DsExpr.doDo@ function)
 655 \item @let@ patterns, are treated by @matchSimply@
 656    List Comprension Patterns, are treated by @matchSimply@ also
 657 \end{itemize}
 658
 659 We can't call @matchSimply@ with Lambda patterns,
 660 due to the fact that lambda patterns can have more than
 661 one pattern, and match simply only accepts one pattern.
 662
 663 JJQC 30-Nov-1997
 664
 665 \begin{code}
 666 matchWrapper ctxt (MatchGroup matches match_ty)
 667   = ASSERT( notNull matches )
 668     do  { eqns_info   <- mapM mk_eqn_info matches
 669         ; new_vars    <- selectMatchVars arg_pats
 670         ; result_expr <- matchEquations ctxt new_vars eqns_info rhs_ty
 671         ; return (new_vars, result_expr) }
 672   where
 673     arg_pats    = map unLoc (hsLMatchPats (head matches))
 674     n_pats      = length arg_pats
 675     (_, rhs_ty) = splitFunTysN n_pats match_ty
 676
 677     mk_eqn_info (L _ (Match pats _ grhss))
 678       = do { let upats = map unLoc pats
 679            ; match_result <- dsGRHSs ctxt upats grhss rhs_ty
 680            ; return (EqnInfo { eqn_pats = upats, eqn_rhs  = match_result}) }
 681
 682
 683 matchEquations  :: HsMatchContext Name
 684                 -> [Id] -> [EquationInfo] -> Type
 685                 -> DsM CoreExpr
 686 matchEquations ctxt vars eqns_info rhs_ty
 687   = do  { dflags <- getDOptsDs
 688         ; locn   <- getSrcSpanDs
 689         ; let   ds_ctxt      = DsMatchContext ctxt locn
 690                 error_doc = matchContextErrString ctxt
 691
 692         ; match_result <- match_fun dflags ds_ctxt vars rhs_ty eqns_info
 693
 694         ; fail_expr <- mkErrorAppDs pAT_ERROR_ID rhs_ty error_doc
 695         ; extractMatchResult match_result fail_expr }
 696   where
 697     match_fun dflags ds_ctxt
 698        = case ctxt of
 699            LambdaExpr | dopt Opt_WarnSimplePatterns dflags -> matchCheck ds_ctxt
 700                       | otherwise                          -> match
 701            _                                               -> matchCheck ds_ctxt
 702 \end{code}
 703
 704 %************************************************************************
 705 %*                                                                      *
 706 \subsection[matchSimply]{@matchSimply@: match a single expression against a single pattern}
 707 %*                                                                      *
 708 %************************************************************************
 709
 710 @mkSimpleMatch@ is a wrapper for @match@ which deals with the
 711 situation where we want to match a single expression against a single
 712 pattern. It returns an expression.
 713
 714 \begin{code}
 715 matchSimply :: CoreExpr                 -- Scrutinee
 716             -> HsMatchContext Name      -- Match kind
 717             -> LPat Id                  -- Pattern it should match
 718             -> CoreExpr                 -- Return this if it matches
 719             -> CoreExpr                 -- Return this if it doesn't
 720             -> DsM CoreExpr
 721
 722 matchSimply scrut hs_ctx pat result_expr fail_expr = do
 723     let
 724       match_result = cantFailMatchResult result_expr
 725       rhs_ty       = exprType fail_expr
 726         -- Use exprType of fail_expr, because won't refine in the case of failure!
 727     match_result' <- matchSinglePat scrut hs_ctx pat rhs_ty match_result
 728     extractMatchResult match_result' fail_expr
 729
 730
 731 matchSinglePat :: CoreExpr -> HsMatchContext Name -> LPat Id
 732                -> Type -> MatchResult -> DsM MatchResult
 733 matchSinglePat (Var var) hs_ctx (L _ pat) ty match_result = do
 734     dflags <- getDOptsDs
 735     locn <- getSrcSpanDs
 736     let
 737         match_fn dflags
 738            | dopt Opt_WarnSimplePatterns dflags = matchCheck ds_ctx
 739            | otherwise                          = match
 740            where
 741              ds_ctx = DsMatchContext hs_ctx locn
 742     match_fn dflags [var] ty [EqnInfo { eqn_pats = [pat], eqn_rhs  = match_result }]
 743
 744 matchSinglePat scrut hs_ctx pat ty match_result = do
 745     var <- selectSimpleMatchVarL pat
 746     match_result' <- matchSinglePat (Var var) hs_ctx pat ty match_result
 747     return (adjustMatchResult (bindNonRec var scrut) match_result')
 748 \end{code}
 749
 750
 751 %************************************************************************
 752 %*                                                                      *
 753                 Pattern classification
 754 %*                                                                      *
 755 %************************************************************************
 756
 757 \begin{code}
 758 data PatGroup
 759   = PgAny               -- Immediate match: variables, wildcards,
 760                         --                  lazy patterns
 761   | PgCon DataCon       -- Constructor patterns (incl list, tuple)
 762   | PgLit Literal       -- Literal patterns
 763   | PgN   Literal       -- Overloaded literals
 764   | PgNpK Literal       -- n+k patterns
 765   | PgBang              -- Bang patterns
 766   | PgCo Type           -- Coercion patterns; the type is the type
 767                         --      of the pattern *inside*
 768   | PgView (LHsExpr Id) -- view pattern (e -> p):
 769                         -- the LHsExpr is the expression e
 770            Type         -- the Type is the type of p (equivalently, the result type of e)
 771
 772 groupEquations :: [EquationInfo] -> [[(PatGroup, EquationInfo)]]
 773 -- If the result is of form [g1, g2, g3],
 774 -- (a) all the (pg,eq) pairs in g1 have the same pg
 775 -- (b) none of the gi are empty
 776 -- The ordering of equations is unchanged
 777 groupEquations eqns
 778   = runs same_gp [(patGroup (firstPat eqn), eqn) | eqn <- eqns]
 779   where
 780     same_gp :: (PatGroup,EquationInfo) -> (PatGroup,EquationInfo) -> Bool
 781     (pg1,_) `same_gp` (pg2,_) = pg1 `sameGroup` pg2
 782
 783 subGroup :: Ord a => [(a, EquationInfo)] -> [[EquationInfo]]
 784 -- Input is a particular group.  The result sub-groups the
 785 -- equations by with particular constructor, literal etc they match.
 786 -- Each sub-list in the result has the same PatGroup
 787 -- See Note [Take care with pattern order]
 788 subGroup group
 789     = map reverse $ eltsFM $ foldl accumulate emptyFM group
 790   where
 791     accumulate pg_map (pg, eqn)
 792       = case lookupFM pg_map pg of
 793           Just eqns -> addToFM pg_map pg (eqn:eqns)
 794           Nothing   -> addToFM pg_map pg [eqn]
 795
 796     -- pg_map :: FiniteMap a [EquationInfo]
 797     -- Equations seen so far in reverse order of appearance
 798 \end{code}
 799
 800 Note [Take care with pattern order]
 801 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 802 In the subGroup function we must be very careful about pattern re-ordering,
 803 Consider the patterns [ (True, Nothing), (False, x), (True, y) ]
 804 Then in bringing together the patterns for True, we must not
 805 swap the Nothing and y!
 806
 807
 808 \begin{code}
 809 sameGroup :: PatGroup -> PatGroup -> Bool
 810 -- Same group means that a single case expression
 811 -- or test will suffice to match both, *and* the order
 812 -- of testing within the group is insignificant.
 813 sameGroup PgAny      PgAny      = True
 814 sameGroup PgBang     PgBang     = True
 815 sameGroup (PgCon _)  (PgCon _)  = True          -- One case expression
 816 sameGroup (PgLit _)  (PgLit _)  = True          -- One case expression
 817 sameGroup (PgN l1)   (PgN l2)   = l1==l2        -- Order is significant
 818 sameGroup (PgNpK l1) (PgNpK l2) = l1==l2        -- See Note [Grouping overloaded literal patterns]
 819 sameGroup (PgCo t1)  (PgCo t2)  = t1 `coreEqType` t2
 820         -- CoPats are in the same goup only if the type of the
 821         -- enclosed pattern is the same. The patterns outside the CoPat
 822         -- always have the same type, so this boils down to saying that
 823         -- the two coercions are identical.
 824 sameGroup (PgView e1 t1) (PgView e2 t2) = viewLExprEq (e1,t1) (e2,t2)
 825        -- ViewPats are in the same gorup iff the expressions
 826        -- are "equal"---conservatively, we use syntactic equality
 827 sameGroup _          _          = False
 828
 829 -- an approximation of syntactic equality used for determining when view
 830 -- exprs are in the same group.
 831 -- this function can always safely return false;
 832 -- but doing so will result in the application of the view function being repeated.
 833 --
 834 -- currently: compare applications of literals and variables
 835 --            and anything else that we can do without involving other
 836 --            HsSyn types in the recursion
 837 --
 838 -- NB we can't assume that the two view expressions have the same type.  Consider
 839 --   f (e1 -> True) = ...
 840 --   f (e2 -> "hi") = ...
 841 viewLExprEq :: (LHsExpr Id,Type) -> (LHsExpr Id,Type) -> Bool
 842 viewLExprEq (e1,_) (e2,_) =
 843     let
 844         -- short name for recursive call on unLoc
 845         lexp e e' = exp (unLoc e) (unLoc e')
 846
 847         -- check that two lists have the same length
 848         -- and that they match up pairwise
 849         lexps [] [] = True
 850         lexps [] (_:_) = False
 851         lexps (_:_) [] = False
 852         lexps (x:xs) (y:ys) = lexp x y && lexps xs ys
 853
 854         -- conservative, in that it demands that wrappers be
 855         -- syntactically identical and doesn't look under binders
 856         --
 857         -- coarser notions of equality are possible
 858         -- (e.g., reassociating compositions,
 859         --        equating different ways of writing a coercion)
 860         wrap WpHole WpHole = True
 861         wrap (WpCompose w1 w2) (WpCompose w1' w2') = wrap w1 w1' && wrap w2 w2'
 862         wrap (WpCast c)  (WpCast c')  = tcEqType c c'
 863         wrap (WpApp d)   (WpApp d')   = d == d'
 864         wrap (WpTyApp t) (WpTyApp t') = tcEqType t t'
 865         -- Enhancement: could implement equality for more wrappers
 866         --   if it seems useful (lams and lets)
 867         wrap _ _ = False
 868
 869         -- real comparison is on HsExpr's
 870         -- strip parens
 871         exp (HsPar (L _ e)) e'   = exp e e'
 872         exp e (HsPar (L _ e'))   = exp e e'
 873         -- because the expressions do not necessarily have the same type,
 874         -- we have to compare the wrappers
 875         exp (HsWrap h e) (HsWrap h' e') = wrap h h' && exp e e'
 876         exp (HsVar i) (HsVar i') =  i == i'
 877         -- the instance for IPName derives using the id, so this works if the
 878         -- above does
 879         exp (HsIPVar i) (HsIPVar i') = i == i'
 880         exp (HsOverLit l) (HsOverLit l') =
 881             -- overloaded lits are equal if they have the same type
 882             -- and the data is the same.
 883             -- this is coarser than comparing the SyntaxExpr's in l and l',
 884             -- which resolve the overloading (e.g., fromInteger 1),
 885             -- because these expressions get written as a bunch of different variables
 886             -- (presumably to improve sharing)
 887             tcEqType (overLitType l) (overLitType l') && l == l'
 888         -- comparing the constants seems right
 889         exp (HsLit l) (HsLit l') = l == l'
 890         exp (HsApp e1 e2) (HsApp e1' e2') = lexp e1 e1' && lexp e2 e2'
 891         -- the fixities have been straightened out by now, so it's safe
 892         -- to ignore them?
 893         exp (OpApp l o _ ri) (OpApp l' o' _ ri') =
 894             lexp l l' && lexp o o' && lexp ri ri'
 895         exp (NegApp e n) (NegApp e' n') = lexp e e' && exp n n'
 896         exp (SectionL e1 e2) (SectionL e1' e2') =
 897             lexp e1 e1' && lexp e2 e2'
 898         exp (SectionR e1 e2) (SectionR e1' e2') =
 899             lexp e1 e1' && lexp e2 e2'
 900         exp (HsIf e e1 e2) (HsIf e' e1' e2') =
 901             lexp e e' && lexp e1 e1' && lexp e2 e2'
 902         exp (ExplicitList _ ls) (ExplicitList _ ls') = lexps ls ls'
 903         exp (ExplicitPArr _ ls) (ExplicitPArr _ ls') = lexps ls ls'
 904         exp (ExplicitTuple ls _) (ExplicitTuple ls' _) = lexps ls ls'
 905         -- Enhancement: could implement equality for more expressions
 906         --   if it seems useful
 907         exp _ _  = False
 908     in
 909       lexp e1 e2
 910
 911 patGroup :: Pat Id -> PatGroup
 912 patGroup (WildPat {})                 = PgAny
 913 patGroup (BangPat {})                 = PgBang
 914 patGroup (ConPatOut { pat_con = dc }) = PgCon (unLoc dc)
 915 patGroup (LitPat lit)                 = PgLit (hsLitKey lit)
 916 patGroup (NPat olit mb_neg _)         = PgN   (hsOverLitKey olit (isJust mb_neg))
 917 patGroup (NPlusKPat _ olit _ _)       = PgNpK (hsOverLitKey olit False)
 918 patGroup (CoPat _ p _)                = PgCo  (hsPatType p)     -- Type of innelexp pattern
 919 patGroup (ViewPat expr p _)               = PgView expr (hsPatType (unLoc p))
 920 patGroup pat = pprPanic "patGroup" (ppr pat)
 921 \end{code}
 922
 923 Note [Grouping overloaded literal patterns]
 924 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 925 WATCH OUT!  Consider
 926
 927         f (n+1) = ...
 928         f (n+2) = ...
 929         f (n+1) = ...
 930
 931 We can't group the first and third together, because the second may match
 932 the same thing as the first.  Same goes for *overloaded* literal patterns
 933         f 1 True = ...
 934         f 2 False = ...
 935         f 1 False = ...
 936 If the first arg matches '1' but the second does not match 'True', we
 937 cannot jump to the third equation!  Because the same argument might
 938 match '2'!
 939 Hence we don't regard 1 and 2, or (n+1) and (n+2), as part of the same group.