compiler/iface/TcIface.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Type checking of type signatures in interface files
   7
   8 \begin{code}
   9 module TcIface (
  10         tcImportDecl, checkWiredInTyCon, tcHiBootIface, typecheckIface,
  11         tcIfaceDecl, tcIfaceInst, tcIfaceFamInst, tcIfaceRules,
  12         tcIfaceVectInfo, tcIfaceAnnotations, tcIfaceGlobal, tcExtCoreBindings
  13  ) where
  14
  15 #include "HsVersions.h"
  16
  17 import IfaceSyn
  18 import LoadIface
  19 import IfaceEnv
  20 import BuildTyCl
  21 import TcRnMonad
  22 import TcType
  23 import Type
  24 import Coercion
  25 import TypeRep
  26 import HscTypes
  27 import Annotations
  28 import InstEnv
  29 import FamInstEnv
  30 import CoreSyn
  31 import CoreUtils
  32 import CoreUnfold
  33 import CoreLint
  34 import WorkWrap
  35 import Id
  36 import MkId
  37 import IdInfo
  38 import Class
  39 import TyCon
  40 import DataCon
  41 import TysWiredIn
  42 import TysPrim          ( anyTyConOfKind )
  43 import BasicTypes       ( Arity, nonRuleLoopBreaker )
  44 import qualified Var
  45 import VarEnv
  46 import Name
  47 import NameEnv
  48 import OccurAnal        ( occurAnalyseExpr )
  49 import Demand           ( isBottomingSig )
  50 import Module
  51 import UniqFM
  52 import UniqSupply
  53 import Outputable
  54 import ErrUtils
  55 import Maybes
  56 import SrcLoc
  57 import DynFlags
  58 import Util
  59 import FastString
  60
  61 import Control.Monad
  62 import Data.List
  63 \end{code}
  64
  65 This module takes
  66
  67         IfaceDecl -> TyThing
  68         IfaceType -> Type
  69         etc
  70
  71 An IfaceDecl is populated with RdrNames, and these are not renamed to
  72 Names before typechecking, because there should be no scope errors etc.
  73
  74         -- For (b) consider: f = \$(...h....)
  75         -- where h is imported, and calls f via an hi-boot file.
  76         -- This is bad!  But it is not seen as a staging error, because h
  77         -- is indeed imported.  We don't want the type-checker to black-hole
  78         -- when simplifying and compiling the splice!
  79         --
  80         -- Simple solution: discard any unfolding that mentions a variable
  81         -- bound in this module (and hence not yet processed).
  82         -- The discarding happens when forkM finds a type error.
  83
  84 %************************************************************************
  85 %*                                                                      *
  86 %*      tcImportDecl is the key function for "faulting in"              *
  87 %*      imported things
  88 %*                                                                      *
  89 %************************************************************************
  90
  91 The main idea is this.  We are chugging along type-checking source code, and
  92 find a reference to GHC.Base.map.  We call tcLookupGlobal, which doesn't find
  93 it in the EPS type envt.  So it
  94         1 loads GHC.Base.hi
  95         2 gets the decl for GHC.Base.map
  96         3 typechecks it via tcIfaceDecl
  97         4 and adds it to the type env in the EPS
  98
  99 Note that DURING STEP 4, we may find that map's type mentions a type
 100 constructor that also
 101
 102 Notice that for imported things we read the current version from the EPS
 103 mutable variable.  This is important in situations like
 104         ...$(e1)...$(e2)...
 105 where the code that e1 expands to might import some defns that
 106 also turn out to be needed by the code that e2 expands to.
 107
 108 \begin{code}
 109 tcImportDecl :: Name -> TcM TyThing
 110 -- Entry point for *source-code* uses of importDecl
 111 tcImportDecl name
 112   | Just thing <- wiredInNameTyThing_maybe name
 113   = do  { when (needWiredInHomeIface thing)
 114                (initIfaceTcRn (loadWiredInHomeIface name))
 115                 -- See Note [Loading instances for wired-in things]
 116         ; return thing }
 117   | otherwise
 118   = do  { traceIf (text "tcImportDecl" <+> ppr name)
 119         ; mb_thing <- initIfaceTcRn (importDecl name)
 120         ; case mb_thing of
 121             Succeeded thing -> return thing
 122             Failed err      -> failWithTc err }
 123
 124 importDecl :: Name -> IfM lcl (MaybeErr Message TyThing)
 125 -- Get the TyThing for this Name from an interface file
 126 -- It's not a wired-in thing -- the caller caught that
 127 importDecl name
 128   = ASSERT( not (isWiredInName name) )
 129     do  { traceIf nd_doc
 130
 131         -- Load the interface, which should populate the PTE
 132         ; mb_iface <- ASSERT2( isExternalName name, ppr name )
 133                       loadInterface nd_doc (nameModule name) ImportBySystem
 134         ; case mb_iface of {
 135                 Failed err_msg  -> return (Failed err_msg) ;
 136                 Succeeded _ -> do
 137
 138         -- Now look it up again; this time we should find it
 139         { eps <- getEps
 140         ; case lookupTypeEnv (eps_PTE eps) name of
 141             Just thing -> return (Succeeded thing)
 142             Nothing    -> return (Failed not_found_msg)
 143     }}}
 144   where
 145     nd_doc = ptext (sLit "Need decl for") <+> ppr name
 146     not_found_msg = hang (ptext (sLit "Can't find interface-file declaration for") <+>
 147                                 pprNameSpace (occNameSpace (nameOccName name)) <+> (ppr (nameOccName name)))
 148                        2 (vcat [ptext (sLit "Probable cause: bug in .hi-boot file, or inconsistent .hi file"),
 149                                 ptext (sLit "Use -ddump-if-trace to get an idea of which file caused the error")])
 150 \end{code}
 151
 152 %************************************************************************
 153 %*                                                                      *
 154            Checks for wired-in things
 155 %*                                                                      *
 156 %************************************************************************
 157
 158 Note [Loading instances for wired-in things]
 159 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 160 We need to make sure that we have at least *read* the interface files
 161 for any module with an instance decl or RULE that we might want.
 162
 163 * If the instance decl is an orphan, we have a whole separate mechanism
 164   (loadOprhanModules)
 165
 166 * If the instance decl not an orphan, then the act of looking at the
 167   TyCon or Class will force in the defining module for the
 168   TyCon/Class, and hence the instance decl
 169
 170 * BUT, if the TyCon is a wired-in TyCon, we don't really need its interface;
 171   but we must make sure we read its interface in case it has instances or
 172   rules.  That is what LoadIface.loadWiredInHomeInterface does.  It's called
 173   from TcIface.{tcImportDecl, checkWiredInTyCon, ifCheckWiredInThing}
 174
 175 * HOWEVER, only do this for TyCons.  There are no wired-in Classes.  There
 176   are some wired-in Ids, but we don't want to load their interfaces. For
 177   example, Control.Exception.Base.recSelError is wired in, but that module
 178   is compiled late in the base library, and we don't want to force it to
 179   load before it's been compiled!
 180
 181 All of this is done by the type checker. The renamer plays no role.
 182 (It used to, but no longer.)
 183
 184
 185 \begin{code}
 186 checkWiredInTyCon :: TyCon -> TcM ()
 187 -- Ensure that the home module of the TyCon (and hence its instances)
 188 -- are loaded. See Note [Loading instances for wired-in things]
 189 -- It might not be a wired-in tycon (see the calls in TcUnify),
 190 -- in which case this is a no-op.
 191 checkWiredInTyCon tc
 192   | not (isWiredInName tc_name)
 193   = return ()
 194   | otherwise
 195   = do  { mod <- getModule
 196         ; ASSERT( isExternalName tc_name )
 197           when (mod /= nameModule tc_name)
 198                (initIfaceTcRn (loadWiredInHomeIface tc_name))
 199                 -- Don't look for (non-existent) Float.hi when
 200                 -- compiling Float.lhs, which mentions Float of course
 201                 -- A bit yukky to call initIfaceTcRn here
 202         }
 203   where
 204     tc_name = tyConName tc
 205
 206 ifCheckWiredInThing :: TyThing -> IfL ()
 207 -- Even though we are in an interface file, we want to make
 208 -- sure the instances of a wired-in thing are loaded (imagine f :: Double -> Double)
 209 -- Ditto want to ensure that RULES are loaded too
 210 -- See Note [Loading instances for wired-in things]
 211 ifCheckWiredInThing thing
 212   = do  { mod <- getIfModule
 213                 -- Check whether we are typechecking the interface for this
 214                 -- very module.  E.g when compiling the base library in --make mode
 215                 -- we may typecheck GHC.Base.hi. At that point, GHC.Base is not in
 216                 -- the HPT, so without the test we'll demand-load it into the PIT!
 217                 -- C.f. the same test in checkWiredInTyCon above
 218         ; let name = getName thing
 219         ; ASSERT2( isExternalName name, ppr name )
 220           when (needWiredInHomeIface thing && mod /= nameModule name)
 221                (loadWiredInHomeIface name) }
 222
 223 needWiredInHomeIface :: TyThing -> Bool
 224 -- Only for TyCons; see Note [Loading instances for wired-in things]
 225 needWiredInHomeIface (ATyCon {}) = True
 226 needWiredInHomeIface _           = False
 227 \end{code}
 228
 229 %************************************************************************
 230 %*                                                                      *
 231                 Type-checking a complete interface
 232 %*                                                                      *
 233 %************************************************************************
 234
 235 Suppose we discover we don't need to recompile.  Then we must type
 236 check the old interface file.  This is a bit different to the
 237 incremental type checking we do as we suck in interface files.  Instead
 238 we do things similarly as when we are typechecking source decls: we
 239 bring into scope the type envt for the interface all at once, using a
 240 knot.  Remember, the decls aren't necessarily in dependency order --
 241 and even if they were, the type decls might be mutually recursive.
 242
 243 \begin{code}
 244 typecheckIface :: ModIface      -- Get the decls from here
 245                -> TcRnIf gbl lcl ModDetails
 246 typecheckIface iface
 247   = initIfaceTc iface $ \ tc_env_var -> do
 248         -- The tc_env_var is freshly allocated, private to
 249         -- type-checking this particular interface
 250         {       -- Get the right set of decls and rules.  If we are compiling without -O
 251                 -- we discard pragmas before typechecking, so that we don't "see"
 252                 -- information that we shouldn't.  From a versioning point of view
 253                 -- It's not actually *wrong* to do so, but in fact GHCi is unable
 254                 -- to handle unboxed tuples, so it must not see unfoldings.
 255           ignore_prags <- doptM Opt_IgnoreInterfacePragmas
 256
 257                 -- Typecheck the decls.  This is done lazily, so that the knot-tying
 258                 -- within this single module work out right.  In the If monad there is
 259                 -- no global envt for the current interface; instead, the knot is tied
 260                 -- through the if_rec_types field of IfGblEnv
 261         ; names_w_things <- loadDecls ignore_prags (mi_decls iface)
 262         ; let type_env = mkNameEnv names_w_things
 263         ; writeMutVar tc_env_var type_env
 264
 265                 -- Now do those rules, instances and annotations
 266         ; insts     <- mapM tcIfaceInst    (mi_insts     iface)
 267         ; fam_insts <- mapM tcIfaceFamInst (mi_fam_insts iface)
 268         ; rules     <- tcIfaceRules ignore_prags (mi_rules iface)
 269         ; anns      <- tcIfaceAnnotations  (mi_anns iface)
 270
 271                 -- Vectorisation information
 272         ; vect_info <- tcIfaceVectInfo (mi_module iface) type_env
 273                                        (mi_vect_info iface)
 274
 275                 -- Exports
 276         ; exports <- ifaceExportNames (mi_exports iface)
 277
 278                 -- Finished
 279         ; traceIf (vcat [text "Finished typechecking interface for" <+> ppr (mi_module iface),
 280                          text "Type envt:" <+> ppr type_env])
 281         ; return $ ModDetails { md_types     = type_env
 282                               , md_insts     = insts
 283                               , md_fam_insts = fam_insts
 284                               , md_rules     = rules
 285                               , md_anns      = anns
 286                               , md_vect_info = vect_info
 287                               , md_exports   = exports
 288                               }
 289     }
 290 \end{code}
 291
 292
 293 %************************************************************************
 294 %*                                                                      *
 295                 Type and class declarations
 296 %*                                                                      *
 297 %************************************************************************
 298
 299 \begin{code}
 300 tcHiBootIface :: HscSource -> Module -> TcRn ModDetails
 301 -- Load the hi-boot iface for the module being compiled,
 302 -- if it indeed exists in the transitive closure of imports
 303 -- Return the ModDetails, empty if no hi-boot iface
 304 tcHiBootIface hsc_src mod
 305   | isHsBoot hsc_src            -- Already compiling a hs-boot file
 306   = return emptyModDetails
 307   | otherwise
 308   = do  { traceIf (text "loadHiBootInterface" <+> ppr mod)
 309
 310         ; mode <- getGhcMode
 311         ; if not (isOneShot mode)
 312                 -- In --make and interactive mode, if this module has an hs-boot file
 313                 -- we'll have compiled it already, and it'll be in the HPT
 314                 --
 315                 -- We check wheher the interface is a *boot* interface.
 316                 -- It can happen (when using GHC from Visual Studio) that we
 317                 -- compile a module in TypecheckOnly mode, with a stable,
 318                 -- fully-populated HPT.  In that case the boot interface isn't there
 319                 -- (it's been replaced by the mother module) so we can't check it.
 320                 -- And that's fine, because if M's ModInfo is in the HPT, then
 321                 -- it's been compiled once, and we don't need to check the boot iface
 322           then do { hpt <- getHpt
 323                   ; case lookupUFM hpt (moduleName mod) of
 324                       Just info | mi_boot (hm_iface info)
 325                                 -> return (hm_details info)
 326                       _ -> return emptyModDetails }
 327           else do
 328
 329         -- OK, so we're in one-shot mode.
 330         -- In that case, we're read all the direct imports by now,
 331         -- so eps_is_boot will record if any of our imports mention us by
 332         -- way of hi-boot file
 333         { eps <- getEps
 334         ; case lookupUFM (eps_is_boot eps) (moduleName mod) of {
 335             Nothing -> return emptyModDetails ; -- The typical case
 336
 337             Just (_, False) -> failWithTc moduleLoop ;
 338                 -- Someone below us imported us!
 339                 -- This is a loop with no hi-boot in the way
 340
 341             Just (_mod, True) ->        -- There's a hi-boot interface below us
 342
 343     do  { read_result <- findAndReadIface
 344                                 need mod
 345                                 True    -- Hi-boot file
 346
 347         ; case read_result of
 348                 Failed err               -> failWithTc (elaborate err)
 349                 Succeeded (iface, _path) -> typecheckIface iface
 350     }}}}
 351   where
 352     need = ptext (sLit "Need the hi-boot interface for") <+> ppr mod
 353                  <+> ptext (sLit "to compare against the Real Thing")
 354
 355     moduleLoop = ptext (sLit "Circular imports: module") <+> quotes (ppr mod)
 356                      <+> ptext (sLit "depends on itself")
 357
 358     elaborate err = hang (ptext (sLit "Could not find hi-boot interface for") <+>
 359                           quotes (ppr mod) <> colon) 4 err
 360 \end{code}
 361
 362
 363 %************************************************************************
 364 %*                                                                      *
 365                 Type and class declarations
 366 %*                                                                      *
 367 %************************************************************************
 368
 369 When typechecking a data type decl, we *lazily* (via forkM) typecheck
 370 the constructor argument types.  This is in the hope that we may never
 371 poke on those argument types, and hence may never need to load the
 372 interface files for types mentioned in the arg types.
 373
 374 E.g.
 375         data Foo.S = MkS Baz.T
 376 Mabye we can get away without even loading the interface for Baz!
 377
 378 This is not just a performance thing.  Suppose we have
 379         data Foo.S = MkS Baz.T
 380         data Baz.T = MkT Foo.S
 381 (in different interface files, of course).
 382 Now, first we load and typecheck Foo.S, and add it to the type envt.
 383 If we do explore MkS's argument, we'll load and typecheck Baz.T.
 384 If we explore MkT's argument we'll find Foo.S already in the envt.
 385
 386 If we typechecked constructor args eagerly, when loading Foo.S we'd try to
 387 typecheck the type Baz.T.  So we'd fault in Baz.T... and then need Foo.S...
 388 which isn't done yet.
 389
 390 All very cunning. However, there is a rather subtle gotcha which bit
 391 me when developing this stuff.  When we typecheck the decl for S, we
 392 extend the type envt with S, MkS, and all its implicit Ids.  Suppose
 393 (a bug, but it happened) that the list of implicit Ids depended in
 394 turn on the constructor arg types.  Then the following sequence of
 395 events takes place:
 396         * we build a thunk <t> for the constructor arg tys
 397         * we build a thunk for the extended type environment (depends on <t>)
 398         * we write the extended type envt into the global EPS mutvar
 399
 400 Now we look something up in the type envt
 401         * that pulls on <t>
 402         * which reads the global type envt out of the global EPS mutvar
 403         * but that depends in turn on <t>
 404
 405 It's subtle, because, it'd work fine if we typechecked the constructor args
 406 eagerly -- they don't need the extended type envt.  They just get the extended
 407 type envt by accident, because they look at it later.
 408
 409 What this means is that the implicitTyThings MUST NOT DEPEND on any of
 410 the forkM stuff.
 411
 412
 413 \begin{code}
 414 tcIfaceDecl :: Bool     -- True <=> discard IdInfo on IfaceId bindings
 415             -> IfaceDecl
 416             -> IfL TyThing
 417 tcIfaceDecl = tc_iface_decl NoParentTyCon
 418
 419 tc_iface_decl :: TyConParent    -- For nested declarations
 420               -> Bool   -- True <=> discard IdInfo on IfaceId bindings
 421               -> IfaceDecl
 422               -> IfL TyThing
 423 tc_iface_decl _ ignore_prags (IfaceId {ifName = occ_name, ifType = iface_type,
 424                                        ifIdDetails = details, ifIdInfo = info})
 425   = do  { name <- lookupIfaceTop occ_name
 426         ; ty <- tcIfaceType iface_type
 427         ; details <- tcIdDetails ty details
 428         ; info <- tcIdInfo ignore_prags name ty info
 429         ; return (AnId (mkGlobalId details name ty info)) }
 430
 431 tc_iface_decl parent _ (IfaceData {ifName = occ_name,
 432                           ifTyVars = tv_bndrs,
 433                           ifCtxt = ctxt, ifGadtSyntax = gadt_syn,
 434                           ifCons = rdr_cons,
 435                           ifRec = is_rec,
 436                           ifFamInst = mb_family })
 437   = bindIfaceTyVars_AT tv_bndrs $ \ tyvars -> do
 438     { tc_name <- lookupIfaceTop occ_name
 439     ; tycon <- fixM ( \ tycon -> do
 440             { stupid_theta <- tcIfaceCtxt ctxt
 441             ; cons <- tcIfaceDataCons tc_name tycon tyvars rdr_cons
 442             ; mb_fam_inst  <- tcFamInst mb_family
 443             ; buildAlgTyCon tc_name tyvars stupid_theta cons is_rec
 444                             gadt_syn parent mb_fam_inst
 445             })
 446     ; traceIf (text "tcIfaceDecl4" <+> ppr tycon)
 447     ; return (ATyCon tycon) }
 448
 449 tc_iface_decl parent _ (IfaceSyn {ifName = occ_name, ifTyVars = tv_bndrs,
 450                                   ifSynRhs = mb_rhs_ty,
 451                                   ifSynKind = kind, ifFamInst = mb_family})
 452    = bindIfaceTyVars_AT tv_bndrs $ \ tyvars -> do
 453      { tc_name  <- lookupIfaceTop occ_name
 454      ; rhs_kind <- tcIfaceType kind     -- Note [Synonym kind loop]
 455      ; rhs      <- forkM (mk_doc tc_name) $
 456                    tc_syn_rhs mb_rhs_ty
 457      ; fam_info <- tcFamInst mb_family
 458      ; tycon <- buildSynTyCon tc_name tyvars rhs rhs_kind parent fam_info
 459      ; return (ATyCon tycon)
 460      }
 461    where
 462      mk_doc n = ptext (sLit "Type syonym") <+> ppr n
 463      tc_syn_rhs Nothing   = return SynFamilyTyCon
 464      tc_syn_rhs (Just ty) = do { rhs_ty <- tcIfaceType ty
 465                                ; return (SynonymTyCon rhs_ty) }
 466
 467 tc_iface_decl _parent ignore_prags
 468             (IfaceClass {ifCtxt = rdr_ctxt, ifName = occ_name,
 469                          ifTyVars = tv_bndrs, ifFDs = rdr_fds,
 470                          ifATs = rdr_ats, ifSigs = rdr_sigs,
 471                          ifRec = tc_isrec })
 472 -- ToDo: in hs-boot files we should really treat abstract classes specially,
 473 --       as we do abstract tycons
 474   = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 475     { cls_name <- lookupIfaceTop occ_name
 476     ; ctxt <- tcIfaceCtxt rdr_ctxt
 477     ; sigs <- mapM tc_sig rdr_sigs
 478     ; fds  <- mapM tc_fd rdr_fds
 479     ; cls  <- fixM $ \ cls -> do
 480               { ats  <- mapM (tc_iface_decl (AssocFamilyTyCon cls) ignore_prags) rdr_ats
 481               ; buildClass ignore_prags cls_name tyvars ctxt fds ats sigs tc_isrec }
 482     ; return (AClass cls) }
 483   where
 484    tc_sig (IfaceClassOp occ dm rdr_ty)
 485      = do { op_name <- lookupIfaceTop occ
 486           ; op_ty   <- forkM (mk_doc op_name rdr_ty) (tcIfaceType rdr_ty)
 487                 -- Must be done lazily for just the same reason as the
 488                 -- type of a data con; to avoid sucking in types that
 489                 -- it mentions unless it's necessray to do so
 490           ; return (op_name, dm, op_ty) }
 491
 492    mk_doc op_name op_ty = ptext (sLit "Class op") <+> sep [ppr op_name, ppr op_ty]
 493
 494    tc_fd (tvs1, tvs2) = do { tvs1' <- mapM tcIfaceTyVar tvs1
 495                            ; tvs2' <- mapM tcIfaceTyVar tvs2
 496                            ; return (tvs1', tvs2') }
 497
 498 tc_iface_decl _ _ (IfaceForeign {ifName = rdr_name, ifExtName = ext_name})
 499   = do  { name <- lookupIfaceTop rdr_name
 500         ; return (ATyCon (mkForeignTyCon name ext_name
 501                                          liftedTypeKind 0)) }
 502
 503 tcFamInst :: Maybe (IfaceTyCon, [IfaceType]) -> IfL (Maybe (TyCon, [Type]))
 504 tcFamInst Nothing           = return Nothing
 505 tcFamInst (Just (fam, tys)) = do { famTyCon <- tcIfaceTyCon fam
 506                                  ; insttys <- mapM tcIfaceType tys
 507                                  ; return $ Just (famTyCon, insttys) }
 508
 509 tcIfaceDataCons :: Name -> TyCon -> [TyVar] -> IfaceConDecls -> IfL AlgTyConRhs
 510 tcIfaceDataCons tycon_name tycon _ if_cons
 511   = case if_cons of
 512         IfAbstractTyCon  -> return mkAbstractTyConRhs
 513         IfOpenDataTyCon  -> return DataFamilyTyCon
 514         IfDataTyCon cons -> do  { data_cons <- mapM tc_con_decl cons
 515                                 ; return (mkDataTyConRhs data_cons) }
 516         IfNewTyCon con   -> do  { data_con <- tc_con_decl con
 517                                 ; mkNewTyConRhs tycon_name tycon data_con }
 518   where
 519     tc_con_decl (IfCon { ifConInfix = is_infix,
 520                          ifConUnivTvs = univ_tvs, ifConExTvs = ex_tvs,
 521                          ifConOcc = occ, ifConCtxt = ctxt, ifConEqSpec = spec,
 522                          ifConArgTys = args, ifConFields = field_lbls,
 523                          ifConStricts = stricts})
 524      = bindIfaceTyVars univ_tvs $ \ univ_tyvars -> do
 525        bindIfaceTyVars ex_tvs    $ \ ex_tyvars -> do
 526         { name  <- lookupIfaceTop occ
 527         ; eq_spec <- tcIfaceEqSpec spec
 528         ; theta <- tcIfaceCtxt ctxt     -- Laziness seems not worth the bother here
 529                 -- At one stage I thought that this context checking *had*
 530                 -- to be lazy, because of possible mutual recursion between the
 531                 -- type and the classe:
 532                 -- E.g.
 533                 --      class Real a where { toRat :: a -> Ratio Integer }
 534                 --      data (Real a) => Ratio a = ...
 535                 -- But now I think that the laziness in checking class ops breaks
 536                 -- the loop, so no laziness needed
 537
 538         -- Read the argument types, but lazily to avoid faulting in
 539         -- the component types unless they are really needed
 540         ; arg_tys <- forkM (mk_doc name) (mapM tcIfaceType args)
 541         ; lbl_names <- mapM lookupIfaceTop field_lbls
 542
 543         -- Remember, tycon is the representation tycon
 544         ; let orig_res_ty = mkFamilyTyConApp tycon
 545                                 (substTyVars (mkTopTvSubst eq_spec) univ_tyvars)
 546
 547         ; buildDataCon name is_infix {- Not infix -}
 548                        stricts lbl_names
 549                        univ_tyvars ex_tyvars
 550                        eq_spec theta
 551                        arg_tys orig_res_ty tycon
 552         }
 553     mk_doc con_name = ptext (sLit "Constructor") <+> ppr con_name
 554
 555 tcIfaceEqSpec :: [(OccName, IfaceType)] -> IfL [(TyVar, Type)]
 556 tcIfaceEqSpec spec
 557   = mapM do_item spec
 558   where
 559     do_item (occ, if_ty) = do { tv <- tcIfaceTyVar (occNameFS occ)
 560                               ; ty <- tcIfaceType if_ty
 561                               ; return (tv,ty) }
 562 \end{code}
 563
 564 Note [Synonym kind loop]
 565 ~~~~~~~~~~~~~~~~~~~~~~~~
 566 Notice that we eagerly grab the *kind* from the interface file, but
 567 build a forkM thunk for the *rhs* (and family stuff).  To see why,
 568 consider this (Trac #2412)
 569
 570 M.hs:       module M where { import X; data T = MkT S }
 571 X.hs:       module X where { import {-# SOURCE #-} M; type S = T }
 572 M.hs-boot:  module M where { data T }
 573
 574 When kind-checking M.hs we need S's kind.  But we do not want to
 575 find S's kind from (typeKind S-rhs), because we don't want to look at
 576 S-rhs yet!  Since S is imported from X.hi, S gets just one chance to
 577 be defined, and we must not do that until we've finished with M.T.
 578
 579 Solution: record S's kind in the interface file; now we can safely
 580 look at it.
 581
 582 %************************************************************************
 583 %*                                                                      *
 584                 Instances
 585 %*                                                                      *
 586 %************************************************************************
 587
 588 \begin{code}
 589 tcIfaceInst :: IfaceInst -> IfL Instance
 590 tcIfaceInst (IfaceInst { ifDFun = dfun_occ, ifOFlag = oflag,
 591                          ifInstCls = cls, ifInstTys = mb_tcs })
 592   = do  { dfun    <- forkM (ptext (sLit "Dict fun") <+> ppr dfun_occ) $
 593                      tcIfaceExtId dfun_occ
 594         ; let mb_tcs' = map (fmap ifaceTyConName) mb_tcs
 595         ; return (mkImportedInstance cls mb_tcs' dfun oflag) }
 596
 597 tcIfaceFamInst :: IfaceFamInst -> IfL FamInst
 598 tcIfaceFamInst (IfaceFamInst { ifFamInstTyCon = tycon,
 599                                ifFamInstFam = fam, ifFamInstTys = mb_tcs })
 600 --      { tycon'  <- forkM (ptext (sLit "Inst tycon") <+> ppr tycon) $
 601 -- the above line doesn't work, but this below does => CPP in Haskell = evil!
 602     = do tycon'  <- forkM (text ("Inst tycon") <+> ppr tycon) $
 603                     tcIfaceTyCon tycon
 604          let mb_tcs' = map (fmap ifaceTyConName) mb_tcs
 605          return (mkImportedFamInst fam mb_tcs' tycon')
 606 \end{code}
 607
 608
 609 %************************************************************************
 610 %*                                                                      *
 611                 Rules
 612 %*                                                                      *
 613 %************************************************************************
 614
 615 We move a IfaceRule from eps_rules to eps_rule_base when all its LHS free vars
 616 are in the type environment.  However, remember that typechecking a Rule may
 617 (as a side effect) augment the type envt, and so we may need to iterate the process.
 618
 619 \begin{code}
 620 tcIfaceRules :: Bool            -- True <=> ignore rules
 621              -> [IfaceRule]
 622              -> IfL [CoreRule]
 623 tcIfaceRules ignore_prags if_rules
 624   | ignore_prags = return []
 625   | otherwise    = mapM tcIfaceRule if_rules
 626
 627 tcIfaceRule :: IfaceRule -> IfL CoreRule
 628 tcIfaceRule (IfaceRule {ifRuleName = name, ifActivation = act, ifRuleBndrs = bndrs,
 629                         ifRuleHead = fn, ifRuleArgs = args, ifRuleRhs = rhs,
 630                         ifRuleAuto = auto })
 631   = do  { ~(bndrs', args', rhs') <-
 632                 -- Typecheck the payload lazily, in the hope it'll never be looked at
 633                 forkM (ptext (sLit "Rule") <+> ftext name) $
 634                 bindIfaceBndrs bndrs                      $ \ bndrs' ->
 635                 do { args' <- mapM tcIfaceExpr args
 636                    ; rhs'  <- tcIfaceExpr rhs
 637                    ; return (bndrs', args', rhs') }
 638         ; let mb_tcs = map ifTopFreeName args
 639         ; return (Rule { ru_name = name, ru_fn = fn, ru_act = act,
 640                           ru_bndrs = bndrs', ru_args = args',
 641                           ru_rhs = occurAnalyseExpr rhs',
 642                           ru_rough = mb_tcs,
 643                           ru_auto = auto,
 644                           ru_local = False }) } -- An imported RULE is never for a local Id
 645                                                 -- or, even if it is (module loop, perhaps)
 646                                                 -- we'll just leave it in the non-local set
 647   where
 648         -- This function *must* mirror exactly what Rules.topFreeName does
 649         -- We could have stored the ru_rough field in the iface file
 650         -- but that would be redundant, I think.
 651         -- The only wrinkle is that we must not be deceived by
 652         -- type syononyms at the top of a type arg.  Since
 653         -- we can't tell at this point, we are careful not
 654         -- to write them out in coreRuleToIfaceRule
 655     ifTopFreeName :: IfaceExpr -> Maybe Name
 656     ifTopFreeName (IfaceType (IfaceTyConApp tc _ )) = Just (ifaceTyConName tc)
 657     ifTopFreeName (IfaceApp f _)                    = ifTopFreeName f
 658     ifTopFreeName (IfaceExt n)                      = Just n
 659     ifTopFreeName _                                 = Nothing
 660 \end{code}
 661
 662
 663 %************************************************************************
 664 %*                                                                      *
 665                 Annotations
 666 %*                                                                      *
 667 %************************************************************************
 668
 669 \begin{code}
 670 tcIfaceAnnotations :: [IfaceAnnotation] -> IfL [Annotation]
 671 tcIfaceAnnotations = mapM tcIfaceAnnotation
 672
 673 tcIfaceAnnotation :: IfaceAnnotation -> IfL Annotation
 674 tcIfaceAnnotation (IfaceAnnotation target serialized) = do
 675     target' <- tcIfaceAnnTarget target
 676     return $ Annotation {
 677         ann_target = target',
 678         ann_value = serialized
 679     }
 680
 681 tcIfaceAnnTarget :: IfaceAnnTarget -> IfL (AnnTarget Name)
 682 tcIfaceAnnTarget (NamedTarget occ) = do
 683     name <- lookupIfaceTop occ
 684     return $ NamedTarget name
 685 tcIfaceAnnTarget (ModuleTarget mod) = do
 686     return $ ModuleTarget mod
 687
 688 \end{code}
 689
 690
 691 %************************************************************************
 692 %*                                                                      *
 693                 Vectorisation information
 694 %*                                                                      *
 695 %************************************************************************
 696
 697 \begin{code}
 698 tcIfaceVectInfo :: Module -> TypeEnv  -> IfaceVectInfo -> IfL VectInfo
 699 tcIfaceVectInfo mod typeEnv (IfaceVectInfo
 700                              { ifaceVectInfoVar        = vars
 701                              , ifaceVectInfoTyCon      = tycons
 702                              , ifaceVectInfoTyConReuse = tyconsReuse
 703                              })
 704   = do { vVars     <- mapM vectVarMapping vars
 705        ; tyConRes1 <- mapM vectTyConMapping      tycons
 706        ; tyConRes2 <- mapM vectTyConReuseMapping tyconsReuse
 707        ; let (vTyCons, vDataCons, vPAs, vIsos) = unzip4 (tyConRes1 ++ tyConRes2)
 708        ; return $ VectInfo
 709                   { vectInfoVar     = mkVarEnv  vVars
 710                   , vectInfoTyCon   = mkNameEnv vTyCons
 711                   , vectInfoDataCon = mkNameEnv (concat vDataCons)
 712                   , vectInfoPADFun  = mkNameEnv vPAs
 713                   , vectInfoIso     = mkNameEnv vIsos
 714                   }
 715        }
 716   where
 717     vectVarMapping name
 718       = do { vName <- lookupOrig mod (mkVectOcc (nameOccName name))
 719            ; let { var  = lookupVar name
 720                  ; vVar = lookupVar vName
 721                  }
 722            ; return (var, (var, vVar))
 723            }
 724     vectTyConMapping name
 725       = do { vName   <- lookupOrig mod (mkVectTyConOcc (nameOccName name))
 726            ; paName  <- lookupOrig mod (mkPADFunOcc    (nameOccName name))
 727            ; isoName <- lookupOrig mod (mkVectIsoOcc   (nameOccName name))
 728            ; let { tycon    = lookupTyCon name
 729                  ; vTycon   = lookupTyCon vName
 730                  ; paTycon  = lookupVar paName
 731                  ; isoTycon = lookupVar isoName
 732                  }
 733            ; vDataCons <- mapM vectDataConMapping (tyConDataCons tycon)
 734            ; return ((name, (tycon, vTycon)),    -- (T, T_v)
 735                      vDataCons,                  -- list of (Ci, Ci_v)
 736                      (vName, (vTycon, paTycon)), -- (T_v, paT)
 737                      (name, (tycon, isoTycon)))  -- (T, isoT)
 738            }
 739     vectTyConReuseMapping name
 740       = do { paName  <- lookupOrig mod (mkPADFunOcc    (nameOccName name))
 741            ; isoName <- lookupOrig mod (mkVectIsoOcc   (nameOccName name))
 742            ; let { tycon      = lookupTyCon name
 743                  ; paTycon    = lookupVar paName
 744                  ; isoTycon   = lookupVar isoName
 745                  ; vDataCons  = [ (dataConName dc, (dc, dc))
 746                                 | dc <- tyConDataCons tycon]
 747                  }
 748            ; return ((name, (tycon, tycon)),     -- (T, T)
 749                      vDataCons,                  -- list of (Ci, Ci)
 750                      (name, (tycon, paTycon)),   -- (T, paT)
 751                      (name, (tycon, isoTycon)))  -- (T, isoT)
 752            }
 753     vectDataConMapping datacon
 754       = do { let name = dataConName datacon
 755            ; vName <- lookupOrig mod (mkVectDataConOcc (nameOccName name))
 756            ; let vDataCon = lookupDataCon vName
 757            ; return (name, (datacon, vDataCon))
 758            }
 759     --
 760     lookupVar name = case lookupTypeEnv typeEnv name of
 761                        Just (AnId var) -> var
 762                        Just _         ->
 763                          panic "TcIface.tcIfaceVectInfo: not an id"
 764                        Nothing        ->
 765                          panic "TcIface.tcIfaceVectInfo: unknown name"
 766     lookupTyCon name = case lookupTypeEnv typeEnv name of
 767                          Just (ATyCon tc) -> tc
 768                          Just _         ->
 769                            panic "TcIface.tcIfaceVectInfo: not a tycon"
 770                          Nothing        ->
 771                            panic "TcIface.tcIfaceVectInfo: unknown name"
 772     lookupDataCon name = case lookupTypeEnv typeEnv name of
 773                            Just (ADataCon dc) -> dc
 774                            Just _         ->
 775                              panic "TcIface.tcIfaceVectInfo: not a datacon"
 776                            Nothing        ->
 777                              panic "TcIface.tcIfaceVectInfo: unknown name"
 778 \end{code}
 779
 780 %************************************************************************
 781 %*                                                                      *
 782                         Types
 783 %*                                                                      *
 784 %************************************************************************
 785
 786 \begin{code}
 787 tcIfaceType :: IfaceType -> IfL Type
 788 tcIfaceType (IfaceTyVar n)        = do { tv <- tcIfaceTyVar n; return (TyVarTy tv) }
 789 tcIfaceType (IfaceAppTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (AppTy t1' t2') }
 790 tcIfaceType (IfaceFunTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (FunTy t1' t2') }
 791 tcIfaceType (IfaceTyConApp tc ts) = do { tc' <- tcIfaceTyCon tc; ts' <- tcIfaceTypes ts; return (mkTyConApp tc' ts') }
 792 tcIfaceType (IfaceForAllTy tv t)  = bindIfaceTyVar tv $ \ tv' -> do { t' <- tcIfaceType t; return (ForAllTy tv' t') }
 793 tcIfaceType (IfacePredTy st)      = do { st' <- tcIfacePred tcIfaceType st; return (PredTy st') }
 794 tcIfaceType t@(IfaceCoConApp {})  = pprPanic "tcIfaceType" (ppr t)
 795
 796 tcIfaceTypes :: [IfaceType] -> IfL [Type]
 797 tcIfaceTypes tys = mapM tcIfaceType tys
 798
 799 -----------------------------------------
 800 tcIfacePred :: (IfaceType -> IfL a) -> IfacePredType -> IfL (Pred a)
 801 tcIfacePred tc (IfaceClassP cls ts)
 802   = do { cls' <- tcIfaceClass cls; ts' <- mapM tc ts; return (ClassP cls' ts') }
 803 tcIfacePred tc (IfaceIParam ip t)
 804   = do { ip' <- newIPName ip; t' <- tc t; return (IParam ip' t') }
 805 tcIfacePred tc (IfaceEqPred t1 t2)
 806   = do { t1' <- tc t1; t2' <- tc t2; return (EqPred t1' t2') }
 807
 808 -----------------------------------------
 809 tcIfaceCtxt :: IfaceContext -> IfL ThetaType
 810 tcIfaceCtxt sts = mapM (tcIfacePred tcIfaceType) sts
 811 \end{code}
 812
 813 %************************************************************************
 814 %*                                                                      *
 815                         Coercions
 816 %*                                                                      *
 817 %************************************************************************
 818
 819 \begin{code}
 820 tcIfaceCo :: IfaceType -> IfL Coercion
 821 tcIfaceCo (IfaceTyVar n)        = mkCoVarCo <$> tcIfaceCoVar n
 822 tcIfaceCo (IfaceAppTy t1 t2)    = mkAppCo <$> tcIfaceCo t1 <*> tcIfaceCo t2
 823 tcIfaceCo (IfaceFunTy t1 t2)    = mkFunCo <$> tcIfaceCo t1 <*> tcIfaceCo t2
 824 tcIfaceCo (IfaceTyConApp tc ts) = mkTyConAppCo <$> tcIfaceTyCon tc <*> mapM tcIfaceCo ts
 825 tcIfaceCo (IfaceCoConApp tc ts) = tcIfaceCoApp tc ts
 826 tcIfaceCo (IfaceForAllTy tv t)  = bindIfaceTyVar tv $ \ tv' ->
 827                                   mkForAllCo tv' <$> tcIfaceCo t
 828 -- tcIfaceCo (IfacePredTy co)      = mkPredCo <$> tcIfacePred tcIfaceCo co
 829 tcIfaceCo (IfacePredTy _)      = panic "tcIfaceCo"
 830
 831 tcIfaceCoApp :: IfaceCoCon -> [IfaceType] -> IfL Coercion
 832 tcIfaceCoApp IfaceReflCo    [t]     = Refl         <$> tcIfaceType t
 833 tcIfaceCoApp (IfaceCoAx n)  ts      = AxiomInstCo  <$> tcIfaceCoAxiom n <*> mapM tcIfaceCo ts
 834 tcIfaceCoApp IfaceUnsafeCo  [t1,t2] = UnsafeCo     <$> tcIfaceType t1 <*> tcIfaceType t2
 835 tcIfaceCoApp IfaceSymCo     [t]     = SymCo        <$> tcIfaceCo t
 836 tcIfaceCoApp IfaceTransCo   [t1,t2] = TransCo      <$> tcIfaceCo t1 <*> tcIfaceCo t2
 837 tcIfaceCoApp IfaceInstCo    [t1,t2] = InstCo       <$> tcIfaceCo t1 <*> tcIfaceType t2
 838 tcIfaceCoApp (IfaceNthCo d) [t]     = NthCo d      <$> tcIfaceCo t
 839 tcIfaceCoApp cc ts = pprPanic "toIfaceCoApp" (ppr cc <+> ppr ts)
 840
 841 tcIfaceCoVar :: FastString -> IfL CoVar
 842 tcIfaceCoVar = tcIfaceLclId
 843 \end{code}
 844
 845
 846 %************************************************************************
 847 %*                                                                      *
 848                         Core
 849 %*                                                                      *
 850 %************************************************************************
 851
 852 \begin{code}
 853 tcIfaceExpr :: IfaceExpr -> IfL CoreExpr
 854 tcIfaceExpr (IfaceType ty)
 855   = Type <$> tcIfaceType ty
 856
 857 tcIfaceExpr (IfaceCo co)
 858   = Coercion <$> tcIfaceCo co
 859
 860 tcIfaceExpr (IfaceCast expr co)
 861   = Cast <$> tcIfaceExpr expr <*> tcIfaceCo co
 862
 863 tcIfaceExpr (IfaceLcl name)
 864   = Var <$> tcIfaceLclId name
 865
 866 tcIfaceExpr (IfaceTick modName tickNo)
 867   = Var <$> tcIfaceTick modName tickNo
 868
 869 tcIfaceExpr (IfaceExt gbl)
 870   = Var <$> tcIfaceExtId gbl
 871
 872 tcIfaceExpr (IfaceLit lit)
 873   = return (Lit lit)
 874
 875 tcIfaceExpr (IfaceFCall cc ty) = do
 876     ty' <- tcIfaceType ty
 877     u <- newUnique
 878     return (Var (mkFCallId u cc ty'))
 879
 880 tcIfaceExpr (IfaceTuple boxity args)  = do
 881     args' <- mapM tcIfaceExpr args
 882     -- Put the missing type arguments back in
 883     let con_args = map (Type . exprType) args' ++ args'
 884     return (mkApps (Var con_id) con_args)
 885   where
 886     arity = length args
 887     con_id = dataConWorkId (tupleCon boxity arity)
 888
 889
 890 tcIfaceExpr (IfaceLam bndr body)
 891   = bindIfaceBndr bndr $ \bndr' ->
 892     Lam bndr' <$> tcIfaceExpr body
 893
 894 tcIfaceExpr (IfaceApp fun arg)
 895   = App <$> tcIfaceExpr fun <*> tcIfaceExpr arg
 896
 897 tcIfaceExpr (IfaceCase scrut case_bndr alts)  = do
 898     scrut' <- tcIfaceExpr scrut
 899     case_bndr_name <- newIfaceName (mkVarOccFS case_bndr)
 900     let
 901         scrut_ty   = exprType scrut'
 902         case_bndr' = mkLocalId case_bndr_name scrut_ty
 903         tc_app     = splitTyConApp scrut_ty
 904                 -- NB: Won't always succeed (polymoprhic case)
 905                 --     but won't be demanded in those cases
 906                 -- NB: not tcSplitTyConApp; we are looking at Core here
 907                 --     look through non-rec newtypes to find the tycon that
 908                 --     corresponds to the datacon in this case alternative
 909
 910     extendIfaceIdEnv [case_bndr'] $ do
 911      alts' <- mapM (tcIfaceAlt scrut' tc_app) alts
 912      return (Case scrut' case_bndr' (coreAltsType alts') alts')
 913
 914 tcIfaceExpr (IfaceLet (IfaceNonRec (IfLetBndr fs ty info) rhs) body)
 915   = do  { name    <- newIfaceName (mkVarOccFS fs)
 916         ; ty'     <- tcIfaceType ty
 917         ; id_info <- tcIdInfo False {- Don't ignore prags; we are inside one! -}
 918                               name ty' info
 919         ; let id = mkLocalIdWithInfo name ty' id_info
 920         ; rhs' <- tcIfaceExpr rhs
 921         ; body' <- extendIfaceIdEnv [id] (tcIfaceExpr body)
 922         ; return (Let (NonRec id rhs') body') }
 923
 924 tcIfaceExpr (IfaceLet (IfaceRec pairs) body)
 925   = do { ids <- mapM tc_rec_bndr (map fst pairs)
 926        ; extendIfaceIdEnv ids $ do
 927        { pairs' <- zipWithM tc_pair pairs ids
 928        ; body' <- tcIfaceExpr body
 929        ; return (Let (Rec pairs') body') } }
 930  where
 931    tc_rec_bndr (IfLetBndr fs ty _)
 932      = do { name <- newIfaceName (mkVarOccFS fs)
 933           ; ty'  <- tcIfaceType ty
 934           ; return (mkLocalId name ty') }
 935    tc_pair (IfLetBndr _ _ info, rhs) id
 936      = do { rhs' <- tcIfaceExpr rhs
 937           ; id_info <- tcIdInfo False {- Don't ignore prags; we are inside one! -}
 938                                 (idName id) (idType id) info
 939           ; return (setIdInfo id id_info, rhs') }
 940
 941 tcIfaceExpr (IfaceNote note expr) = do
 942     expr' <- tcIfaceExpr expr
 943     case note of
 944         IfaceSCC cc       -> return (Note (SCC cc)   expr')
 945         IfaceCoreNote n   -> return (Note (CoreNote n) expr')
 946
 947 -------------------------
 948 tcIfaceAlt :: CoreExpr -> (TyCon, [Type])
 949            -> (IfaceConAlt, [FastString], IfaceExpr)
 950            -> IfL (AltCon, [TyVar], CoreExpr)
 951 tcIfaceAlt _ _ (IfaceDefault, names, rhs)
 952   = ASSERT( null names ) do
 953     rhs' <- tcIfaceExpr rhs
 954     return (DEFAULT, [], rhs')
 955
 956 tcIfaceAlt _ _ (IfaceLitAlt lit, names, rhs)
 957   = ASSERT( null names ) do
 958     rhs' <- tcIfaceExpr rhs
 959     return (LitAlt lit, [], rhs')
 960
 961 -- A case alternative is made quite a bit more complicated
 962 -- by the fact that we omit type annotations because we can
 963 -- work them out.  True enough, but its not that easy!
 964 tcIfaceAlt scrut (tycon, inst_tys) (IfaceDataAlt data_occ, arg_strs, rhs)
 965   = do  { con <- tcIfaceDataCon data_occ
 966         ; when (debugIsOn && not (con `elem` tyConDataCons tycon))
 967                (failIfM (ppr scrut $$ ppr con $$ ppr tycon $$ ppr (tyConDataCons tycon)))
 968         ; tcIfaceDataAlt con inst_tys arg_strs rhs }
 969
 970 tcIfaceAlt _ (tycon, inst_tys) (IfaceTupleAlt _boxity, arg_occs, rhs)
 971   = ASSERT2( isTupleTyCon tycon, ppr tycon )
 972     do  { let [data_con] = tyConDataCons tycon
 973         ; tcIfaceDataAlt data_con inst_tys arg_occs rhs }
 974
 975 tcIfaceDataAlt :: DataCon -> [Type] -> [FastString] -> IfaceExpr
 976                -> IfL (AltCon, [TyVar], CoreExpr)
 977 tcIfaceDataAlt con inst_tys arg_strs rhs
 978   = do  { us <- newUniqueSupply
 979         ; let uniqs = uniqsFromSupply us
 980         ; let (ex_tvs, arg_ids)
 981                       = dataConRepFSInstPat arg_strs uniqs con inst_tys
 982
 983         ; rhs' <- extendIfaceTyVarEnv ex_tvs    $
 984                   extendIfaceIdEnv arg_ids      $
 985                   tcIfaceExpr rhs
 986         ; return (DataAlt con, ex_tvs ++ arg_ids, rhs') }
 987 \end{code}
 988
 989
 990 \begin{code}
 991 tcExtCoreBindings :: [IfaceBinding] -> IfL [CoreBind]   -- Used for external core
 992 tcExtCoreBindings []     = return []
 993 tcExtCoreBindings (b:bs) = do_one b (tcExtCoreBindings bs)
 994
 995 do_one :: IfaceBinding -> IfL [CoreBind] -> IfL [CoreBind]
 996 do_one (IfaceNonRec bndr rhs) thing_inside
 997   = do  { rhs' <- tcIfaceExpr rhs
 998         ; bndr' <- newExtCoreBndr bndr
 999         ; extendIfaceIdEnv [bndr'] $ do
1000         { core_binds <- thing_inside
1001         ; return (NonRec bndr' rhs' : core_binds) }}
1002
1003 do_one (IfaceRec pairs) thing_inside
1004   = do  { bndrs' <- mapM newExtCoreBndr bndrs
1005         ; extendIfaceIdEnv bndrs' $ do
1006         { rhss' <- mapM tcIfaceExpr rhss
1007         ; core_binds <- thing_inside
1008         ; return (Rec (bndrs' `zip` rhss') : core_binds) }}
1009   where
1010     (bndrs,rhss) = unzip pairs
1011 \end{code}
1012
1013
1014 %************************************************************************
1015 %*                                                                      *
1016                 IdInfo
1017 %*                                                                      *
1018 %************************************************************************
1019
1020 \begin{code}
1021 tcIdDetails :: Type -> IfaceIdDetails -> IfL IdDetails
1022 tcIdDetails _  IfVanillaId = return VanillaId
1023 tcIdDetails ty (IfDFunId ns)
1024   = return (DFunId ns (isNewTyCon (classTyCon cls)))
1025   where
1026     (_, _, cls, _) = tcSplitDFunTy ty
1027
1028 tcIdDetails _ (IfRecSelId tc naughty)
1029   = do { tc' <- tcIfaceTyCon tc
1030        ; return (RecSelId { sel_tycon = tc', sel_naughty = naughty }) }
1031
1032 tcIdInfo :: Bool -> Name -> Type -> IfaceIdInfo -> IfL IdInfo
1033 tcIdInfo ignore_prags name ty info
1034   | ignore_prags = return vanillaIdInfo
1035   | otherwise    = case info of
1036                         NoInfo       -> return vanillaIdInfo
1037                         HasInfo info -> foldlM tcPrag init_info info
1038   where
1039     -- Set the CgInfo to something sensible but uninformative before
1040     -- we start; default assumption is that it has CAFs
1041     init_info = vanillaIdInfo
1042
1043     tcPrag :: IdInfo -> IfaceInfoItem -> IfL IdInfo
1044     tcPrag info HsNoCafRefs        = return (info `setCafInfo`   NoCafRefs)
1045     tcPrag info (HsArity arity)    = return (info `setArityInfo` arity)
1046     tcPrag info (HsStrictness str) = return (info `setStrictnessInfo` Just str)
1047     tcPrag info (HsInline prag)    = return (info `setInlinePragInfo` prag)
1048
1049         -- The next two are lazy, so they don't transitively suck stuff in
1050     tcPrag info (HsUnfold lb if_unf)
1051       = do { unf <- tcUnfolding name ty info if_unf
1052            ; let info1 | lb        = info `setOccInfo` nonRuleLoopBreaker
1053                        | otherwise = info
1054            ; return (info1 `setUnfoldingInfoLazily` unf) }
1055 \end{code}
1056
1057 \begin{code}
1058 tcUnfolding :: Name -> Type -> IdInfo -> IfaceUnfolding -> IfL Unfolding
1059 tcUnfolding name _ info (IfCoreUnfold stable if_expr)
1060   = do  { mb_expr <- tcPragExpr name if_expr
1061         ; let unf_src = if stable then InlineStable else InlineRhs
1062         ; return (case mb_expr of
1063                     Nothing   -> NoUnfolding
1064                     Just expr -> mkUnfolding unf_src
1065                                              True {- Top level -}
1066                                              is_bottoming expr) }
1067   where
1068      -- Strictness should occur before unfolding!
1069     is_bottoming = case strictnessInfo info of
1070                      Just sig -> isBottomingSig sig
1071                      Nothing  -> False
1072
1073 tcUnfolding name _ _ (IfCompulsory if_expr)
1074   = do  { mb_expr <- tcPragExpr name if_expr
1075         ; return (case mb_expr of
1076                     Nothing   -> NoUnfolding
1077                     Just expr -> mkCompulsoryUnfolding expr) }
1078
1079 tcUnfolding name _ _ (IfInlineRule arity unsat_ok boring_ok if_expr)
1080   = do  { mb_expr <- tcPragExpr name if_expr
1081         ; return (case mb_expr of
1082                     Nothing   -> NoUnfolding
1083                     Just expr -> mkCoreUnfolding InlineStable True expr arity
1084                                                  (UnfWhen unsat_ok boring_ok))
1085     }
1086
1087 tcUnfolding name dfun_ty _ (IfDFunUnfold ops)
1088   = do { mb_ops1 <- forkM_maybe doc $ mapM tc_arg ops
1089        ; return (case mb_ops1 of
1090                     Nothing   -> noUnfolding
1091                     Just ops1 -> mkDFunUnfolding dfun_ty ops1) }
1092   where
1093     doc = text "Class ops for dfun" <+> ppr name
1094     tc_arg (DFunPolyArg  e) = do { e' <- tcIfaceExpr e; return (DFunPolyArg e') }
1095     tc_arg (DFunConstArg e) = do { e' <- tcIfaceExpr e; return (DFunConstArg e') }
1096     tc_arg (DFunLamArg i)   = return (DFunLamArg i)
1097
1098 tcUnfolding name ty info (IfExtWrapper arity wkr)
1099   = tcIfaceWrapper name ty info arity (tcIfaceExtId wkr)
1100 tcUnfolding name ty info (IfLclWrapper arity wkr)
1101   = tcIfaceWrapper name ty info arity (tcIfaceLclId wkr)
1102
1103 -------------
1104 tcIfaceWrapper :: Name -> Type -> IdInfo -> Arity -> IfL Id -> IfL Unfolding
1105 tcIfaceWrapper name ty info arity get_worker
1106   = do  { mb_wkr_id <- forkM_maybe doc get_worker
1107         ; us <- newUniqueSupply
1108         ; return (case mb_wkr_id of
1109                      Nothing     -> noUnfolding
1110                      Just wkr_id -> make_inline_rule wkr_id us) }
1111   where
1112     doc = text "Worker for" <+> ppr name
1113
1114     make_inline_rule wkr_id us
1115         = mkWwInlineRule wkr_id
1116                          (initUs_ us (mkWrapper ty strict_sig) wkr_id)
1117                          arity
1118
1119         -- Again we rely here on strictness info always appearing
1120         -- before unfolding
1121     strict_sig = case strictnessInfo info of
1122                    Just sig -> sig
1123                    Nothing  -> pprPanic "Worker info but no strictness for" (ppr name)
1124 \end{code}
1125
1126 For unfoldings we try to do the job lazily, so that we never type check
1127 an unfolding that isn't going to be looked at.
1128
1129 \begin{code}
1130 tcPragExpr :: Name -> IfaceExpr -> IfL (Maybe CoreExpr)
1131 tcPragExpr name expr
1132   = forkM_maybe doc $ do
1133     core_expr' <- tcIfaceExpr expr
1134
1135                 -- Check for type consistency in the unfolding
1136     ifDOptM Opt_DoCoreLinting $ do
1137         in_scope <- get_in_scope
1138         case lintUnfolding noSrcLoc in_scope core_expr' of
1139           Nothing       -> return ()
1140           Just fail_msg -> do { mod <- getIfModule
1141                               ; pprPanic "Iface Lint failure"
1142                                   (vcat [ ptext (sLit "In interface for") <+> ppr mod
1143                                         , hang doc 2 fail_msg
1144                                         , ppr name <+> equals <+> ppr core_expr'
1145                                         , ptext (sLit "Iface expr =") <+> ppr expr ]) }
1146     return core_expr'
1147   where
1148     doc = text "Unfolding of" <+> ppr name
1149
1150     get_in_scope :: IfL [Var] -- Totally disgusting; but just for linting
1151     get_in_scope
1152         = do { (gbl_env, lcl_env) <- getEnvs
1153              ; rec_ids <- case if_rec_types gbl_env of
1154                             Nothing -> return []
1155                             Just (_, get_env) -> do
1156                                { type_env <- setLclEnv () get_env
1157                                ; return (typeEnvIds type_env) }
1158              ; return (varEnvElts (if_tv_env lcl_env) ++
1159                        varEnvElts (if_id_env lcl_env) ++
1160                        rec_ids) }
1161 \end{code}
1162
1163
1164
1165 %************************************************************************
1166 %*                                                                      *
1167                 Getting from Names to TyThings
1168 %*                                                                      *
1169 %************************************************************************
1170
1171 \begin{code}
1172 tcIfaceGlobal :: Name -> IfL TyThing
1173 tcIfaceGlobal name
1174   | Just thing <- wiredInNameTyThing_maybe name
1175         -- Wired-in things include TyCons, DataCons, and Ids
1176   = do { ifCheckWiredInThing thing; return thing }
1177   | otherwise
1178   = do  { env <- getGblEnv
1179         ; case if_rec_types env of {    -- Note [Tying the knot]
1180             Just (mod, get_type_env)
1181                 | nameIsLocalOrFrom mod name
1182                 -> do           -- It's defined in the module being compiled
1183                 { type_env <- setLclEnv () get_type_env         -- yuk
1184                 ; case lookupNameEnv type_env name of
1185                         Just thing -> return thing
1186                         Nothing   -> pprPanic "tcIfaceGlobal (local): not found:"
1187                                                 (ppr name $$ ppr type_env) }
1188
1189           ; _ -> do
1190
1191         { hsc_env <- getTopEnv
1192         ; mb_thing <- liftIO (lookupTypeHscEnv hsc_env name)
1193         ; case mb_thing of {
1194             Just thing -> return thing ;
1195             Nothing    -> do
1196
1197         { mb_thing <- importDecl name   -- It's imported; go get it
1198         ; case mb_thing of
1199             Failed err      -> failIfM err
1200             Succeeded thing -> return thing
1201     }}}}}
1202
1203 -- Note [Tying the knot]
1204 -- ~~~~~~~~~~~~~~~~~~~~~
1205 -- The if_rec_types field is used in two situations:
1206 --
1207 -- a) Compiling M.hs, which indiretly imports Foo.hi, which mentions M.T
1208 --    Then we look up M.T in M's type environment, which is splatted into if_rec_types
1209 --    after we've built M's type envt.
1210 --
1211 -- b) In ghc --make, during the upsweep, we encounter M.hs, whose interface M.hi
1212 --    is up to date.  So we call typecheckIface on M.hi.  This splats M.T into
1213 --    if_rec_types so that the (lazily typechecked) decls see all the other decls
1214 --
1215 -- In case (b) it's important to do the if_rec_types check *before* looking in the HPT
1216 -- Because if M.hs also has M.hs-boot, M.T will *already be* in the HPT, but in its
1217 -- emasculated form (e.g. lacking data constructors).
1218
1219 tcIfaceTyCon :: IfaceTyCon -> IfL TyCon
1220 tcIfaceTyCon IfaceIntTc         = tcWiredInTyCon intTyCon
1221 tcIfaceTyCon IfaceBoolTc        = tcWiredInTyCon boolTyCon
1222 tcIfaceTyCon IfaceCharTc        = tcWiredInTyCon charTyCon
1223 tcIfaceTyCon IfaceListTc        = tcWiredInTyCon listTyCon
1224 tcIfaceTyCon IfacePArrTc        = tcWiredInTyCon parrTyCon
1225 tcIfaceTyCon (IfaceTupTc bx ar) = tcWiredInTyCon (tupleTyCon bx ar)
1226 tcIfaceTyCon (IfaceAnyTc kind)  = do { tc_kind <- tcIfaceType kind
1227                                      ; tcWiredInTyCon (anyTyConOfKind tc_kind) }
1228 tcIfaceTyCon (IfaceTc name)     = do { thing <- tcIfaceGlobal name
1229                                      ; return (check_tc (tyThingTyCon thing)) }
1230   where
1231     check_tc tc
1232      | debugIsOn = case toIfaceTyCon tc of
1233                    IfaceTc _ -> tc
1234                    _         -> pprTrace "check_tc" (ppr tc) tc
1235      | otherwise = tc
1236 -- we should be okay just returning Kind constructors without extra loading
1237 tcIfaceTyCon IfaceLiftedTypeKindTc   = return liftedTypeKindTyCon
1238 tcIfaceTyCon IfaceOpenTypeKindTc     = return openTypeKindTyCon
1239 tcIfaceTyCon IfaceUnliftedTypeKindTc = return unliftedTypeKindTyCon
1240 tcIfaceTyCon IfaceArgTypeKindTc      = return argTypeKindTyCon
1241 tcIfaceTyCon IfaceUbxTupleKindTc     = return ubxTupleKindTyCon
1242
1243 -- Even though we are in an interface file, we want to make
1244 -- sure the instances and RULES of this tycon are loaded
1245 -- Imagine: f :: Double -> Double
1246 tcWiredInTyCon :: TyCon -> IfL TyCon
1247 tcWiredInTyCon tc = do { ifCheckWiredInThing (ATyCon tc)
1248                        ; return tc }
1249
1250 tcIfaceClass :: Name -> IfL Class
1251 tcIfaceClass name = do { thing <- tcIfaceGlobal name
1252                        ; return (tyThingClass thing) }
1253
1254 tcIfaceCoAxiom :: Name -> IfL CoAxiom
1255 tcIfaceCoAxiom name = do { thing <- tcIfaceGlobal name
1256                          ; return (tyThingCoAxiom thing) }
1257
1258 tcIfaceDataCon :: Name -> IfL DataCon
1259 tcIfaceDataCon name = do { thing <- tcIfaceGlobal name
1260                          ; case thing of
1261                                 ADataCon dc -> return dc
1262                                 _       -> pprPanic "tcIfaceExtDC" (ppr name$$ ppr thing) }
1263
1264 tcIfaceExtId :: Name -> IfL Id
1265 tcIfaceExtId name = do { thing <- tcIfaceGlobal name
1266                        ; case thing of
1267                           AnId id -> return id
1268                           _       -> pprPanic "tcIfaceExtId" (ppr name$$ ppr thing) }
1269 \end{code}
1270
1271 %************************************************************************
1272 %*                                                                      *
1273                 Bindings
1274 %*                                                                      *
1275 %************************************************************************
1276
1277 \begin{code}
1278 bindIfaceBndr :: IfaceBndr -> (CoreBndr -> IfL a) -> IfL a
1279 bindIfaceBndr (IfaceIdBndr (fs, ty)) thing_inside
1280   = do  { name <- newIfaceName (mkVarOccFS fs)
1281         ; ty' <- tcIfaceType ty
1282         ; let id = mkLocalId name ty'
1283         ; extendIfaceIdEnv [id] (thing_inside id) }
1284 bindIfaceBndr (IfaceTvBndr bndr) thing_inside
1285   = bindIfaceTyVar bndr thing_inside
1286
1287 bindIfaceBndrs :: [IfaceBndr] -> ([CoreBndr] -> IfL a) -> IfL a
1288 bindIfaceBndrs []     thing_inside = thing_inside []
1289 bindIfaceBndrs (b:bs) thing_inside
1290   = bindIfaceBndr b     $ \ b' ->
1291     bindIfaceBndrs bs   $ \ bs' ->
1292     thing_inside (b':bs')
1293
1294 -----------------------
1295 newExtCoreBndr :: IfaceLetBndr -> IfL Id
1296 newExtCoreBndr (IfLetBndr var ty _)    -- Ignoring IdInfo for now
1297   = do  { mod <- getIfModule
1298         ; name <- newGlobalBinder mod (mkVarOccFS var) noSrcSpan
1299         ; ty' <- tcIfaceType ty
1300         ; return (mkLocalId name ty') }
1301
1302 -----------------------
1303 bindIfaceTyVar :: IfaceTvBndr -> (TyVar -> IfL a) -> IfL a
1304 bindIfaceTyVar (occ,kind) thing_inside
1305   = do  { name <- newIfaceName (mkTyVarOccFS occ)
1306         ; tyvar <- mk_iface_tyvar name kind
1307         ; extendIfaceTyVarEnv [tyvar] (thing_inside tyvar) }
1308
1309 bindIfaceTyVars :: [IfaceTvBndr] -> ([TyVar] -> IfL a) -> IfL a
1310 bindIfaceTyVars bndrs thing_inside
1311   = do  { names <- newIfaceNames (map mkTyVarOccFS occs)
1312         ; tyvars <- zipWithM mk_iface_tyvar names kinds
1313         ; extendIfaceTyVarEnv tyvars (thing_inside tyvars) }
1314   where
1315     (occs,kinds) = unzip bndrs
1316
1317 mk_iface_tyvar :: Name -> IfaceKind -> IfL TyVar
1318 mk_iface_tyvar name ifKind
1319    = do { kind <- tcIfaceType ifKind
1320         ; if isCoercionKind kind then
1321                 return (Var.mkCoVar name kind)
1322           else
1323                 return (Var.mkTyVar name kind) }
1324
1325 bindIfaceTyVars_AT :: [IfaceTvBndr] -> ([TyVar] -> IfL a) -> IfL a
1326 -- Used for type variable in nested associated data/type declarations
1327 -- where some of the type variables are already in scope
1328 --    class C a where { data T a b }
1329 -- Here 'a' is in scope when we look at the 'data T'
1330 bindIfaceTyVars_AT [] thing_inside
1331   = thing_inside []
1332 bindIfaceTyVars_AT (b@(tv_occ,_) : bs) thing_inside
1333   = bindIfaceTyVars_AT bs $ \ bs' ->
1334     do { mb_tv <- lookupIfaceTyVar tv_occ
1335        ; case mb_tv of
1336            Just b' -> thing_inside (b':bs')
1337            Nothing -> bindIfaceTyVar b $ \ b' ->
1338                       thing_inside (b':bs') }
1339 \end{code}
1340