compiler/iface/MkIface.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   4 %
   5
   6 \begin{code}
   7 module MkIface (
   8         mkUsageInfo,    -- Construct the usage info for a module
   9
  10         mkIface,        -- Build a ModIface from a ModGuts,
  11                         -- including computing version information
  12
  13         writeIfaceFile, -- Write the interface file
  14
  15         checkOldIface,  -- See if recompilation is required, by
  16                         -- comparing version information
  17
  18         tyThingToIfaceDecl -- Converting things to their Iface equivalents
  19  ) where
  20 \end{code}
  21
  22         -----------------------------------------------
  23                 MkIface.lhs deals with versioning
  24         -----------------------------------------------
  25
  26 Here's the version-related info in an interface file
  27
  28   module Foo 8          -- module-version
  29              3          -- export-list-version
  30              2          -- rule-version
  31     Usages:     -- Version info for what this compilation of Foo imported
  32         Baz 3           -- Module version
  33             [4]         -- The export-list version if Foo depended on it
  34             (g,2)       -- Function and its version
  35             (T,1)       -- Type and its version
  36
  37     <version> f :: Int -> Int {- Unfolding: \x -> Wib.t[2] x -}
  38                 -- The [2] says that f's unfolding
  39                 -- mentions verison 2 of Wib.t
  40
  41         -----------------------------------------------
  42                         Basic idea
  43         -----------------------------------------------
  44
  45 Basic idea:
  46   * In the mi_usages information in an interface, we record the
  47     version number of each free variable of the module
  48
  49   * In mkIface, we compute the version number of each exported thing A.f
  50     by comparing its A.f's info with its new info, and bumping its
  51     version number if it differs.  If A.f mentions B.g, and B.g's version
  52     number has changed, then we count A.f as having changed too.
  53
  54   * In checkOldIface we compare the mi_usages for the module with
  55     the actual version info for all each thing recorded in mi_usages
  56
  57
  58 Fixities
  59 ~~~~~~~~
  60 We count A.f as changing if its fixity changes
  61
  62 Rules
  63 ~~~~~
  64 If a rule changes, we want to recompile any module that might be
  65 affected by that rule.  For non-orphan rules, this is relatively easy.
  66 If module M defines f, and a rule for f, just arrange that the version
  67 number for M.f changes if any of the rules for M.f change.  Any module
  68 that does not depend on M.f can't be affected by the rule-change
  69 either.
  70
  71 Orphan rules (ones whose 'head function' is not defined in M) are
  72 harder.  Here's what we do.
  73
  74   * We have a per-module orphan-rule version number which changes if
  75     any orphan rule changes. (It's unaffected by non-orphan rules.)
  76
  77   * We record usage info for any orphan module 'below' this one,
  78     giving the orphan-rule version number.  We recompile if this
  79     changes.
  80
  81 The net effect is that if an orphan rule changes, we recompile every
  82 module above it.  That's very conservative, but it's devilishly hard
  83 to know what it might affect, so we just have to be conservative.
  84
  85 Instance decls
  86 ~~~~~~~~~~~~~~
  87 In an iface file we have
  88      module A where
  89         instance Eq a => Eq [a]  =  dfun29
  90         dfun29 :: ...
  91
  92 We have a version number for dfun29, covering its unfolding
  93 etc. Suppose we are compiling a module M that imports A only
  94 indirectly.  If typechecking M uses this instance decl, we record the
  95 dependency on A.dfun29 as if it were a free variable of the module
  96 (via the tcg_inst_usages accumulator).  That means that A will appear
  97 in M's usage list.  If the shape of the instance declaration changes,
  98 then so will dfun29's version, triggering a recompilation.
  99
 100 Adding an instance declaration, or changing an instance decl that is
 101 not currently used, is more tricky.  (This really only makes a
 102 difference when we have overlapping instance decls, because then the
 103 new instance decl might kick in to override the old one.)  We handle
 104 this in a very similar way that we handle rules above.
 105
 106   * For non-orphan instance decls, identify one locally-defined tycon/class
 107     mentioned in the decl.  Treat the instance decl as part of the defn of that
 108     tycon/class, so that if the shape of the instance decl changes, so does the
 109     tycon/class; that in turn will force recompilation of anything that uses
 110     that tycon/class.
 111
 112   * For orphan instance decls, act the same way as for orphan rules.
 113     Indeed, we use the same global orphan-rule version number.
 114
 115 mkUsageInfo
 116 ~~~~~~~~~~~
 117 mkUsageInfo figures out what the ``usage information'' for this
 118 moudule is; that is, what it must record in its interface file as the
 119 things it uses.
 120
 121 We produce a line for every module B below the module, A, currently being
 122 compiled:
 123         import B <n> ;
 124 to record the fact that A does import B indirectly.  This is used to decide
 125 to look to look for B.hi rather than B.hi-boot when compiling a module that
 126 imports A.  This line says that A imports B, but uses nothing in it.
 127 So we'll get an early bale-out when compiling A if B's version changes.
 128
 129 The usage information records:
 130
 131 \begin{itemize}
 132 \item   (a) anything reachable from its body code
 133 \item   (b) any module exported with a @module Foo@
 134 \item   (c) anything reachable from an exported item
 135 \end{itemize}
 136
 137 Why (b)?  Because if @Foo@ changes then this module's export list
 138 will change, so we must recompile this module at least as far as
 139 making a new interface file --- but in practice that means complete
 140 recompilation.
 141
 142 Why (c)?  Consider this:
 143 \begin{verbatim}
 144         module A( f, g ) where  |       module B( f ) where
 145           import B( f )         |         f = h 3
 146           g = ...               |         h = ...
 147 \end{verbatim}
 148
 149 Here, @B.f@ isn't used in A.  Should we nevertheless record @B.f@ in
 150 @A@'s usages?  Our idea is that we aren't going to touch A.hi if it is
 151 *identical* to what it was before.  If anything about @B.f@ changes
 152 than anyone who imports @A@ should be recompiled in case they use
 153 @B.f@ (they'll get an early exit if they don't).  So, if anything
 154 about @B.f@ changes we'd better make sure that something in A.hi
 155 changes, and the convenient way to do that is to record the version
 156 number @B.f@ in A.hi in the usage list.  If B.f changes that'll force a
 157 complete recompiation of A, which is overkill but it's the only way to
 158 write a new, slightly different, A.hi.
 159
 160 But the example is tricker.  Even if @B.f@ doesn't change at all,
 161 @B.h@ may do so, and this change may not be reflected in @f@'s version
 162 number.  But with -O, a module that imports A must be recompiled if
 163 @B.h@ changes!  So A must record a dependency on @B.h@.  So we treat
 164 the occurrence of @B.f@ in the export list *just as if* it were in the
 165 code of A, and thereby haul in all the stuff reachable from it.
 166
 167         *** Conclusion: if A mentions B.f in its export list,
 168             behave just as if A mentioned B.f in its source code,
 169             and slurp in B.f and all its transitive closure ***
 170
 171 [NB: If B was compiled with -O, but A isn't, we should really *still*
 172 haul in all the unfoldings for B, in case the module that imports A *is*
 173 compiled with -O.  I think this is the case.]
 174
 175
 176 \begin{code}
 177 #include "HsVersions.h"
 178
 179 import IfaceSyn
 180 import IfaceType
 181 import LoadIface
 182 import Id
 183 import IdInfo
 184 import NewDemand
 185 import CoreSyn
 186 import Class
 187 import TyCon
 188 import DataCon
 189 import Type
 190 import TcType
 191 import InstEnv
 192 import FamInstEnv
 193 import TcRnMonad
 194 import HscTypes
 195
 196 import DynFlags
 197 import Name
 198 import NameEnv
 199 import NameSet
 200 import OccName
 201 import Module
 202 import BinIface
 203 import Unique
 204 import ErrUtils
 205 import Digraph
 206 import SrcLoc
 207 import PackageConfig    hiding ( Version )
 208 import Outputable
 209 import BasicTypes       hiding ( SuccessFlag(..) )
 210 import UniqFM
 211 import Util             hiding ( eqListBy )
 212 import FiniteMap
 213 import FastString
 214 import Maybes
 215
 216 import Control.Monad
 217 import Data.List
 218 \end{code}
 219
 220
 221
 222 %************************************************************************
 223 %*                                                                      *
 224 \subsection{Completing an interface}
 225 %*                                                                      *
 226 %************************************************************************
 227
 228 \begin{code}
 229 mkIface :: HscEnv
 230         -> Maybe ModIface       -- The old interface, if we have it
 231         -> ModGuts              -- Usages, deprecations, etc
 232         -> ModDetails           -- The trimmed, tidied interface
 233         -> IO (ModIface,        -- The new one, complete with decls and versions
 234                Bool)            -- True <=> there was an old Iface, and the new one
 235                                 --          is identical, so no need to write it
 236
 237 mkIface hsc_env maybe_old_iface
 238         (ModGuts{     mg_module    = this_mod,
 239                       mg_boot      = is_boot,
 240                       mg_usages    = usages,
 241                       mg_deps      = deps,
 242                       mg_rdr_env   = rdr_env,
 243                       mg_fix_env   = fix_env,
 244                       mg_deprecs   = src_deprecs })
 245         (ModDetails{  md_insts     = insts,
 246                       md_fam_insts = fam_insts,
 247                       md_rules     = rules,
 248                       md_types     = type_env,
 249                       md_exports   = exports })
 250
 251 -- NB:  notice that mkIface does not look at the bindings
 252 --      only at the TypeEnv.  The previous Tidy phase has
 253 --      put exactly the info into the TypeEnv that we want
 254 --      to expose in the interface
 255
 256   = do  { eps <- hscEPS hsc_env
 257         ; let   { entities = typeEnvElts type_env ;
 258                   decls  = [ tyThingToIfaceDecl entity
 259                            | entity <- entities,
 260                              let name = getName entity,
 261                              not (isImplicitTyThing entity),
 262                                 -- No implicit Ids and class tycons in the interface file
 263                              not (isWiredInName name),
 264                                 -- Nor wired-in things; the compiler knows about them anyhow
 265                              nameIsLocalOrFrom this_mod name  ]
 266                                 -- Sigh: see Note [Root-main Id] in TcRnDriver
 267
 268                 ; fixities    = [(occ,fix) | FixItem occ fix _ <- nameEnvElts fix_env]
 269                 ; deprecs     = mkIfaceDeprec src_deprecs
 270                 ; iface_rules = map coreRuleToIfaceRule rules
 271                 ; iface_insts = map instanceToIfaceInst insts
 272                 ; iface_fam_insts = map famInstToIfaceFamInst fam_insts
 273
 274                 ; intermediate_iface = ModIface {
 275                         mi_module   = this_mod,
 276                         mi_boot     = is_boot,
 277                         mi_deps     = deps,
 278                         mi_usages   = usages,
 279                         mi_exports  = mkIfaceExports exports,
 280
 281                         -- Sort these lexicographically, so that
 282                         -- the result is stable across compilations
 283                         mi_insts    = sortLe le_inst iface_insts,
 284                         mi_fam_insts= sortLe le_fam_inst iface_fam_insts,
 285                         mi_rules    = sortLe le_rule iface_rules,
 286
 287                         mi_fixities = fixities,
 288                         mi_deprecs  = deprecs,
 289                         mi_globals  = Just rdr_env,
 290
 291                         -- Left out deliberately: filled in by addVersionInfo
 292                         mi_mod_vers  = initialVersion,
 293                         mi_exp_vers  = initialVersion,
 294                         mi_rule_vers = initialVersion,
 295                         mi_orphan    = False,   -- Always set by addVersionInfo, but
 296                                                 -- it's a strict field, so we can't omit it.
 297                         mi_finsts    = False,   -- Ditto
 298                         mi_decls     = deliberatelyOmitted "decls",
 299                         mi_ver_fn    = deliberatelyOmitted "ver_fn",
 300
 301                         -- And build the cached values
 302                         mi_dep_fn = mkIfaceDepCache deprecs,
 303                         mi_fix_fn = mkIfaceFixCache fixities }
 304
 305                 -- Add version information
 306                 ; ext_ver_fn = mkParentVerFun hsc_env eps
 307                 ; (new_iface, no_change_at_all, pp_diffs, pp_orphs)
 308                         = _scc_ "versioninfo"
 309                          addVersionInfo ext_ver_fn maybe_old_iface
 310                                          intermediate_iface decls
 311                 }
 312
 313                 -- Debug printing
 314         ; when (isJust pp_orphs && dopt Opt_WarnOrphans dflags)
 315                (printDump (expectJust "mkIface" pp_orphs))
 316         ; when (dopt Opt_D_dump_hi_diffs dflags) (printDump pp_diffs)
 317         ; dumpIfSet_dyn dflags Opt_D_dump_hi "FINAL INTERFACE"
 318                         (pprModIface new_iface)
 319
 320         ; return (new_iface, no_change_at_all) }
 321   where
 322      r1 `le_rule`     r2 = ifRuleName      r1    <=    ifRuleName      r2
 323      i1 `le_inst`     i2 = ifDFun          i1 `le_occ` ifDFun          i2
 324      i1 `le_fam_inst` i2 = ifFamInstTcName i1 `le_occ` ifFamInstTcName i2
 325
 326      le_occ :: Name -> Name -> Bool
 327         -- Compare lexicographically by OccName, *not* by unique, because
 328         -- the latter is not stable across compilations
 329      le_occ n1 n2 = nameOccName n1 <= nameOccName n2
 330
 331      dflags = hsc_dflags hsc_env
 332      deliberatelyOmitted x = panic ("Deliberately omitted: " ++ x)
 333      ifFamInstTcName = ifaceTyConName . ifFamInstTyCon
 334
 335 -----------------------------
 336 writeIfaceFile :: DynFlags -> ModLocation -> ModIface -> IO ()
 337 writeIfaceFile dflags location new_iface
 338     = do createDirectoryHierarchy (directoryOf hi_file_path)
 339          writeBinIface dflags hi_file_path new_iface
 340     where hi_file_path = ml_hi_file location
 341
 342
 343 -- -----------------------------------------------------------------------------
 344 -- Look up parents and versions of Names
 345
 346 -- This is like a global version of the mi_ver_fn field in each ModIface.
 347 -- Given a Name, it finds the ModIface, and then uses mi_ver_fn to get
 348 -- the parent and version info.
 349
 350 mkParentVerFun
 351         :: HscEnv                       -- needed to look up versions
 352         -> ExternalPackageState         -- ditto
 353         -> (Name -> (OccName,Version))
 354 mkParentVerFun hsc_env eps
 355   = \name ->
 356       let
 357         mod = nameModule name
 358         occ = nameOccName name
 359         iface = lookupIfaceByModule (hsc_dflags hsc_env) hpt pit mod `orElse`
 360                    pprPanic "lookupVers2" (ppr mod <+> ppr occ)
 361       in
 362         mi_ver_fn iface occ `orElse`
 363                  pprPanic "lookupVers1" (ppr mod <+> ppr occ)
 364   where
 365       hpt = hsc_HPT hsc_env
 366       pit = eps_PIT eps
 367
 368 -----------------------------------------------------------------------------
 369 -- Compute version numbers for local decls
 370
 371 addVersionInfo
 372         :: (Name -> (OccName,Version))  -- lookup parents and versions of names
 373         -> Maybe ModIface  -- The old interface, read from M.hi
 374         -> ModIface        -- The new interface (lacking decls)
 375         -> [IfaceDecl]     -- The new decls
 376         -> (ModIface,   -- Updated interface
 377             Bool,          -- True <=> no changes at all; no need to write Iface
 378             SDoc,          -- Differences
 379             Maybe SDoc) -- Warnings about orphans
 380
 381 addVersionInfo ver_fn Nothing new_iface new_decls
 382 -- No old interface, so definitely write a new one!
 383   = (new_iface { mi_orphan = anyNothing ifInstOrph (mi_insts new_iface)
 384                                 || anyNothing ifRuleOrph (mi_rules new_iface)
 385                , mi_finsts = not . null $ mi_fam_insts new_iface
 386                , mi_decls  = [(initialVersion, decl) | decl <- new_decls]
 387                , mi_ver_fn = mkIfaceVerCache (zip (repeat initialVersion)
 388                                                   new_decls)
 389                },
 390      False,
 391      ptext SLIT("No old interface file"),
 392      pprOrphans orph_insts orph_rules)
 393   where
 394     orph_insts = filter (isNothing . ifInstOrph) (mi_insts new_iface)
 395     orph_rules = filter (isNothing . ifRuleOrph) (mi_rules new_iface)
 396
 397 addVersionInfo ver_fn (Just old_iface@(ModIface {
 398                                            mi_mod_vers  = old_mod_vers,
 399                                            mi_exp_vers  = old_exp_vers,
 400                                            mi_rule_vers = old_rule_vers,
 401                                            mi_decls     = old_decls,
 402                                            mi_ver_fn    = old_decl_vers,
 403                                            mi_fix_fn    = old_fixities }))
 404                new_iface@(ModIface { mi_fix_fn = new_fixities })
 405                new_decls
 406  | no_change_at_all
 407  = (old_iface,  True,   ptext SLIT("Interface file unchanged"), pp_orphs)
 408  | otherwise
 409  = (final_iface, False, vcat [ptext SLIT("Interface file has changed"),
 410                               nest 2 pp_diffs], pp_orphs)
 411  where
 412     final_iface = new_iface {
 413                 mi_mod_vers  = bump_unless no_output_change old_mod_vers,
 414                 mi_exp_vers  = bump_unless no_export_change old_exp_vers,
 415                 mi_rule_vers = bump_unless no_rule_change   old_rule_vers,
 416                 mi_orphan    = not (null new_orph_rules && null new_orph_insts),
 417                 mi_finsts    = not . null $ mi_fam_insts new_iface,
 418                 mi_decls     = decls_w_vers,
 419                 mi_ver_fn    = mkIfaceVerCache decls_w_vers }
 420
 421     decls_w_vers = [(add_vers decl, decl) | decl <- new_decls]
 422
 423     -------------------
 424     (old_non_orph_insts, old_orph_insts) =
 425         mkOrphMap ifInstOrph (mi_insts old_iface)
 426     (new_non_orph_insts, new_orph_insts) =
 427         mkOrphMap ifInstOrph (mi_insts new_iface)
 428     old_fam_insts = mi_fam_insts old_iface
 429     new_fam_insts = mi_fam_insts new_iface
 430     same_insts occ = eqMaybeBy  (eqListBy eqIfInst)
 431                                 (lookupOccEnv old_non_orph_insts occ)
 432                                 (lookupOccEnv new_non_orph_insts occ)
 433
 434     (old_non_orph_rules, old_orph_rules) =
 435         mkOrphMap ifRuleOrph (mi_rules old_iface)
 436     (new_non_orph_rules, new_orph_rules) =
 437         mkOrphMap ifRuleOrph (mi_rules new_iface)
 438     same_rules occ = eqMaybeBy  (eqListBy eqIfRule)
 439                                 (lookupOccEnv old_non_orph_rules occ)
 440                                 (lookupOccEnv new_non_orph_rules occ)
 441     -------------------
 442     -- Computing what changed
 443     no_output_change = no_decl_change   && no_rule_change &&
 444                        no_export_change && no_deprec_change
 445     no_export_change = mi_exports new_iface == mi_exports old_iface
 446                                 -- Kept sorted
 447     no_decl_change   = isEmptyOccSet changed_occs
 448     no_rule_change   = not (changedWrtNames changed_occs (eqListBy eqIfRule old_orph_rules new_orph_rules)
 449                          || changedWrtNames changed_occs (eqListBy eqIfInst old_orph_insts new_orph_insts)
 450                          || changedWrtNames changed_occs (eqListBy eqIfFamInst old_fam_insts new_fam_insts))
 451     no_deprec_change = mi_deprecs new_iface == mi_deprecs old_iface
 452
 453         -- If the usages havn't changed either, we don't need to write the interface file
 454     no_other_changes = mi_usages new_iface == mi_usages old_iface &&
 455                        mi_deps new_iface == mi_deps old_iface
 456     no_change_at_all = no_output_change && no_other_changes
 457
 458     pp_diffs = vcat [pp_change no_export_change "Export list"
 459                         (ppr old_exp_vers <+> arrow <+> ppr (mi_exp_vers final_iface)),
 460                      pp_change no_rule_change "Rules"
 461                         (ppr old_rule_vers <+> arrow <+> ppr (mi_rule_vers final_iface)),
 462                      pp_change no_deprec_change "Deprecations" empty,
 463                      pp_change no_other_changes  "Usages" empty,
 464                      pp_decl_diffs]
 465     pp_change True  what info = empty
 466     pp_change False what info = text what <+> ptext SLIT("changed") <+> info
 467
 468     -------------------
 469     old_decl_env = mkOccEnv [(ifName decl, decl) | (_,decl) <- old_decls]
 470     same_fixity n = bool (old_fixities n == new_fixities n)
 471
 472     -------------------
 473     -- Adding version info
 474     new_version = bumpVersion old_mod_vers
 475                         -- Start from the old module version, not from
 476                         -- zero so that if you remove f, and then add
 477                         -- it again, you don't thereby reduce f's
 478                         -- version number
 479
 480     add_vers decl | occ `elemOccSet` changed_occs = new_version
 481                   | otherwise = snd (expectJust "add_vers" (old_decl_vers occ))
 482                                 -- If it's unchanged, there jolly well
 483                   where         -- should be an old version number
 484                     occ = ifName decl
 485
 486     -------------------
 487     -- Deciding which declarations have changed
 488
 489     -- For each local decl, the IfaceEq gives the list of things that
 490     -- must be unchanged for the declaration as a whole to be unchanged.
 491     eq_info :: [(OccName, IfaceEq)]
 492     eq_info = map check_eq new_decls
 493     check_eq new_decl
 494          | Just old_decl <- lookupOccEnv old_decl_env occ
 495          = (occ, new_decl `eqIfDecl` old_decl &&& eq_indirects new_decl)
 496          | otherwise {- No corresponding old decl -}
 497          = (occ, NotEqual)
 498         where
 499           occ = ifName new_decl
 500
 501     eq_indirects :: IfaceDecl -> IfaceEq
 502                 -- When seeing if two decls are the same, remember to
 503                 -- check whether any relevant fixity or rules have changed
 504     eq_indirects (IfaceId {ifName = occ}) = eq_ind_occ occ
 505     eq_indirects (IfaceClass {ifName = cls_occ, ifSigs = sigs})
 506         = same_insts cls_occ &&&
 507           eq_ind_occs [op | IfaceClassOp op _ _ <- sigs]
 508     eq_indirects (IfaceData {ifName = tc_occ, ifCons = cons})
 509         = same_insts tc_occ &&& same_fixity tc_occ &&&  -- The TyCon can have a fixity too
 510           eq_ind_occs (map ifConOcc (visibleIfConDecls cons))
 511     eq_indirects other = Equal  -- Synonyms and foreign declarations
 512
 513     eq_ind_occ :: OccName -> IfaceEq    -- For class ops and Ids; check fixity and rules
 514     eq_ind_occ occ = same_fixity occ &&& same_rules occ
 515     eq_ind_occs = foldr ((&&&) . eq_ind_occ) Equal
 516
 517     -- The Occs of declarations that changed.
 518     changed_occs :: OccSet
 519     changed_occs = computeChangedOccs ver_fn (mi_module new_iface)
 520                          (mi_usages old_iface) eq_info
 521
 522     -------------------
 523     -- Diffs
 524     pp_decl_diffs :: SDoc       -- Nothing => no changes
 525     pp_decl_diffs
 526         | isEmptyOccSet changed_occs = empty
 527         | otherwise
 528         = vcat [ptext SLIT("Changed occs:") <+> ppr (occSetElts changed_occs),
 529                 ptext SLIT("Version change for these decls:"),
 530                 nest 2 (vcat (map show_change new_decls))]
 531
 532     eq_env = mkOccEnv eq_info
 533     show_change new_decl
 534         | not (occ `elemOccSet` changed_occs) = empty
 535         | otherwise
 536         = vcat [ppr occ <+> ppr (old_decl_vers occ) <+> arrow <+> ppr new_version,
 537                 nest 2 why]
 538         where
 539           occ = ifName new_decl
 540           why = case lookupOccEnv eq_env occ of
 541                     Just (EqBut names) -> sep [ppr occ <> colon, ptext SLIT("Free vars (only) changed:") <> ppr names,
 542                                               nest 2 (braces (fsep (map ppr (occSetElts
 543                                                 (occs `intersectOccSet` changed_occs)))))]
 544                            where occs = mkOccSet (map nameOccName (nameSetToList names))
 545                     Just NotEqual
 546                         | Just old_decl <- lookupOccEnv old_decl_env occ
 547                         -> vcat [ptext SLIT("Old:") <+> ppr old_decl,
 548                          ptext SLIT("New:") <+> ppr new_decl]
 549                         | otherwise
 550                         -> ppr occ <+> ptext SLIT("only in new interface")
 551                     other -> pprPanic "MkIface.show_change" (ppr occ)
 552
 553     pp_orphs = pprOrphans new_orph_insts new_orph_rules
 554
 555
 556 pprOrphans insts rules
 557   | null insts && null rules = Nothing
 558   | otherwise
 559   = Just $ vcat [
 560         if null insts then empty else
 561              hang (ptext SLIT("Warning: orphan instances:"))
 562                 2 (vcat (map ppr insts)),
 563         if null rules then empty else
 564              hang (ptext SLIT("Warning: orphan rules:"))
 565                 2 (vcat (map ppr rules))
 566     ]
 567
 568 computeChangedOccs
 569         :: (Name -> (OccName,Version))     -- get parents and versions
 570         -> Module                       -- This module
 571         -> [Usage]                      -- Usages from old iface
 572         -> [(OccName, IfaceEq)]         -- decl names, equality conditions
 573         -> OccSet                       -- set of things that have changed
 574 computeChangedOccs ver_fn this_module old_usages eq_info
 575   = foldl add_changes emptyOccSet (stronglyConnComp edges)
 576   where
 577
 578     -- return True if an external name has changed
 579     name_changed :: Name -> Bool
 580     name_changed nm
 581         | Just ents <- lookupUFM usg_modmap (moduleName mod)
 582         = case lookupUFM ents parent_occ of
 583                 Nothing -> pprPanic "computeChangedOccs" (ppr nm)
 584                 Just v  -> v < new_version
 585         | otherwise = False -- must be in another package
 586       where
 587          mod = nameModule nm
 588          (parent_occ, new_version) = ver_fn nm
 589
 590     -- Turn the usages from the old ModIface into a mapping
 591     usg_modmap = listToUFM [ (usg_mod usg, listToUFM (usg_entities usg))
 592                            | usg <- old_usages ]
 593
 594     get_local_eq_info :: GenIfaceEq NameSet -> GenIfaceEq OccSet
 595     get_local_eq_info Equal = Equal
 596     get_local_eq_info NotEqual = NotEqual
 597     get_local_eq_info (EqBut ns) = foldNameSet f Equal ns
 598         where f name eq | nameModule name == this_module =
 599                           EqBut (unitOccSet (nameOccName name)) `and_occifeq` eq
 600                         | name_changed name = NotEqual
 601                         | otherwise = eq
 602
 603     local_eq_infos = mapSnd get_local_eq_info eq_info
 604
 605     edges :: [((OccName, OccIfaceEq), Unique, [Unique])]
 606     edges = [ (node, getUnique occ, map getUnique occs)
 607             | node@(occ, iface_eq) <- local_eq_infos
 608             , let occs = case iface_eq of
 609                            EqBut occ_set -> occSetElts occ_set
 610                            other -> [] ]
 611
 612     -- Changes in declarations
 613     add_changes :: OccSet -> SCC (OccName, OccIfaceEq) -> OccSet
 614     add_changes so_far (AcyclicSCC (occ, iface_eq))
 615         | changedWrt so_far iface_eq -- This one has changed
 616         = extendOccSet so_far occ
 617     add_changes so_far (CyclicSCC pairs)
 618         | changedWrt so_far (foldr1 and_occifeq iface_eqs)
 619                 -- One of this group has changed
 620         = extendOccSetList so_far occs
 621         where (occs, iface_eqs) = unzip pairs
 622     add_changes so_far other = so_far
 623
 624 type OccIfaceEq = GenIfaceEq OccSet
 625
 626 changedWrt :: OccSet -> OccIfaceEq -> Bool
 627 changedWrt so_far Equal        = False
 628 changedWrt so_far NotEqual     = True
 629 changedWrt so_far (EqBut kids) = so_far `intersectsOccSet` kids
 630
 631 changedWrtNames :: OccSet -> IfaceEq -> Bool
 632 changedWrtNames so_far Equal        = False
 633 changedWrtNames so_far NotEqual     = True
 634 changedWrtNames so_far (EqBut kids) =
 635   so_far `intersectsOccSet` mkOccSet (map nameOccName (nameSetToList kids))
 636
 637 and_occifeq :: OccIfaceEq -> OccIfaceEq -> OccIfaceEq
 638 Equal       `and_occifeq` x         = x
 639 NotEqual    `and_occifeq` x         = NotEqual
 640 EqBut nms   `and_occifeq` Equal       = EqBut nms
 641 EqBut nms   `and_occifeq` NotEqual    = NotEqual
 642 EqBut nms1  `and_occifeq` EqBut nms2  = EqBut (nms1 `unionOccSets` nms2)
 643
 644 ----------------------
 645 -- mkOrphMap partitions instance decls or rules into
 646 --      (a) an OccEnv for ones that are not orphans,
 647 --          mapping the local OccName to a list of its decls
 648 --      (b) a list of orphan decls
 649 mkOrphMap :: (decl -> Maybe OccName)    -- (Just occ) for a non-orphan decl, keyed by occ
 650                                         -- Nothing for an orphan decl
 651           -> [decl]                     -- Sorted into canonical order
 652           -> (OccEnv [decl],            -- Non-orphan decls associated with their key;
 653                                         --      each sublist in canonical order
 654               [decl])                   -- Orphan decls; in canonical order
 655 mkOrphMap get_key decls
 656   = foldl go (emptyOccEnv, []) decls
 657   where
 658     go (non_orphs, orphs) d
 659         | Just occ <- get_key d
 660         = (extendOccEnv_C (\ ds _ -> d:ds) non_orphs occ [d], orphs)
 661         | otherwise = (non_orphs, d:orphs)
 662
 663 anyNothing :: (a -> Maybe b) -> [a] -> Bool
 664 anyNothing p []     = False
 665 anyNothing p (x:xs) = isNothing (p x) || anyNothing p xs
 666
 667 ----------------------
 668 mkIfaceDeprec :: Deprecations -> IfaceDeprecs
 669 mkIfaceDeprec NoDeprecs        = NoDeprecs
 670 mkIfaceDeprec (DeprecAll t)    = DeprecAll t
 671 mkIfaceDeprec (DeprecSome env) = DeprecSome (sortLe (<=) (nameEnvElts env))
 672
 673 ----------------------
 674 bump_unless :: Bool -> Version -> Version
 675 bump_unless True  v = v -- True <=> no change
 676 bump_unless False v = bumpVersion v
 677 \end{code}
 678
 679
 680 %*********************************************************
 681 %*                                                      *
 682 \subsection{Keeping track of what we've slurped, and version numbers}
 683 %*                                                      *
 684 %*********************************************************
 685
 686
 687 \begin{code}
 688 mkUsageInfo :: HscEnv
 689             -> ModuleEnv (Module, Bool, SrcSpan)
 690             -> [(ModuleName, IsBootInterface)]
 691             -> NameSet -> IO [Usage]
 692 mkUsageInfo hsc_env dir_imp_mods dep_mods used_names
 693   = do  { eps <- hscEPS hsc_env
 694         ; let usages = mk_usage_info (eps_PIT eps) hsc_env
 695                                      dir_imp_mods dep_mods used_names
 696         ; usages `seqList`  return usages }
 697          -- seq the list of Usages returned: occasionally these
 698          -- don't get evaluated for a while and we can end up hanging on to
 699          -- the entire collection of Ifaces.
 700
 701 mk_usage_info pit hsc_env dir_imp_mods dep_mods used_names
 702   = mapCatMaybes mkUsage dep_mods
 703         -- ToDo: do we need to sort into canonical order?
 704   where
 705     hpt = hsc_HPT hsc_env
 706     dflags = hsc_dflags hsc_env
 707
 708     -- ent_map groups together all the things imported and used
 709     -- from a particular module in this package
 710     ent_map :: ModuleEnv [OccName]
 711     ent_map  = foldNameSet add_mv emptyModuleEnv used_names
 712     add_mv name mv_map
 713         | isWiredInName name = mv_map  -- ignore wired-in names
 714         | otherwise
 715         = case nameModule_maybe name of
 716              Nothing  -> mv_map         -- ignore internal names
 717              Just mod -> extendModuleEnv_C add_item mv_map mod [occ]
 718                    where
 719                      occ = nameOccName name
 720                      add_item occs _ = occ:occs
 721
 722     depend_on_exports mod = case lookupModuleEnv dir_imp_mods mod of
 723                                 Just (_,no_imp,_) -> not no_imp
 724                                 Nothing           -> True
 725
 726     -- We want to create a Usage for a home module if
 727     --  a) we used something from; has something in used_names
 728     --  b) we imported all of it, even if we used nothing from it
 729     --          (need to recompile if its export list changes: export_vers)
 730     --  c) is a home-package orphan or family-instance module (need to
 731     --          recompile if its instance decls change: rules_vers)
 732     mkUsage :: (ModuleName, IsBootInterface) -> Maybe Usage
 733     mkUsage (mod_name, _)
 734       |  isNothing maybe_iface          -- We can't depend on it if we didn't
 735       || (null used_occs                -- load its interface.
 736           && isNothing export_vers
 737           && not orphan_mod
 738           && not finsts_mod)
 739       = Nothing                 -- Record no usage info
 740
 741       | otherwise
 742       = Just (Usage { usg_name     = mod_name,
 743                       usg_mod      = mod_vers,
 744                       usg_exports  = export_vers,
 745                       usg_entities = fmToList ent_vers,
 746                       usg_rules    = rules_vers })
 747       where
 748         maybe_iface  = lookupIfaceByModule dflags hpt pit mod
 749                 -- In one-shot mode, the interfaces for home-package
 750                 -- modules accumulate in the PIT not HPT.  Sigh.
 751
 752         mod = mkModule (thisPackage dflags) mod_name
 753
 754         Just iface   = maybe_iface
 755         orphan_mod   = mi_orphan    iface
 756         finsts_mod   = mi_finsts    iface
 757         version_env  = mi_ver_fn    iface
 758         mod_vers     = mi_mod_vers  iface
 759         rules_vers   = mi_rule_vers iface
 760         export_vers | depend_on_exports mod = Just (mi_exp_vers iface)
 761                     | otherwise             = Nothing
 762
 763         used_occs = lookupModuleEnv ent_map mod `orElse` []
 764
 765         -- Making a FiniteMap here ensures that (a) we remove duplicates
 766         -- when we have usages on several subordinates of a single parent,
 767         -- and (b) that the usages emerge in a canonical order, which
 768         -- is why we use FiniteMap rather than OccEnv: FiniteMap works
 769         -- using Ord on the OccNames, which is a lexicographic ordering.
 770         ent_vers :: FiniteMap OccName Version
 771         ent_vers = listToFM (map lookup_occ used_occs)
 772
 773         lookup_occ occ =
 774             case version_env occ of
 775                 Nothing -> pprTrace "hmm, strange" (ppr mod <+> ppr occ) $
 776                            (occ, initialVersion) -- does this ever happen?
 777                 Just (parent, version) -> (parent, version)
 778 \end{code}
 779
 780 \begin{code}
 781 mkIfaceExports :: [AvailInfo]
 782                -> [(Module, [GenAvailInfo OccName])]
 783   -- Group by module and sort by occurrence
 784   -- This keeps the list in canonical order
 785 mkIfaceExports exports
 786   = [ (mod, eltsFM avails)
 787     | (mod, avails) <- fmToList groupFM
 788     ]
 789   where
 790         -- Deliberately use FiniteMap rather than UniqFM so we
 791         -- get a canonical ordering
 792     groupFM :: ModuleEnv (FiniteMap FastString (GenAvailInfo OccName))
 793     groupFM = foldl add emptyModuleEnv exports
 794
 795     add env avail
 796       = extendModuleEnv_C add_avail env mod (unitFM avail_fs avail_occ)
 797       where
 798         avail_occ = availToOccs avail
 799         mod  = nameModule (availName avail)
 800         avail_fs = occNameFS (availName avail_occ)
 801         add_avail avail_fm _ = addToFM avail_fm avail_fs avail_occ
 802
 803     availToOccs (Avail n) = Avail (nameOccName n)
 804     availToOccs (AvailTC tc ns) = AvailTC (nameOccName tc) (map nameOccName ns)
 805 \end{code}
 806
 807
 808 %************************************************************************
 809 %*                                                                      *
 810         Load the old interface file for this module (unless
 811         we have it aleady), and check whether it is up to date
 812
 813 %*                                                                      *
 814 %************************************************************************
 815
 816 \begin{code}
 817 checkOldIface :: HscEnv
 818               -> ModSummary
 819               -> Bool                   -- Source unchanged
 820               -> Maybe ModIface         -- Old interface from compilation manager, if any
 821               -> IO (RecompileRequired, Maybe ModIface)
 822
 823 checkOldIface hsc_env mod_summary source_unchanged maybe_iface
 824   = do  { showPass (hsc_dflags hsc_env)
 825                    ("Checking old interface for " ++
 826                         showSDoc (ppr (ms_mod mod_summary))) ;
 827
 828         ; initIfaceCheck hsc_env $
 829           check_old_iface hsc_env mod_summary source_unchanged maybe_iface
 830      }
 831
 832 check_old_iface hsc_env mod_summary source_unchanged maybe_iface
 833  =  do  -- CHECK WHETHER THE SOURCE HAS CHANGED
 834     { ifM (not source_unchanged)
 835            (traceHiDiffs (nest 4 (text "Source file changed or recompilation check turned off")))
 836
 837      -- If the source has changed and we're in interactive mode, avoid reading
 838      -- an interface; just return the one we might have been supplied with.
 839     ; ghc_mode <- getGhcMode
 840     ; if (ghc_mode == Interactive || ghc_mode == JustTypecheck)
 841          && not source_unchanged then
 842          return (outOfDate, maybe_iface)
 843       else
 844       case maybe_iface of {
 845         Just old_iface -> do -- Use the one we already have
 846           { traceIf (text "We already have the old interface for" <+> ppr (ms_mod mod_summary))
 847           ; recomp <- checkVersions hsc_env source_unchanged old_iface
 848           ; return (recomp, Just old_iface) }
 849
 850       ; Nothing -> do
 851
 852         -- Try and read the old interface for the current module
 853         -- from the .hi file left from the last time we compiled it
 854     { let iface_path = msHiFilePath mod_summary
 855     ; read_result <- readIface (ms_mod mod_summary) iface_path False
 856     ; case read_result of {
 857          Failed err -> do       -- Old interface file not found, or garbled; give up
 858                 { traceIf (text "FYI: cannot read old interface file:"
 859                                  $$ nest 4 err)
 860                 ; return (outOfDate, Nothing) }
 861
 862       ;  Succeeded iface -> do
 863
 864         -- We have got the old iface; check its versions
 865     { traceIf (text "Read the interface file" <+> text iface_path)
 866     ; recomp <- checkVersions hsc_env source_unchanged iface
 867     ; returnM (recomp, Just iface)
 868     }}}}}
 869 \end{code}
 870
 871 @recompileRequired@ is called from the HscMain.   It checks whether
 872 a recompilation is required.  It needs access to the persistent state,
 873 finder, etc, because it may have to load lots of interface files to
 874 check their versions.
 875
 876 \begin{code}
 877 type RecompileRequired = Bool
 878 upToDate  = False       -- Recompile not required
 879 outOfDate = True        -- Recompile required
 880
 881 checkVersions :: HscEnv
 882               -> Bool           -- True <=> source unchanged
 883               -> ModIface       -- Old interface
 884               -> IfG RecompileRequired
 885 checkVersions hsc_env source_unchanged iface
 886   | not source_unchanged
 887   = returnM outOfDate
 888   | otherwise
 889   = do  { traceHiDiffs (text "Considering whether compilation is required for" <+>
 890                         ppr (mi_module iface) <> colon)
 891
 892         -- Source code unchanged and no errors yet... carry on
 893
 894         -- First put the dependent-module info, read from the old interface, into the envt,
 895         -- so that when we look for interfaces we look for the right one (.hi or .hi-boot)
 896         --
 897         -- It's just temporary because either the usage check will succeed
 898         -- (in which case we are done with this module) or it'll fail (in which
 899         -- case we'll compile the module from scratch anyhow).
 900         --
 901         -- We do this regardless of compilation mode, although in --make mode
 902         -- all the dependent modules should be in the HPT already, so it's
 903         -- quite redundant
 904         ; updateEps_ $ \eps  -> eps { eps_is_boot = mod_deps }
 905
 906         ; let this_pkg = thisPackage (hsc_dflags hsc_env)
 907         ; checkList [checkModUsage this_pkg u | u <- mi_usages iface]
 908     }
 909   where
 910         -- This is a bit of a hack really
 911     mod_deps :: ModuleNameEnv (ModuleName, IsBootInterface)
 912     mod_deps = mkModDeps (dep_mods (mi_deps iface))
 913
 914 checkModUsage :: PackageId ->Usage -> IfG RecompileRequired
 915 -- Given the usage information extracted from the old
 916 -- M.hi file for the module being compiled, figure out
 917 -- whether M needs to be recompiled.
 918
 919 checkModUsage this_pkg (Usage { usg_name = mod_name, usg_mod = old_mod_vers,
 920                                 usg_rules = old_rule_vers,
 921                                 usg_exports = maybe_old_export_vers,
 922                                 usg_entities = old_decl_vers })
 923   =     -- Load the imported interface is possible
 924     let
 925         doc_str = sep [ptext SLIT("need version info for"), ppr mod_name]
 926     in
 927     traceHiDiffs (text "Checking usages for module" <+> ppr mod_name) `thenM_`
 928
 929     let
 930         mod = mkModule this_pkg mod_name
 931     in
 932     loadInterface doc_str mod ImportBySystem            `thenM` \ mb_iface ->
 933         -- Load the interface, but don't complain on failure;
 934         -- Instead, get an Either back which we can test
 935
 936     case mb_iface of {
 937         Failed exn ->  (out_of_date (sep [ptext SLIT("Can't find version number for module"),
 938                                        ppr mod_name]));
 939                 -- Couldn't find or parse a module mentioned in the
 940                 -- old interface file.  Don't complain -- it might just be that
 941                 -- the current module doesn't need that import and it's been deleted
 942
 943         Succeeded iface ->
 944     let
 945         new_mod_vers    = mi_mod_vers  iface
 946         new_decl_vers   = mi_ver_fn    iface
 947         new_export_vers = mi_exp_vers  iface
 948         new_rule_vers   = mi_rule_vers iface
 949     in
 950         -- CHECK MODULE
 951     checkModuleVersion old_mod_vers new_mod_vers        `thenM` \ recompile ->
 952     if not recompile then
 953         returnM upToDate
 954     else
 955
 956         -- CHECK EXPORT LIST
 957     if checkExportList maybe_old_export_vers new_export_vers then
 958         out_of_date_vers (ptext SLIT("  Export list changed"))
 959                          (expectJust "checkModUsage" maybe_old_export_vers)
 960                          new_export_vers
 961     else
 962
 963         -- CHECK RULES
 964     if old_rule_vers /= new_rule_vers then
 965         out_of_date_vers (ptext SLIT("  Rules changed"))
 966                          old_rule_vers new_rule_vers
 967     else
 968
 969         -- CHECK ITEMS ONE BY ONE
 970     checkList [checkEntityUsage new_decl_vers u | u <- old_decl_vers]   `thenM` \ recompile ->
 971     if recompile then
 972         returnM outOfDate       -- This one failed, so just bail out now
 973     else
 974         up_to_date (ptext SLIT("  Great!  The bits I use are up to date"))
 975     }
 976
 977 ------------------------
 978 checkModuleVersion old_mod_vers new_mod_vers
 979   | new_mod_vers == old_mod_vers
 980   = up_to_date (ptext SLIT("Module version unchanged"))
 981
 982   | otherwise
 983   = out_of_date_vers (ptext SLIT("  Module version has changed"))
 984                      old_mod_vers new_mod_vers
 985
 986 ------------------------
 987 checkExportList Nothing  new_vers = upToDate
 988 checkExportList (Just v) new_vers = v /= new_vers
 989
 990 ------------------------
 991 checkEntityUsage new_vers (name,old_vers)
 992   = case new_vers name of
 993
 994         Nothing       ->        -- We used it before, but it ain't there now
 995                           out_of_date (sep [ptext SLIT("No longer exported:"), ppr name])
 996
 997         Just (_, new_vers)      -- It's there, but is it up to date?
 998           | new_vers == old_vers -> traceHiDiffs (text "  Up to date" <+> ppr name <+> parens (ppr new_vers)) `thenM_`
 999                                     returnM upToDate
