compiler/hsSyn/HsBinds.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsBinds]{Abstract syntax: top-level bindings and signatures}
   5
   6 Datatype for: @BindGroup@, @Bind@, @Sig@, @Bind@.
   7
   8 \begin{code}
   9 module HsBinds where
  10
  11 #include "HsVersions.h"
  12
  13 import {-# SOURCE #-} HsExpr ( HsExpr, pprExpr, LHsExpr,
  14                                MatchGroup, pprFunBind,
  15                                GRHSs, pprPatBind )
  16 import {-# SOURCE #-} HsPat  ( LPat )
  17
  18 import HsTypes          ( LHsType, PostTcType )
  19 import Type             ( Type )
  20 import Name             ( Name )
  21 import NameSet          ( NameSet, elemNameSet )
  22 import BasicTypes       ( IPName, RecFlag(..), InlineSpec(..), Fixity )
  23 import Outputable
  24 import SrcLoc           ( Located(..), SrcSpan, unLoc )
  25 import Util             ( sortLe )
  26 import Var              ( TyVar, DictId, Id )
  27 import Bag              ( Bag, emptyBag, isEmptyBag, bagToList, unionBags, unionManyBags )
  28 \end{code}
  29
  30 %************************************************************************
  31 %*                                                                      *
  32 \subsection{Bindings: @BindGroup@}
  33 %*                                                                      *
  34 %************************************************************************
  35
  36 Global bindings (where clauses)
  37
  38 \begin{code}
  39 data HsLocalBinds id    -- Bindings in a 'let' expression
  40                         -- or a 'where' clause
  41   = HsValBinds (HsValBinds id)
  42   | HsIPBinds  (HsIPBinds id)
  43
  44   | EmptyLocalBinds
  45
  46 data HsValBinds id      -- Value bindings (not implicit parameters)
  47   = ValBindsIn                          -- Before typechecking
  48         (LHsBinds id) [LSig id]         -- Not dependency analysed
  49                                         -- Recursive by default
  50
  51   | ValBindsOut                         -- After renaming
  52         [(RecFlag, LHsBinds id)]        -- Dependency analysed
  53         [LSig Name]
  54
  55 type LHsBinds id  = Bag (LHsBind id)
  56 type DictBinds id = LHsBinds id         -- Used for dictionary or method bindings
  57 type LHsBind  id  = Located (HsBind id)
  58
  59 data HsBind id
  60   = FunBind {   -- FunBind is used for both functions   f x = e
  61                 -- and variables                        f = \x -> e
  62 -- Reason 1: Special case for type inference: see TcBinds.tcMonoBinds
  63 --
  64 -- Reason 2: instance decls can only have FunBinds, which is convenient
  65 --           If you change this, you'll need tochange e.g. rnMethodBinds
  66
  67 -- But note that the form       f :: a->a = ...
  68 -- parses as a pattern binding, just like
  69 --                      (f :: a -> a) = ...
  70
  71         fun_id :: Located id,
  72
  73         fun_infix :: Bool,      -- True => infix declaration
  74
  75         fun_matches :: MatchGroup id,   -- The payload
  76
  77         fun_co_fn :: ExprCoFn,  -- Coercion from the type of the MatchGroup to the type of
  78                                 -- the Id.  Example:
  79                                 --      f :: Int -> forall a. a -> a
  80                                 --      f x y = y
  81                                 -- Then the MatchGroup will have type (Int -> a' -> a')
  82                                 -- (with a free type variable a').  The coercion will take
  83                                 -- a CoreExpr of this type and convert it to a CoreExpr of
  84                                 -- type         Int -> forall a'. a' -> a'
  85                                 -- Notice that the coercion captures the free a'.  That's
  86                                 -- why coercions are (CoreExpr -> CoreExpr), rather than
  87                                 -- just CoreExpr (with a functional type)
  88
  89         bind_fvs :: NameSet     -- After the renamer, this contains a superset of the
  90                                 -- Names of the other binders in this binding group that
  91                                 -- are free in the RHS of the defn
  92                                 -- Before renaming, and after typechecking,
  93                                 -- the field is unused; it's just an error thunk
  94     }
  95
  96   | PatBind {   -- The pattern is never a simple variable;
  97                 -- That case is done by FunBind
  98         pat_lhs    :: LPat id,
  99         pat_rhs    :: GRHSs id,
 100         pat_rhs_ty :: PostTcType,       -- Type of the GRHSs
 101         bind_fvs   :: NameSet           -- Same as for FunBind
 102     }
 103
 104   | VarBind {   -- Dictionary binding and suchlike
 105         var_id :: id,           -- All VarBinds are introduced by the type checker
 106         var_rhs :: LHsExpr id   -- Located only for consistency
 107     }
 108
 109   | AbsBinds {                                  -- Binds abstraction; TRANSLATION
 110         abs_tvs     :: [TyVar],
 111         abs_dicts   :: [DictId],
 112         abs_exports :: [([TyVar], id, id, [Prag])],     -- (tvs, poly_id, mono_id, prags)
 113         abs_binds   :: LHsBinds id              -- The dictionary bindings and typechecked user bindings
 114                                                 -- mixed up together; you can tell the dict bindings because
 115                                                 -- they are all VarBinds
 116     }
 117         -- Consider (AbsBinds tvs ds [(ftvs, poly_f, mono_f) binds]
 118         --
 119         -- Creates bindings for (polymorphic, overloaded) poly_f
 120         -- in terms of monomorphic, non-overloaded mono_f
 121         --
 122         -- Invariants:
 123         --      1. 'binds' binds mono_f
 124         --      2. ftvs is a subset of tvs
 125         --      3. ftvs includes all tyvars free in ds
 126         --
 127         -- See section 9 of static semantics paper for more details.
 128         -- (You can get a PhD for explaining the True Meaning
 129         --  of this last construct.)
 130
 131 placeHolderNames :: NameSet
 132 -- Used for the NameSet in FunBind and PatBind prior to the renamer
 133 placeHolderNames = panic "placeHolderNames"
 134
 135 ------------
 136 instance OutputableBndr id => Outputable (HsLocalBinds id) where
 137   ppr (HsValBinds bs) = ppr bs
 138   ppr (HsIPBinds bs)  = ppr bs
 139   ppr EmptyLocalBinds = empty
 140
 141 instance OutputableBndr id => Outputable (HsValBinds id) where
 142   ppr (ValBindsIn binds sigs)
 143    = pprValBindsForUser binds sigs
 144
 145   ppr (ValBindsOut sccs sigs)
 146     = getPprStyle $ \ sty ->
 147       if debugStyle sty then    -- Print with sccs showing
 148         vcat (map ppr sigs) $$ vcat (map ppr_scc sccs)
 149      else
 150         pprValBindsForUser (unionManyBags (map snd sccs)) sigs
 151    where
 152      ppr_scc (rec_flag, binds) = pp_rec rec_flag <+> pprLHsBinds binds
 153      pp_rec Recursive    = ptext SLIT("rec")
 154      pp_rec NonRecursive = ptext SLIT("nonrec")
 155
 156 --  *not* pprLHsBinds because we don't want braces; 'let' and
 157 -- 'where' include a list of HsBindGroups and we don't want
 158 -- several groups of bindings each with braces around.
 159 -- Sort by location before printing
 160 pprValBindsForUser :: (OutputableBndr id1, OutputableBndr id2)
 161                    => LHsBinds id1 -> [LSig id2] -> SDoc
 162 pprValBindsForUser binds sigs
 163   = vcat (map snd (sort_by_loc decls))
 164   where
 165
 166     decls :: [(SrcSpan, SDoc)]
 167     decls = [(loc, ppr sig)  | L loc sig <- sigs] ++
 168             [(loc, ppr bind) | L loc bind <- bagToList binds]
 169
 170     sort_by_loc decls = sortLe (\(l1,_) (l2,_) -> l1 <= l2) decls
 171
 172 pprLHsBinds :: OutputableBndr id => LHsBinds id -> SDoc
 173 pprLHsBinds binds
 174   | isEmptyLHsBinds binds = empty
 175   | otherwise = lbrace <+> vcat (map ppr (bagToList binds)) <+> rbrace
 176
 177 ------------
 178 emptyLocalBinds :: HsLocalBinds a
 179 emptyLocalBinds = EmptyLocalBinds
 180
 181 isEmptyLocalBinds :: HsLocalBinds a -> Bool
 182 isEmptyLocalBinds (HsValBinds ds) = isEmptyValBinds ds
 183 isEmptyLocalBinds (HsIPBinds ds)  = isEmptyIPBinds ds
 184 isEmptyLocalBinds EmptyLocalBinds = True
 185
 186 isEmptyValBinds :: HsValBinds a -> Bool
 187 isEmptyValBinds (ValBindsIn ds sigs)  = isEmptyLHsBinds ds && null sigs
 188 isEmptyValBinds (ValBindsOut ds sigs) = null ds && null sigs
 189
 190 emptyValBindsIn, emptyValBindsOut :: HsValBinds a
 191 emptyValBindsIn  = ValBindsIn emptyBag []
 192 emptyValBindsOut = ValBindsOut []      []
 193
 194 emptyLHsBinds :: LHsBinds id
 195 emptyLHsBinds = emptyBag
 196
 197 isEmptyLHsBinds :: LHsBinds id -> Bool
 198 isEmptyLHsBinds = isEmptyBag
 199
 200 ------------
 201 plusHsValBinds :: HsValBinds a -> HsValBinds a -> HsValBinds a
 202 plusHsValBinds (ValBindsIn ds1 sigs1) (ValBindsIn ds2 sigs2)
 203   = ValBindsIn (ds1 `unionBags` ds2) (sigs1 ++ sigs2)
 204 plusHsValBinds (ValBindsOut ds1 sigs1) (ValBindsOut ds2 sigs2)
 205   = ValBindsOut (ds1 ++ ds2) (sigs1 ++ sigs2)
 206 \end{code}
 207
 208 What AbsBinds means
 209 ~~~~~~~~~~~~~~~~~~~
 210          AbsBinds tvs
 211                   [d1,d2]
 212                   [(tvs1, f1p, f1m),
 213                    (tvs2, f2p, f2m)]
 214                   BIND
 215 means
 216
 217         f1p = /\ tvs -> \ [d1,d2] -> letrec DBINDS and BIND
 218                                       in fm
 219
 220         gp = ...same again, with gm instead of fm
 221
 222 This is a pretty bad translation, because it duplicates all the bindings.
 223 So the desugarer tries to do a better job:
 224
 225         fp = /\ [a,b] -> \ [d1,d2] -> case tp [a,b] [d1,d2] of
 226                                         (fm,gm) -> fm
 227         ..ditto for gp..
 228
 229         tp = /\ [a,b] -> \ [d1,d2] -> letrec DBINDS and BIND
 230                                        in (fm,gm)
 231
 232 \begin{code}
 233 instance OutputableBndr id => Outputable (HsBind id) where
 234     ppr mbind = ppr_monobind mbind
 235
 236 ppr_monobind :: OutputableBndr id => HsBind id -> SDoc
 237
 238 ppr_monobind (PatBind { pat_lhs = pat, pat_rhs = grhss })      = pprPatBind pat grhss
 239 ppr_monobind (VarBind { var_id = var, var_rhs = rhs })         = ppr var <+> equals <+> pprExpr (unLoc rhs)
 240 ppr_monobind (FunBind { fun_id = fun, fun_matches = matches }) = pprFunBind (unLoc fun) matches
 241       -- ToDo: print infix if appropriate
 242
 243 ppr_monobind (AbsBinds { abs_tvs = tyvars, abs_dicts = dictvars,
 244                          abs_exports = exports, abs_binds = val_binds })
 245      = sep [ptext SLIT("AbsBinds"),
 246             brackets (interpp'SP tyvars),
 247             brackets (interpp'SP dictvars),
 248             brackets (sep (punctuate comma (map ppr_exp exports)))]
 249        $$
 250        nest 2 ( vcat [pprBndr LetBind x | (_,x,_,_) <- exports]
 251                         -- Print type signatures
 252                 $$ pprLHsBinds val_binds )
 253   where
 254     ppr_exp (tvs, gbl, lcl, prags)
 255         = vcat [ppr gbl <+> ptext SLIT("<=") <+> ppr tvs <+> ppr lcl,
 256                 nest 2 (vcat (map (pprPrag gbl) prags))]
 257 \end{code}
 258
 259 %************************************************************************
 260 %*                                                                      *
 261                 Implicit parameter bindings
 262 %*                                                                      *
 263 %************************************************************************
 264
 265 \begin{code}
 266 data HsIPBinds id
 267   = IPBinds
 268         [LIPBind id]
 269         (DictBinds id)  -- Only in typechecker output; binds
 270                         -- uses of the implicit parameters
 271
 272 isEmptyIPBinds :: HsIPBinds id -> Bool
 273 isEmptyIPBinds (IPBinds is ds) = null is && isEmptyBag ds
 274
 275 type LIPBind id = Located (IPBind id)
 276
 277 -- | Implicit parameter bindings.
 278 data IPBind id
 279   = IPBind
 280         (IPName id)
 281         (LHsExpr id)
 282
 283 instance (OutputableBndr id) => Outputable (HsIPBinds id) where
 284   ppr (IPBinds bs ds) = vcat (map ppr bs)
 285                         $$ pprLHsBinds ds
 286
 287 instance (OutputableBndr id) => Outputable (IPBind id) where
 288   ppr (IPBind id rhs) = pprBndr LetBind id <+> equals <+> pprExpr (unLoc rhs)
 289 \end{code}
 290
 291
 292 %************************************************************************
 293 %*                                                                      *
 294 \subsection{Coercion functions}
 295 %*                                                                      *
 296 %************************************************************************
 297
 298 \begin{code}
 299 -- A Coercion is an expression with a hole in it
 300 -- We need coercions to have concrete form so that we can zonk them
 301
 302 data ExprCoFn
 303   = CoHole                      -- The identity coercion
 304   | CoCompose ExprCoFn ExprCoFn
 305   | CoApps ExprCoFn [Id]                -- Non-empty list
 306   | CoTyApps ExprCoFn [Type]            --   in all of these
 307   | CoLams [Id] ExprCoFn                --   so that the identity coercion
 308   | CoTyLams [TyVar] ExprCoFn           --   is just Hole
 309   | CoLet (LHsBinds Id) ExprCoFn        -- Would be nicer to be core bindings
 310
 311 (<.>) :: ExprCoFn -> ExprCoFn -> ExprCoFn
 312 (<.>) = CoCompose
 313
 314 idCoercion :: ExprCoFn
 315 idCoercion = CoHole
 316
 317 isIdCoercion :: ExprCoFn -> Bool
 318 isIdCoercion CoHole = True
 319 isIdCoercion other  = False
 320 \end{code}
 321
 322
 323 %************************************************************************
 324 %*                                                                      *
 325 \subsection{@Sig@: type signatures and value-modifying user pragmas}
 326 %*                                                                      *
 327 %************************************************************************
 328
 329 It is convenient to lump ``value-modifying'' user-pragmas (e.g.,
 330 ``specialise this function to these four types...'') in with type
 331 signatures.  Then all the machinery to move them into place, etc.,
 332 serves for both.
 333
 334 \begin{code}
 335 type LSig name = Located (Sig name)
 336
 337 data Sig name
 338   = TypeSig     (Located name)  -- A bog-std type signature
 339                 (LHsType name)
 340
 341   | SpecSig     (Located name)  -- Specialise a function or datatype ...
 342                 (LHsType name)  -- ... to these types
 343                 InlineSpec
 344
 345   | InlineSig   (Located name)  -- Function name
 346                 InlineSpec
 347
 348   | SpecInstSig (LHsType name)  -- (Class tys); should be a specialisation of the
 349                                 -- current instance decl
 350
 351   | FixSig      (FixitySig name)        -- Fixity declaration
 352
 353 type LFixitySig name = Located (FixitySig name)
 354 data FixitySig name = FixitySig (Located name) Fixity
 355
 356 -- A Prag conveys pragmas from the type checker to the desugarer
 357 data Prag
 358   = InlinePrag
 359         InlineSpec
 360
 361   | SpecPrag
 362         (HsExpr Id)     -- An expression, of the given specialised type, which
 363         PostTcType      -- specialises the polymorphic function
 364         [Id]            -- Dicts mentioned free in the expression
 365         InlineSpec      -- Inlining spec for the specialised function
 366
 367 isInlinePrag (InlinePrag _) = True
 368 isInlinePrag prag           = False
 369
 370 isSpecPrag (SpecPrag _ _ _ _) = True
 371 isSpecPrag prag               = False
 372 \end{code}
 373
 374 \begin{code}
 375 okBindSig :: NameSet -> LSig Name -> Bool
 376 okBindSig ns sig = sigForThisGroup ns sig
 377
 378 okHsBootSig :: LSig Name -> Bool
 379 okHsBootSig (L _ (TypeSig  _ _)) = True
 380 okHsBootSig (L _ (FixSig _))     = True
 381 okHsBootSig sig                  = False
 382
 383 okClsDclSig :: LSig Name -> Bool
 384 okClsDclSig (L _ (SpecInstSig _)) = False
 385 okClsDclSig sig                   = True        -- All others OK
 386
 387 okInstDclSig :: NameSet -> LSig Name -> Bool
 388 okInstDclSig ns lsig@(L _ sig) = ok ns sig
 389   where
 390     ok ns (TypeSig _ _)   = False
 391     ok ns (FixSig _)      = False
 392     ok ns (SpecInstSig _) = True
 393     ok ns sig             = sigForThisGroup ns lsig
 394
 395 sigForThisGroup :: NameSet -> LSig Name -> Bool
 396 sigForThisGroup ns sig
 397   = case sigName sig of
 398         Nothing -> False
 399         Just n  -> n `elemNameSet` ns
 400
 401 sigName :: LSig name -> Maybe name
 402 sigName (L _ sig) = f sig
 403  where
 404     f (TypeSig   n _)          = Just (unLoc n)
 405     f (SpecSig   n _ _)        = Just (unLoc n)
 406     f (InlineSig n _)          = Just (unLoc n)
 407     f (FixSig (FixitySig n _)) = Just (unLoc n)
 408     f other                     = Nothing
 409
 410 isFixityLSig :: LSig name -> Bool
 411 isFixityLSig (L _ (FixSig {})) = True
 412 isFixityLSig _                 = False
 413
 414 isVanillaLSig :: LSig name -> Bool
 415 isVanillaLSig (L _(TypeSig {})) = True
 416 isVanillaLSig sig               = False
 417
 418 isSpecLSig :: LSig name -> Bool
 419 isSpecLSig (L _(SpecSig {})) = True
 420 isSpecLSig sig               = False
 421
 422 isSpecInstLSig (L _ (SpecInstSig {})) = True
 423 isSpecInstLSig sig                    = False
 424
 425 isPragLSig :: LSig name -> Bool
 426         -- Identifies pragmas
 427 isPragLSig (L _ (SpecSig {}))   = True
 428 isPragLSig (L _ (InlineSig {})) = True
 429 isPragLSig other                = False
 430
 431 isInlineLSig :: LSig name -> Bool
 432         -- Identifies inline pragmas
 433 isInlineLSig (L _ (InlineSig {})) = True
 434 isInlineLSig other                = False
 435
 436 hsSigDoc (TypeSig {})           = ptext SLIT("type signature")
 437 hsSigDoc (SpecSig {})           = ptext SLIT("SPECIALISE pragma")
 438 hsSigDoc (InlineSig _ spec)     = ppr spec <+> ptext SLIT("pragma")
 439 hsSigDoc (SpecInstSig {})       = ptext SLIT("SPECIALISE instance pragma")
 440 hsSigDoc (FixSig {})            = ptext SLIT("fixity declaration")
 441 \end{code}
 442
 443 Signature equality is used when checking for duplicate signatures
 444
 445 \begin{code}
 446 eqHsSig :: LSig Name -> LSig Name -> Bool
 447 eqHsSig (L _ (FixSig (FixitySig n1 _))) (L _ (FixSig (FixitySig n2 _))) = unLoc n1 == unLoc n2
 448 eqHsSig (L _ (TypeSig n1 _))            (L _ (TypeSig n2 _))            = unLoc n1 == unLoc n2
 449 eqHsSig (L _ (InlineSig n1 s1)) (L _ (InlineSig n2 s2))                 = s1 == s2 && unLoc n1 == unLoc n2
 450         -- For specialisations, we don't have equality over
 451         -- HsType, so it's not convenient to spot duplicate
 452         -- specialisations here.  Check for this later, when we're in Type land
 453 eqHsSig _other1 _other2 = False
 454 \end{code}
 455
 456 \begin{code}
 457 instance (OutputableBndr name) => Outputable (Sig name) where
 458     ppr sig = ppr_sig sig
 459
 460 ppr_sig :: OutputableBndr name => Sig name -> SDoc
 461 ppr_sig (TypeSig var ty)          = pprVarSig (unLoc var) ty
 462 ppr_sig (FixSig fix_sig)          = ppr fix_sig
 463 ppr_sig (SpecSig var ty inl)      = pragBrackets (pprSpec var ty inl)
 464 ppr_sig (InlineSig var inl)       = pragBrackets (ppr inl <+> ppr var)
 465 ppr_sig (SpecInstSig ty)          = pragBrackets (ptext SLIT("SPECIALIZE instance") <+> ppr ty)
 466
 467 instance Outputable name => Outputable (FixitySig name) where
 468   ppr (FixitySig name fixity) = sep [ppr fixity, ppr name]
 469
 470 pragBrackets :: SDoc -> SDoc
 471 pragBrackets doc = ptext SLIT("{-#") <+> doc <+> ptext SLIT("#-}")
 472
 473 pprVarSig :: (Outputable id, Outputable ty) => id -> ty -> SDoc
 474 pprVarSig var ty = sep [ppr var <+> dcolon, nest 2 (ppr ty)]
 475
 476 pprSpec :: (Outputable id, Outputable ty) => id -> ty -> InlineSpec -> SDoc
 477 pprSpec var ty inl = sep [ptext SLIT("SPECIALIZE") <+> ppr inl <+> pprVarSig var ty]
 478
 479 pprPrag :: Outputable id => id -> Prag -> SDoc
 480 pprPrag var (InlinePrag inl)         = ppr inl <+> ppr var
 481 pprPrag var (SpecPrag expr ty _ inl) = pprSpec var ty inl
 482 \end{code}