compiler/iface/BuildTyCl.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 \begin{code}
   7 module BuildTyCl (
   8         buildSynTyCon,
   9         buildAlgTyCon,
  10         buildDataCon,
  11         TcMethInfo, buildClass,
  12         mkAbstractTyConRhs,
  13         mkNewTyConRhs, mkDataTyConRhs
  14     ) where
  15
  16 #include "HsVersions.h"
  17
  18 import IfaceEnv
  19
  20 import DataCon
  21 import Var
  22 import VarSet
  23 import BasicTypes
  24 import Name
  25 import MkId
  26 import Class
  27 import TyCon
  28 import Type
  29 import Coercion
  30
  31 import TcRnMonad
  32 import Data.List        ( partition )
  33 import Outputable
  34 \end{code}
  35
  36
  37 \begin{code}
  38 ------------------------------------------------------
  39 buildSynTyCon :: Name -> [TyVar]
  40               -> SynTyConRhs
  41               -> Kind                   -- ^ Kind of the RHS
  42               -> TyConParent
  43               -> Maybe (TyCon, [Type])    -- ^ family instance if applicable
  44               -> TcRnIf m n TyCon
  45 buildSynTyCon tc_name tvs rhs rhs_kind parent mb_family
  46   | Just fam_inst_info <- mb_family
  47   = ASSERT( isNoParent parent )
  48     fixM $ \ tycon_rec -> do
  49     { fam_parent <- mkFamInstParentInfo tc_name tvs fam_inst_info tycon_rec
  50     ; return (mkSynTyCon tc_name kind tvs rhs fam_parent) }
  51
  52   | otherwise
  53   = return (mkSynTyCon tc_name kind tvs rhs parent)
  54   where
  55     kind = mkArrowKinds (map tyVarKind tvs) rhs_kind
  56
  57 ------------------------------------------------------
  58 buildAlgTyCon :: Name -> [TyVar]
  59               -> ThetaType              -- ^ Stupid theta
  60               -> AlgTyConRhs
  61               -> RecFlag
  62               -> Bool                   -- ^ True <=> want generics functions
  63               -> Bool                   -- ^ True <=> was declared in GADT syntax
  64               -> TyConParent
  65               -> Maybe (TyCon, [Type])  -- ^ family instance if applicable
  66               -> TcRnIf m n TyCon
  67
  68 buildAlgTyCon tc_name tvs stupid_theta rhs is_rec want_generics gadt_syn
  69               parent mb_family
  70   | Just fam_inst_info <- mb_family
  71   = -- We need to tie a knot as the coercion of a data instance depends
  72      -- on the instance representation tycon and vice versa.
  73     ASSERT( isNoParent parent )
  74     fixM $ \ tycon_rec -> do
  75     { fam_parent <- mkFamInstParentInfo tc_name tvs fam_inst_info tycon_rec
  76     ; return (mkAlgTyCon tc_name kind tvs stupid_theta rhs
  77                          fam_parent is_rec want_generics gadt_syn) }
  78
  79   | otherwise
  80   = return (mkAlgTyCon tc_name kind tvs stupid_theta rhs
  81                        parent is_rec want_generics gadt_syn)
  82   where
  83     kind = mkArrowKinds (map tyVarKind tvs) liftedTypeKind
  84
  85 -- | If a family tycon with instance types is given, the current tycon is an
  86 -- instance of that family and we need to
  87 --
  88 -- (1) create a coercion that identifies the family instance type and the
  89 --     representation type from Step (1); ie, it is of the form
  90 --         `Co tvs :: F ts ~ R tvs', where `Co' is the name of the coercion,
  91 --         `F' the family tycon and `R' the (derived) representation tycon,
  92 --         and
  93 -- (2) produce a `TyConParent' value containing the parent and coercion
  94 --     information.
  95 --
  96 mkFamInstParentInfo :: Name -> [TyVar]
  97                     -> (TyCon, [Type])
  98                     -> TyCon
  99                     -> TcRnIf m n TyConParent
 100 mkFamInstParentInfo tc_name tvs (family, instTys) rep_tycon
 101   = do { -- Create the coercion
 102        ; co_tycon_name <- newImplicitBinder tc_name mkInstTyCoOcc
 103        ; let co_tycon = mkFamInstCo co_tycon_name tvs
 104                                     family instTys rep_tycon
 105        ; return $ FamInstTyCon family instTys co_tycon }
 106
 107 ------------------------------------------------------
 108 mkAbstractTyConRhs :: AlgTyConRhs
 109 mkAbstractTyConRhs = AbstractTyCon
 110
 111 mkDataTyConRhs :: [DataCon] -> AlgTyConRhs
 112 mkDataTyConRhs cons
 113   = DataTyCon {
 114         data_cons = cons,
 115         is_enum = not (null cons) && all is_enum_con cons
 116                   -- See Note [Enumeration types] in TyCon
 117     }
 118   where
 119     is_enum_con con
 120        | (_tvs, theta, arg_tys, _res) <- dataConSig con
 121        = null theta && null arg_tys
 122
 123
 124 mkNewTyConRhs :: Name -> TyCon -> DataCon -> TcRnIf m n AlgTyConRhs
 125 -- ^ Monadic because it makes a Name for the coercion TyCon
 126 --   We pass the Name of the parent TyCon, as well as the TyCon itself,
 127 --   because the latter is part of a knot, whereas the former is not.
 128 mkNewTyConRhs tycon_name tycon con
 129   = do  { co_tycon_name <- newImplicitBinder tycon_name mkNewTyCoOcc
 130         ; let co_tycon = mkNewTypeCo co_tycon_name tycon etad_tvs etad_rhs
 131         ; traceIf (text "mkNewTyConRhs" <+> ppr co_tycon)
 132         ; return (NewTyCon { data_con    = con,
 133                              nt_rhs      = rhs_ty,
 134                              nt_etad_rhs = (etad_tvs, etad_rhs),
 135                              nt_co       = co_tycon } ) }
 136                              -- Coreview looks through newtypes with a Nothing
 137                              -- for nt_co, or uses explicit coercions otherwise
 138   where
 139     tvs    = tyConTyVars tycon
 140     inst_con_ty = applyTys (dataConUserType con) (mkTyVarTys tvs)
 141     rhs_ty = ASSERT( isFunTy inst_con_ty ) funArgTy inst_con_ty
 142         -- Instantiate the data con with the
 143         -- type variables from the tycon
 144         -- NB: a newtype DataCon has a type that must look like
 145         --        forall tvs.  <arg-ty> -> T tvs
 146         -- Note that we *can't* use dataConInstOrigArgTys here because
 147         -- the newtype arising from   class Foo a => Bar a where {}
 148         -- has a single argument (Foo a) that is a *type class*, so
 149         -- dataConInstOrigArgTys returns [].
 150
 151     etad_tvs :: [TyVar] -- Matched lazily, so that mkNewTypeCo can
 152     etad_rhs :: Type    -- return a TyCon without pulling on rhs_ty
 153                         -- See Note [Tricky iface loop] in LoadIface
 154     (etad_tvs, etad_rhs) = eta_reduce (reverse tvs) rhs_ty
 155
 156     eta_reduce :: [TyVar]               -- Reversed
 157                -> Type                  -- Rhs type
 158                -> ([TyVar], Type)       -- Eta-reduced version (tyvars in normal order)
 159     eta_reduce (a:as) ty | Just (fun, arg) <- splitAppTy_maybe ty,
 160                            Just tv <- getTyVar_maybe arg,
 161                            tv == a,
 162                            not (a `elemVarSet` tyVarsOfType fun)
 163                          = eta_reduce as fun
 164     eta_reduce tvs ty = (reverse tvs, ty)
 165
 166
 167 ------------------------------------------------------
 168 buildDataCon :: Name -> Bool
 169             -> [HsBang]
 170             -> [Name]                   -- Field labels
 171             -> [TyVar] -> [TyVar]       -- Univ and ext
 172             -> [(TyVar,Type)]           -- Equality spec
 173             -> ThetaType                -- Does not include the "stupid theta"
 174                                         -- or the GADT equalities
 175             -> [Type] -> Type           -- Argument and result types
 176             -> TyCon                    -- Rep tycon
 177             -> TcRnIf m n DataCon
 178 -- A wrapper for DataCon.mkDataCon that
 179 --   a) makes the worker Id
 180 --   b) makes the wrapper Id if necessary, including
 181 --      allocating its unique (hence monadic)
 182 buildDataCon src_name declared_infix arg_stricts field_lbls
 183              univ_tvs ex_tvs eq_spec ctxt arg_tys res_ty rep_tycon
 184   = do  { wrap_name <- newImplicitBinder src_name mkDataConWrapperOcc
 185         ; work_name <- newImplicitBinder src_name mkDataConWorkerOcc
 186         -- This last one takes the name of the data constructor in the source
 187         -- code, which (for Haskell source anyway) will be in the DataName name
 188         -- space, and puts it into the VarName name space
 189
 190         ; let
 191                 stupid_ctxt = mkDataConStupidTheta rep_tycon arg_tys univ_tvs
 192                 data_con = mkDataCon src_name declared_infix
 193                                      arg_stricts field_lbls
 194                                      univ_tvs ex_tvs eq_spec ctxt
 195                                      arg_tys res_ty rep_tycon
 196                                      stupid_ctxt dc_ids
 197                 dc_ids = mkDataConIds wrap_name work_name data_con
 198
 199         ; return data_con }
 200
 201
 202 -- The stupid context for a data constructor should be limited to
 203 -- the type variables mentioned in the arg_tys
 204 -- ToDo: Or functionally dependent on?
 205 --       This whole stupid theta thing is, well, stupid.
 206 mkDataConStupidTheta :: TyCon -> [Type] -> [TyVar] -> [PredType]
 207 mkDataConStupidTheta tycon arg_tys univ_tvs
 208   | null stupid_theta = []      -- The common case
 209   | otherwise         = filter in_arg_tys stupid_theta
 210   where
 211     tc_subst     = zipTopTvSubst (tyConTyVars tycon) (mkTyVarTys univ_tvs)
 212     stupid_theta = substTheta tc_subst (tyConStupidTheta tycon)
 213         -- Start by instantiating the master copy of the
 214         -- stupid theta, taken from the TyCon
 215
 216     arg_tyvars      = tyVarsOfTypes arg_tys
 217     in_arg_tys pred = not $ isEmptyVarSet $
 218                       tyVarsOfPred pred `intersectVarSet` arg_tyvars
 219 \end{code}
 220
 221
 222 ------------------------------------------------------
 223 \begin{code}
 224 type TcMethInfo = (Name, DefMethSpec, Type)  -- A temporary intermediate, to communicate
 225                                              -- between tcClassSigs and buildClass
 226
 227 buildClass :: Bool              -- True <=> do not include unfoldings
 228                                 --          on dict selectors
 229                                 -- Used when importing a class without -O
 230            -> Name -> [TyVar] -> ThetaType
 231            -> [FunDep TyVar]               -- Functional dependencies
 232            -> [TyThing]                    -- Associated types
 233            -> [TcMethInfo]                 -- Method info
 234            -> RecFlag                      -- Info for type constructor
 235            -> TcRnIf m n Class
 236
 237 buildClass no_unf class_name tvs sc_theta fds ats sig_stuff tc_isrec
 238   = do  { traceIf (text "buildClass")
 239         ; tycon_name <- newImplicitBinder class_name mkClassTyConOcc
 240         ; datacon_name <- newImplicitBinder class_name mkClassDataConOcc
 241                 -- The class name is the 'parent' for this datacon, not its tycon,
 242                 -- because one should import the class to get the binding for
 243                 -- the datacon
 244
 245         ; fixM (\ rec_clas -> do {      -- Only name generation inside loop
 246
 247         ; op_items <- mapM (mk_op_item rec_clas) sig_stuff
 248                         -- Build the selector id and default method id
 249
 250         ; let (eq_theta, dict_theta) = partition isEqPred sc_theta
 251
 252               -- We only make selectors for the *value* superclasses,
 253               -- not equality predicates
 254         ; sc_sel_names <- mapM  (newImplicitBinder class_name . mkSuperDictSelOcc)
 255                                 [1..length dict_theta]
 256         ; let sc_sel_ids = [ mkDictSelId no_unf sc_name rec_clas
 257                            | sc_name <- sc_sel_names]
 258               -- We number off the Dict superclass selectors, 1, 2, 3 etc so that we
 259               -- can construct names for the selectors. Thus
 260               --      class (C a, C b) => D a b where ...
 261               -- gives superclass selectors
 262               --      D_sc1, D_sc2
 263               -- (We used to call them D_C, but now we can have two different
 264               --  superclasses both called C!)
 265
 266         ; let use_newtype = null eq_theta && (length dict_theta + length sig_stuff == 1)
 267                 -- Use a newtype if the data constructor has
 268                 --      (a) exactly one value field
 269                 --      (b) no existential or equality-predicate fields
 270                 -- i.e. exactly one operation or superclass taken together
 271                 -- See note [Class newtypes and equality predicates]
 272
 273                 -- We play a bit fast and loose by treating the dictionary
 274                 -- superclasses as ordinary arguments.  That means that in
 275                 -- the case of
 276                 --     class C a => D a
 277                 -- we don't get a newtype with no arguments!
 278               args      = sc_sel_names ++ op_names
 279               op_tys    = [ty | (_,_,ty) <- sig_stuff]
 280               op_names  = [op | (op,_,_) <- sig_stuff]
 281               arg_tys   = map mkPredTy dict_theta ++ op_tys
 282               rec_tycon = classTyCon rec_clas
 283
 284         ; dict_con <- buildDataCon datacon_name
 285                                    False        -- Not declared infix
 286                                    (map (const HsNoBang) args)
 287                                    [{- No fields -}]
 288                                    tvs [{- no existentials -}]
 289                                    [{- No GADT equalities -}]
 290                                    eq_theta
 291                                    arg_tys
 292                                    (mkTyConApp rec_tycon (mkTyVarTys tvs))
 293                                    rec_tycon
 294
 295         ; rhs <- if use_newtype
 296                  then mkNewTyConRhs tycon_name rec_tycon dict_con
 297                  else return (mkDataTyConRhs [dict_con])
 298
 299         ; let { clas_kind = mkArrowKinds (map tyVarKind tvs) liftedTypeKind
 300
 301               ; tycon = mkClassTyCon tycon_name clas_kind tvs
 302                                      rhs rec_clas tc_isrec
 303                 -- A class can be recursive, and in the case of newtypes
 304                 -- this matters.  For example
 305                 --      class C a where { op :: C b => a -> b -> Int }
 306                 -- Because C has only one operation, it is represented by
 307                 -- a newtype, and it should be a *recursive* newtype.
 308                 -- [If we don't make it a recursive newtype, we'll expand the
 309                 -- newtype like a synonym, but that will lead to an infinite
 310                 -- type]
 311               ; atTyCons = [tycon | ATyCon tycon <- ats]
 312
 313               ; result = mkClass class_name tvs fds
 314                                  (eq_theta ++ dict_theta)  -- Equalities first
 315                                  (length eq_theta)         -- Number of equalities
 316                                  sc_sel_ids atTyCons
 317                                  op_items tycon
 318               }
 319         ; traceIf (text "buildClass" <+> ppr tycon)
 320         ; return result
 321         })}
 322   where
 323     mk_op_item :: Class -> TcMethInfo -> TcRnIf n m ClassOpItem
 324     mk_op_item rec_clas (op_name, dm_spec, _)
 325       = do { dm_info <- case dm_spec of
 326                           NoDM      -> return NoDefMeth
 327                           GenericDM -> return GenDefMeth
 328                           VanillaDM -> do { dm_name <- newImplicitBinder op_name mkDefaultMethodOcc
 329                                           ; return (DefMeth dm_name) }
 330            ; return (mkDictSelId no_unf op_name rec_clas, dm_info) }
 331 \end{code}
 332
 333 Note [Class newtypes and equality predicates]
 334 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 335 Consider
 336         class (a ~ F b) => C a b where
 337           op :: a -> b
 338
 339 We cannot represent this by a newtype, even though it's not
 340 existential, and there's only one value field, because we do
 341 capture an equality predicate:
 342
 343         data C a b where
 344           MkC :: forall a b. (a ~ F b) => (a->b) -> C a b
 345
 346 We need to access this equality predicate when we get passes a C
 347 dictionary.  See Trac #2238
 348