compiler/iface/MkIface.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   4 %
   5
   6 \begin{code}
   7 module MkIface (
   8         mkUsageInfo,    -- Construct the usage info for a module
   9
  10         mkIface,        -- Build a ModIface from a ModGuts,
  11                         -- including computing version information
  12
  13         writeIfaceFile, -- Write the interface file
  14
  15         checkOldIface,  -- See if recompilation is required, by
  16                         -- comparing version information
  17
  18         tyThingToIfaceDecl -- Converting things to their Iface equivalents
  19  ) where
  20 \end{code}
  21
  22         -----------------------------------------------
  23                 MkIface.lhs deals with versioning
  24         -----------------------------------------------
  25
  26 Here's the version-related info in an interface file
  27
  28   module Foo 8          -- module-version
  29              3          -- export-list-version
  30              2          -- rule-version
  31     Usages:     -- Version info for what this compilation of Foo imported
  32         Baz 3           -- Module version
  33             [4]         -- The export-list version if Foo depended on it
  34             (g,2)       -- Function and its version
  35             (T,1)       -- Type and its version
  36
  37     <version> f :: Int -> Int {- Unfolding: \x -> Wib.t[2] x -}
  38                 -- The [2] says that f's unfolding
  39                 -- mentions verison 2 of Wib.t
  40
  41         -----------------------------------------------
  42                         Basic idea
  43         -----------------------------------------------
  44
  45 Basic idea:
  46   * In the mi_usages information in an interface, we record the
  47     version number of each free variable of the module
  48
  49   * In mkIface, we compute the version number of each exported thing A.f
  50     by comparing its A.f's info with its new info, and bumping its
  51     version number if it differs.  If A.f mentions B.g, and B.g's version
  52     number has changed, then we count A.f as having changed too.
  53
  54   * In checkOldIface we compare the mi_usages for the module with
  55     the actual version info for all each thing recorded in mi_usages
  56
  57
  58 Fixities
  59 ~~~~~~~~
  60 We count A.f as changing if its fixity changes
  61
  62 Rules
  63 ~~~~~
  64 If a rule changes, we want to recompile any module that might be
  65 affected by that rule.  For non-orphan rules, this is relatively easy.
  66 If module M defines f, and a rule for f, just arrange that the version
  67 number for M.f changes if any of the rules for M.f change.  Any module
  68 that does not depend on M.f can't be affected by the rule-change
  69 either.
  70
  71 Orphan rules (ones whose 'head function' is not defined in M) are
  72 harder.  Here's what we do.
  73
  74   * We have a per-module orphan-rule version number which changes if
  75     any orphan rule changes. (It's unaffected by non-orphan rules.)
  76
  77   * We record usage info for any orphan module 'below' this one,
  78     giving the orphan-rule version number.  We recompile if this
  79     changes.
  80
  81 The net effect is that if an orphan rule changes, we recompile every
  82 module above it.  That's very conservative, but it's devilishly hard
  83 to know what it might affect, so we just have to be conservative.
  84
  85 Instance decls
  86 ~~~~~~~~~~~~~~
  87 In an iface file we have
  88      module A where
  89         instance Eq a => Eq [a]  =  dfun29
  90         dfun29 :: ...
  91
  92 We have a version number for dfun29, covering its unfolding
  93 etc. Suppose we are compiling a module M that imports A only
  94 indirectly.  If typechecking M uses this instance decl, we record the
  95 dependency on A.dfun29 as if it were a free variable of the module
  96 (via the tcg_inst_usages accumulator).  That means that A will appear
  97 in M's usage list.  If the shape of the instance declaration changes,
  98 then so will dfun29's version, triggering a recompilation.
  99
 100 Adding an instance declaration, or changing an instance decl that is
 101 not currently used, is more tricky.  (This really only makes a
 102 difference when we have overlapping instance decls, because then the
 103 new instance decl might kick in to override the old one.)  We handle
 104 this in a very similar way that we handle rules above.
 105
 106   * For non-orphan instance decls, identify one locally-defined tycon/class
 107     mentioned in the decl.  Treat the instance decl as part of the defn of that
 108     tycon/class, so that if the shape of the instance decl changes, so does the
 109     tycon/class; that in turn will force recompilation of anything that uses
 110     that tycon/class.
 111
 112   * For orphan instance decls, act the same way as for orphan rules.
 113     Indeed, we use the same global orphan-rule version number.
 114
 115 mkUsageInfo
 116 ~~~~~~~~~~~
 117 mkUsageInfo figures out what the ``usage information'' for this
 118 moudule is; that is, what it must record in its interface file as the
 119 things it uses.
 120
 121 We produce a line for every module B below the module, A, currently being
 122 compiled:
 123         import B <n> ;
 124 to record the fact that A does import B indirectly.  This is used to decide
 125 to look to look for B.hi rather than B.hi-boot when compiling a module that
 126 imports A.  This line says that A imports B, but uses nothing in it.
 127 So we'll get an early bale-out when compiling A if B's version changes.
 128
 129 The usage information records:
 130
 131 \begin{itemize}
 132 \item   (a) anything reachable from its body code
 133 \item   (b) any module exported with a @module Foo@
 134 \item   (c) anything reachable from an exported item
 135 \end{itemize}
 136
 137 Why (b)?  Because if @Foo@ changes then this module's export list
 138 will change, so we must recompile this module at least as far as
 139 making a new interface file --- but in practice that means complete
 140 recompilation.
 141
 142 Why (c)?  Consider this:
 143 \begin{verbatim}
 144         module A( f, g ) where  |       module B( f ) where
 145           import B( f )         |         f = h 3
 146           g = ...               |         h = ...
 147 \end{verbatim}
 148
 149 Here, @B.f@ isn't used in A.  Should we nevertheless record @B.f@ in
 150 @A@'s usages?  Our idea is that we aren't going to touch A.hi if it is
 151 *identical* to what it was before.  If anything about @B.f@ changes
 152 than anyone who imports @A@ should be recompiled in case they use
 153 @B.f@ (they'll get an early exit if they don't).  So, if anything
 154 about @B.f@ changes we'd better make sure that something in A.hi
 155 changes, and the convenient way to do that is to record the version
 156 number @B.f@ in A.hi in the usage list.  If B.f changes that'll force a
 157 complete recompiation of A, which is overkill but it's the only way to
 158 write a new, slightly different, A.hi.
 159
 160 But the example is tricker.  Even if @B.f@ doesn't change at all,
 161 @B.h@ may do so, and this change may not be reflected in @f@'s version
 162 number.  But with -O, a module that imports A must be recompiled if
 163 @B.h@ changes!  So A must record a dependency on @B.h@.  So we treat
 164 the occurrence of @B.f@ in the export list *just as if* it were in the
 165 code of A, and thereby haul in all the stuff reachable from it.
 166
 167         *** Conclusion: if A mentions B.f in its export list,
 168             behave just as if A mentioned B.f in its source code,
 169             and slurp in B.f and all its transitive closure ***
 170
 171 [NB: If B was compiled with -O, but A isn't, we should really *still*
 172 haul in all the unfoldings for B, in case the module that imports A *is*
 173 compiled with -O.  I think this is the case.]
 174
 175
 176 \begin{code}
 177 #include "HsVersions.h"
 178
 179 import IfaceSyn
 180 import IfaceType
 181 import LoadIface
 182 import Id
 183 import IdInfo
 184 import NewDemand
 185 import CoreSyn
 186 import CoreFVs
 187 import Class
 188 import TyCon
 189 import DataCon
 190 import Type
 191 import TcType
 192 import InstEnv
 193 import FamInstEnv
 194 import TcRnMonad
 195 import HscTypes
 196
 197 import DynFlags
 198 import VarEnv
 199 import Var
 200 import Name
 201 import NameEnv
 202 import NameSet
 203 import OccName
 204 import Module
 205 import BinIface
 206 import Unique
 207 import ErrUtils
 208 import Digraph
 209 import SrcLoc
 210 import PackageConfig    hiding ( Version )
 211 import Outputable
 212 import BasicTypes       hiding ( SuccessFlag(..) )
 213 import UniqFM
 214 import Util             hiding ( eqListBy )
 215 import FiniteMap
 216 import FastString
 217 import Maybes
 218
 219 import Control.Monad
 220 import Data.List
 221 \end{code}
 222
 223
 224
 225 %************************************************************************
 226 %*                                                                      *
 227 \subsection{Completing an interface}
 228 %*                                                                      *
 229 %************************************************************************
 230
 231 \begin{code}
 232 mkIface :: HscEnv
 233         -> Maybe ModIface       -- The old interface, if we have it
 234         -> ModGuts              -- Usages, deprecations, etc
 235         -> ModDetails           -- The trimmed, tidied interface
 236         -> IO (ModIface,        -- The new one, complete with decls and versions
 237                Bool)            -- True <=> there was an old Iface, and the new one
 238                                 --          is identical, so no need to write it
 239
 240 mkIface hsc_env maybe_old_iface
 241         (ModGuts{     mg_module    = this_mod,
 242                       mg_boot      = is_boot,
 243                       mg_usages    = usages,
 244                       mg_deps      = deps,
 245                       mg_rdr_env   = rdr_env,
 246                       mg_fix_env   = fix_env,
 247                       mg_deprecs   = src_deprecs,
 248                       mg_hpc_info  = hpc_info })
 249         (ModDetails{  md_insts     = insts,
 250                       md_fam_insts = fam_insts,
 251                       md_rules     = rules,
 252                       md_vect_info = vect_info,
 253                       md_types     = type_env,
 254                       md_exports   = exports })
 255
 256 -- NB:  notice that mkIface does not look at the bindings
 257 --      only at the TypeEnv.  The previous Tidy phase has
 258 --      put exactly the info into the TypeEnv that we want
 259 --      to expose in the interface
 260
 261   = do  { eps <- hscEPS hsc_env
 262         ; let   { entities = typeEnvElts type_env ;
 263                   decls  = [ tyThingToIfaceDecl entity
 264                            | entity <- entities,
 265                              let name = getName entity,
 266                              not (isImplicitTyThing entity),
 267                                 -- No implicit Ids and class tycons in the interface file
 268                              not (isWiredInName name),
 269                                 -- Nor wired-in things; the compiler knows about them anyhow
 270                              nameIsLocalOrFrom this_mod name  ]
 271                                 -- Sigh: see Note [Root-main Id] in TcRnDriver
 272
 273                 ; fixities    = [(occ,fix) | FixItem occ fix _ <- nameEnvElts fix_env]
 274                 ; deprecs     = mkIfaceDeprec src_deprecs
 275                 ; iface_rules = map (coreRuleToIfaceRule this_mod) rules
 276                 ; iface_insts = map instanceToIfaceInst insts
 277                 ; iface_fam_insts = map famInstToIfaceFamInst fam_insts
 278                 ; iface_vect_info = flattenVectInfo vect_info
 279
 280                 ; intermediate_iface = ModIface {
 281                         mi_module   = this_mod,
 282                         mi_boot     = is_boot,
 283                         mi_deps     = deps,
 284                         mi_usages   = usages,
 285                         mi_exports  = mkIfaceExports exports,
 286
 287                         -- Sort these lexicographically, so that
 288                         -- the result is stable across compilations
 289                         mi_insts    = sortLe le_inst iface_insts,
 290                         mi_fam_insts= sortLe le_fam_inst iface_fam_insts,
 291                         mi_rules    = sortLe le_rule iface_rules,
 292
 293                         mi_vect_info = iface_vect_info,
 294
 295                         mi_fixities = fixities,
 296                         mi_deprecs  = deprecs,
 297                         mi_globals  = Just rdr_env,
 298
 299                         -- Left out deliberately: filled in by addVersionInfo
 300                         mi_mod_vers  = initialVersion,
 301                         mi_exp_vers  = initialVersion,
 302                         mi_rule_vers = initialVersion,
 303                         mi_orphan    = False,   -- Always set by addVersionInfo, but
 304                                                 -- it's a strict field, so we can't omit it.
 305                         mi_finsts    = False,   -- Ditto
 306                         mi_decls     = deliberatelyOmitted "decls",
 307                         mi_ver_fn    = deliberatelyOmitted "ver_fn",
 308                         mi_hpc       = isHpcUsed hpc_info,
 309
 310                         -- And build the cached values
 311                         mi_dep_fn = mkIfaceDepCache deprecs,
 312                         mi_fix_fn = mkIfaceFixCache fixities }
 313
 314                 -- Add version information
 315                 ; ext_ver_fn = mkParentVerFun hsc_env eps
 316                 ; (new_iface, no_change_at_all, pp_diffs, pp_orphs)
 317                         = _scc_ "versioninfo"
 318                          addVersionInfo ext_ver_fn maybe_old_iface
 319                                          intermediate_iface decls
 320                 }
 321
 322                 -- Debug printing
 323         ; when (isJust pp_orphs && dopt Opt_WarnOrphans dflags)
 324                (printDump (expectJust "mkIface" pp_orphs))
 325         ; when (dopt Opt_D_dump_hi_diffs dflags) (printDump pp_diffs)
 326         ; dumpIfSet_dyn dflags Opt_D_dump_hi "FINAL INTERFACE"
 327                         (pprModIface new_iface)
 328
 329         ; return (new_iface, no_change_at_all) }
 330   where
 331      r1 `le_rule`     r2 = ifRuleName      r1    <=    ifRuleName      r2
 332      i1 `le_inst`     i2 = ifDFun          i1 `le_occ` ifDFun          i2
 333      i1 `le_fam_inst` i2 = ifFamInstTcName i1 `le_occ` ifFamInstTcName i2
 334
 335      le_occ :: Name -> Name -> Bool
 336         -- Compare lexicographically by OccName, *not* by unique, because
 337         -- the latter is not stable across compilations
 338      le_occ n1 n2 = nameOccName n1 <= nameOccName n2
 339
 340      dflags = hsc_dflags hsc_env
 341      deliberatelyOmitted x = panic ("Deliberately omitted: " ++ x)
 342      ifFamInstTcName = ifaceTyConName . ifFamInstTyCon
 343
 344      flattenVectInfo (VectInfo { vectInfoVar   = vVar
 345                                , vectInfoTyCon = vTyCon
 346                                }) =
 347        IfaceVectInfo {
 348          ifaceVectInfoVar        = [ Var.varName v
 349                                    | (v, _) <- varEnvElts vVar],
 350          ifaceVectInfoTyCon      = [ tyConName t
 351                                    | (t, t_v) <- nameEnvElts vTyCon
 352                                    , t /= t_v],
 353          ifaceVectInfoTyConReuse = [ tyConName t
 354                                    | (t, t_v) <- nameEnvElts vTyCon
 355                                    , t == t_v]
 356        }
 357
 358 -----------------------------
 359 writeIfaceFile :: DynFlags -> ModLocation -> ModIface -> IO ()
 360 writeIfaceFile dflags location new_iface
 361     = do createDirectoryHierarchy (directoryOf hi_file_path)
 362          writeBinIface dflags hi_file_path new_iface
 363     where hi_file_path = ml_hi_file location
 364
 365
 366 -- -----------------------------------------------------------------------------
 367 -- Look up parents and versions of Names
 368
 369 -- This is like a global version of the mi_ver_fn field in each ModIface.
 370 -- Given a Name, it finds the ModIface, and then uses mi_ver_fn to get
 371 -- the parent and version info.
 372
 373 mkParentVerFun
 374         :: HscEnv                       -- needed to look up versions
 375         -> ExternalPackageState         -- ditto
 376         -> (Name -> (OccName,Version))
 377 mkParentVerFun hsc_env eps
 378   = \name ->
 379       let
 380         mod = nameModule name
 381         occ = nameOccName name
 382         iface = lookupIfaceByModule (hsc_dflags hsc_env) hpt pit mod `orElse`
 383                    pprPanic "lookupVers2" (ppr mod <+> ppr occ)
 384       in
 385         mi_ver_fn iface occ `orElse`
 386                  pprPanic "lookupVers1" (ppr mod <+> ppr occ)
 387   where
 388       hpt = hsc_HPT hsc_env
 389       pit = eps_PIT eps
 390
 391 -----------------------------------------------------------------------------
 392 -- Compute version numbers for local decls
 393
 394 addVersionInfo
 395         :: (Name -> (OccName,Version))  -- lookup parents and versions of names
 396         -> Maybe ModIface  -- The old interface, read from M.hi
 397         -> ModIface        -- The new interface (lacking decls)
 398         -> [IfaceDecl]     -- The new decls
 399         -> (ModIface,   -- Updated interface
 400             Bool,          -- True <=> no changes at all; no need to write Iface
 401             SDoc,          -- Differences
 402             Maybe SDoc) -- Warnings about orphans
 403
 404 addVersionInfo ver_fn Nothing new_iface new_decls
 405 -- No old interface, so definitely write a new one!
 406   = (new_iface { mi_orphan = not (null orph_insts && null orph_rules)
 407                , mi_finsts = not . null $ mi_fam_insts new_iface
 408                , mi_decls  = [(initialVersion, decl) | decl <- new_decls]
 409                , mi_ver_fn = mkIfaceVerCache (zip (repeat initialVersion)
 410                                                   new_decls)
 411                },
 412      False,
 413      ptext SLIT("No old interface file"),
 414      pprOrphans orph_insts orph_rules)
 415   where
 416     orph_insts = filter (isNothing . ifInstOrph) (mi_insts new_iface)
 417     orph_rules = filter (isNothing . ifRuleOrph) (mi_rules new_iface)
 418
 419 addVersionInfo ver_fn (Just old_iface@(ModIface {
 420                                            mi_mod_vers  = old_mod_vers,
 421                                            mi_exp_vers  = old_exp_vers,
 422                                            mi_rule_vers = old_rule_vers,
 423                                            mi_decls     = old_decls,
 424                                            mi_ver_fn    = old_decl_vers,
 425                                            mi_fix_fn    = old_fixities }))
 426                new_iface@(ModIface { mi_fix_fn = new_fixities })
 427                new_decls
 428  | no_change_at_all
 429  = (old_iface,  True,   ptext SLIT("Interface file unchanged"), pp_orphs)
 430  | otherwise
 431  = (final_iface, False, vcat [ptext SLIT("Interface file has changed"),
 432                               nest 2 pp_diffs], pp_orphs)
 433  where
 434     final_iface = new_iface {
 435                 mi_mod_vers  = bump_unless no_output_change old_mod_vers,
 436                 mi_exp_vers  = bump_unless no_export_change old_exp_vers,
 437                 mi_rule_vers = bump_unless no_rule_change   old_rule_vers,
 438                 mi_orphan    = not (null new_orph_rules && null new_orph_insts),
 439                 mi_finsts    = not . null $ mi_fam_insts new_iface,
 440                 mi_decls     = decls_w_vers,
 441                 mi_ver_fn    = mkIfaceVerCache decls_w_vers }
 442
 443     decls_w_vers = [(add_vers decl, decl) | decl <- new_decls]
 444
 445     -------------------
 446     (old_non_orph_insts, old_orph_insts) =
 447         mkOrphMap ifInstOrph (mi_insts old_iface)
 448     (new_non_orph_insts, new_orph_insts) =
 449         mkOrphMap ifInstOrph (mi_insts new_iface)
 450     old_fam_insts = mi_fam_insts old_iface
 451     new_fam_insts = mi_fam_insts new_iface
 452     same_insts occ = eqMaybeBy  (eqListBy eqIfInst)
 453                                 (lookupOccEnv old_non_orph_insts occ)
 454                                 (lookupOccEnv new_non_orph_insts occ)
 455
 456     (old_non_orph_rules, old_orph_rules) =
 457         mkOrphMap ifRuleOrph (mi_rules old_iface)
 458     (new_non_orph_rules, new_orph_rules) =
 459         mkOrphMap ifRuleOrph (mi_rules new_iface)
 460     same_rules occ = eqMaybeBy  (eqListBy eqIfRule)
 461                                 (lookupOccEnv old_non_orph_rules occ)
 462                                 (lookupOccEnv new_non_orph_rules occ)
 463     -------------------
 464     -- Computing what changed
 465     no_output_change = no_decl_change   && no_rule_change &&
 466                        no_export_change && no_deprec_change
 467     no_export_change = mi_exports new_iface == mi_exports old_iface
 468                                 -- Kept sorted
 469     no_decl_change   = isEmptyOccSet changed_occs
 470     no_rule_change   = not (changedWrtNames changed_occs (eqListBy eqIfRule old_orph_rules new_orph_rules)
 471                          || changedWrtNames changed_occs (eqListBy eqIfInst old_orph_insts new_orph_insts)
 472                          || changedWrtNames changed_occs (eqListBy eqIfFamInst old_fam_insts new_fam_insts))
 473     no_deprec_change = mi_deprecs new_iface == mi_deprecs old_iface
 474
 475         -- If the usages havn't changed either, we don't need to write the interface file
 476     no_other_changes = mi_usages new_iface == mi_usages old_iface &&
 477                        mi_deps new_iface == mi_deps old_iface &&
 478                        mi_hpc new_iface == mi_hpc old_iface
 479     no_change_at_all = no_output_change && no_other_changes
 480
 481     pp_diffs = vcat [pp_change no_export_change "Export list"
 482                         (ppr old_exp_vers <+> arrow <+> ppr (mi_exp_vers final_iface)),
 483                      pp_change no_rule_change "Rules"
 484                         (ppr old_rule_vers <+> arrow <+> ppr (mi_rule_vers final_iface)),
 485                      pp_change no_deprec_change "Deprecations" empty,
 486                      pp_change no_other_changes  "Usages" empty,
 487                      pp_decl_diffs]
 488     pp_change True  what info = empty
 489     pp_change False what info = text what <+> ptext SLIT("changed") <+> info
 490
 491     -------------------
 492     old_decl_env = mkOccEnv [(ifName decl, decl) | (_,decl) <- old_decls]
 493     same_fixity n = bool (old_fixities n == new_fixities n)
 494
 495     -------------------
 496     -- Adding version info
 497     new_version = bumpVersion old_mod_vers
 498                         -- Start from the old module version, not from
 499                         -- zero so that if you remove f, and then add
 500                         -- it again, you don't thereby reduce f's
 501                         -- version number
 502
 503     add_vers decl | occ `elemOccSet` changed_occs = new_version
 504                   | otherwise = snd (expectJust "add_vers" (old_decl_vers occ))
 505                                 -- If it's unchanged, there jolly well
 506                   where         -- should be an old version number
 507                     occ = ifName decl
 508
 509     -------------------
 510     -- Deciding which declarations have changed
 511
 512     -- For each local decl, the IfaceEq gives the list of things that
 513     -- must be unchanged for the declaration as a whole to be unchanged.
 514     eq_info :: [(OccName, IfaceEq)]
 515     eq_info = map check_eq new_decls
 516     check_eq new_decl
 517          | Just old_decl <- lookupOccEnv old_decl_env occ
 518          = (occ, new_decl `eqIfDecl` old_decl &&& eq_indirects new_decl)
 519          | otherwise {- No corresponding old decl -}
 520          = (occ, NotEqual)
 521         where
 522           occ = ifName new_decl
 523
 524     eq_indirects :: IfaceDecl -> IfaceEq
 525                 -- When seeing if two decls are the same, remember to
 526                 -- check whether any relevant fixity or rules have changed
 527     eq_indirects (IfaceId {ifName = occ}) = eq_ind_occ occ
 528     eq_indirects (IfaceClass {ifName = cls_occ, ifSigs = sigs})
 529         = same_insts cls_occ &&&
 530           eq_ind_occs [op | IfaceClassOp op _ _ <- sigs]
 531     eq_indirects (IfaceData {ifName = tc_occ, ifCons = cons})
 532         = same_insts tc_occ &&& same_fixity tc_occ &&&  -- The TyCon can have a fixity too
 533           eq_ind_occs (map ifConOcc (visibleIfConDecls cons))
 534     eq_indirects other = Equal  -- Synonyms and foreign declarations
 535
 536     eq_ind_occ :: OccName -> IfaceEq    -- For class ops and Ids; check fixity and rules
 537     eq_ind_occ occ = same_fixity occ &&& same_rules occ
 538     eq_ind_occs = foldr ((&&&) . eq_ind_occ) Equal
 539
 540     -- The Occs of declarations that changed.
 541     changed_occs :: OccSet
 542     changed_occs = computeChangedOccs ver_fn (mi_module new_iface)
 543                          (mi_usages old_iface) eq_info
 544
 545     -------------------
 546     -- Diffs
 547     pp_decl_diffs :: SDoc       -- Nothing => no changes
 548     pp_decl_diffs
 549         | isEmptyOccSet changed_occs = empty
 550         | otherwise
 551         = vcat [ptext SLIT("Changed occs:") <+> ppr (occSetElts changed_occs),
 552                 ptext SLIT("Version change for these decls:"),
 553                 nest 2 (vcat (map show_change new_decls))]
 554
 555     eq_env = mkOccEnv eq_info
 556     show_change new_decl
 557         | not (occ `elemOccSet` changed_occs) = empty
 558         | otherwise
 559         = vcat [ppr occ <+> ppr (old_decl_vers occ) <+> arrow <+> ppr new_version,
 560                 nest 2 why]
 561         where
 562           occ = ifName new_decl
 563           why = case lookupOccEnv eq_env occ of
 564                     Just (EqBut names) -> sep [ppr occ <> colon, ptext SLIT("Free vars (only) changed:") <> ppr names,
 565                                               nest 2 (braces (fsep (map ppr (occSetElts
 566                                                 (occs `intersectOccSet` changed_occs)))))]
 567                            where occs = mkOccSet (map nameOccName (nameSetToList names))
 568                     Just NotEqual
 569                         | Just old_decl <- lookupOccEnv old_decl_env occ
 570                         -> vcat [ptext SLIT("Old:") <+> ppr old_decl,
 571                          ptext SLIT("New:") <+> ppr new_decl]
 572                         | otherwise
 573                         -> ppr occ <+> ptext SLIT("only in new interface")
 574                     other -> pprPanic "MkIface.show_change" (ppr occ)
 575
 576     pp_orphs = pprOrphans new_orph_insts new_orph_rules
 577
 578
 579 pprOrphans insts rules
 580   | null insts && null rules = Nothing
 581   | otherwise
 582   = Just $ vcat [
 583         if null insts then empty else
 584              hang (ptext SLIT("Warning: orphan instances:"))
 585                 2 (vcat (map ppr insts)),
 586         if null rules then empty else
 587              hang (ptext SLIT("Warning: orphan rules:"))
 588                 2 (vcat (map ppr rules))
 589     ]
 590
 591 computeChangedOccs
 592         :: (Name -> (OccName,Version))     -- get parents and versions
 593         -> Module                       -- This module
 594         -> [Usage]                      -- Usages from old iface
 595         -> [(OccName, IfaceEq)]         -- decl names, equality conditions
 596         -> OccSet                       -- set of things that have changed
 597 computeChangedOccs ver_fn this_module old_usages eq_info
 598   = foldl add_changes emptyOccSet (stronglyConnComp edges)
 599   where
 600
 601     -- return True if an external name has changed
 602     name_changed :: Name -> Bool
 603     name_changed nm
 604         | Just ents <- lookupUFM usg_modmap (moduleName mod)
 605         = case lookupUFM ents parent_occ of
 606                 Nothing -> pprPanic "computeChangedOccs" (ppr nm)
 607                 Just v  -> v < new_version
 608         | otherwise = False -- must be in another package
 609       where
 610          mod = nameModule nm
 611          (parent_occ, new_version) = ver_fn nm
 612
 613     -- Turn the usages from the old ModIface into a mapping
 614     usg_modmap = listToUFM [ (usg_mod usg, listToUFM (usg_entities usg))
 615                            | usg <- old_usages ]
 616
 617     get_local_eq_info :: GenIfaceEq NameSet -> GenIfaceEq OccSet
 618     get_local_eq_info Equal = Equal
 619     get_local_eq_info NotEqual = NotEqual
 620     get_local_eq_info (EqBut ns) = foldNameSet f Equal ns
 621         where f name eq | nameModule name == this_module =
 622                           EqBut (unitOccSet (nameOccName name)) `and_occifeq` eq
 623                         | name_changed name = NotEqual
 624                         | otherwise = eq
 625
 626     local_eq_infos = mapSnd get_local_eq_info eq_info
 627
 628     edges :: [((OccName, OccIfaceEq), Unique, [Unique])]
 629     edges = [ (node, getUnique occ, map getUnique occs)
 630             | node@(occ, iface_eq) <- local_eq_infos
 631             , let occs = case iface_eq of
 632                            EqBut occ_set -> occSetElts occ_set
 633                            other -> [] ]
 634
 635     -- Changes in declarations
 636     add_changes :: OccSet -> SCC (OccName, OccIfaceEq) -> OccSet
 637     add_changes so_far (AcyclicSCC (occ, iface_eq))
 638         | changedWrt so_far iface_eq -- This one has changed
 639         = extendOccSet so_far occ
 640     add_changes so_far (CyclicSCC pairs)
 641         | changedWrt so_far (foldr1 and_occifeq iface_eqs)
 642                 -- One of this group has changed
 643         = extendOccSetList so_far occs
 644         where (occs, iface_eqs) = unzip pairs
 645     add_changes so_far other = so_far
 646
 647 type OccIfaceEq = GenIfaceEq OccSet
 648
 649 changedWrt :: OccSet -> OccIfaceEq -> Bool
 650 changedWrt so_far Equal        = False
 651 changedWrt so_far NotEqual     = True
 652 changedWrt so_far (EqBut kids) = so_far `intersectsOccSet` kids
 653
 654 changedWrtNames :: OccSet -> IfaceEq -> Bool
 655 changedWrtNames so_far Equal        = False
 656 changedWrtNames so_far NotEqual     = True
 657 changedWrtNames so_far (EqBut kids) =
 658   so_far `intersectsOccSet` mkOccSet (map nameOccName (nameSetToList kids))
 659
 660 and_occifeq :: OccIfaceEq -> OccIfaceEq -> OccIfaceEq
 661 Equal       `and_occifeq` x         = x
 662 NotEqual    `and_occifeq` x         = NotEqual
 663 EqBut nms   `and_occifeq` Equal       = EqBut nms
 664 EqBut nms   `and_occifeq` NotEqual    = NotEqual
 665 EqBut nms1  `and_occifeq` EqBut nms2  = EqBut (nms1 `unionOccSets` nms2)
 666
 667 ----------------------
 668 -- mkOrphMap partitions instance decls or rules into
 669 --      (a) an OccEnv for ones that are not orphans,
 670 --          mapping the local OccName to a list of its decls
 671 --      (b) a list of orphan decls
 672 mkOrphMap :: (decl -> Maybe OccName)    -- (Just occ) for a non-orphan decl, keyed by occ
 673                                         -- Nothing for an orphan decl
 674           -> [decl]                     -- Sorted into canonical order
 675           -> (OccEnv [decl],            -- Non-orphan decls associated with their key;
 676                                         --      each sublist in canonical order
 677               [decl])                   -- Orphan decls; in canonical order
 678 mkOrphMap get_key decls
 679   = foldl go (emptyOccEnv, []) decls
 680   where
 681     go (non_orphs, orphs) d
 682         | Just occ <- get_key d
 683         = (extendOccEnv_C (\ ds _ -> d:ds) non_orphs occ [d], orphs)
 684         | otherwise = (non_orphs, d:orphs)
 685
 686 ----------------------
 687 mkIfaceDeprec :: Deprecations -> IfaceDeprecs
 688 mkIfaceDeprec NoDeprecs        = NoDeprecs
 689 mkIfaceDeprec (DeprecAll t)    = DeprecAll t
 690 mkIfaceDeprec (DeprecSome env) = DeprecSome (sortLe (<=) (nameEnvElts env))
 691
 692 ----------------------
 693 bump_unless :: Bool -> Version -> Version
 694 bump_unless True  v = v -- True <=> no change
 695 bump_unless False v = bumpVersion v
 696 \end{code}
 697
 698
 699 %*********************************************************
 700 %*                                                      *
 701 \subsection{Keeping track of what we've slurped, and version numbers}
 702 %*                                                      *
 703 %*********************************************************
 704
 705
 706 \begin{code}
 707 mkUsageInfo :: HscEnv
 708             -> ModuleEnv (Module, Bool, SrcSpan)
 709             -> [(ModuleName, IsBootInterface)]
 710             -> NameSet -> IO [Usage]
 711 mkUsageInfo hsc_env dir_imp_mods dep_mods used_names
 712   = do  { eps <- hscEPS hsc_env
 713         ; let usages = mk_usage_info (eps_PIT eps) hsc_env
 714                                      dir_imp_mods dep_mods used_names
 715         ; usages `seqList`  return usages }
 716          -- seq the list of Usages returned: occasionally these
 717          -- don't get evaluated for a while and we can end up hanging on to
 718          -- the entire collection of Ifaces.
 719
 720 mk_usage_info pit hsc_env dir_imp_mods dep_mods used_names
 721   = mapCatMaybes mkUsage dep_mods
 722         -- ToDo: do we need to sort into canonical order?
 723   where
 724     hpt = hsc_HPT hsc_env
 725     dflags = hsc_dflags hsc_env
 726
 727     -- ent_map groups together all the things imported and used
 728     -- from a particular module in this package
 729     ent_map :: ModuleEnv [OccName]
 730     ent_map  = foldNameSet add_mv emptyModuleEnv used_names
 731     add_mv name mv_map
 732         | isWiredInName name = mv_map  -- ignore wired-in names
 733         | otherwise
 734         = case nameModule_maybe name of
 735              Nothing  -> mv_map         -- ignore internal names
 736              Just mod -> extendModuleEnv_C add_item mv_map mod [occ]
 737                    where
 738                      occ = nameOccName name
 739                      add_item occs _ = occ:occs
 740
 741     depend_on_exports mod = case lookupModuleEnv dir_imp_mods mod of
 742                                 Just (_,no_imp,_) -> not no_imp
 743                                 Nothing           -> True
 744
 745     -- We want to create a Usage for a home module if
 746     --  a) we used something from; has something in used_names
 747     --  b) we imported all of it, even if we used nothing from it
 748     --          (need to recompile if its export list changes: export_vers)
 749     --  c) is a home-package orphan or family-instance module (need to
 750     --          recompile if its instance decls change: rules_vers)
 751     mkUsage :: (ModuleName, IsBootInterface) -> Maybe Usage
 752     mkUsage (mod_name, _)
 753       |  isNothing maybe_iface          -- We can't depend on it if we didn't
 754       || (null used_occs                -- load its interface.
 755           && isNothing export_vers
 756           && not orphan_mod
 757           && not finsts_mod)
 758       = Nothing                 -- Record no usage info
 759
 760       | otherwise
 761       = Just (Usage { usg_name     = mod_name,
 762                       usg_mod      = mod_vers,
 763                       usg_exports  = export_vers,
 764                       usg_entities = fmToList ent_vers,
 765                       usg_rules    = rules_vers })
 766       where
 767         maybe_iface  = lookupIfaceByModule dflags hpt pit mod
 768                 -- In one-shot mode, the interfaces for home-package
 769                 -- modules accumulate in the PIT not HPT.  Sigh.
 770
 771         mod = mkModule (thisPackage dflags) mod_name
 772
 773         Just iface   = maybe_iface
 774         orphan_mod   = mi_orphan    iface
 775         finsts_mod   = mi_finsts    iface
 776         version_env  = mi_ver_fn    iface
 777         mod_vers     = mi_mod_vers  iface
 778         rules_vers   = mi_rule_vers iface
 779         export_vers | depend_on_exports mod = Just (mi_exp_vers iface)
 780                     | otherwise             = Nothing
 781
 782         used_occs = lookupModuleEnv ent_map mod `orElse` []
 783
 784         -- Making a FiniteMap here ensures that (a) we remove duplicates
 785         -- when we have usages on several subordinates of a single parent,
 786         -- and (b) that the usages emerge in a canonical order, which
 787         -- is why we use FiniteMap rather than OccEnv: FiniteMap works
 788         -- using Ord on the OccNames, which is a lexicographic ordering.
 789         ent_vers :: FiniteMap OccName Version
 790         ent_vers = listToFM (map lookup_occ used_occs)
 791
 792         lookup_occ occ =
 793             case version_env occ of
 794                 Nothing -> pprTrace "hmm, strange" (ppr mod <+> ppr occ) $
 795                            (occ, initialVersion) -- does this ever happen?
 796                 Just (parent, version) -> (parent, version)
 797 \end{code}
 798
 799 \begin{code}
 800 mkIfaceExports :: [AvailInfo]
 801                -> [(Module, [GenAvailInfo OccName])]
 802   -- Group by module and sort by occurrence
 803   -- This keeps the list in canonical order
 804 mkIfaceExports exports
 805   = [ (mod, eltsFM avails)
 806     | (mod, avails) <- fmToList groupFM
 807     ]
 808   where
 809         -- Group by the module where the exported entities are defined
 810         -- (which may not be the same for all Names in an Avail)
 811         -- Deliberately use FiniteMap rather than UniqFM so we
 812         -- get a canonical ordering
 813     groupFM :: ModuleEnv (FiniteMap FastString (GenAvailInfo OccName))
 814     groupFM = foldl add emptyModuleEnv exports
 815
 816     add_one :: ModuleEnv (FiniteMap FastString (GenAvailInfo OccName))
 817             -> Module -> GenAvailInfo OccName
 818             -> ModuleEnv (FiniteMap FastString (GenAvailInfo OccName))
 819     add_one env mod avail
 820       =  extendModuleEnv_C plusFM env mod
 821                 (unitFM (occNameFS (availName avail)) avail)
 822
 823         -- NB: we should not get T(X) and T(Y) in the export list
 824         --     else the plusFM will simply discard one!  They
 825         --     should have been combined by now.
 826     add env (Avail n)
 827       = add_one env (nameModule n) (Avail (nameOccName n))
 828
 829     add env (AvailTC tc ns)
 830       = foldl add_for_mod env mods
 831       where
 832         tc_occ = nameOccName tc
 833         mods   = nub (map nameModule ns)
 834                 -- Usually just one, but see Note [Original module]
 835
 836         add_for_mod env mod
 837             = add_one env mod (AvailTC tc_occ names_from_mod)
 838             where
 839               names_from_mod = [nameOccName n | n <- ns, nameModule n == mod]
 840 \end{code}
 841
 842 Note [Orignal module]
 843 ~~~~~~~~~~~~~~~~~~~~~
 844 Consider this:
 845         module X where { data family T }
 846         module Y( T(..) ) where { import X; data instance T Int = MkT Int }
 847 The exported Avail from Y will look like
 848         X.T{X.T, Y.MkT}
 849 That is, in Y,
 850   - only MkT is brought into scope by the data instance;
 851   - but the parent (used for grouping and naming in T(..) exports) is X.T
 852   - and in this case we export X.T too
 853
 854 In the result of MkIfaceExports, the names are grouped by defining module,
 855 so we may need to split up a single Avail into multiple ones.
 856
 857
 858 %************************************************************************
 859 %*                                                                      *
 860         Load the old interface file for this module (unless
 861         we have it aleady), and check whether it is up to date
 862
 863 %*                                                                      *
 864 %************************************************************************
 865
 866 \begin{code}
 867 checkOldIface :: HscEnv
 868               -> ModSummary
 869               -> Bool                   -- Source unchanged
 870               -> Maybe ModIface         -- Old interface from compilation manager, if any
 871               -> IO (RecompileRequired, Maybe ModIface)
 872
 873 checkOldIface hsc_env mod_summary source_unchanged maybe_iface
 874   = do  { showPass (hsc_dflags hsc_env)
 875                    ("Checking old interface for " ++
 876                         showSDoc (ppr (ms_mod mod_summary))) ;
 877
 878         ; initIfaceCheck hsc_env $
 879           check_old_iface hsc_env mod_summary source_unchanged maybe_iface
 880      }
 881
 882 check_old_iface hsc_env mod_summary source_unchanged maybe_iface
 883  =  do  -- CHECK WHETHER THE SOURCE HAS CHANGED
 884     { ifM (not source_unchanged)
 885            (traceHiDiffs (nest 4 (text "Source file changed or recompilation check turned off")))
 886
 887      -- If the source has changed and we're in interactive mode, avoid reading
 888      -- an interface; just return the one we might have been supplied with.
 889     ; let dflags = hsc_dflags hsc_env
 890     ; if not (isObjectTarget (hscTarget dflags)) && not source_unchanged then
 891          return (outOfDate, maybe_iface)
 892       else
 893       case maybe_iface of {
 894         Just old_iface -> do -- Use the one we already have
 895           { traceIf (text "We already have the old interface for" <+> ppr (ms_mod mod_summary))
 896           ; recomp <- checkVersions hsc_env source_unchanged old_iface
 897           ; return (recomp, Just old_iface) }
 898
 899       ; Nothing -> do
 900
 901         -- Try and read the old interface for the current module
 902         -- from the .hi file left from the last time we compiled it
 903     { let iface_path = msHiFilePath mod_summary
 904     ; read_result <- readIface (ms_mod mod_summary) iface_path False
 905     ; case read_result of {
 906          Failed err -> do       -- Old interface file not found, or garbled; give up
 907                 { traceIf (text "FYI: cannot read old interface file:"
 908                                  $$ nest 4 err)
 909                 ; return (outOfDate, Nothing) }
 910
 911       ;  Succeeded iface -> do
 912
 913         -- We have got the old iface; check its versions
 914     { traceIf (text "Read the interface file" <+> text iface_path)
 915     ; recomp <- checkVersions hsc_env source_unchanged iface
 916     ; returnM (recomp, Just iface)
 917     }}}}}
 918 \end{code}
 919
 920 @recompileRequired@ is called from the HscMain.   It checks whether
 921 a recompilation is required.  It needs access to the persistent state,
 922 finder, etc, because it may have to load lots of interface files to
 923 check their versions.
 924
 925 \begin{code}
 926 type RecompileRequired = Bool
 927 upToDate  = False       -- Recompile not required
 928 outOfDate = True        -- Recompile required
 929
 930 checkVersions :: HscEnv
 931               -> Bool           -- True <=> source unchanged
 932               -> ModIface       -- Old interface
 933               -> IfG RecompileRequired
 934 checkVersions hsc_env source_unchanged iface
 935   | not source_unchanged
 936   = returnM outOfDate
 937   | otherwise
 938   = do  { traceHiDiffs (text "Considering whether compilation is required for" <+>
 939                         ppr (mi_module iface) <> colon)
 940
 941         -- Source code unchanged and no errors yet... carry on
 942
 943         -- First put the dependent-module info, read from the old interface, into the envt,
 944         -- so that when we look for interfaces we look for the right one (.hi or .hi-boot)
 945         --
 946         -- It's just temporary because either the usage check will succeed
 947         -- (in which case we are done with this module) or it'll fail (in which
 948         -- case we'll compile the module from scratch anyhow).
 949         --
 950         -- We do this regardless of compilation mode, although in --make mode
 951         -- all the dependent modules should be in the HPT already, so it's
 952         -- quite redundant
 953         ; updateEps_ $ \eps  -> eps { eps_is_boot = mod_deps }
 954
 955         ; let this_pkg = thisPackage (hsc_dflags hsc_env)
 956         ; checkList [checkModUsage this_pkg u | u <- mi_usages iface]
 957     }
 958   where
 959         -- This is a bit of a hack really
 960     mod_deps :: ModuleNameEnv (ModuleName, IsBootInterface)
 961     mod_deps = mkModDeps (dep_mods (mi_deps iface))
 962
 963 checkModUsage :: PackageId ->Usage -> IfG RecompileRequired
 964 -- Given the usage information extracted from the old
 965 -- M.hi file for the module being compiled, figure out
 966 -- whether M needs to be recompiled.
 967
 968 checkModUsage this_pkg (Usage { usg_name = mod_name, usg_mod = old_mod_vers,
 969                                 usg_rules = old_rule_vers,
 970                                 usg_exports = maybe_old_export_vers,
 971                                 usg_entities = old_decl_vers })
 972   =     -- Load the imported interface is possible
 973     let
 974         doc_str = sep [ptext SLIT("need version info for"), ppr mod_name]
 975     in
 976     traceHiDiffs (text "Checking usages for module" <+> ppr mod_name) `thenM_`
 977
 978     let
 979         mod = mkModule this_pkg mod_name
 980     in
 981     loadInterface doc_str mod ImportBySystem            `thenM` \ mb_iface ->
 982         -- Load the interface, but don't complain on failure;
 983         -- Instead, get an Either back which we can test
 984
 985     case mb_iface of {
 986         Failed exn ->  (out_of_date (sep [ptext SLIT("Can't find version number for module"),
 987                                        ppr mod_name]));
 988                 -- Couldn't find or parse a module mentioned in the
 989                 -- old interface file.  Don't complain -- it might just be that
 990                 -- the current module doesn't need that import and it's been deleted
 991
 992         Succeeded iface ->
 993     let
 994         new_mod_vers    = mi_mod_vers  iface
 995         new_decl_vers   = mi_ver_fn    iface
 996         new_export_vers = mi_exp_vers  iface
 997         new_rule_vers   = mi_rule_vers iface
 998     in
 999         -- CHECK MODULE
1000     checkModuleVersion old_mod_vers new_mod_vers        `thenM` \ recompile ->
1001     if not recompile then
1002         returnM upToDate
1003     else
1004
1005         -- CHECK EXPORT LIST
1006     if checkExportList maybe_old_export_vers new_export_vers then
1007         out_of_date_vers (ptext SLIT("  Export list changed"))
1008                          (expectJust "checkModUsage" maybe_old_export_vers)
1009                          new_export_vers
1010     else
1011
1012         -- CHECK RULES
1013     if old_rule_vers /= new_rule_vers then
1014         out_of_date_vers (ptext SLIT("  Rules changed"))
1015                          old_rule_vers new_rule_vers
1016     else
1017
1018         -- CHECK ITEMS ONE BY ONE
1019     checkList [checkEntityUsage new_decl_vers u | u <- old_decl_vers]   `thenM` \ recompile ->
1020     if recompile then
1021         returnM outOfDate       -- This one failed, so just bail out now
1022     else
1023         up_to_date (ptext SLIT("  Great!  The bits I use are up to date"))
1024     }
1025
1026 ------------------------
1027 checkModuleVersion old_mod_vers new_mod_vers
1028   | new_mod_vers == old_mod_vers
1029   = up_to_date (ptext SLIT("Module version unchanged"))
1030
1031   | otherwise
1032   = out_of_date_vers (ptext SLIT("  Module version has changed"))
1033                      old_mod_vers new_mod_vers
1034
1035 ------------------------
1036 checkExportList Nothing  new_vers = upToDate
1037 checkExportList (Just v) new_vers = v /= new_vers
1038
1039 ------------------------
1040 checkEntityUsage new_vers (name,old_vers)
1041   = case new_vers name of
1042
1043         Nothing       ->        -- We used it before, but it ain't there now
1044                           out_of_date (sep [ptext SLIT("No longer exported:"), ppr name])
1045
1046         Just (_, new_vers)      -- It's there, but is it up to date?
1047           | new_vers == old_vers -> traceHiDiffs (text "  Up to date" <+> ppr name <+> parens (ppr new_vers)) `thenM_`
1048                                     returnM upToDate
1049           | otherwise            -> out_of_date_vers (ptext SLIT("  Out of date:") <+> ppr name)
1050                                                      old_vers new_vers
1051
1052 up_to_date  msg = traceHiDiffs msg `thenM_` returnM upToDate
1053 out_of_date msg = traceHiDiffs msg `thenM_` returnM outOfDate
1054 out_of_date_vers msg old_vers new_vers
1055   = out_of_date (hsep [msg, ppr old_vers, ptext SLIT("->"), ppr new_vers])
1056
1057 ----------------------
1058 checkList :: [IfG RecompileRequired] -> IfG RecompileRequired
1059 -- This helper is used in two places
1060 checkList []             = returnM upToDate
1061 checkList (check:checks) = check        `thenM` \ recompile ->
1062                            if recompile then
1063                                 returnM outOfDate
1064                            else
1065                                 checkList checks
1066 \end{code}
1067
1068 %************************************************************************
1069 %*                                                                      *
1070                 Converting things to their Iface equivalents
1071 %*                                                                      *
1072 %************************************************************************
1073
1074 \begin{code}
1075 tyThingToIfaceDecl :: TyThing -> IfaceDecl
1076 -- Assumption: the thing is already tidied, so that locally-bound names
1077 --             (lambdas, for-alls) already have non-clashing OccNames
1078 -- Reason: Iface stuff uses OccNames, and the conversion here does
1079 --         not do tidying on the way
1080 tyThingToIfaceDecl (AnId id)
1081   = IfaceId { ifName   = getOccName id,
1082               ifType   = toIfaceType (idType id),
1083               ifIdInfo = info }
1084   where
1085     info = case toIfaceIdInfo (idInfo id) of
1086                 []    -> NoInfo
1087                 items -> HasInfo items
1088
1089 tyThingToIfaceDecl (AClass clas)
1090   = IfaceClass { ifCtxt   = toIfaceContext sc_theta,
1091                  ifName   = getOccName clas,
1092                  ifTyVars = toIfaceTvBndrs clas_tyvars,
1093                  ifFDs    = map toIfaceFD clas_fds,
1094                  ifATs    = map (tyThingToIfaceDecl . ATyCon) clas_ats,
1095                  ifSigs   = map toIfaceClassOp op_stuff,
1096                  ifRec    = boolToRecFlag (isRecursiveTyCon tycon) }
1097   where
1098     (clas_tyvars, clas_fds, sc_theta, _, clas_ats, op_stuff)
1099       = classExtraBigSig clas
1100     tycon = classTyCon clas
1101
1102     toIfaceClassOp (sel_id, def_meth)
1103         = ASSERT(sel_tyvars == clas_tyvars)
1104           IfaceClassOp (getOccName sel_id) def_meth (toIfaceType op_ty)
1105         where
1106                 -- Be careful when splitting the type, because of things
1107                 -- like         class Foo a where
1108                 --                op :: (?x :: String) => a -> a
1109                 -- and          class Baz a where
1110                 --                op :: (Ord a) => a -> a
1111           (sel_tyvars, rho_ty) = splitForAllTys (idType sel_id)
1112           op_ty                = funResultTy rho_ty
1113
1114     toIfaceFD (tvs1, tvs2) = (map getFS tvs1, map getFS tvs2)
1115
1116 tyThingToIfaceDecl (ATyCon tycon)
1117   | isSynTyCon tycon
1118   = IfaceSyn {  ifName    = getOccName tycon,
1119                 ifTyVars  = toIfaceTvBndrs tyvars,
1120                 ifOpenSyn = syn_isOpen,
1121                 ifSynRhs  = toIfaceType syn_tyki,
1122                 ifFamInst = famInstToIface (tyConFamInst_maybe tycon)
1123              }
1124
1125   | isAlgTyCon tycon
1126   = IfaceData { ifName    = getOccName tycon,
1127                 ifTyVars  = toIfaceTvBndrs tyvars,
1128                 ifCtxt    = toIfaceContext (tyConStupidTheta tycon),
1129                 ifCons    = ifaceConDecls (algTyConRhs tycon),
1130                 ifRec     = boolToRecFlag (isRecursiveTyCon tycon),
1131                 ifGadtSyntax = isGadtSyntaxTyCon tycon,
1132                 ifGeneric = tyConHasGenerics tycon,
1133                 ifFamInst = famInstToIface (tyConFamInst_maybe tycon)}
1134
1135   | isForeignTyCon tycon
1136   = IfaceForeign { ifName    = getOccName tycon,
1137                    ifExtName = tyConExtName tycon }
1138
1139   | otherwise = pprPanic "toIfaceDecl" (ppr tycon)
1140   where
1141     tyvars = tyConTyVars tycon
1142     (syn_isOpen, syn_tyki) = case synTyConRhs tycon of
1143                                OpenSynTyCon ki _ -> (True , ki)
1144                                SynonymTyCon ty   -> (False, ty)
1145
1146     ifaceConDecls (NewTyCon { data_con = con })     =
1147       IfNewTyCon  (ifaceConDecl con)
1148     ifaceConDecls (DataTyCon { data_cons = cons })  =
1149       IfDataTyCon (map ifaceConDecl cons)
1150     ifaceConDecls OpenTyCon {}                      = IfOpenDataTyCon
1151     ifaceConDecls AbstractTyCon                     = IfAbstractTyCon
1152         -- The last case happens when a TyCon has been trimmed during tidying
1153         -- Furthermore, tyThingToIfaceDecl is also used
1154         -- in TcRnDriver for GHCi, when browsing a module, in which case the
1155         -- AbstractTyCon case is perfectly sensible.
1156
1157     ifaceConDecl data_con
1158         = IfCon   { ifConOcc     = getOccName (dataConName data_con),
1159                     ifConInfix   = dataConIsInfix data_con,
1160                     ifConUnivTvs = toIfaceTvBndrs (dataConUnivTyVars data_con),
1161                     ifConExTvs   = toIfaceTvBndrs (dataConExTyVars data_con),
1162                     ifConEqSpec  = to_eq_spec (dataConEqSpec data_con),
1163                     ifConCtxt    = toIfaceContext (dataConTheta data_con),
1164                     ifConArgTys  = map toIfaceType (dataConOrigArgTys data_con),
1165                     ifConFields  = map getOccName
1166                                        (dataConFieldLabels data_con),
1167                     ifConStricts = dataConStrictMarks data_con }
1168
1169     to_eq_spec spec = [(getOccName tv, toIfaceType ty) | (tv,ty) <- spec]
1170
1171     famInstToIface Nothing                    = Nothing
1172     famInstToIface (Just (famTyCon, instTys)) =
1173       Just (toIfaceTyCon famTyCon, map toIfaceType instTys)
1174
1175 tyThingToIfaceDecl (ADataCon dc)
1176  = pprPanic "toIfaceDecl" (ppr dc)      -- Should be trimmed out earlier
1177
1178
1179 getFS x = occNameFS (getOccName x)
1180
1181 --------------------------
1182 instanceToIfaceInst :: Instance -> IfaceInst
1183 instanceToIfaceInst ispec@(Instance { is_dfun = dfun_id, is_flag = oflag,
1184                                       is_cls = cls_name, is_tcs = mb_tcs })
1185   = ASSERT( cls_name == className cls )
1186     IfaceInst { ifDFun    = dfun_name,
1187                 ifOFlag   = oflag,
1188                 ifInstCls = cls_name,
1189                 ifInstTys = map do_rough mb_tcs,
1190                 ifInstOrph = orph }
1191   where
1192     do_rough Nothing  = Nothing
1193     do_rough (Just n) = Just (toIfaceTyCon_name n)
1194
1195     dfun_name = idName dfun_id
1196     mod       = nameModule dfun_name
1197     is_local name = nameIsLocalOrFrom mod name
1198
1199         -- Compute orphanhood.  See Note [Orphans] in IfaceSyn
1200     (_, _, cls, tys) = tcSplitDFunTy (idType dfun_id)
1201                 -- Slightly awkward: we need the Class to get the fundeps
1202     (tvs, fds) = classTvsFds cls
1203     arg_names = [filterNameSet is_local (tyClsNamesOfType ty) | ty <- tys]
1204     orph | is_local cls_name = Just (nameOccName cls_name)
1205          | all isJust mb_ns  = head mb_ns
1206          | otherwise         = Nothing
1207
1208     mb_ns :: [Maybe OccName]    -- One for each fundep; a locally-defined name
1209                                 -- that is not in the "determined" arguments
1210     mb_ns | null fds   = [choose_one arg_names]
1211           | otherwise  = map do_one fds
1212     do_one (ltvs,rtvs) = choose_one [ns | (tv,ns) <- tvs `zip` arg_names
1213                                         , not (tv `elem` rtvs)]
1214
1215     choose_one :: [NameSet] -> Maybe OccName
1216     choose_one nss = case nameSetToList (unionManyNameSets nss) of
1217                         []     -> Nothing
1218                         (n:ns) -> Just (nameOccName n)
1219
1220 --------------------------
1221 famInstToIfaceFamInst :: FamInst -> IfaceFamInst
1222 famInstToIfaceFamInst fi@(FamInst { fi_tycon = tycon,
1223                                             fi_fam = fam, fi_tcs = mb_tcs })
1224   = IfaceFamInst { ifFamInstTyCon  = toIfaceTyCon tycon
1225                  , ifFamInstFam    = fam
1226                  , ifFamInstTys    = map do_rough mb_tcs }
1227   where
1228     do_rough Nothing  = Nothing
1229     do_rough (Just n) = Just (toIfaceTyCon_name n)
1230
1231 --------------------------
1232 toIfaceLetBndr id  = IfLetBndr (occNameFS (getOccName id))
1233                                (toIfaceType (idType id))
1234                                prag_info
1235   where
1236         -- Stripped-down version of tcIfaceIdInfo
1237         -- Change this if you want to export more IdInfo for
1238         -- non-top-level Ids.  Don't forget to change
1239         -- CoreTidy.tidyLetBndr too!
1240         --
1241         -- See Note [IdInfo on nested let-bindings] in IfaceSyn
1242     id_info = idInfo id
1243     inline_prag = inlinePragInfo id_info
1244     prag_info | isAlwaysActive inline_prag = NoInfo
1245               | otherwise                  = HasInfo [HsInline inline_prag]
1246
1247 --------------------------
1248 toIfaceIdInfo :: IdInfo -> [IfaceInfoItem]
1249 toIfaceIdInfo id_info
1250   = catMaybes [arity_hsinfo, caf_hsinfo, strict_hsinfo,
1251                inline_hsinfo, wrkr_hsinfo,  unfold_hsinfo]
1252   where
1253     ------------  Arity  --------------
1254     arity_info = arityInfo id_info
1255     arity_hsinfo | arity_info == 0 = Nothing
1256                  | otherwise       = Just (HsArity arity_info)
1257
1258     ------------ Caf Info --------------
1259     caf_info   = cafInfo id_info
1260     caf_hsinfo = case caf_info of
1261                    NoCafRefs -> Just HsNoCafRefs
1262                    _other    -> Nothing
1263
1264     ------------  Strictness  --------------
1265         -- No point in explicitly exporting TopSig
1266     strict_hsinfo = case newStrictnessInfo id_info of
1267                         Just sig | not (isTopSig sig) -> Just (HsStrictness sig)
1268                         _other                        -> Nothing
1269
1270     ------------  Worker  --------------
1271     work_info   = workerInfo id_info
1272     has_worker  = case work_info of { HasWorker _ _ -> True; other -> False }
1273     wrkr_hsinfo = case work_info of
1274                     HasWorker work_id wrap_arity ->
1275                         Just (HsWorker ((idName work_id)) wrap_arity)
1276                     NoWorker -> Nothing
1277
1278     ------------  Unfolding  --------------
1279     -- The unfolding is redundant if there is a worker
1280     unfold_info  = unfoldingInfo id_info
1281     rhs          = unfoldingTemplate unfold_info
1282     no_unfolding = neverUnfold unfold_info
1283                         -- The CoreTidy phase retains unfolding info iff
1284                         -- we want to expose the unfolding, taking into account
1285                         -- unconditional NOINLINE, etc.  See TidyPgm.addExternal
1286     unfold_hsinfo | no_unfolding = Nothing
1287                   | has_worker   = Nothing      -- Unfolding is implicit
1288                   | otherwise    = Just (HsUnfold (toIfaceExpr rhs))
1289
1290     ------------  Inline prag  --------------
1291     inline_prag = inlinePragInfo id_info
1292     inline_hsinfo | isAlwaysActive inline_prag     = Nothing
1293                   | no_unfolding && not has_worker = Nothing
1294                         -- If the iface file give no unfolding info, we
1295                         -- don't need to say when inlining is OK!
1296                   | otherwise                      = Just (HsInline inline_prag)
1297
1298 --------------------------
1299 coreRuleToIfaceRule :: Module -> CoreRule -> IfaceRule
1300 coreRuleToIfaceRule mod (BuiltinRule { ru_fn = fn})
1301   = pprTrace "toHsRule: builtin" (ppr fn) $
1302     bogusIfaceRule fn
1303
1304 coreRuleToIfaceRule mod (Rule { ru_name = name, ru_fn = fn,
1305                                 ru_act = act, ru_bndrs = bndrs,
1306                                 ru_args = args, ru_rhs = rhs })
1307   = IfaceRule { ifRuleName  = name, ifActivation = act,
1308                 ifRuleBndrs = map toIfaceBndr bndrs,
1309                 ifRuleHead  = fn,
1310                 ifRuleArgs  = map do_arg args,
1311                 ifRuleRhs   = toIfaceExpr rhs,
1312                 ifRuleOrph  = orph }
1313   where
1314         -- For type args we must remove synonyms from the outermost
1315         -- level.  Reason: so that when we read it back in we'll
1316         -- construct the same ru_rough field as we have right now;
1317         -- see tcIfaceRule
1318     do_arg (Type ty) = IfaceType (toIfaceType (deNoteType ty))
1319     do_arg arg       = toIfaceExpr arg
1320
1321         -- Compute orphanhood.  See Note [Orphans] in IfaceSyn
1322         -- A rule is an orphan only if none of the variables
1323         -- mentioned on its left-hand side are locally defined
1324     lhs_names = fn : nameSetToList (exprsFreeNames args)
1325                 -- No need to delete bndrs, because
1326                 -- exprsFreeNames finds only External names
1327
1328     orph = case filter (nameIsLocalOrFrom mod) lhs_names of
1329                         (n:ns) -> Just (nameOccName n)
1330                         []     -> Nothing
1331
1332 bogusIfaceRule :: Name -> IfaceRule
1333 bogusIfaceRule id_name
1334   = IfaceRule { ifRuleName = FSLIT("bogus"), ifActivation = NeverActive,
1335         ifRuleBndrs = [], ifRuleHead = id_name, ifRuleArgs = [],
1336         ifRuleRhs = IfaceExt id_name, ifRuleOrph = Nothing }
1337
1338 ---------------------
1339 toIfaceExpr :: CoreExpr -> IfaceExpr
1340 toIfaceExpr (Var v)       = toIfaceVar v
1341 toIfaceExpr (Lit l)       = IfaceLit l
1342 toIfaceExpr (Type ty)     = IfaceType (toIfaceType ty)
1343 toIfaceExpr (Lam x b)     = IfaceLam (toIfaceBndr x) (toIfaceExpr b)
1344 toIfaceExpr (App f a)     = toIfaceApp f [a]
1345 toIfaceExpr (Case s x ty as) = IfaceCase (toIfaceExpr s) (getFS x) (toIfaceType ty) (map toIfaceAlt as)
1346 toIfaceExpr (Let b e)     = IfaceLet (toIfaceBind b) (toIfaceExpr e)
1347 toIfaceExpr (Cast e co)   = IfaceCast (toIfaceExpr e) (toIfaceType co)
1348 toIfaceExpr (Note n e)    = IfaceNote (toIfaceNote n) (toIfaceExpr e)
1349
1350 ---------------------
1351 toIfaceNote (SCC cc)      = IfaceSCC cc
1352 toIfaceNote InlineMe      = IfaceInlineMe
1353 toIfaceNote (CoreNote s)  = IfaceCoreNote s
1354
1355 ---------------------
1356 toIfaceBind (NonRec b r) = IfaceNonRec (toIfaceLetBndr b) (toIfaceExpr r)
1357 toIfaceBind (Rec prs)    = IfaceRec [(toIfaceLetBndr b, toIfaceExpr r) | (b,r) <- prs]
1358
1359 ---------------------
1360 toIfaceAlt (c,bs,r) = (toIfaceCon c, map getFS bs, toIfaceExpr r)
1361
1362 ---------------------
1363 toIfaceCon (DataAlt dc) | isTupleTyCon tc = IfaceTupleAlt (tupleTyConBoxity tc)
1364                         | otherwise       = IfaceDataAlt (getName dc)
1365                         where
1366                           tc = dataConTyCon dc
1367
1368 toIfaceCon (LitAlt l) = IfaceLitAlt l
1369 toIfaceCon DEFAULT    = IfaceDefault
1370
1371 ---------------------
1372 toIfaceApp (App f a) as = toIfaceApp f (a:as)
1373 toIfaceApp (Var v) as
1374   = case isDataConWorkId_maybe v of
1375         -- We convert the *worker* for tuples into IfaceTuples
1376         Just dc |  isTupleTyCon tc && saturated
1377                 -> IfaceTuple (tupleTyConBoxity tc) tup_args
1378           where
1379             val_args  = dropWhile isTypeArg as
1380             saturated = val_args `lengthIs` idArity v
1381             tup_args  = map toIfaceExpr val_args
1382             tc        = dataConTyCon dc
1383
1384         other -> mkIfaceApps (toIfaceVar v) as
1385
1386 toIfaceApp e as = mkIfaceApps (toIfaceExpr e) as
1387
1388 mkIfaceApps f as = foldl (\f a -> IfaceApp f (toIfaceExpr a)) f as
1389
1390 ---------------------
1391 toIfaceVar :: Id -> IfaceExpr
1392 toIfaceVar v
1393   | Just fcall <- isFCallId_maybe v = IfaceFCall fcall (toIfaceType (idType v))
1394           -- Foreign calls have special syntax
1395   | isExternalName name             = IfaceExt name
1396   | Just (TickBox m ix) <- isTickBoxOp_maybe v
1397                                     = IfaceTick m ix
1398   | otherwise                       = IfaceLcl (getFS name)
1399   where
1400     name = idName v
1401 \end{code}