compiler/iface/LoadIface.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Loading interface files
   7
   8 \begin{code}
   9 {-# OPTIONS -w #-}
  10 -- The above warning supression flag is a temporary kludge.
  11 -- While working on this module you are encouraged to remove it and fix
  12 -- any warnings in the module. See
  13 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  14 -- for details
  15
  16 module LoadIface (
  17         loadInterface, loadInterfaceForName, loadWiredInHomeIface,
  18         loadSrcInterface, loadSysInterface, loadOrphanModules,
  19         findAndReadIface, readIface,    -- Used when reading the module's old interface
  20         loadDecls,      -- Should move to TcIface and be renamed
  21         initExternalPackageState,
  22
  23         ifaceStats, pprModIface, showIface
  24    ) where
  25
  26 #include "HsVersions.h"
  27
  28 import {-# SOURCE #-}   TcIface( tcIfaceDecl, tcIfaceRules, tcIfaceInst,
  29                                  tcIfaceFamInst, tcIfaceVectInfo )
  30
  31 import DynFlags
  32 import IfaceSyn
  33 import IfaceEnv
  34 import HscTypes
  35
  36 import BasicTypes hiding (SuccessFlag(..))
  37 import TcRnMonad
  38 import Type
  39
  40 import PrelNames
  41 import PrelInfo
  42 import PrelRules
  43 import Rules
  44 import InstEnv
  45 import FamInstEnv
  46 import Name
  47 import NameEnv
  48 import MkId
  49 import Module
  50 import OccName
  51 import SrcLoc
  52 import Maybes
  53 import ErrUtils
  54 import Finder
  55 import LazyUniqFM
  56 import StaticFlags
  57 import Outputable
  58 import BinIface
  59 import Panic
  60
  61 import Data.List
  62 import Data.Maybe
  63 import Data.IORef
  64 \end{code}
  65
  66
  67 %************************************************************************
  68 %*                                                                      *
  69         loadSrcInterface, loadOrphanModules, loadHomeInterface
  70
  71                 These three are called from TcM-land
  72 %*                                                                      *
  73 %************************************************************************
  74
  75 \begin{code}
  76 -- | Load the interface corresponding to an @import@ directive in
  77 -- source code.  On a failure, fail in the monad with an error message.
  78 loadSrcInterface :: SDoc -> ModuleName -> IsBootInterface -> RnM ModIface
  79 loadSrcInterface doc mod want_boot  = do
  80   -- We must first find which Module this import refers to.  This involves
  81   -- calling the Finder, which as a side effect will search the filesystem
  82   -- and create a ModLocation.  If successful, loadIface will read the
  83   -- interface; it will call the Finder again, but the ModLocation will be
  84   -- cached from the first search.
  85   hsc_env <- getTopEnv
  86   res <- liftIO $ findImportedModule hsc_env mod Nothing
  87   case res of
  88     Found _ mod -> do
  89       mb_iface <- initIfaceTcRn $ loadInterface doc mod (ImportByUser want_boot)
  90       case mb_iface of
  91         Failed err      -> failWithTc err
  92         Succeeded iface -> return iface
  93     err ->
  94         let dflags = hsc_dflags hsc_env in
  95         failWithTc (cannotFindInterface dflags mod err)
  96
  97 -- | Load interfaces for a collection of orphan modules.
  98 loadOrphanModules :: [Module]         -- the modules
  99                   -> Bool             -- these are family instance-modules
 100                   -> TcM ()
 101 loadOrphanModules mods isFamInstMod
 102   | null mods = return ()
 103   | otherwise = initIfaceTcRn $
 104                 do { traceIf (text "Loading orphan modules:" <+>
 105                                  fsep (map ppr mods))
 106                    ; mapM_ load mods
 107                    ; return () }
 108   where
 109     load mod   = loadSysInterface (mk_doc mod) mod
 110     mk_doc mod
 111       | isFamInstMod = ppr mod <+> ptext SLIT("is a family-instance module")
 112       | otherwise    = ppr mod <+> ptext SLIT("is a orphan-instance module")
 113
 114 -- | Loads the interface for a given Name.
 115 loadInterfaceForName :: SDoc -> Name -> TcRn ModIface
 116 loadInterfaceForName doc name
 117   = do  {
 118 #ifdef DEBUG
 119                 -- Should not be called with a name from the module being compiled
 120           this_mod <- getModule
 121         ; ASSERT2( not (nameIsLocalOrFrom this_mod name), ppr name <+> parens doc )
 122 #endif
 123           initIfaceTcRn $ loadSysInterface doc (nameModule name)
 124     }
 125
 126 -- | An 'IfM' function to load the home interface for a wired-in thing,
 127 -- so that we're sure that we see its instance declarations and rules
 128 -- See Note [Loading instances]
 129 loadWiredInHomeIface :: Name -> IfM lcl ()
 130 loadWiredInHomeIface name
 131   = ASSERT( isWiredInName name )
 132     do loadSysInterface doc (nameModule name); return ()
 133   where
 134     doc = ptext SLIT("Need home interface for wired-in thing") <+> ppr name
 135
 136 -- | A wrapper for 'loadInterface' that throws an exception if it fails
 137 loadSysInterface :: SDoc -> Module -> IfM lcl ModIface
 138 loadSysInterface doc mod_name
 139   = do  { mb_iface <- loadInterface doc mod_name ImportBySystem
 140         ; case mb_iface of
 141             Failed err      -> ghcError (ProgramError (showSDoc err))
 142             Succeeded iface -> return iface }
 143 \end{code}
 144
 145 Note [Loading instances]
 146 ~~~~~~~~~~~~~~~~~~~~~~~~
 147 We need to make sure that we have at least *read* the interface files
 148 for any module with an instance decl or RULE that we might want.
 149
 150 * If the instance decl is an orphan, we have a whole separate mechanism
 151   (loadOprhanModules)
 152
 153 * If the instance decl not an orphan, then the act of looking at the
 154   TyCon or Class will force in the defining module for the
 155   TyCon/Class, and hence the instance decl
 156
 157 * BUT, if the TyCon is a wired-in TyCon, we don't really need its interface;
 158   but we must make sure we read its interface in case it has instances or
 159   rules.  That is what LoadIface.loadWiredInHomeInterface does.  It's called
 160   from TcIface.{tcImportDecl, checkWiredInTyCon, ifCHeckWiredInThing}
 161
 162 All of this is done by the type checker. The renamer plays no role.
 163 (It used to, but no longer.)
 164
 165
 166
 167 %*********************************************************
 168 %*                                                      *
 169                 loadInterface
 170
 171         The main function to load an interface
 172         for an imported module, and put it in
 173         the External Package State
 174 %*                                                      *
 175 %*********************************************************
 176
 177 \begin{code}
 178 loadInterface :: SDoc -> Module -> WhereFrom
 179               -> IfM lcl (MaybeErr Message ModIface)
 180
 181 -- loadInterface looks in both the HPT and PIT for the required interface
 182 -- If not found, it loads it, and puts it in the PIT (always).
 183
 184 -- If it can't find a suitable interface file, we
 185 --      a) modify the PackageIfaceTable to have an empty entry
 186 --              (to avoid repeated complaints)
 187 --      b) return (Left message)
 188 --
 189 -- It's not necessarily an error for there not to be an interface
 190 -- file -- perhaps the module has changed, and that interface
 191 -- is no longer used
 192
 193 loadInterface doc_str mod from
 194   = do  {       -- Read the state
 195           (eps,hpt) <- getEpsAndHpt
 196
 197         ; traceIf (text "Considering whether to load" <+> ppr mod <+> ppr from)
 198
 199                 -- Check whether we have the interface already
 200         ; dflags <- getDOpts
 201         ; case lookupIfaceByModule dflags hpt (eps_PIT eps) mod of {
 202             Just iface
 203                 -> return (Succeeded iface) ;   -- Already loaded
 204                         -- The (src_imp == mi_boot iface) test checks that the already-loaded
 205                         -- interface isn't a boot iface.  This can conceivably happen,
 206                         -- if an earlier import had a before we got to real imports.   I think.
 207             other -> do {
 208
 209           let { hi_boot_file = case from of
 210                                 ImportByUser usr_boot -> usr_boot
 211                                 ImportBySystem        -> sys_boot
 212
 213               ; mb_dep   = lookupUFM (eps_is_boot eps) (moduleName mod)
 214               ; sys_boot = case mb_dep of
 215                                 Just (_, is_boot) -> is_boot
 216                                 Nothing           -> False
 217                         -- The boot-ness of the requested interface,
 218               }         -- based on the dependencies in directly-imported modules
 219
 220         -- READ THE MODULE IN
 221         ; read_result <- findAndReadIface doc_str mod hi_boot_file
 222         ; case read_result of {
 223             Failed err -> do
 224                 { let fake_iface = emptyModIface mod
 225
 226                 ; updateEps_ $ \eps ->
 227                         eps { eps_PIT = extendModuleEnv (eps_PIT eps) (mi_module fake_iface) fake_iface }
 228                         -- Not found, so add an empty iface to
 229                         -- the EPS map so that we don't look again
 230
 231                 ; return (Failed err) } ;
 232
 233         -- Found and parsed!
 234             Succeeded (iface, file_path)        -- Sanity check:
 235                 | ImportBySystem <- from,       --   system-importing...
 236                   modulePackageId (mi_module iface) == thisPackage dflags,
 237                                                 --   a home-package module...
 238                   Nothing <- mb_dep             --   that we know nothing about
 239                 -> return (Failed (badDepMsg mod))
 240
 241                 | otherwise ->
 242
 243         let
 244             loc_doc = text file_path
 245         in
 246         initIfaceLcl mod loc_doc $ do
 247
 248         --      Load the new ModIface into the External Package State
 249         -- Even home-package interfaces loaded by loadInterface
 250         --      (which only happens in OneShot mode; in Batch/Interactive
 251         --      mode, home-package modules are loaded one by one into the HPT)
 252         -- are put in the EPS.
 253         --
 254         -- The main thing is to add the ModIface to the PIT, but
 255         -- we also take the
 256         --      IfaceDecls, IfaceInst, IfaceFamInst, IfaceRules, IfaceVectInfo
 257         -- out of the ModIface and put them into the big EPS pools
 258
 259         -- NB: *first* we do loadDecl, so that the provenance of all the locally-defined
 260         ---    names is done correctly (notably, whether this is an .hi file or .hi-boot file).
 261         --     If we do loadExport first the wrong info gets into the cache (unless we
 262         --      explicitly tag each export which seems a bit of a bore)
 263
 264         ; ignore_prags      <- doptM Opt_IgnoreInterfacePragmas
 265         ; new_eps_decls     <- loadDecls ignore_prags (mi_decls iface)
 266         ; new_eps_insts     <- mapM tcIfaceInst (mi_insts iface)
 267         ; new_eps_fam_insts <- mapM tcIfaceFamInst (mi_fam_insts iface)
 268         ; new_eps_rules     <- tcIfaceRules ignore_prags (mi_rules iface)
 269         ; new_eps_vect_info <- tcIfaceVectInfo mod (mkNameEnv new_eps_decls)
 270                                                (mi_vect_info iface)
 271
 272         ; let { final_iface = iface {
 273                                 mi_decls     = panic "No mi_decls in PIT",
 274                                 mi_insts     = panic "No mi_insts in PIT",
 275                                 mi_fam_insts = panic "No mi_fam_insts in PIT",
 276                                 mi_rules     = panic "No mi_rules in PIT"
 277                               }
 278                }
 279
 280         ; updateEps_  $ \ eps ->
 281             eps {
 282               eps_PIT          = extendModuleEnv (eps_PIT eps) mod final_iface,
 283               eps_PTE          = addDeclsToPTE   (eps_PTE eps) new_eps_decls,
 284               eps_rule_base    = extendRuleBaseList (eps_rule_base eps)
 285                                                     new_eps_rules,
 286               eps_inst_env     = extendInstEnvList (eps_inst_env eps)
 287                                                    new_eps_insts,
 288               eps_fam_inst_env = extendFamInstEnvList (eps_fam_inst_env eps)
 289                                                       new_eps_fam_insts,
 290               eps_vect_info    = plusVectInfo (eps_vect_info eps)
 291                                               new_eps_vect_info,
 292               eps_mod_fam_inst_env
 293                                = let
 294                                    fam_inst_env =
 295                                      extendFamInstEnvList emptyFamInstEnv
 296                                                           new_eps_fam_insts
 297                                  in
 298                                  extendModuleEnv (eps_mod_fam_inst_env eps)
 299                                                  mod
 300                                                  fam_inst_env,
 301               eps_stats        = addEpsInStats (eps_stats eps)
 302                                                (length new_eps_decls)
 303                                                (length new_eps_insts)
 304                                                (length new_eps_rules) }
 305
 306         ; return (Succeeded final_iface)
 307     }}}}
 308
 309 badDepMsg mod
 310   = hang (ptext SLIT("Interface file inconsistency:"))
 311        2 (sep [ptext SLIT("home-package module") <+> quotes (ppr mod) <+> ptext SLIT("is needed,"),
 312                ptext SLIT("but is not listed in the dependencies of the interfaces directly imported by the module being compiled")])
 313
 314 -----------------------------------------------------
 315 --      Loading type/class/value decls
 316 -- We pass the full Module name here, replete with
 317 -- its package info, so that we can build a Name for
 318 -- each binder with the right package info in it
 319 -- All subsequent lookups, including crucially lookups during typechecking
 320 -- the declaration itself, will find the fully-glorious Name
 321 --
 322 -- We handle ATs specially.  They are not main declarations, but also not
 323 -- implict things (in particular, adding them to `implicitTyThings' would mess
 324 -- things up in the renaming/type checking of source programs).
 325 -----------------------------------------------------
 326
 327 addDeclsToPTE :: PackageTypeEnv -> [(Name,TyThing)] -> PackageTypeEnv
 328 addDeclsToPTE pte things = extendNameEnvList pte things
 329
 330 loadDecls :: Bool
 331           -> [(Version, IfaceDecl)]
 332           -> IfL [(Name,TyThing)]
 333 loadDecls ignore_prags ver_decls
 334    = do { mod <- getIfModule
 335         ; thingss <- mapM (loadDecl ignore_prags mod) ver_decls
 336         ; return (concat thingss)
 337         }
 338
 339 loadDecl :: Bool                    -- Don't load pragmas into the decl pool
 340          -> Module
 341           -> (Version, IfaceDecl)
 342           -> IfL [(Name,TyThing)]   -- The list can be poked eagerly, but the
 343                                     -- TyThings are forkM'd thunks
 344 loadDecl ignore_prags mod (_version, decl)
 345   = do  {       -- Populate the name cache with final versions of all
 346                 -- the names associated with the decl
 347           main_name      <- lookupOrig mod (ifName decl)
 348 --        ; traceIf (text "Loading decl for " <> ppr main_name)
 349         ; implicit_names <- mapM (lookupOrig mod) (ifaceDeclSubBndrs decl)
 350
 351         -- Typecheck the thing, lazily
 352         -- NB. Firstly, the laziness is there in case we never need the
 353         -- declaration (in one-shot mode), and secondly it is there so that
 354         -- we don't look up the occurrence of a name before calling mk_new_bndr
 355         -- on the binder.  This is important because we must get the right name
 356         -- which includes its nameParent.
 357
 358         ; thing <- forkM doc $ do { bumpDeclStats main_name
 359                                   ; tcIfaceDecl ignore_prags decl }
 360
 361         -- Populate the type environment with the implicitTyThings too.
 362         --
 363         -- Note [Tricky iface loop]
 364         -- ~~~~~~~~~~~~~~~~~~~~~~~~
 365         -- Summary: The delicate point here is that 'mini-env' must be
 366         -- buildable from 'thing' without demanding any of the things
 367         -- 'forkM'd by tcIfaceDecl.
 368         --
 369         -- In more detail: Consider the example
 370         --      data T a = MkT { x :: T a }
 371         -- The implicitTyThings of T are:  [ <datacon MkT>, <selector x>]
 372         -- (plus their workers, wrappers, coercions etc etc)
 373         --
 374         -- We want to return an environment
 375         --      [ "MkT" -> <datacon MkT>, "x" -> <selector x>, ... ]
 376         -- (where the "MkT" is the *Name* associated with MkT, etc.)
 377         --
 378         -- We do this by mapping the implict_names to the associated
 379         -- TyThings.  By the invariant on ifaceDeclSubBndrs and
 380         -- implicitTyThings, we can use getOccName on the implicit
 381         -- TyThings to make this association: each Name's OccName should
 382         -- be the OccName of exactly one implictTyThing.  So the key is
 383         -- to define a "mini-env"
 384         --
 385         -- [ 'MkT' -> <datacon MkT>, 'x' -> <selector x>, ... ]
 386         -- where the 'MkT' here is the *OccName* associated with MkT.
 387         --
 388         -- However, there is a subtlety: due to how type checking needs
 389         -- to be staged, we can't poke on the forkM'd thunks inside the
 390         -- implictTyThings while building this mini-env.
 391         -- If we poke these thunks too early, two problems could happen:
 392         --    (1) When processing mutually recursive modules across
 393         --        hs-boot boundaries, poking too early will do the
 394         --        type-checking before the recursive knot has been tied,
 395         --        so things will be type-checked in the wrong
 396         --        environment, and necessary variables won't be in
 397         --        scope.
 398         --
 399         --    (2) Looking up one OccName in the mini_env will cause
 400         --        others to be looked up, which might cause that
 401         --        original one to be looked up again, and hence loop.
 402         --
 403         -- The code below works because of the following invariant:
 404         -- getOccName on a TyThing does not force the suspended type
 405         -- checks in order to extract the name. For example, we don't
 406         -- poke on the "T a" type of <selector x> on the way to
 407         -- extracting <selector x>'s OccName. Of course, there is no
 408         -- reason in principle why getting the OccName should force the
 409         -- thunks, but this means we need to be careful in
 410         -- implicitTyThings and its helper functions.
 411         --
 412         -- All a bit too finely-balanced for my liking.
 413
 414         -- This mini-env and lookup function mediates between the
 415         -- *Name*s n and the map from *OccName*s to the implicit TyThings
 416         ; let mini_env = mkOccEnv [(getOccName t, t) | t <- implicitTyThings thing]
 417               lookup n = case lookupOccEnv mini_env (getOccName n) of
 418                            Just thing -> thing
 419                            Nothing    ->
 420                              pprPanic "loadDecl" (ppr main_name <+> ppr n $$ ppr (decl))
 421
 422         ; return $ (main_name, thing) :
 423                       -- uses the invariant that implicit_names and
 424                       -- implictTyThings are bijective
 425                       [(n, lookup n) | n <- implicit_names]
 426         }
 427   where
 428     doc = ptext SLIT("Declaration for") <+> ppr (ifName decl)
 429
 430 bumpDeclStats :: Name -> IfL ()         -- Record that one more declaration has actually been used
 431 bumpDeclStats name
 432   = do  { traceIf (text "Loading decl for" <+> ppr name)
 433         ; updateEps_ (\eps -> let stats = eps_stats eps
 434                               in eps { eps_stats = stats { n_decls_out = n_decls_out stats + 1 } })
 435         }
 436 \end{code}
 437
 438
 439 %*********************************************************
 440 %*                                                      *
 441 \subsection{Reading an interface file}
 442 %*                                                      *
 443 %*********************************************************
 444
 445 \begin{code}
 446 findAndReadIface :: SDoc -> Module
 447                  -> IsBootInterface     -- True  <=> Look for a .hi-boot file
 448                                         -- False <=> Look for .hi file
 449                  -> TcRnIf gbl lcl (MaybeErr Message (ModIface, FilePath))
 450         -- Nothing <=> file not found, or unreadable, or illegible
 451         -- Just x  <=> successfully found and parsed
 452
 453         -- It *doesn't* add an error to the monad, because
 454         -- sometimes it's ok to fail... see notes with loadInterface
 455
 456 findAndReadIface doc_str mod hi_boot_file
 457   = do  { traceIf (sep [hsep [ptext SLIT("Reading"),
 458                               if hi_boot_file
 459                                 then ptext SLIT("[boot]")
 460                                 else empty,
 461                               ptext SLIT("interface for"),
 462                               ppr mod <> semi],
 463                         nest 4 (ptext SLIT("reason:") <+> doc_str)])
 464
 465         -- Check for GHC.Prim, and return its static interface
 466         ; dflags <- getDOpts
 467         ; if mod == gHC_PRIM
 468           then return (Succeeded (ghcPrimIface,
 469                                    "<built in interface for GHC.Prim>"))
 470           else do
 471
 472         -- Look for the file
 473         ; hsc_env <- getTopEnv
 474         ; mb_found <- liftIO (findExactModule hsc_env mod)
 475         ; case mb_found of {
 476
 477               err | notFound err -> do
 478                 { traceIf (ptext SLIT("...not found"))
 479                 ; dflags <- getDOpts
 480                 ; return (Failed (cannotFindInterface dflags
 481                                         (moduleName mod) err)) } ;
 482               Found loc mod -> do
 483
 484         -- Found file, so read it
 485         { let { file_path = addBootSuffix_maybe hi_boot_file (ml_hi_file loc) }
 486
 487         ; if thisPackage dflags == modulePackageId mod
 488                 && not (isOneShot (ghcMode dflags))
 489             then return (Failed (homeModError mod loc))
 490             else do {
 491
 492         ; traceIf (ptext SLIT("readIFace") <+> text file_path)
 493         ; read_result <- readIface mod file_path hi_boot_file
 494         ; case read_result of
 495             Failed err -> return (Failed (badIfaceFile file_path err))
 496             Succeeded iface
 497                 | mi_module iface /= mod ->
 498                   return (Failed (wrongIfaceModErr iface mod file_path))
 499                 | otherwise ->
 500                   return (Succeeded (iface, file_path))
 501                         -- Don't forget to fill in the package name...
 502         }}}}
 503
 504 notFound (Found _ _) = False
 505 notFound _ = True
 506 \end{code}
 507
 508 @readIface@ tries just the one file.
 509
 510 \begin{code}
 511 readIface :: Module -> FilePath -> IsBootInterface
 512           -> TcRnIf gbl lcl (MaybeErr Message ModIface)
 513         -- Failed err    <=> file not found, or unreadable, or illegible
 514         -- Succeeded iface <=> successfully found and parsed
 515
 516 readIface wanted_mod file_path is_hi_boot_file
 517   = do  { dflags <- getDOpts
 518         ; res <- tryMostM $ readBinIface file_path
 519         ; case res of
 520             Right iface
 521                 | wanted_mod == actual_mod -> return (Succeeded iface)
 522                 | otherwise                -> return (Failed err)
 523                 where
 524                   actual_mod = mi_module iface
 525                   err = hiModuleNameMismatchWarn wanted_mod actual_mod
 526
 527             Left exn    -> return (Failed (text (showException exn)))
 528     }
 529 \end{code}
 530
 531
 532 %*********************************************************
 533 %*                                                       *
 534         Wired-in interface for GHC.Prim
 535 %*                                                       *
 536 %*********************************************************
 537
 538 \begin{code}
 539 initExternalPackageState :: ExternalPackageState
 540 initExternalPackageState
 541   = EPS {
 542       eps_is_boot      = emptyUFM,
 543       eps_PIT          = emptyPackageIfaceTable,
 544       eps_PTE          = emptyTypeEnv,
 545       eps_inst_env     = emptyInstEnv,
 546       eps_fam_inst_env = emptyFamInstEnv,
 547       eps_rule_base    = mkRuleBase builtinRules,
 548         -- Initialise the EPS rule pool with the built-in rules
 549       eps_mod_fam_inst_env
 550                        = emptyModuleEnv,
 551       eps_vect_info    = noVectInfo,
 552       eps_stats = EpsStats { n_ifaces_in = 0, n_decls_in = 0, n_decls_out = 0
 553                            , n_insts_in = 0, n_insts_out = 0
 554                            , n_rules_in = length builtinRules, n_rules_out = 0 }
 555     }
 556 \end{code}
 557
 558
 559 %*********************************************************
 560 %*                                                       *
 561         Wired-in interface for GHC.Prim
 562 %*                                                       *
 563 %*********************************************************
 564
 565 \begin{code}
 566 ghcPrimIface :: ModIface
 567 ghcPrimIface
 568   = (emptyModIface gHC_PRIM) {
 569         mi_exports  = [(gHC_PRIM, ghcPrimExports)],
 570         mi_decls    = [],
 571         mi_fixities = fixities,
 572         mi_fix_fn  = mkIfaceFixCache fixities
 573     }
 574   where
 575     fixities = [(getOccName seqId, Fixity 0 InfixR)]
 576                         -- seq is infixr 0
 577 \end{code}
 578
 579 %*********************************************************
 580 %*                                                      *
 581 \subsection{Statistics}
 582 %*                                                      *
 583 %*********************************************************
 584
 585 \begin{code}
 586 ifaceStats :: ExternalPackageState -> SDoc
 587 ifaceStats eps
 588   = hcat [text "Renamer stats: ", msg]
 589   where
 590     stats = eps_stats eps
 591     msg = vcat
 592         [int (n_ifaces_in stats) <+> text "interfaces read",
 593          hsep [ int (n_decls_out stats), text "type/class/variable imported, out of",
 594                 int (n_decls_in stats), text "read"],
 595          hsep [ int (n_insts_out stats), text "instance decls imported, out of",
 596                 int (n_insts_in stats), text "read"],
 597          hsep [ int (n_rules_out stats), text "rule decls imported, out of",
 598                 int (n_rules_in stats), text "read"]
 599         ]
 600 \end{code}
 601
 602
 603 %************************************************************************
 604 %*                                                                      *
 605                 Printing interfaces
 606 %*                                                                      *
 607 %************************************************************************
 608
 609 \begin{code}
 610 -- | Read binary interface, and print it out
 611 showIface :: HscEnv -> FilePath -> IO ()
 612 showIface hsc_env filename = do
 613    -- skip the version check; we don't want to worry about profiled vs.
 614    -- non-profiled interfaces, for example.
 615    writeIORef v_IgnoreHiWay True
 616    iface <- initTcRnIf 's' hsc_env () () $ readBinIface  filename
 617    printDump (pprModIface iface)
 618 \end{code}
 619
 620 \begin{code}
 621 pprModIface :: ModIface -> SDoc
 622 -- Show a ModIface
 623 pprModIface iface
 624  = vcat [ ptext SLIT("interface")
 625                 <+> ppr (mi_module iface) <+> pp_boot
 626                 <+> ppr (mi_mod_vers iface) <+> pp_sub_vers
 627                 <+> (if mi_orphan iface then ptext SLIT("[orphan module]") else empty)
 628                 <+> (if mi_finsts iface then ptext SLIT("[family instance module]") else empty)
 629                 <+> (if mi_hpc    iface then ptext SLIT("[hpc]") else empty)
 630                 <+> integer opt_HiVersion
 631                 <+> ptext SLIT("where")
 632         , vcat (map pprExport (mi_exports iface))
 633         , pprDeps (mi_deps iface)
 634         , vcat (map pprUsage (mi_usages iface))
 635         , pprFixities (mi_fixities iface)
 636         , vcat (map pprIfaceDecl (mi_decls iface))
 637         , vcat (map ppr (mi_insts iface))
 638         , vcat (map ppr (mi_fam_insts iface))
 639         , vcat (map ppr (mi_rules iface))
 640         , pprVectInfo (mi_vect_info iface)
 641         , pprDeprecs (mi_deprecs iface)
 642         ]
 643   where
 644     pp_boot | mi_boot iface = ptext SLIT("[boot]")
 645             | otherwise     = empty
 646
 647     exp_vers  = mi_exp_vers iface
 648     rule_vers = mi_rule_vers iface
 649
 650     pp_sub_vers | exp_vers == initialVersion && rule_vers == initialVersion = empty
 651                 | otherwise = brackets (ppr exp_vers <+> ppr rule_vers)
 652 \end{code}
 653
 654 When printing export lists, we print like this:
 655         Avail   f               f
 656         AvailTC C [C, x, y]     C(x,y)
 657         AvailTC C [x, y]        C!(x,y)         -- Exporting x, y but not C
 658
 659 \begin{code}
 660 pprExport :: IfaceExport -> SDoc
 661 pprExport (mod, items)
 662  = hsep [ ptext SLIT("export"), ppr mod, hsep (map pp_avail items) ]
 663   where
 664     pp_avail :: GenAvailInfo OccName -> SDoc
 665     pp_avail (Avail occ)    = ppr occ
 666     pp_avail (AvailTC _ []) = empty
 667     pp_avail (AvailTC n (n':ns))
 668         | n==n'     = ppr n <> pp_export ns
 669         | otherwise = ppr n <> char '|' <> pp_export (n':ns)
 670
 671     pp_export []    = empty
 672     pp_export names = braces (hsep (map ppr names))
 673
 674 pprUsage :: Usage -> SDoc
 675 pprUsage usage
 676   = hsep [ptext SLIT("import"), ppr (usg_name usage),
 677           int (usg_mod usage),
 678           pp_export_version (usg_exports usage),
 679           int (usg_rules usage),
 680           pp_versions (usg_entities usage) ]
 681   where
 682     pp_versions nvs = hsep [ ppr n <+> int v | (n,v) <- nvs ]
 683     pp_export_version Nothing  = empty
 684     pp_export_version (Just v) = int v
 685
 686 pprDeps :: Dependencies -> SDoc
 687 pprDeps (Deps { dep_mods = mods, dep_pkgs = pkgs, dep_orphs = orphs,
 688                 dep_finsts = finsts })
 689   = vcat [ptext SLIT("module dependencies:") <+> fsep (map ppr_mod mods),
 690           ptext SLIT("package dependencies:") <+> fsep (map ppr pkgs),
 691           ptext SLIT("orphans:") <+> fsep (map ppr orphs),
 692           ptext SLIT("family instance modules:") <+> fsep (map ppr finsts)
 693         ]
 694   where
 695     ppr_mod (mod_name, boot) = ppr mod_name <+> ppr_boot boot
 696     ppr_boot True  = text "[boot]"
 697     ppr_boot False = empty
 698
 699 pprIfaceDecl :: (Version, IfaceDecl) -> SDoc
 700 pprIfaceDecl (ver, decl)
 701   = ppr_vers ver <+> ppr decl
 702   where
 703         -- Print the version for the decl
 704     ppr_vers v | v == initialVersion = empty
 705                | otherwise           = int v
 706
 707 pprFixities :: [(OccName, Fixity)] -> SDoc
 708 pprFixities []    = empty
 709 pprFixities fixes = ptext SLIT("fixities") <+> pprWithCommas pprFix fixes
 710                   where
 711                     pprFix (occ,fix) = ppr fix <+> ppr occ
 712
 713 pprVectInfo :: IfaceVectInfo -> SDoc
 714 pprVectInfo (IfaceVectInfo { ifaceVectInfoVar        = vars
 715                            , ifaceVectInfoTyCon      = tycons
 716                            , ifaceVectInfoTyConReuse = tyconsReuse
 717                            }) =
 718   vcat
 719   [ ptext SLIT("vectorised variables:") <+> hsep (map ppr vars)
 720   , ptext SLIT("vectorised tycons:") <+> hsep (map ppr tycons)
 721   , ptext SLIT("vectorised reused tycons:") <+> hsep (map ppr tyconsReuse)
 722   ]
 723
 724 pprDeprecs NoDeprecs        = empty
 725 pprDeprecs (DeprecAll txt)  = ptext SLIT("Deprecate all") <+> doubleQuotes (ftext txt)
 726 pprDeprecs (DeprecSome prs) = ptext SLIT("Deprecate") <+> vcat (map pprDeprec prs)
 727                             where
 728                               pprDeprec (name, txt) = ppr name <+> doubleQuotes (ftext txt)
 729 \end{code}
 730
 731
 732 %*********************************************************
 733 %*                                                       *
 734 \subsection{Errors}
 735 %*                                                       *
 736 %*********************************************************
 737
 738 \begin{code}
 739 badIfaceFile file err
 740   = vcat [ptext SLIT("Bad interface file:") <+> text file,
 741           nest 4 err]
 742
 743 hiModuleNameMismatchWarn :: Module -> Module -> Message
 744 hiModuleNameMismatchWarn requested_mod read_mod =
 745   withPprStyle defaultUserStyle $
 746     -- we want the Modules below to be qualified with package names,
 747     -- so reset the PrintUnqualified setting.
 748     hsep [ ptext SLIT("Something is amiss; requested module ")
 749          , ppr requested_mod
 750          , ptext SLIT("differs from name found in the interface file")
 751          , ppr read_mod
 752          ]
 753
 754 wrongIfaceModErr iface mod_name file_path
 755   = sep [ptext SLIT("Interface file") <+> iface_file,
 756          ptext SLIT("contains module") <+> quotes (ppr (mi_module iface)) <> comma,
 757          ptext SLIT("but we were expecting module") <+> quotes (ppr mod_name),
 758          sep [ptext SLIT("Probable cause: the source code which generated"),
 759              nest 2 iface_file,
 760              ptext SLIT("has an incompatible module name")
 761             ]
 762         ]
 763   where iface_file = doubleQuotes (text file_path)
 764
 765 homeModError mod location
 766   = ptext SLIT("attempting to use module ") <> quotes (ppr mod)
 767     <> (case ml_hs_file location of
 768            Just file -> space <> parens (text file)
 769            Nothing   -> empty)
 770     <+> ptext SLIT("which is not loaded")
 771 \end{code}
 772