compiler/iface/TcIface.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcIfaceSig]{Type checking of type signatures in interface files}
   5
   6 \begin{code}
   7 module TcIface (
   8         tcImportDecl, checkWiredInTyCon, tcHiBootIface, typecheckIface,
   9         tcIfaceDecl, tcIfaceInst, tcIfaceRule, tcIfaceGlobal,
  10         tcExtCoreBindings
  11  ) where
  12
  13 #include "HsVersions.h"
  14
  15 import IfaceSyn
  16 import LoadIface        ( loadInterface, loadWiredInHomeIface,
  17                           loadDecls, findAndReadIface )
  18 import IfaceEnv         ( lookupIfaceTop, lookupIfaceExt, newGlobalBinder,
  19                           extendIfaceIdEnv, extendIfaceTyVarEnv, newIPName,
  20                           tcIfaceTyVar, tcIfaceLclId, lookupIfaceTc, refineIfaceIdEnv,
  21                           newIfaceName, newIfaceNames, ifaceExportNames )
  22 import BuildTyCl        ( buildSynTyCon, buildAlgTyCon, buildDataCon, buildClass,
  23                           mkAbstractTyConRhs, mkDataTyConRhs, mkNewTyConRhs )
  24 import TcRnMonad
  25 import Type             ( liftedTypeKind, splitTyConApp, mkTyConApp,
  26                           mkTyVarTys, ThetaType )
  27 import TypeRep          ( Type(..), PredType(..) )
  28 import TyCon            ( TyCon, tyConName )
  29 import HscTypes         ( ExternalPackageState(..),
  30                           TyThing(..), tyThingClass, tyThingTyCon,
  31                           ModIface(..), ModDetails(..), HomeModInfo(..),
  32                           emptyModDetails, lookupTypeEnv, lookupType, typeEnvIds )
  33 import InstEnv          ( Instance(..), mkImportedInstance )
  34 import Unify            ( coreRefineTys )
  35 import CoreSyn
  36 import CoreUtils        ( exprType )
  37 import CoreUnfold
  38 import CoreLint         ( lintUnfolding )
  39 import WorkWrap         ( mkWrapper )
  40 import Id               ( Id, mkVanillaGlobal, mkLocalId )
  41 import MkId             ( mkFCallId )
  42 import IdInfo           ( IdInfo, CafInfo(..), WorkerInfo(..),
  43                           setUnfoldingInfoLazily, setAllStrictnessInfo, setWorkerInfo,
  44                           setArityInfo, setInlinePragInfo, setCafInfo,
  45                           vanillaIdInfo, newStrictnessInfo )
  46 import Class            ( Class )
  47 import TyCon            ( tyConDataCons, isTupleTyCon, mkForeignTyCon )
  48 import DataCon          ( DataCon, dataConWorkId, dataConTyVars, dataConInstArgTys, isVanillaDataCon )
  49 import TysWiredIn       ( tupleCon, tupleTyCon, listTyCon, intTyCon, boolTyCon, charTyCon, parrTyCon )
  50 import Var              ( TyVar, mkTyVar, tyVarKind )
  51 import Name             ( Name, nameModule, nameIsLocalOrFrom, isWiredInName,
  52                           wiredInNameTyThing_maybe, nameParent )
  53 import NameEnv
  54 import OccName          ( OccName, mkVarOccFS, mkTyVarOcc )
  55 import FastString       ( FastString )
  56 import Module           ( Module, moduleName )
  57 import UniqFM           ( lookupUFM )
  58 import UniqSupply       ( initUs_ )
  59 import Outputable
  60 import ErrUtils         ( Message )
  61 import Maybes           ( MaybeErr(..) )
  62 import SrcLoc           ( noSrcLoc )
  63 import Util             ( zipWithEqual, equalLength, splitAtList )
  64 import DynFlags         ( DynFlag(..), isOneShot )
  65 \end{code}
  66
  67 This module takes
  68
  69         IfaceDecl -> TyThing
  70         IfaceType -> Type
  71         etc
  72
  73 An IfaceDecl is populated with RdrNames, and these are not renamed to
  74 Names before typechecking, because there should be no scope errors etc.
  75
  76         -- For (b) consider: f = $(...h....)
  77         -- where h is imported, and calls f via an hi-boot file.
  78         -- This is bad!  But it is not seen as a staging error, because h
  79         -- is indeed imported.  We don't want the type-checker to black-hole
  80         -- when simplifying and compiling the splice!
  81         --
  82         -- Simple solution: discard any unfolding that mentions a variable
  83         -- bound in this module (and hence not yet processed).
  84         -- The discarding happens when forkM finds a type error.
  85
  86 %************************************************************************
  87 %*                                                                      *
  88 %*      tcImportDecl is the key function for "faulting in"              *
  89 %*      imported things
  90 %*                                                                      *
  91 %************************************************************************
  92
  93 The main idea is this.  We are chugging along type-checking source code, and
  94 find a reference to GHC.Base.map.  We call tcLookupGlobal, which doesn't find
  95 it in the EPS type envt.  So it
  96         1 loads GHC.Base.hi
  97         2 gets the decl for GHC.Base.map
  98         3 typechecks it via tcIfaceDecl
  99         4 and adds it to the type env in the EPS
 100
 101 Note that DURING STEP 4, we may find that map's type mentions a type
 102 constructor that also
 103
 104 Notice that for imported things we read the current version from the EPS
 105 mutable variable.  This is important in situations like
 106         ...$(e1)...$(e2)...
 107 where the code that e1 expands to might import some defns that
 108 also turn out to be needed by the code that e2 expands to.
 109
 110 \begin{code}
 111 tcImportDecl :: Name -> TcM TyThing
 112 -- Entry point for *source-code* uses of importDecl
 113 tcImportDecl name
 114   | Just thing <- wiredInNameTyThing_maybe name
 115   = do  { initIfaceTcRn (loadWiredInHomeIface name)
 116         ; return thing }
 117   | otherwise
 118   = do  { traceIf (text "tcImportDecl" <+> ppr name)
 119         ; mb_thing <- initIfaceTcRn (importDecl name)
 120         ; case mb_thing of
 121             Succeeded thing -> return thing
 122             Failed err      -> failWithTc err }
 123
 124 checkWiredInTyCon :: TyCon -> TcM ()
 125 -- Ensure that the home module of the TyCon (and hence its instances)
 126 -- are loaded. It might not be a wired-in tycon (see the calls in TcUnify),
 127 -- in which case this is a no-op.
 128 checkWiredInTyCon tc
 129   | not (isWiredInName tc_name)
 130   = return ()
 131   | otherwise
 132   = do  { mod <- getModule
 133         ; if nameIsLocalOrFrom mod tc_name then
 134                 -- Don't look for (non-existent) Float.hi when
 135                 -- compiling Float.lhs, which mentions Float of course
 136                 return ()
 137           else  -- A bit yukky to call initIfaceTcRn here
 138                 initIfaceTcRn (loadWiredInHomeIface tc_name)
 139         }
 140   where
 141     tc_name = tyConName tc
 142
 143 importDecl :: Name -> IfM lcl (MaybeErr Message TyThing)
 144 -- Get the TyThing for this Name from an interface file
 145 -- It's not a wired-in thing -- the caller caught that
 146 importDecl name
 147   = ASSERT( not (isWiredInName name) )
 148     do  { traceIf nd_doc
 149
 150         -- Load the interface, which should populate the PTE
 151         ; mb_iface <- loadInterface nd_doc (nameModule name) ImportBySystem
 152         ; case mb_iface of {
 153                 Failed err_msg  -> return (Failed err_msg) ;
 154                 Succeeded iface -> do
 155
 156         -- Now look it up again; this time we should find it
 157         { eps <- getEps
 158         ; case lookupTypeEnv (eps_PTE eps) name of
 159             Just thing -> return (Succeeded thing)
 160             Nothing    -> return (Failed not_found_msg)
 161     }}}
 162   where
 163     nd_doc = ptext SLIT("Need decl for") <+> ppr name
 164     not_found_msg = hang (ptext SLIT("Can't find interface-file declaration for") <+> ppr (nameParent name))
 165                        2 (vcat [ptext SLIT("Probable cause: bug in .hi-boot file, or inconsistent .hi file"),
 166                                 ptext SLIT("Use -ddump-if-trace to get an idea of which file caused the error")])
 167 \end{code}
 168
 169 %************************************************************************
 170 %*                                                                      *
 171                 Type-checking a complete interface
 172 %*                                                                      *
 173 %************************************************************************
 174
 175 Suppose we discover we don't need to recompile.  Then we must type
 176 check the old interface file.  This is a bit different to the
 177 incremental type checking we do as we suck in interface files.  Instead
 178 we do things similarly as when we are typechecking source decls: we
 179 bring into scope the type envt for the interface all at once, using a
 180 knot.  Remember, the decls aren't necessarily in dependency order --
 181 and even if they were, the type decls might be mutually recursive.
 182
 183 \begin{code}
 184 typecheckIface :: ModIface      -- Get the decls from here
 185                -> TcRnIf gbl lcl ModDetails
 186 typecheckIface iface
 187   = initIfaceTc iface $ \ tc_env_var -> do
 188         -- The tc_env_var is freshly allocated, private to
 189         -- type-checking this particular interface
 190         {       -- Get the right set of decls and rules.  If we are compiling without -O
 191                 -- we discard pragmas before typechecking, so that we don't "see"
 192                 -- information that we shouldn't.  From a versioning point of view
 193                 -- It's not actually *wrong* to do so, but in fact GHCi is unable
 194                 -- to handle unboxed tuples, so it must not see unfoldings.
 195           ignore_prags <- doptM Opt_IgnoreInterfacePragmas
 196
 197                 -- Load & typecheck the decls
 198         ; decl_things <- loadDecls ignore_prags (mi_decls iface)
 199
 200         ; let type_env = mkNameEnv decl_things
 201         ; writeMutVar tc_env_var type_env
 202
 203                 -- Now do those rules and instances
 204         ; let { rules | ignore_prags = []
 205                       | otherwise    = mi_rules iface
 206               ; dfuns = mi_insts iface
 207               }
 208         ; dfuns <- mapM tcIfaceInst dfuns
 209         ; rules <- mapM tcIfaceRule rules
 210
 211                 -- Exports
 212         ; exports <-  ifaceExportNames (mi_exports iface)
 213
 214                 -- Finished
 215         ; return (ModDetails {  md_types = type_env,
 216                                 md_insts = dfuns,
 217                                 md_rules = rules,
 218                                 md_exports = exports })
 219     }
 220 \end{code}
 221
 222
 223 %************************************************************************
 224 %*                                                                      *
 225                 Type and class declarations
 226 %*                                                                      *
 227 %************************************************************************
 228
 229 \begin{code}
 230 tcHiBootIface :: Module -> TcRn ModDetails
 231 -- Load the hi-boot iface for the module being compiled,
 232 -- if it indeed exists in the transitive closure of imports
 233 -- Return the ModDetails, empty if no hi-boot iface
 234 tcHiBootIface mod
 235   = do  { traceIf (text "loadHiBootInterface" <+> ppr mod)
 236
 237         ; mode <- getGhcMode
 238         ; if not (isOneShot mode)
 239                 -- In --make and interactive mode, if this module has an hs-boot file
 240                 -- we'll have compiled it already, and it'll be in the HPT
 241                 --
 242                 -- We check wheher the interface is a *boot* interface.
 243                 -- It can happen (when using GHC from Visual Studio) that we
 244                 -- compile a module in TypecheckOnly mode, with a stable,
 245                 -- fully-populated HPT.  In that case the boot interface isn't there
 246                 -- (it's been replaced by the mother module) so we can't check it.
 247                 -- And that's fine, because if M's ModInfo is in the HPT, then
 248                 -- it's been compiled once, and we don't need to check the boot iface
 249           then do { hpt <- getHpt
 250                   ; case lookupUFM hpt (moduleName mod) of
 251                       Just info | mi_boot (hm_iface info)
 252                                 -> return (hm_details info)
 253                       other -> return emptyModDetails }
 254           else do
 255
 256         -- OK, so we're in one-shot mode.
 257         -- In that case, we're read all the direct imports by now,
 258         -- so eps_is_boot will record if any of our imports mention us by
 259         -- way of hi-boot file
 260         { eps <- getEps
 261         ; case lookupUFM (eps_is_boot eps) (moduleName mod) of {
 262             Nothing -> return emptyModDetails ; -- The typical case
 263
 264             Just (_, False) -> failWithTc moduleLoop ;
 265                 -- Someone below us imported us!
 266                 -- This is a loop with no hi-boot in the way
 267
 268             Just (_mod, True) ->        -- There's a hi-boot interface below us
 269
 270     do  { read_result <- findAndReadIface
 271                                 need mod
 272                                 True    -- Hi-boot file
 273
 274         ; case read_result of
 275                 Failed err               -> failWithTc (elaborate err)
 276                 Succeeded (iface, _path) -> typecheckIface iface
 277     }}}}
 278   where
 279     need = ptext SLIT("Need the hi-boot interface for") <+> ppr mod
 280                  <+> ptext SLIT("to compare against the Real Thing")
 281
 282     moduleLoop = ptext SLIT("Circular imports: module") <+> quotes (ppr mod)
 283                      <+> ptext SLIT("depends on itself")
 284
 285     elaborate err = hang (ptext SLIT("Could not find hi-boot interface for") <+>
 286                           quotes (ppr mod) <> colon) 4 err
 287 \end{code}
 288
 289
 290 %************************************************************************
 291 %*                                                                      *
 292                 Type and class declarations
 293 %*                                                                      *
 294 %************************************************************************
 295
 296 When typechecking a data type decl, we *lazily* (via forkM) typecheck
 297 the constructor argument types.  This is in the hope that we may never
 298 poke on those argument types, and hence may never need to load the
 299 interface files for types mentioned in the arg types.
 300
 301 E.g.
 302         data Foo.S = MkS Baz.T
 303 Mabye we can get away without even loading the interface for Baz!
 304
 305 This is not just a performance thing.  Suppose we have
 306         data Foo.S = MkS Baz.T
 307         data Baz.T = MkT Foo.S
 308 (in different interface files, of course).
 309 Now, first we load and typecheck Foo.S, and add it to the type envt.
 310 If we do explore MkS's argument, we'll load and typecheck Baz.T.
 311 If we explore MkT's argument we'll find Foo.S already in the envt.
 312
 313 If we typechecked constructor args eagerly, when loading Foo.S we'd try to
 314 typecheck the type Baz.T.  So we'd fault in Baz.T... and then need Foo.S...
 315 which isn't done yet.
 316
 317 All very cunning. However, there is a rather subtle gotcha which bit
 318 me when developing this stuff.  When we typecheck the decl for S, we
 319 extend the type envt with S, MkS, and all its implicit Ids.  Suppose
 320 (a bug, but it happened) that the list of implicit Ids depended in
 321 turn on the constructor arg types.  Then the following sequence of
 322 events takes place:
 323         * we build a thunk <t> for the constructor arg tys
 324         * we build a thunk for the extended type environment (depends on <t>)
 325         * we write the extended type envt into the global EPS mutvar
 326
 327 Now we look something up in the type envt
 328         * that pulls on <t>
 329         * which reads the global type envt out of the global EPS mutvar
 330         * but that depends in turn on <t>
 331
 332 It's subtle, because, it'd work fine if we typechecked the constructor args
 333 eagerly -- they don't need the extended type envt.  They just get the extended
 334 type envt by accident, because they look at it later.
 335
 336 What this means is that the implicitTyThings MUST NOT DEPEND on any of
 337 the forkM stuff.
 338
 339
 340 \begin{code}
 341 tcIfaceDecl :: IfaceDecl -> IfL TyThing
 342
 343 tcIfaceDecl (IfaceId {ifName = occ_name, ifType = iface_type, ifIdInfo = info})
 344   = do  { name <- lookupIfaceTop occ_name
 345         ; ty <- tcIfaceType iface_type
 346         ; info <- tcIdInfo name ty info
 347         ; return (AnId (mkVanillaGlobal name ty info)) }
 348
 349 tcIfaceDecl (IfaceData {ifName = occ_name,
 350                         ifTyVars = tv_bndrs,
 351                         ifCtxt = ctxt,
 352                         ifCons = rdr_cons,
 353                         ifVrcs = arg_vrcs, ifRec = is_rec,
 354                         ifGeneric = want_generic })
 355   = do  { tc_name <- lookupIfaceTop occ_name
 356         ; bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 357
 358         { tycon <- fixM ( \ tycon -> do
 359             { stupid_theta <- tcIfaceCtxt ctxt
 360             ; cons  <- tcIfaceDataCons tycon tyvars rdr_cons
 361             ; buildAlgTyCon tc_name tyvars stupid_theta
 362                             cons arg_vrcs is_rec want_generic
 363             })
 364         ; traceIf (text "tcIfaceDecl4" <+> ppr tycon)
 365         ; return (ATyCon tycon)
 366     }}
 367
 368 tcIfaceDecl (IfaceSyn {ifName = occ_name, ifTyVars = tv_bndrs,
 369                        ifSynRhs = rdr_rhs_ty, ifVrcs = arg_vrcs})
 370    = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 371      { tc_name <- lookupIfaceTop occ_name
 372      ; rhs_ty <- tcIfaceType rdr_rhs_ty
 373      ; return (ATyCon (buildSynTyCon tc_name tyvars rhs_ty arg_vrcs))
 374      }
 375
 376 tcIfaceDecl (IfaceClass {ifCtxt = rdr_ctxt, ifName = occ_name, ifTyVars = tv_bndrs,
 377                          ifFDs = rdr_fds, ifSigs = rdr_sigs,
 378                          ifVrcs = tc_vrcs, ifRec = tc_isrec })
 379   = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 380     { cls_name <- lookupIfaceTop occ_name
 381     ; ctxt <- tcIfaceCtxt rdr_ctxt
 382     ; sigs <- mappM tc_sig rdr_sigs
 383     ; fds  <- mappM tc_fd rdr_fds
 384     ; cls  <- buildClass cls_name tyvars ctxt fds sigs tc_isrec tc_vrcs
 385     ; return (AClass cls) }
 386   where
 387    tc_sig (IfaceClassOp occ dm rdr_ty)
 388      = do { op_name <- lookupIfaceTop occ
 389           ; op_ty   <- forkM (mk_doc op_name rdr_ty) (tcIfaceType rdr_ty)
 390                 -- Must be done lazily for just the same reason as the
 391                 -- context of a data decl: the type sig might mention the
 392                 -- class being defined
 393           ; return (op_name, dm, op_ty) }
 394
 395    mk_doc op_name op_ty = ptext SLIT("Class op") <+> sep [ppr op_name, ppr op_ty]
 396
 397    tc_fd (tvs1, tvs2) = do { tvs1' <- mappM tcIfaceTyVar tvs1
 398                            ; tvs2' <- mappM tcIfaceTyVar tvs2
 399                            ; return (tvs1', tvs2') }
 400
 401 tcIfaceDecl (IfaceForeign {ifName = rdr_name, ifExtName = ext_name})
 402   = do  { name <- lookupIfaceTop rdr_name
 403         ; return (ATyCon (mkForeignTyCon name ext_name
 404                                          liftedTypeKind 0 [])) }
 405
 406 tcIfaceDataCons tycon tc_tyvars if_cons
 407   = case if_cons of
 408         IfAbstractTyCon  -> return mkAbstractTyConRhs
 409         IfDataTyCon cons -> do  { data_cons <- mappM tc_con_decl cons
 410                                 ; return (mkDataTyConRhs data_cons) }
 411         IfNewTyCon con   -> do  { data_con <- tc_con_decl con
 412                                 ; return (mkNewTyConRhs tycon data_con) }
 413   where
 414     tc_con_decl (IfVanillaCon { ifConOcc = occ, ifConInfix = is_infix, ifConArgTys = args,
 415                                 ifConStricts = stricts, ifConFields = field_lbls})
 416       = do { name  <- lookupIfaceTop occ
 417                 -- Read the argument types, but lazily to avoid faulting in
 418                 -- the component types unless they are really needed
 419            ; arg_tys <- forkM (mk_doc name) (mappM tcIfaceType args)
 420            ; lbl_names <- mappM lookupIfaceTop field_lbls
 421            ; buildDataCon name is_infix True {- Vanilla -}
 422                           stricts lbl_names
 423                           tc_tyvars [] arg_tys tycon
 424                           (mkTyVarTys tc_tyvars)        -- Vanilla => we know result tys
 425            }
 426
 427     tc_con_decl (IfGadtCon {    ifConTyVars = con_tvs,
 428                                 ifConOcc = occ, ifConCtxt = ctxt,
 429                                 ifConArgTys = args, ifConResTys = ress,
 430                                 ifConStricts = stricts})
 431       = bindIfaceTyVars con_tvs $ \ con_tyvars -> do
 432         { name  <- lookupIfaceTop occ
 433         ; theta <- tcIfaceCtxt ctxt     -- Laziness seems not worth the bother here
 434                 -- At one stage I thought that this context checking *had*
 435                 -- to be lazy, because of possible mutual recursion between the
 436                 -- type and the classe:
 437                 -- E.g.
 438                 --      class Real a where { toRat :: a -> Ratio Integer }
 439                 --      data (Real a) => Ratio a = ...
 440                 -- But now I think that the laziness in checking class ops breaks
 441                 -- the loop, so no laziness needed
 442
 443         -- Read the argument types, but lazily to avoid faulting in
 444         -- the component types unless they are really needed
 445         ; arg_tys <- forkM (mk_doc name) (mappM tcIfaceType args)
 446         ; res_tys <- forkM (mk_doc name) (mappM tcIfaceType ress)
 447
 448         ; buildDataCon name False {- Not infix -} False {- Not vanilla -}
 449                        stricts [{- No fields -}]
 450                        con_tyvars theta
 451                        arg_tys tycon res_tys
 452         }
 453     mk_doc con_name = ptext SLIT("Constructor") <+> ppr con_name
 454 \end{code}
 455
 456
 457 %************************************************************************
 458 %*                                                                      *
 459                 Instances
 460 %*                                                                      *
 461 %************************************************************************
 462
 463 \begin{code}
 464 tcIfaceInst :: IfaceInst -> IfL Instance
 465 tcIfaceInst (IfaceInst { ifDFun = dfun_occ, ifOFlag = oflag,
 466                          ifInstCls = cls, ifInstTys = mb_tcs,
 467                          ifInstOrph = orph })
 468   = do  { dfun    <- forkM (ptext SLIT("Dict fun") <+> ppr dfun_occ) $
 469                      tcIfaceExtId (LocalTop dfun_occ)
 470         ; cls'    <- lookupIfaceExt cls
 471         ; mb_tcs' <- mapM do_tc mb_tcs
 472         ; return (mkImportedInstance cls' mb_tcs' orph dfun oflag) }
 473   where
 474     do_tc Nothing   = return Nothing
 475     do_tc (Just tc) = do { tc' <- lookupIfaceTc tc; return (Just tc') }
 476 \end{code}
 477
 478
 479 %************************************************************************
 480 %*                                                                      *
 481                 Rules
 482 %*                                                                      *
 483 %************************************************************************
 484
 485 We move a IfaceRule from eps_rules to eps_rule_base when all its LHS free vars
 486 are in the type environment.  However, remember that typechecking a Rule may
 487 (as a side effect) augment the type envt, and so we may need to iterate the process.
 488
 489 \begin{code}
 490 tcIfaceRule :: IfaceRule -> IfL CoreRule
 491 tcIfaceRule (IfaceRule {ifRuleName = name, ifActivation = act, ifRuleBndrs = bndrs,
 492                         ifRuleHead = fn, ifRuleArgs = args, ifRuleRhs = rhs,
 493                         ifRuleOrph = orph })
 494   = do  { fn' <- lookupIfaceExt fn
 495         ; ~(bndrs', args', rhs') <-
 496                 -- Typecheck the payload lazily, in the hope it'll never be looked at
 497                 forkM (ptext SLIT("Rule") <+> ftext name) $
 498                 bindIfaceBndrs bndrs                      $ \ bndrs' ->
 499                 do { args' <- mappM tcIfaceExpr args
 500                    ; rhs'  <- tcIfaceExpr rhs
 501                    ; return (bndrs', args', rhs') }
 502         ; mb_tcs <- mapM ifTopFreeName args
 503         ; returnM (Rule { ru_name = name, ru_fn = fn', ru_act = act,
 504                           ru_bndrs = bndrs', ru_args = args',
 505                           ru_rhs = rhs', ru_orph = orph,
 506                           ru_rough = mb_tcs,
 507                           ru_local = isLocalIfaceExtName fn }) }
 508   where
 509         -- This function *must* mirror exactly what Rules.topFreeName does
 510         -- We could have stored the ru_rough field in the iface file
 511         -- but that would be redundant, I think.
 512         -- The only wrinkle is that we must not be deceived by
 513         -- type syononyms at the top of a type arg.  Since
 514         -- we can't tell at this point, we are careful not
 515         -- to write them out in coreRuleToIfaceRule
 516     ifTopFreeName :: IfaceExpr -> IfL (Maybe Name)
 517     ifTopFreeName (IfaceType (IfaceTyConApp tc _ ))
 518         = do { n <- lookupIfaceTc tc
 519              ; return (Just n) }
 520     ifTopFreeName (IfaceApp f a) = ifTopFreeName f
 521     ifTopFreeName (IfaceExt ext) = do { n <- lookupIfaceExt ext
 522                                       ; return (Just n) }
 523     ifTopFreeName other = return Nothing
 524 \end{code}
 525
 526
 527 %************************************************************************
 528 %*                                                                      *
 529                         Types
 530 %*                                                                      *
 531 %************************************************************************
 532
 533 \begin{code}
 534 tcIfaceType :: IfaceType -> IfL Type
 535 tcIfaceType (IfaceTyVar n)        = do { tv <- tcIfaceTyVar n; return (TyVarTy tv) }
 536 tcIfaceType (IfaceAppTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (AppTy t1' t2') }
 537 tcIfaceType (IfaceFunTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (FunTy t1' t2') }
 538 tcIfaceType (IfaceTyConApp tc ts) = do { tc' <- tcIfaceTyCon tc; ts' <- tcIfaceTypes ts; return (mkTyConApp tc' ts') }
 539 tcIfaceType (IfaceForAllTy tv t)  = bindIfaceTyVar tv $ \ tv' -> do { t' <- tcIfaceType t; return (ForAllTy tv' t') }
 540 tcIfaceType (IfacePredTy st)      = do { st' <- tcIfacePredType st; return (PredTy st') }
 541
 542 tcIfaceTypes tys = mapM tcIfaceType tys
 543
 544 -----------------------------------------
 545 tcIfacePredType :: IfacePredType -> IfL PredType
 546 tcIfacePredType (IfaceClassP cls ts) = do { cls' <- tcIfaceClass cls; ts' <- tcIfaceTypes ts; return (ClassP cls' ts') }
 547 tcIfacePredType (IfaceIParam ip t)   = do { ip' <- newIPName ip; t' <- tcIfaceType t; return (IParam ip' t') }
 548
 549 -----------------------------------------
 550 tcIfaceCtxt :: IfaceContext -> IfL ThetaType
 551 tcIfaceCtxt sts = mappM tcIfacePredType sts
 552 \end{code}
 553
 554
 555 %************************************************************************
 556 %*                                                                      *
 557                         Core
 558 %*                                                                      *
 559 %************************************************************************
 560
 561 \begin{code}
 562 tcIfaceExpr :: IfaceExpr -> IfL CoreExpr
 563 tcIfaceExpr (IfaceType ty)
 564   = tcIfaceType ty              `thenM` \ ty' ->
 565     returnM (Type ty')
 566
 567 tcIfaceExpr (IfaceLcl name)
 568   = tcIfaceLclId name   `thenM` \ id ->
 569     returnM (Var id)
 570
 571 tcIfaceExpr (IfaceExt gbl)
 572   = tcIfaceExtId gbl    `thenM` \ id ->
 573     returnM (Var id)
 574
 575 tcIfaceExpr (IfaceLit lit)
 576   = returnM (Lit lit)
 577
 578 tcIfaceExpr (IfaceFCall cc ty)
 579   = tcIfaceType ty      `thenM` \ ty' ->
 580     newUnique           `thenM` \ u ->
 581     returnM (Var (mkFCallId u cc ty'))
 582
 583 tcIfaceExpr (IfaceTuple boxity args)
 584   = mappM tcIfaceExpr args      `thenM` \ args' ->
 585     let
 586         -- Put the missing type arguments back in
 587         con_args = map (Type . exprType) args' ++ args'
 588     in
 589     returnM (mkApps (Var con_id) con_args)
 590   where
 591     arity = length args
 592     con_id = dataConWorkId (tupleCon boxity arity)
 593
 594
 595 tcIfaceExpr (IfaceLam bndr body)
 596   = bindIfaceBndr bndr          $ \ bndr' ->
 597     tcIfaceExpr body            `thenM` \ body' ->
 598     returnM (Lam bndr' body')
 599
 600 tcIfaceExpr (IfaceApp fun arg)
 601   = tcIfaceExpr fun             `thenM` \ fun' ->
 602     tcIfaceExpr arg             `thenM` \ arg' ->
 603     returnM (App fun' arg')
 604
 605 tcIfaceExpr (IfaceCase scrut case_bndr ty alts)
 606   = tcIfaceExpr scrut           `thenM` \ scrut' ->
 607     newIfaceName (mkVarOccFS case_bndr) `thenM` \ case_bndr_name ->
 608     let
 609         scrut_ty   = exprType scrut'
 610         case_bndr' = mkLocalId case_bndr_name scrut_ty
 611         tc_app     = splitTyConApp scrut_ty
 612                 -- NB: Won't always succeed (polymoprhic case)
 613                 --     but won't be demanded in those cases
 614                 -- NB: not tcSplitTyConApp; we are looking at Core here
 615                 --     look through non-rec newtypes to find the tycon that
 616                 --     corresponds to the datacon in this case alternative
 617     in
 618     extendIfaceIdEnv [case_bndr']       $
 619     mappM (tcIfaceAlt tc_app) alts      `thenM` \ alts' ->
 620     tcIfaceType ty              `thenM` \ ty' ->
 621     returnM (Case scrut' case_bndr' ty' alts')
 622
 623 tcIfaceExpr (IfaceLet (IfaceNonRec bndr rhs) body)
 624   = tcIfaceExpr rhs             `thenM` \ rhs' ->
 625     bindIfaceId bndr            $ \ bndr' ->
 626     tcIfaceExpr body            `thenM` \ body' ->
 627     returnM (Let (NonRec bndr' rhs') body')
 628
 629 tcIfaceExpr (IfaceLet (IfaceRec pairs) body)
 630   = bindIfaceIds bndrs          $ \ bndrs' ->
 631     mappM tcIfaceExpr rhss      `thenM` \ rhss' ->
 632     tcIfaceExpr body            `thenM` \ body' ->
 633     returnM (Let (Rec (bndrs' `zip` rhss')) body')
 634   where
 635     (bndrs, rhss) = unzip pairs
 636
 637 tcIfaceExpr (IfaceNote note expr)
 638   = tcIfaceExpr expr            `thenM` \ expr' ->
 639     case note of
 640         IfaceCoerce to_ty -> tcIfaceType to_ty  `thenM` \ to_ty' ->
 641                              returnM (Note (Coerce to_ty'
 642                                                    (exprType expr')) expr')
 643         IfaceInlineMe     -> returnM (Note InlineMe   expr')
 644         IfaceSCC cc       -> returnM (Note (SCC cc)   expr')
 645         IfaceCoreNote n   -> returnM (Note (CoreNote n) expr')
 646
 647 -------------------------
 648 tcIfaceAlt _ (IfaceDefault, names, rhs)
 649   = ASSERT( null names )
 650     tcIfaceExpr rhs             `thenM` \ rhs' ->
 651     returnM (DEFAULT, [], rhs')
 652
 653 tcIfaceAlt _ (IfaceLitAlt lit, names, rhs)
 654   = ASSERT( null names )
 655     tcIfaceExpr rhs             `thenM` \ rhs' ->
 656     returnM (LitAlt lit, [], rhs')
 657
 658 -- A case alternative is made quite a bit more complicated
 659 -- by the fact that we omit type annotations because we can
 660 -- work them out.  True enough, but its not that easy!
 661 tcIfaceAlt (tycon, inst_tys) (IfaceDataAlt data_occ, arg_strs, rhs)
 662   = do  { let tycon_mod = nameModule (tyConName tycon)
 663         ; con <- tcIfaceDataCon (ExtPkg tycon_mod data_occ)
 664         ; ASSERT2( con `elem` tyConDataCons tycon,
 665                    ppr con $$ ppr tycon $$ ppr (tyConDataCons tycon) )
 666
 667           if isVanillaDataCon con then
 668                 tcVanillaAlt con inst_tys arg_strs rhs
 669           else
 670     do  {       -- General case
 671           let (tyvar_strs, id_strs) = splitAtList (dataConTyVars con) arg_strs
 672         ; tyvar_names <- mapM (newIfaceName . mkTyVarOcc) tyvar_strs
 673         ; id_names    <- mapM (newIfaceName . mkVarOccFS) id_strs
 674         ; let   tyvars   = [ mkTyVar name (tyVarKind tv)
 675                            | (name,tv) <- tyvar_names `zip` dataConTyVars con ]
 676                 arg_tys  = dataConInstArgTys con (mkTyVarTys tyvars)
 677                 arg_ids  = ASSERT2( equalLength id_names arg_tys,
 678                                     ppr (con, tyvar_names++id_names, rhs) $$ ppr tyvars $$ ppr arg_tys )
 679                            zipWith mkLocalId id_names arg_tys
 680
 681                 Just refine = coreRefineTys con tyvars (mkTyConApp tycon inst_tys)
 682
 683         ; rhs' <- extendIfaceTyVarEnv tyvars    $
 684                   extendIfaceIdEnv arg_ids      $
 685                   refineIfaceIdEnv refine       $
 686                         -- You might think that we don't need to refine the envt here,
 687                         -- but we do: \(x::a) -> case y of
 688                         --                           MkT -> case x of { True -> ... }
 689                         -- In the "case x" we need to know x's type, because we use that
 690                         -- to find which module to look for "True" in. Sigh.
 691                   tcIfaceExpr rhs
 692         ; return (DataAlt con, tyvars ++ arg_ids, rhs') }}
 693
 694 tcIfaceAlt (tycon, inst_tys) (IfaceTupleAlt boxity, arg_occs, rhs)
 695   = ASSERT( isTupleTyCon tycon )
 696     do  { let [data_con] = tyConDataCons tycon
 697         ; tcVanillaAlt data_con inst_tys arg_occs rhs }
 698
 699 tcVanillaAlt data_con inst_tys arg_strs rhs
 700   = do  { arg_names <- newIfaceNames (map mkVarOccFS arg_strs)
 701         ; let arg_tys = dataConInstArgTys data_con inst_tys
 702         ; let arg_ids = ASSERT2( equalLength arg_names arg_tys,
 703                                  ppr data_con <+> ppr inst_tys <+> ppr arg_strs $$ ppr rhs )
 704                         zipWith mkLocalId arg_names arg_tys
 705         ; rhs' <- extendIfaceIdEnv arg_ids (tcIfaceExpr rhs)
 706         ; returnM (DataAlt data_con, arg_ids, rhs') }
 707 \end{code}
 708
 709
 710 \begin{code}
 711 tcExtCoreBindings :: [IfaceBinding] -> IfL [CoreBind]   -- Used for external core
 712 tcExtCoreBindings []     = return []
 713 tcExtCoreBindings (b:bs) = do_one b (tcExtCoreBindings bs)
 714
 715 do_one :: IfaceBinding -> IfL [CoreBind] -> IfL [CoreBind]
 716 do_one (IfaceNonRec bndr rhs) thing_inside
 717   = do  { rhs' <- tcIfaceExpr rhs
 718         ; bndr' <- newExtCoreBndr bndr
 719         ; extendIfaceIdEnv [bndr'] $ do
 720         { core_binds <- thing_inside
 721         ; return (NonRec bndr' rhs' : core_binds) }}
 722
 723 do_one (IfaceRec pairs) thing_inside
 724   = do  { bndrs' <- mappM newExtCoreBndr bndrs
 725         ; extendIfaceIdEnv bndrs' $ do
 726         { rhss' <- mappM tcIfaceExpr rhss
 727         ; core_binds <- thing_inside
 728         ; return (Rec (bndrs' `zip` rhss') : core_binds) }}
 729   where
 730     (bndrs,rhss) = unzip pairs
 731 \end{code}
 732
 733
 734 %************************************************************************
 735 %*                                                                      *
 736                 IdInfo
 737 %*                                                                      *
 738 %************************************************************************
 739
 740 \begin{code}
 741 tcIdInfo :: Name -> Type -> IfaceIdInfo -> IfL IdInfo
 742 tcIdInfo name ty NoInfo         = return vanillaIdInfo
 743 tcIdInfo name ty (HasInfo info) = foldlM tcPrag init_info info
 744   where
 745     -- Set the CgInfo to something sensible but uninformative before
 746     -- we start; default assumption is that it has CAFs
 747     init_info = vanillaIdInfo
 748
 749     tcPrag info HsNoCafRefs         = returnM (info `setCafInfo`   NoCafRefs)
 750     tcPrag info (HsArity arity)     = returnM (info `setArityInfo` arity)
 751     tcPrag info (HsStrictness str)  = returnM (info `setAllStrictnessInfo` Just str)
 752
 753         -- The next two are lazy, so they don't transitively suck stuff in
 754     tcPrag info (HsWorker nm arity) = tcWorkerInfo ty info nm arity
 755     tcPrag info (HsInline inline_prag) = returnM (info `setInlinePragInfo` inline_prag)
 756     tcPrag info (HsUnfold expr)
 757         = tcPragExpr name expr  `thenM` \ maybe_expr' ->
 758           let
 759                 -- maybe_expr' doesn't get looked at if the unfolding
 760                 -- is never inspected; so the typecheck doesn't even happen
 761                 unfold_info = case maybe_expr' of
 762                                 Nothing    -> noUnfolding
 763                                 Just expr' -> mkTopUnfolding expr'
 764           in
 765           returnM (info `setUnfoldingInfoLazily` unfold_info)
 766 \end{code}
 767
 768 \begin{code}
 769 tcWorkerInfo ty info wkr arity
 770   = do  { mb_wkr_id <- forkM_maybe doc (tcIfaceExtId wkr)
 771
 772         -- We return without testing maybe_wkr_id, but as soon as info is
 773         -- looked at we will test it.  That's ok, because its outside the
 774         -- knot; and there seems no big reason to further defer the
 775         -- tcIfaceId lookup.  (Contrast with tcPragExpr, where postponing walking
 776         -- over the unfolding until it's actually used does seem worth while.)
 777         ; us <- newUniqueSupply
 778
 779         ; returnM (case mb_wkr_id of
 780                      Nothing     -> info
 781                      Just wkr_id -> add_wkr_info us wkr_id info) }
 782   where
 783     doc = text "Worker for" <+> ppr wkr
 784     add_wkr_info us wkr_id info
 785         = info `setUnfoldingInfoLazily`  mk_unfolding us wkr_id
 786                `setWorkerInfo`           HasWorker wkr_id arity
 787
 788     mk_unfolding us wkr_id = mkTopUnfolding (initUs_ us (mkWrapper ty strict_sig) wkr_id)
 789
 790         -- We are relying here on strictness info always appearing
 791         -- before worker info,  fingers crossed ....
 792     strict_sig = case newStrictnessInfo info of
 793                    Just sig -> sig
 794                    Nothing  -> pprPanic "Worker info but no strictness for" (ppr wkr)
 795 \end{code}
 796
 797 For unfoldings we try to do the job lazily, so that we never type check
 798 an unfolding that isn't going to be looked at.
 799
 800 \begin{code}
 801 tcPragExpr :: Name -> IfaceExpr -> IfL (Maybe CoreExpr)
 802 tcPragExpr name expr
 803   = forkM_maybe doc $
 804     tcIfaceExpr expr            `thenM` \ core_expr' ->
 805
 806                 -- Check for type consistency in the unfolding
 807     ifOptM Opt_DoCoreLinting (
 808         get_in_scope_ids                        `thenM` \ in_scope ->
 809         case lintUnfolding noSrcLoc in_scope core_expr' of
 810           Nothing       -> returnM ()
 811           Just fail_msg -> pprPanic "Iface Lint failure" (doc <+> fail_msg)
 812     )                           `thenM_`
 813
 814    returnM core_expr'
 815   where
 816     doc = text "Unfolding of" <+> ppr name
 817     get_in_scope_ids    -- Urgh; but just for linting
 818         = setLclEnv () $
 819           do    { env <- getGblEnv
 820                 ; case if_rec_types env of {
 821                           Nothing -> return [] ;
 822                           Just (_, get_env) -> do
 823                 { type_env <- get_env
 824                 ; return (typeEnvIds type_env) }}}
 825 \end{code}
 826
 827
 828
 829 %************************************************************************
 830 %*                                                                      *
 831                 Getting from Names to TyThings
 832 %*                                                                      *
 833 %************************************************************************
 834
 835 \begin{code}
 836 tcIfaceGlobal :: Name -> IfL TyThing
 837 tcIfaceGlobal name
 838   | Just thing <- wiredInNameTyThing_maybe name
 839         -- Wired-in things include TyCons, DataCons, and Ids
 840   = do { loadWiredInHomeIface name; return thing }
 841         -- Even though we are in an interface file, we want to make
 842         -- sure its instances are loaded (imagine f :: Double -> Double)
 843         -- and its RULES are loaded too
 844   | otherwise
 845   = do  { (eps,hpt) <- getEpsAndHpt
 846         ; dflags <- getDOpts
 847         ; case lookupType dflags hpt (eps_PTE eps) name of {
 848             Just thing -> return thing ;
 849             Nothing    -> do
 850
 851         { env <- getGblEnv
 852         ; case if_rec_types env of {
 853             Just (mod, get_type_env)
 854                 | nameIsLocalOrFrom mod name
 855                 -> do           -- It's defined in the module being compiled
 856                 { type_env <- setLclEnv () get_type_env         -- yuk
 857                 ; case lookupNameEnv type_env name of
 858                         Just thing -> return thing
 859                         Nothing    -> pprPanic "tcIfaceGlobal (local): not found:"
 860                                                 (ppr name $$ ppr type_env) }
 861
 862           ; other -> do
 863
 864         { mb_thing <- importDecl name   -- It's imported; go get it
 865         ; case mb_thing of
 866             Failed err      -> failIfM err
 867             Succeeded thing -> return thing
 868     }}}}}
 869
 870 tcIfaceTyCon :: IfaceTyCon -> IfL TyCon
 871 tcIfaceTyCon IfaceIntTc         = tcWiredInTyCon intTyCon
 872 tcIfaceTyCon IfaceBoolTc        = tcWiredInTyCon boolTyCon
 873 tcIfaceTyCon IfaceCharTc        = tcWiredInTyCon charTyCon
 874 tcIfaceTyCon IfaceListTc        = tcWiredInTyCon listTyCon
 875 tcIfaceTyCon IfacePArrTc        = tcWiredInTyCon parrTyCon
 876 tcIfaceTyCon (IfaceTupTc bx ar) = tcWiredInTyCon (tupleTyCon bx ar)
 877 tcIfaceTyCon (IfaceTc ext_nm)   = do { name <- lookupIfaceExt ext_nm
 878                                      ; thing <- tcIfaceGlobal name
 879                                      ; return (check_tc (tyThingTyCon thing)) }
 880   where
 881 #ifdef DEBUG
 882     check_tc tc = case toIfaceTyCon (error "urk") tc of
 883                    IfaceTc _ -> tc
 884                    other     -> pprTrace "check_tc" (ppr tc) tc
 885 #else
 886     check_tc tc = tc
 887 #endif
 888
 889 -- Even though we are in an interface file, we want to make
 890 -- sure the instances and RULES of this tycon are loaded
 891 -- Imagine: f :: Double -> Double
 892 tcWiredInTyCon :: TyCon -> IfL TyCon
 893 tcWiredInTyCon tc = do { loadWiredInHomeIface (tyConName tc)
 894                        ; return tc }
 895
 896 tcIfaceClass :: IfaceExtName -> IfL Class
 897 tcIfaceClass rdr_name = do { name <- lookupIfaceExt rdr_name
 898                            ; thing <- tcIfaceGlobal name
 899                            ; return (tyThingClass thing) }
 900
 901 tcIfaceDataCon :: IfaceExtName -> IfL DataCon
 902 tcIfaceDataCon gbl = do { name <- lookupIfaceExt gbl
 903                         ; thing <- tcIfaceGlobal name
 904                         ; case thing of
 905                                 ADataCon dc -> return dc
 906                                 other   -> pprPanic "tcIfaceExtDC" (ppr gbl $$ ppr name$$ ppr thing) }
 907
 908 tcIfaceExtId :: IfaceExtName -> IfL Id
 909 tcIfaceExtId gbl = do { name <- lookupIfaceExt gbl
 910                       ; thing <- tcIfaceGlobal name
 911                       ; case thing of
 912                           AnId id -> return id
 913                           other   -> pprPanic "tcIfaceExtId" (ppr gbl $$ ppr name$$ ppr thing) }
 914 \end{code}
 915
 916 %************************************************************************
 917 %*                                                                      *
 918                 Bindings
 919 %*                                                                      *
 920 %************************************************************************
 921
 922 \begin{code}
 923 bindIfaceBndr :: IfaceBndr -> (CoreBndr -> IfL a) -> IfL a
 924 bindIfaceBndr (IfaceIdBndr bndr) thing_inside
 925   = bindIfaceId bndr thing_inside
 926 bindIfaceBndr (IfaceTvBndr bndr) thing_inside
 927   = bindIfaceTyVar bndr thing_inside
 928
 929 bindIfaceBndrs :: [IfaceBndr] -> ([CoreBndr] -> IfL a) -> IfL a
 930 bindIfaceBndrs []     thing_inside = thing_inside []
 931 bindIfaceBndrs (b:bs) thing_inside
 932   = bindIfaceBndr b     $ \ b' ->
 933     bindIfaceBndrs bs   $ \ bs' ->
 934     thing_inside (b':bs')
 935
 936 -----------------------
 937 bindIfaceId :: IfaceIdBndr -> (Id -> IfL a) -> IfL a
 938 bindIfaceId (occ, ty) thing_inside
 939   = do  { name <- newIfaceName (mkVarOccFS occ)
 940         ; ty' <- tcIfaceType ty
 941         ; let { id = mkLocalId name ty' }
 942         ; extendIfaceIdEnv [id] (thing_inside id) }
 943
 944 bindIfaceIds :: [IfaceIdBndr] -> ([Id] -> IfL a) -> IfL a
 945 bindIfaceIds bndrs thing_inside
 946   = do  { names <- newIfaceNames (map mkVarOccFS occs)
 947         ; tys' <- mappM tcIfaceType tys
 948         ; let { ids = zipWithEqual "tcCoreValBndr" mkLocalId names tys' }
 949         ; extendIfaceIdEnv ids (thing_inside ids) }
 950   where
 951     (occs,tys) = unzip bndrs
 952
 953
 954 -----------------------
 955 newExtCoreBndr :: IfaceIdBndr -> IfL Id
 956 newExtCoreBndr (var, ty)
 957   = do  { mod <- getIfModule
 958         ; name <- newGlobalBinder mod (mkVarOccFS var) Nothing noSrcLoc
 959         ; ty' <- tcIfaceType ty
 960         ; return (mkLocalId name ty') }
 961
 962 -----------------------
 963 bindIfaceTyVar :: IfaceTvBndr -> (TyVar -> IfL a) -> IfL a
 964 bindIfaceTyVar (occ,kind) thing_inside
 965   = do  { name <- newIfaceName (mkTyVarOcc occ)
 966         ; let tyvar = mk_iface_tyvar name kind
 967         ; extendIfaceTyVarEnv [tyvar] (thing_inside tyvar) }
 968
 969 bindIfaceTyVars :: [IfaceTvBndr] -> ([TyVar] -> IfL a) -> IfL a
 970 bindIfaceTyVars bndrs thing_inside
 971   = do  { names <- newIfaceNames (map mkTyVarOcc occs)
 972         ; let tyvars = zipWith mk_iface_tyvar names kinds
 973         ; extendIfaceTyVarEnv tyvars (thing_inside tyvars) }
 974   where
 975     (occs,kinds) = unzip bndrs
 976
 977 mk_iface_tyvar name kind = mkTyVar name kind
 978 \end{code}
 979