compiler/iface/LoadIface.lhs

   1
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Dealing with interface files}
   5
   6 \begin{code}
   7 module LoadIface (
   8         loadInterface, loadInterfaceForName, loadWiredInHomeIface,
   9         loadSrcInterface, loadSysInterface, loadOrphanModules,
  10         findAndReadIface, readIface,    -- Used when reading the module's old interface
  11         loadDecls, ifaceStats, discardDeclPrags,
  12         initExternalPackageState,
  13
  14         pprModIface, showIface  -- Print the iface in Foo.hi
  15    ) where
  16
  17 #include "HsVersions.h"
  18
  19 import {-# SOURCE #-}   TcIface( tcIfaceDecl, tcIfaceRule, tcIfaceInst )
  20
  21 import DynFlags         ( DynFlags(..), DynFlag( Opt_IgnoreInterfacePragmas ) )
  22 import IfaceSyn         ( IfaceDecl(..), IfaceConDecl(..), IfaceClassOp(..),
  23                           IfaceConDecls(..), IfaceIdInfo(..) )
  24 import IfaceEnv         ( newGlobalBinder )
  25 import HscTypes         ( ModIface(..), TyThing, IfaceExport, Usage(..),
  26                           Deprecs(..), Dependencies(..),
  27                           emptyModIface, EpsStats(..), GenAvailInfo(..),
  28                           addEpsInStats, ExternalPackageState(..),
  29                           PackageTypeEnv, emptyTypeEnv,  HscEnv(..),
  30                           lookupIfaceByModule, emptyPackageIfaceTable,
  31                           IsBootInterface, mkIfaceFixCache,
  32                           implicitTyThings
  33                          )
  34
  35 import BasicTypes       ( Version, initialVersion,
  36                           Fixity(..), FixityDirection(..), isMarkedStrict )
  37 import TcRnMonad
  38 import Type             ( TyThing(..) )
  39 import Class            ( classATs )
  40
  41 import PrelNames        ( gHC_PRIM )
  42 import PrelInfo         ( ghcPrimExports )
  43 import PrelRules        ( builtinRules )
  44 import Rules            ( extendRuleBaseList, mkRuleBase )
  45 import InstEnv          ( emptyInstEnv, extendInstEnvList )
  46 import Name             ( Name {-instance NamedThing-}, getOccName,
  47                           nameModule, nameIsLocalOrFrom, isWiredInName )
  48 import NameEnv
  49 import MkId             ( seqId )
  50 import Module
  51 import OccName          ( OccName, mkOccEnv, lookupOccEnv, mkClassTyConOcc,
  52                           mkClassDataConOcc, mkSuperDictSelOcc,
  53                           mkDataConWrapperOcc, mkDataConWorkerOcc,
  54                           mkNewTyCoOcc, mkInstTyTcOcc, mkInstTyCoOcc )
  55 import SrcLoc           ( importedSrcLoc )
  56 import Maybes           ( MaybeErr(..) )
  57 import ErrUtils         ( Message )
  58 import Finder           ( findImportedModule, findExactModule,
  59                           FindResult(..), cannotFindInterface )
  60 import UniqFM
  61 import StaticFlags      ( opt_HiVersion )
  62 import Outputable
  63 import BinIface         ( readBinIface, v_IgnoreHiWay )
  64 import Binary           ( getBinFileWithDict )
  65 import Panic            ( ghcError, tryMost, showException, GhcException(..) )
  66 import List             ( nub )
  67 import Maybe            ( isJust )
  68 import DATA_IOREF       ( writeIORef )
  69 \end{code}
  70
  71
  72 %************************************************************************
  73 %*                                                                      *
  74         loadSrcInterface, loadOrphanModules, loadHomeInterface
  75
  76                 These three are called from TcM-land
  77 %*                                                                      *
  78 %************************************************************************
  79
  80 \begin{code}
  81 -- | Load the interface corresponding to an @import@ directive in
  82 -- source code.  On a failure, fail in the monad with an error message.
  83 loadSrcInterface :: SDoc -> ModuleName -> IsBootInterface -> RnM ModIface
  84 loadSrcInterface doc mod want_boot  = do
  85   -- We must first find which Module this import refers to.  This involves
  86   -- calling the Finder, which as a side effect will search the filesystem
  87   -- and create a ModLocation.  If successful, loadIface will read the
  88   -- interface; it will call the Finder again, but the ModLocation will be
  89   -- cached from the first search.
  90   hsc_env <- getTopEnv
  91   res <- ioToIOEnv $ findImportedModule hsc_env mod Nothing
  92   case res of
  93     Found _ mod -> do
  94       mb_iface <- initIfaceTcRn $ loadInterface doc mod (ImportByUser want_boot)
  95       case mb_iface of
  96         Failed err      -> failWithTc err
  97         Succeeded iface -> return iface
  98     err ->
  99         let dflags = hsc_dflags hsc_env in
 100         failWithTc (cannotFindInterface dflags mod err)
 101
 102 -- | Load interfaces for a collection of orphan modules.
 103 loadOrphanModules :: [Module] -> TcM ()
 104 loadOrphanModules mods
 105   | null mods = returnM ()
 106   | otherwise = initIfaceTcRn $
 107                 do { traceIf (text "Loading orphan modules:" <+>
 108                                  fsep (map ppr mods))
 109                    ; mappM_ load mods
 110                    ; returnM () }
 111   where
 112     load mod   = loadSysInterface (mk_doc mod) mod
 113     mk_doc mod = ppr mod <+> ptext SLIT("is a orphan-instance module")
 114
 115 -- | Loads the interface for a given Name.
 116 loadInterfaceForName :: SDoc -> Name -> TcRn ModIface
 117 loadInterfaceForName doc name
 118   = do  {
 119 #ifdef DEBUG
 120                 -- Should not be called with a name from the module being compiled
 121           this_mod <- getModule
 122         ; ASSERT2( not (nameIsLocalOrFrom this_mod name), ppr name <+> parens doc )
 123 #endif
 124           initIfaceTcRn $ loadSysInterface doc (nameModule name)
 125     }
 126
 127 -- | An 'IfM' function to load the home interface for a wired-in thing,
 128 -- so that we're sure that we see its instance declarations and rules
 129 loadWiredInHomeIface :: Name -> IfM lcl ()
 130 loadWiredInHomeIface name
 131   = ASSERT( isWiredInName name )
 132     do loadSysInterface doc (nameModule name); return ()
 133   where
 134     doc = ptext SLIT("Need home interface for wired-in thing") <+> ppr name
 135
 136 -- | A wrapper for 'loadInterface' that throws an exception if it fails
 137 loadSysInterface :: SDoc -> Module -> IfM lcl ModIface
 138 loadSysInterface doc mod_name
 139   = do  { mb_iface <- loadInterface doc mod_name ImportBySystem
 140         ; case mb_iface of
 141             Failed err      -> ghcError (ProgramError (showSDoc err))
 142             Succeeded iface -> return iface }
 143 \end{code}
 144
 145
 146 %*********************************************************
 147 %*                                                      *
 148                 loadInterface
 149
 150         The main function to load an interface
 151         for an imported module, and put it in
 152         the External Package State
 153 %*                                                      *
 154 %*********************************************************
 155
 156 \begin{code}
 157 loadInterface :: SDoc -> Module -> WhereFrom
 158               -> IfM lcl (MaybeErr Message ModIface)
 159
 160 -- If it can't find a suitable interface file, we
 161 --      a) modify the PackageIfaceTable to have an empty entry
 162 --              (to avoid repeated complaints)
 163 --      b) return (Left message)
 164 --
 165 -- It's not necessarily an error for there not to be an interface
 166 -- file -- perhaps the module has changed, and that interface
 167 -- is no longer used
 168
 169 loadInterface doc_str mod from
 170   = do  {       -- Read the state
 171           (eps,hpt) <- getEpsAndHpt
 172
 173         ; traceIf (text "Considering whether to load" <+> ppr mod <+> ppr from)
 174
 175                 -- Check whether we have the interface already
 176         ; dflags <- getDOpts
 177         ; case lookupIfaceByModule dflags hpt (eps_PIT eps) mod of {
 178             Just iface
 179                 -> returnM (Succeeded iface) ;  -- Already loaded
 180                         -- The (src_imp == mi_boot iface) test checks that the already-loaded
 181                         -- interface isn't a boot iface.  This can conceivably happen,
 182                         -- if an earlier import had a before we got to real imports.   I think.
 183             other -> do
 184
 185         { let { hi_boot_file = case from of
 186                                 ImportByUser usr_boot -> usr_boot
 187                                 ImportBySystem        -> sys_boot
 188
 189               ; mb_dep   = lookupUFM (eps_is_boot eps) (moduleName mod)
 190               ; sys_boot = case mb_dep of
 191                                 Just (_, is_boot) -> is_boot
 192                                 Nothing           -> False
 193                         -- The boot-ness of the requested interface,
 194               }         -- based on the dependencies in directly-imported modules
 195
 196         -- READ THE MODULE IN
 197         ; read_result <- findAndReadIface doc_str mod hi_boot_file
 198         ; dflags <- getDOpts
 199         ; case read_result of {
 200             Failed err -> do
 201                 { let fake_iface = emptyModIface mod
 202
 203                 ; updateEps_ $ \eps ->
 204                         eps { eps_PIT = extendModuleEnv (eps_PIT eps) (mi_module fake_iface) fake_iface }
 205                         -- Not found, so add an empty iface to
 206                         -- the EPS map so that we don't look again
 207
 208                 ; returnM (Failed err) } ;
 209
 210         -- Found and parsed!
 211             Succeeded (iface, file_path)                        -- Sanity check:
 212                 | ImportBySystem <- from,       --   system-importing...
 213                   modulePackageId (mi_module iface) == thisPackage dflags,
 214                                                 --   a home-package module...
 215                   Nothing <- mb_dep             --   that we know nothing about
 216                 -> returnM (Failed (badDepMsg mod))
 217
 218                 | otherwise ->
 219
 220         let
 221             loc_doc = text file_path
 222         in
 223         initIfaceLcl mod loc_doc $ do
 224
 225         --      Load the new ModIface into the External Package State
 226         -- Even home-package interfaces loaded by loadInterface
 227         --      (which only happens in OneShot mode; in Batch/Interactive
 228         --      mode, home-package modules are loaded one by one into the HPT)
 229         -- are put in the EPS.
 230         --
 231         -- The main thing is to add the ModIface to the PIT, but
 232         -- we also take the
 233         --      IfaceDecls, IfaceInst, IfaceRules
 234         -- out of the ModIface and put them into the big EPS pools
 235
 236         -- NB: *first* we do loadDecl, so that the provenance of all the locally-defined
 237         ---    names is done correctly (notably, whether this is an .hi file or .hi-boot file).
 238         --     If we do loadExport first the wrong info gets into the cache (unless we
 239         --      explicitly tag each export which seems a bit of a bore)
 240
 241         ; ignore_prags <- doptM Opt_IgnoreInterfacePragmas
 242         ; new_eps_decls <- loadDecls ignore_prags (mi_decls iface)
 243         ; new_eps_insts <- mapM tcIfaceInst (mi_insts iface)
 244         ; new_eps_rules <- if ignore_prags
 245                            then return []
 246                            else mapM tcIfaceRule (mi_rules iface)
 247
 248         ; let { final_iface = iface {   mi_decls = panic "No mi_decls in PIT",
 249                                         mi_insts = panic "No mi_insts in PIT",
 250                                         mi_rules = panic "No mi_rules in PIT" } }
 251
 252         ; updateEps_  $ \ eps ->
 253             eps { eps_PIT       = extendModuleEnv (eps_PIT eps) mod final_iface,
 254                   eps_PTE       = addDeclsToPTE   (eps_PTE eps) new_eps_decls,
 255                   eps_rule_base = extendRuleBaseList (eps_rule_base eps) new_eps_rules,
 256                   eps_inst_env  = extendInstEnvList  (eps_inst_env eps)  new_eps_insts,
 257                   eps_stats     = addEpsInStats (eps_stats eps) (length new_eps_decls)
 258                                                 (length new_eps_insts) (length new_eps_rules) }
 259
 260         ; return (Succeeded final_iface)
 261     }}}}
 262
 263 badDepMsg mod
 264   = hang (ptext SLIT("Interface file inconsistency:"))
 265        2 (sep [ptext SLIT("home-package module") <+> quotes (ppr mod) <+> ptext SLIT("is mentioned,"),
 266                ptext SLIT("but does not appear in the dependencies of the interface")])
 267
 268 -----------------------------------------------------
 269 --      Loading type/class/value decls
 270 -- We pass the full Module name here, replete with
 271 -- its package info, so that we can build a Name for
 272 -- each binder with the right package info in it
 273 -- All subsequent lookups, including crucially lookups during typechecking
 274 -- the declaration itself, will find the fully-glorious Name
 275 --
 276 -- We handle ATs specially.  They are not main declarations, but also not
 277 -- implict things (in particular, adding them to `implicitTyThings' would mess
 278 -- things up in the renaming/type checking of source programs).
 279 -----------------------------------------------------
 280
 281 addDeclsToPTE :: PackageTypeEnv -> [(Name,TyThing)] -> PackageTypeEnv
 282 addDeclsToPTE pte things = extendNameEnvList pte things
 283
 284 loadDecls :: Bool
 285           -> [(Version, IfaceDecl)]
 286           -> IfL [(Name,TyThing)]
 287 loadDecls ignore_prags ver_decls
 288    = do { mod <- getIfModule
 289         ; thingss <- mapM (loadDecl ignore_prags mod) ver_decls
 290         ; return (concat thingss)
 291         }
 292
 293 loadDecl :: Bool                        -- Don't load pragmas into the decl pool
 294          -> Module
 295           -> (Version, IfaceDecl)
 296           -> IfL [(Name,TyThing)]       -- The list can be poked eagerly, but the
 297                                         -- TyThings are forkM'd thunks
 298 loadDecl ignore_prags mod (_version, decl)
 299   = do  {       -- Populate the name cache with final versions of all
 300                 -- the names associated with the decl
 301           main_name      <- mk_new_bndr mod Nothing (ifName decl)
 302         ; implicit_names <- mapM (mk_new_bndr mod (Just main_name))
 303                                  (ifaceDeclSubBndrs decl)
 304
 305         -- Typecheck the thing, lazily
 306         -- NB. firstly, the laziness is there in case we never need the
 307         -- declaration (in one-shot mode), and secondly it is there so that
 308         -- we don't look up the occurrence of a name before calling mk_new_bndr
 309         -- on the binder.  This is important because we must get the right name
 310         -- which includes its nameParent.
 311         ; thing <- forkM doc (bumpDeclStats main_name >> tcIfaceDecl stripped_decl)
 312         ; let mini_env = mkOccEnv [(getOccName t, t) | t <- implicitTyThings thing]
 313               lookup n = case lookupOccEnv mini_env (getOccName n) of
 314                            Just thing -> thing
 315                            Nothing    ->
 316                              pprPanic "loadDecl" (ppr main_name <+>
 317                                                   ppr n $$ ppr (stripped_decl))
 318
 319         ; returnM $ (main_name, thing) :  [(n, lookup n) | n <- implicit_names]
 320         }
 321                 -- We build a list from the *known* names, with (lookup n) thunks
 322                 -- as the TyThings.  That way we can extend the PTE without poking the
 323                 -- thunks
 324   where
 325     stripped_decl | ignore_prags = discardDeclPrags decl
 326                   | otherwise    = decl
 327
 328         -- mk_new_bndr allocates in the name cache the final canonical
 329         -- name for the thing, with the correct
 330         --      * parent
 331         --      * location
 332         -- imported name, to fix the module correctly in the cache
 333     mk_new_bndr mod mb_parent occ
 334         = newGlobalBinder mod occ mb_parent
 335                           (importedSrcLoc (showSDoc (ppr (moduleName mod))))
 336                         -- ToDo: qualify with the package name if necessary
 337
 338     doc = ptext SLIT("Declaration for") <+> ppr (ifName decl)
 339
 340 discardDeclPrags :: IfaceDecl -> IfaceDecl
 341 discardDeclPrags decl@(IfaceId {ifIdInfo = HasInfo _}) = decl { ifIdInfo = NoInfo }
 342 discardDeclPrags decl                                  = decl
 343
 344 bumpDeclStats :: Name -> IfL ()         -- Record that one more declaration has actually been used
 345 bumpDeclStats name
 346   = do  { traceIf (text "Loading decl for" <+> ppr name)
 347         ; updateEps_ (\eps -> let stats = eps_stats eps
 348                               in eps { eps_stats = stats { n_decls_out = n_decls_out stats + 1 } })
 349         }
 350
 351 -----------------
 352 ifaceDeclSubBndrs :: IfaceDecl -> [OccName]
 353 --  *Excludes* the 'main' name, but *includes* the implicitly-bound names
 354 -- Deeply revolting, because it has to predict what gets bound,
 355 -- especially the question of whether there's a wrapper for a datacon
 356 --
 357 -- If you change this, make sure you change HscTypes.implicitTyThings in sync
 358
 359 ifaceDeclSubBndrs (IfaceClass {ifCtxt = sc_ctxt, ifName = cls_occ,
 360                                ifSigs = sigs, ifATs = ats })
 361   = co_occs ++
 362     [tc_occ, dc_occ, dcww_occ] ++
 363     [op | IfaceClassOp op  _ _ <- sigs] ++
 364     [ifName at | at <- ats ] ++
 365     [mkSuperDictSelOcc n cls_occ | n <- [1..n_ctxt]]
 366   where
 367     n_ctxt = length sc_ctxt
 368     n_sigs = length sigs
 369     tc_occ  = mkClassTyConOcc cls_occ
 370     dc_occ  = mkClassDataConOcc cls_occ
 371     co_occs | is_newtype = [mkNewTyCoOcc tc_occ]
 372             | otherwise  = []
 373     dcww_occ -- | is_newtype = mkDataConWrapperOcc dc_occ       -- Newtypes have wrapper but no worker
 374              | otherwise  = mkDataConWorkerOcc dc_occ   -- Otherwise worker but no wrapper
 375     is_newtype = n_sigs + n_ctxt == 1                   -- Sigh
 376
 377 ifaceDeclSubBndrs IfaceData {ifCons = IfAbstractTyCon}
 378   = []
 379 -- Newtype
 380 ifaceDeclSubBndrs (IfaceData {ifName = tc_occ,
 381                               ifCons = IfNewTyCon (
 382                                          IfCon { ifConOcc = con_occ,
 383                                                            ifConFields = fields
 384                                                          }),
 385                               ifFamInst = famInst})
 386   = fields ++ [con_occ, mkDataConWorkerOcc con_occ, mkNewTyCoOcc tc_occ]
 387     ++ famInstCo famInst tc_occ
 388
 389 ifaceDeclSubBndrs (IfaceData {ifName = tc_occ,
 390                               ifCons = IfDataTyCon cons,
 391                               ifFamInst = famInst})
 392   = nub (concatMap ifConFields cons)    -- Eliminate duplicate fields
 393     ++ concatMap dc_occs cons
 394     ++ famInstCo famInst tc_occ
 395   where
 396     dc_occs con_decl
 397         | has_wrapper = [con_occ, work_occ, wrap_occ]
 398         | otherwise   = [con_occ, work_occ]
 399         where
 400           con_occ = ifConOcc con_decl
 401           strs    = ifConStricts con_decl
 402           wrap_occ = mkDataConWrapperOcc con_occ
 403           work_occ = mkDataConWorkerOcc con_occ
 404           has_wrapper = any isMarkedStrict strs -- See MkId.mkDataConIds (sigh)
 405                         || not (null . ifConEqSpec $ con_decl)
 406                         || isJust famInst
 407                 -- ToDo: may miss strictness in existential dicts
 408
 409 ifaceDeclSubBndrs _other = []
 410
 411 -- coercion for data/newtype family instances
 412 famInstCo Nothing  baseOcc = []
 413 famInstCo (Just _) baseOcc = [mkInstTyCoOcc baseOcc]
 414 \end{code}
 415
 416
 417 %*********************************************************
 418 %*                                                      *
 419 \subsection{Reading an interface file}
 420 %*                                                      *
 421 %*********************************************************
 422
 423 \begin{code}
 424 findAndReadIface :: SDoc -> Module
 425                  -> IsBootInterface     -- True  <=> Look for a .hi-boot file
 426                                         -- False <=> Look for .hi file
 427                  -> TcRnIf gbl lcl (MaybeErr Message (ModIface, FilePath))
 428         -- Nothing <=> file not found, or unreadable, or illegible
 429         -- Just x  <=> successfully found and parsed
 430
 431         -- It *doesn't* add an error to the monad, because
 432         -- sometimes it's ok to fail... see notes with loadInterface
 433
 434 findAndReadIface doc_str mod hi_boot_file
 435   = do  { traceIf (sep [hsep [ptext SLIT("Reading"),
 436                               if hi_boot_file
 437                                 then ptext SLIT("[boot]")
 438                                 else empty,
 439                               ptext SLIT("interface for"),
 440                               ppr mod <> semi],
 441                         nest 4 (ptext SLIT("reason:") <+> doc_str)])
 442
 443         -- Check for GHC.Prim, and return its static interface
 444         ; dflags <- getDOpts
 445         ; if mod == gHC_PRIM
 446           then returnM (Succeeded (ghcPrimIface,
 447                                    "<built in interface for GHC.Prim>"))
 448           else do
 449
 450         -- Look for the file
 451         ; hsc_env <- getTopEnv
 452         ; mb_found <- ioToIOEnv (findHiFile hsc_env mod hi_boot_file)
 453         ; case mb_found of {
 454               Failed err -> do
 455                 { traceIf (ptext SLIT("...not found"))
 456                 ; dflags <- getDOpts
 457                 ; returnM (Failed (cannotFindInterface dflags
 458                                         (moduleName mod) err)) } ;
 459
 460               Succeeded file_path -> do
 461
 462         -- Found file, so read it
 463         { traceIf (ptext SLIT("readIFace") <+> text file_path)
 464         ; read_result <- readIface mod file_path hi_boot_file
 465         ; case read_result of
 466             Failed err -> returnM (Failed (badIfaceFile file_path err))
 467             Succeeded iface
 468                 | mi_module iface /= mod ->
 469                   return (Failed (wrongIfaceModErr iface mod file_path))
 470                 | otherwise ->
 471                   returnM (Succeeded (iface, file_path))
 472                         -- Don't forget to fill in the package name...
 473         }}}
 474
 475 findHiFile :: HscEnv -> Module -> IsBootInterface
 476            -> IO (MaybeErr FindResult FilePath)
 477 findHiFile hsc_env mod hi_boot_file
 478   = do
 479       maybe_found <- findExactModule hsc_env mod
 480       case maybe_found of
 481         Found loc mod -> return (Succeeded path)
 482                 where
 483                    path = addBootSuffix_maybe hi_boot_file (ml_hi_file loc)
 484         err -> return (Failed err)
 485 \end{code}
 486
 487 @readIface@ tries just the one file.
 488
 489 \begin{code}
 490 readIface :: Module -> FilePath -> IsBootInterface
 491           -> TcRnIf gbl lcl (MaybeErr Message ModIface)
 492         -- Failed err    <=> file not found, or unreadable, or illegible
 493         -- Succeeded iface <=> successfully found and parsed
 494
 495 readIface wanted_mod file_path is_hi_boot_file
 496   = do  { dflags <- getDOpts
 497         ; ioToIOEnv $ do
 498         { res <- tryMost (readBinIface file_path)
 499         ; case res of
 500             Right iface
 501                 | wanted_mod == actual_mod -> return (Succeeded iface)
 502                 | otherwise                -> return (Failed err)
 503                 where
 504                   actual_mod = mi_module iface
 505                   err = hiModuleNameMismatchWarn wanted_mod actual_mod
 506
 507             Left exn    -> return (Failed (text (showException exn)))
 508     }}
 509 \end{code}
 510
 511
 512 %*********************************************************
 513 %*                                                       *
 514         Wired-in interface for GHC.Prim
 515 %*                                                       *
 516 %*********************************************************
 517
 518 \begin{code}
 519 initExternalPackageState :: ExternalPackageState
 520 initExternalPackageState
 521   = EPS {
 522       eps_is_boot    = emptyUFM,
 523       eps_PIT        = emptyPackageIfaceTable,
 524       eps_PTE        = emptyTypeEnv,
 525       eps_inst_env   = emptyInstEnv,
 526       eps_rule_base  = mkRuleBase builtinRules,
 527         -- Initialise the EPS rule pool with the built-in rules
 528       eps_stats = EpsStats { n_ifaces_in = 0, n_decls_in = 0, n_decls_out = 0
 529                            , n_insts_in = 0, n_insts_out = 0
 530                            , n_rules_in = length builtinRules, n_rules_out = 0 }
 531     }
 532 \end{code}
 533
 534
 535 %*********************************************************
 536 %*                                                       *
 537         Wired-in interface for GHC.Prim
 538 %*                                                       *
 539 %*********************************************************
 540
 541 \begin{code}
 542 ghcPrimIface :: ModIface
 543 ghcPrimIface
 544   = (emptyModIface gHC_PRIM) {
 545         mi_exports  = [(gHC_PRIM, ghcPrimExports)],
 546         mi_decls    = [],
 547         mi_fixities = fixities,
 548         mi_fix_fn  = mkIfaceFixCache fixities
 549     }
 550   where
 551     fixities = [(getOccName seqId, Fixity 0 InfixR)]
 552                         -- seq is infixr 0
 553 \end{code}
 554
 555 %*********************************************************
 556 %*                                                      *
 557 \subsection{Statistics}
 558 %*                                                      *
 559 %*********************************************************
 560
 561 \begin{code}
 562 ifaceStats :: ExternalPackageState -> SDoc
 563 ifaceStats eps
 564   = hcat [text "Renamer stats: ", msg]
 565   where
 566     stats = eps_stats eps
 567     msg = vcat
 568         [int (n_ifaces_in stats) <+> text "interfaces read",
 569          hsep [ int (n_decls_out stats), text "type/class/variable imported, out of",
 570                 int (n_decls_in stats), text "read"],
 571          hsep [ int (n_insts_out stats), text "instance decls imported, out of",
 572                 int (n_insts_in stats), text "read"],
 573          hsep [ int (n_rules_out stats), text "rule decls imported, out of",
 574                 int (n_rules_in stats), text "read"]
 575         ]
 576 \end{code}
 577
 578
 579 %************************************************************************
 580 %*                                                                      *
 581                 Printing interfaces
 582 %*                                                                      *
 583 %************************************************************************
 584
 585 \begin{code}
 586 showIface :: FilePath -> IO ()
 587 -- Read binary interface, and print it out
 588 showIface filename = do
 589    -- skip the version check; we don't want to worry about profiled vs.
 590    -- non-profiled interfaces, for example.
 591    writeIORef v_IgnoreHiWay True
 592    iface <- Binary.getBinFileWithDict filename
 593    printDump (pprModIface iface)
 594  where
 595 \end{code}
 596
 597
 598 \begin{code}
 599 pprModIface :: ModIface -> SDoc
 600 -- Show a ModIface
 601 pprModIface iface
 602  = vcat [ ptext SLIT("interface")
 603                 <+> ppr (mi_module iface) <+> pp_boot
 604                 <+> ppr (mi_mod_vers iface) <+> pp_sub_vers
 605                 <+> (if mi_orphan iface then ptext SLIT("[orphan module]") else empty)
 606                 <+> int opt_HiVersion
 607                 <+> ptext SLIT("where")
 608         , vcat (map pprExport (mi_exports iface))
 609         , pprDeps (mi_deps iface)
 610         , vcat (map pprUsage (mi_usages iface))
 611         , pprFixities (mi_fixities iface)
 612         , vcat (map pprIfaceDecl (mi_decls iface))
 613         , vcat (map ppr (mi_insts iface))
 614         , vcat (map ppr (mi_rules iface))
 615         , pprDeprecs (mi_deprecs iface)
 616         ]
 617   where
 618     pp_boot | mi_boot iface = ptext SLIT("[boot]")
 619             | otherwise     = empty
 620
 621     exp_vers  = mi_exp_vers iface
 622     rule_vers = mi_rule_vers iface
 623
 624     pp_sub_vers | exp_vers == initialVersion && rule_vers == initialVersion = empty
 625                 | otherwise = brackets (ppr exp_vers <+> ppr rule_vers)
 626 \end{code}
 627
 628 When printing export lists, we print like this:
 629         Avail   f               f
 630         AvailTC C [C, x, y]     C(x,y)
 631         AvailTC C [x, y]        C!(x,y)         -- Exporting x, y but not C
 632
 633 \begin{code}
 634 pprExport :: IfaceExport -> SDoc
 635 pprExport (mod, items)
 636  = hsep [ ptext SLIT("export"), ppr mod, hsep (map pp_avail items) ]
 637   where
 638     pp_avail :: GenAvailInfo OccName -> SDoc
 639     pp_avail (Avail occ)    = ppr occ
 640     pp_avail (AvailTC _ []) = empty
 641     pp_avail (AvailTC n (n':ns))
 642         | n==n'     = ppr n <> pp_export ns
 643         | otherwise = ppr n <> char '|' <> pp_export (n':ns)
 644
 645     pp_export []    = empty
 646     pp_export names = braces (hsep (map ppr names))
 647
 648 pprUsage :: Usage -> SDoc
 649 pprUsage usage
 650   = hsep [ptext SLIT("import"), ppr (usg_name usage),
 651           int (usg_mod usage),
 652           pp_export_version (usg_exports usage),
 653           int (usg_rules usage),
 654           pp_versions (usg_entities usage) ]
 655   where
 656     pp_versions nvs = hsep [ ppr n <+> int v | (n,v) <- nvs ]
 657     pp_export_version Nothing  = empty
 658     pp_export_version (Just v) = int v
 659
 660 pprDeps :: Dependencies -> SDoc
 661 pprDeps (Deps { dep_mods = mods, dep_pkgs = pkgs, dep_orphs = orphs})
 662   = vcat [ptext SLIT("module dependencies:") <+> fsep (map ppr_mod mods),
 663           ptext SLIT("package dependencies:") <+> fsep (map ppr pkgs),
 664           ptext SLIT("orphans:") <+> fsep (map ppr orphs)
 665         ]
 666   where
 667     ppr_mod (mod_name, boot) = ppr mod_name <+> ppr_boot boot
 668     ppr_boot True  = text "[boot]"
 669     ppr_boot False = empty
 670
 671 pprIfaceDecl :: (Version, IfaceDecl) -> SDoc
 672 pprIfaceDecl (ver, decl)
 673   = ppr_vers ver <+> ppr decl
 674   where
 675         -- Print the version for the decl
 676     ppr_vers v | v == initialVersion = empty
 677                | otherwise           = int v
 678
 679 pprFixities :: [(OccName, Fixity)] -> SDoc
 680 pprFixities []    = empty
 681 pprFixities fixes = ptext SLIT("fixities") <+> pprWithCommas pprFix fixes
 682                   where
 683                     pprFix (occ,fix) = ppr fix <+> ppr occ
 684
 685 pprDeprecs NoDeprecs        = empty
 686 pprDeprecs (DeprecAll txt)  = ptext SLIT("Deprecate all") <+> doubleQuotes (ftext txt)
 687 pprDeprecs (DeprecSome prs) = ptext SLIT("Deprecate") <+> vcat (map pprDeprec prs)
 688                             where
 689                               pprDeprec (name, txt) = ppr name <+> doubleQuotes (ftext txt)
 690 \end{code}
 691
 692
 693 %*********************************************************
 694 %*                                                       *
 695 \subsection{Errors}
 696 %*                                                       *
 697 %*********************************************************
 698
 699 \begin{code}
 700 badIfaceFile file err
 701   = vcat [ptext SLIT("Bad interface file:") <+> text file,
 702           nest 4 err]
 703
 704 hiModuleNameMismatchWarn :: Module -> Module -> Message
 705 hiModuleNameMismatchWarn requested_mod read_mod =
 706   withPprStyle defaultUserStyle $
 707     -- we want the Modules below to be qualified with package names,
 708     -- so reset the PrintUnqualified setting.
 709     hsep [ ptext SLIT("Something is amiss; requested module ")
 710          , ppr requested_mod
 711          , ptext SLIT("differs from name found in the interface file")
 712          , ppr read_mod
 713          ]
 714
 715 wrongIfaceModErr iface mod_name file_path
 716   = sep [ptext SLIT("Interface file") <+> iface_file,
 717          ptext SLIT("contains module") <+> quotes (ppr (mi_module iface)) <> comma,
 718          ptext SLIT("but we were expecting module") <+> quotes (ppr mod_name),
 719          sep [ptext SLIT("Probable cause: the source code which generated"),
 720              nest 2 iface_file,
 721              ptext SLIT("has an incompatible module name")
 722             ]
 723         ]
 724   where iface_file = doubleQuotes (text file_path)
 725 \end{code}
 726