compiler/hsSyn/HsTypes.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 HsTypes: Abstract syntax: user-defined types
   7
   8 \begin{code}
   9 {-# LANGUAGE DeriveDataTypeable #-}
  10
  11 module HsTypes (
  12         HsType(..), LHsType,
  13         HsTyVarBndr(..), LHsTyVarBndr,
  14         HsExplicitFlag(..),
  15         HsContext, LHsContext,
  16         HsPred(..), LHsPred,
  17         HsQuasiQuote(..),
  18
  19         LBangType, BangType, HsBang(..),
  20         getBangType, getBangStrictness,
  21
  22         ConDeclField(..), pprConDeclFields,
  23
  24         mkExplicitHsForAllTy, mkImplicitHsForAllTy, hsExplicitTvs,
  25         hsTyVarName, hsTyVarNames, replaceTyVarName,
  26         hsTyVarKind, hsTyVarNameKind,
  27         hsLTyVarName, hsLTyVarNames, hsLTyVarLocName, hsLTyVarLocNames,
  28         splitHsInstDeclTy, splitHsFunType,
  29
  30         -- Type place holder
  31         PostTcType, placeHolderType, PostTcKind, placeHolderKind,
  32
  33         -- Printing
  34         pprParendHsType, pprHsForAll, pprHsContext, ppr_hs_context,
  35     ) where
  36
  37 import {-# SOURCE #-} HsExpr ( HsSplice, pprSplice )
  38
  39 import NameSet( FreeVars )
  40 import Type
  41 import HsDoc
  42 import BasicTypes
  43 import SrcLoc
  44 import StaticFlags
  45 import Outputable
  46 import FastString
  47
  48 import Data.Data
  49 \end{code}
  50
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection{Annotating the syntax}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 \begin{code}
  59 type PostTcKind = Kind
  60 type PostTcType = Type          -- Used for slots in the abstract syntax
  61                                 -- where we want to keep slot for a type
  62                                 -- to be added by the type checker...but
  63                                 -- before typechecking it's just bogus
  64
  65 placeHolderType :: PostTcType   -- Used before typechecking
  66 placeHolderType  = panic "Evaluated the place holder for a PostTcType"
  67
  68 placeHolderKind :: PostTcKind   -- Used before typechecking
  69 placeHolderKind  = panic "Evaluated the place holder for a PostTcKind"
  70 \end{code}
  71
  72 %************************************************************************
  73 %*                                                                      *
  74         Quasi quotes; used in types and elsewhere
  75 %*                                                                      *
  76 %************************************************************************
  77
  78 \begin{code}
  79 data HsQuasiQuote id = HsQuasiQuote
  80                            id           -- The quasi-quoter
  81                            SrcSpan      -- The span of the enclosed string
  82                            FastString   -- The enclosed string
  83   deriving (Data, Typeable)
  84
  85 instance OutputableBndr id => Outputable (HsQuasiQuote id) where
  86     ppr = ppr_qq
  87
  88 ppr_qq :: OutputableBndr id => HsQuasiQuote id -> SDoc
  89 ppr_qq (HsQuasiQuote quoter _ quote) =
  90     char '[' <> ppr quoter <> ptext (sLit "|") <>
  91     ppr quote <> ptext (sLit "|]")
  92 \end{code}
  93
  94
  95 %************************************************************************
  96 %*                                                                      *
  97 \subsection{Bang annotations}
  98 %*                                                                      *
  99 %************************************************************************
 100
 101 \begin{code}
 102 type LBangType name = Located (BangType name)
 103 type BangType name  = HsType name       -- Bangs are in the HsType data type
 104
 105 getBangType :: LHsType a -> LHsType a
 106 getBangType (L _ (HsBangTy _ ty)) = ty
 107 getBangType ty                    = ty
 108
 109 getBangStrictness :: LHsType a -> HsBang
 110 getBangStrictness (L _ (HsBangTy s _)) = s
 111 getBangStrictness _                    = HsNoBang
 112 \end{code}
 113
 114
 115 %************************************************************************
 116 %*                                                                      *
 117 \subsection{Data types}
 118 %*                                                                      *
 119 %************************************************************************
 120
 121 This is the syntax for types as seen in type signatures.
 122
 123 \begin{code}
 124 type LHsContext name = Located (HsContext name)
 125
 126 type HsContext name = [LHsPred name]
 127
 128 type LHsPred name = Located (HsPred name)
 129
 130 data HsPred name = HsClassP name [LHsType name]          -- class constraint
 131                  | HsEqualP (LHsType name) (LHsType name)-- equality constraint
 132                  | HsIParam (IPName name) (LHsType name)
 133                  deriving (Data, Typeable)
 134
 135 type LHsType name = Located (HsType name)
 136
 137 data HsType name
 138   = HsForAllTy  HsExplicitFlag          -- Renamer leaves this flag unchanged, to record the way
 139                                         -- the user wrote it originally, so that the printer can
 140                                         -- print it as the user wrote it
 141                 [LHsTyVarBndr name]     -- With ImplicitForAll, this is the empty list
 142                                         -- until the renamer fills in the variables
 143                 (LHsContext name)
 144                 (LHsType name)
 145
 146   | HsTyVar             name            -- Type variable or type constructor
 147
 148   | HsAppTy             (LHsType name)
 149                         (LHsType name)
 150
 151   | HsFunTy             (LHsType name)   -- function type
 152                         (LHsType name)
 153
 154   | HsListTy            (LHsType name)  -- Element type
 155
 156   | HsPArrTy            (LHsType name)  -- Elem. type of parallel array: [:t:]
 157
 158   | HsTupleTy           Boxity
 159                         [LHsType name]  -- Element types (length gives arity)
 160
 161   | HsOpTy              (LHsType name) (Located name) (LHsType name)
 162
 163   | HsParTy             (LHsType name)
 164         -- Parenthesis preserved for the precedence re-arrangement in RnTypes
 165         -- It's important that a * (b + c) doesn't get rearranged to (a*b) + c!
 166         --
 167         -- However, NB that toHsType doesn't add HsParTys (in an effort to keep
 168         -- interface files smaller), so when printing a HsType we may need to
 169         -- add parens.
 170
 171   | HsNumTy             Integer         -- Generics only
 172
 173   | HsPredTy            (HsPred name)   -- Only used in the type of an instance
 174                                         -- declaration, eg.  Eq [a] -> Eq a
 175                                         --                             ^^^^
 176                                         --                            HsPredTy
 177                                         -- Note no need for location info on the
 178                                         -- enclosed HsPred; the one on the type will do
 179
 180   | HsKindSig           (LHsType name)  -- (ty :: kind)
 181                         Kind            -- A type with a kind signature
 182
 183   | HsQuasiQuoteTy      (HsQuasiQuote name)
 184
 185   | HsSpliceTy          (HsSplice name)
 186                         FreeVars        -- Variables free in the splice (filled in by renamer)
 187                         PostTcKind
 188
 189   | HsDocTy             (LHsType name) LHsDocString -- A documented type
 190
 191   | HsBangTy    HsBang (LHsType name)   -- Bang-style type annotations
 192   | HsRecTy [ConDeclField name]         -- Only in data type declarations
 193   deriving (Data, Typeable)
 194
 195 data HsExplicitFlag = Explicit | Implicit deriving (Data, Typeable)
 196
 197 data ConDeclField name  -- Record fields have Haddoc docs on them
 198   = ConDeclField { cd_fld_name :: Located name,
 199                    cd_fld_type :: LBangType name,
 200                    cd_fld_doc  :: Maybe LHsDocString }
 201   deriving (Data, Typeable)
 202
 203 -----------------------
 204 -- Combine adjacent for-alls.
 205 -- The following awkward situation can happen otherwise:
 206 --      f :: forall a. ((Num a) => Int)
 207 -- might generate HsForAll (Just [a]) [] (HsForAll Nothing [Num a] t)
 208 -- Then a isn't discovered as ambiguous, and we abstract the AbsBinds wrt []
 209 -- but the export list abstracts f wrt [a].  Disaster.
 210 --
 211 -- A valid type must have one for-all at the top of the type, or of the fn arg types
 212
 213 mkImplicitHsForAllTy ::                        LHsContext name -> LHsType name -> HsType name
 214 mkExplicitHsForAllTy :: [LHsTyVarBndr name] -> LHsContext name -> LHsType name -> HsType name
 215 mkImplicitHsForAllTy     ctxt ty = mkHsForAllTy Implicit [] ctxt ty
 216 mkExplicitHsForAllTy tvs ctxt ty = mkHsForAllTy Explicit tvs ctxt ty
 217
 218 mkHsForAllTy :: HsExplicitFlag -> [LHsTyVarBndr name] -> LHsContext name -> LHsType name -> HsType name
 219 -- Smart constructor for HsForAllTy
 220 mkHsForAllTy exp tvs (L _ []) ty = mk_forall_ty exp tvs ty
 221 mkHsForAllTy exp tvs ctxt ty = HsForAllTy exp tvs ctxt ty
 222
 223 -- mk_forall_ty makes a pure for-all type (no context)
 224 mk_forall_ty :: HsExplicitFlag -> [LHsTyVarBndr name] -> LHsType name -> HsType name
 225 mk_forall_ty exp  tvs  (L _ (HsParTy ty))                   = mk_forall_ty exp tvs ty
 226 mk_forall_ty exp1 tvs1 (L _ (HsForAllTy exp2 tvs2 ctxt ty)) = mkHsForAllTy (exp1 `plus` exp2) (tvs1 ++ tvs2) ctxt ty
 227 mk_forall_ty exp  tvs  ty                                   = HsForAllTy exp tvs (L noSrcSpan []) ty
 228         -- Even if tvs is empty, we still make a HsForAll!
 229         -- In the Implicit case, this signals the place to do implicit quantification
 230         -- In the Explicit case, it prevents implicit quantification
 231         --      (see the sigtype production in Parser.y.pp)
 232         --      so that (forall. ty) isn't implicitly quantified
 233
 234 plus :: HsExplicitFlag -> HsExplicitFlag -> HsExplicitFlag
 235 Implicit `plus` Implicit = Implicit
 236 _        `plus` _        = Explicit
 237
 238 hsExplicitTvs :: LHsType name -> [name]
 239 -- The explicitly-given forall'd type variables of a HsType
 240 hsExplicitTvs (L _ (HsForAllTy Explicit tvs _ _)) = hsLTyVarNames tvs
 241 hsExplicitTvs _                                   = []
 242
 243 ---------------------
 244 type LHsTyVarBndr name = Located (HsTyVarBndr name)
 245
 246 data HsTyVarBndr name
 247   = UserTyVar           -- No explicit kinding
 248          name           -- See Note [Printing KindedTyVars]
 249          PostTcKind
 250
 251   | KindedTyVar
 252          name
 253          Kind
 254       --  *** NOTA BENE *** A "monotype" in a pragma can have
 255       -- for-alls in it, (mostly to do with dictionaries).  These
 256       -- must be explicitly Kinded.
 257   deriving (Data, Typeable)
 258
 259 hsTyVarName :: HsTyVarBndr name -> name
 260 hsTyVarName (UserTyVar n _)   = n
 261 hsTyVarName (KindedTyVar n _) = n
 262
 263 hsTyVarKind :: HsTyVarBndr name -> Kind
 264 hsTyVarKind (UserTyVar _ k)   = k
 265 hsTyVarKind (KindedTyVar _ k) = k
 266
 267 hsTyVarNameKind :: HsTyVarBndr name -> (name, Kind)
 268 hsTyVarNameKind (UserTyVar n k)   = (n,k)
 269 hsTyVarNameKind (KindedTyVar n k) = (n,k)
 270
 271 hsLTyVarName :: LHsTyVarBndr name -> name
 272 hsLTyVarName = hsTyVarName . unLoc
 273
 274 hsTyVarNames :: [HsTyVarBndr name] -> [name]
 275 hsTyVarNames tvs = map hsTyVarName tvs
 276
 277 hsLTyVarNames :: [LHsTyVarBndr name] -> [name]
 278 hsLTyVarNames = map hsLTyVarName
 279
 280 hsLTyVarLocName :: LHsTyVarBndr name -> Located name
 281 hsLTyVarLocName = fmap hsTyVarName
 282
 283 hsLTyVarLocNames :: [LHsTyVarBndr name] -> [Located name]
 284 hsLTyVarLocNames = map hsLTyVarLocName
 285
 286 replaceTyVarName :: HsTyVarBndr name1 -> name2 -> HsTyVarBndr name2
 287 replaceTyVarName (UserTyVar _ k)   n' = UserTyVar n' k
 288 replaceTyVarName (KindedTyVar _ k) n' = KindedTyVar n' k
 289 \end{code}
 290
 291
 292 \begin{code}
 293 splitHsInstDeclTy
 294     :: OutputableBndr name
 295     => HsType name
 296     -> ([LHsTyVarBndr name], HsContext name, name, [LHsType name])
 297         -- Split up an instance decl type, returning the pieces
 298
 299 splitHsInstDeclTy inst_ty
 300   = case inst_ty of
 301         HsParTy (L _ ty)              -> splitHsInstDeclTy ty
 302         HsForAllTy _ tvs cxt (L _ ty) -> split_tau tvs (unLoc cxt) ty
 303         other                         -> split_tau []  []          other
 304     -- The type vars should have been computed by now, even if they were implicit
 305   where
 306     split_tau tvs cxt (HsPredTy (HsClassP cls tys)) = (tvs, cxt, cls, tys)
 307     split_tau tvs cxt (HsParTy (L _ ty))            = split_tau tvs cxt ty
 308     split_tau _ _ _ = pprPanic "splitHsInstDeclTy" (ppr inst_ty)
 309
 310 -- Splits HsType into the (init, last) parts
 311 -- Breaks up any parens in the result type:
 312 --      splitHsFunType (a -> (b -> c)) = ([a,b], c)
 313 splitHsFunType :: LHsType name -> ([LHsType name], LHsType name)
 314 splitHsFunType (L _ (HsFunTy x y)) = (x:args, res)
 315   where
 316   (args, res) = splitHsFunType y
 317 splitHsFunType (L _ (HsParTy ty))  = splitHsFunType ty
 318 splitHsFunType other               = ([], other)
 319 \end{code}
 320
 321
 322 %************************************************************************
 323 %*                                                                      *
 324 \subsection{Pretty printing}
 325 %*                                                                      *
 326 %************************************************************************
 327
 328 \begin{code}
 329 instance (OutputableBndr name) => Outputable (HsType name) where
 330     ppr ty = pprHsType ty
 331
 332 instance (Outputable name) => Outputable (HsTyVarBndr name) where
 333     ppr (UserTyVar name _)      = ppr name
 334     ppr (KindedTyVar name kind) = hsep [ppr name, dcolon, pprParendKind kind]
 335
 336 instance OutputableBndr name => Outputable (HsPred name) where
 337     ppr (HsClassP clas tys) = ppr clas <+> hsep (map pprLHsType tys)
 338     ppr (HsEqualP t1 t2)    = hsep [pprLHsType t1, ptext (sLit "~"),
 339                                     pprLHsType t2]
 340     ppr (HsIParam n ty)     = hsep [ppr n, dcolon, ppr ty]
 341
 342 pprLHsType :: OutputableBndr name => LHsType name -> SDoc
 343 pprLHsType = pprParendHsType . unLoc
 344
 345 pprHsForAll :: OutputableBndr name => HsExplicitFlag -> [LHsTyVarBndr name] ->  LHsContext name -> SDoc
 346 pprHsForAll exp tvs cxt
 347   | show_forall = forall_part <+> pprHsContext (unLoc cxt)
 348   | otherwise   = pprHsContext (unLoc cxt)
 349   where
 350     show_forall =  opt_PprStyle_Debug
 351                 || (not (null tvs) && is_explicit)
 352     is_explicit = case exp of {Explicit -> True; Implicit -> False}
 353     forall_part = ptext (sLit "forall") <+> interppSP tvs <> dot
 354
 355 pprHsContext :: (OutputableBndr name) => HsContext name -> SDoc
 356 pprHsContext []         = empty
 357 pprHsContext [L _ pred]
 358    | noParenHsPred pred = ppr pred <+> ptext (sLit "=>")
 359 pprHsContext cxt        = ppr_hs_context cxt <+> ptext (sLit "=>")
 360
 361 noParenHsPred :: HsPred name -> Bool
 362 -- c.f. TypeRep.noParenPred
 363 noParenHsPred (HsClassP {}) = True
 364 noParenHsPred (HsEqualP {}) = True
 365 noParenHsPred (HsIParam {}) = False
 366
 367 ppr_hs_context :: (OutputableBndr name) => HsContext name -> SDoc
 368 ppr_hs_context []  = empty
 369 ppr_hs_context cxt = parens (interpp'SP cxt)
 370
 371 pprConDeclFields :: OutputableBndr name => [ConDeclField name] -> SDoc
 372 pprConDeclFields fields = braces (sep (punctuate comma (map ppr_fld fields)))
 373   where
 374     ppr_fld (ConDeclField { cd_fld_name = n, cd_fld_type = ty,
 375                             cd_fld_doc = doc })
 376         = ppr n <+> dcolon <+> ppr ty <+> ppr_mbDoc doc
 377 \end{code}
 378
 379 Note [Printing KindedTyVars]
 380 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 381 Trac #3830 reminded me that we should really only print the kind
 382 signature on a KindedTyVar if the kind signature was put there by the
 383 programmer.  During kind inference GHC now adds a PostTcKind to UserTyVars,
 384 rather than converting to KindedTyVars as before.
 385
 386 (As it happens, the message in #3830 comes out a different way now,
 387 and the problem doesn't show up; but having the flag on a KindedTyVar
 388 seems like the Right Thing anyway.)
 389
 390 \begin{code}
 391 pREC_TOP, pREC_FUN, pREC_OP, pREC_CON :: Int
 392 pREC_TOP = 0  -- type   in ParseIface.y
 393 pREC_FUN = 1  -- btype  in ParseIface.y
 394               -- Used for LH arg of (->)
 395 pREC_OP  = 2  -- Used for arg of any infix operator
 396               -- (we don't keep their fixities around)
 397 pREC_CON = 3  -- Used for arg of type applicn:
 398               -- always parenthesise unless atomic
 399
 400 maybeParen :: Int       -- Precedence of context
 401            -> Int       -- Precedence of top-level operator
 402            -> SDoc -> SDoc      -- Wrap in parens if (ctxt >= op)
 403 maybeParen ctxt_prec op_prec p | ctxt_prec >= op_prec = parens p
 404                                | otherwise            = p
 405
 406 -- printing works more-or-less as for Types
 407
 408 pprHsType, pprParendHsType :: (OutputableBndr name) => HsType name -> SDoc
 409
 410 pprHsType ty       = getPprStyle $ \sty -> ppr_mono_ty pREC_TOP (prepare sty ty)
 411 pprParendHsType ty = ppr_mono_ty pREC_CON ty
 412
 413 -- Before printing a type
 414 -- (a) Remove outermost HsParTy parens
 415 -- (b) Drop top-level for-all type variables in user style
 416 --     since they are implicit in Haskell
 417 prepare :: PprStyle -> HsType name -> HsType name
 418 prepare sty (HsParTy ty)          = prepare sty (unLoc ty)
 419 prepare _   ty                    = ty
 420
 421 ppr_mono_lty :: (OutputableBndr name) => Int -> LHsType name -> SDoc
 422 ppr_mono_lty ctxt_prec ty = ppr_mono_ty ctxt_prec (unLoc ty)
 423
 424 ppr_mono_ty :: (OutputableBndr name) => Int -> HsType name -> SDoc
 425 ppr_mono_ty ctxt_prec (HsForAllTy exp tvs ctxt ty)
 426   = maybeParen ctxt_prec pREC_FUN $
 427     sep [pprHsForAll exp tvs ctxt, ppr_mono_lty pREC_TOP ty]
 428
 429 ppr_mono_ty _    (HsBangTy b ty)     = ppr b <> ppr ty
 430 ppr_mono_ty _    (HsQuasiQuoteTy qq) = ppr qq
 431 ppr_mono_ty _    (HsRecTy flds)      = pprConDeclFields flds
 432 ppr_mono_ty _    (HsTyVar name)      = ppr name
 433 ppr_mono_ty prec (HsFunTy ty1 ty2)   = ppr_fun_ty prec ty1 ty2
 434 ppr_mono_ty _    (HsTupleTy con tys) = tupleParens con (interpp'SP tys)
 435 ppr_mono_ty _    (HsKindSig ty kind) = parens (ppr_mono_lty pREC_TOP ty <+> dcolon <+> pprKind kind)
 436 ppr_mono_ty _    (HsListTy ty)       = brackets (ppr_mono_lty pREC_TOP ty)
 437 ppr_mono_ty _    (HsPArrTy ty)       = pabrackets (ppr_mono_lty pREC_TOP ty)
 438 ppr_mono_ty _    (HsPredTy pred)     = ppr pred
 439 ppr_mono_ty _    (HsNumTy n)         = integer n  -- generics only
 440 ppr_mono_ty _    (HsSpliceTy s _ _)  = pprSplice s
 441
 442 ppr_mono_ty ctxt_prec (HsAppTy fun_ty arg_ty)
 443   = maybeParen ctxt_prec pREC_CON $
 444     hsep [ppr_mono_lty pREC_FUN fun_ty, ppr_mono_lty pREC_CON arg_ty]
 445
 446 ppr_mono_ty ctxt_prec (HsOpTy ty1 op ty2)
 447   = maybeParen ctxt_prec pREC_OP $
 448     ppr_mono_lty pREC_OP ty1 <+> ppr op <+> ppr_mono_lty pREC_OP ty2
 449
 450 ppr_mono_ty _         (HsParTy ty)
 451   = parens (ppr_mono_lty pREC_TOP ty)
 452   -- Put the parens in where the user did
 453   -- But we still use the precedence stuff to add parens because
 454   --    toHsType doesn't put in any HsParTys, so we may still need them
 455
 456 ppr_mono_ty ctxt_prec (HsDocTy ty doc)
 457   = maybeParen ctxt_prec pREC_OP $
 458     ppr_mono_lty pREC_OP ty <+> ppr (unLoc doc)
 459   -- we pretty print Haddock comments on types as if they were
 460   -- postfix operators
 461
 462 --------------------------
 463 ppr_fun_ty :: (OutputableBndr name) => Int -> LHsType name -> LHsType name -> SDoc
 464 ppr_fun_ty ctxt_prec ty1 ty2
 465   = let p1 = ppr_mono_lty pREC_FUN ty1
 466         p2 = ppr_mono_lty pREC_TOP ty2
 467     in
 468     maybeParen ctxt_prec pREC_FUN $
 469     sep [p1, ptext (sLit "->") <+> p2]
 470
 471 --------------------------
 472 pabrackets :: SDoc -> SDoc
 473 pabrackets p = ptext (sLit "[:") <> p <> ptext (sLit ":]")
 474 \end{code}
 475
 476