compiler/ghci/ByteCodeGen.lhs

   1 %
   2 % (c) The University of Glasgow 2002
   3 %
   4 \section[ByteCodeGen]{Generate bytecode from Core}
   5
   6 \begin{code}
   7 module ByteCodeGen ( UnlinkedBCO, byteCodeGen, coreExprToBCOs ) where
   8
   9 #include "HsVersions.h"
  10
  11 import ByteCodeInstr
  12 import ByteCodeFFI      ( mkMarshalCode, moan64 )
  13 import ByteCodeAsm      ( CompiledByteCode(..), UnlinkedBCO,
  14                           assembleBCO, assembleBCOs, iNTERP_STACK_CHECK_THRESH )
  15 import ByteCodeLink     ( lookupStaticPtr )
  16
  17 import Outputable
  18 import Name             ( Name, getName, mkSystemVarName )
  19 import Id
  20 import FiniteMap
  21 import ForeignCall      ( ForeignCall(..), CCallTarget(..), CCallSpec(..) )
  22 import HscTypes         ( TypeEnv, typeEnvTyCons, typeEnvClasses )
  23 import CoreUtils        ( exprType )
  24 import CoreSyn
  25 import PprCore          ( pprCoreExpr )
  26 import Literal          ( Literal(..), literalType )
  27 import PrimOp           ( PrimOp(..) )
  28 import CoreFVs          ( freeVars )
  29 import Type             ( isUnLiftedType, splitTyConApp_maybe )
  30 import DataCon          ( DataCon, dataConTag, fIRST_TAG, dataConTyCon,
  31                           isUnboxedTupleCon, isNullaryRepDataCon, dataConWorkId,
  32                           dataConRepArity )
  33 import TyCon            ( TyCon, tyConFamilySize, isDataTyCon,
  34                           tyConDataCons, isUnboxedTupleTyCon )
  35 import Class            ( Class, classTyCon )
  36 import Type             ( Type, repType, splitFunTys, dropForAlls, pprType )
  37 import Util
  38 import DataCon          ( dataConRepArity )
  39 import Var              ( isTyVar )
  40 import VarSet           ( VarSet, varSetElems )
  41 import TysPrim          ( arrayPrimTyCon, mutableArrayPrimTyCon,
  42                           byteArrayPrimTyCon, mutableByteArrayPrimTyCon
  43                         )
  44 import DynFlags ( DynFlags, DynFlag(..) )
  45 import ErrUtils         ( showPass, dumpIfSet_dyn )
  46 import Unique           ( mkPseudoUniqueE )
  47 import FastString       ( FastString(..), unpackFS )
  48 import Panic            ( GhcException(..) )
  49 import SMRep            ( typeCgRep, arrWordsHdrSize, arrPtrsHdrSize, StgWord,
  50                           CgRep(..), cgRepSizeW, isFollowableArg, idCgRep )
  51 import Bitmap           ( intsToReverseBitmap, mkBitmap )
  52 import OrdList
  53 import Constants        ( wORD_SIZE )
  54
  55 import Data.List        ( intersperse, sortBy, zip4, zip6, partition )
  56 import Foreign          ( Ptr, castPtr, mallocBytes, pokeByteOff, Word8,
  57                           withForeignPtr )
  58 import Foreign.C        ( CInt )
  59 import Control.Exception        ( throwDyn )
  60
  61 import GHC.Exts         ( Int(..), ByteArray# )
  62
  63 import Control.Monad    ( when )
  64 import Data.Char        ( ord, chr )
  65
  66 -- -----------------------------------------------------------------------------
  67 -- Generating byte code for a complete module
  68
  69 byteCodeGen :: DynFlags
  70             -> [CoreBind]
  71             -> [TyCon]
  72             -> IO CompiledByteCode
  73 byteCodeGen dflags binds tycs
  74    = do showPass dflags "ByteCodeGen"
  75
  76         let flatBinds = [ (bndr, freeVars rhs)
  77                         | (bndr, rhs) <- flattenBinds binds]
  78
  79         (BcM_State final_ctr mallocd, proto_bcos)
  80            <- runBc (mapM schemeTopBind flatBinds)
  81
  82         when (notNull mallocd)
  83              (panic "ByteCodeGen.byteCodeGen: missing final emitBc?")
  84
  85         dumpIfSet_dyn dflags Opt_D_dump_BCOs
  86            "Proto-BCOs" (vcat (intersperse (char ' ') (map ppr proto_bcos)))
  87
  88         assembleBCOs proto_bcos tycs
  89
  90 -- -----------------------------------------------------------------------------
  91 -- Generating byte code for an expression
  92
  93 -- Returns: (the root BCO for this expression,
  94 --           a list of auxilary BCOs resulting from compiling closures)
  95 coreExprToBCOs :: DynFlags
  96                -> CoreExpr
  97                -> IO UnlinkedBCO
  98 coreExprToBCOs dflags expr
  99  = do showPass dflags "ByteCodeGen"
 100
 101       -- create a totally bogus name for the top-level BCO; this
 102       -- should be harmless, since it's never used for anything
 103       let invented_name  = mkSystemVarName (mkPseudoUniqueE 0) FSLIT("ExprTopLevel")
 104           invented_id    = mkLocalId invented_name (panic "invented_id's type")
 105
 106       (BcM_State final_ctr mallocd, proto_bco)
 107          <- runBc (schemeTopBind (invented_id, freeVars expr))
 108
 109       when (notNull mallocd)
 110            (panic "ByteCodeGen.coreExprToBCOs: missing final emitBc?")
 111
 112       dumpIfSet_dyn dflags Opt_D_dump_BCOs "Proto-BCOs" (ppr proto_bco)
 113
 114       assembleBCO proto_bco
 115
 116
 117 -- -----------------------------------------------------------------------------
 118 -- Compilation schema for the bytecode generator
 119
 120 type BCInstrList = OrdList BCInstr
 121
 122 type Sequel = Int       -- back off to this depth before ENTER
 123
 124 -- Maps Ids to the offset from the stack _base_ so we don't have
 125 -- to mess with it after each push/pop.
 126 type BCEnv = FiniteMap Id Int   -- To find vars on the stack
 127
 128 ppBCEnv :: BCEnv -> SDoc
 129 ppBCEnv p
 130    = text "begin-env"
 131      $$ nest 4 (vcat (map pp_one (sortBy cmp_snd (fmToList p))))
 132      $$ text "end-env"
 133      where
 134         pp_one (var, offset) = int offset <> colon <+> ppr var <+> ppr (idCgRep var)
 135         cmp_snd x y = compare (snd x) (snd y)
 136
 137 -- Create a BCO and do a spot of peephole optimisation on the insns
 138 -- at the same time.
 139 mkProtoBCO
 140    :: name
 141    -> BCInstrList
 142    -> Either  [AnnAlt Id VarSet] (AnnExpr Id VarSet)
 143    -> Int
 144    -> Int
 145    -> [StgWord]
 146    -> Bool      -- True <=> is a return point, rather than a function
 147    -> [Ptr ()]
 148    -> ProtoBCO name
 149 mkProtoBCO nm instrs_ordlist origin arity bitmap_size bitmap
 150   is_ret mallocd_blocks
 151    = ProtoBCO {
 152         protoBCOName = nm,
 153         protoBCOInstrs = maybe_with_stack_check,
 154         protoBCOBitmap = bitmap,
 155         protoBCOBitmapSize = bitmap_size,
 156         protoBCOArity = arity,
 157         protoBCOExpr = origin,
 158         protoBCOPtrs = mallocd_blocks
 159       }
 160      where
 161         -- Overestimate the stack usage (in words) of this BCO,
 162         -- and if >= iNTERP_STACK_CHECK_THRESH, add an explicit
 163         -- stack check.  (The interpreter always does a stack check
 164         -- for iNTERP_STACK_CHECK_THRESH words at the start of each
 165         -- BCO anyway, so we only need to add an explicit on in the
 166         -- (hopefully rare) cases when the (overestimated) stack use
 167         -- exceeds iNTERP_STACK_CHECK_THRESH.
 168         maybe_with_stack_check
 169            | is_ret = peep_d
 170                 -- don't do stack checks at return points;
 171                 -- everything is aggregated up to the top BCO
 172                 -- (which must be a function)
 173            | stack_overest >= 65535
 174            = pprPanic "mkProtoBCO: stack use won't fit in 16 bits"
 175                       (int stack_overest)
 176            | stack_overest >= iNTERP_STACK_CHECK_THRESH
 177            = STKCHECK stack_overest : peep_d
 178            | otherwise
 179            = peep_d     -- the supposedly common case
 180
 181         stack_overest = sum (map bciStackUse peep_d)
 182
 183         -- Merge local pushes
 184         peep_d = peep (fromOL instrs_ordlist)
 185
 186         peep (PUSH_L off1 : PUSH_L off2 : PUSH_L off3 : rest)
 187            = PUSH_LLL off1 (off2-1) (off3-2) : peep rest
 188         peep (PUSH_L off1 : PUSH_L off2 : rest)
 189            = PUSH_LL off1 (off2-1) : peep rest
 190         peep (i:rest)
 191            = i : peep rest
 192         peep []
 193            = []
 194
 195 argBits :: [CgRep] -> [Bool]
 196 argBits [] = []
 197 argBits (rep : args)
 198   | isFollowableArg rep = False : argBits args
 199   | otherwise = take (cgRepSizeW rep) (repeat True) ++ argBits args
 200
 201 -- -----------------------------------------------------------------------------
 202 -- schemeTopBind
 203
 204 -- Compile code for the right-hand side of a top-level binding
 205
 206 schemeTopBind :: (Id, AnnExpr Id VarSet) -> BcM (ProtoBCO Name)
 207
 208
 209 schemeTopBind (id, rhs)
 210   | Just data_con <- isDataConWorkId_maybe id,
 211     isNullaryRepDataCon data_con
 212   =     -- Special case for the worker of a nullary data con.
 213         -- It'll look like this:        Nil = /\a -> Nil a
 214         -- If we feed it into schemeR, we'll get
 215         --      Nil = Nil
 216         -- because mkConAppCode treats nullary constructor applications
 217         -- by just re-using the single top-level definition.  So
 218         -- for the worker itself, we must allocate it directly.
 219     emitBc (mkProtoBCO (getName id) (toOL [PACK data_con 0, ENTER])
 220                        (Right rhs) 0 0 [{-no bitmap-}] False{-not alts-})
 221
 222   | otherwise
 223   = schemeR [{- No free variables -}] (id, rhs)
 224
 225 -- -----------------------------------------------------------------------------
 226 -- schemeR
 227
 228 -- Compile code for a right-hand side, to give a BCO that,
 229 -- when executed with the free variables and arguments on top of the stack,
 230 -- will return with a pointer to the result on top of the stack, after
 231 -- removing the free variables and arguments.
 232 --
 233 -- Park the resulting BCO in the monad.  Also requires the
 234 -- variable to which this value was bound, so as to give the
 235 -- resulting BCO a name.
 236
 237 schemeR :: [Id]                 -- Free vars of the RHS, ordered as they
 238                                 -- will appear in the thunk.  Empty for
 239                                 -- top-level things, which have no free vars.
 240         -> (Id, AnnExpr Id VarSet)
 241         -> BcM (ProtoBCO Name)
 242 schemeR fvs (nm, rhs)
 243 {-
 244    | trace (showSDoc (
 245               (char ' '
 246                $$ (ppr.filter (not.isTyVar).varSetElems.fst) rhs
 247                $$ pprCoreExpr (deAnnotate rhs)
 248                $$ char ' '
 249               ))) False
 250    = undefined
 251    | otherwise
 252 -}
 253    = schemeR_wrk fvs nm rhs (collect [] rhs)
 254
 255 collect xs (_, AnnNote note e) = collect xs e
 256 collect xs (_, AnnLam x e)     = collect (if isTyVar x then xs else (x:xs)) e
 257 collect xs (_, not_lambda)     = (reverse xs, not_lambda)
 258
 259 schemeR_wrk fvs nm original_body (args, body)
 260    = let
 261          all_args  = reverse args ++ fvs
 262          arity     = length all_args
 263          -- all_args are the args in reverse order.  We're compiling a function
 264          -- \fv1..fvn x1..xn -> e
 265          -- i.e. the fvs come first
 266
 267          szsw_args = map idSizeW all_args
 268          szw_args  = sum szsw_args
 269          p_init    = listToFM (zip all_args (mkStackOffsets 0 szsw_args))
 270
 271          -- make the arg bitmap
 272          bits = argBits (reverse (map idCgRep all_args))
 273          bitmap_size = length bits
 274          bitmap = mkBitmap bits
 275      in
 276      schemeE szw_args 0 p_init body             `thenBc` \ body_code ->
 277      emitBc (mkProtoBCO (getName nm) body_code (Right original_body)
 278                 arity bitmap_size bitmap False{-not alts-})
 279
 280
 281 fvsToEnv :: BCEnv -> VarSet -> [Id]
 282 -- Takes the free variables of a right-hand side, and
 283 -- delivers an ordered list of the local variables that will
 284 -- be captured in the thunk for the RHS
 285 -- The BCEnv argument tells which variables are in the local
 286 -- environment: these are the ones that should be captured
 287 --
 288 -- The code that constructs the thunk, and the code that executes
 289 -- it, have to agree about this layout
 290 fvsToEnv p fvs = [v | v <- varSetElems fvs,
 291                       isId v,           -- Could be a type variable
 292                       v `elemFM` p]
 293
 294 -- -----------------------------------------------------------------------------
 295 -- schemeE
 296
 297 -- Compile code to apply the given expression to the remaining args
 298 -- on the stack, returning a HNF.
 299 schemeE :: Int -> Sequel -> BCEnv -> AnnExpr' Id VarSet -> BcM BCInstrList
 300
 301 -- Delegate tail-calls to schemeT.
 302 schemeE d s p e@(AnnApp f a)
 303    = schemeT d s p e
 304
 305 schemeE d s p e@(AnnVar v)
 306    | not (isUnLiftedType v_type)
 307    =  -- Lifted-type thing; push it in the normal way
 308      schemeT d s p e
 309
 310    | otherwise
 311    = -- Returning an unlifted value.
 312      -- Heave it on the stack, SLIDE, and RETURN.
 313      pushAtom d p (AnnVar v)    `thenBc` \ (push, szw) ->
 314      returnBc (push                     -- value onto stack
 315                `appOL`  mkSLIDE szw (d-s)       -- clear to sequel
 316                `snocOL` RETURN_UBX v_rep)       -- go
 317    where
 318       v_type = idType v
 319       v_rep = typeCgRep v_type
 320
 321 schemeE d s p (AnnLit literal)
 322    = pushAtom d p (AnnLit literal)      `thenBc` \ (push, szw) ->
 323      let l_rep = typeCgRep (literalType literal)
 324      in  returnBc (push                         -- value onto stack
 325                    `appOL`  mkSLIDE szw (d-s)   -- clear to sequel
 326                    `snocOL` RETURN_UBX l_rep)   -- go
 327
 328
 329 schemeE d s p (AnnLet (AnnNonRec x (_,rhs)) (_,body))
 330    | (AnnVar v, args_r_to_l) <- splitApp rhs,
 331      Just data_con <- isDataConWorkId_maybe v,
 332      dataConRepArity data_con == length args_r_to_l
 333    =    -- Special case for a non-recursive let whose RHS is a
 334         -- saturatred constructor application.
 335         -- Just allocate the constructor and carry on
 336      mkConAppCode d s p data_con args_r_to_l    `thenBc` \ alloc_code ->
 337      schemeE (d+1) s (addToFM p x d) body       `thenBc` \ body_code ->
 338      returnBc (alloc_code `appOL` body_code)
 339
 340 -- General case for let.  Generates correct, if inefficient, code in
 341 -- all situations.
 342 schemeE d s p (AnnLet binds (_,body))
 343    = let (xs,rhss) = case binds of AnnNonRec x rhs  -> ([x],[rhs])
 344                                    AnnRec xs_n_rhss -> unzip xs_n_rhss
 345          n_binds = length xs
 346
 347          fvss  = map (fvsToEnv p' . fst) rhss
 348
 349          -- Sizes of free vars
 350          sizes = map (\rhs_fvs -> sum (map idSizeW rhs_fvs)) fvss
 351
 352          -- the arity of each rhs
 353          arities = map (length . fst . collect []) rhss
 354
 355          -- This p', d' defn is safe because all the items being pushed
 356          -- are ptrs, so all have size 1.  d' and p' reflect the stack
 357          -- after the closures have been allocated in the heap (but not
 358          -- filled in), and pointers to them parked on the stack.
 359          p'    = addListToFM p (zipE xs (mkStackOffsets d (nOfThem n_binds 1)))
 360          d'    = d + n_binds
 361          zipE  = zipEqual "schemeE"
 362
 363          -- ToDo: don't build thunks for things with no free variables
 364          build_thunk dd [] size bco off arity
 365             = returnBc (PUSH_BCO bco `consOL` unitOL (mkap (off+size) size))
 366            where
 367                 mkap | arity == 0 = MKAP
 368                      | otherwise  = MKPAP
 369          build_thunk dd (fv:fvs) size bco off arity = do
 370               (push_code, pushed_szw) <- pushAtom dd p' (AnnVar fv)
 371               more_push_code <- build_thunk (dd+pushed_szw) fvs size bco off arity
 372               returnBc (push_code `appOL` more_push_code)
 373
 374          alloc_code = toOL (zipWith mkAlloc sizes arities)
 375            where mkAlloc sz 0     = ALLOC_AP sz
 376                  mkAlloc sz arity = ALLOC_PAP arity sz
 377
 378          compile_bind d' fvs x rhs size arity off = do
 379                 bco <- schemeR fvs (x,rhs)
 380                 build_thunk d' fvs size bco off arity
 381
 382          compile_binds =
 383             [ compile_bind d' fvs x rhs size arity n
 384             | (fvs, x, rhs, size, arity, n) <-
 385                 zip6 fvss xs rhss sizes arities [n_binds, n_binds-1 .. 1]
 386             ]
 387      in do
 388      body_code <- schemeE d' s p' body
 389      thunk_codes <- sequence compile_binds
 390      returnBc (alloc_code `appOL` concatOL thunk_codes `appOL` body_code)
 391
 392
 393
 394 schemeE d s p (AnnCase scrut bndr _ [(DataAlt dc, [bind1, bind2], rhs)])
 395    | isUnboxedTupleCon dc, VoidArg <- typeCgRep (idType bind1)
 396         -- Convert
 397         --      case .... of x { (# VoidArg'd-thing, a #) -> ... }
 398         -- to
 399         --      case .... of a { DEFAULT -> ... }
 400         -- becuse the return convention for both are identical.
 401         --
 402         -- Note that it does not matter losing the void-rep thing from the
 403         -- envt (it won't be bound now) because we never look such things up.
 404
 405    = --trace "automagic mashing of case alts (# VoidArg, a #)" $
 406      doCase d s p scrut bind2 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
 407
 408    | isUnboxedTupleCon dc, VoidArg <- typeCgRep (idType bind2)
 409    = --trace "automagic mashing of case alts (# a, VoidArg #)" $
 410      doCase d s p scrut bind1 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
 411
 412 schemeE d s p (AnnCase scrut bndr _ [(DataAlt dc, [bind1], rhs)])
 413    | isUnboxedTupleCon dc
 414         -- Similarly, convert
 415         --      case .... of x { (# a #) -> ... }
 416         -- to
 417         --      case .... of a { DEFAULT -> ... }
 418    = --trace "automagic mashing of case alts (# a #)"  $
 419      doCase d s p scrut bind1 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
 420
 421 schemeE d s p (AnnCase scrut bndr _ alts)
 422    = doCase d s p scrut bndr alts False{-not an unboxed tuple-}
 423
 424 schemeE d s p (AnnNote note (_, body))
 425    = schemeE d s p body
 426
 427 schemeE d s p other
 428    = pprPanic "ByteCodeGen.schemeE: unhandled case"
 429                (pprCoreExpr (deAnnotate' other))
 430
 431
 432 -- Compile code to do a tail call.  Specifically, push the fn,
 433 -- slide the on-stack app back down to the sequel depth,
 434 -- and enter.  Four cases:
 435 --
 436 -- 0.  (Nasty hack).
 437 --     An application "GHC.Prim.tagToEnum# <type> unboxed-int".
 438 --     The int will be on the stack.  Generate a code sequence
 439 --     to convert it to the relevant constructor, SLIDE and ENTER.
 440 --
 441 -- 1.  The fn denotes a ccall.  Defer to generateCCall.
 442 --
 443 -- 2.  (Another nasty hack).  Spot (# a::VoidArg, b #) and treat
 444 --     it simply as  b  -- since the representations are identical
 445 --     (the VoidArg takes up zero stack space).  Also, spot
 446 --     (# b #) and treat it as  b.
 447 --
 448 -- 3.  Application of a constructor, by defn saturated.
 449 --     Split the args into ptrs and non-ptrs, and push the nonptrs,
 450 --     then the ptrs, and then do PACK and RETURN.
 451 --
 452 -- 4.  Otherwise, it must be a function call.  Push the args
 453 --     right to left, SLIDE and ENTER.
 454
 455 schemeT :: Int          -- Stack depth
 456         -> Sequel       -- Sequel depth
 457         -> BCEnv        -- stack env
 458         -> AnnExpr' Id VarSet
 459         -> BcM BCInstrList
 460
 461 schemeT d s p app
 462
 463 --   | trace ("schemeT: env in = \n" ++ showSDocDebug (ppBCEnv p)) False
 464 --   = panic "schemeT ?!?!"
 465
 466 --   | trace ("\nschemeT\n" ++ showSDoc (pprCoreExpr (deAnnotate' app)) ++ "\n") False
 467 --   = error "?!?!"
 468
 469    -- Case 0
 470    | Just (arg, constr_names) <- maybe_is_tagToEnum_call
 471    = pushAtom d p arg                   `thenBc` \ (push, arg_words) ->
 472      implement_tagToId constr_names     `thenBc` \ tagToId_sequence ->
 473      returnBc (push `appOL`  tagToId_sequence
 474                     `appOL`  mkSLIDE 1 (d+arg_words-s)
 475                     `snocOL` ENTER)
 476
 477    -- Case 1
 478    | Just (CCall ccall_spec) <- isFCallId_maybe fn
 479    = generateCCall d s p ccall_spec fn args_r_to_l
 480
 481    -- Case 2: Constructor application
 482    | Just con <- maybe_saturated_dcon,
 483      isUnboxedTupleCon con
 484    = case args_r_to_l of
 485         [arg1,arg2] | isVoidArgAtom arg1 ->
 486                   unboxedTupleReturn d s p arg2
 487         [arg1,arg2] | isVoidArgAtom arg2 ->
 488                   unboxedTupleReturn d s p arg1
 489         _other -> unboxedTupleException
 490
 491    -- Case 3: Ordinary data constructor
 492    | Just con <- maybe_saturated_dcon
 493    = mkConAppCode d s p con args_r_to_l `thenBc` \ alloc_con ->
 494      returnBc (alloc_con         `appOL`
 495                mkSLIDE 1 (d - s) `snocOL`
 496                ENTER)
 497
 498    -- Case 4: Tail call of function
 499    | otherwise
 500    = doTailCall d s p fn args_r_to_l
 501
 502    where
 503       -- Detect and extract relevant info for the tagToEnum kludge.
 504       maybe_is_tagToEnum_call
 505          = let extract_constr_Names ty
 506                  | Just (tyc, []) <- splitTyConApp_maybe (repType ty),
 507                    isDataTyCon tyc
 508                    = map (getName . dataConWorkId) (tyConDataCons tyc)
 509                    -- NOTE: use the worker name, not the source name of
 510                    -- the DataCon.  See DataCon.lhs for details.
 511                  | otherwise
 512                    = panic "maybe_is_tagToEnum_call.extract_constr_Ids"
 513            in
 514            case app of
 515               (AnnApp (_, AnnApp (_, AnnVar v) (_, AnnType t)) arg)
 516                  -> case isPrimOpId_maybe v of
 517                        Just TagToEnumOp -> Just (snd arg, extract_constr_Names t)
 518                        other            -> Nothing
 519               other -> Nothing
 520
 521         -- Extract the args (R->L) and fn
 522         -- The function will necessarily be a variable,
 523         -- because we are compiling a tail call
 524       (AnnVar fn, args_r_to_l) = splitApp app
 525
 526       -- Only consider this to be a constructor application iff it is
 527       -- saturated.  Otherwise, we'll call the constructor wrapper.
 528       n_args = length args_r_to_l
 529       maybe_saturated_dcon
 530         = case isDataConWorkId_maybe fn of
 531                 Just con | dataConRepArity con == n_args -> Just con
 532                 _ -> Nothing
 533
 534 -- -----------------------------------------------------------------------------
 535 -- Generate code to build a constructor application,
 536 -- leaving it on top of the stack
 537
 538 mkConAppCode :: Int -> Sequel -> BCEnv
 539              -> DataCon                 -- The data constructor
 540              -> [AnnExpr' Id VarSet]    -- Args, in *reverse* order
 541              -> BcM BCInstrList
 542
 543 mkConAppCode orig_d s p con []  -- Nullary constructor
 544   = ASSERT( isNullaryRepDataCon con )
 545     returnBc (unitOL (PUSH_G (getName (dataConWorkId con))))
 546         -- Instead of doing a PACK, which would allocate a fresh
 547         -- copy of this constructor, use the single shared version.
 548
 549 mkConAppCode orig_d s p con args_r_to_l
 550   = ASSERT( dataConRepArity con == length args_r_to_l )
 551     do_pushery orig_d (non_ptr_args ++ ptr_args)
 552  where
 553         -- The args are already in reverse order, which is the way PACK
 554         -- expects them to be.  We must push the non-ptrs after the ptrs.
 555       (ptr_args, non_ptr_args) = partition isPtrAtom args_r_to_l
 556
 557       do_pushery d (arg:args)
 558          = pushAtom d p arg                     `thenBc` \ (push, arg_words) ->
 559            do_pushery (d+arg_words) args        `thenBc` \ more_push_code ->
 560            returnBc (push `appOL` more_push_code)
 561       do_pushery d []
 562          = returnBc (unitOL (PACK con n_arg_words))
 563          where
 564            n_arg_words = d - orig_d
 565
 566
 567 -- -----------------------------------------------------------------------------
 568 -- Returning an unboxed tuple with one non-void component (the only
 569 -- case we can handle).
 570 --
 571 -- Remember, we don't want to *evaluate* the component that is being
 572 -- returned, even if it is a pointed type.  We always just return.
 573
 574 unboxedTupleReturn
 575         :: Int -> Sequel -> BCEnv
 576         -> AnnExpr' Id VarSet -> BcM BCInstrList
 577 unboxedTupleReturn d s p arg = do
 578   (push, sz) <- pushAtom d p arg
 579   returnBc (push `appOL`
 580             mkSLIDE sz (d-s) `snocOL`
 581             RETURN_UBX (atomRep arg))
 582
 583 -- -----------------------------------------------------------------------------
 584 -- Generate code for a tail-call
 585
 586 doTailCall
 587         :: Int -> Sequel -> BCEnv
 588         -> Id -> [AnnExpr' Id VarSet]
 589         -> BcM BCInstrList
 590 doTailCall init_d s p fn args
 591   = do_pushes init_d args (map atomRep args)
 592   where
 593   do_pushes d [] reps = do
 594         ASSERT( null reps ) return ()
 595         (push_fn, sz) <- pushAtom d p (AnnVar fn)
 596         ASSERT( sz == 1 ) return ()
 597         returnBc (push_fn `appOL` (
 598                   mkSLIDE ((d-init_d) + 1) (init_d - s) `appOL`
 599                   unitOL ENTER))
 600   do_pushes d args reps = do
 601       let (push_apply, n, rest_of_reps) = findPushSeq reps
 602           (these_args, rest_of_args) = splitAt n args
 603       (next_d, push_code) <- push_seq d these_args
 604       instrs <- do_pushes (next_d + 1) rest_of_args rest_of_reps
 605                 --                ^^^ for the PUSH_APPLY_ instruction
 606       returnBc (push_code `appOL` (push_apply `consOL` instrs))
 607
 608   push_seq d [] = return (d, nilOL)
 609   push_seq d (arg:args) = do
 610     (push_code, sz) <- pushAtom d p arg
 611     (final_d, more_push_code) <- push_seq (d+sz) args
 612     return (final_d, push_code `appOL` more_push_code)
 613
 614 -- v. similar to CgStackery.findMatch, ToDo: merge
 615 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: rest)
 616   = (PUSH_APPLY_PPPPPP, 6, rest)
 617 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: rest)
 618   = (PUSH_APPLY_PPPPP, 5, rest)
 619 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: rest)
 620   = (PUSH_APPLY_PPPP, 4, rest)
 621 findPushSeq (PtrArg: PtrArg: PtrArg: rest)
 622   = (PUSH_APPLY_PPP, 3, rest)
 623 findPushSeq (PtrArg: PtrArg: rest)
 624   = (PUSH_APPLY_PP, 2, rest)
 625 findPushSeq (PtrArg: rest)
 626   = (PUSH_APPLY_P, 1, rest)
 627 findPushSeq (VoidArg: rest)
 628   = (PUSH_APPLY_V, 1, rest)
 629 findPushSeq (NonPtrArg: rest)
 630   = (PUSH_APPLY_N, 1, rest)
 631 findPushSeq (FloatArg: rest)
 632   = (PUSH_APPLY_F, 1, rest)
 633 findPushSeq (DoubleArg: rest)
 634   = (PUSH_APPLY_D, 1, rest)
 635 findPushSeq (LongArg: rest)
 636   = (PUSH_APPLY_L, 1, rest)
 637 findPushSeq _
 638   = panic "ByteCodeGen.findPushSeq"
 639
 640 -- -----------------------------------------------------------------------------
 641 -- Case expressions
 642
 643 doCase  :: Int -> Sequel -> BCEnv
 644         -> AnnExpr Id VarSet -> Id -> [AnnAlt Id VarSet]
 645         -> Bool  -- True <=> is an unboxed tuple case, don't enter the result
 646         -> BcM BCInstrList
 647 doCase d s p (_,scrut)
 648  bndr alts is_unboxed_tuple
 649   = let
 650         -- Top of stack is the return itbl, as usual.
 651         -- underneath it is the pointer to the alt_code BCO.
 652         -- When an alt is entered, it assumes the returned value is
 653         -- on top of the itbl.
 654         ret_frame_sizeW = 2
 655
 656         -- An unlifted value gets an extra info table pushed on top
 657         -- when it is returned.
 658         unlifted_itbl_sizeW | isAlgCase = 0
 659                             | otherwise = 1
 660
 661         -- depth of stack after the return value has been pushed
 662         d_bndr = d + ret_frame_sizeW + idSizeW bndr
 663
 664         -- depth of stack after the extra info table for an unboxed return
 665         -- has been pushed, if any.  This is the stack depth at the
 666         -- continuation.
 667         d_alts = d_bndr + unlifted_itbl_sizeW
 668
 669         -- Env in which to compile the alts, not including
 670         -- any vars bound by the alts themselves
 671         p_alts = addToFM p bndr (d_bndr - 1)
 672
 673         bndr_ty = idType bndr
 674         isAlgCase = not (isUnLiftedType bndr_ty) && not is_unboxed_tuple
 675
 676         -- given an alt, return a discr and code for it.
 677         codeALt alt@(DEFAULT, _, (_,rhs))
 678            = schemeE d_alts s p_alts rhs        `thenBc` \ rhs_code ->
 679              returnBc (NoDiscr, rhs_code)
 680         codeAlt alt@(discr, bndrs, (_,rhs))
 681            -- primitive or nullary constructor alt: no need to UNPACK
 682            | null real_bndrs = do
 683                 rhs_code <- schemeE d_alts s p_alts rhs
 684                 returnBc (my_discr alt, rhs_code)
 685            -- algebraic alt with some binders
 686            | ASSERT(isAlgCase) otherwise =
 687              let
 688                  (ptrs,nptrs) = partition (isFollowableArg.idCgRep) real_bndrs
 689                  ptr_sizes    = map idSizeW ptrs
 690                  nptrs_sizes  = map idSizeW nptrs
 691                  bind_sizes   = ptr_sizes ++ nptrs_sizes
 692                  size         = sum ptr_sizes + sum nptrs_sizes
 693                  -- the UNPACK instruction unpacks in reverse order...
 694                  p' = addListToFM p_alts
 695                         (zip (reverse (ptrs ++ nptrs))
 696                           (mkStackOffsets d_alts (reverse bind_sizes)))
 697              in do
 698              rhs_code <- schemeE (d_alts+size) s p' rhs
 699              return (my_discr alt, unitOL (UNPACK size) `appOL` rhs_code)
 700            where
 701              real_bndrs = filter (not.isTyVar) bndrs
 702
 703
 704         my_discr (DEFAULT, binds, rhs) = NoDiscr {-shouldn't really happen-}
 705         my_discr (DataAlt dc, binds, rhs)
 706            | isUnboxedTupleCon dc
 707            = unboxedTupleException
 708            | otherwise
 709            = DiscrP (dataConTag dc - fIRST_TAG)
 710         my_discr (LitAlt l, binds, rhs)
 711            = case l of MachInt i     -> DiscrI (fromInteger i)
 712                        MachFloat r   -> DiscrF (fromRational r)
 713                        MachDouble r  -> DiscrD (fromRational r)
 714                        MachChar i    -> DiscrI (ord i)
 715                        _ -> pprPanic "schemeE(AnnCase).my_discr" (ppr l)
 716
 717         maybe_ncons
 718            | not isAlgCase = Nothing
 719            | otherwise
 720            = case [dc | (DataAlt dc, _, _) <- alts] of
 721                 []     -> Nothing
 722                 (dc:_) -> Just (tyConFamilySize (dataConTyCon dc))
 723
 724         -- the bitmap is relative to stack depth d, i.e. before the
 725         -- BCO, info table and return value are pushed on.
 726         -- This bit of code is v. similar to buildLivenessMask in CgBindery,
 727         -- except that here we build the bitmap from the known bindings of
 728         -- things that are pointers, whereas in CgBindery the code builds the
 729         -- bitmap from the free slots and unboxed bindings.
 730         -- (ToDo: merge?)
 731         bitmap = intsToReverseBitmap d{-size-} (sortLe (<=) rel_slots)
 732           where
 733           binds = fmToList p
 734           rel_slots = concat (map spread binds)
 735           spread (id, offset)
 736                 | isFollowableArg (idCgRep id) = [ rel_offset ]
 737                 | otherwise = []
 738                 where rel_offset = d - offset - 1
 739
 740      in do
 741      alt_stuff <- mapM codeAlt alts
 742      alt_final <- mkMultiBranch maybe_ncons alt_stuff
 743      let
 744          alt_bco_name = getName bndr
 745          alt_bco = mkProtoBCO alt_bco_name alt_final (Left alts)
 746                         0{-no arity-} d{-bitmap size-} bitmap True{-is alts-}
 747      -- in
 748 --     trace ("case: bndr = " ++ showSDocDebug (ppr bndr) ++ "\ndepth = " ++ show d ++ "\nenv = \n" ++ showSDocDebug (ppBCEnv p) ++
 749 --           "\n      bitmap = " ++ show bitmap) $ do
 750      scrut_code <- schemeE (d + ret_frame_sizeW) (d + ret_frame_sizeW) p scrut
 751      alt_bco' <- emitBc alt_bco
 752      let push_alts
 753             | isAlgCase = PUSH_ALTS alt_bco'
 754             | otherwise = PUSH_ALTS_UNLIFTED alt_bco' (typeCgRep bndr_ty)
 755      returnBc (push_alts `consOL` scrut_code)
 756
 757
 758 -- -----------------------------------------------------------------------------
 759 -- Deal with a CCall.
 760
 761 -- Taggedly push the args onto the stack R->L,
 762 -- deferencing ForeignObj#s and adjusting addrs to point to
 763 -- payloads in Ptr/Byte arrays.  Then, generate the marshalling
 764 -- (machine) code for the ccall, and create bytecodes to call that and
 765 -- then return in the right way.
 766
 767 generateCCall :: Int -> Sequel          -- stack and sequel depths
 768               -> BCEnv
 769               -> CCallSpec              -- where to call
 770               -> Id                     -- of target, for type info
 771               -> [AnnExpr' Id VarSet]   -- args (atoms)
 772               -> BcM BCInstrList
 773
 774 generateCCall d0 s p ccall_spec@(CCallSpec target cconv safety) fn args_r_to_l
 775    = let
 776          -- useful constants
 777          addr_sizeW = cgRepSizeW NonPtrArg
 778
 779          -- Get the args on the stack, with tags and suitably
 780          -- dereferenced for the CCall.  For each arg, return the
 781          -- depth to the first word of the bits for that arg, and the
 782          -- CgRep of what was actually pushed.
 783
 784          pargs d [] = returnBc []
 785          pargs d (a:az)
 786             = let arg_ty = repType (exprType (deAnnotate' a))
 787
 788               in case splitTyConApp_maybe arg_ty of
 789                     -- Don't push the FO; instead push the Addr# it
 790                     -- contains.
 791                     Just (t, _)
 792                      | t == arrayPrimTyCon || t == mutableArrayPrimTyCon
 793                        -> pargs (d + addr_sizeW) az     `thenBc` \ rest ->
 794                           parg_ArrayishRep arrPtrsHdrSize d p a
 795                                                         `thenBc` \ code ->
 796                           returnBc ((code,NonPtrArg):rest)
 797
 798                      | t == byteArrayPrimTyCon || t == mutableByteArrayPrimTyCon
 799                        -> pargs (d + addr_sizeW) az     `thenBc` \ rest ->
 800                           parg_ArrayishRep arrWordsHdrSize d p a
 801                                                         `thenBc` \ code ->
 802                           returnBc ((code,NonPtrArg):rest)
 803
 804                     -- Default case: push taggedly, but otherwise intact.
 805                     other
 806                        -> pushAtom d p a                `thenBc` \ (code_a, sz_a) ->
 807                           pargs (d+sz_a) az             `thenBc` \ rest ->
 808                           returnBc ((code_a, atomRep a) : rest)
 809
 810          -- Do magic for Ptr/Byte arrays.  Push a ptr to the array on
 811          -- the stack but then advance it over the headers, so as to
 812          -- point to the payload.
 813          parg_ArrayishRep hdrSize d p a
 814             = pushAtom d p a `thenBc` \ (push_fo, _) ->
 815               -- The ptr points at the header.  Advance it over the
 816               -- header and then pretend this is an Addr#.
 817               returnBc (push_fo `snocOL` SWIZZLE 0 hdrSize)
 818
 819      in
 820          pargs d0 args_r_to_l                   `thenBc` \ code_n_reps ->
 821      let
 822          (pushs_arg, a_reps_pushed_r_to_l) = unzip code_n_reps
 823
 824          push_args    = concatOL pushs_arg
 825          d_after_args = d0 + sum (map cgRepSizeW a_reps_pushed_r_to_l)
 826          a_reps_pushed_RAW
 827             | null a_reps_pushed_r_to_l || head a_reps_pushed_r_to_l /= VoidArg
 828             = panic "ByteCodeGen.generateCCall: missing or invalid World token?"
 829             | otherwise
 830             = reverse (tail a_reps_pushed_r_to_l)
 831
 832          -- Now: a_reps_pushed_RAW are the reps which are actually on the stack.
 833          -- push_args is the code to do that.
 834          -- d_after_args is the stack depth once the args are on.
 835
 836          -- Get the result rep.
 837          (returns_void, r_rep)
 838             = case maybe_getCCallReturnRep (idType fn) of
 839                  Nothing -> (True,  VoidArg)
 840                  Just rr -> (False, rr)
 841          {-
 842          Because the Haskell stack grows down, the a_reps refer to
 843          lowest to highest addresses in that order.  The args for the call
 844          are on the stack.  Now push an unboxed Addr# indicating
 845          the C function to call.  Then push a dummy placeholder for the
 846          result.  Finally, emit a CCALL insn with an offset pointing to the
 847          Addr# just pushed, and a literal field holding the mallocville
 848          address of the piece of marshalling code we generate.
 849          So, just prior to the CCALL insn, the stack looks like this
 850          (growing down, as usual):
 851
 852             <arg_n>
 853             ...
 854             <arg_1>
 855             Addr# address_of_C_fn
 856             <placeholder-for-result#> (must be an unboxed type)
 857
 858          The interpreter then calls the marshall code mentioned
 859          in the CCALL insn, passing it (& <placeholder-for-result#>),
 860          that is, the addr of the topmost word in the stack.
 861          When this returns, the placeholder will have been
 862          filled in.  The placeholder is slid down to the sequel
 863          depth, and we RETURN.
 864
 865          This arrangement makes it simple to do f-i-dynamic since the Addr#
 866          value is the first arg anyway.
 867
 868          The marshalling code is generated specifically for this
 869          call site, and so knows exactly the (Haskell) stack
 870          offsets of the args, fn address and placeholder.  It
 871          copies the args to the C stack, calls the stacked addr,
 872          and parks the result back in the placeholder.  The interpreter
 873          calls it as a normal C call, assuming it has a signature
 874             void marshall_code ( StgWord* ptr_to_top_of_stack )
 875          -}
 876          -- resolve static address
 877          get_target_info
 878             = case target of
 879                  DynamicTarget
 880                     -> returnBc (False, panic "ByteCodeGen.generateCCall(dyn)")
 881                  StaticTarget target
 882                     -> ioToBc (lookupStaticPtr target) `thenBc` \res ->
 883                        returnBc (True, res)
 884      in
 885          get_target_info        `thenBc` \ (is_static, static_target_addr) ->
 886      let
 887
 888          -- Get the arg reps, zapping the leading Addr# in the dynamic case
 889          a_reps --  | trace (showSDoc (ppr a_reps_pushed_RAW)) False = error "???"
 890                 | is_static = a_reps_pushed_RAW
 891                 | otherwise = if null a_reps_pushed_RAW
 892                               then panic "ByteCodeGen.generateCCall: dyn with no args"
 893                               else tail a_reps_pushed_RAW
 894
 895          -- push the Addr#
 896          (push_Addr, d_after_Addr)
 897             | is_static
 898             = (toOL [PUSH_UBX (Right static_target_addr) addr_sizeW],
 899                d_after_args + addr_sizeW)
 900             | otherwise -- is already on the stack
 901             = (nilOL, d_after_args)
 902
 903          -- Push the return placeholder.  For a call returning nothing,
 904          -- this is a VoidArg (tag).
 905          r_sizeW   = cgRepSizeW r_rep
 906          d_after_r = d_after_Addr + r_sizeW
 907          r_lit     = mkDummyLiteral r_rep
 908          push_r    = (if   returns_void
 909                       then nilOL
 910                       else unitOL (PUSH_UBX (Left r_lit) r_sizeW))
 911
 912          -- generate the marshalling code we're going to call
 913          r_offW       = 0
 914          addr_offW    = r_sizeW
 915          arg1_offW    = r_sizeW + addr_sizeW
 916          args_offW    = map (arg1_offW +)
 917                             (init (scanl (+) 0 (map cgRepSizeW a_reps)))
 918      in
 919          ioToBc (mkMarshalCode cconv
 920                     (r_offW, r_rep) addr_offW
 921                     (zip args_offW a_reps))     `thenBc` \ addr_of_marshaller ->
 922          recordMallocBc addr_of_marshaller      `thenBc_`
 923      let
 924          -- Offset of the next stack frame down the stack.  The CCALL
 925          -- instruction needs to describe the chunk of stack containing
 926          -- the ccall args to the GC, so it needs to know how large it
 927          -- is.  See comment in Interpreter.c with the CCALL instruction.
 928          stk_offset   = d_after_r - s
 929
 930          -- do the call
 931          do_call      = unitOL (CCALL stk_offset (castPtr addr_of_marshaller))
 932          -- slide and return
 933          wrapup       = mkSLIDE r_sizeW (d_after_r - r_sizeW - s)
 934                         `snocOL` RETURN_UBX r_rep
 935      in
 936          --trace (show (arg1_offW, args_offW  ,  (map cgRepSizeW a_reps) )) $
 937          returnBc (
 938          push_args `appOL`
 939          push_Addr `appOL` push_r `appOL` do_call `appOL` wrapup
 940          )
 941
 942
 943 -- Make a dummy literal, to be used as a placeholder for FFI return
 944 -- values on the stack.
 945 mkDummyLiteral :: CgRep -> Literal
 946 mkDummyLiteral pr
 947    = case pr of
 948         NonPtrArg -> MachWord 0
 949         DoubleArg -> MachDouble 0
 950         FloatArg  -> MachFloat 0
 951         _         -> moan64 "mkDummyLiteral" (ppr pr)
 952
 953
 954 -- Convert (eg)
 955 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
 956 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld, GHC.Prim.Int# #)
 957 --
 958 -- to  Just IntRep
 959 -- and check that an unboxed pair is returned wherein the first arg is VoidArg'd.
 960 --
 961 -- Alternatively, for call-targets returning nothing, convert
 962 --
 963 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
 964 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld #)
 965 --
 966 -- to  Nothing
 967
 968 maybe_getCCallReturnRep :: Type -> Maybe CgRep
 969 maybe_getCCallReturnRep fn_ty
 970    = let (a_tys, r_ty) = splitFunTys (dropForAlls fn_ty)
 971          maybe_r_rep_to_go
 972             = if isSingleton r_reps then Nothing else Just (r_reps !! 1)
 973          (r_tycon, r_reps)
 974             = case splitTyConApp_maybe (repType r_ty) of
 975                       (Just (tyc, tys)) -> (tyc, map typeCgRep tys)
 976                       Nothing -> blargh
 977          ok = ( ( r_reps `lengthIs` 2 && VoidArg == head r_reps)
 978                 || r_reps == [VoidArg] )
 979               && isUnboxedTupleTyCon r_tycon
 980               && case maybe_r_rep_to_go of
 981                     Nothing    -> True
 982                     Just r_rep -> r_rep /= PtrArg
 983                                   -- if it was, it would be impossible
 984                                   -- to create a valid return value
 985                                   -- placeholder on the stack
 986          blargh = pprPanic "maybe_getCCallReturn: can't handle:"
 987                            (pprType fn_ty)
 988      in
 989      --trace (showSDoc (ppr (a_reps, r_reps))) $
 990      if ok then maybe_r_rep_to_go else blargh
 991
 992 -- Compile code which expects an unboxed Int on the top of stack,
 993 -- (call it i), and pushes the i'th closure in the supplied list
 994 -- as a consequence.
 995 implement_tagToId :: [Name] -> BcM BCInstrList
 996 implement_tagToId names
 997    = ASSERT( notNull names )
 998      getLabelsBc (length names)                 `thenBc` \ labels ->
 999      getLabelBc                                 `thenBc` \ label_fail ->
1000      getLabelBc                                 `thenBc` \ label_exit ->
1001      zip4 labels (tail labels ++ [label_fail])
1002                  [0 ..] names                   `bind`   \ infos ->
1003      map (mkStep label_exit) infos              `bind`   \ steps ->
1004      returnBc (concatOL steps
1005                `appOL`
1006                toOL [LABEL label_fail, CASEFAIL, LABEL label_exit])
1007      where
1008         mkStep l_exit (my_label, next_label, n, name_for_n)
1009            = toOL [LABEL my_label,
1010                    TESTEQ_I n next_label,
1011                    PUSH_G name_for_n,
1012                    JMP l_exit]
1013
1014
1015 -- -----------------------------------------------------------------------------
1016 -- pushAtom
1017
1018 -- Push an atom onto the stack, returning suitable code & number of
1019 -- stack words used.
1020 --
1021 -- The env p must map each variable to the highest- numbered stack
1022 -- slot for it.  For example, if the stack has depth 4 and we
1023 -- tagged-ly push (v :: Int#) on it, the value will be in stack[4],
1024 -- the tag in stack[5], the stack will have depth 6, and p must map v
1025 -- to 5 and not to 4.  Stack locations are numbered from zero, so a
1026 -- depth 6 stack has valid words 0 .. 5.
1027
1028 pushAtom :: Int -> BCEnv -> AnnExpr' Id VarSet -> BcM (BCInstrList, Int)
1029
1030 pushAtom d p (AnnApp f (_, AnnType _))
1031    = pushAtom d p (snd f)
1032
1033 pushAtom d p (AnnNote note e)
1034    = pushAtom d p (snd e)
1035
1036 pushAtom d p (AnnLam x e)
1037    | isTyVar x
1038    = pushAtom d p (snd e)
1039
1040 pushAtom d p (AnnVar v)
1041
1042    | idCgRep v == VoidArg
1043    = returnBc (nilOL, 0)
1044
1045    | isFCallId v
1046    = pprPanic "pushAtom: shouldn't get an FCallId here" (ppr v)
1047
1048    | Just primop <- isPrimOpId_maybe v
1049    = returnBc (unitOL (PUSH_PRIMOP primop), 1)
1050
1051    | Just d_v <- lookupBCEnv_maybe p v  -- v is a local variable
1052    = returnBc (toOL (nOfThem sz (PUSH_L (d-d_v+sz-2))), sz)
1053          -- d - d_v                 the number of words between the TOS
1054          --                         and the 1st slot of the object
1055          --
1056          -- d - d_v - 1             the offset from the TOS of the 1st slot
1057          --
1058          -- d - d_v - 1 + sz - 1    the offset from the TOS of the last slot
1059          --                         of the object.
1060          --
1061          -- Having found the last slot, we proceed to copy the right number of
1062          -- slots on to the top of the stack.
1063
1064     | otherwise  -- v must be a global variable
1065     = ASSERT(sz == 1)
1066       returnBc (unitOL (PUSH_G (getName v)), sz)
1067
1068     where
1069          sz = idSizeW v
1070
1071
1072 pushAtom d p (AnnLit lit)
1073    = case lit of
1074         MachLabel fs _ -> code NonPtrArg
1075         MachWord w     -> code NonPtrArg
1076         MachInt i      -> code PtrArg
1077         MachFloat r    -> code FloatArg
1078         MachDouble r   -> code DoubleArg
1079         MachChar c     -> code NonPtrArg
1080         MachStr s      -> pushStr s
1081      where
1082         code rep
1083            = let size_host_words = cgRepSizeW rep
1084              in  returnBc (unitOL (PUSH_UBX (Left lit) size_host_words),
1085                            size_host_words)
1086
1087         pushStr s
1088            = let getMallocvilleAddr
1089                     = case s of
1090                          FastString _ n _ fp _ ->
1091                             -- we could grab the Ptr from the ForeignPtr,
1092                             -- but then we have no way to control its lifetime.
1093                             -- In reality it'll probably stay alive long enoungh
1094                             -- by virtue of the global FastString table, but
1095                             -- to be on the safe side we copy the string into
1096                             -- a malloc'd area of memory.
1097                                 ioToBc (mallocBytes (n+1)) `thenBc` \ ptr ->
1098                                 recordMallocBc ptr         `thenBc_`
1099                                 ioToBc (
1100                                    withForeignPtr fp $ \p -> do
1101                                       memcpy ptr p (fromIntegral n)
1102                                       pokeByteOff ptr n (fromIntegral (ord '\0') :: Word8)
1103                                       return ptr
1104                                    )
1105              in
1106                 getMallocvilleAddr `thenBc` \ addr ->
1107                 -- Get the addr on the stack, untaggedly
1108                    returnBc (unitOL (PUSH_UBX (Right addr) 1), 1)
1109
1110 pushAtom d p other
1111    = pprPanic "ByteCodeGen.pushAtom"
1112               (pprCoreExpr (deAnnotate (undefined, other)))
1113
1114 foreign import ccall unsafe "memcpy"
1115  memcpy :: Ptr a -> Ptr b -> CInt -> IO ()
1116
1117
1118 -- -----------------------------------------------------------------------------
1119 -- Given a bunch of alts code and their discrs, do the donkey work
1120 -- of making a multiway branch using a switch tree.
1121 -- What a load of hassle!
1122
1123 mkMultiBranch :: Maybe Int      --  # datacons in tycon, if alg alt
1124                                 -- a hint; generates better code
1125                                 -- Nothing is always safe
1126               -> [(Discr, BCInstrList)]
1127               -> BcM BCInstrList
1128 mkMultiBranch maybe_ncons raw_ways
1129    = let d_way     = filter (isNoDiscr.fst) raw_ways
1130          notd_ways = sortLe
1131                         (\w1 w2 -> leAlt (fst w1) (fst w2))
1132                         (filter (not.isNoDiscr.fst) raw_ways)
1133
1134          mkTree :: [(Discr, BCInstrList)] -> Discr -> Discr -> BcM BCInstrList
1135          mkTree [] range_lo range_hi = returnBc the_default
1136
1137          mkTree [val] range_lo range_hi
1138             | range_lo `eqAlt` range_hi
1139             = returnBc (snd val)
1140             | otherwise
1141             = getLabelBc                                `thenBc` \ label_neq ->
1142               returnBc (mkTestEQ (fst val) label_neq
1143                         `consOL` (snd val
1144                         `appOL`   unitOL (LABEL label_neq)
1145                         `appOL`   the_default))
1146
1147          mkTree vals range_lo range_hi
1148             = let n = length vals `div` 2
1149                   vals_lo = take n vals
1150                   vals_hi = drop n vals
1151                   v_mid = fst (head vals_hi)
1152               in
1153               getLabelBc                                `thenBc` \ label_geq ->
1154               mkTree vals_lo range_lo (dec v_mid)       `thenBc` \ code_lo ->
1155               mkTree vals_hi v_mid range_hi             `thenBc` \ code_hi ->
1156               returnBc (mkTestLT v_mid label_geq
1157                         `consOL` (code_lo
1158                         `appOL`   unitOL (LABEL label_geq)
1159                         `appOL`   code_hi))
1160
1161          the_default
1162             = case d_way of [] -> unitOL CASEFAIL
1163                             [(_, def)] -> def
1164
1165          -- None of these will be needed if there are no non-default alts
1166          (mkTestLT, mkTestEQ, init_lo, init_hi)
1167             | null notd_ways
1168             = panic "mkMultiBranch: awesome foursome"
1169             | otherwise
1170             = case fst (head notd_ways) of {
1171               DiscrI _ -> ( \(DiscrI i) fail_label -> TESTLT_I i fail_label,
1172                             \(DiscrI i) fail_label -> TESTEQ_I i fail_label,
1173                             DiscrI minBound,
1174                             DiscrI maxBound );
1175               DiscrF _ -> ( \(DiscrF f) fail_label -> TESTLT_F f fail_label,
1176                             \(DiscrF f) fail_label -> TESTEQ_F f fail_label,
1177                             DiscrF minF,
1178                             DiscrF maxF );
1179               DiscrD _ -> ( \(DiscrD d) fail_label -> TESTLT_D d fail_label,
1180                             \(DiscrD d) fail_label -> TESTEQ_D d fail_label,
1181                             DiscrD minD,
1182                             DiscrD maxD );
1183               DiscrP _ -> ( \(DiscrP i) fail_label -> TESTLT_P i fail_label,
1184                             \(DiscrP i) fail_label -> TESTEQ_P i fail_label,
1185                             DiscrP algMinBound,
1186                             DiscrP algMaxBound )
1187               }
1188
1189          (algMinBound, algMaxBound)
1190             = case maybe_ncons of
1191                  Just n  -> (0, n - 1)
1192                  Nothing -> (minBound, maxBound)
1193
1194          (DiscrI i1) `eqAlt` (DiscrI i2) = i1 == i2
1195          (DiscrF f1) `eqAlt` (DiscrF f2) = f1 == f2
1196          (DiscrD d1) `eqAlt` (DiscrD d2) = d1 == d2
1197          (DiscrP i1) `eqAlt` (DiscrP i2) = i1 == i2
1198          NoDiscr     `eqAlt` NoDiscr     = True
1199          _           `eqAlt` _           = False
1200
1201          (DiscrI i1) `leAlt` (DiscrI i2) = i1 <= i2
1202          (DiscrF f1) `leAlt` (DiscrF f2) = f1 <= f2
1203          (DiscrD d1) `leAlt` (DiscrD d2) = d1 <= d2
1204          (DiscrP i1) `leAlt` (DiscrP i2) = i1 <= i2
1205          NoDiscr     `leAlt` NoDiscr     = True
1206          _           `leAlt` _           = False
1207
1208          isNoDiscr NoDiscr = True
1209          isNoDiscr _       = False
1210
1211          dec (DiscrI i) = DiscrI (i-1)
1212          dec (DiscrP i) = DiscrP (i-1)
1213          dec other      = other         -- not really right, but if you
1214                 -- do cases on floating values, you'll get what you deserve
1215
1216          -- same snotty comment applies to the following
1217          minF, maxF :: Float
1218          minD, maxD :: Double
1219          minF = -1.0e37
1220          maxF =  1.0e37
1221          minD = -1.0e308
1222          maxD =  1.0e308
1223      in
1224          mkTree notd_ways init_lo init_hi
1225
1226
1227 -- -----------------------------------------------------------------------------
1228 -- Supporting junk for the compilation schemes
1229
1230 -- Describes case alts
1231 data Discr
1232    = DiscrI Int
1233    | DiscrF Float
1234    | DiscrD Double
1235    | DiscrP Int
1236    | NoDiscr
1237
1238 instance Outputable Discr where
1239    ppr (DiscrI i) = int i
1240    ppr (DiscrF f) = text (show f)
1241    ppr (DiscrD d) = text (show d)
1242    ppr (DiscrP i) = int i
1243    ppr NoDiscr    = text "DEF"
1244
1245
1246 lookupBCEnv_maybe :: BCEnv -> Id -> Maybe Int
1247 lookupBCEnv_maybe = lookupFM
1248
1249 idSizeW :: Id -> Int
1250 idSizeW id = cgRepSizeW (typeCgRep (idType id))
1251
1252 unboxedTupleException :: a
1253 unboxedTupleException
1254    = throwDyn
1255         (Panic
1256            ("Bytecode generator can't handle unboxed tuples.  Possibly due\n" ++
1257             "\tto foreign import/export decls in source.  Workaround:\n" ++
1258             "\tcompile this module to a .o file, then restart session."))
1259
1260
1261 mkSLIDE n d = if d == 0 then nilOL else unitOL (SLIDE n d)
1262 bind x f    = f x
1263
1264 splitApp :: AnnExpr' id ann -> (AnnExpr' id ann, [AnnExpr' id ann])
1265         -- The arguments are returned in *right-to-left* order
1266 splitApp (AnnApp (_,f) (_,a))
1267                | isTypeAtom a = splitApp f
1268                | otherwise    = case splitApp f of
1269                                      (f', as) -> (f', a:as)
1270 splitApp (AnnNote n (_,e))    = splitApp e
1271 splitApp e                    = (e, [])
1272
1273
1274 isTypeAtom :: AnnExpr' id ann -> Bool
1275 isTypeAtom (AnnType _) = True
1276 isTypeAtom _           = False
1277
1278 isVoidArgAtom :: AnnExpr' id ann -> Bool
1279 isVoidArgAtom (AnnVar v)        = typeCgRep (idType v) == VoidArg
1280 isVoidArgAtom (AnnNote n (_,e)) = isVoidArgAtom e
1281 isVoidArgAtom _                 = False
1282
1283 atomRep :: AnnExpr' Id ann -> CgRep
1284 atomRep (AnnVar v)    = typeCgRep (idType v)
1285 atomRep (AnnLit l)    = typeCgRep (literalType l)
1286 atomRep (AnnNote n b) = atomRep (snd b)
1287 atomRep (AnnApp f (_, AnnType _)) = atomRep (snd f)
1288 atomRep (AnnLam x e) | isTyVar x = atomRep (snd e)
1289 atomRep other = pprPanic "atomRep" (ppr (deAnnotate (undefined,other)))
1290
1291 isPtrAtom :: AnnExpr' Id ann -> Bool
1292 isPtrAtom e = atomRep e == PtrArg
1293
1294 -- Let szsw be the sizes in words of some items pushed onto the stack,
1295 -- which has initial depth d'.  Return the values which the stack environment
1296 -- should map these items to.
1297 mkStackOffsets :: Int -> [Int] -> [Int]
1298 mkStackOffsets original_depth szsw
1299    = map (subtract 1) (tail (scanl (+) original_depth szsw))
1300
1301 -- -----------------------------------------------------------------------------
1302 -- The bytecode generator's monad
1303
1304 data BcM_State
1305    = BcM_State {
1306         nextlabel :: Int,               -- for generating local labels
1307         malloced  :: [Ptr ()] }         -- ptrs malloced for current BCO
1308                                         -- Should be free()d when it is GCd
1309
1310 newtype BcM r = BcM (BcM_State -> IO (BcM_State, r))
1311
1312 ioToBc :: IO a -> BcM a
1313 ioToBc io = BcM $ \st -> do
1314   x <- io
1315   return (st, x)
1316
1317 runBc :: BcM r -> IO (BcM_State, r)
1318 runBc (BcM m) = m (BcM_State 0 [])
1319
1320 thenBc :: BcM a -> (a -> BcM b) -> BcM b
1321 thenBc (BcM expr) cont = BcM $ \st0 -> do
1322   (st1, q) <- expr st0
1323   let BcM k = cont q
1324   (st2, r) <- k st1
1325   return (st2, r)
1326
1327 thenBc_ :: BcM a -> BcM b -> BcM b
1328 thenBc_ (BcM expr) (BcM cont) = BcM $ \st0 -> do
1329   (st1, q) <- expr st0
1330   (st2, r) <- cont st1
1331   return (st2, r)
1332
1333 returnBc :: a -> BcM a
1334 returnBc result = BcM $ \st -> (return (st, result))
1335
1336 instance Monad BcM where
1337   (>>=) = thenBc
1338   (>>)  = thenBc_
1339   return = returnBc
1340
1341 emitBc :: ([Ptr ()] -> ProtoBCO Name) -> BcM (ProtoBCO Name)
1342 emitBc bco
1343   = BcM $ \st -> return (st{malloced=[]}, bco (malloced st))
1344
1345 recordMallocBc :: Ptr a -> BcM ()
1346 recordMallocBc a
1347   = BcM $ \st -> return (st{malloced = castPtr a : malloced st}, ())
1348
1349 getLabelBc :: BcM Int
1350 getLabelBc
1351   = BcM $ \st -> return (st{nextlabel = 1 + nextlabel st}, nextlabel st)
1352
1353 getLabelsBc :: Int -> BcM [Int]
1354 getLabelsBc n
1355   = BcM $ \st -> let ctr = nextlabel st
1356                  in return (st{nextlabel = ctr+n}, [ctr .. ctr+n-1])
1357 \end{code}