compiler/hsSyn/HsExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsExpr]{Abstract Haskell syntax: expressions}
   5
   6 \begin{code}
   7 module HsExpr where
   8
   9 #include "HsVersions.h"
  10
  11 -- friends:
  12 import HsDecls          ( HsGroup )
  13 import HsPat            ( LPat )
  14 import HsLit            ( HsLit(..), HsOverLit )
  15 import HsTypes          ( LHsType, PostTcType )
  16 import HsImpExp         ( isOperator, pprHsVar )
  17 import HsBinds          ( HsLocalBinds, DictBinds, ExprCoFn, isEmptyLocalBinds )
  18
  19 -- others:
  20 import Type             ( Type, pprParendType )
  21 import Var              ( TyVar, Id )
  22 import Name             ( Name )
  23 import BasicTypes       ( IPName, Boxity, tupleParens, Arity, Fixity(..) )
  24 import SrcLoc           ( Located(..), unLoc )
  25 import Outputable
  26 import FastString
  27 \end{code}
  28
  29
  30 %************************************************************************
  31 %*                                                                      *
  32 \subsection{Expressions proper}
  33 %*                                                                      *
  34 %************************************************************************
  35
  36 \begin{code}
  37 type LHsExpr id = Located (HsExpr id)
  38
  39 -------------------------
  40 -- PostTcExpr is an evidence expression attached to the
  41 -- syntax tree by the type checker (c.f. postTcType)
  42 -- We use a PostTcTable where there are a bunch of pieces of
  43 -- evidence, more than is convenient to keep individually
  44 type PostTcExpr  = HsExpr Id
  45 type PostTcTable = [(Name, Id)]
  46
  47 noPostTcExpr :: PostTcExpr
  48 noPostTcExpr = HsLit (HsString FSLIT("noPostTcExpr"))
  49
  50 noPostTcTable :: PostTcTable
  51 noPostTcTable = []
  52
  53 -------------------------
  54 -- SyntaxExpr is like PostTcExpr, but it's filled in a little earlier,
  55 -- by the renamer.  It's used for rebindable syntax.
  56 -- E.g. (>>=) is filled in before the renamer by the appropriate Name
  57 --      for (>>=), and then instantiated by the type checker with its
  58 --      type args tec
  59
  60 type SyntaxExpr id = HsExpr id
  61
  62 noSyntaxExpr :: SyntaxExpr id   -- Before renaming, and sometimes after,
  63                                 -- (if the syntax slot makes no sense)
  64 noSyntaxExpr = HsLit (HsString FSLIT("noSyntaxExpr"))
  65
  66
  67 type SyntaxTable id = [(Name, SyntaxExpr id)]
  68 --      *** Currently used only for CmdTop (sigh) ***
  69 -- * Before the renamer, this list is noSyntaxTable
  70 --
  71 -- * After the renamer, it takes the form [(std_name, HsVar actual_name)]
  72 --   For example, for the 'return' op of a monad
  73 --      normal case:            (GHC.Base.return, HsVar GHC.Base.return)
  74 --      with rebindable syntax: (GHC.Base.return, return_22)
  75 --              where return_22 is whatever "return" is in scope
  76 --
  77 -- * After the type checker, it takes the form [(std_name, <expression>)]
  78 --      where <expression> is the evidence for the method
  79
  80 noSyntaxTable :: SyntaxTable id
  81 noSyntaxTable = []
  82
  83
  84 -------------------------
  85 data HsExpr id
  86   = HsVar       id              -- variable
  87   | HsIPVar     (IPName id)     -- implicit parameter
  88   | HsOverLit   (HsOverLit id)  -- Overloaded literals
  89   | HsLit       HsLit           -- Simple (non-overloaded) literals
  90
  91   | HsLam       (MatchGroup  id)        -- Currently always a single match
  92
  93   | HsApp       (LHsExpr id)            -- Application
  94                 (LHsExpr id)
  95
  96   -- Operator applications:
  97   -- NB Bracketed ops such as (+) come out as Vars.
  98
  99   -- NB We need an expr for the operator in an OpApp/Section since
 100   -- the typechecker may need to apply the operator to a few types.
 101
 102   | OpApp       (LHsExpr id)    -- left operand
 103                 (LHsExpr id)    -- operator
 104                 Fixity          -- Renamer adds fixity; bottom until then
 105                 (LHsExpr id)    -- right operand
 106
 107   | NegApp      (LHsExpr id)    -- negated expr
 108                 (SyntaxExpr id) -- Name of 'negate'
 109
 110   | HsPar       (LHsExpr id)    -- parenthesised expr
 111
 112   | SectionL    (LHsExpr id)    -- operand
 113                 (LHsExpr id)    -- operator
 114   | SectionR    (LHsExpr id)    -- operator
 115                 (LHsExpr id)    -- operand
 116
 117   | HsCase      (LHsExpr id)
 118                 (MatchGroup id)
 119
 120   | HsIf        (LHsExpr id)    --  predicate
 121                 (LHsExpr id)    --  then part
 122                 (LHsExpr id)    --  else part
 123
 124   | HsLet       (HsLocalBinds id) -- let(rec)
 125                 (LHsExpr  id)
 126
 127   | HsDo        (HsStmtContext Name)    -- The parameterisation is unimportant
 128                                         -- because in this context we never use
 129                                         -- the PatGuard or ParStmt variant
 130                 [LStmt id]              -- "do":one or more stmts
 131                 (LHsExpr id)            -- The body; the last expression in the 'do'
 132                                         --           of [ body | ... ] in a list comp
 133                 PostTcType              -- Type of the whole expression
 134
 135   | ExplicitList                -- syntactic list
 136                 PostTcType      -- Gives type of components of list
 137                 [LHsExpr id]
 138
 139   | ExplicitPArr                -- syntactic parallel array: [:e1, ..., en:]
 140                 PostTcType      -- type of elements of the parallel array
 141                 [LHsExpr id]
 142
 143   | ExplicitTuple               -- tuple
 144                 [LHsExpr id]
 145                                 -- NB: Unit is ExplicitTuple []
 146                                 -- for tuples, we can get the types
 147                                 -- direct from the components
 148                 Boxity
 149
 150
 151         -- Record construction
 152   | RecordCon   (Located id)            -- The constructor.  After type checking
 153                                         -- it's the dataConWrapId of the constructor
 154                 PostTcExpr              -- Data con Id applied to type args
 155                 (HsRecordBinds id)
 156
 157         -- Record update
 158   | RecordUpd   (LHsExpr id)
 159                 (HsRecordBinds id)
 160                 PostTcType              -- Type of *input* record
 161                 PostTcType              -- Type of *result* record (may differ from
 162                                         --      type of input record)
 163
 164   | ExprWithTySig                       -- e :: type
 165                 (LHsExpr id)
 166                 (LHsType id)
 167
 168   | ExprWithTySigOut                    -- TRANSLATION
 169                 (LHsExpr id)
 170                 (LHsType Name)          -- Retain the signature for round-tripping purposes
 171
 172   | ArithSeq                            -- arithmetic sequence
 173                 PostTcExpr
 174                 (ArithSeqInfo id)
 175
 176   | PArrSeq                             -- arith. sequence for parallel array
 177                 PostTcExpr              -- [:e1..e2:] or [:e1, e2..e3:]
 178                 (ArithSeqInfo id)
 179
 180   | HsSCC       FastString      -- "set cost centre" (_scc_) annotation
 181                 (LHsExpr id)    -- expr whose cost is to be measured
 182
 183   | HsCoreAnn   FastString      -- hdaume: core annotation
 184                 (LHsExpr id)
 185
 186   -----------------------------------------------------------
 187   -- MetaHaskell Extensions
 188   | HsBracket    (HsBracket id)
 189
 190   | HsBracketOut (HsBracket Name)       -- Output of the type checker is the *original*
 191                  [PendingSplice]        -- renamed expression, plus *typechecked* splices
 192                                         -- to be pasted back in by the desugarer
 193
 194   | HsSpliceE (HsSplice id)
 195
 196   -----------------------------------------------------------
 197   -- Arrow notation extension
 198
 199   | HsProc      (LPat id)               -- arrow abstraction, proc
 200                 (LHsCmdTop id)          -- body of the abstraction
 201                                         -- always has an empty stack
 202
 203   ---------------------------------------
 204   -- The following are commands, not expressions proper
 205
 206   | HsArrApp    -- Arrow tail, or arrow application (f -< arg)
 207         (LHsExpr id)    -- arrow expression, f
 208         (LHsExpr id)    -- input expression, arg
 209         PostTcType      -- type of the arrow expressions f,
 210                         -- of the form a t t', where arg :: t
 211         HsArrAppType    -- higher-order (-<<) or first-order (-<)
 212         Bool            -- True => right-to-left (f -< arg)
 213                         -- False => left-to-right (arg >- f)
 214
 215   | HsArrForm   -- Command formation,  (| e cmd1 .. cmdn |)
 216         (LHsExpr id)    -- the operator
 217                         -- after type-checking, a type abstraction to be
 218                         -- applied to the type of the local environment tuple
 219         (Maybe Fixity)  -- fixity (filled in by the renamer), for forms that
 220                         -- were converted from OpApp's by the renamer
 221         [LHsCmdTop id]  -- argument commands
 222 \end{code}
 223
 224
 225 These constructors only appear temporarily in the parser.
 226 The renamer translates them into the Right Thing.
 227
 228 \begin{code}
 229   | EWildPat                    -- wildcard
 230
 231   | EAsPat      (Located id)    -- as pattern
 232                 (LHsExpr id)
 233
 234   | ELazyPat    (LHsExpr id) -- ~ pattern
 235
 236   | HsType      (LHsType id)     -- Explicit type argument; e.g  f {| Int |} x y
 237 \end{code}
 238
 239 Everything from here on appears only in typechecker output.
 240
 241 \begin{code}
 242   | TyLam                       -- TRANSLATION
 243                 [TyVar]
 244                 (LHsExpr id)
 245   | TyApp                       -- TRANSLATION
 246                 (LHsExpr id) -- generated by Spec
 247                 [Type]
 248
 249   -- DictLam and DictApp are "inverses"
 250   |  DictLam
 251                 [id]
 252                 (LHsExpr id)
 253   |  DictApp
 254                 (LHsExpr id)
 255                 [id]
 256
 257   |  HsCoerce   ExprCoFn        -- TRANSLATION
 258                 (HsExpr id)
 259
 260 type PendingSplice = (Name, LHsExpr Id) -- Typechecked splices, waiting to be
 261                                         -- pasted back in by the desugarer
 262 \end{code}
 263
 264 A @Dictionary@, unless of length 0 or 1, becomes a tuple.  A
 265 @ClassDictLam dictvars methods expr@ is, therefore:
 266 \begin{verbatim}
 267 \ x -> case x of ( dictvars-and-methods-tuple ) -> expr
 268 \end{verbatim}
 269
 270 \begin{code}
 271 instance OutputableBndr id => Outputable (HsExpr id) where
 272     ppr expr = pprExpr expr
 273 \end{code}
 274
 275 \begin{code}
 276 pprExpr :: OutputableBndr id => HsExpr id -> SDoc
 277
 278 pprExpr  e = pprDeeper (ppr_expr e)
 279
 280 pprBinds :: OutputableBndr id => HsLocalBinds id -> SDoc
 281 pprBinds b = pprDeeper (ppr b)
 282
 283 ppr_lexpr :: OutputableBndr id => LHsExpr id -> SDoc
 284 ppr_lexpr e = ppr_expr (unLoc e)
 285
 286 ppr_expr (HsVar v)       = pprHsVar v
 287 ppr_expr (HsIPVar v)     = ppr v
 288 ppr_expr (HsLit lit)     = ppr lit
 289 ppr_expr (HsOverLit lit) = ppr lit
 290
 291 ppr_expr (HsApp e1 e2)
 292   = let (fun, args) = collect_args e1 [e2] in
 293     (ppr_lexpr fun) <+> (sep (map pprParendExpr args))
 294   where
 295     collect_args (L _ (HsApp fun arg)) args = collect_args fun (arg:args)
 296     collect_args fun args = (fun, args)
 297
 298 ppr_expr (OpApp e1 op fixity e2)
 299   = case unLoc op of
 300       HsVar v -> pp_infixly v
 301       _       -> pp_prefixly
 302   where
 303     pp_e1 = pprParendExpr e1            -- Add parens to make precedence clear
 304     pp_e2 = pprParendExpr e2
 305
 306     pp_prefixly
 307       = hang (ppr op) 4 (sep [pp_e1, pp_e2])
 308
 309     pp_infixly v
 310       = sep [pp_e1, hsep [pprInfix v, pp_e2]]
 311
 312 ppr_expr (NegApp e _) = char '-' <+> pprParendExpr e
 313
 314 ppr_expr (HsPar e) = parens (ppr_lexpr e)
 315
 316 ppr_expr (SectionL expr op)
 317   = case unLoc op of
 318       HsVar v -> pp_infixly v
 319       _       -> pp_prefixly
 320   where
 321     pp_expr = pprParendExpr expr
 322
 323     pp_prefixly = hang (hsep [text " \\ x_ ->", ppr op])
 324                        4 (hsep [pp_expr, ptext SLIT("x_ )")])
 325     pp_infixly v = parens (sep [pp_expr, pprInfix v])
 326
 327 ppr_expr (SectionR op expr)
 328   = case unLoc op of
 329       HsVar v -> pp_infixly v
 330       _       -> pp_prefixly
 331   where
 332     pp_expr = pprParendExpr expr
 333
 334     pp_prefixly = hang (hsep [text "( \\ x_ ->", ppr op, ptext SLIT("x_")])
 335                        4 ((<>) pp_expr rparen)
 336     pp_infixly v
 337       = parens (sep [pprInfix v, pp_expr])
 338
 339 ppr_expr (HsLam matches)
 340   = pprMatches LambdaExpr matches
 341
 342 ppr_expr (HsCase expr matches)
 343   = sep [ sep [ptext SLIT("case"), nest 4 (ppr expr), ptext SLIT("of")],
 344             nest 2 (pprMatches CaseAlt matches) ]
 345
 346 ppr_expr (HsIf e1 e2 e3)
 347   = sep [hsep [ptext SLIT("if"), nest 2 (ppr e1), ptext SLIT("then")],
 348            nest 4 (ppr e2),
 349            ptext SLIT("else"),
 350            nest 4 (ppr e3)]
 351
 352 -- special case: let ... in let ...
 353 ppr_expr (HsLet binds expr@(L _ (HsLet _ _)))
 354   = sep [hang (ptext SLIT("let")) 2 (hsep [pprBinds binds, ptext SLIT("in")]),
 355          ppr_lexpr expr]
 356
 357 ppr_expr (HsLet binds expr)
 358   = sep [hang (ptext SLIT("let")) 2 (pprBinds binds),
 359          hang (ptext SLIT("in"))  2 (ppr expr)]
 360
 361 ppr_expr (HsDo do_or_list_comp stmts body _) = pprDo do_or_list_comp stmts body
 362
 363 ppr_expr (ExplicitList _ exprs)
 364   = brackets (fsep (punctuate comma (map ppr_lexpr exprs)))
 365
 366 ppr_expr (ExplicitPArr _ exprs)
 367   = pa_brackets (fsep (punctuate comma (map ppr_lexpr exprs)))
 368
 369 ppr_expr (ExplicitTuple exprs boxity)
 370   = tupleParens boxity (sep (punctuate comma (map ppr_lexpr exprs)))
 371
 372 ppr_expr (RecordCon con_id con_expr rbinds)
 373   = pp_rbinds (ppr con_id) rbinds
 374
 375 ppr_expr (RecordUpd aexp rbinds _ _)
 376   = pp_rbinds (pprParendExpr aexp) rbinds
 377
 378 ppr_expr (ExprWithTySig expr sig)
 379   = hang (nest 2 (ppr_lexpr expr) <+> dcolon)
 380          4 (ppr sig)
 381 ppr_expr (ExprWithTySigOut expr sig)
 382   = hang (nest 2 (ppr_lexpr expr) <+> dcolon)
 383          4 (ppr sig)
 384
 385 ppr_expr (ArithSeq expr info) = brackets (ppr info)
 386 ppr_expr (PArrSeq expr info)  = pa_brackets (ppr info)
 387
 388 ppr_expr EWildPat     = char '_'
 389 ppr_expr (ELazyPat e) = char '~' <> pprParendExpr e
 390 ppr_expr (EAsPat v e) = ppr v <> char '@' <> pprParendExpr e
 391
 392 ppr_expr (HsSCC lbl expr)
 393   = sep [ ptext SLIT("_scc_") <+> doubleQuotes (ftext lbl), pprParendExpr expr ]
 394
 395 ppr_expr (TyLam tyvars expr)
 396   = hang (hsep [ptext SLIT("/\\"),
 397                 hsep (map (pprBndr LambdaBind) tyvars),
 398                 ptext SLIT("->")])
 399          4 (ppr_lexpr expr)
 400
 401 ppr_expr (TyApp expr [ty])
 402   = hang (ppr_lexpr expr) 4 (pprParendType ty)
 403
 404 ppr_expr (TyApp expr tys)
 405   = hang (ppr_lexpr expr)
 406          4 (brackets (interpp'SP tys))
 407
 408 ppr_expr (DictLam dictvars expr)
 409   = hang (hsep [ptext SLIT("\\{-dict-}"),
 410                 hsep (map (pprBndr LambdaBind) dictvars),
 411                 ptext SLIT("->")])
 412          4 (ppr_lexpr expr)
 413
 414 ppr_expr (DictApp expr [dname])
 415   = hang (ppr_lexpr expr) 4 (ppr dname)
 416
 417 ppr_expr (DictApp expr dnames)
 418   = hang (ppr_lexpr expr)
 419          4 (brackets (interpp'SP dnames))
 420
 421 ppr_expr (HsCoerce co_fn e) = ppr_expr e
 422
 423 ppr_expr (HsType id) = ppr id
 424
 425 ppr_expr (HsSpliceE s)       = pprSplice s
 426 ppr_expr (HsBracket b)       = pprHsBracket b
 427 ppr_expr (HsBracketOut e []) = ppr e
 428 ppr_expr (HsBracketOut e ps) = ppr e $$ ptext SLIT("pending") <+> ppr ps
 429
 430 ppr_expr (HsProc pat (L _ (HsCmdTop cmd _ _ _)))
 431   = hsep [ptext SLIT("proc"), ppr pat, ptext SLIT("->"), ppr cmd]
 432
 433 ppr_expr (HsArrApp arrow arg _ HsFirstOrderApp True)
 434   = hsep [ppr_lexpr arrow, ptext SLIT("-<"), ppr_lexpr arg]
 435 ppr_expr (HsArrApp arrow arg _ HsFirstOrderApp False)
 436   = hsep [ppr_lexpr arg, ptext SLIT(">-"), ppr_lexpr arrow]
 437 ppr_expr (HsArrApp arrow arg _ HsHigherOrderApp True)
 438   = hsep [ppr_lexpr arrow, ptext SLIT("-<<"), ppr_lexpr arg]
 439 ppr_expr (HsArrApp arrow arg _ HsHigherOrderApp False)
 440   = hsep [ppr_lexpr arg, ptext SLIT(">>-"), ppr_lexpr arrow]
 441
 442 ppr_expr (HsArrForm (L _ (HsVar v)) (Just _) [arg1, arg2])
 443   = sep [pprCmdArg (unLoc arg1), hsep [pprInfix v, pprCmdArg (unLoc arg2)]]
 444 ppr_expr (HsArrForm op _ args)
 445   = hang (ptext SLIT("(|") <> ppr_lexpr op)
 446          4 (sep (map (pprCmdArg.unLoc) args) <> ptext SLIT("|)"))
 447
 448 pprCmdArg :: OutputableBndr id => HsCmdTop id -> SDoc
 449 pprCmdArg (HsCmdTop cmd@(L _ (HsArrForm _ Nothing [])) _ _ _)
 450   = ppr_lexpr cmd
 451 pprCmdArg (HsCmdTop cmd _ _ _)
 452   = parens (ppr_lexpr cmd)
 453
 454 -- Put a var in backquotes if it's not an operator already
 455 pprInfix :: Outputable name => name -> SDoc
 456 pprInfix v | isOperator ppr_v = ppr_v
 457            | otherwise        = char '`' <> ppr_v <> char '`'
 458            where
 459              ppr_v = ppr v
 460
 461 -- add parallel array brackets around a document
 462 --
 463 pa_brackets :: SDoc -> SDoc
 464 pa_brackets p = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 465 \end{code}
 466
 467 Parenthesize unless very simple:
 468 \begin{code}
 469 pprParendExpr :: OutputableBndr id => LHsExpr id -> SDoc
 470 pprParendExpr expr
 471   = let
 472         pp_as_was = ppr_lexpr expr
 473         -- Using ppr_expr here avoids the call to 'deeper'
 474         -- Not sure if that's always right.
 475     in
 476     case unLoc expr of
 477       HsLit l           -> ppr l
 478       HsOverLit l       -> ppr l
 479
 480       HsVar _           -> pp_as_was
 481       HsIPVar _         -> pp_as_was
 482       ExplicitList _ _  -> pp_as_was
 483       ExplicitPArr _ _  -> pp_as_was
 484       ExplicitTuple _ _ -> pp_as_was
 485       HsPar _           -> pp_as_was
 486       HsBracket _       -> pp_as_was
 487       HsBracketOut _ [] -> pp_as_was
 488
 489       _                 -> parens pp_as_was
 490 \end{code}
 491
 492 %************************************************************************
 493 %*                                                                      *
 494 \subsection{Commands (in arrow abstractions)}
 495 %*                                                                      *
 496 %************************************************************************
 497
 498 We re-use HsExpr to represent these.
 499
 500 \begin{code}
 501 type HsCmd id = HsExpr id
 502
 503 type LHsCmd id = LHsExpr id
 504
 505 data HsArrAppType = HsHigherOrderApp | HsFirstOrderApp
 506 \end{code}
 507
 508 The legal constructors for commands are:
 509
 510   = HsArrApp ...                -- as above
 511
 512   | HsArrForm ...               -- as above
 513
 514   | HsApp       (HsCmd id)
 515                 (HsExpr id)
 516
 517   | HsLam       (Match  id)     -- kappa
 518
 519   -- the renamer turns this one into HsArrForm
 520   | OpApp       (HsExpr id)     -- left operand
 521                 (HsCmd id)      -- operator
 522                 Fixity          -- Renamer adds fixity; bottom until then
 523                 (HsCmd id)      -- right operand
 524
 525   | HsPar       (HsCmd id)      -- parenthesised command
 526
 527   | HsCase      (HsExpr id)
 528                 [Match id]      -- bodies are HsCmd's
 529                 SrcLoc
 530
 531   | HsIf        (HsExpr id)     --  predicate
 532                 (HsCmd id)      --  then part
 533                 (HsCmd id)      --  else part
 534                 SrcLoc
 535
 536   | HsLet       (HsLocalBinds id)       -- let(rec)
 537                 (HsCmd  id)
 538
 539   | HsDo        (HsStmtContext Name)    -- The parameterisation is unimportant
 540                                         -- because in this context we never use
 541                                         -- the PatGuard or ParStmt variant
 542                 [Stmt id]       -- HsExpr's are really HsCmd's
 543                 PostTcType      -- Type of the whole expression
 544                 SrcLoc
 545
 546 Top-level command, introducing a new arrow.
 547 This may occur inside a proc (where the stack is empty) or as an
 548 argument of a command-forming operator.
 549
 550 \begin{code}
 551 type LHsCmdTop id = Located (HsCmdTop id)
 552
 553 data HsCmdTop id
 554   = HsCmdTop    (LHsCmd id)
 555                 [PostTcType]    -- types of inputs on the command's stack
 556                 PostTcType      -- return type of the command
 557                 (SyntaxTable id)
 558                                 -- after type checking:
 559                                 -- names used in the command's desugaring
 560 \end{code}
 561
 562 %************************************************************************
 563 %*                                                                      *
 564 \subsection{Record binds}
 565 %*                                                                      *
 566 %************************************************************************
 567
 568 \begin{code}
 569 type HsRecordBinds id = [(Located id, LHsExpr id)]
 570
 571 recBindFields :: HsRecordBinds id -> [id]
 572 recBindFields rbinds = [unLoc field | (field,_) <- rbinds]
 573
 574 pp_rbinds :: OutputableBndr id => SDoc -> HsRecordBinds id -> SDoc
 575 pp_rbinds thing rbinds
 576   = hang thing
 577          4 (braces (sep (punctuate comma (map (pp_rbind) rbinds))))
 578   where
 579     pp_rbind (v, e) = hsep [pprBndr LetBind (unLoc v), char '=', ppr e]
 580 \end{code}
 581
 582
 583
 584 %************************************************************************
 585 %*                                                                      *
 586 \subsection{@Match@, @GRHSs@, and @GRHS@ datatypes}
 587 %*                                                                      *
 588 %************************************************************************
 589
 590 @Match@es are sets of pattern bindings and right hand sides for
 591 functions, patterns or case branches. For example, if a function @g@
 592 is defined as:
 593 \begin{verbatim}
 594 g (x,y) = y
 595 g ((x:ys),y) = y+1,
 596 \end{verbatim}
 597 then \tr{g} has two @Match@es: @(x,y) = y@ and @((x:ys),y) = y+1@.
 598
 599 It is always the case that each element of an @[Match]@ list has the
 600 same number of @pats@s inside it.  This corresponds to saying that
 601 a function defined by pattern matching must have the same number of
 602 patterns in each equation.
 603
 604 \begin{code}
 605 data MatchGroup id
 606   = MatchGroup
 607         [LMatch id]     -- The alternatives
 608         PostTcType      -- The type is the type of the entire group
 609                         --      t1 -> ... -> tn -> tr
 610                         -- where there are n patterns
 611
 612 type LMatch id = Located (Match id)
 613
 614 data Match id
 615   = Match
 616         [LPat id]               -- The patterns
 617         (Maybe (LHsType id))    -- A type signature for the result of the match
 618                                 --      Nothing after typechecking
 619         (GRHSs id)
 620
 621 matchGroupArity :: MatchGroup id -> Arity
 622 matchGroupArity (MatchGroup (match:matches) _)
 623   = ASSERT( all ((== n_pats) . length . hsLMatchPats) matches )
 624         -- Assertion just checks that all the matches have the same number of pats
 625     n_pats
 626   where
 627     n_pats = length (hsLMatchPats match)
 628
 629 hsLMatchPats :: LMatch id -> [LPat id]
 630 hsLMatchPats (L _ (Match pats _ _)) = pats
 631
 632 -- GRHSs are used both for pattern bindings and for Matches
 633 data GRHSs id
 634   = GRHSs [LGRHS id]            -- Guarded RHSs
 635           (HsLocalBinds id)     -- The where clause
 636
 637 type LGRHS id = Located (GRHS id)
 638
 639 data GRHS id = GRHS [LStmt id]          -- Guards
 640                     (LHsExpr id)        -- Right hand side
 641 \end{code}
 642
 643 We know the list must have at least one @Match@ in it.
 644
 645 \begin{code}
 646 pprMatches :: (OutputableBndr id) => HsMatchContext id -> MatchGroup id -> SDoc
 647 pprMatches ctxt (MatchGroup matches _) = vcat (map (pprMatch ctxt) (map unLoc matches))
 648
 649 -- Exported to HsBinds, which can't see the defn of HsMatchContext
 650 pprFunBind :: (OutputableBndr id) => id -> MatchGroup id -> SDoc
 651 pprFunBind fun matches = pprMatches (FunRhs fun) matches
 652
 653 -- Exported to HsBinds, which can't see the defn of HsMatchContext
 654 pprPatBind :: (OutputableBndr bndr, OutputableBndr id)
 655            => LPat bndr -> GRHSs id -> SDoc
 656 pprPatBind pat grhss = sep [ppr pat, nest 4 (pprGRHSs PatBindRhs grhss)]
 657
 658
 659 pprMatch :: OutputableBndr id => HsMatchContext id -> Match id -> SDoc
 660 pprMatch ctxt (Match pats maybe_ty grhss)
 661   = pp_name ctxt <+> sep [sep (map ppr pats),
 662                      ppr_maybe_ty,
 663                      nest 2 (pprGRHSs ctxt grhss)]
 664   where
 665     pp_name (FunRhs fun) = ppr fun      -- Not pprBndr; the AbsBinds will
 666                                         -- have printed the signature
 667     pp_name LambdaExpr   = char '\\'
 668     pp_name other        = empty
 669
 670     ppr_maybe_ty = case maybe_ty of
 671                         Just ty -> dcolon <+> ppr ty
 672                         Nothing -> empty
 673
 674
 675 pprGRHSs :: OutputableBndr id => HsMatchContext id -> GRHSs id -> SDoc
 676 pprGRHSs ctxt (GRHSs grhss binds)
 677   = vcat (map (pprGRHS ctxt . unLoc) grhss)
 678     $$
 679     (if isEmptyLocalBinds binds then empty
 680      else text "where" $$ nest 4 (pprBinds binds))
 681
 682 pprGRHS :: OutputableBndr id => HsMatchContext id -> GRHS id -> SDoc
 683
 684 pprGRHS ctxt (GRHS [] expr)
 685  =  pp_rhs ctxt expr
 686
 687 pprGRHS ctxt (GRHS guards expr)
 688  = sep [char '|' <+> interpp'SP guards, pp_rhs ctxt expr]
 689
 690 pp_rhs ctxt rhs = matchSeparator ctxt <+> pprDeeper (ppr rhs)
 691 \end{code}
 692
 693 %************************************************************************
 694 %*                                                                      *
 695 \subsection{Do stmts and list comprehensions}
 696 %*                                                                      *
 697 %************************************************************************
 698
 699 \begin{code}
 700 type LStmt id = Located (Stmt id)
 701
 702 -- The SyntaxExprs in here are used *only* for do-notation, which
 703 -- has rebindable syntax.  Otherwise they are unused.
 704 data Stmt id
 705   = BindStmt    (LPat id)
 706                 (LHsExpr id)
 707                 (SyntaxExpr id)         -- The (>>=) operator
 708                 (SyntaxExpr id)         -- The fail operator
 709                 -- The fail operator is noSyntaxExpr
 710                 -- if the pattern match can't fail
 711
 712   | ExprStmt    (LHsExpr id)
 713                 (SyntaxExpr id)         -- The (>>) operator
 714                 PostTcType              -- Element type of the RHS (used for arrows)
 715
 716   | LetStmt     (HsLocalBinds id)
 717
 718         -- ParStmts only occur in a list comprehension
 719   | ParStmt     [([LStmt id], [id])]    -- After renaming, the ids are the binders
 720                                         -- bound by the stmts and used subsequently
 721
 722         -- Recursive statement (see Note [RecStmt] below)
 723   | RecStmt  [LStmt id]
 724                 --- The next two fields are only valid after renaming
 725              [id]       -- The ids are a subset of the variables bound by the stmts
 726                         -- that are used in stmts that follow the RecStmt
 727
 728              [id]       -- Ditto, but these variables are the "recursive" ones, that
 729                         -- are used before they are bound in the stmts of the RecStmt
 730                         -- From a type-checking point of view, these ones have to be monomorphic
 731
 732                 --- These fields are only valid after typechecking
 733              [PostTcExpr]       -- These expressions correspond
 734                                 -- 1-to-1 with the "recursive" [id], and are the expresions that
 735                                 -- should be returned by the recursion.  They may not quite be the
 736                                 -- Ids themselves, because the Id may be *polymorphic*, but
 737                                 -- the returned thing has to be *monomorphic*.
 738              (DictBinds id)     -- Method bindings of Ids bound by the RecStmt,
 739                                 -- and used afterwards
 740 \end{code}
 741
 742 ExprStmts are a bit tricky, because what they mean
 743 depends on the context.  Consider the following contexts:
 744
 745         A do expression of type (m res_ty)
 746         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 747         * ExprStmt E any_ty:   do { ....; E; ... }
 748                 E :: m any_ty
 749           Translation: E >> ...
 750
 751         A list comprehensions of type [elt_ty]
 752         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 753         * ExprStmt E Bool:   [ .. | .... E ]
 754                         [ .. | ..., E, ... ]
 755                         [ .. | .... | ..., E | ... ]
 756                 E :: Bool
 757           Translation: if E then fail else ...
 758
 759         A guard list, guarding a RHS of type rhs_ty
 760         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 761         * ExprStmt E Bool:   f x | ..., E, ... = ...rhs...
 762                 E :: Bool
 763           Translation: if E then fail else ...
 764
 765 Array comprehensions are handled like list comprehensions -=chak
 766
 767 Note [RecStmt]
 768 ~~~~~~~~~~~~~~
 769 Example:
 770         HsDo [ BindStmt x ex
 771
 772              , RecStmt [a::forall a. a -> a, b]
 773                        [a::Int -> Int,       c]
 774                        [ BindStmt b (return x)
 775                        , LetStmt a = ea
 776                        , BindStmt c ec ]
 777
 778              , return (a b) ]
 779
 780 Here, the RecStmt binds a,b,c; but
 781   - Only a,b are used in the stmts *following* the RecStmt,
 782         This 'a' is *polymorphic'
 783   - Only a,c are used in the stmts *inside* the RecStmt
 784         *before* their bindings
 785         This 'a' is monomorphic
 786
 787 Nota Bene: the two a's have different types, even though they
 788 have the same Name.
 789
 790
 791 \begin{code}
 792 instance OutputableBndr id => Outputable (Stmt id) where
 793     ppr stmt = pprStmt stmt
 794
 795 pprStmt (BindStmt pat expr _ _)   = hsep [ppr pat, ptext SLIT("<-"), ppr expr]
 796 pprStmt (LetStmt binds)           = hsep [ptext SLIT("let"), pprBinds binds]
 797 pprStmt (ExprStmt expr _ _)       = ppr expr
 798 pprStmt (ParStmt stmtss)          = hsep (map (\stmts -> ptext SLIT("| ") <> ppr stmts) stmtss)
 799 pprStmt (RecStmt segment _ _ _ _) = ptext SLIT("rec") <+> braces (vcat (map ppr segment))
 800
 801 pprDo :: OutputableBndr id => HsStmtContext any -> [LStmt id] -> LHsExpr id -> SDoc
 802 pprDo DoExpr      stmts body = hang (ptext SLIT("do"))  2 (vcat (map ppr stmts) $$ ppr body)
 803 pprDo (MDoExpr _) stmts body = hang (ptext SLIT("mdo")) 3 (vcat (map ppr stmts) $$ ppr body)
 804 pprDo ListComp    stmts body = pprComp brackets    stmts body
 805 pprDo PArrComp    stmts body = pprComp pa_brackets stmts body
 806
 807 pprComp :: OutputableBndr id => (SDoc -> SDoc) -> [LStmt id] -> LHsExpr id -> SDoc
 808 pprComp brack quals body
 809   = brack $
 810         hang (ppr body <+> char '|')
 811              4 (interpp'SP quals)
 812 \end{code}
 813
 814 %************************************************************************
 815 %*                                                                      *
 816                 Template Haskell quotation brackets
 817 %*                                                                      *
 818 %************************************************************************
 819
 820 \begin{code}
 821 data HsSplice id  = HsSplice    --  $z  or $(f 4)
 822                         id              -- The id is just a unique name to
 823                         (LHsExpr id)    -- identify this splice point
 824
 825 instance OutputableBndr id => Outputable (HsSplice id) where
 826   ppr = pprSplice
 827
 828 pprSplice :: OutputableBndr id => HsSplice id -> SDoc
 829 pprSplice (HsSplice n e) = char '$' <> brackets (ppr n) <> pprParendExpr e
 830
 831
 832 data HsBracket id = ExpBr (LHsExpr id)          -- [|  expr  |]
 833                   | PatBr (LPat id)             -- [p| pat   |]
 834                   | DecBr (HsGroup id)          -- [d| decls |]
 835                   | TypBr (LHsType id)          -- [t| type  |]
 836                   | VarBr id                    -- 'x, ''T
 837
 838 instance OutputableBndr id => Outputable (HsBracket id) where
 839   ppr = pprHsBracket
 840
 841
 842 pprHsBracket (ExpBr e) = thBrackets empty (ppr e)
 843 pprHsBracket (PatBr p) = thBrackets (char 'p') (ppr p)
 844 pprHsBracket (DecBr d) = thBrackets (char 'd') (ppr d)
 845 pprHsBracket (TypBr t) = thBrackets (char 't') (ppr t)
 846 pprHsBracket (VarBr n) = char '\'' <> ppr n
 847         -- Infelicity: can't show ' vs '', because
 848         -- we can't ask n what its OccName is, because the
 849         -- pretty-printer for HsExpr doesn't ask for NamedThings
 850         -- But the pretty-printer for names will show the OccName class
 851
 852 thBrackets pp_kind pp_body = char '[' <> pp_kind <> char '|' <+>
 853                              pp_body <+> ptext SLIT("|]")
 854 \end{code}
 855
 856 %************************************************************************
 857 %*                                                                      *
 858 \subsection{Enumerations and list comprehensions}
 859 %*                                                                      *
 860 %************************************************************************
 861
 862 \begin{code}
 863 data ArithSeqInfo id
 864   = From            (LHsExpr id)
 865   | FromThen        (LHsExpr id)
 866                     (LHsExpr id)
 867   | FromTo          (LHsExpr id)
 868                     (LHsExpr id)
 869   | FromThenTo      (LHsExpr id)
 870                     (LHsExpr id)
 871                     (LHsExpr id)
 872 \end{code}
 873
 874 \begin{code}
 875 instance OutputableBndr id => Outputable (ArithSeqInfo id) where
 876     ppr (From e1)               = hcat [ppr e1, pp_dotdot]
 877     ppr (FromThen e1 e2)        = hcat [ppr e1, comma, space, ppr e2, pp_dotdot]
 878     ppr (FromTo e1 e3)  = hcat [ppr e1, pp_dotdot, ppr e3]
 879     ppr (FromThenTo e1 e2 e3)
 880       = hcat [ppr e1, comma, space, ppr e2, pp_dotdot, ppr e3]
 881
 882 pp_dotdot = ptext SLIT(" .. ")
 883 \end{code}
 884
 885
 886 %************************************************************************
 887 %*                                                                      *
 888 \subsection{HsMatchCtxt}
 889 %*                                                                      *
 890 %************************************************************************
 891
 892 \begin{code}
 893 data HsMatchContext id  -- Context of a Match
 894   = FunRhs id                   -- Function binding for f
 895   | CaseAlt                     -- Guard on a case alternative
 896   | LambdaExpr                  -- Pattern of a lambda
 897   | ProcExpr                    -- Pattern of a proc
 898   | PatBindRhs                  -- Pattern binding
 899   | RecUpd                      -- Record update [used only in DsExpr to tell matchWrapper
 900                                 --      what sort of runtime error message to generate]
 901   | StmtCtxt (HsStmtContext id) -- Pattern of a do-stmt or list comprehension
 902   deriving ()
 903
 904 data HsStmtContext id
 905   = ListComp
 906   | DoExpr
 907   | MDoExpr PostTcTable                 -- Recursive do-expression
 908                                         -- (tiresomely, it needs table
 909                                         --  of its return/bind ops)
 910   | PArrComp                            -- Parallel array comprehension
 911   | PatGuard (HsMatchContext id)        -- Pattern guard for specified thing
 912   | ParStmtCtxt (HsStmtContext id)      -- A branch of a parallel stmt
 913 \end{code}
 914
 915 \begin{code}
 916 isDoExpr :: HsStmtContext id -> Bool
 917 isDoExpr DoExpr      = True
 918 isDoExpr (MDoExpr _) = True
 919 isDoExpr other       = False
 920 \end{code}
 921
 922 \begin{code}
 923 matchSeparator (FunRhs _)   = ptext SLIT("=")
 924 matchSeparator CaseAlt      = ptext SLIT("->")
 925 matchSeparator LambdaExpr   = ptext SLIT("->")
 926 matchSeparator ProcExpr     = ptext SLIT("->")
 927 matchSeparator PatBindRhs   = ptext SLIT("=")
 928 matchSeparator (StmtCtxt _) = ptext SLIT("<-")
 929 matchSeparator RecUpd       = panic "unused"
 930 \end{code}
 931
 932 \begin{code}
 933 pprMatchContext (FunRhs fun)      = ptext SLIT("the definition of") <+> quotes (ppr fun)
 934 pprMatchContext CaseAlt           = ptext SLIT("a case alternative")
 935 pprMatchContext RecUpd            = ptext SLIT("a record-update construct")
 936 pprMatchContext PatBindRhs        = ptext SLIT("a pattern binding")
 937 pprMatchContext LambdaExpr        = ptext SLIT("a lambda abstraction")
 938 pprMatchContext ProcExpr          = ptext SLIT("an arrow abstraction")
 939 pprMatchContext (StmtCtxt ctxt)   = ptext SLIT("a pattern binding in") $$ pprStmtContext ctxt
 940
 941 pprMatchRhsContext (FunRhs fun) = ptext SLIT("a right-hand side of function") <+> quotes (ppr fun)
 942 pprMatchRhsContext CaseAlt      = ptext SLIT("the body of a case alternative")
 943 pprMatchRhsContext PatBindRhs   = ptext SLIT("the right-hand side of a pattern binding")
 944 pprMatchRhsContext LambdaExpr   = ptext SLIT("the body of a lambda")
 945 pprMatchRhsContext ProcExpr     = ptext SLIT("the body of a proc")
 946 pprMatchRhsContext RecUpd       = panic "pprMatchRhsContext"
 947
 948 pprStmtContext (ParStmtCtxt c) = sep [ptext SLIT("a parallel branch of"), pprStmtContext c]
 949 pprStmtContext (PatGuard ctxt) = ptext SLIT("a pattern guard for") $$ pprMatchContext ctxt
 950 pprStmtContext DoExpr          = ptext SLIT("a 'do' expression")
 951 pprStmtContext (MDoExpr _)     = ptext SLIT("an 'mdo' expression")
 952 pprStmtContext ListComp        = ptext SLIT("a list comprehension")
 953 pprStmtContext PArrComp        = ptext SLIT("an array comprehension")
 954
 955 -- Used for the result statement of comprehension
 956 -- e.g. the 'e' in      [ e | ... ]
 957 --      or the 'r' in   f x = r
 958 pprStmtResultContext (PatGuard ctxt) = pprMatchRhsContext ctxt
 959 pprStmtResultContext other           = ptext SLIT("the result of") <+> pprStmtContext other
 960
 961
 962 -- Used to generate the string for a *runtime* error message
 963 matchContextErrString (FunRhs fun)               = "function " ++ showSDoc (ppr fun)
 964 matchContextErrString CaseAlt                    = "case"
 965 matchContextErrString PatBindRhs                 = "pattern binding"
 966 matchContextErrString RecUpd                     = "record update"
 967 matchContextErrString LambdaExpr                 = "lambda"
 968 matchContextErrString ProcExpr                   = "proc"
 969 matchContextErrString (StmtCtxt (ParStmtCtxt c)) = matchContextErrString (StmtCtxt c)
 970 matchContextErrString (StmtCtxt (PatGuard _))    = "pattern guard"
 971 matchContextErrString (StmtCtxt DoExpr)          = "'do' expression"
 972 matchContextErrString (StmtCtxt (MDoExpr _))     = "'mdo' expression"
 973 matchContextErrString (StmtCtxt ListComp)        = "list comprehension"
 974 matchContextErrString (StmtCtxt PArrComp)        = "array comprehension"
 975 \end{code}