1000           | otherwise            -> out_of_date_vers (ptext SLIT("  Out of date:") <+> ppr name)
1001                                                      old_vers new_vers
1002
1003 up_to_date  msg = traceHiDiffs msg `thenM_` returnM upToDate
1004 out_of_date msg = traceHiDiffs msg `thenM_` returnM outOfDate
1005 out_of_date_vers msg old_vers new_vers
1006   = out_of_date (hsep [msg, ppr old_vers, ptext SLIT("->"), ppr new_vers])
1007
1008 ----------------------
1009 checkList :: [IfG RecompileRequired] -> IfG RecompileRequired
1010 -- This helper is used in two places
1011 checkList []             = returnM upToDate
1012 checkList (check:checks) = check        `thenM` \ recompile ->
1013                            if recompile then
1014                                 returnM outOfDate
1015                            else
1016                                 checkList checks
1017 \end{code}
1018
1019 %************************************************************************
1020 %*                                                                      *
1021                 Converting things to their Iface equivalents
1022 %*                                                                      *
1023 %************************************************************************
1024
1025 \begin{code}
1026 tyThingToIfaceDecl :: TyThing -> IfaceDecl
1027 -- Assumption: the thing is already tidied, so that locally-bound names
1028 --             (lambdas, for-alls) already have non-clashing OccNames
1029 -- Reason: Iface stuff uses OccNames, and the conversion here does
1030 --         not do tidying on the way
1031 tyThingToIfaceDecl (AnId id)
1032   = IfaceId { ifName   = getOccName id,
1033               ifType   = toIfaceType (idType id),
1034               ifIdInfo = info }
1035   where
1036     info = case toIfaceIdInfo (idInfo id) of
1037                 []    -> NoInfo
1038                 items -> HasInfo items
1039
1040 tyThingToIfaceDecl (AClass clas)
1041   = IfaceClass { ifCtxt   = toIfaceContext sc_theta,
1042                  ifName   = getOccName clas,
1043                  ifTyVars = toIfaceTvBndrs clas_tyvars,
1044                  ifFDs    = map toIfaceFD clas_fds,
1045                  ifATs    = map (tyThingToIfaceDecl . ATyCon) clas_ats,
1046                  ifSigs   = map toIfaceClassOp op_stuff,
1047                  ifRec    = boolToRecFlag (isRecursiveTyCon tycon) }
1048   where
1049     (clas_tyvars, clas_fds, sc_theta, _, clas_ats, op_stuff)
1050       = classExtraBigSig clas
1051     tycon = classTyCon clas
1052
1053     toIfaceClassOp (sel_id, def_meth)
1054         = ASSERT(sel_tyvars == clas_tyvars)
1055           IfaceClassOp (getOccName sel_id) def_meth (toIfaceType op_ty)
1056         where
1057                 -- Be careful when splitting the type, because of things
1058                 -- like         class Foo a where
1059                 --                op :: (?x :: String) => a -> a
1060                 -- and          class Baz a where
1061                 --                op :: (Ord a) => a -> a
1062           (sel_tyvars, rho_ty) = splitForAllTys (idType sel_id)
1063           op_ty                = funResultTy rho_ty
1064
1065     toIfaceFD (tvs1, tvs2) = (map getFS tvs1, map getFS tvs2)
1066
1067 tyThingToIfaceDecl (ATyCon tycon)
1068   | isSynTyCon tycon
1069   = IfaceSyn {  ifName   = getOccName tycon,
1070                 ifTyVars = toIfaceTvBndrs tyvars,
1071                 ifOpenSyn = syn_isOpen,
1072                 ifSynRhs  = toIfaceType syn_tyki }
1073
1074   | isAlgTyCon tycon
1075   = IfaceData { ifName    = getOccName tycon,
1076                 ifTyVars  = toIfaceTvBndrs tyvars,
1077                 ifCtxt    = toIfaceContext (tyConStupidTheta tycon),
1078                 ifCons    = ifaceConDecls (algTyConRhs tycon),
1079                 ifRec     = boolToRecFlag (isRecursiveTyCon tycon),
1080                 ifGadtSyntax = isGadtSyntaxTyCon tycon,
1081                 ifGeneric = tyConHasGenerics tycon,
1082                 ifFamInst = famInstToIface (tyConFamInst_maybe tycon)}
1083
1084   | isForeignTyCon tycon
1085   = IfaceForeign { ifName    = getOccName tycon,
1086                    ifExtName = tyConExtName tycon }
1087
1088   | otherwise = pprPanic "toIfaceDecl" (ppr tycon)
1089   where
1090     tyvars = tyConTyVars tycon
1091     (syn_isOpen, syn_tyki) = case synTyConRhs tycon of
1092                                OpenSynTyCon ki -> (True , ki)
1093                                SynonymTyCon ty -> (False, ty)
1094
1095     ifaceConDecls (NewTyCon { data_con = con })    =
1096       IfNewTyCon  (ifaceConDecl con)
1097     ifaceConDecls (DataTyCon { data_cons = cons }) =
1098       IfDataTyCon (map ifaceConDecl cons)
1099     ifaceConDecls OpenDataTyCon                    = IfOpenDataTyCon
1100     ifaceConDecls OpenNewTyCon                     = IfOpenNewTyCon
1101     ifaceConDecls AbstractTyCon                    = IfAbstractTyCon
1102         -- The last case happens when a TyCon has been trimmed during tidying
1103         -- Furthermore, tyThingToIfaceDecl is also used
1104         -- in TcRnDriver for GHCi, when browsing a module, in which case the
1105         -- AbstractTyCon case is perfectly sensible.
1106
1107     ifaceConDecl data_con
1108         = IfCon   { ifConOcc     = getOccName (dataConName data_con),
1109                     ifConInfix   = dataConIsInfix data_con,
1110                     ifConUnivTvs = toIfaceTvBndrs (dataConUnivTyVars data_con),
1111                     ifConExTvs   = toIfaceTvBndrs (dataConExTyVars data_con),
1112                     ifConEqSpec  = to_eq_spec (dataConEqSpec data_con),
1113                     ifConCtxt    = toIfaceContext (dataConTheta data_con),
1114                     ifConArgTys  = map toIfaceType (dataConOrigArgTys data_con),
1115                     ifConFields  = map getOccName
1116                                        (dataConFieldLabels data_con),
1117                     ifConStricts = dataConStrictMarks data_con }
1118
1119     to_eq_spec spec = [(getOccName tv, toIfaceType ty) | (tv,ty) <- spec]
1120
1121     famInstToIface Nothing                    = Nothing
1122     famInstToIface (Just (famTyCon, instTys)) =
1123       Just (toIfaceTyCon famTyCon, map toIfaceType instTys)
1124
1125 tyThingToIfaceDecl (ADataCon dc)
1126  = pprPanic "toIfaceDecl" (ppr dc)      -- Should be trimmed out earlier
1127
1128
1129 getFS x = occNameFS (getOccName x)
1130
1131 --------------------------
1132 instanceToIfaceInst :: Instance -> IfaceInst
1133 instanceToIfaceInst ispec@(Instance { is_dfun = dfun_id, is_flag = oflag,
1134                                       is_cls = cls, is_tcs = mb_tcs,
1135                                       is_orph = orph })
1136   = IfaceInst { ifDFun    = getName dfun_id,
1137                 ifOFlag   = oflag,
1138                 ifInstCls = cls,
1139                 ifInstTys = map do_rough mb_tcs,
1140                 ifInstOrph = orph }
1141   where
1142     do_rough Nothing  = Nothing
1143     do_rough (Just n) = Just (toIfaceTyCon_name n)
1144
1145 --------------------------
1146 famInstToIfaceFamInst :: FamInst -> IfaceFamInst
1147 famInstToIfaceFamInst fi@(FamInst { fi_tycon = tycon,
1148                                             fi_fam = fam, fi_tcs = mb_tcs })
1149   = IfaceFamInst { ifFamInstTyCon  = toIfaceTyCon tycon
1150                  , ifFamInstFam    = fam
1151                  , ifFamInstTys    = map do_rough mb_tcs }
1152   where
1153     do_rough Nothing  = Nothing
1154     do_rough (Just n) = Just (toIfaceTyCon_name n)
1155
1156 --------------------------
1157 toIfaceIdInfo :: IdInfo -> [IfaceInfoItem]
1158 toIfaceIdInfo id_info
1159   = catMaybes [arity_hsinfo, caf_hsinfo, strict_hsinfo,
1160                inline_hsinfo, wrkr_hsinfo,  unfold_hsinfo]
1161   where
1162     ------------  Arity  --------------
1163     arity_info = arityInfo id_info
1164     arity_hsinfo | arity_info == 0 = Nothing
1165                  | otherwise       = Just (HsArity arity_info)
1166
1167     ------------ Caf Info --------------
1168     caf_info   = cafInfo id_info
1169     caf_hsinfo = case caf_info of
1170                    NoCafRefs -> Just HsNoCafRefs
1171                    _other    -> Nothing
1172
1173     ------------  Strictness  --------------
1174         -- No point in explicitly exporting TopSig
1175     strict_hsinfo = case newStrictnessInfo id_info of
1176                         Just sig | not (isTopSig sig) -> Just (HsStrictness sig)
1177                         _other                        -> Nothing
1178
1179     ------------  Worker  --------------
1180     work_info   = workerInfo id_info
1181     has_worker  = case work_info of { HasWorker _ _ -> True; other -> False }
1182     wrkr_hsinfo = case work_info of
1183                     HasWorker work_id wrap_arity ->
1184                         Just (HsWorker ((idName work_id)) wrap_arity)
1185                     NoWorker -> Nothing
1186
1187     ------------  Unfolding  --------------
1188     -- The unfolding is redundant if there is a worker
1189     unfold_info  = unfoldingInfo id_info
1190     rhs          = unfoldingTemplate unfold_info
1191     no_unfolding = neverUnfold unfold_info
1192                         -- The CoreTidy phase retains unfolding info iff
1193                         -- we want to expose the unfolding, taking into account
1194                         -- unconditional NOINLINE, etc.  See TidyPgm.addExternal
1195     unfold_hsinfo | no_unfolding = Nothing
1196                   | has_worker   = Nothing      -- Unfolding is implicit
1197                   | otherwise    = Just (HsUnfold (toIfaceExpr rhs))
1198
1199     ------------  Inline prag  --------------
1200     inline_prag = inlinePragInfo id_info
1201     inline_hsinfo | isAlwaysActive inline_prag     = Nothing
1202                   | no_unfolding && not has_worker = Nothing
1203                         -- If the iface file give no unfolding info, we
1204                         -- don't need to say when inlining is OK!
1205                   | otherwise                      = Just (HsInline inline_prag)
1206
1207 --------------------------
1208 coreRuleToIfaceRule :: CoreRule -> IfaceRule
1209 coreRuleToIfaceRule (BuiltinRule { ru_fn = fn})
1210   = pprTrace "toHsRule: builtin" (ppr fn) $
1211     bogusIfaceRule fn
1212
1213 coreRuleToIfaceRule (Rule { ru_name = name, ru_fn = fn,
1214                             ru_act = act, ru_bndrs = bndrs,
1215                             ru_args = args, ru_rhs = rhs, ru_orph = orph })
1216   = IfaceRule { ifRuleName  = name, ifActivation = act,
1217                 ifRuleBndrs = map toIfaceBndr bndrs,
1218                 ifRuleHead  = fn,
1219                 ifRuleArgs  = map do_arg args,
1220                 ifRuleRhs   = toIfaceExpr rhs,
1221                 ifRuleOrph  = orph }
1222   where
1223         -- For type args we must remove synonyms from the outermost
1224         -- level.  Reason: so that when we read it back in we'll
1225         -- construct the same ru_rough field as we have right now;
1226         -- see tcIfaceRule
1227     do_arg (Type ty) = IfaceType (toIfaceType (deNoteType ty))
1228     do_arg arg       = toIfaceExpr arg
1229
1230 bogusIfaceRule :: Name -> IfaceRule
1231 bogusIfaceRule id_name
1232   = IfaceRule { ifRuleName = FSLIT("bogus"), ifActivation = NeverActive,
1233         ifRuleBndrs = [], ifRuleHead = id_name, ifRuleArgs = [],
1234         ifRuleRhs = IfaceExt id_name, ifRuleOrph = Nothing }
1235
1236 ---------------------
1237 toIfaceExpr :: CoreExpr -> IfaceExpr
1238 toIfaceExpr (Var v)       = toIfaceVar v
1239 toIfaceExpr (Lit l)       = IfaceLit l
1240 toIfaceExpr (Type ty)     = IfaceType (toIfaceType ty)
1241 toIfaceExpr (Lam x b)     = IfaceLam (toIfaceBndr x) (toIfaceExpr b)
1242 toIfaceExpr (App f a)     = toIfaceApp f [a]
1243 toIfaceExpr (Case s x ty as) = IfaceCase (toIfaceExpr s) (getFS x) (toIfaceType ty) (map toIfaceAlt as)
1244 toIfaceExpr (Let b e)     = IfaceLet (toIfaceBind b) (toIfaceExpr e)
1245 toIfaceExpr (Cast e co)   = IfaceCast (toIfaceExpr e) (toIfaceType co)
1246 toIfaceExpr (Note n e)    = IfaceNote (toIfaceNote n) (toIfaceExpr e)
1247
1248 ---------------------
1249 toIfaceNote (SCC cc)      = IfaceSCC cc
1250 toIfaceNote InlineMe      = IfaceInlineMe
1251 toIfaceNote (CoreNote s)  = IfaceCoreNote s
1252
1253 ---------------------
1254 toIfaceBind (NonRec b r) = IfaceNonRec (toIfaceIdBndr b) (toIfaceExpr r)
1255 toIfaceBind (Rec prs)    = IfaceRec [(toIfaceIdBndr b, toIfaceExpr r) | (b,r) <- prs]
1256
1257 ---------------------
1258 toIfaceAlt (c,bs,r) = (toIfaceCon c, map getFS bs, toIfaceExpr r)
1259
1260 ---------------------
1261 toIfaceCon (DataAlt dc) | isTupleTyCon tc = IfaceTupleAlt (tupleTyConBoxity tc)
1262                         | otherwise       = IfaceDataAlt (getName dc)
1263                         where
1264                           tc = dataConTyCon dc
1265
1266 toIfaceCon (LitAlt l) = IfaceLitAlt l
1267 toIfaceCon DEFAULT    = IfaceDefault
1268
1269 ---------------------
1270 toIfaceApp (App f a) as = toIfaceApp f (a:as)
1271 toIfaceApp (Var v) as
1272   = case isDataConWorkId_maybe v of
1273         -- We convert the *worker* for tuples into IfaceTuples
1274         Just dc |  isTupleTyCon tc && saturated
1275                 -> IfaceTuple (tupleTyConBoxity tc) tup_args
1276           where
1277             val_args  = dropWhile isTypeArg as
1278             saturated = val_args `lengthIs` idArity v
1279             tup_args  = map toIfaceExpr val_args
1280             tc        = dataConTyCon dc
1281
1282         other -> mkIfaceApps (toIfaceVar v) as
1283
1284 toIfaceApp e as = mkIfaceApps (toIfaceExpr e) as
1285
1286 mkIfaceApps f as = foldl (\f a -> IfaceApp f (toIfaceExpr a)) f as
1287
1288 ---------------------
1289 toIfaceVar :: Id -> IfaceExpr
1290 toIfaceVar v
1291   | Just fcall <- isFCallId_maybe v = IfaceFCall fcall (toIfaceType (idType v))
1292           -- Foreign calls have special syntax
1293   | isExternalName name             = IfaceExt name
1294   | otherwise                       = IfaceLcl (getFS name)
1295   where
1296     name = idName v
1297 \end{code}