compiler/iface/IfaceEnv.lhs

   1 (c) The University of Glasgow 2002-2006
   2
   3 \begin{code}
   4 module IfaceEnv (
   5         newGlobalBinder, newIPName, newImplicitBinder,
   6         lookupIfaceTop,
   7         lookupOrig, lookupOrigNameCache, extendNameCache,
   8         newIfaceName, newIfaceNames,
   9         extendIfaceIdEnv, extendIfaceTyVarEnv,
  10         tcIfaceLclId,     tcIfaceTyVar,
  11         tcIfaceTick,
  12
  13         ifaceExportNames,
  14
  15         -- Name-cache stuff
  16         allocateGlobalBinder, initNameCache,
  17         getNameCache, setNameCache
  18    ) where
  19
  20 #include "HsVersions.h"
  21
  22 import TcRnMonad
  23 import TysWiredIn
  24 import HscTypes
  25 import TyCon
  26 import DataCon
  27 import Var
  28 import Name
  29 import OccName
  30 import PrelNames
  31 import Module
  32 import UniqFM
  33 import FastString
  34 import UniqSupply
  35 import FiniteMap
  36 import BasicTypes
  37 import SrcLoc
  38 import MkId
  39
  40 import Outputable
  41 \end{code}
  42
  43
  44 %*********************************************************
  45 %*                                                      *
  46         Allocating new Names in the Name Cache
  47 %*                                                      *
  48 %*********************************************************
  49
  50 \begin{code}
  51 newGlobalBinder :: Module -> OccName -> SrcSpan -> TcRnIf a b Name
  52 -- Used for source code and interface files, to make the
  53 -- Name for a thing, given its Module and OccName
  54 --
  55 -- The cache may already already have a binding for this thing,
  56 -- because we may have seen an occurrence before, but now is the
  57 -- moment when we know its Module and SrcLoc in their full glory
  58
  59 newGlobalBinder mod occ loc
  60   = do  { mod `seq` occ `seq` return () -- See notes with lookupOrig_help
  61 --      ; traceIf (text "newGlobalBinder" <+> ppr mod <+> ppr occ <+> ppr loc)
  62         ; name_supply <- getNameCache
  63         ; let (name_supply', name) = allocateGlobalBinder
  64                                         name_supply mod occ
  65                                         loc
  66         ; setNameCache name_supply'
  67         ; return name }
  68
  69 allocateGlobalBinder
  70   :: NameCache
  71   -> Module -> OccName -> SrcSpan
  72   -> (NameCache, Name)
  73 allocateGlobalBinder name_supply mod occ loc
  74   = case lookupOrigNameCache (nsNames name_supply) mod occ of
  75         -- A hit in the cache!  We are at the binding site of the name.
  76         -- This is the moment when we know the SrcLoc
  77         -- of the Name, so we set this field in the Name we return.
  78         --
  79         -- Then (bogus) multiple bindings of the same Name
  80         -- get different SrcLocs can can be reported as such.
  81         --
  82         -- Possible other reason: it might be in the cache because we
  83         --      encountered an occurrence before the binding site for an
  84         --      implicitly-imported Name.  Perhaps the current SrcLoc is
  85         --      better... but not really: it'll still just say 'imported'
  86         --
  87         -- IMPORTANT: Don't mess with wired-in names.
  88         --            Their wired-in-ness is in their NameSort
  89         --            and their Module is correct.
  90
  91         Just name | isWiredInName name -> (name_supply, name)
  92                   | otherwise -> (new_name_supply, name')
  93                   where
  94                     uniq      = nameUnique name
  95                     name'     = mkExternalName uniq mod occ loc
  96                     new_cache = extendNameCache (nsNames name_supply) mod occ name'
  97                     new_name_supply = name_supply {nsNames = new_cache}
  98
  99         -- Miss in the cache!
 100         -- Build a completely new Name, and put it in the cache
 101         Nothing -> (new_name_supply, name)
 102                 where
 103                   (us', us1)      = splitUniqSupply (nsUniqs name_supply)
 104                   uniq            = uniqFromSupply us1
 105                   name            = mkExternalName uniq mod occ loc
 106                   new_cache       = extendNameCache (nsNames name_supply) mod occ name
 107                   new_name_supply = name_supply {nsUniqs = us', nsNames = new_cache}
 108
 109
 110 newImplicitBinder :: Name                       -- Base name
 111                   -> (OccName -> OccName)       -- Occurrence name modifier
 112                   -> TcRnIf m n Name            -- Implicit name
 113 -- Called in BuildTyCl to allocate the implicit binders of type/class decls
 114 -- For source type/class decls, this is the first occurrence
 115 -- For iface ones, the LoadIface has alrady allocated a suitable name in the cache
 116 newImplicitBinder base_name mk_sys_occ
 117   = newGlobalBinder (nameModule base_name)
 118                     (mk_sys_occ (nameOccName base_name))
 119                     (nameSrcSpan base_name)
 120
 121 ifaceExportNames :: [IfaceExport] -> TcRnIf gbl lcl [AvailInfo]
 122 ifaceExportNames exports = do
 123   mod_avails <- mapM (\(mod,avails) -> mapM (lookupAvail mod) avails) exports
 124   return (concat mod_avails)
 125
 126 -- Convert OccNames in GenAvailInfo to Names.
 127 lookupAvail :: Module -> GenAvailInfo OccName -> TcRnIf a b AvailInfo
 128 lookupAvail mod (Avail n) = do
 129   n' <- lookupOrig mod n
 130   return (Avail n')
 131 lookupAvail mod (AvailTC p_occ occs) = do
 132   p_name <- lookupOrig mod p_occ
 133   let lookup_sub occ | occ == p_occ = return p_name
 134                      | otherwise    = lookupOrig mod occ
 135   subs <- mappM lookup_sub occs
 136   return (AvailTC p_name subs)
 137         -- Remember that 'occs' is all the exported things, including
 138         -- the parent.  It's possible to export just class ops without
 139         -- the class, which shows up as C( op ) here. If the class was
 140         -- exported too we'd have C( C, op )
 141
 142 lookupOrig :: Module -> OccName ->  TcRnIf a b Name
 143 lookupOrig mod occ
 144   = do  {       -- First ensure that mod and occ are evaluated
 145                 -- If not, chaos can ensue:
 146                 --      we read the name-cache
 147                 --      then pull on mod (say)
 148                 --      which does some stuff that modifies the name cache
 149                 -- This did happen, with tycon_mod in TcIface.tcIfaceAlt (DataAlt..)
 150           mod `seq` occ `seq` return ()
 151 --      ; traceIf (text "lookup_orig" <+> ppr mod <+> ppr occ)
 152
 153         ; name_cache <- getNameCache
 154         ; case lookupOrigNameCache (nsNames name_cache) mod occ of {
 155               Just name -> returnM name;
 156               Nothing   ->
 157               let
 158                 us        = nsUniqs name_cache
 159                 uniq      = uniqFromSupply us
 160                 name      = mkExternalName uniq mod occ noSrcSpan
 161                 new_cache = extendNameCache (nsNames name_cache) mod occ name
 162               in
 163               case splitUniqSupply us of { (us',_) -> do
 164                 setNameCache name_cache{ nsUniqs = us', nsNames = new_cache }
 165                 return name
 166     }}}
 167
 168 newIPName :: IPName OccName -> TcRnIf m n (IPName Name)
 169 newIPName occ_name_ip
 170   = getNameCache                `thenM` \ name_supply ->
 171     let
 172         ipcache = nsIPs name_supply
 173     in
 174     case lookupFM ipcache key of
 175         Just name_ip -> returnM name_ip
 176         Nothing      -> setNameCache new_ns     `thenM_`
 177                         returnM name_ip
 178                   where
 179                      (us', us1)  = splitUniqSupply (nsUniqs name_supply)
 180                      uniq        = uniqFromSupply us1
 181                      name_ip     = mapIPName (mkIPName uniq) occ_name_ip
 182                      new_ipcache = addToFM ipcache key name_ip
 183                      new_ns      = name_supply {nsUniqs = us', nsIPs = new_ipcache}
 184     where
 185         key = occ_name_ip       -- Ensures that ?x and %x get distinct Names
 186 \end{code}
 187
 188         Local helper functions (not exported)
 189
 190 \begin{code}
 191 lookupOrigNameCache :: OrigNameCache -> Module -> OccName -> Maybe Name
 192 lookupOrigNameCache nc mod occ
 193   | mod == dATA_TUP || mod == gHC_PRIM,         -- Boxed tuples from one,
 194     Just tup_info <- isTupleOcc_maybe occ       -- unboxed from the other
 195   =     -- Special case for tuples; there are too many
 196         -- of them to pre-populate the original-name cache
 197     Just (mk_tup_name tup_info)
 198   where
 199     mk_tup_name (ns, boxity, arity)
 200         | ns == tcName   = tyConName (tupleTyCon boxity arity)
 201         | ns == dataName = dataConName (tupleCon boxity arity)
 202         | otherwise      = Var.varName (dataConWorkId (tupleCon boxity arity))
 203
 204 lookupOrigNameCache nc mod occ  -- The normal case
 205   = case lookupModuleEnv nc mod of
 206         Nothing      -> Nothing
 207         Just occ_env -> lookupOccEnv occ_env occ
 208
 209 extendOrigNameCache :: OrigNameCache -> Name -> OrigNameCache
 210 extendOrigNameCache nc name
 211   = extendNameCache nc (nameModule name) (nameOccName name) name
 212
 213 extendNameCache :: OrigNameCache -> Module -> OccName -> Name -> OrigNameCache
 214 extendNameCache nc mod occ name
 215   = extendModuleEnv_C combine nc mod (unitOccEnv occ name)
 216   where
 217     combine occ_env _ = extendOccEnv occ_env occ name
 218
 219 getNameCache :: TcRnIf a b NameCache
 220 getNameCache = do { HscEnv { hsc_NC = nc_var } <- getTopEnv;
 221                     readMutVar nc_var }
 222
 223 setNameCache :: NameCache -> TcRnIf a b ()
 224 setNameCache nc = do { HscEnv { hsc_NC = nc_var } <- getTopEnv;
 225                        writeMutVar nc_var nc }
 226 \end{code}
 227
 228
 229 \begin{code}
 230 initNameCache :: UniqSupply -> [Name] -> NameCache
 231 initNameCache us names
 232   = NameCache { nsUniqs = us,
 233                 nsNames = initOrigNames names,
 234                 nsIPs   = emptyFM }
 235
 236 initOrigNames :: [Name] -> OrigNameCache
 237 initOrigNames names = foldl extendOrigNameCache emptyModuleEnv names
 238 \end{code}
 239
 240
 241
 242 %************************************************************************
 243 %*                                                                      *
 244                 Type variables and local Ids
 245 %*                                                                      *
 246 %************************************************************************
 247
 248 \begin{code}
 249 tcIfaceLclId :: FastString -> IfL Id
 250 tcIfaceLclId occ
 251   = do  { lcl <- getLclEnv
 252         ; case (lookupUFM (if_id_env lcl) occ) of
 253             Just ty_var -> return ty_var
 254             Nothing     -> failIfM (text "Iface id out of scope: " <+> ppr occ)
 255         }
 256
 257 extendIfaceIdEnv :: [Id] -> IfL a -> IfL a
 258 extendIfaceIdEnv ids thing_inside
 259   = do  { env <- getLclEnv
 260         ; let { id_env' = addListToUFM (if_id_env env) pairs
 261               ; pairs   = [(occNameFS (getOccName id), id) | id <- ids] }
 262         ; setLclEnv (env { if_id_env = id_env' }) thing_inside }
 263
 264
 265 tcIfaceTyVar :: FastString -> IfL TyVar
 266 tcIfaceTyVar occ
 267   = do  { lcl <- getLclEnv
 268         ; case (lookupUFM (if_tv_env lcl) occ) of
 269             Just ty_var -> return ty_var
 270             Nothing     -> failIfM (text "Iface type variable out of scope: " <+> ppr occ)
 271         }
 272
 273 extendIfaceTyVarEnv :: [TyVar] -> IfL a -> IfL a
 274 extendIfaceTyVarEnv tyvars thing_inside
 275   = do  { env <- getLclEnv
 276         ; let { tv_env' = addListToUFM (if_tv_env env) pairs
 277               ; pairs   = [(occNameFS (getOccName tv), tv) | tv <- tyvars] }
 278         ; setLclEnv (env { if_tv_env = tv_env' }) thing_inside }
 279 \end{code}
 280
 281
 282 %************************************************************************
 283 %*                                                                      *
 284                 Getting from RdrNames to Names
 285 %*                                                                      *
 286 %************************************************************************
 287
 288 \begin{code}
 289 lookupIfaceTop :: OccName -> IfL Name
 290 -- Look up a top-level name from the current Iface module
 291 lookupIfaceTop occ
 292   = do  { env <- getLclEnv; lookupOrig (if_mod env) occ }
 293
 294 newIfaceName :: OccName -> IfL Name
 295 newIfaceName occ
 296   = do  { uniq <- newUnique
 297         ; return $! mkInternalName uniq occ noSrcSpan }
 298
 299 newIfaceNames :: [OccName] -> IfL [Name]
 300 newIfaceNames occs
 301   = do  { uniqs <- newUniqueSupply
 302         ; return [ mkInternalName uniq occ noSrcSpan
 303                  | (occ,uniq) <- occs `zip` uniqsFromSupply uniqs] }
 304 \end{code}
 305
 306 %************************************************************************
 307 %*                                                                      *
 308                 (Re)creating tick boxes
 309 %*                                                                      *
 310 %************************************************************************
 311
 312 \begin{code}
 313 tcIfaceTick :: Module -> Int -> IfL Id
 314 tcIfaceTick modName tickNo
 315   = do { uniq <- newUnique
 316        ; return $ mkTickBoxOpId uniq modName tickNo
 317        }
 318 \end{code}
 319
 320