compiler/iface/TcIface.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Type checking of type signatures in interface files
   7
   8 \begin{code}
   9 module TcIface (
  10         tcImportDecl, checkWiredInTyCon, tcHiBootIface, typecheckIface,
  11         tcIfaceDecl, tcIfaceInst, tcIfaceFamInst, tcIfaceRules,
  12         tcIfaceVectInfo, tcIfaceGlobal, tcExtCoreBindings
  13  ) where
  14
  15 #include "HsVersions.h"
  16
  17 import IfaceSyn
  18 import LoadIface
  19 import IfaceEnv
  20 import BuildTyCl
  21 import TcRnMonad
  22 import Type
  23 import TypeRep
  24 import HscTypes
  25 import InstEnv
  26 import FamInstEnv
  27 import CoreSyn
  28 import CoreUtils
  29 import CoreUnfold
  30 import CoreLint
  31 import WorkWrap
  32 import Id
  33 import MkId
  34 import IdInfo
  35 import Class
  36 import TyCon
  37 import DataCon
  38 import TysWiredIn
  39 import Var              ( TyVar )
  40 import qualified Var
  41 import VarEnv
  42 import Name
  43 import NameEnv
  44 import OccName
  45 import Module
  46 import UniqFM
  47 import UniqSupply
  48 import Outputable
  49 import ErrUtils
  50 import Maybes
  51 import SrcLoc
  52 import DynFlags
  53 import Control.Monad
  54
  55 import Data.List
  56 import Data.Maybe
  57 \end{code}
  58
  59 This module takes
  60
  61         IfaceDecl -> TyThing
  62         IfaceType -> Type
  63         etc
  64
  65 An IfaceDecl is populated with RdrNames, and these are not renamed to
  66 Names before typechecking, because there should be no scope errors etc.
  67
  68         -- For (b) consider: f = $(...h....)
  69         -- where h is imported, and calls f via an hi-boot file.
  70         -- This is bad!  But it is not seen as a staging error, because h
  71         -- is indeed imported.  We don't want the type-checker to black-hole
  72         -- when simplifying and compiling the splice!
  73         --
  74         -- Simple solution: discard any unfolding that mentions a variable
  75         -- bound in this module (and hence not yet processed).
  76         -- The discarding happens when forkM finds a type error.
  77
  78 %************************************************************************
  79 %*                                                                      *
  80 %*      tcImportDecl is the key function for "faulting in"              *
  81 %*      imported things
  82 %*                                                                      *
  83 %************************************************************************
  84
  85 The main idea is this.  We are chugging along type-checking source code, and
  86 find a reference to GHC.Base.map.  We call tcLookupGlobal, which doesn't find
  87 it in the EPS type envt.  So it
  88         1 loads GHC.Base.hi
  89         2 gets the decl for GHC.Base.map
  90         3 typechecks it via tcIfaceDecl
  91         4 and adds it to the type env in the EPS
  92
  93 Note that DURING STEP 4, we may find that map's type mentions a type
  94 constructor that also
  95
  96 Notice that for imported things we read the current version from the EPS
  97 mutable variable.  This is important in situations like
  98         ...$(e1)...$(e2)...
  99 where the code that e1 expands to might import some defns that
 100 also turn out to be needed by the code that e2 expands to.
 101
 102 \begin{code}
 103 tcImportDecl :: Name -> TcM TyThing
 104 -- Entry point for *source-code* uses of importDecl
 105 tcImportDecl name
 106   | Just thing <- wiredInNameTyThing_maybe name
 107   = do  { initIfaceTcRn (loadWiredInHomeIface name)
 108         ; return thing }
 109   | otherwise
 110   = do  { traceIf (text "tcImportDecl" <+> ppr name)
 111         ; mb_thing <- initIfaceTcRn (importDecl name)
 112         ; case mb_thing of
 113             Succeeded thing -> return thing
 114             Failed err      -> failWithTc err }
 115
 116 checkWiredInTyCon :: TyCon -> TcM ()
 117 -- Ensure that the home module of the TyCon (and hence its instances)
 118 -- are loaded. It might not be a wired-in tycon (see the calls in TcUnify),
 119 -- in which case this is a no-op.
 120 checkWiredInTyCon tc
 121   | not (isWiredInName tc_name)
 122   = return ()
 123   | otherwise
 124   = do  { mod <- getModule
 125         ; unless (mod == nameModule tc_name)
 126                  (initIfaceTcRn (loadWiredInHomeIface tc_name))
 127                 -- Don't look for (non-existent) Float.hi when
 128                 -- compiling Float.lhs, which mentions Float of course
 129                 -- A bit yukky to call initIfaceTcRn here
 130         }
 131   where
 132     tc_name = tyConName tc
 133
 134 importDecl :: Name -> IfM lcl (MaybeErr Message TyThing)
 135 -- Get the TyThing for this Name from an interface file
 136 -- It's not a wired-in thing -- the caller caught that
 137 importDecl name
 138   = ASSERT( not (isWiredInName name) )
 139     do  { traceIf nd_doc
 140
 141         -- Load the interface, which should populate the PTE
 142         ; mb_iface <- loadInterface nd_doc (nameModule name) ImportBySystem
 143         ; case mb_iface of {
 144                 Failed err_msg  -> return (Failed err_msg) ;
 145                 Succeeded iface -> do
 146
 147         -- Now look it up again; this time we should find it
 148         { eps <- getEps
 149         ; case lookupTypeEnv (eps_PTE eps) name of
 150             Just thing -> return (Succeeded thing)
 151             Nothing    -> return (Failed not_found_msg)
 152     }}}
 153   where
 154     nd_doc = ptext SLIT("Need decl for") <+> ppr name
 155     not_found_msg = hang (ptext SLIT("Can't find interface-file declaration for") <+>
 156                                 pprNameSpace (occNameSpace (nameOccName name)) <+> ppr name)
 157                        2 (vcat [ptext SLIT("Probable cause: bug in .hi-boot file, or inconsistent .hi file"),
 158                                 ptext SLIT("Use -ddump-if-trace to get an idea of which file caused the error")])
 159 \end{code}
 160
 161 %************************************************************************
 162 %*                                                                      *
 163                 Type-checking a complete interface
 164 %*                                                                      *
 165 %************************************************************************
 166
 167 Suppose we discover we don't need to recompile.  Then we must type
 168 check the old interface file.  This is a bit different to the
 169 incremental type checking we do as we suck in interface files.  Instead
 170 we do things similarly as when we are typechecking source decls: we
 171 bring into scope the type envt for the interface all at once, using a
 172 knot.  Remember, the decls aren't necessarily in dependency order --
 173 and even if they were, the type decls might be mutually recursive.
 174
 175 \begin{code}
 176 typecheckIface :: ModIface      -- Get the decls from here
 177                -> TcRnIf gbl lcl ModDetails
 178 typecheckIface iface
 179   = initIfaceTc iface $ \ tc_env_var -> do
 180         -- The tc_env_var is freshly allocated, private to
 181         -- type-checking this particular interface
 182         {       -- Get the right set of decls and rules.  If we are compiling without -O
 183                 -- we discard pragmas before typechecking, so that we don't "see"
 184                 -- information that we shouldn't.  From a versioning point of view
 185                 -- It's not actually *wrong* to do so, but in fact GHCi is unable
 186                 -- to handle unboxed tuples, so it must not see unfoldings.
 187           ignore_prags <- doptM Opt_IgnoreInterfacePragmas
 188
 189                 -- Typecheck the decls.  This is done lazily, so that the knot-tying
 190                 -- within this single module work out right.  In the If monad there is
 191                 -- no global envt for the current interface; instead, the knot is tied
 192                 -- through the if_rec_types field of IfGblEnv
 193         ; names_w_things <- loadDecls ignore_prags (mi_decls iface)
 194         ; let type_env = mkNameEnv names_w_things
 195         ; writeMutVar tc_env_var type_env
 196
 197                 -- Now do those rules and instances
 198         ; insts     <- mapM tcIfaceInst    (mi_insts     iface)
 199         ; fam_insts <- mapM tcIfaceFamInst (mi_fam_insts iface)
 200         ; rules     <- tcIfaceRules ignore_prags (mi_rules iface)
 201
 202                 -- Vectorisation information
 203         ; vect_info <- tcIfaceVectInfo (mi_module iface) type_env
 204                                        (mi_vect_info iface)
 205
 206                 -- Exports
 207         ; exports <- ifaceExportNames (mi_exports iface)
 208
 209                 -- Finished
 210         ; traceIf (vcat [text "Finished typechecking interface for" <+> ppr (mi_module iface),
 211                          text "Type envt:" <+> ppr type_env])
 212         ; return $ ModDetails { md_types     = type_env
 213                               , md_insts     = insts
 214                               , md_fam_insts = fam_insts
 215                               , md_rules     = rules
 216                               , md_vect_info = vect_info
 217                               , md_exports   = exports
 218                               , md_modBreaks = emptyModBreaks
 219                               }
 220     }
 221 \end{code}
 222
 223
 224 %************************************************************************
 225 %*                                                                      *
 226                 Type and class declarations
 227 %*                                                                      *
 228 %************************************************************************
 229
 230 \begin{code}
 231 tcHiBootIface :: HscSource -> Module -> TcRn ModDetails
 232 -- Load the hi-boot iface for the module being compiled,
 233 -- if it indeed exists in the transitive closure of imports
 234 -- Return the ModDetails, empty if no hi-boot iface
 235 tcHiBootIface hsc_src mod
 236   | isHsBoot hsc_src            -- Already compiling a hs-boot file
 237   = return emptyModDetails
 238   | otherwise
 239   = do  { traceIf (text "loadHiBootInterface" <+> ppr mod)
 240
 241         ; mode <- getGhcMode
 242         ; if not (isOneShot mode)
 243                 -- In --make and interactive mode, if this module has an hs-boot file
 244                 -- we'll have compiled it already, and it'll be in the HPT
 245                 --
 246                 -- We check wheher the interface is a *boot* interface.
 247                 -- It can happen (when using GHC from Visual Studio) that we
 248                 -- compile a module in TypecheckOnly mode, with a stable,
 249                 -- fully-populated HPT.  In that case the boot interface isn't there
 250                 -- (it's been replaced by the mother module) so we can't check it.
 251                 -- And that's fine, because if M's ModInfo is in the HPT, then
 252                 -- it's been compiled once, and we don't need to check the boot iface
 253           then do { hpt <- getHpt
 254                   ; case lookupUFM hpt (moduleName mod) of
 255                       Just info | mi_boot (hm_iface info)
 256                                 -> return (hm_details info)
 257                       other -> return emptyModDetails }
 258           else do
 259
 260         -- OK, so we're in one-shot mode.
 261         -- In that case, we're read all the direct imports by now,
 262         -- so eps_is_boot will record if any of our imports mention us by
 263         -- way of hi-boot file
 264         { eps <- getEps
 265         ; case lookupUFM (eps_is_boot eps) (moduleName mod) of {
 266             Nothing -> return emptyModDetails ; -- The typical case
 267
 268             Just (_, False) -> failWithTc moduleLoop ;
 269                 -- Someone below us imported us!
 270                 -- This is a loop with no hi-boot in the way
 271
 272             Just (_mod, True) ->        -- There's a hi-boot interface below us
 273
 274     do  { read_result <- findAndReadIface
 275                                 need mod
 276                                 True    -- Hi-boot file
 277
 278         ; case read_result of
 279                 Failed err               -> failWithTc (elaborate err)
 280                 Succeeded (iface, _path) -> typecheckIface iface
 281     }}}}
 282   where
 283     need = ptext SLIT("Need the hi-boot interface for") <+> ppr mod
 284                  <+> ptext SLIT("to compare against the Real Thing")
 285
 286     moduleLoop = ptext SLIT("Circular imports: module") <+> quotes (ppr mod)
 287                      <+> ptext SLIT("depends on itself")
 288
 289     elaborate err = hang (ptext SLIT("Could not find hi-boot interface for") <+>
 290                           quotes (ppr mod) <> colon) 4 err
 291 \end{code}
 292
 293
 294 %************************************************************************
 295 %*                                                                      *
 296                 Type and class declarations
 297 %*                                                                      *
 298 %************************************************************************
 299
 300 When typechecking a data type decl, we *lazily* (via forkM) typecheck
 301 the constructor argument types.  This is in the hope that we may never
 302 poke on those argument types, and hence may never need to load the
 303 interface files for types mentioned in the arg types.
 304
 305 E.g.
 306         data Foo.S = MkS Baz.T
 307 Mabye we can get away without even loading the interface for Baz!
 308
 309 This is not just a performance thing.  Suppose we have
 310         data Foo.S = MkS Baz.T
 311         data Baz.T = MkT Foo.S
 312 (in different interface files, of course).
 313 Now, first we load and typecheck Foo.S, and add it to the type envt.
 314 If we do explore MkS's argument, we'll load and typecheck Baz.T.
 315 If we explore MkT's argument we'll find Foo.S already in the envt.
 316
 317 If we typechecked constructor args eagerly, when loading Foo.S we'd try to
 318 typecheck the type Baz.T.  So we'd fault in Baz.T... and then need Foo.S...
 319 which isn't done yet.
 320
 321 All very cunning. However, there is a rather subtle gotcha which bit
 322 me when developing this stuff.  When we typecheck the decl for S, we
 323 extend the type envt with S, MkS, and all its implicit Ids.  Suppose
 324 (a bug, but it happened) that the list of implicit Ids depended in
 325 turn on the constructor arg types.  Then the following sequence of
 326 events takes place:
 327         * we build a thunk <t> for the constructor arg tys
 328         * we build a thunk for the extended type environment (depends on <t>)
 329         * we write the extended type envt into the global EPS mutvar
 330
 331 Now we look something up in the type envt
 332         * that pulls on <t>
 333         * which reads the global type envt out of the global EPS mutvar
 334         * but that depends in turn on <t>
 335
 336 It's subtle, because, it'd work fine if we typechecked the constructor args
 337 eagerly -- they don't need the extended type envt.  They just get the extended
 338 type envt by accident, because they look at it later.
 339
 340 What this means is that the implicitTyThings MUST NOT DEPEND on any of
 341 the forkM stuff.
 342
 343
 344 \begin{code}
 345 tcIfaceDecl :: Bool     -- True <=> discard IdInfo on IfaceId bindings
 346             -> IfaceDecl
 347             -> IfL TyThing
 348
 349 tcIfaceDecl ignore_prags (IfaceId {ifName = occ_name, ifType = iface_type, ifIdInfo = info})
 350   = do  { name <- lookupIfaceTop occ_name
 351         ; ty <- tcIfaceType iface_type
 352         ; info <- tcIdInfo ignore_prags name ty info
 353         ; return (AnId (mkVanillaGlobal name ty info)) }
 354
 355 tcIfaceDecl ignore_prags
 356             (IfaceData {ifName = occ_name,
 357                         ifTyVars = tv_bndrs,
 358                         ifCtxt = ctxt, ifGadtSyntax = gadt_syn,
 359                         ifCons = rdr_cons,
 360                         ifRec = is_rec,
 361                         ifGeneric = want_generic,
 362                         ifFamInst = mb_family })
 363   = do  { tc_name <- lookupIfaceTop occ_name
 364         ; bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 365
 366         { tycon <- fixM ( \ tycon -> do
 367             { stupid_theta <- tcIfaceCtxt ctxt
 368             ; famInst <-
 369                 case mb_family of
 370                   Nothing         -> return Nothing
 371                   Just (fam, tys) ->
 372                     do { famTyCon <- tcIfaceTyCon fam
 373                        ; insttys <- mapM tcIfaceType tys
 374                        ; return $ Just (famTyCon, insttys)
 375                        }
 376             ; cons <- tcIfaceDataCons tc_name tycon tyvars rdr_cons
 377             ; buildAlgTyCon tc_name tyvars stupid_theta
 378                             cons is_rec want_generic gadt_syn famInst
 379             })
 380         ; traceIf (text "tcIfaceDecl4" <+> ppr tycon)
 381         ; return (ATyCon tycon)
 382     }}
 383
 384 tcIfaceDecl ignore_prags
 385             (IfaceSyn {ifName = occ_name, ifTyVars = tv_bndrs,
 386                        ifOpenSyn = isOpen, ifSynRhs = rdr_rhs_ty,
 387                        ifFamInst = mb_family})
 388    = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 389      { tc_name <- lookupIfaceTop occ_name
 390      ; rhs_tyki <- tcIfaceType rdr_rhs_ty
 391      ; let rhs = if isOpen then OpenSynTyCon rhs_tyki Nothing
 392                            else SynonymTyCon rhs_tyki
 393      ; famInst <- case mb_family of
 394                     Nothing         -> return Nothing
 395                     Just (fam, tys) ->
 396                       do { famTyCon <- tcIfaceTyCon fam
 397                          ; insttys <- mapM tcIfaceType tys
 398                          ; return $ Just (famTyCon, insttys)
 399                          }
 400      ; tycon <- buildSynTyCon tc_name tyvars rhs famInst
 401      ; return $ ATyCon tycon
 402      }
 403
 404 tcIfaceDecl ignore_prags
 405             (IfaceClass {ifCtxt = rdr_ctxt, ifName = occ_name,
 406                          ifTyVars = tv_bndrs, ifFDs = rdr_fds,
 407                          ifATs = rdr_ats, ifSigs = rdr_sigs,
 408                          ifRec = tc_isrec })
 409 -- ToDo: in hs-boot files we should really treat abstract classes specially,
 410 --       as we do abstract tycons
 411   = bindIfaceTyVars tv_bndrs $ \ tyvars -> do
 412     { cls_name <- lookupIfaceTop occ_name
 413     ; ctxt <- tcIfaceCtxt rdr_ctxt
 414     ; sigs <- mappM tc_sig rdr_sigs
 415     ; fds  <- mappM tc_fd rdr_fds
 416     ; ats'  <- mappM (tcIfaceDecl ignore_prags) rdr_ats
 417     ; let ats = zipWith setTyThingPoss ats' (map ifTyVars rdr_ats)
 418     ; cls  <- buildClass cls_name tyvars ctxt fds ats sigs tc_isrec
 419     ; return (AClass cls) }
 420   where
 421    tc_sig (IfaceClassOp occ dm rdr_ty)
 422      = do { op_name <- lookupIfaceTop occ
 423           ; op_ty   <- forkM (mk_doc op_name rdr_ty) (tcIfaceType rdr_ty)
 424                 -- Must be done lazily for just the same reason as the
 425                 -- type of a data con; to avoid sucking in types that
 426                 -- it mentions unless it's necessray to do so
 427           ; return (op_name, dm, op_ty) }
 428
 429    mk_doc op_name op_ty = ptext SLIT("Class op") <+> sep [ppr op_name, ppr op_ty]
 430
 431    tc_fd (tvs1, tvs2) = do { tvs1' <- mappM tcIfaceTyVar tvs1
 432                            ; tvs2' <- mappM tcIfaceTyVar tvs2
 433                            ; return (tvs1', tvs2') }
 434
 435    -- For each AT argument compute the position of the corresponding class
 436    -- parameter in the class head.  This will later serve as a permutation
 437    -- vector when checking the validity of instance declarations.
 438    setTyThingPoss (ATyCon tycon) atTyVars =
 439      let classTyVars = map fst tv_bndrs
 440          poss        =   catMaybes
 441                        . map ((`elemIndex` classTyVars) . fst)
 442                        $ atTyVars
 443                     -- There will be no Nothing, as we already passed renaming
 444      in
 445      ATyCon (setTyConArgPoss tycon poss)
 446    setTyThingPoss _               _ = panic "TcIface.setTyThingPoss"
 447
 448 tcIfaceDecl ignore_prags (IfaceForeign {ifName = rdr_name, ifExtName = ext_name})
 449   = do  { name <- lookupIfaceTop rdr_name
 450         ; return (ATyCon (mkForeignTyCon name ext_name
 451                                          liftedTypeKind 0)) }
 452
 453 tcIfaceDataCons tycon_name tycon tc_tyvars if_cons
 454   = case if_cons of
 455         IfAbstractTyCon  -> return mkAbstractTyConRhs
 456         IfOpenDataTyCon  -> return mkOpenDataTyConRhs
 457         IfDataTyCon cons -> do  { data_cons <- mappM tc_con_decl cons
 458                                 ; return (mkDataTyConRhs data_cons) }
 459         IfNewTyCon con   -> do  { data_con <- tc_con_decl con
 460                                 ; mkNewTyConRhs tycon_name tycon data_con }
 461   where
 462     tc_con_decl (IfCon { ifConInfix = is_infix,
 463                          ifConUnivTvs = univ_tvs, ifConExTvs = ex_tvs,
 464                          ifConOcc = occ, ifConCtxt = ctxt, ifConEqSpec = spec,
 465                          ifConArgTys = args, ifConFields = field_lbls,
 466                          ifConStricts = stricts})
 467      = bindIfaceTyVars univ_tvs $ \ univ_tyvars -> do
 468        bindIfaceTyVars ex_tvs    $ \ ex_tyvars -> do
 469         { name  <- lookupIfaceTop occ
 470         ; eq_spec <- tcIfaceEqSpec spec
 471         ; theta <- tcIfaceCtxt ctxt     -- Laziness seems not worth the bother here
 472                 -- At one stage I thought that this context checking *had*
 473                 -- to be lazy, because of possible mutual recursion between the
 474                 -- type and the classe:
 475                 -- E.g.
 476                 --      class Real a where { toRat :: a -> Ratio Integer }
 477                 --      data (Real a) => Ratio a = ...
 478                 -- But now I think that the laziness in checking class ops breaks
 479                 -- the loop, so no laziness needed
 480
 481         -- Read the argument types, but lazily to avoid faulting in
 482         -- the component types unless they are really needed
 483         ; arg_tys <- forkM (mk_doc name) (mappM tcIfaceType args)
 484         ; lbl_names <- mappM lookupIfaceTop field_lbls
 485
 486         ; buildDataCon name is_infix {- Not infix -}
 487                        stricts lbl_names
 488                        univ_tyvars ex_tyvars
 489                        eq_spec theta
 490                        arg_tys tycon
 491         }
 492     mk_doc con_name = ptext SLIT("Constructor") <+> ppr con_name
 493
 494 tcIfaceEqSpec spec
 495   = mapM do_item spec
 496   where
 497     do_item (occ, if_ty) = do { tv <- tcIfaceTyVar (occNameFS occ)
 498                               ; ty <- tcIfaceType if_ty
 499                               ; return (tv,ty) }
 500 \end{code}
 501
 502
 503 %************************************************************************
 504 %*                                                                      *
 505                 Instances
 506 %*                                                                      *
 507 %************************************************************************
 508
 509 \begin{code}
 510 tcIfaceInst :: IfaceInst -> IfL Instance
 511 tcIfaceInst (IfaceInst { ifDFun = dfun_occ, ifOFlag = oflag,
 512                          ifInstCls = cls, ifInstTys = mb_tcs,
 513                          ifInstOrph = orph })
 514   = do  { dfun    <- forkM (ptext SLIT("Dict fun") <+> ppr dfun_occ) $
 515                      tcIfaceExtId dfun_occ
 516         ; let mb_tcs' = map (fmap ifaceTyConName) mb_tcs
 517         ; return (mkImportedInstance cls mb_tcs' dfun oflag) }
 518
 519 tcIfaceFamInst :: IfaceFamInst -> IfL FamInst
 520 tcIfaceFamInst (IfaceFamInst { ifFamInstTyCon = tycon,
 521                                ifFamInstFam = fam, ifFamInstTys = mb_tcs })
 522 --  = do        { tycon'  <- forkM (ptext SLIT("Inst tycon") <+> ppr tycon) $
 523 -- ^^^this line doesn't work, but vvv this does => CPP in Haskell = evil!
 524   = do  { tycon'  <- forkM (text ("Inst tycon") <+> ppr tycon) $
 525                      tcIfaceTyCon tycon
 526         ; let mb_tcs' = map (fmap ifaceTyConName) mb_tcs
 527         ; return (mkImportedFamInst fam mb_tcs' tycon') }
 528 \end{code}
 529
 530
 531 %************************************************************************
 532 %*                                                                      *
 533                 Rules
 534 %*                                                                      *
 535 %************************************************************************
 536
 537 We move a IfaceRule from eps_rules to eps_rule_base when all its LHS free vars
 538 are in the type environment.  However, remember that typechecking a Rule may
 539 (as a side effect) augment the type envt, and so we may need to iterate the process.
 540
 541 \begin{code}
 542 tcIfaceRules :: Bool            -- True <=> ignore rules
 543              -> [IfaceRule]
 544              -> IfL [CoreRule]
 545 tcIfaceRules ignore_prags if_rules
 546   | ignore_prags = return []
 547   | otherwise    = mapM tcIfaceRule if_rules
 548
 549 tcIfaceRule :: IfaceRule -> IfL CoreRule
 550 tcIfaceRule (IfaceRule {ifRuleName = name, ifActivation = act, ifRuleBndrs = bndrs,
 551                         ifRuleHead = fn, ifRuleArgs = args, ifRuleRhs = rhs,
 552                         ifRuleOrph = orph })
 553   = do  { ~(bndrs', args', rhs') <-
 554                 -- Typecheck the payload lazily, in the hope it'll never be looked at
 555                 forkM (ptext SLIT("Rule") <+> ftext name) $
 556                 bindIfaceBndrs bndrs                      $ \ bndrs' ->
 557                 do { args' <- mappM tcIfaceExpr args
 558                    ; rhs'  <- tcIfaceExpr rhs
 559                    ; return (bndrs', args', rhs') }
 560         ; let mb_tcs = map ifTopFreeName args
 561         ; lcl <- getLclEnv
 562         ; returnM (Rule { ru_name = name, ru_fn = fn, ru_act = act,
 563                           ru_bndrs = bndrs', ru_args = args',
 564                           ru_rhs = rhs',
 565                           ru_rough = mb_tcs,
 566                           ru_local = False }) } -- An imported RULE is never for a local Id
 567                                                 -- or, even if it is (module loop, perhaps)
 568                                                 -- we'll just leave it in the non-local set
 569   where
 570         -- This function *must* mirror exactly what Rules.topFreeName does
 571         -- We could have stored the ru_rough field in the iface file
 572         -- but that would be redundant, I think.
 573         -- The only wrinkle is that we must not be deceived by
 574         -- type syononyms at the top of a type arg.  Since
 575         -- we can't tell at this point, we are careful not
 576         -- to write them out in coreRuleToIfaceRule
 577     ifTopFreeName :: IfaceExpr -> Maybe Name
 578     ifTopFreeName (IfaceType (IfaceTyConApp tc _ )) = Just (ifaceTyConName tc)
 579     ifTopFreeName (IfaceApp f a)                    = ifTopFreeName f
 580     ifTopFreeName (IfaceExt n)                      = Just n
 581     ifTopFreeName other                             = Nothing
 582 \end{code}
 583
 584
 585 %************************************************************************
 586 %*                                                                      *
 587                 Vectorisation information
 588 %*                                                                      *
 589 %************************************************************************
 590
 591 \begin{code}
 592 tcIfaceVectInfo :: Module -> TypeEnv  -> IfaceVectInfo -> IfL VectInfo
 593 tcIfaceVectInfo mod typeEnv (IfaceVectInfo names)
 594   = do { ccVars <- mapM ccMapping names
 595        ; return $ VectInfo (mkVarEnv ccVars)
 596        }
 597   where
 598     ccMapping name
 599       = do { ccName <- lookupOrig mod (mkCloOcc (nameOccName name))
 600            ; let { var   = lookup name
 601                  ; ccVar = lookup ccName
 602                  }
 603            ; return (var, (var, ccVar))
 604            }
 605     lookup name = case lookupTypeEnv typeEnv name of
 606                     Just (AnId var) -> var
 607                     Just _          ->
 608                       panic "TcIface.tcIfaceVectInfo: wrong TyThing"
 609                     Nothing         ->
 610                       panic "TcIface.tcIfaceVectInfo: unknown name"
 611 \end{code}
 612
 613 %************************************************************************
 614 %*                                                                      *
 615                         Types
 616 %*                                                                      *
 617 %************************************************************************
 618
 619 \begin{code}
 620 tcIfaceType :: IfaceType -> IfL Type
 621 tcIfaceType (IfaceTyVar n)        = do { tv <- tcIfaceTyVar n; return (TyVarTy tv) }
 622 tcIfaceType (IfaceAppTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (AppTy t1' t2') }
 623 tcIfaceType (IfaceFunTy t1 t2)    = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (FunTy t1' t2') }
 624 tcIfaceType (IfaceTyConApp tc ts) = do { tc' <- tcIfaceTyCon tc; ts' <- tcIfaceTypes ts; return (mkTyConApp tc' ts') }
 625 tcIfaceType (IfaceForAllTy tv t)  = bindIfaceTyVar tv $ \ tv' -> do { t' <- tcIfaceType t; return (ForAllTy tv' t') }
 626 tcIfaceType (IfacePredTy st)      = do { st' <- tcIfacePredType st; return (PredTy st') }
 627
 628 tcIfaceTypes tys = mapM tcIfaceType tys
 629
 630 -----------------------------------------
 631 tcIfacePredType :: IfacePredType -> IfL PredType
 632 tcIfacePredType (IfaceClassP cls ts) = do { cls' <- tcIfaceClass cls; ts' <- tcIfaceTypes ts; return (ClassP cls' ts') }
 633 tcIfacePredType (IfaceIParam ip t)   = do { ip' <- newIPName ip; t' <- tcIfaceType t; return (IParam ip' t') }
 634 tcIfacePredType (IfaceEqPred t1 t2)  = do { t1' <- tcIfaceType t1; t2' <- tcIfaceType t2; return (EqPred t1' t2') }
 635
 636 -----------------------------------------
 637 tcIfaceCtxt :: IfaceContext -> IfL ThetaType
 638 tcIfaceCtxt sts = mappM tcIfacePredType sts
 639 \end{code}
 640
 641
 642 %************************************************************************
 643 %*                                                                      *
 644                         Core
 645 %*                                                                      *
 646 %************************************************************************
 647
 648 \begin{code}
 649 tcIfaceExpr :: IfaceExpr -> IfL CoreExpr
 650 tcIfaceExpr (IfaceType ty)
 651   = tcIfaceType ty              `thenM` \ ty' ->
 652     returnM (Type ty')
 653
 654 tcIfaceExpr (IfaceLcl name)
 655   = tcIfaceLclId name   `thenM` \ id ->
 656     returnM (Var id)
 657
 658 tcIfaceExpr (IfaceExt gbl)
 659   = tcIfaceExtId gbl    `thenM` \ id ->
 660     returnM (Var id)
 661
 662 tcIfaceExpr (IfaceLit lit)
 663   = returnM (Lit lit)
 664
 665 tcIfaceExpr (IfaceFCall cc ty)
 666   = tcIfaceType ty      `thenM` \ ty' ->
 667     newUnique           `thenM` \ u ->
 668     returnM (Var (mkFCallId u cc ty'))
 669
 670 tcIfaceExpr (IfaceTuple boxity args)
 671   = mappM tcIfaceExpr args      `thenM` \ args' ->
 672     let
 673         -- Put the missing type arguments back in
 674         con_args = map (Type . exprType) args' ++ args'
 675     in
 676     returnM (mkApps (Var con_id) con_args)
 677   where
 678     arity = length args
 679     con_id = dataConWorkId (tupleCon boxity arity)
 680
 681
 682 tcIfaceExpr (IfaceLam bndr body)
 683   = bindIfaceBndr bndr          $ \ bndr' ->
 684     tcIfaceExpr body            `thenM` \ body' ->
 685     returnM (Lam bndr' body')
 686
 687 tcIfaceExpr (IfaceApp fun arg)
 688   = tcIfaceExpr fun             `thenM` \ fun' ->
 689     tcIfaceExpr arg             `thenM` \ arg' ->
 690     returnM (App fun' arg')
 691
 692 tcIfaceExpr (IfaceCase scrut case_bndr ty alts)
 693   = tcIfaceExpr scrut           `thenM` \ scrut' ->
 694     newIfaceName (mkVarOccFS case_bndr) `thenM` \ case_bndr_name ->
 695     let
 696         scrut_ty   = exprType scrut'
 697         case_bndr' = mkLocalId case_bndr_name scrut_ty
 698         tc_app     = splitTyConApp scrut_ty
 699                 -- NB: Won't always succeed (polymoprhic case)
 700                 --     but won't be demanded in those cases
 701                 -- NB: not tcSplitTyConApp; we are looking at Core here
 702                 --     look through non-rec newtypes to find the tycon that
 703                 --     corresponds to the datacon in this case alternative
 704     in
 705     extendIfaceIdEnv [case_bndr']       $
 706     mappM (tcIfaceAlt tc_app) alts      `thenM` \ alts' ->
 707     tcIfaceType ty              `thenM` \ ty' ->
 708     returnM (Case scrut' case_bndr' ty' alts')
 709
 710 tcIfaceExpr (IfaceLet (IfaceNonRec bndr rhs) body)
 711   = do  { rhs' <- tcIfaceExpr rhs
 712         ; id   <- tcIfaceLetBndr bndr
 713         ; body' <- extendIfaceIdEnv [id] (tcIfaceExpr body)
 714         ; return (Let (NonRec id rhs') body') }
 715
 716 tcIfaceExpr (IfaceLet (IfaceRec pairs) body)
 717   = do  { ids <- mapM tcIfaceLetBndr bndrs
 718         ; extendIfaceIdEnv ids $ do
 719         { rhss' <- mapM tcIfaceExpr rhss
 720         ; body' <- tcIfaceExpr body
 721         ; return (Let (Rec (ids `zip` rhss')) body') } }
 722   where
 723     (bndrs, rhss) = unzip pairs
 724
 725 tcIfaceExpr (IfaceCast expr co) = do
 726   expr' <- tcIfaceExpr expr
 727   co' <- tcIfaceType co
 728   returnM (Cast expr' co')
 729
 730 tcIfaceExpr (IfaceNote note expr)
 731   = tcIfaceExpr expr            `thenM` \ expr' ->
 732     case note of
 733         IfaceInlineMe     -> returnM (Note InlineMe   expr')
 734         IfaceSCC cc       -> returnM (Note (SCC cc)   expr')
 735         IfaceCoreNote n   -> returnM (Note (CoreNote n) expr')
 736
 737 -------------------------
 738 tcIfaceAlt _ (IfaceDefault, names, rhs)
 739   = ASSERT( null names )
 740     tcIfaceExpr rhs             `thenM` \ rhs' ->
 741     returnM (DEFAULT, [], rhs')
 742
 743 tcIfaceAlt _ (IfaceLitAlt lit, names, rhs)
 744   = ASSERT( null names )
 745     tcIfaceExpr rhs             `thenM` \ rhs' ->
 746     returnM (LitAlt lit, [], rhs')
 747
 748 -- A case alternative is made quite a bit more complicated
 749 -- by the fact that we omit type annotations because we can
 750 -- work them out.  True enough, but its not that easy!
 751 tcIfaceAlt (tycon, inst_tys) (IfaceDataAlt data_occ, arg_strs, rhs)
 752   = do  { con <- tcIfaceDataCon data_occ
 753         ; ASSERT2( con `elem` tyConDataCons tycon,
 754                    ppr con $$ ppr tycon $$ ppr (tyConDataCons tycon) )
 755           tcIfaceDataAlt con inst_tys arg_strs rhs }
 756
 757 tcIfaceAlt (tycon, inst_tys) (IfaceTupleAlt boxity, arg_occs, rhs)
 758   = ASSERT( isTupleTyCon tycon )
 759     do  { let [data_con] = tyConDataCons tycon
 760         ; tcIfaceDataAlt data_con inst_tys arg_occs rhs }
 761
 762 tcIfaceDataAlt con inst_tys arg_strs rhs
 763   = do  { us <- newUniqueSupply
 764         ; let uniqs = uniqsFromSupply us
 765         ; let (ex_tvs, co_tvs, arg_ids)
 766                       = dataConRepFSInstPat arg_strs uniqs con inst_tys
 767               all_tvs = ex_tvs ++ co_tvs
 768
 769         ; rhs' <- extendIfaceTyVarEnv all_tvs   $
 770                   extendIfaceIdEnv arg_ids      $
 771                   tcIfaceExpr rhs
 772         ; return (DataAlt con, all_tvs ++ arg_ids, rhs') }
 773 \end{code}
 774
 775
 776 \begin{code}
 777 tcExtCoreBindings :: [IfaceBinding] -> IfL [CoreBind]   -- Used for external core
 778 tcExtCoreBindings []     = return []
 779 tcExtCoreBindings (b:bs) = do_one b (tcExtCoreBindings bs)
 780
 781 do_one :: IfaceBinding -> IfL [CoreBind] -> IfL [CoreBind]
 782 do_one (IfaceNonRec bndr rhs) thing_inside
 783   = do  { rhs' <- tcIfaceExpr rhs
 784         ; bndr' <- newExtCoreBndr bndr
 785         ; extendIfaceIdEnv [bndr'] $ do
 786         { core_binds <- thing_inside
 787         ; return (NonRec bndr' rhs' : core_binds) }}
 788
 789 do_one (IfaceRec pairs) thing_inside
 790   = do  { bndrs' <- mappM newExtCoreBndr bndrs
 791         ; extendIfaceIdEnv bndrs' $ do
 792         { rhss' <- mappM tcIfaceExpr rhss
 793         ; core_binds <- thing_inside
 794         ; return (Rec (bndrs' `zip` rhss') : core_binds) }}
 795   where
 796     (bndrs,rhss) = unzip pairs
 797 \end{code}
 798
 799
 800 %************************************************************************
 801 %*                                                                      *
 802                 IdInfo
 803 %*                                                                      *
 804 %************************************************************************
 805
 806 \begin{code}
 807 tcIdInfo :: Bool -> Name -> Type -> IfaceIdInfo -> IfL IdInfo
 808 tcIdInfo ignore_prags name ty info
 809   | ignore_prags = return vanillaIdInfo
 810   | otherwise    = case info of
 811                         NoInfo       -> return vanillaIdInfo
 812                         HasInfo info -> foldlM tcPrag init_info info
 813   where
 814     -- Set the CgInfo to something sensible but uninformative before
 815     -- we start; default assumption is that it has CAFs
 816     init_info = vanillaIdInfo
 817
 818     tcPrag info HsNoCafRefs         = returnM (info `setCafInfo`   NoCafRefs)
 819     tcPrag info (HsArity arity)     = returnM (info `setArityInfo` arity)
 820     tcPrag info (HsStrictness str)  = returnM (info `setAllStrictnessInfo` Just str)
 821
 822         -- The next two are lazy, so they don't transitively suck stuff in
 823     tcPrag info (HsWorker nm arity) = tcWorkerInfo ty info nm arity
 824     tcPrag info (HsInline inline_prag) = returnM (info `setInlinePragInfo` inline_prag)
 825     tcPrag info (HsUnfold expr)
 826         = tcPragExpr name expr  `thenM` \ maybe_expr' ->
 827           let
 828                 -- maybe_expr' doesn't get looked at if the unfolding
 829                 -- is never inspected; so the typecheck doesn't even happen
 830                 unfold_info = case maybe_expr' of
 831                                 Nothing    -> noUnfolding
 832                                 Just expr' -> mkTopUnfolding expr'
 833           in
 834           returnM (info `setUnfoldingInfoLazily` unfold_info)
 835 \end{code}
 836
 837 \begin{code}
 838 tcWorkerInfo ty info wkr arity
 839   = do  { mb_wkr_id <- forkM_maybe doc (tcIfaceExtId wkr)
 840
 841         -- We return without testing maybe_wkr_id, but as soon as info is
 842         -- looked at we will test it.  That's ok, because its outside the
 843         -- knot; and there seems no big reason to further defer the
 844         -- tcIfaceId lookup.  (Contrast with tcPragExpr, where postponing walking
 845         -- over the unfolding until it's actually used does seem worth while.)
 846         ; us <- newUniqueSupply
 847
 848         ; returnM (case mb_wkr_id of
 849                      Nothing     -> info
 850                      Just wkr_id -> add_wkr_info us wkr_id info) }
 851   where
 852     doc = text "Worker for" <+> ppr wkr
 853     add_wkr_info us wkr_id info
 854         = info `setUnfoldingInfoLazily`  mk_unfolding us wkr_id
 855                `setWorkerInfo`           HasWorker wkr_id arity
 856
 857     mk_unfolding us wkr_id = mkTopUnfolding (initUs_ us (mkWrapper ty strict_sig) wkr_id)
 858
 859         -- We are relying here on strictness info always appearing
 860         -- before worker info,  fingers crossed ....
 861     strict_sig = case newStrictnessInfo info of
 862                    Just sig -> sig
 863                    Nothing  -> pprPanic "Worker info but no strictness for" (ppr wkr)
 864 \end{code}
 865
 866 For unfoldings we try to do the job lazily, so that we never type check
 867 an unfolding that isn't going to be looked at.
 868
 869 \begin{code}
 870 tcPragExpr :: Name -> IfaceExpr -> IfL (Maybe CoreExpr)
 871 tcPragExpr name expr
 872   = forkM_maybe doc $
 873     tcIfaceExpr expr            `thenM` \ core_expr' ->
 874
 875                 -- Check for type consistency in the unfolding
 876     ifOptM Opt_DoCoreLinting (
 877         get_in_scope_ids                        `thenM` \ in_scope ->
 878         case lintUnfolding noSrcLoc in_scope core_expr' of
 879           Nothing       -> returnM ()
 880           Just fail_msg -> pprPanic "Iface Lint failure" (hang doc 2 fail_msg)
 881     )                           `thenM_`
 882
 883    returnM core_expr'
 884   where
 885     doc = text "Unfolding of" <+> ppr name
 886     get_in_scope_ids    -- Urgh; but just for linting
 887         = setLclEnv () $
 888           do    { env <- getGblEnv
 889                 ; case if_rec_types env of {
 890                           Nothing -> return [] ;
 891                           Just (_, get_env) -> do
 892                 { type_env <- get_env
 893                 ; return (typeEnvIds type_env) }}}
 894 \end{code}
 895
 896
 897
 898 %************************************************************************
 899 %*                                                                      *
 900                 Getting from Names to TyThings
 901 %*                                                                      *
 902 %************************************************************************
 903
 904 \begin{code}
 905 tcIfaceGlobal :: Name -> IfL TyThing
 906 tcIfaceGlobal name
 907   | Just thing <- wiredInNameTyThing_maybe name
 908         -- Wired-in things include TyCons, DataCons, and Ids
 909   = do { ifCheckWiredInThing name; return thing }
 910   | otherwise
 911   = do  { (eps,hpt) <- getEpsAndHpt
 912         ; dflags <- getDOpts
 913         ; case lookupType dflags hpt (eps_PTE eps) name of {
 914             Just thing -> return thing ;
 915             Nothing    -> do
 916
 917         { env <- getGblEnv
 918         ; case if_rec_types env of {
 919             Just (mod, get_type_env)
 920                 | nameIsLocalOrFrom mod name
 921                 -> do           -- It's defined in the module being compiled
 922                 { type_env <- setLclEnv () get_type_env         -- yuk
 923                 ; case lookupNameEnv type_env name of
 924                         Just thing -> return thing
 925                         Nothing    -> pprPanic "tcIfaceGlobal (local): not found:"
 926                                                 (ppr name $$ ppr type_env) }
 927
 928           ; other -> do
 929
 930         { mb_thing <- importDecl name   -- It's imported; go get it
 931         ; case mb_thing of
 932             Failed err      -> failIfM err
 933             Succeeded thing -> return thing
 934     }}}}}
 935
 936 ifCheckWiredInThing :: Name -> IfL ()
 937 -- Even though we are in an interface file, we want to make
 938 -- sure the instances of a wired-in thing are loaded (imagine f :: Double -> Double)
 939 -- Ditto want to ensure that RULES are loaded too
 940 ifCheckWiredInThing name
 941   = do  { mod <- getIfModule
 942                 -- Check whether we are typechecking the interface for this
 943                 -- very module.  E.g when compiling the base library in --make mode
 944                 -- we may typecheck GHC.Base.hi. At that point, GHC.Base is not in
 945                 -- the HPT, so without the test we'll demand-load it into the PIT!
 946                 -- C.f. the same test in checkWiredInTyCon above
 947         ; unless (mod == nameModule name)
 948                  (loadWiredInHomeIface name) }
 949
 950 tcIfaceTyCon :: IfaceTyCon -> IfL TyCon
 951 tcIfaceTyCon IfaceIntTc         = tcWiredInTyCon intTyCon
 952 tcIfaceTyCon IfaceBoolTc        = tcWiredInTyCon boolTyCon
 953 tcIfaceTyCon IfaceCharTc        = tcWiredInTyCon charTyCon
 954 tcIfaceTyCon IfaceListTc        = tcWiredInTyCon listTyCon
 955 tcIfaceTyCon IfacePArrTc        = tcWiredInTyCon parrTyCon
 956 tcIfaceTyCon (IfaceTupTc bx ar) = tcWiredInTyCon (tupleTyCon bx ar)
 957 tcIfaceTyCon (IfaceTc name)     = do { thing <- tcIfaceGlobal name
 958                                      ; return (check_tc (tyThingTyCon thing)) }
 959   where
 960 #ifdef DEBUG
 961     check_tc tc = case toIfaceTyCon tc of
 962                    IfaceTc _ -> tc
 963                    other     -> pprTrace "check_tc" (ppr tc) tc
 964 #else
 965     check_tc tc = tc
 966 #endif
 967 -- we should be okay just returning Kind constructors without extra loading
 968 tcIfaceTyCon IfaceLiftedTypeKindTc   = return liftedTypeKindTyCon
 969 tcIfaceTyCon IfaceOpenTypeKindTc     = return openTypeKindTyCon
 970 tcIfaceTyCon IfaceUnliftedTypeKindTc = return unliftedTypeKindTyCon
 971 tcIfaceTyCon IfaceArgTypeKindTc      = return argTypeKindTyCon
 972 tcIfaceTyCon IfaceUbxTupleKindTc     = return ubxTupleKindTyCon
 973
 974 -- Even though we are in an interface file, we want to make
 975 -- sure the instances and RULES of this tycon are loaded
 976 -- Imagine: f :: Double -> Double
 977 tcWiredInTyCon :: TyCon -> IfL TyCon
 978 tcWiredInTyCon tc = do { ifCheckWiredInThing (tyConName tc)
 979                        ; return tc }
 980
 981 tcIfaceClass :: Name -> IfL Class
 982 tcIfaceClass name = do { thing <- tcIfaceGlobal name
 983                        ; return (tyThingClass thing) }
 984
 985 tcIfaceDataCon :: Name -> IfL DataCon
 986 tcIfaceDataCon name = do { thing <- tcIfaceGlobal name
 987                          ; case thing of
 988                                 ADataCon dc -> return dc
 989                                 other   -> pprPanic "tcIfaceExtDC" (ppr name$$ ppr thing) }
 990
 991 tcIfaceExtId :: Name -> IfL Id
 992 tcIfaceExtId name = do { thing <- tcIfaceGlobal name
 993                        ; case thing of
 994                           AnId id -> return id
 995                           other   -> pprPanic "tcIfaceExtId" (ppr name$$ ppr thing) }
 996 \end{code}
 997
 998 %************************************************************************
 999 %*                                                                      *
1000                 Bindings
1001 %*                                                                      *
1002 %************************************************************************
1003
1004 \begin{code}
1005 bindIfaceBndr :: IfaceBndr -> (CoreBndr -> IfL a) -> IfL a
1006 bindIfaceBndr (IfaceIdBndr (fs, ty)) thing_inside
1007   = do  { name <- newIfaceName (mkVarOccFS fs)
1008         ; ty' <- tcIfaceType ty
1009         ; let id = mkLocalId name ty'
1010         ; extendIfaceIdEnv [id] (thing_inside id) }
1011 bindIfaceBndr (IfaceTvBndr bndr) thing_inside
1012   = bindIfaceTyVar bndr thing_inside
1013
1014 bindIfaceBndrs :: [IfaceBndr] -> ([CoreBndr] -> IfL a) -> IfL a
1015 bindIfaceBndrs []     thing_inside = thing_inside []
1016 bindIfaceBndrs (b:bs) thing_inside
1017   = bindIfaceBndr b     $ \ b' ->
1018     bindIfaceBndrs bs   $ \ bs' ->
1019     thing_inside (b':bs')
1020
1021 -----------------------
1022 tcIfaceLetBndr (IfLetBndr fs ty info)
1023   = do  { name <- newIfaceName (mkVarOccFS fs)
1024         ; ty' <- tcIfaceType ty
1025         ; case info of
1026                 NoInfo    -> return (mkLocalId name ty')
1027                 HasInfo i -> return (mkLocalIdWithInfo name ty' (tc_info i)) }
1028   where
1029         -- Similar to tcIdInfo, but much simpler
1030     tc_info [] = vanillaIdInfo
1031     tc_info (HsInline p     : i) = tc_info i `setInlinePragInfo` p
1032     tc_info (HsArity a      : i) = tc_info i `setArityInfo` a
1033     tc_info (HsStrictness s : i) = tc_info i `setAllStrictnessInfo` Just s
1034     tc_info (other          : i) = pprTrace "tcIfaceLetBndr: discarding unexpected IdInfo"
1035                                             (ppr other) (tc_info i)
1036
1037 -----------------------
1038 newExtCoreBndr :: IfaceLetBndr -> IfL Id
1039 newExtCoreBndr (IfLetBndr var ty _)     -- Ignoring IdInfo for now
1040   = do  { mod <- getIfModule
1041         ; name <- newGlobalBinder mod (mkVarOccFS var) noSrcSpan
1042         ; ty' <- tcIfaceType ty
1043         ; return (mkLocalId name ty') }
1044
1045 -----------------------
1046 bindIfaceTyVar :: IfaceTvBndr -> (TyVar -> IfL a) -> IfL a
1047 bindIfaceTyVar (occ,kind) thing_inside
1048   = do  { name <- newIfaceName (mkTyVarOcc occ)
1049         ; tyvar <- mk_iface_tyvar name kind
1050         ; extendIfaceTyVarEnv [tyvar] (thing_inside tyvar) }
1051
1052 bindIfaceTyVars :: [IfaceTvBndr] -> ([TyVar] -> IfL a) -> IfL a
1053 bindIfaceTyVars bndrs thing_inside
1054   = do  { names <- newIfaceNames (map mkTyVarOcc occs)
1055         ; tyvars <- TcRnMonad.zipWithM mk_iface_tyvar names kinds
1056         ; extendIfaceTyVarEnv tyvars (thing_inside tyvars) }
1057   where
1058     (occs,kinds) = unzip bndrs
1059
1060 mk_iface_tyvar :: Name -> IfaceKind -> IfL TyVar
1061 mk_iface_tyvar name ifKind
1062    = do { kind <- tcIfaceType ifKind
1063         ; if isCoercionKind kind then
1064                 return (Var.mkCoVar name kind)
1065           else
1066                 return (Var.mkTyVar name kind) }
1067 \end{code}
1068