compiler/hsSyn/HsTypes.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsTypes]{Abstract syntax: user-defined types}
   5
   6 \begin{code}
   7 module HsTypes (
   8         HsType(..), LHsType,
   9         HsTyVarBndr(..), LHsTyVarBndr,
  10         HsExplicitForAll(..),
  11         HsContext, LHsContext,
  12         HsPred(..), LHsPred,
  13
  14         LBangType, BangType, HsBang(..),
  15         getBangType, getBangStrictness,
  16
  17         mkExplicitHsForAllTy, mkImplicitHsForAllTy,
  18         hsTyVarName, hsTyVarNames, replaceTyVarName,
  19         hsLTyVarName, hsLTyVarNames, hsLTyVarLocName, hsLTyVarLocNames,
  20         splitHsInstDeclTy, splitHsFunType,
  21
  22         -- Type place holder
  23         PostTcType, placeHolderType,
  24
  25         -- Printing
  26         pprParendHsType, pprHsForAll, pprHsContext, ppr_hs_context, pprHsTyVarBndr
  27     ) where
  28
  29 #include "HsVersions.h"
  30
  31 import {-# SOURCE #-} HsExpr ( HsSplice, pprSplice )
  32
  33 import Type             ( Type )
  34 import {- Kind parts of -}
  35        Type             ( {- instance Outputable Kind -}, Kind,
  36                           pprParendKind, pprKind, isLiftedTypeKind )
  37 import BasicTypes       ( IPName, Boxity, tupleParens )
  38 import SrcLoc           ( Located(..), unLoc, noSrcSpan )
  39 import StaticFlags      ( opt_PprStyle_Debug )
  40 import Outputable
  41 \end{code}
  42
  43
  44 %************************************************************************
  45 %*                                                                      *
  46 \subsection{Annotating the syntax}
  47 %*                                                                      *
  48 %************************************************************************
  49
  50 \begin{code}
  51 type PostTcType = Type          -- Used for slots in the abstract syntax
  52                                 -- where we want to keep slot for a type
  53                                 -- to be added by the type checker...but
  54                                 -- before typechecking it's just bogus
  55
  56 placeHolderType :: PostTcType   -- Used before typechecking
  57 placeHolderType  = panic "Evaluated the place holder for a PostTcType"
  58 \end{code}
  59
  60 %************************************************************************
  61 %*                                                                      *
  62 \subsection{Bang annotations}
  63 %*                                                                      *
  64 %************************************************************************
  65
  66 \begin{code}
  67 type LBangType name = Located (BangType name)
  68 type BangType name  = HsType name       -- Bangs are in the HsType data type
  69
  70 data HsBang = HsNoBang  -- Only used as a return value for getBangStrictness,
  71                         -- never appears on a HsBangTy
  72             | HsStrict  -- !
  73             | HsUnbox   -- {-# UNPACK #-} ! (GHC extension, meaning "unbox")
  74
  75 instance Outputable HsBang where
  76     ppr (HsNoBang) = empty
  77     ppr (HsStrict) = char '!'
  78     ppr (HsUnbox)  = ptext SLIT("!!")
  79
  80 getBangType :: LHsType a -> LHsType a
  81 getBangType (L _ (HsBangTy _ ty)) = ty
  82 getBangType ty                    = ty
  83
  84 getBangStrictness :: LHsType a -> HsBang
  85 getBangStrictness (L _ (HsBangTy s _)) = s
  86 getBangStrictness _                    = HsNoBang
  87 \end{code}
  88
  89
  90 %************************************************************************
  91 %*                                                                      *
  92 \subsection{Data types}
  93 %*                                                                      *
  94 %************************************************************************
  95
  96 This is the syntax for types as seen in type signatures.
  97
  98 \begin{code}
  99 type LHsContext name = Located (HsContext name)
 100
 101 type HsContext name = [LHsPred name]
 102
 103 type LHsPred name = Located (HsPred name)
 104
 105 data HsPred name = HsClassP name [LHsType name]
 106                  | HsIParam (IPName name) (LHsType name)
 107
 108 type LHsType name = Located (HsType name)
 109
 110 data HsType name
 111   = HsForAllTy  HsExplicitForAll        -- Renamer leaves this flag unchanged, to record the way
 112                                         -- the user wrote it originally, so that the printer can
 113                                         -- print it as the user wrote it
 114                 [LHsTyVarBndr name]     -- With ImplicitForAll, this is the empty list
 115                                         -- until the renamer fills in the variables
 116                 (LHsContext name)
 117                 (LHsType name)
 118
 119   | HsTyVar             name            -- Type variable or type constructor
 120
 121   | HsBangTy    HsBang (LHsType name)   -- Bang-style type annotations
 122
 123   | HsAppTy             (LHsType name)
 124                         (LHsType name)
 125
 126   | HsFunTy             (LHsType name)   -- function type
 127                         (LHsType name)
 128
 129   | HsListTy            (LHsType name)  -- Element type
 130
 131   | HsPArrTy            (LHsType name)  -- Elem. type of parallel array: [:t:]
 132
 133   | HsTupleTy           Boxity
 134                         [LHsType name]  -- Element types (length gives arity)
 135
 136   | HsOpTy              (LHsType name) (Located name) (LHsType name)
 137
 138   | HsParTy             (LHsType name)
 139         -- Parenthesis preserved for the precedence re-arrangement in RnTypes
 140         -- It's important that a * (b + c) doesn't get rearranged to (a*b) + c!
 141         --
 142         -- However, NB that toHsType doesn't add HsParTys (in an effort to keep
 143         -- interface files smaller), so when printing a HsType we may need to
 144         -- add parens.
 145
 146   | HsNumTy             Integer         -- Generics only
 147
 148   | HsPredTy            (HsPred name)   -- Only used in the type of an instance
 149                                         -- declaration, eg.  Eq [a] -> Eq a
 150                                         --                             ^^^^
 151                                         --                            HsPredTy
 152                                         -- Note no need for location info on the
 153                                         -- enclosed HsPred; the one on the type will do
 154
 155   | HsKindSig           (LHsType name)  -- (ty :: kind)
 156                         Kind            -- A type with a kind signature
 157
 158   | HsSpliceTy          (HsSplice name)
 159
 160 data HsExplicitForAll = Explicit | Implicit
 161
 162 -----------------------
 163 -- Combine adjacent for-alls.
 164 -- The following awkward situation can happen otherwise:
 165 --      f :: forall a. ((Num a) => Int)
 166 -- might generate HsForAll (Just [a]) [] (HsForAll Nothing [Num a] t)
 167 -- Then a isn't discovered as ambiguous, and we abstract the AbsBinds wrt []
 168 -- but the export list abstracts f wrt [a].  Disaster.
 169 --
 170 -- A valid type must have one for-all at the top of the type, or of the fn arg types
 171
 172 mkImplicitHsForAllTy     ctxt ty = mkHsForAllTy Implicit [] ctxt ty
 173 mkExplicitHsForAllTy tvs ctxt ty = mkHsForAllTy Explicit tvs ctxt ty
 174
 175 mkHsForAllTy :: HsExplicitForAll -> [LHsTyVarBndr name] -> LHsContext name -> LHsType name -> HsType name
 176 -- Smart constructor for HsForAllTy
 177 mkHsForAllTy exp tvs (L _ []) ty = mk_forall_ty exp tvs ty
 178 mkHsForAllTy exp tvs ctxt ty = HsForAllTy exp tvs ctxt ty
 179
 180 -- mk_forall_ty makes a pure for-all type (no context)
 181 mk_forall_ty exp  tvs  (L _ (HsParTy ty))                   = mk_forall_ty exp tvs ty
 182 mk_forall_ty exp1 tvs1 (L _ (HsForAllTy exp2 tvs2 ctxt ty)) = mkHsForAllTy (exp1 `plus` exp2) (tvs1 ++ tvs2) ctxt ty
 183 mk_forall_ty exp  tvs  ty                                   = HsForAllTy exp tvs (L noSrcSpan []) ty
 184         -- Even if tvs is empty, we still make a HsForAll!
 185         -- In the Implicit case, this signals the place to do implicit quantification
 186         -- In the Explicit case, it prevents implicit quantification
 187         --      (see the sigtype production in Parser.y.pp)
 188         --      so that (forall. ty) isn't implicitly quantified
 189
 190 Implicit `plus` Implicit = Implicit
 191 exp1     `plus` exp2     = Explicit
 192
 193 type LHsTyVarBndr name = Located (HsTyVarBndr name)
 194
 195 data HsTyVarBndr name
 196   = UserTyVar name
 197   | KindedTyVar name Kind
 198         --  *** NOTA BENE *** A "monotype" in a pragma can have
 199         -- for-alls in it, (mostly to do with dictionaries).  These
 200         -- must be explicitly Kinded.
 201
 202 hsTyVarName :: HsTyVarBndr name -> name
 203 hsTyVarName (UserTyVar n)     = n
 204 hsTyVarName (KindedTyVar n _) = n
 205
 206 hsLTyVarName :: LHsTyVarBndr name -> name
 207 hsLTyVarName = hsTyVarName . unLoc
 208
 209 hsTyVarNames :: [HsTyVarBndr name] -> [name]
 210 hsTyVarNames tvs = map hsTyVarName tvs
 211
 212 hsLTyVarNames :: [LHsTyVarBndr name] -> [name]
 213 hsLTyVarNames = map hsLTyVarName
 214
 215 hsLTyVarLocName :: LHsTyVarBndr name -> Located name
 216 hsLTyVarLocName = fmap hsTyVarName
 217
 218 hsLTyVarLocNames :: [LHsTyVarBndr name] -> [Located name]
 219 hsLTyVarLocNames = map hsLTyVarLocName
 220
 221 replaceTyVarName :: HsTyVarBndr name1 -> name2 -> HsTyVarBndr name2
 222 replaceTyVarName (UserTyVar n)     n' = UserTyVar n'
 223 replaceTyVarName (KindedTyVar n k) n' = KindedTyVar n' k
 224 \end{code}
 225
 226
 227 \begin{code}
 228 splitHsInstDeclTy
 229     :: OutputableBndr name
 230     => HsType name
 231     -> ([LHsTyVarBndr name], HsContext name, name, [LHsType name])
 232         -- Split up an instance decl type, returning the pieces
 233
 234 splitHsInstDeclTy inst_ty
 235   = case inst_ty of
 236         HsParTy (L _ ty)              -> splitHsInstDeclTy ty
 237         HsForAllTy _ tvs cxt (L _ ty) -> split_tau tvs (unLoc cxt) ty
 238         other                         -> split_tau []  []          other
 239     -- The type vars should have been computed by now, even if they were implicit
 240   where
 241     split_tau tvs cxt (HsPredTy (HsClassP cls tys)) = (tvs, cxt, cls, tys)
 242     split_tau tvs cxt (HsParTy (L _ ty))            = split_tau tvs cxt ty
 243
 244 -- Splits HsType into the (init, last) parts
 245 -- Breaks up any parens in the result type:
 246 --      splitHsFunType (a -> (b -> c)) = ([a,b], c)
 247 splitHsFunType :: LHsType name -> ([LHsType name], LHsType name)
 248 splitHsFunType (L l (HsFunTy x y)) = (x:args, res)
 249   where
 250   (args, res) = splitHsFunType y
 251 splitHsFunType (L _ (HsParTy ty))  = splitHsFunType ty
 252 splitHsFunType other               = ([], other)
 253 \end{code}
 254
 255
 256 %************************************************************************
 257 %*                                                                      *
 258 \subsection{Pretty printing}
 259 %*                                                                      *
 260 %************************************************************************
 261
 262 NB: these types get printed into interface files, so
 263     don't change the printing format lightly
 264
 265 \begin{code}
 266 instance (OutputableBndr name) => Outputable (HsType name) where
 267     ppr ty = pprHsType ty
 268
 269 instance (Outputable name) => Outputable (HsTyVarBndr name) where
 270     ppr (UserTyVar name)        = ppr name
 271     ppr (KindedTyVar name kind) = pprHsTyVarBndr name kind
 272
 273 instance OutputableBndr name => Outputable (HsPred name) where
 274     ppr (HsClassP clas tys) = ppr clas <+> hsep (map (pprParendHsType.unLoc) tys)
 275     ppr (HsIParam n ty)    = hsep [ppr n, dcolon, ppr ty]
 276
 277 pprHsTyVarBndr :: Outputable name => name -> Kind -> SDoc
 278 pprHsTyVarBndr name kind | isLiftedTypeKind kind = ppr name
 279                          | otherwise             = hsep [ppr name, dcolon, pprParendKind kind]
 280
 281 pprHsForAll exp tvs cxt
 282   | show_forall = forall_part <+> pprHsContext (unLoc cxt)
 283   | otherwise   = pprHsContext (unLoc cxt)
 284   where
 285     show_forall =  opt_PprStyle_Debug
 286                 || (not (null tvs) && is_explicit)
 287     is_explicit = case exp of {Explicit -> True; Implicit -> False}
 288     forall_part = ptext SLIT("forall") <+> interppSP tvs <> dot
 289
 290 pprHsContext :: (OutputableBndr name) => HsContext name -> SDoc
 291 pprHsContext []  = empty
 292 pprHsContext cxt = ppr_hs_context cxt <+> ptext SLIT("=>")
 293
 294 ppr_hs_context []  = empty
 295 ppr_hs_context cxt = parens (interpp'SP cxt)
 296 \end{code}
 297
 298 \begin{code}
 299 pREC_TOP = (0 :: Int)  -- type   in ParseIface.y
 300 pREC_FUN = (1 :: Int)  -- btype  in ParseIface.y
 301                         -- Used for LH arg of (->)
 302 pREC_OP  = (2 :: Int)   -- Used for arg of any infix operator
 303                         -- (we don't keep their fixities around)
 304 pREC_CON = (3 :: Int)   -- Used for arg of type applicn:
 305                         -- always parenthesise unless atomic
 306
 307 maybeParen :: Int       -- Precedence of context
 308            -> Int       -- Precedence of top-level operator
 309            -> SDoc -> SDoc      -- Wrap in parens if (ctxt >= op)
 310 maybeParen ctxt_prec op_prec p | ctxt_prec >= op_prec = parens p
 311                                | otherwise            = p
 312
 313 -- printing works more-or-less as for Types
 314
 315 pprHsType, pprParendHsType :: (OutputableBndr name) => HsType name -> SDoc
 316
 317 pprHsType ty       = getPprStyle $ \sty -> ppr_mono_ty pREC_TOP (prepare sty ty)
 318 pprParendHsType ty = ppr_mono_ty pREC_CON ty
 319
 320 -- Before printing a type
 321 -- (a) Remove outermost HsParTy parens
 322 -- (b) Drop top-level for-all type variables in user style
 323 --     since they are implicit in Haskell
 324 prepare sty (HsParTy ty)          = prepare sty (unLoc ty)
 325 prepare sty ty                    = ty
 326
 327 ppr_mono_lty ctxt_prec ty = ppr_mono_ty ctxt_prec (unLoc ty)
 328
 329 ppr_mono_ty ctxt_prec (HsForAllTy exp tvs ctxt ty)
 330   = maybeParen ctxt_prec pREC_FUN $
 331     sep [pprHsForAll exp tvs ctxt, ppr_mono_lty pREC_TOP ty]
 332
 333 -- gaw 2004
 334 ppr_mono_ty ctxt_prec (HsBangTy b ty)     = ppr b <> ppr ty
 335 ppr_mono_ty ctxt_prec (HsTyVar name)      = ppr name
 336 ppr_mono_ty ctxt_prec (HsFunTy ty1 ty2)   = ppr_fun_ty ctxt_prec ty1 ty2
 337 ppr_mono_ty ctxt_prec (HsTupleTy con tys) = tupleParens con (interpp'SP tys)
 338 ppr_mono_ty ctxt_prec (HsKindSig ty kind) = parens (ppr_mono_lty pREC_TOP ty <+> dcolon <+> pprKind kind)
 339 ppr_mono_ty ctxt_prec (HsListTy ty)       = brackets (ppr_mono_lty pREC_TOP ty)
 340 ppr_mono_ty ctxt_prec (HsPArrTy ty)       = pabrackets (ppr_mono_lty pREC_TOP ty)
 341 ppr_mono_ty ctxt_prec (HsPredTy pred)     = braces (ppr pred)
 342 ppr_mono_ty ctxt_prec (HsNumTy n)         = integer n  -- generics only
 343 ppr_mono_ty ctxt_prec (HsSpliceTy s)      = pprSplice s
 344
 345 ppr_mono_ty ctxt_prec (HsAppTy fun_ty arg_ty)
 346   = maybeParen ctxt_prec pREC_CON $
 347     hsep [ppr_mono_lty pREC_FUN fun_ty, ppr_mono_lty pREC_CON arg_ty]
 348
 349 ppr_mono_ty ctxt_prec (HsOpTy ty1 op ty2)
 350   = maybeParen ctxt_prec pREC_OP $
 351     ppr_mono_lty pREC_OP ty1 <+> ppr op <+> ppr_mono_lty pREC_OP ty2
 352
 353 ppr_mono_ty ctxt_prec (HsParTy ty)
 354   = parens (ppr_mono_lty pREC_TOP ty)
 355   -- Put the parens in where the user did
 356   -- But we still use the precedence stuff to add parens because
 357   --    toHsType doesn't put in any HsParTys, so we may still need them
 358
 359 --------------------------
 360 ppr_fun_ty ctxt_prec ty1 ty2
 361   = let p1 = ppr_mono_lty pREC_FUN ty1
 362         p2 = ppr_mono_lty pREC_TOP ty2
 363     in
 364     maybeParen ctxt_prec pREC_FUN $
 365     sep [p1, ptext SLIT("->") <+> p2]
 366
 367 --------------------------
 368 pabrackets p = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 369 \end{code}
 370
 371