compiler/ghci/ByteCodeGen.lhs

   1 %
   2 % (c) The University of Glasgow 2002-2006
   3 %
   4
   5 ByteCodeGen: Generate bytecode from Core
   6
   7 \begin{code}
   8 {-# OPTIONS -w #-}
   9 -- The above warning supression flag is a temporary kludge.
  10 -- While working on this module you are encouraged to remove it and fix
  11 -- any warnings in the module. See
  12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  13 -- for details
  14
  15 module ByteCodeGen ( UnlinkedBCO, byteCodeGen, coreExprToBCOs ) where
  16
  17 #include "HsVersions.h"
  18
  19 import ByteCodeInstr
  20 import ByteCodeItbls
  21 import ByteCodeFFI
  22 import ByteCodeAsm
  23 import ByteCodeLink
  24
  25 import Outputable
  26 import Name
  27 import Id
  28 import FiniteMap
  29 import ForeignCall
  30 import HscTypes
  31 import CoreUtils
  32 import CoreSyn
  33 import PprCore
  34 import Literal
  35 import PrimOp
  36 import CoreFVs
  37 import Type
  38 import DataCon
  39 import TyCon
  40 import Class
  41 import Type
  42 import Util
  43 import DataCon
  44 import Var
  45 import VarSet
  46 import TysPrim
  47 import DynFlags
  48 import ErrUtils
  49 import Unique
  50 import FastString
  51 import Panic
  52 import SMRep
  53 import Bitmap
  54 import OrdList
  55 import Constants
  56
  57 import Data.List        ( intersperse, sortBy, zip4, zip6, partition )
  58 import Foreign          ( Ptr, castPtr, mallocBytes, pokeByteOff, Word8,
  59                           withForeignPtr, castFunPtrToPtr, nullPtr, plusPtr )
  60 import Foreign.C
  61 import Control.Exception        ( throwDyn )
  62
  63 import GHC.Exts         ( Int(..), ByteArray# )
  64
  65 import Control.Monad    ( when )
  66 import Data.Char        ( ord, chr )
  67
  68 import UniqSupply
  69 import BreakArray
  70 import Data.Maybe
  71 import Module
  72 import IdInfo
  73
  74 -- -----------------------------------------------------------------------------
  75 -- Generating byte code for a complete module
  76
  77 byteCodeGen :: DynFlags
  78             -> [CoreBind]
  79             -> [TyCon]
  80             -> ModBreaks
  81             -> IO CompiledByteCode
  82 byteCodeGen dflags binds tycs modBreaks
  83    = do showPass dflags "ByteCodeGen"
  84
  85         let flatBinds = [ (bndr, freeVars rhs)
  86                         | (bndr, rhs) <- flattenBinds binds]
  87
  88         us <- mkSplitUniqSupply 'y'
  89         (BcM_State _us final_ctr mallocd _, proto_bcos)
  90            <- runBc us modBreaks (mapM schemeTopBind flatBinds)
  91
  92         when (notNull mallocd)
  93              (panic "ByteCodeGen.byteCodeGen: missing final emitBc?")
  94
  95         dumpIfSet_dyn dflags Opt_D_dump_BCOs
  96            "Proto-BCOs" (vcat (intersperse (char ' ') (map ppr proto_bcos)))
  97
  98         assembleBCOs proto_bcos tycs
  99
 100 -- -----------------------------------------------------------------------------
 101 -- Generating byte code for an expression
 102
 103 -- Returns: (the root BCO for this expression,
 104 --           a list of auxilary BCOs resulting from compiling closures)
 105 coreExprToBCOs :: DynFlags
 106                -> CoreExpr
 107                -> IO UnlinkedBCO
 108 coreExprToBCOs dflags expr
 109  = do showPass dflags "ByteCodeGen"
 110
 111       -- create a totally bogus name for the top-level BCO; this
 112       -- should be harmless, since it's never used for anything
 113       let invented_name  = mkSystemVarName (mkPseudoUniqueE 0) FSLIT("ExprTopLevel")
 114           invented_id    = Id.mkLocalId invented_name (panic "invented_id's type")
 115
 116       -- the uniques are needed to generate fresh variables when we introduce new
 117       -- let bindings for ticked expressions
 118       us <- mkSplitUniqSupply 'y'
 119       (BcM_State _us final_ctr mallocd _ , proto_bco)
 120          <- runBc us emptyModBreaks (schemeTopBind (invented_id, freeVars expr))
 121
 122       when (notNull mallocd)
 123            (panic "ByteCodeGen.coreExprToBCOs: missing final emitBc?")
 124
 125       dumpIfSet_dyn dflags Opt_D_dump_BCOs "Proto-BCOs" (ppr proto_bco)
 126
 127       assembleBCO proto_bco
 128
 129
 130 -- -----------------------------------------------------------------------------
 131 -- Compilation schema for the bytecode generator
 132
 133 type BCInstrList = OrdList BCInstr
 134
 135 type Sequel = Int       -- back off to this depth before ENTER
 136
 137 -- Maps Ids to the offset from the stack _base_ so we don't have
 138 -- to mess with it after each push/pop.
 139 type BCEnv = FiniteMap Id Int   -- To find vars on the stack
 140
 141 ppBCEnv :: BCEnv -> SDoc
 142 ppBCEnv p
 143    = text "begin-env"
 144      $$ nest 4 (vcat (map pp_one (sortBy cmp_snd (fmToList p))))
 145      $$ text "end-env"
 146      where
 147         pp_one (var, offset) = int offset <> colon <+> ppr var <+> ppr (idCgRep var)
 148         cmp_snd x y = compare (snd x) (snd y)
 149
 150 -- Create a BCO and do a spot of peephole optimisation on the insns
 151 -- at the same time.
 152 mkProtoBCO
 153    :: name
 154    -> BCInstrList
 155    -> Either  [AnnAlt Id VarSet] (AnnExpr Id VarSet)
 156    -> Int
 157    -> Int
 158    -> [StgWord]
 159    -> Bool      -- True <=> is a return point, rather than a function
 160    -> [BcPtr]
 161    -> ProtoBCO name
 162 mkProtoBCO nm instrs_ordlist origin arity bitmap_size bitmap is_ret mallocd_blocks
 163    = ProtoBCO {
 164         protoBCOName = nm,
 165         protoBCOInstrs = maybe_with_stack_check,
 166         protoBCOBitmap = bitmap,
 167         protoBCOBitmapSize = bitmap_size,
 168         protoBCOArity = arity,
 169         protoBCOExpr = origin,
 170         protoBCOPtrs = mallocd_blocks
 171       }
 172      where
 173         -- Overestimate the stack usage (in words) of this BCO,
 174         -- and if >= iNTERP_STACK_CHECK_THRESH, add an explicit
 175         -- stack check.  (The interpreter always does a stack check
 176         -- for iNTERP_STACK_CHECK_THRESH words at the start of each
 177         -- BCO anyway, so we only need to add an explicit on in the
 178         -- (hopefully rare) cases when the (overestimated) stack use
 179         -- exceeds iNTERP_STACK_CHECK_THRESH.
 180         maybe_with_stack_check
 181            | is_ret && stack_usage < aP_STACK_SPLIM = peep_d
 182                 -- don't do stack checks at return points,
 183                 -- everything is aggregated up to the top BCO
 184                 -- (which must be a function).
 185                 -- That is, unless the stack usage is >= AP_STACK_SPLIM,
 186                 -- see bug #1466.
 187            | stack_usage >= iNTERP_STACK_CHECK_THRESH
 188            = STKCHECK stack_usage : peep_d
 189            | otherwise
 190            = peep_d     -- the supposedly common case
 191
 192         -- We assume that this sum doesn't wrap
 193         stack_usage = sum (map bciStackUse peep_d)
 194
 195         -- Merge local pushes
 196         peep_d = peep (fromOL instrs_ordlist)
 197
 198         peep (PUSH_L off1 : PUSH_L off2 : PUSH_L off3 : rest)
 199            = PUSH_LLL off1 (off2-1) (off3-2) : peep rest
 200         peep (PUSH_L off1 : PUSH_L off2 : rest)
 201            = PUSH_LL off1 (off2-1) : peep rest
 202         peep (i:rest)
 203            = i : peep rest
 204         peep []
 205            = []
 206
 207 argBits :: [CgRep] -> [Bool]
 208 argBits [] = []
 209 argBits (rep : args)
 210   | isFollowableArg rep = False : argBits args
 211   | otherwise = take (cgRepSizeW rep) (repeat True) ++ argBits args
 212
 213 -- -----------------------------------------------------------------------------
 214 -- schemeTopBind
 215
 216 -- Compile code for the right-hand side of a top-level binding
 217
 218 schemeTopBind :: (Id, AnnExpr Id VarSet) -> BcM (ProtoBCO Name)
 219
 220
 221 schemeTopBind (id, rhs)
 222   | Just data_con <- isDataConWorkId_maybe id,
 223     isNullaryRepDataCon data_con = do
 224         -- Special case for the worker of a nullary data con.
 225         -- It'll look like this:        Nil = /\a -> Nil a
 226         -- If we feed it into schemeR, we'll get
 227         --      Nil = Nil
 228         -- because mkConAppCode treats nullary constructor applications
 229         -- by just re-using the single top-level definition.  So
 230         -- for the worker itself, we must allocate it directly.
 231     -- ioToBc (putStrLn $ "top level BCO")
 232     emitBc (mkProtoBCO (getName id) (toOL [PACK data_con 0, ENTER])
 233                        (Right rhs) 0 0 [{-no bitmap-}] False{-not alts-})
 234
 235   | otherwise
 236   = schemeR [{- No free variables -}] (id, rhs)
 237
 238
 239 -- -----------------------------------------------------------------------------
 240 -- schemeR
 241
 242 -- Compile code for a right-hand side, to give a BCO that,
 243 -- when executed with the free variables and arguments on top of the stack,
 244 -- will return with a pointer to the result on top of the stack, after
 245 -- removing the free variables and arguments.
 246 --
 247 -- Park the resulting BCO in the monad.  Also requires the
 248 -- variable to which this value was bound, so as to give the
 249 -- resulting BCO a name.
 250
 251 schemeR :: [Id]                 -- Free vars of the RHS, ordered as they
 252                                 -- will appear in the thunk.  Empty for
 253                                 -- top-level things, which have no free vars.
 254         -> (Id, AnnExpr Id VarSet)
 255         -> BcM (ProtoBCO Name)
 256 schemeR fvs (nm, rhs)
 257 {-
 258    | trace (showSDoc (
 259               (char ' '
 260                $$ (ppr.filter (not.isTyVar).varSetElems.fst) rhs
 261                $$ pprCoreExpr (deAnnotate rhs)
 262                $$ char ' '
 263               ))) False
 264    = undefined
 265    | otherwise
 266 -}
 267    = schemeR_wrk fvs nm rhs (collect [] rhs)
 268
 269 collect :: [Var] -> AnnExpr Id VarSet -> ([Var], AnnExpr' Id VarSet)
 270 collect xs (_, AnnNote note e) = collect xs e
 271 collect xs (_, AnnCast e _)    = collect xs e
 272 collect xs (_, AnnLam x e)     = collect (if isTyVar x then xs else (x:xs)) e
 273 collect xs (_, not_lambda)     = (reverse xs, not_lambda)
 274
 275 schemeR_wrk :: [Id] -> Id -> AnnExpr Id VarSet -> ([Var], AnnExpr' Var VarSet) -> BcM (ProtoBCO Name)
 276 schemeR_wrk fvs nm original_body (args, body)
 277    = let
 278          all_args  = reverse args ++ fvs
 279          arity     = length all_args
 280          -- all_args are the args in reverse order.  We're compiling a function
 281          -- \fv1..fvn x1..xn -> e
 282          -- i.e. the fvs come first
 283
 284          szsw_args = map idSizeW all_args
 285          szw_args  = sum szsw_args
 286          p_init    = listToFM (zip all_args (mkStackOffsets 0 szsw_args))
 287
 288          -- make the arg bitmap
 289          bits = argBits (reverse (map idCgRep all_args))
 290          bitmap_size = length bits
 291          bitmap = mkBitmap bits
 292      in do
 293      body_code <- schemeER_wrk szw_args p_init body
 294
 295      emitBc (mkProtoBCO (getName nm) body_code (Right original_body)
 296                 arity bitmap_size bitmap False{-not alts-})
 297
 298 -- introduce break instructions for ticked expressions
 299 schemeER_wrk :: Int -> BCEnv -> AnnExpr' Id VarSet -> BcM BCInstrList
 300 schemeER_wrk d p rhs
 301    | Just (tickInfo, (_annot, newRhs)) <- isTickedExp' rhs = do
 302         code <- schemeE d 0 p newRhs
 303         arr <- getBreakArray
 304         let idOffSets = getVarOffSets d p tickInfo
 305         let tickNumber = tickInfo_number tickInfo
 306         let breakInfo = BreakInfo
 307                         { breakInfo_module = tickInfo_module tickInfo
 308                         , breakInfo_number = tickNumber
 309                         , breakInfo_vars = idOffSets
 310                         , breakInfo_resty = exprType (deAnnotate' newRhs)
 311                         }
 312         let breakInstr = case arr of (BA arr#) -> BRK_FUN arr# tickNumber breakInfo
 313         return $ breakInstr `consOL` code
 314    | otherwise = schemeE d 0 p rhs
 315
 316 getVarOffSets :: Int -> BCEnv -> TickInfo -> [(Id, Int)]
 317 getVarOffSets d p = catMaybes . map (getOffSet d p) . tickInfo_locals
 318
 319 getOffSet :: Int -> BCEnv -> Id -> Maybe (Id, Int)
 320 getOffSet d env id
 321    = case lookupBCEnv_maybe env id of
 322         Nothing     -> Nothing
 323         Just offset -> Just (id, d - offset)
 324
 325 fvsToEnv :: BCEnv -> VarSet -> [Id]
 326 -- Takes the free variables of a right-hand side, and
 327 -- delivers an ordered list of the local variables that will
 328 -- be captured in the thunk for the RHS
 329 -- The BCEnv argument tells which variables are in the local
 330 -- environment: these are the ones that should be captured
 331 --
 332 -- The code that constructs the thunk, and the code that executes
 333 -- it, have to agree about this layout
 334 fvsToEnv p fvs = [v | v <- varSetElems fvs,
 335                       isId v,           -- Could be a type variable
 336                       v `elemFM` p]
 337
 338 -- -----------------------------------------------------------------------------
 339 -- schemeE
 340
 341 data TickInfo
 342    = TickInfo
 343      { tickInfo_number :: Int     -- the (module) unique number of the tick
 344      , tickInfo_module :: Module  -- the origin of the ticked expression
 345      , tickInfo_locals :: [Id]    -- the local vars in scope at the ticked expression
 346      }
 347
 348 instance Outputable TickInfo where
 349    ppr info = text "TickInfo" <+>
 350               parens (int (tickInfo_number info) <+> ppr (tickInfo_module info) <+>
 351                       ppr (tickInfo_locals info))
 352
 353 -- Compile code to apply the given expression to the remaining args
 354 -- on the stack, returning a HNF.
 355 schemeE :: Int -> Sequel -> BCEnv -> AnnExpr' Id VarSet -> BcM BCInstrList
 356
 357 -- Delegate tail-calls to schemeT.
 358 schemeE d s p e@(AnnApp f a)
 359    = schemeT d s p e
 360
 361 schemeE d s p e@(AnnVar v)
 362    | not (isUnLiftedType v_type)
 363    =  -- Lifted-type thing; push it in the normal way
 364      schemeT d s p e
 365
 366    | otherwise
 367    = do -- Returning an unlifted value.
 368         -- Heave it on the stack, SLIDE, and RETURN.
 369         (push, szw) <- pushAtom d p (AnnVar v)
 370         return (push                    -- value onto stack
 371                   `appOL`  mkSLIDE szw (d-s)    -- clear to sequel
 372                   `snocOL` RETURN_UBX v_rep)    -- go
 373    where
 374       v_type = idType v
 375       v_rep = typeCgRep v_type
 376
 377 schemeE d s p (AnnLit literal)
 378    = do (push, szw) <- pushAtom d p (AnnLit literal)
 379         let l_rep = typeCgRep (literalType literal)
 380         return (push                    -- value onto stack
 381                `appOL`  mkSLIDE szw (d-s)       -- clear to sequel
 382                `snocOL` RETURN_UBX l_rep)       -- go
 383
 384 schemeE d s p (AnnLet (AnnNonRec x (_,rhs)) (_,body))
 385    | (AnnVar v, args_r_to_l) <- splitApp rhs,
 386      Just data_con <- isDataConWorkId_maybe v,
 387      dataConRepArity data_con == length args_r_to_l
 388    = do -- Special case for a non-recursive let whose RHS is a
 389         -- saturatred constructor application.
 390         -- Just allocate the constructor and carry on
 391         alloc_code <- mkConAppCode d s p data_con args_r_to_l
 392         body_code <- schemeE (d+1) s (addToFM p x d) body
 393         return (alloc_code `appOL` body_code)
 394
 395 -- General case for let.  Generates correct, if inefficient, code in
 396 -- all situations.
 397 schemeE d s p (AnnLet binds (_,body))
 398    = let (xs,rhss) = case binds of AnnNonRec x rhs  -> ([x],[rhs])
 399                                    AnnRec xs_n_rhss -> unzip xs_n_rhss
 400          n_binds = length xs
 401
 402          fvss  = map (fvsToEnv p' . fst) rhss
 403
 404          -- Sizes of free vars
 405          sizes = map (\rhs_fvs -> sum (map idSizeW rhs_fvs)) fvss
 406
 407          -- the arity of each rhs
 408          arities = map (length . fst . collect []) rhss
 409
 410          -- This p', d' defn is safe because all the items being pushed
 411          -- are ptrs, so all have size 1.  d' and p' reflect the stack
 412          -- after the closures have been allocated in the heap (but not
 413          -- filled in), and pointers to them parked on the stack.
 414          p'    = addListToFM p (zipE xs (mkStackOffsets d (nOfThem n_binds 1)))
 415          d'    = d + n_binds
 416          zipE  = zipEqual "schemeE"
 417
 418          -- ToDo: don't build thunks for things with no free variables
 419          build_thunk dd [] size bco off arity
 420             = return (PUSH_BCO bco `consOL` unitOL (mkap (off+size) size))
 421            where
 422                 mkap | arity == 0 = MKAP
 423                      | otherwise  = MKPAP
 424          build_thunk dd (fv:fvs) size bco off arity = do
 425               (push_code, pushed_szw) <- pushAtom dd p' (AnnVar fv)
 426               more_push_code <- build_thunk (dd+pushed_szw) fvs size bco off arity
 427               return (push_code `appOL` more_push_code)
 428
 429          alloc_code = toOL (zipWith mkAlloc sizes arities)
 430            where mkAlloc sz 0     = ALLOC_AP sz
 431                  mkAlloc sz arity = ALLOC_PAP arity sz
 432
 433          compile_bind d' fvs x rhs size arity off = do
 434                 bco <- schemeR fvs (x,rhs)
 435                 build_thunk d' fvs size bco off arity
 436
 437          compile_binds =
 438             [ compile_bind d' fvs x rhs size arity n
 439             | (fvs, x, rhs, size, arity, n) <-
 440                 zip6 fvss xs rhss sizes arities [n_binds, n_binds-1 .. 1]
 441             ]
 442      in do
 443      body_code <- schemeE d' s p' body
 444      thunk_codes <- sequence compile_binds
 445      return (alloc_code `appOL` concatOL thunk_codes `appOL` body_code)
 446
 447 -- introduce a let binding for a ticked case expression. This rule
 448 -- *should* only fire when the expression was not already let-bound
 449 -- (the code gen for let bindings should take care of that).  Todo: we
 450 -- call exprFreeVars on a deAnnotated expression, this may not be the
 451 -- best way to calculate the free vars but it seemed like the least
 452 -- intrusive thing to do
 453 schemeE d s p exp@(AnnCase {})
 454    | Just (tickInfo,rhs) <- isTickedExp' exp
 455    = if isUnLiftedType ty
 456         then schemeE d s p (snd rhs)
 457         else do
 458           id <- newId ty
 459           -- Todo: is emptyVarSet correct on the next line?
 460           let letExp = AnnLet (AnnNonRec id (fvs, exp)) (emptyVarSet, AnnVar id)
 461           schemeE d s p letExp
 462    where exp' = deAnnotate' exp
 463          fvs  = exprFreeVars exp'
 464          ty   = exprType exp'
 465
 466 schemeE d s p (AnnCase scrut bndr _ [(DataAlt dc, [bind1, bind2], rhs)])
 467    | isUnboxedTupleCon dc, VoidArg <- typeCgRep (idType bind1)
 468         -- Convert
 469         --      case .... of x { (# VoidArg'd-thing, a #) -> ... }
 470         -- to
 471         --      case .... of a { DEFAULT -> ... }
 472         -- becuse the return convention for both are identical.
 473         --
 474         -- Note that it does not matter losing the void-rep thing from the
 475         -- envt (it won't be bound now) because we never look such things up.
 476
 477    = --trace "automagic mashing of case alts (# VoidArg, a #)" $
 478      doCase d s p scrut bind2 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
 479
 480    | isUnboxedTupleCon dc, VoidArg <- typeCgRep (idType bind2)
 481    = --trace "automagic mashing of case alts (# a, VoidArg #)" $
 482      doCase d s p scrut bind1 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
 483
 484 schemeE d s p (AnnCase scrut bndr _ [(DataAlt dc, [bind1], rhs)])
 485    | isUnboxedTupleCon dc
 486         -- Similarly, convert
 487         --      case .... of x { (# a #) -> ... }
 488         -- to
 489         --      case .... of a { DEFAULT -> ... }
 490    = --trace "automagic mashing of case alts (# a #)"  $
 491      doCase d s p scrut bind1 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
 492
 493 schemeE d s p (AnnCase scrut bndr _ alts)
 494    = doCase d s p scrut bndr alts False{-not an unboxed tuple-}
 495
 496 schemeE d s p (AnnNote note (_, body))
 497    = schemeE d s p body
 498
 499 schemeE d s p (AnnCast (_, body) _)
 500    = schemeE d s p body
 501
 502 schemeE d s p other
 503    = pprPanic "ByteCodeGen.schemeE: unhandled case"
 504                (pprCoreExpr (deAnnotate' other))
 505
 506 {-
 507    Ticked Expressions
 508    ------------------
 509
 510    A ticked expression looks like this:
 511
 512       case tick<n> var1 ... varN of DEFAULT -> e
 513
 514    (*) <n> is the number of the tick, which is unique within a module
 515    (*) var1 ... varN are the local variables in scope at the tick site
 516
 517    If we find a ticked expression we return:
 518
 519       Just ((n, [var1 ... varN]), e)
 520
 521   otherwise we return Nothing.
 522
 523   The idea is that the "case tick<n> ..." is really just an annotation on
 524   the code. When we find such a thing, we pull out the useful information,
 525   and then compile the code as if it was just the expression "e".
 526
 527 -}
 528
 529 isTickedExp :: AnnExpr Id a -> Maybe (TickInfo, AnnExpr Id a)
 530 isTickedExp (annot, expr) = isTickedExp' expr
 531
 532 isTickedExp' :: AnnExpr' Id a -> Maybe (TickInfo, AnnExpr Id a)
 533 isTickedExp' (AnnCase scrut _bndr _type alts)
 534    | Just tickInfo <- isTickedScrut scrut,
 535      [(DEFAULT, _bndr, rhs)] <- alts
 536      = Just (tickInfo, rhs)
 537    where
 538    isTickedScrut :: (AnnExpr Id a) -> Maybe TickInfo
 539    isTickedScrut expr
 540       | Var id <- f,
 541         Just (TickBox modName tickNumber) <- isTickBoxOp_maybe id
 542            = Just $ TickInfo { tickInfo_number = tickNumber
 543                              , tickInfo_module = modName
 544                              , tickInfo_locals = idsOfArgs args
 545                              }
 546       | otherwise = Nothing
 547       where
 548       (f, args) = collectArgs $ deAnnotate expr
 549       idsOfArgs :: [Expr Id] -> [Id]
 550       idsOfArgs = catMaybes . map exprId
 551       exprId :: Expr Id -> Maybe Id
 552       exprId (Var id) = Just id
 553       exprId other    = Nothing
 554
 555 isTickedExp' other = Nothing
 556
 557 -- Compile code to do a tail call.  Specifically, push the fn,
 558 -- slide the on-stack app back down to the sequel depth,
 559 -- and enter.  Four cases:
 560 --
 561 -- 0.  (Nasty hack).
 562 --     An application "GHC.Prim.tagToEnum# <type> unboxed-int".
 563 --     The int will be on the stack.  Generate a code sequence
 564 --     to convert it to the relevant constructor, SLIDE and ENTER.
 565 --
 566 -- 1.  The fn denotes a ccall.  Defer to generateCCall.
 567 --
 568 -- 2.  (Another nasty hack).  Spot (# a::VoidArg, b #) and treat
 569 --     it simply as  b  -- since the representations are identical
 570 --     (the VoidArg takes up zero stack space).  Also, spot
 571 --     (# b #) and treat it as  b.
 572 --
 573 -- 3.  Application of a constructor, by defn saturated.
 574 --     Split the args into ptrs and non-ptrs, and push the nonptrs,
 575 --     then the ptrs, and then do PACK and RETURN.
 576 --
 577 -- 4.  Otherwise, it must be a function call.  Push the args
 578 --     right to left, SLIDE and ENTER.
 579
 580 schemeT :: Int          -- Stack depth
 581         -> Sequel       -- Sequel depth
 582         -> BCEnv        -- stack env
 583         -> AnnExpr' Id VarSet
 584         -> BcM BCInstrList
 585
 586 schemeT d s p app
 587
 588 --   | trace ("schemeT: env in = \n" ++ showSDocDebug (ppBCEnv p)) False
 589 --   = panic "schemeT ?!?!"
 590
 591 --   | trace ("\nschemeT\n" ++ showSDoc (pprCoreExpr (deAnnotate' app)) ++ "\n") False
 592 --   = error "?!?!"
 593
 594    -- Case 0
 595    | Just (arg, constr_names) <- maybe_is_tagToEnum_call
 596    = do (push, arg_words) <- pushAtom d p arg
 597         tagToId_sequence <- implement_tagToId constr_names
 598         return (push `appOL`  tagToId_sequence
 599                        `appOL`  mkSLIDE 1 (d+arg_words-s)
 600                        `snocOL` ENTER)
 601
 602    -- Case 1
 603    | Just (CCall ccall_spec) <- isFCallId_maybe fn
 604    = generateCCall d s p ccall_spec fn args_r_to_l
 605
 606    -- Case 2: Constructor application
 607    | Just con <- maybe_saturated_dcon,
 608      isUnboxedTupleCon con
 609    = case args_r_to_l of
 610         [arg1,arg2] | isVoidArgAtom arg1 ->
 611                   unboxedTupleReturn d s p arg2
 612         [arg1,arg2] | isVoidArgAtom arg2 ->
 613                   unboxedTupleReturn d s p arg1
 614         _other -> unboxedTupleException
 615
 616    -- Case 3: Ordinary data constructor
 617    | Just con <- maybe_saturated_dcon
 618    = do alloc_con <- mkConAppCode d s p con args_r_to_l
 619         return (alloc_con        `appOL`
 620                   mkSLIDE 1 (d - s) `snocOL`
 621                   ENTER)
 622
 623    -- Case 4: Tail call of function
 624    | otherwise
 625    = doTailCall d s p fn args_r_to_l
 626
 627    where
 628       -- Detect and extract relevant info for the tagToEnum kludge.
 629       maybe_is_tagToEnum_call
 630          = let extract_constr_Names ty
 631                  | Just (tyc, []) <- splitTyConApp_maybe (repType ty),
 632                    isDataTyCon tyc
 633                    = map (getName . dataConWorkId) (tyConDataCons tyc)
 634                    -- NOTE: use the worker name, not the source name of
 635                    -- the DataCon.  See DataCon.lhs for details.
 636                  | otherwise
 637                    = panic "maybe_is_tagToEnum_call.extract_constr_Ids"
 638            in
 639            case app of
 640               (AnnApp (_, AnnApp (_, AnnVar v) (_, AnnType t)) arg)
 641                  -> case isPrimOpId_maybe v of
 642                        Just TagToEnumOp -> Just (snd arg, extract_constr_Names t)
 643                        other            -> Nothing
 644               other -> Nothing
 645
 646         -- Extract the args (R->L) and fn
 647         -- The function will necessarily be a variable,
 648         -- because we are compiling a tail call
 649       (AnnVar fn, args_r_to_l) = splitApp app
 650
 651       -- Only consider this to be a constructor application iff it is
 652       -- saturated.  Otherwise, we'll call the constructor wrapper.
 653       n_args = length args_r_to_l
 654       maybe_saturated_dcon
 655         = case isDataConWorkId_maybe fn of
 656                 Just con | dataConRepArity con == n_args -> Just con
 657                 _ -> Nothing
 658
 659 -- -----------------------------------------------------------------------------
 660 -- Generate code to build a constructor application,
 661 -- leaving it on top of the stack
 662
 663 mkConAppCode :: Int -> Sequel -> BCEnv
 664              -> DataCon                 -- The data constructor
 665              -> [AnnExpr' Id VarSet]    -- Args, in *reverse* order
 666              -> BcM BCInstrList
 667
 668 mkConAppCode orig_d s p con []  -- Nullary constructor
 669   = ASSERT( isNullaryRepDataCon con )
 670     return (unitOL (PUSH_G (getName (dataConWorkId con))))
 671         -- Instead of doing a PACK, which would allocate a fresh
 672         -- copy of this constructor, use the single shared version.
 673
 674 mkConAppCode orig_d s p con args_r_to_l
 675   = ASSERT( dataConRepArity con == length args_r_to_l )
 676     do_pushery orig_d (non_ptr_args ++ ptr_args)
 677  where
 678         -- The args are already in reverse order, which is the way PACK
 679         -- expects them to be.  We must push the non-ptrs after the ptrs.
 680       (ptr_args, non_ptr_args) = partition isPtrAtom args_r_to_l
 681
 682       do_pushery d (arg:args)
 683          = do (push, arg_words) <- pushAtom d p arg
 684               more_push_code <- do_pushery (d+arg_words) args
 685               return (push `appOL` more_push_code)
 686       do_pushery d []
 687          = return (unitOL (PACK con n_arg_words))
 688          where
 689            n_arg_words = d - orig_d
 690
 691
 692 -- -----------------------------------------------------------------------------
 693 -- Returning an unboxed tuple with one non-void component (the only
 694 -- case we can handle).
 695 --
 696 -- Remember, we don't want to *evaluate* the component that is being
 697 -- returned, even if it is a pointed type.  We always just return.
 698
 699 unboxedTupleReturn
 700         :: Int -> Sequel -> BCEnv
 701         -> AnnExpr' Id VarSet -> BcM BCInstrList
 702 unboxedTupleReturn d s p arg = do
 703   (push, sz) <- pushAtom d p arg
 704   return (push `appOL`
 705             mkSLIDE sz (d-s) `snocOL`
 706             RETURN_UBX (atomRep arg))
 707
 708 -- -----------------------------------------------------------------------------
 709 -- Generate code for a tail-call
 710
 711 doTailCall
 712         :: Int -> Sequel -> BCEnv
 713         -> Id -> [AnnExpr' Id VarSet]
 714         -> BcM BCInstrList
 715 doTailCall init_d s p fn args
 716   = do_pushes init_d args (map atomRep args)
 717   where
 718   do_pushes d [] reps = do
 719         ASSERT( null reps ) return ()
 720         (push_fn, sz) <- pushAtom d p (AnnVar fn)
 721         ASSERT( sz == 1 ) return ()
 722         return (push_fn `appOL` (
 723                   mkSLIDE ((d-init_d) + 1) (init_d - s) `appOL`
 724                   unitOL ENTER))
 725   do_pushes d args reps = do
 726       let (push_apply, n, rest_of_reps) = findPushSeq reps
 727           (these_args, rest_of_args) = splitAt n args
 728       (next_d, push_code) <- push_seq d these_args
 729       instrs <- do_pushes (next_d + 1) rest_of_args rest_of_reps
 730                 --                ^^^ for the PUSH_APPLY_ instruction
 731       return (push_code `appOL` (push_apply `consOL` instrs))
 732
 733   push_seq d [] = return (d, nilOL)
 734   push_seq d (arg:args) = do
 735     (push_code, sz) <- pushAtom d p arg
 736     (final_d, more_push_code) <- push_seq (d+sz) args
 737     return (final_d, push_code `appOL` more_push_code)
 738
 739 -- v. similar to CgStackery.findMatch, ToDo: merge
 740 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: rest)
 741   = (PUSH_APPLY_PPPPPP, 6, rest)
 742 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: rest)
 743   = (PUSH_APPLY_PPPPP, 5, rest)
 744 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: rest)
 745   = (PUSH_APPLY_PPPP, 4, rest)
 746 findPushSeq (PtrArg: PtrArg: PtrArg: rest)
 747   = (PUSH_APPLY_PPP, 3, rest)
 748 findPushSeq (PtrArg: PtrArg: rest)
 749   = (PUSH_APPLY_PP, 2, rest)
 750 findPushSeq (PtrArg: rest)
 751   = (PUSH_APPLY_P, 1, rest)
 752 findPushSeq (VoidArg: rest)
 753   = (PUSH_APPLY_V, 1, rest)
 754 findPushSeq (NonPtrArg: rest)
 755   = (PUSH_APPLY_N, 1, rest)
 756 findPushSeq (FloatArg: rest)
 757   = (PUSH_APPLY_F, 1, rest)
 758 findPushSeq (DoubleArg: rest)
 759   = (PUSH_APPLY_D, 1, rest)
 760 findPushSeq (LongArg: rest)
 761   = (PUSH_APPLY_L, 1, rest)
 762 findPushSeq _
 763   = panic "ByteCodeGen.findPushSeq"
 764
 765 -- -----------------------------------------------------------------------------
 766 -- Case expressions
 767
 768 doCase  :: Int -> Sequel -> BCEnv
 769         -> AnnExpr Id VarSet -> Id -> [AnnAlt Id VarSet]
 770         -> Bool  -- True <=> is an unboxed tuple case, don't enter the result
 771         -> BcM BCInstrList
 772 doCase d s p (_,scrut) bndr alts is_unboxed_tuple
 773   = let
 774         -- Top of stack is the return itbl, as usual.
 775         -- underneath it is the pointer to the alt_code BCO.
 776         -- When an alt is entered, it assumes the returned value is
 777         -- on top of the itbl.
 778         ret_frame_sizeW = 2
 779
 780         -- An unlifted value gets an extra info table pushed on top
 781         -- when it is returned.
 782         unlifted_itbl_sizeW | isAlgCase = 0
 783                             | otherwise = 1
 784
 785         -- depth of stack after the return value has been pushed
 786         d_bndr = d + ret_frame_sizeW + idSizeW bndr
 787
 788         -- depth of stack after the extra info table for an unboxed return
 789         -- has been pushed, if any.  This is the stack depth at the
 790         -- continuation.
 791         d_alts = d_bndr + unlifted_itbl_sizeW
 792
 793         -- Env in which to compile the alts, not including
 794         -- any vars bound by the alts themselves
 795         p_alts = addToFM p bndr (d_bndr - 1)
 796
 797         bndr_ty = idType bndr
 798         isAlgCase = not (isUnLiftedType bndr_ty) && not is_unboxed_tuple
 799
 800         -- given an alt, return a discr and code for it.
 801         codeAlt alt@(DEFAULT, _, (_,rhs))
 802            = do rhs_code <- schemeE d_alts s p_alts rhs
 803                 return (NoDiscr, rhs_code)
 804
 805         codeAlt alt@(discr, bndrs, (_,rhs))
 806            -- primitive or nullary constructor alt: no need to UNPACK
 807            | null real_bndrs = do
 808                 rhs_code <- schemeE d_alts s p_alts rhs
 809                 return (my_discr alt, rhs_code)
 810            -- algebraic alt with some binders
 811            | ASSERT(isAlgCase) otherwise =
 812              let
 813                  (ptrs,nptrs) = partition (isFollowableArg.idCgRep) real_bndrs
 814                  ptr_sizes    = map idSizeW ptrs
 815                  nptrs_sizes  = map idSizeW nptrs
 816                  bind_sizes   = ptr_sizes ++ nptrs_sizes
 817                  size         = sum ptr_sizes + sum nptrs_sizes
 818                  -- the UNPACK instruction unpacks in reverse order...
 819                  p' = addListToFM p_alts
 820                         (zip (reverse (ptrs ++ nptrs))
 821                           (mkStackOffsets d_alts (reverse bind_sizes)))
 822              in do
 823              rhs_code <- schemeE (d_alts+size) s p' rhs
 824              return (my_discr alt, unitOL (UNPACK size) `appOL` rhs_code)
 825            where
 826              real_bndrs = filter (not.isTyVar) bndrs
 827
 828         my_discr (DEFAULT, binds, rhs) = NoDiscr {-shouldn't really happen-}
 829         my_discr (DataAlt dc, binds, rhs)
 830            | isUnboxedTupleCon dc
 831            = unboxedTupleException
 832            | otherwise
 833            = DiscrP (dataConTag dc - fIRST_TAG)
 834         my_discr (LitAlt l, binds, rhs)
 835            = case l of MachInt i     -> DiscrI (fromInteger i)
 836                        MachFloat r   -> DiscrF (fromRational r)
 837                        MachDouble r  -> DiscrD (fromRational r)
 838                        MachChar i    -> DiscrI (ord i)
 839                        _ -> pprPanic "schemeE(AnnCase).my_discr" (ppr l)
 840
 841         maybe_ncons
 842            | not isAlgCase = Nothing
 843            | otherwise
 844            = case [dc | (DataAlt dc, _, _) <- alts] of
 845                 []     -> Nothing
 846                 (dc:_) -> Just (tyConFamilySize (dataConTyCon dc))
 847
 848         -- the bitmap is relative to stack depth d, i.e. before the
 849         -- BCO, info table and return value are pushed on.
 850         -- This bit of code is v. similar to buildLivenessMask in CgBindery,
 851         -- except that here we build the bitmap from the known bindings of
 852         -- things that are pointers, whereas in CgBindery the code builds the
 853         -- bitmap from the free slots and unboxed bindings.
 854         -- (ToDo: merge?)
 855         --
 856         -- NOTE [7/12/2006] bug #1013, testcase ghci/should_run/ghci002.
 857         -- The bitmap must cover the portion of the stack up to the sequel only.
 858         -- Previously we were building a bitmap for the whole depth (d), but we
 859         -- really want a bitmap up to depth (d-s).  This affects compilation of
 860         -- case-of-case expressions, which is the only time we can be compiling a
 861         -- case expression with s /= 0.
 862         bitmap_size = d-s
 863         bitmap = intsToReverseBitmap bitmap_size{-size-}
 864                         (sortLe (<=) (filter (< bitmap_size) rel_slots))
 865           where
 866           binds = fmToList p
 867           rel_slots = concat (map spread binds)
 868           spread (id, offset)
 869                 | isFollowableArg (idCgRep id) = [ rel_offset ]
 870                 | otherwise = []
 871                 where rel_offset = d - offset - 1
 872
 873      in do
 874      alt_stuff <- mapM codeAlt alts
 875      alt_final <- mkMultiBranch maybe_ncons alt_stuff
 876
 877      let
 878          alt_bco_name = getName bndr
 879          alt_bco = mkProtoBCO alt_bco_name alt_final (Left alts)
 880                         0{-no arity-} bitmap_size bitmap True{-is alts-}
 881      -- in
 882 --     trace ("case: bndr = " ++ showSDocDebug (ppr bndr) ++ "\ndepth = " ++ show d ++ "\nenv = \n" ++ showSDocDebug (ppBCEnv p) ++
 883 --           "\n      bitmap = " ++ show bitmap) $ do
 884      scrut_code <- schemeE (d + ret_frame_sizeW) (d + ret_frame_sizeW) p scrut
 885      alt_bco' <- emitBc alt_bco
 886      let push_alts
 887             | isAlgCase = PUSH_ALTS alt_bco'
 888             | otherwise = PUSH_ALTS_UNLIFTED alt_bco' (typeCgRep bndr_ty)
 889      return (push_alts `consOL` scrut_code)
 890
 891
 892 -- -----------------------------------------------------------------------------
 893 -- Deal with a CCall.
 894
 895 -- Taggedly push the args onto the stack R->L,
 896 -- deferencing ForeignObj#s and adjusting addrs to point to
 897 -- payloads in Ptr/Byte arrays.  Then, generate the marshalling
 898 -- (machine) code for the ccall, and create bytecodes to call that and
 899 -- then return in the right way.
 900
 901 generateCCall :: Int -> Sequel          -- stack and sequel depths
 902               -> BCEnv
 903               -> CCallSpec              -- where to call
 904               -> Id                     -- of target, for type info
 905               -> [AnnExpr' Id VarSet]   -- args (atoms)
 906               -> BcM BCInstrList
 907
 908 generateCCall d0 s p ccall_spec@(CCallSpec target cconv safety) fn args_r_to_l
 909    = let
 910          -- useful constants
 911          addr_sizeW = cgRepSizeW NonPtrArg
 912
 913          -- Get the args on the stack, with tags and suitably
 914          -- dereferenced for the CCall.  For each arg, return the
 915          -- depth to the first word of the bits for that arg, and the
 916          -- CgRep of what was actually pushed.
 917
 918          pargs d [] = return []
 919          pargs d (a:az)
 920             = let arg_ty = repType (exprType (deAnnotate' a))
 921
 922               in case splitTyConApp_maybe arg_ty of
 923                     -- Don't push the FO; instead push the Addr# it
 924                     -- contains.
 925                     Just (t, _)
 926                      | t == arrayPrimTyCon || t == mutableArrayPrimTyCon
 927                        -> do rest <- pargs (d + addr_sizeW) az
 928                              code <- parg_ArrayishRep arrPtrsHdrSize d p a
 929                              return ((code,NonPtrArg):rest)
 930
 931                      | t == byteArrayPrimTyCon || t == mutableByteArrayPrimTyCon
 932                        -> do rest <- pargs (d + addr_sizeW) az
 933                              code <- parg_ArrayishRep arrWordsHdrSize d p a
 934                              return ((code,NonPtrArg):rest)
 935
 936                     -- Default case: push taggedly, but otherwise intact.
 937                     other
 938                        -> do (code_a, sz_a) <- pushAtom d p a
 939                              rest <- pargs (d+sz_a) az
 940                              return ((code_a, atomRep a) : rest)
 941
 942          -- Do magic for Ptr/Byte arrays.  Push a ptr to the array on
 943          -- the stack but then advance it over the headers, so as to
 944          -- point to the payload.
 945          parg_ArrayishRep hdrSize d p a
 946             = do (push_fo, _) <- pushAtom d p a
 947                  -- The ptr points at the header.  Advance it over the
 948                  -- header and then pretend this is an Addr#.
 949                  return (push_fo `snocOL` SWIZZLE 0 hdrSize)
 950
 951      in do
 952      code_n_reps <- pargs d0 args_r_to_l
 953      let
 954          (pushs_arg, a_reps_pushed_r_to_l) = unzip code_n_reps
 955
 956          push_args    = concatOL pushs_arg
 957          d_after_args = d0 + sum (map cgRepSizeW a_reps_pushed_r_to_l)
 958          a_reps_pushed_RAW
 959             | null a_reps_pushed_r_to_l || head a_reps_pushed_r_to_l /= VoidArg
 960             = panic "ByteCodeGen.generateCCall: missing or invalid World token?"
 961             | otherwise
 962             = reverse (tail a_reps_pushed_r_to_l)
 963
 964          -- Now: a_reps_pushed_RAW are the reps which are actually on the stack.
 965          -- push_args is the code to do that.
 966          -- d_after_args is the stack depth once the args are on.
 967
 968          -- Get the result rep.
 969          (returns_void, r_rep)
 970             = case maybe_getCCallReturnRep (idType fn) of
 971                  Nothing -> (True,  VoidArg)
 972                  Just rr -> (False, rr)
 973          {-
 974          Because the Haskell stack grows down, the a_reps refer to
 975          lowest to highest addresses in that order.  The args for the call
 976          are on the stack.  Now push an unboxed Addr# indicating
 977          the C function to call.  Then push a dummy placeholder for the
 978          result.  Finally, emit a CCALL insn with an offset pointing to the
 979          Addr# just pushed, and a literal field holding the mallocville
 980          address of the piece of marshalling code we generate.
 981          So, just prior to the CCALL insn, the stack looks like this
 982          (growing down, as usual):
 983
 984             <arg_n>
 985             ...
 986             <arg_1>
 987             Addr# address_of_C_fn
 988             <placeholder-for-result#> (must be an unboxed type)
 989
 990          The interpreter then calls the marshall code mentioned
 991          in the CCALL insn, passing it (& <placeholder-for-result#>),
 992          that is, the addr of the topmost word in the stack.
 993          When this returns, the placeholder will have been
 994          filled in.  The placeholder is slid down to the sequel
 995          depth, and we RETURN.
 996
 997          This arrangement makes it simple to do f-i-dynamic since the Addr#
 998          value is the first arg anyway.
 999
1000          The marshalling code is generated specifically for this
1001          call site, and so knows exactly the (Haskell) stack
1002          offsets of the args, fn address and placeholder.  It
1003          copies the args to the C stack, calls the stacked addr,
1004          and parks the result back in the placeholder.  The interpreter
1005          calls it as a normal C call, assuming it has a signature
1006             void marshall_code ( StgWord* ptr_to_top_of_stack )
1007          -}
1008          -- resolve static address
1009          get_target_info
1010             = case target of
1011                  DynamicTarget
1012                     -> return (False, panic "ByteCodeGen.generateCCall(dyn)")
1013                  StaticTarget target
1014                     -> do res <- ioToBc (lookupStaticPtr target)
1015                           return (True, res)
1016      -- in
1017      (is_static, static_target_addr) <- get_target_info
1018      let
1019
1020          -- Get the arg reps, zapping the leading Addr# in the dynamic case
1021          a_reps --  | trace (showSDoc (ppr a_reps_pushed_RAW)) False = error "???"
1022                 | is_static = a_reps_pushed_RAW
1023                 | otherwise = if null a_reps_pushed_RAW
1024                               then panic "ByteCodeGen.generateCCall: dyn with no args"
1025                               else tail a_reps_pushed_RAW
1026
1027          -- push the Addr#
1028          (push_Addr, d_after_Addr)
1029             | is_static
1030             = (toOL [PUSH_UBX (Right static_target_addr) addr_sizeW],
1031                d_after_args + addr_sizeW)
1032             | otherwise -- is already on the stack
1033             = (nilOL, d_after_args)
1034
1035          -- Push the return placeholder.  For a call returning nothing,
1036          -- this is a VoidArg (tag).
1037          r_sizeW   = cgRepSizeW r_rep
1038          d_after_r = d_after_Addr + r_sizeW
1039          r_lit     = mkDummyLiteral r_rep
1040          push_r    = (if   returns_void
1041                       then nilOL
1042                       else unitOL (PUSH_UBX (Left r_lit) r_sizeW))
1043
1044          -- generate the marshalling code we're going to call
1045          r_offW       = 0
1046          addr_offW    = r_sizeW
1047          arg1_offW    = r_sizeW + addr_sizeW
1048          args_offW    = map (arg1_offW +)
1049                             (init (scanl (+) 0 (map cgRepSizeW a_reps)))
1050      -- in
1051      addr_of_marshaller <- ioToBc (mkMarshalCode cconv
1052                                 (r_offW, r_rep) addr_offW
1053                                 (zip args_offW a_reps))
1054      recordItblMallocBc (ItblPtr (castFunPtrToPtr addr_of_marshaller))
1055      let
1056          -- Offset of the next stack frame down the stack.  The CCALL
1057          -- instruction needs to describe the chunk of stack containing
1058          -- the ccall args to the GC, so it needs to know how large it
1059          -- is.  See comment in Interpreter.c with the CCALL instruction.
1060          stk_offset   = d_after_r - s
1061
1062          -- do the call
1063          do_call      = unitOL (CCALL stk_offset (castFunPtrToPtr addr_of_marshaller))
1064          -- slide and return
1065          wrapup       = mkSLIDE r_sizeW (d_after_r - r_sizeW - s)
1066                         `snocOL` RETURN_UBX r_rep
1067      --in
1068          --trace (show (arg1_offW, args_offW  ,  (map cgRepSizeW a_reps) )) $
1069      return (
1070          push_args `appOL`
1071          push_Addr `appOL` push_r `appOL` do_call `appOL` wrapup
1072          )
1073
1074
1075 -- Make a dummy literal, to be used as a placeholder for FFI return
1076 -- values on the stack.
1077 mkDummyLiteral :: CgRep -> Literal
1078 mkDummyLiteral pr
1079    = case pr of
1080         NonPtrArg -> MachWord 0
1081         DoubleArg -> MachDouble 0
1082         FloatArg  -> MachFloat 0
1083         LongArg   -> MachWord64 0
1084         _         -> moan64 "mkDummyLiteral" (ppr pr)
1085
1086
1087 -- Convert (eg)
1088 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
1089 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld, GHC.Prim.Int# #)
1090 --
1091 -- to  Just IntRep
1092 -- and check that an unboxed pair is returned wherein the first arg is VoidArg'd.
1093 --
1094 -- Alternatively, for call-targets returning nothing, convert
1095 --
1096 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
1097 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld #)
1098 --
1099 -- to  Nothing
1100
1101 maybe_getCCallReturnRep :: Type -> Maybe CgRep
1102 maybe_getCCallReturnRep fn_ty
1103    = let (a_tys, r_ty) = splitFunTys (dropForAlls fn_ty)
1104          maybe_r_rep_to_go
1105             = if isSingleton r_reps then Nothing else Just (r_reps !! 1)
1106          (r_tycon, r_reps)
1107             = case splitTyConApp_maybe (repType r_ty) of
1108                       (Just (tyc, tys)) -> (tyc, map typeCgRep tys)
1109                       Nothing -> blargh
1110          ok = ( ( r_reps `lengthIs` 2 && VoidArg == head r_reps)
1111                 || r_reps == [VoidArg] )
1112               && isUnboxedTupleTyCon r_tycon
1113               && case maybe_r_rep_to_go of
1114                     Nothing    -> True
1115                     Just r_rep -> r_rep /= PtrArg
1116                                   -- if it was, it would be impossible
1117                                   -- to create a valid return value
1118                                   -- placeholder on the stack
1119          blargh = pprPanic "maybe_getCCallReturn: can't handle:"
1120                            (pprType fn_ty)
1121      in
1122      --trace (showSDoc (ppr (a_reps, r_reps))) $
1123      if ok then maybe_r_rep_to_go else blargh
1124
1125 -- Compile code which expects an unboxed Int on the top of stack,
1126 -- (call it i), and pushes the i'th closure in the supplied list
1127 -- as a consequence.
1128 implement_tagToId :: [Name] -> BcM BCInstrList
1129 implement_tagToId names
1130    = ASSERT( notNull names )
1131      do labels <- getLabelsBc (length names)
1132         label_fail <- getLabelBc
1133         label_exit <- getLabelBc
1134         let infos = zip4 labels (tail labels ++ [label_fail])
1135                                 [0 ..] names
1136             steps = map (mkStep label_exit) infos
1137         return (concatOL steps
1138                   `appOL`
1139                   toOL [LABEL label_fail, CASEFAIL, LABEL label_exit])
1140      where
1141         mkStep l_exit (my_label, next_label, n, name_for_n)
1142            = toOL [LABEL my_label,
1143                    TESTEQ_I n next_label,
1144                    PUSH_G name_for_n,
1145                    JMP l_exit]
1146
1147
1148 -- -----------------------------------------------------------------------------
1149 -- pushAtom
1150
1151 -- Push an atom onto the stack, returning suitable code & number of
1152 -- stack words used.
1153 --
1154 -- The env p must map each variable to the highest- numbered stack
1155 -- slot for it.  For example, if the stack has depth 4 and we
1156 -- tagged-ly push (v :: Int#) on it, the value will be in stack[4],
1157 -- the tag in stack[5], the stack will have depth 6, and p must map v
1158 -- to 5 and not to 4.  Stack locations are numbered from zero, so a
1159 -- depth 6 stack has valid words 0 .. 5.
1160
1161 pushAtom :: Int -> BCEnv -> AnnExpr' Id VarSet -> BcM (BCInstrList, Int)
1162
1163 pushAtom d p (AnnApp f (_, AnnType _))
1164    = pushAtom d p (snd f)
1165
1166 pushAtom d p (AnnNote note e)
1167    = pushAtom d p (snd e)
1168
1169 pushAtom d p (AnnLam x e)
1170    | isTyVar x
1171    = pushAtom d p (snd e)
1172
1173 pushAtom d p (AnnVar v)
1174
1175    | idCgRep v == VoidArg
1176    = return (nilOL, 0)
1177
1178    | isFCallId v
1179    = pprPanic "pushAtom: shouldn't get an FCallId here" (ppr v)
1180
1181    | Just primop <- isPrimOpId_maybe v
1182    = return (unitOL (PUSH_PRIMOP primop), 1)
1183
1184    | Just d_v <- lookupBCEnv_maybe p v  -- v is a local variable
1185    = return (toOL (nOfThem sz (PUSH_L (d-d_v+sz-2))), sz)
1186          -- d - d_v                 the number of words between the TOS
1187          --                         and the 1st slot of the object
1188          --
1189          -- d - d_v - 1             the offset from the TOS of the 1st slot
1190          --
1191          -- d - d_v - 1 + sz - 1    the offset from the TOS of the last slot
1192          --                         of the object.
1193          --
1194          -- Having found the last slot, we proceed to copy the right number of
1195          -- slots on to the top of the stack.
1196
1197     | otherwise  -- v must be a global variable
1198     = ASSERT(sz == 1)
1199       return (unitOL (PUSH_G (getName v)), sz)
1200
1201     where
1202          sz = idSizeW v
1203
1204
1205 pushAtom d p (AnnLit lit)
1206    = case lit of
1207         MachLabel fs _ -> code NonPtrArg
1208         MachWord w     -> code NonPtrArg
1209         MachInt i      -> code PtrArg
1210         MachFloat r    -> code FloatArg
1211         MachDouble r   -> code DoubleArg
1212         MachChar c     -> code NonPtrArg
1213         MachStr s      -> pushStr s
1214      where
1215         code rep
1216            = let size_host_words = cgRepSizeW rep
1217              in  return (unitOL (PUSH_UBX (Left lit) size_host_words),
1218                            size_host_words)
1219
1220         pushStr s
1221            = let getMallocvilleAddr
1222                     = case s of
1223                          FastString _ n _ fp _ ->
1224                             -- we could grab the Ptr from the ForeignPtr,
1225                             -- but then we have no way to control its lifetime.
1226                             -- In reality it'll probably stay alive long enoungh
1227                             -- by virtue of the global FastString table, but
1228                             -- to be on the safe side we copy the string into
1229                             -- a malloc'd area of memory.
1230                                 do ptr <- ioToBc (mallocBytes (n+1))
1231                                    recordMallocBc ptr
1232                                    ioToBc (
1233                                       withForeignPtr fp $ \p -> do
1234                                          memcpy ptr p (fromIntegral n)
1235                                          pokeByteOff ptr n (fromIntegral (ord '\0') :: Word8)
1236                                          return ptr
1237                                       )
1238              in do
1239                 addr <- getMallocvilleAddr
1240                 -- Get the addr on the stack, untaggedly
1241                 return (unitOL (PUSH_UBX (Right addr) 1), 1)
1242
1243 pushAtom d p (AnnCast e _)
1244    = pushAtom d p (snd e)
1245
1246 pushAtom d p other
1247    = pprPanic "ByteCodeGen.pushAtom"
1248               (pprCoreExpr (deAnnotate (undefined, other)))
1249
1250 foreign import ccall unsafe "memcpy"
1251  memcpy :: Ptr a -> Ptr b -> CSize -> IO ()
1252
1253
1254 -- -----------------------------------------------------------------------------
1255 -- Given a bunch of alts code and their discrs, do the donkey work
1256 -- of making a multiway branch using a switch tree.
1257 -- What a load of hassle!
1258
1259 mkMultiBranch :: Maybe Int      --  # datacons in tycon, if alg alt
1260                                 -- a hint; generates better code
1261                                 -- Nothing is always safe
1262               -> [(Discr, BCInstrList)]
1263               -> BcM BCInstrList
1264 mkMultiBranch maybe_ncons raw_ways
1265    = let d_way     = filter (isNoDiscr.fst) raw_ways
1266          notd_ways = sortLe
1267                         (\w1 w2 -> leAlt (fst w1) (fst w2))
1268                         (filter (not.isNoDiscr.fst) raw_ways)
1269
1270          mkTree :: [(Discr, BCInstrList)] -> Discr -> Discr -> BcM BCInstrList
1271          mkTree [] range_lo range_hi = return the_default
1272
1273          mkTree [val] range_lo range_hi
1274             | range_lo `eqAlt` range_hi
1275             = return (snd val)
1276             | otherwise
1277             = do label_neq <- getLabelBc
1278                  return (mkTestEQ (fst val) label_neq
1279                           `consOL` (snd val
1280                           `appOL`   unitOL (LABEL label_neq)
1281                           `appOL`   the_default))
1282
1283          mkTree vals range_lo range_hi
1284             = let n = length vals `div` 2
1285                   vals_lo = take n vals
1286                   vals_hi = drop n vals
1287                   v_mid = fst (head vals_hi)
1288               in do
1289               label_geq <- getLabelBc
1290               code_lo <- mkTree vals_lo range_lo (dec v_mid)
1291               code_hi <- mkTree vals_hi v_mid range_hi
1292               return (mkTestLT v_mid label_geq
1293                         `consOL` (code_lo
1294                         `appOL`   unitOL (LABEL label_geq)
1295                         `appOL`   code_hi))
1296
1297          the_default
1298             = case d_way of [] -> unitOL CASEFAIL
1299                             [(_, def)] -> def
1300
1301          -- None of these will be needed if there are no non-default alts
1302          (mkTestLT, mkTestEQ, init_lo, init_hi)
1303             | null notd_ways
1304             = panic "mkMultiBranch: awesome foursome"
1305             | otherwise
1306             = case fst (head notd_ways) of {
1307               DiscrI _ -> ( \(DiscrI i) fail_label -> TESTLT_I i fail_label,
1308                             \(DiscrI i) fail_label -> TESTEQ_I i fail_label,
1309                             DiscrI minBound,
1310                             DiscrI maxBound );
1311               DiscrF _ -> ( \(DiscrF f) fail_label -> TESTLT_F f fail_label,
1312                             \(DiscrF f) fail_label -> TESTEQ_F f fail_label,
1313                             DiscrF minF,
1314                             DiscrF maxF );
1315               DiscrD _ -> ( \(DiscrD d) fail_label -> TESTLT_D d fail_label,
1316                             \(DiscrD d) fail_label -> TESTEQ_D d fail_label,
1317                             DiscrD minD,
1318                             DiscrD maxD );
1319               DiscrP _ -> ( \(DiscrP i) fail_label -> TESTLT_P i fail_label,
1320                             \(DiscrP i) fail_label -> TESTEQ_P i fail_label,
1321                             DiscrP algMinBound,
1322                             DiscrP algMaxBound )
1323               }
1324
1325          (algMinBound, algMaxBound)
1326             = case maybe_ncons of
1327                  Just n  -> (0, n - 1)
1328                  Nothing -> (minBound, maxBound)
1329
1330          (DiscrI i1) `eqAlt` (DiscrI i2) = i1 == i2
1331          (DiscrF f1) `eqAlt` (DiscrF f2) = f1 == f2
1332          (DiscrD d1) `eqAlt` (DiscrD d2) = d1 == d2
1333          (DiscrP i1) `eqAlt` (DiscrP i2) = i1 == i2
1334          NoDiscr     `eqAlt` NoDiscr     = True
1335          _           `eqAlt` _           = False
1336
1337          (DiscrI i1) `leAlt` (DiscrI i2) = i1 <= i2
1338          (DiscrF f1) `leAlt` (DiscrF f2) = f1 <= f2
1339          (DiscrD d1) `leAlt` (DiscrD d2) = d1 <= d2
1340          (DiscrP i1) `leAlt` (DiscrP i2) = i1 <= i2
1341          NoDiscr     `leAlt` NoDiscr     = True
1342          _           `leAlt` _           = False
1343
1344          isNoDiscr NoDiscr = True
1345          isNoDiscr _       = False
1346
1347          dec (DiscrI i) = DiscrI (i-1)
1348          dec (DiscrP i) = DiscrP (i-1)
1349          dec other      = other         -- not really right, but if you
1350                 -- do cases on floating values, you'll get what you deserve
1351
1352          -- same snotty comment applies to the following
1353          minF, maxF :: Float
1354          minD, maxD :: Double
1355          minF = -1.0e37
1356          maxF =  1.0e37
1357          minD = -1.0e308
1358          maxD =  1.0e308
1359      in
1360          mkTree notd_ways init_lo init_hi
1361
1362
1363 -- -----------------------------------------------------------------------------
1364 -- Supporting junk for the compilation schemes
1365
1366 -- Describes case alts
1367 data Discr
1368    = DiscrI Int
1369    | DiscrF Float
1370    | DiscrD Double
1371    | DiscrP Int
1372    | NoDiscr
1373
1374 instance Outputable Discr where
1375    ppr (DiscrI i) = int i
1376    ppr (DiscrF f) = text (show f)
1377    ppr (DiscrD d) = text (show d)
1378    ppr (DiscrP i) = int i
1379    ppr NoDiscr    = text "DEF"
1380
1381
1382 lookupBCEnv_maybe :: BCEnv -> Id -> Maybe Int
1383 lookupBCEnv_maybe = lookupFM
1384
1385 idSizeW :: Id -> Int
1386 idSizeW id = cgRepSizeW (typeCgRep (idType id))
1387
1388 -- See bug #1257
1389 unboxedTupleException :: a
1390 unboxedTupleException
1391    = throwDyn
1392         (ProgramError
1393            ("Error: bytecode compiler can't handle unboxed tuples.\n"++
1394             "  Possibly due to foreign import/export decls in source.\n"++
1395             "  Workaround: use -fobject-code, or compile this module to .o separately."))
1396
1397
1398 mkSLIDE n d = if d == 0 then nilOL else unitOL (SLIDE n d)
1399 bind x f    = f x
1400
1401 splitApp :: AnnExpr' id ann -> (AnnExpr' id ann, [AnnExpr' id ann])
1402         -- The arguments are returned in *right-to-left* order
1403 splitApp (AnnApp (_,f) (_,a))
1404                | isTypeAtom a = splitApp f
1405                | otherwise    = case splitApp f of
1406                                      (f', as) -> (f', a:as)
1407 splitApp (AnnNote n (_,e))    = splitApp e
1408 splitApp (AnnCast (_,e) _)    = splitApp e
1409 splitApp e                    = (e, [])
1410
1411
1412 isTypeAtom :: AnnExpr' id ann -> Bool
1413 isTypeAtom (AnnType _) = True
1414 isTypeAtom _           = False
1415
1416 isVoidArgAtom :: AnnExpr' id ann -> Bool
1417 isVoidArgAtom (AnnVar v)        = typeCgRep (idType v) == VoidArg
1418 isVoidArgAtom (AnnNote n (_,e)) = isVoidArgAtom e
1419 isVoidArgAtom (AnnCast (_,e) _) = isVoidArgAtom e
1420 isVoidArgAtom _                 = False
1421
1422 atomRep :: AnnExpr' Id ann -> CgRep
1423 atomRep (AnnVar v)    = typeCgRep (idType v)
1424 atomRep (AnnLit l)    = typeCgRep (literalType l)
1425 atomRep (AnnNote n b) = atomRep (snd b)
1426 atomRep (AnnApp f (_, AnnType _)) = atomRep (snd f)
1427 atomRep (AnnLam x e) | isTyVar x = atomRep (snd e)
1428 atomRep (AnnCast b _) = atomRep (snd b)
1429 atomRep other = pprPanic "atomRep" (ppr (deAnnotate (undefined,other)))
1430
1431 isPtrAtom :: AnnExpr' Id ann -> Bool
1432 isPtrAtom e = atomRep e == PtrArg
1433
1434 -- Let szsw be the sizes in words of some items pushed onto the stack,
1435 -- which has initial depth d'.  Return the values which the stack environment
1436 -- should map these items to.
1437 mkStackOffsets :: Int -> [Int] -> [Int]
1438 mkStackOffsets original_depth szsw
1439    = map (subtract 1) (tail (scanl (+) original_depth szsw))
1440
1441 -- -----------------------------------------------------------------------------
1442 -- The bytecode generator's monad
1443
1444 type BcPtr = Either ItblPtr (Ptr ())
1445
1446 data BcM_State
1447    = BcM_State {
1448         uniqSupply :: UniqSupply,       -- for generating fresh variable names
1449         nextlabel :: Int,               -- for generating local labels
1450         malloced  :: [BcPtr],           -- thunks malloced for current BCO
1451                                         -- Should be free()d when it is GCd
1452         breakArray :: BreakArray        -- array of breakpoint flags
1453         }
1454
1455 newtype BcM r = BcM (BcM_State -> IO (BcM_State, r))
1456
1457 ioToBc :: IO a -> BcM a
1458 ioToBc io = BcM $ \st -> do
1459   x <- io
1460   return (st, x)
1461
1462 runBc :: UniqSupply -> ModBreaks -> BcM r -> IO (BcM_State, r)
1463 runBc us modBreaks (BcM m)
1464    = m (BcM_State us 0 [] breakArray)
1465    where
1466    breakArray = modBreaks_flags modBreaks
1467
1468 thenBc :: BcM a -> (a -> BcM b) -> BcM b
1469 thenBc (BcM expr) cont = BcM $ \st0 -> do
1470   (st1, q) <- expr st0
1471   let BcM k = cont q
1472   (st2, r) <- k st1
1473   return (st2, r)
1474
1475 thenBc_ :: BcM a -> BcM b -> BcM b
1476 thenBc_ (BcM expr) (BcM cont) = BcM $ \st0 -> do
1477   (st1, q) <- expr st0
1478   (st2, r) <- cont st1
1479   return (st2, r)
1480
1481 returnBc :: a -> BcM a
1482 returnBc result = BcM $ \st -> (return (st, result))
1483
1484 instance Monad BcM where
1485   (>>=) = thenBc
1486   (>>)  = thenBc_
1487   return = returnBc
1488
1489 emitBc :: ([BcPtr] -> ProtoBCO Name) -> BcM (ProtoBCO Name)
1490 emitBc bco
1491   = BcM $ \st -> return (st{malloced=[]}, bco (malloced st))
1492
1493 recordMallocBc :: Ptr a -> BcM ()
1494 recordMallocBc a
1495   = BcM $ \st -> return (st{malloced = Right (castPtr a) : malloced st}, ())
1496
1497 recordItblMallocBc :: ItblPtr -> BcM ()
1498 recordItblMallocBc a
1499   = BcM $ \st -> return (st{malloced = Left a : malloced st}, ())
1500
1501 getLabelBc :: BcM Int
1502 getLabelBc
1503   = BcM $ \st -> return (st{nextlabel = 1 + nextlabel st}, nextlabel st)
1504
1505 getLabelsBc :: Int -> BcM [Int]
1506 getLabelsBc n
1507   = BcM $ \st -> let ctr = nextlabel st
1508                  in return (st{nextlabel = ctr+n}, [ctr .. ctr+n-1])
1509
1510 getBreakArray :: BcM BreakArray
1511 getBreakArray = BcM $ \st -> return (st, breakArray st)
1512
1513 newUnique :: BcM Unique
1514 newUnique = BcM $
1515    \st -> case splitUniqSupply (uniqSupply st) of
1516              (us1, us2) -> let newState = st { uniqSupply = us2 }
1517                            in  return (newState, uniqFromSupply us1)
1518
1519 newId :: Type -> BcM Id
1520 newId ty = do
1521     uniq <- newUnique
1522     return $ mkSysLocal FSLIT("ticked") uniq ty
1523 \end{code}